src/Pure/sign.ML
author wenzelm
Fri Oct 28 22:28:00 2005 +0200 (2005-10-28)
changeset 18032 3295e9982a5b
parent 17995 8b9c6af78a67
child 18062 7a666583e869
permissions -rw-r--r--
certify_term: tuned monomorphic consts;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, constant declarations.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_arities: (xstring * string list * string) list -> theory -> theory
    19   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    20   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    21   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    22   val add_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    23   val add_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    24   val del_modesyntax: (string * bool) -> (bstring * string * mixfix) list -> theory -> theory
    25   val del_modesyntax_i: (string * bool) -> (bstring * typ * mixfix) list -> theory -> theory
    26   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    27   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    28   val add_const_constraint: xstring * string -> theory -> theory
    29   val add_const_constraint_i: string * typ -> theory -> theory
    30   val add_classes: (bstring * xstring list) list -> theory -> theory
    31   val add_classes_i: (bstring * class list) list -> theory -> theory
    32   val add_classrel: (xstring * xstring) list -> theory -> theory
    33   val add_classrel_i: (class * class) list -> theory -> theory
    34   val add_trfuns:
    35     (string * (ast list -> ast)) list *
    36     (string * (term list -> term)) list *
    37     (string * (term list -> term)) list *
    38     (string * (ast list -> ast)) list -> theory -> theory
    39   val add_trfunsT:
    40     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    41   val add_advanced_trfuns:
    42     (string * (theory -> ast list -> ast)) list *
    43     (string * (theory -> term list -> term)) list *
    44     (string * (theory -> term list -> term)) list *
    45     (string * (theory -> ast list -> ast)) list -> theory -> theory
    46   val add_advanced_trfunsT:
    47     (string * (theory -> bool -> typ -> term list -> term)) list -> theory -> theory
    48   val add_tokentrfuns:
    49     (string * string * (string -> string * real)) list -> theory -> theory
    50   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    51     -> theory -> theory
    52   val parse_ast_translation: bool * string -> theory -> theory
    53   val parse_translation: bool * string -> theory -> theory
    54   val print_translation: bool * string -> theory -> theory
    55   val typed_print_translation: bool * string -> theory -> theory
    56   val print_ast_translation: bool * string -> theory -> theory
    57   val token_translation: string -> theory -> theory
    58   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    59   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    60   val add_path: string -> theory -> theory
    61   val parent_path: theory -> theory
    62   val root_path: theory -> theory
    63   val absolute_path: theory -> theory
    64   val local_path: theory -> theory
    65   val qualified_names: theory -> theory
    66   val no_base_names: theory -> theory
    67   val custom_accesses: (string list -> string list list) -> theory -> theory
    68   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    69     theory -> theory
    70   val restore_naming: theory -> theory -> theory
    71   val hide_classes: bool -> xstring list -> theory -> theory
    72   val hide_classes_i: bool -> string list -> theory -> theory
    73   val hide_types: bool -> xstring list -> theory -> theory
    74   val hide_types_i: bool -> string list -> theory -> theory
    75   val hide_consts: bool -> xstring list -> theory -> theory
    76   val hide_consts_i: bool -> string list -> theory -> theory
    77   val hide_names: bool -> string * xstring list -> theory -> theory
    78   val hide_names_i: bool -> string * string list -> theory -> theory
    79 end
    80 
    81 signature SIGN =
    82 sig
    83   type sg    (*obsolete*)
    84   val init_data: theory -> theory
    85   val rep_sg: theory ->
    86    {naming: NameSpace.naming,
    87     syn: Syntax.syntax,
    88     tsig: Type.tsig,
    89     consts: ((typ * bool) * serial) NameSpace.table * typ Symtab.table}
    90   val naming_of: theory -> NameSpace.naming
    91   val base_name: string -> bstring
    92   val full_name: theory -> bstring -> string
    93   val full_name_path: theory -> string -> bstring -> string
    94   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    95   val syn_of: theory -> Syntax.syntax
    96   val tsig_of: theory -> Type.tsig
    97   val classes_of: theory -> Sorts.classes
    98   val classes_arities_of: theory -> Sorts.classes * Sorts.arities
    99   val classes: theory -> class list
   100   val defaultS: theory -> sort
   101   val subsort: theory -> sort * sort -> bool
   102   val of_sort: theory -> typ * sort -> bool
   103   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   104   val universal_witness: theory -> (typ * sort) option
   105   val all_sorts_nonempty: theory -> bool
   106   val typ_instance: theory -> typ * typ -> bool
   107   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   108   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   109   val is_logtype: theory -> string -> bool
   110   val const_constraint: theory -> string -> typ option
   111   val the_const_constraint: theory -> string -> typ
   112   val const_type: theory -> string -> typ option
   113   val the_const_type: theory -> string -> typ
   114   val declared_tyname: theory -> string -> bool
   115   val declared_const: theory -> string -> bool
   116   val monomorphic: theory -> string -> bool
   117   val class_space: theory -> NameSpace.T
   118   val type_space: theory -> NameSpace.T
   119   val const_space: theory -> NameSpace.T
   120   val intern_class: theory -> xstring -> string
   121   val extern_class: theory -> string -> xstring
   122   val intern_type: theory -> xstring -> string
   123   val extern_type: theory -> string -> xstring
   124   val intern_const: theory -> xstring -> string
   125   val extern_const: theory -> string -> xstring
   126   val intern_sort: theory -> sort -> sort
   127   val extern_sort: theory -> sort -> sort
   128   val intern_typ: theory -> typ -> typ
   129   val extern_typ: theory -> typ -> typ
   130   val intern_term: theory -> term -> term
   131   val extern_term: theory -> term -> term
   132   val intern_tycons: theory -> typ -> typ
   133   val pretty_term': Syntax.syntax -> theory -> term -> Pretty.T
   134   val pretty_term: theory -> term -> Pretty.T
   135   val pretty_typ: theory -> typ -> Pretty.T
   136   val pretty_sort: theory -> sort -> Pretty.T
   137   val pretty_classrel: theory -> class list -> Pretty.T
   138   val pretty_arity: theory -> arity -> Pretty.T
   139   val string_of_term: theory -> term -> string
   140   val string_of_typ: theory -> typ -> string
   141   val string_of_sort: theory -> sort -> string
   142   val string_of_classrel: theory -> class list -> string
   143   val string_of_arity: theory -> arity -> string
   144   val pprint_term: theory -> term -> pprint_args -> unit
   145   val pprint_typ: theory -> typ -> pprint_args -> unit
   146   val pp: theory -> Pretty.pp
   147   val certify_class: theory -> class -> class
   148   val certify_sort: theory -> sort -> sort
   149   val certify_typ: theory -> typ -> typ
   150   val certify_typ_syntax: theory -> typ -> typ
   151   val certify_typ_abbrev: theory -> typ -> typ
   152   val certify_term: Pretty.pp -> theory -> term -> term * typ * int
   153   val certify_prop: Pretty.pp -> theory -> term -> term * typ * int
   154   val cert_term: theory -> term -> term
   155   val cert_prop: theory -> term -> term
   156   val read_sort': Syntax.syntax -> theory -> string -> sort
   157   val read_sort: theory -> string -> sort
   158   val read_typ': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   159   val read_typ_syntax': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   160   val read_typ_abbrev': Syntax.syntax -> theory * (indexname -> sort option) -> string -> typ
   161   val read_typ: theory * (indexname -> sort option) -> string -> typ
   162   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   163   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   164   val read_tyname: theory -> string -> typ
   165   val read_const: theory -> string -> term
   166   val infer_types_simult: Pretty.pp -> theory -> (indexname -> typ option) ->
   167     (indexname -> sort option) -> string list -> bool
   168     -> (term list * typ) list -> term list * (indexname * typ) list
   169   val infer_types: Pretty.pp -> theory -> (indexname -> typ option) ->
   170     (indexname -> sort option) -> string list -> bool
   171     -> term list * typ -> term * (indexname * typ) list
   172   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax ->
   173     theory * (indexname -> typ option) * (indexname -> sort option) ->
   174     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   175   val read_def_terms:
   176     theory * (indexname -> typ option) * (indexname -> sort option) ->
   177     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   178   val simple_read_term: theory -> typ -> string -> term
   179   val read_term: theory -> string -> term
   180   val read_prop: theory -> string -> term
   181   val const_of_class: class -> string
   182   val class_of_const: string -> class
   183   include SIGN_THEORY
   184 end
   185 
   186 structure Sign: SIGN =
   187 struct
   188 
   189 type sg = theory;
   190 
   191 
   192 (** datatype sign **)
   193 
   194 datatype sign = Sign of
   195  {naming: NameSpace.naming,                   (*common naming conventions*)
   196   syn: Syntax.syntax,                         (*concrete syntax for terms, types, sorts*)
   197   tsig: Type.tsig,                            (*order-sorted signature of types*)
   198   consts:
   199     ((typ * bool) * serial) NameSpace.table * (*type schemes of declared term constants*)
   200     typ Symtab.table};                        (*type constraints for constants*)
   201 
   202 
   203 fun make_sign (naming, syn, tsig, consts) =
   204   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   205 
   206 fun err_dup_consts cs =
   207   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   208 
   209 fun err_inconsistent_constraints cs =
   210   error ("Inconsistent type constraints for constant(s) " ^ commas_quote cs);
   211 
   212 structure SignData = TheoryDataFun
   213 (struct
   214   val name = "Pure/sign";
   215   type T = sign;
   216   val copy = I;
   217   fun extend (Sign {syn, tsig, consts, ...}) =
   218     make_sign (NameSpace.default_naming, syn, tsig, consts);
   219 
   220   val empty = make_sign (NameSpace.default_naming, Syntax.pure_syn, Type.empty_tsig,
   221     (NameSpace.empty_table, Symtab.empty));
   222 
   223   fun merge pp (sign1, sign2) =
   224     let
   225       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = (consts1, constraints1)} = sign1;
   226       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = (consts2, constraints2)} = sign2;
   227 
   228       val naming = NameSpace.default_naming;
   229       val syn = Syntax.merge_syntaxes syn1 syn2;
   230       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   231       val consts = NameSpace.merge_tables (eq_snd (op =)) (consts1, consts2)
   232         handle Symtab.DUPS cs => err_dup_consts cs;
   233       val constraints = Symtab.merge (op =) (constraints1, constraints2)
   234         handle Symtab.DUPS cs => err_inconsistent_constraints cs;
   235     in make_sign (naming, syn, tsig, (consts, constraints)) end;
   236 
   237   fun print _ _ = ();
   238 end);
   239 
   240 val init_data = SignData.init;
   241 
   242 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   243 
   244 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   245   make_sign (f (naming, syn, tsig, consts)));
   246 
   247 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   248 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   249 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   250 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   251 
   252 
   253 (* naming *)
   254 
   255 val naming_of = #naming o rep_sg;
   256 val base_name = NameSpace.base;
   257 val full_name = NameSpace.full o naming_of;
   258 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   259 val declare_name = NameSpace.declare o naming_of;
   260 
   261 
   262 (* syntax *)
   263 
   264 val syn_of = #syn o rep_sg;
   265 
   266 
   267 (* type signature *)
   268 
   269 val tsig_of = #tsig o rep_sg;
   270 val classes_of = snd o #classes o Type.rep_tsig o tsig_of;
   271 fun classes_arities_of thy = (classes_of thy, #arities (Type.rep_tsig (tsig_of thy)));
   272 val classes = Type.classes o tsig_of;
   273 val defaultS = Type.defaultS o tsig_of;
   274 val subsort = Type.subsort o tsig_of;
   275 val of_sort = Type.of_sort o tsig_of;
   276 val witness_sorts = Type.witness_sorts o tsig_of;
   277 val universal_witness = Type.universal_witness o tsig_of;
   278 val all_sorts_nonempty = is_some o universal_witness;
   279 val typ_instance = Type.typ_instance o tsig_of;
   280 val typ_match = Type.typ_match o tsig_of;
   281 val typ_unify = Type.unify o tsig_of;
   282 fun is_logtype thy c = c mem_string Type.logical_types (tsig_of thy);
   283 
   284 
   285 (* consts signature *)
   286 
   287 fun const_constraint thy c =
   288   let val ((_, consts), constraints) = #consts (rep_sg thy) in
   289     (case Symtab.lookup constraints c of
   290       NONE => Option.map (#1 o #1) (Symtab.lookup consts c)
   291     | some => some)
   292   end;
   293 
   294 fun the_const_constraint thy c =
   295   (case const_constraint thy c of SOME T => T
   296   | NONE => raise TYPE ("Undeclared constant " ^ quote c, [], []));
   297 
   298 val lookup_const = Symtab.lookup o #2 o #1 o #consts o rep_sg;
   299 val const_type = Option.map (#1 o #1) oo lookup_const;
   300 
   301 fun the_const_type thy c =
   302   (case const_type thy c of SOME T => T
   303   | NONE => raise TYPE ("Undeclared constant " ^ quote c, [], []));
   304 
   305 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   306 val declared_const = is_some oo const_type;
   307 
   308 fun monomorphic thy =
   309   let val mono = Symtab.lookup (#2 (#1 (#consts (rep_sg thy))))
   310   in fn c => (case mono c of SOME ((_, m), _) => m | _ => false) end;
   311 
   312 
   313 
   314 (** intern / extern names **)
   315 
   316 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   317 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   318 val const_space = #1 o #1 o #consts o rep_sg
   319 
   320 val intern_class = NameSpace.intern o class_space;
   321 val extern_class = NameSpace.extern o class_space;
   322 val intern_type = NameSpace.intern o type_space;
   323 val extern_type = NameSpace.extern o type_space;
   324 val intern_const = NameSpace.intern o const_space;
   325 val extern_const = NameSpace.extern o const_space;
   326 
   327 val intern_sort = map o intern_class;
   328 val extern_sort = map o extern_class;
   329 
   330 local
   331 
   332 fun mapping add_names f t =
   333   let
   334     fun f' x = let val y = f x in if x = y then NONE else SOME (x, y) end;
   335     val tab = List.mapPartial f' (add_names (t, []));
   336     fun get x = if_none (AList.lookup (op =) tab x) x;
   337   in get end;
   338 
   339 fun typ_mapping f g thy T =
   340   T |> Term.map_typ
   341     (mapping add_typ_classes (f thy) T)
   342     (mapping add_typ_tycons (g thy) T);
   343 
   344 fun term_mapping f g h thy t =
   345   t |> Term.map_term
   346     (mapping add_term_classes (f thy) t)
   347     (mapping add_term_tycons (g thy) t)
   348     (mapping add_term_consts (h thy) t);
   349 
   350 in
   351 
   352 val intern_typ = typ_mapping intern_class intern_type;
   353 val extern_typ = typ_mapping extern_class extern_type;
   354 val intern_term = term_mapping intern_class intern_type intern_const;
   355 val extern_term = term_mapping extern_class extern_type extern_const;
   356 val intern_tycons = typ_mapping (K I) intern_type;
   357 
   358 end;
   359 
   360 
   361 
   362 (** pretty printing of terms, types etc. **)
   363 
   364 fun pretty_term' syn thy t =
   365   Syntax.pretty_term thy syn (Context.exists_name Context.CPureN thy) (extern_term thy t);
   366 fun pretty_term thy t = pretty_term' (syn_of thy) thy t;
   367 fun pretty_typ thy T = Syntax.pretty_typ thy (syn_of thy) (extern_typ thy T);
   368 fun pretty_sort thy S = Syntax.pretty_sort thy (syn_of thy) (extern_sort thy S);
   369 
   370 fun pretty_classrel thy cs = Pretty.block (List.concat
   371   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   372 
   373 fun pretty_arity thy (a, Ss, S) =
   374   let
   375     val a' = extern_type thy a;
   376     val dom =
   377       if null Ss then []
   378       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   379   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   380 
   381 val string_of_term = Pretty.string_of oo pretty_term;
   382 val string_of_typ = Pretty.string_of oo pretty_typ;
   383 val string_of_sort = Pretty.string_of oo pretty_sort;
   384 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   385 val string_of_arity = Pretty.string_of oo pretty_arity;
   386 
   387 val pprint_term = (Pretty.pprint o Pretty.quote) oo pretty_term;
   388 val pprint_typ = (Pretty.pprint o Pretty.quote) oo pretty_typ;
   389 
   390 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   391   pretty_classrel thy, pretty_arity thy);
   392 
   393 
   394 
   395 (** certify entities **)    (*exception TYPE*)
   396 
   397 (* certify wrt. type signature *)
   398 
   399 fun certify cert = cert o tsig_of o Context.check_thy;
   400 
   401 val certify_class      = certify Type.cert_class;
   402 val certify_sort       = certify Type.cert_sort;
   403 val certify_typ        = certify Type.cert_typ;
   404 val certify_typ_syntax = certify Type.cert_typ_syntax;
   405 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   406 
   407 
   408 (* certify_term *)
   409 
   410 local
   411 
   412 (*determine and check the type of a term*)
   413 fun type_check pp tm =
   414   let
   415     fun err_appl why bs t T u U =
   416       let
   417         val xs = map Free bs;           (*we do not rename here*)
   418         val t' = subst_bounds (xs, t);
   419         val u' = subst_bounds (xs, u);
   420         val msg = cat_lines
   421           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   422       in raise TYPE (msg, [T, U], [t', u']) end;
   423 
   424     fun typ_of (_, Const (_, T)) = T
   425       | typ_of (_, Free  (_, T)) = T
   426       | typ_of (_, Var (_, T)) = T
   427       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   428           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   429       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   430       | typ_of (bs, t $ u) =
   431           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   432             (case T of
   433               Type ("fun", [T1, T2]) =>
   434                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   435             | _ => err_appl "Operator not of function type" bs t T u U)
   436           end;
   437 
   438   in typ_of ([], tm) end;
   439 
   440 in
   441 
   442 fun certify_term pp thy tm =
   443   let
   444     val _ = Context.check_thy thy;
   445 
   446     val tm' = map_term_types (certify_typ thy) tm;
   447     val tm' = if tm = tm' then tm else tm';  (*avoid copying of already normal term*)
   448 
   449     fun err msg = raise TYPE (msg, [], [tm']);
   450 
   451     fun show_const a T = quote a ^ " :: " ^ Pretty.string_of_typ pp T;
   452 
   453     fun check_atoms (t $ u) = (check_atoms t; check_atoms u)
   454       | check_atoms (Abs (_, _, t)) = check_atoms t
   455       | check_atoms (Const (a, T)) =
   456           (case lookup_const thy a of
   457             NONE => err ("Undeclared constant " ^ show_const a T)
   458           | SOME ((U, mono), _) =>
   459               if mono andalso T = U orelse typ_instance thy (T, U) then ()
   460               else err ("Illegal type for constant " ^ show_const a T))
   461       | check_atoms (Var ((x, i), _)) =
   462           if i < 0 then err ("Malformed variable: " ^ quote x) else ()
   463       | check_atoms _ = ();
   464   in
   465     check_atoms tm';
   466     (tm', type_check pp tm', maxidx_of_term tm')
   467   end;
   468 
   469 end;
   470 
   471 fun certify_prop pp thy tm =
   472   let val res as (tm', T, _) = certify_term pp thy tm
   473   in if T <> propT then raise TYPE ("Term not of type prop", [T], [tm']) else res end;
   474 
   475 fun cert_term thy tm = #1 (certify_term (pp thy) thy tm);
   476 fun cert_prop thy tm = #1 (certify_prop (pp thy) thy tm);
   477 
   478 
   479 
   480 (** read and certify entities **)    (*exception ERROR*)
   481 
   482 (* sorts *)
   483 
   484 fun read_sort' syn thy str =
   485   let
   486     val _ = Context.check_thy thy;
   487     val S = intern_sort thy (Syntax.read_sort thy syn str);
   488   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   489 
   490 fun read_sort thy str = read_sort' (syn_of thy) thy str;
   491 
   492 
   493 (* types *)
   494 
   495 local
   496 
   497 fun gen_read_typ' cert syn (thy, def_sort) str =
   498   let
   499     val _ = Context.check_thy thy;
   500     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   501     val T = intern_tycons thy (Syntax.read_typ thy syn get_sort (intern_sort thy) str);
   502   in cert thy T handle TYPE (msg, _, _) => error msg end
   503   handle ERROR => error ("The error(s) above occurred in type " ^ quote str);
   504 
   505 fun gen_read_typ cert (thy, def_sort) str =
   506   gen_read_typ' cert (syn_of thy) (thy, def_sort) str;
   507 
   508 in
   509 
   510 fun no_def_sort thy = (thy: theory, K NONE);
   511 
   512 val read_typ'        = gen_read_typ' certify_typ;
   513 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   514 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   515 val read_typ         = gen_read_typ certify_typ;
   516 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   517 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   518 
   519 end;
   520 
   521 
   522 (* type and constant names *)
   523 
   524 fun read_tyname thy raw_c =
   525   let val c = intern_type thy raw_c in
   526     (case Symtab.lookup (#2 (#types (Type.rep_tsig (tsig_of thy)))) c of
   527       SOME (Type.LogicalType n, _) => Type (c, replicate n dummyT)
   528     | _ => error ("Undeclared type constructor: " ^ quote c))
   529   end;
   530 
   531 fun read_const thy raw_c =
   532   let
   533     val c = intern_const thy raw_c;
   534     val _ = the_const_type thy c handle TYPE (msg, _, _) => error msg;
   535   in Const (c, dummyT) end;
   536 
   537 
   538 
   539 (** infer_types **)         (*exception ERROR*)
   540 
   541 (*
   542   def_type: partial map from indexnames to types (constrains Frees and Vars)
   543   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   544   used: list of already used type variables
   545   freeze: if true then generated parameters are turned into TFrees, else TVars
   546 
   547   termss: lists of alternative parses (only one combination should be type-correct)
   548   typs: expected types
   549 *)
   550 
   551 fun infer_types_simult pp thy def_type def_sort used freeze args =
   552   let
   553     val termss = foldr multiply [[]] (map fst args);
   554     val typs =
   555       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   556 
   557     fun infer ts = OK (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   558         (const_constraint thy) def_type def_sort (intern_const thy) (intern_tycons thy)
   559         (intern_sort thy) used freeze typs ts)
   560       handle TYPE (msg, _, _) => Error msg;
   561 
   562     val err_results = map infer termss;
   563     val errs = List.mapPartial get_error err_results;
   564     val results = List.mapPartial get_ok err_results;
   565 
   566     val ambiguity = length termss;
   567 
   568     fun ambig_msg () =
   569       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   570       then
   571         error_msg "Got more than one parse tree.\n\
   572           \Retry with smaller Syntax.ambiguity_level for more information."
   573       else ();
   574   in
   575     if null results then (ambig_msg (); error (cat_lines errs))
   576     else if length results = 1 then
   577       (if ambiguity > ! Syntax.ambiguity_level then
   578         warning "Fortunately, only one parse tree is type correct.\n\
   579           \You may still want to disambiguate your grammar or your input."
   580       else (); hd results)
   581     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   582       cat_lines (map (Pretty.string_of_term pp) (List.concat (map fst results)))))
   583   end;
   584 
   585 fun infer_types pp thy def_type def_sort used freeze tsT =
   586   apfst hd (infer_types_simult pp thy def_type def_sort used freeze [tsT]);
   587 
   588 
   589 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   590 
   591 fun read_def_terms' pp is_logtype syn (thy, types, sorts) used freeze sTs =
   592   let
   593     fun read (s, T) =
   594       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   595       in (Syntax.read thy is_logtype syn T' s, T') end;
   596   in infer_types_simult pp thy types sorts used freeze (map read sTs) end;
   597 
   598 fun read_def_terms (thy, types, sorts) =
   599   read_def_terms' (pp thy) (is_logtype thy) (syn_of thy) (thy, types, sorts);
   600 
   601 fun simple_read_term thy T s =
   602   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   603   in t end
   604   handle ERROR => error ("The error(s) above occurred for term " ^ s);
   605 
   606 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   607 fun read_prop thy = simple_read_term thy propT;
   608 
   609 
   610 
   611 (** signature extension functions **)  (*exception ERROR/TYPE*)
   612 
   613 (* add default sort *)
   614 
   615 fun gen_add_defsort prep_sort s thy =
   616   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   617 
   618 val add_defsort = gen_add_defsort read_sort;
   619 val add_defsort_i = gen_add_defsort certify_sort;
   620 
   621 
   622 (* add type constructors *)
   623 
   624 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   625   let
   626     val syn' = Syntax.extend_type_gram types syn;
   627     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   628     val tsig' = Type.add_types naming decls tsig;
   629   in (naming, syn', tsig', consts) end);
   630 
   631 fun add_typedecls decls thy =
   632   let
   633     fun type_of (a, vs, mx) =
   634       if null (duplicates vs) then (a, length vs, mx)
   635       else error ("Duplicate parameters in type declaration: " ^ quote a);
   636   in add_types (map type_of decls) thy end;
   637 
   638 
   639 (* add nonterminals *)
   640 
   641 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   642   let
   643     val syn' = Syntax.extend_consts ns syn;
   644     val tsig' = Type.add_nonterminals naming ns tsig;
   645   in (naming, syn', tsig', consts) end);
   646 
   647 
   648 (* add type abbreviations *)
   649 
   650 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   651   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   652     let
   653       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   654       val a' = Syntax.type_name a mx;
   655       val abbr = (a', vs, prep_typ thy rhs)
   656         handle ERROR => error ("in type abbreviation " ^ quote a');
   657       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   658     in (naming, syn', tsig', consts) end);
   659 
   660 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   661 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   662 
   663 
   664 (* add type arities *)
   665 
   666 fun gen_add_arities int_type prep_sort arities thy = thy |> map_tsig (fn tsig =>
   667   let
   668     fun prep_arity (a, Ss, S) = (int_type thy a, map (prep_sort thy) Ss, prep_sort thy S)
   669       handle ERROR => error ("in arity for type " ^ quote a);
   670     val tsig' = Type.add_arities (pp thy) (map prep_arity arities) tsig;
   671   in tsig' end);
   672 
   673 val add_arities = gen_add_arities intern_type read_sort;
   674 val add_arities_i = gen_add_arities (K I) certify_sort;
   675 
   676 
   677 (* modify syntax *)
   678 
   679 fun gen_syntax change_gram prep_typ prmode args thy =
   680   let
   681     fun prep (c, T, mx) = (c, prep_typ thy T, mx)
   682       handle ERROR => error ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   683   in thy |> map_syn (change_gram (is_logtype thy) prmode (map prep args)) end;
   684 
   685 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   686 
   687 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   688 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   689 val add_syntax = add_modesyntax Syntax.default_mode;
   690 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   691 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   692 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   693 
   694 
   695 (* add constants *)
   696 
   697 local
   698 
   699 fun is_mono (Type (_, Ts)) = forall is_mono Ts
   700   | is_mono _ = false;
   701 
   702 fun gen_add_consts prep_typ raw_args thy =
   703   let
   704     val prepT = Compress.typ thy o Type.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   705     fun prep (c, T, mx) = ((c, prepT T, mx) handle TYPE (msg, _, _) => error msg)
   706       handle ERROR => error ("in declaration of constant " ^ quote (Syntax.const_name c mx));
   707     val args = map prep raw_args;
   708 
   709     val decls = args |> map (fn (c, T, mx) =>
   710       (Syntax.const_name c mx, ((T, is_mono T), serial ())));
   711 
   712     fun extend_consts consts = NameSpace.extend_table (naming_of thy) (consts, decls)
   713       handle Symtab.DUPS cs => err_dup_consts cs;
   714   in
   715     thy
   716     |> map_consts (apfst extend_consts)
   717     |> add_syntax_i args
   718   end;
   719 
   720 in
   721 
   722 val add_consts = gen_add_consts (read_typ o no_def_sort);
   723 val add_consts_i = gen_add_consts certify_typ;
   724 
   725 end;
   726 
   727 
   728 (* add constraints *)
   729 
   730 fun gen_add_constraint int_const prep_typ (raw_c, raw_T) thy =
   731   let
   732     val c = int_const thy raw_c;
   733     val T = Term.zero_var_indexesT (Term.no_dummyT (prep_typ thy raw_T))
   734       handle TYPE (msg, _, _) => error msg;
   735     val _ = cert_term thy (Const (c, T))
   736       handle TYPE (msg, _, _) => error msg;
   737   in thy |> map_consts (apsnd (Symtab.update (c, T))) end;
   738 
   739 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   740 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   741 
   742 
   743 (* add type classes *)
   744 
   745 val classN = "_class";
   746 
   747 val const_of_class = suffix classN;
   748 fun class_of_const c = unsuffix classN c
   749   handle Fail _ => raise TERM ("class_of_const: bad name " ^ quote c, []);
   750 
   751 fun gen_add_class int_class (bclass, raw_classes) thy =
   752   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   753     let
   754       val classes = map (int_class thy) raw_classes;
   755       val syn' = Syntax.extend_consts [bclass] syn;
   756       val tsig' = Type.add_classes (pp thy) naming [(bclass, classes)] tsig;
   757     in (naming, syn', tsig', consts) end)
   758   |> add_consts_i [(const_of_class bclass, a_itselfT --> propT, Syntax.NoSyn)];
   759 
   760 val add_classes = fold (gen_add_class intern_class);
   761 val add_classes_i = fold (gen_add_class (K I));
   762 
   763 
   764 (* add to classrel *)
   765 
   766 fun gen_add_classrel int_class raw_pairs thy = thy |> map_tsig (fn tsig =>
   767   let
   768     val pairs = map (pairself (int_class thy)) raw_pairs;
   769     val tsig' = Type.add_classrel (pp thy) pairs tsig;
   770   in tsig' end);
   771 
   772 val add_classrel = gen_add_classrel intern_class;
   773 val add_classrel_i = gen_add_classrel (K I);
   774 
   775 
   776 (* add translation functions *)
   777 
   778 local
   779 
   780 fun mk trs = map Syntax.mk_trfun trs;
   781 
   782 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   783   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   784 
   785 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   786 
   787 in
   788 
   789 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   790 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   791 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   792 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   793 
   794 end;
   795 
   796 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   797 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   798 
   799 
   800 (* compile translation functions *)
   801 
   802 local
   803 
   804 fun advancedT false = ""
   805   | advancedT true = "theory -> ";
   806 
   807 fun advancedN false = ""
   808   | advancedN true = "advanced_";
   809 
   810 in
   811 
   812 fun parse_ast_translation (a, txt) =
   813   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   814       "Syntax.ast list -> Syntax.ast)) list")
   815     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   816 
   817 fun parse_translation (a, txt) =
   818   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   819       "term list -> term)) list")
   820     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   821 
   822 fun print_translation (a, txt) =
   823   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   824       "term list -> term)) list")
   825     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   826 
   827 fun print_ast_translation (a, txt) =
   828   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   829       "Syntax.ast list -> Syntax.ast)) list")
   830     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   831 
   832 fun typed_print_translation (a, txt) =
   833   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   834       "bool -> typ -> term list -> term)) list")
   835     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   836 
   837 val token_translation =
   838   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   839     "Sign.add_tokentrfuns token_translation";
   840 
   841 end;
   842 
   843 
   844 (* add translation rules *)
   845 
   846 fun add_trrules args thy = thy |> map_syn (fn syn =>
   847   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   848   in Syntax.extend_trrules thy (is_logtype thy) syn rules syn end);
   849 
   850 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   851 
   852 
   853 (* modify naming *)
   854 
   855 val add_path        = map_naming o NameSpace.add_path;
   856 val qualified_names = map_naming NameSpace.qualified_names;
   857 val no_base_names   = map_naming NameSpace.no_base_names;
   858 val custom_accesses = map_naming o NameSpace.custom_accesses;
   859 val set_policy      = map_naming o NameSpace.set_policy;
   860 val restore_naming  = map_naming o K o naming_of;
   861 
   862 val parent_path     = add_path "..";
   863 val root_path       = add_path "/";
   864 val absolute_path   = add_path "//";
   865 
   866 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   867 
   868 
   869 (* hide names *)
   870 
   871 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   872 val hide_classes_i = map_tsig oo Type.hide_classes;
   873 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   874 val hide_types_i = map_tsig oo Type.hide_types;
   875 fun hide_consts b xs thy =
   876   thy |> map_consts (apfst (apfst (fold (NameSpace.hide b o intern_const thy) xs)));
   877 val hide_consts_i = (map_consts o apfst o apfst) oo (fold o NameSpace.hide);
   878 
   879 local
   880 
   881 val kinds =
   882  [("class", (intern_class, can o certify_class, hide_classes_i)),
   883   ("type", (intern_type, declared_tyname, hide_types_i)),
   884   ("const", (intern_const, declared_const, hide_consts_i))];
   885 
   886 fun gen_hide int b (kind, xnames) thy =
   887   (case AList.lookup (op =) kinds kind of
   888     SOME (intern, check, hide) =>
   889       let
   890         val names = if int then map (intern thy) xnames else xnames;
   891         val bads = filter_out (check thy) names;
   892       in
   893         if null bads then hide b names thy
   894         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   895       end
   896   | NONE => error ("Bad name space specification: " ^ quote kind));
   897 
   898 in
   899 
   900 val hide_names = gen_hide true;
   901 val hide_names_i = gen_hide false;
   902 
   903 end;
   904 
   905 end;