src/Pure/sign.ML
author haftmann
Thu Nov 20 19:06:02 2008 +0100 (2008-11-20)
changeset 28863 32e83a854e5e
parent 28861 f53abb0733ee
child 28941 128459bd72d2
permissions -rw-r--r--
dropped legacy naming code
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN =
    10 sig
    11   val rep_sg: theory ->
    12    {naming: NameSpace.naming,
    13     syn: Syntax.syntax,
    14     tsig: Type.tsig,
    15     consts: Consts.T}
    16   val naming_of: theory -> NameSpace.naming
    17   val base_name: string -> bstring
    18   val full_name: theory -> bstring -> string
    19   val full_binding: theory -> Name.binding -> string
    20   val full_name_path: theory -> string -> bstring -> string
    21   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    22   val syn_of: theory -> Syntax.syntax
    23   val tsig_of: theory -> Type.tsig
    24   val classes_of: theory -> Sorts.algebra
    25   val all_classes: theory -> class list
    26   val super_classes: theory -> class -> class list
    27   val minimize_sort: theory -> sort -> sort
    28   val complete_sort: theory -> sort -> sort
    29   val defaultS: theory -> sort
    30   val subsort: theory -> sort * sort -> bool
    31   val of_sort: theory -> typ * sort -> bool
    32   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    33   val is_logtype: theory -> string -> bool
    34   val typ_instance: theory -> typ * typ -> bool
    35   val typ_equiv: theory -> typ * typ -> bool
    36   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    37   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    38   val consts_of: theory -> Consts.T
    39   val the_const_constraint: theory -> string -> typ
    40   val const_type: theory -> string -> typ option
    41   val the_const_type: theory -> string -> typ
    42   val declared_tyname: theory -> string -> bool
    43   val declared_const: theory -> string -> bool
    44   val const_monomorphic: theory -> string -> bool
    45   val const_syntax_name: theory -> string -> string
    46   val const_typargs: theory -> string * typ -> typ list
    47   val const_instance: theory -> string * typ list -> typ
    48   val mk_const: theory -> string * typ list -> term
    49   val class_space: theory -> NameSpace.T
    50   val type_space: theory -> NameSpace.T
    51   val const_space: theory -> NameSpace.T
    52   val intern_class: theory -> xstring -> string
    53   val extern_class: theory -> string -> xstring
    54   val intern_type: theory -> xstring -> string
    55   val extern_type: theory -> string -> xstring
    56   val intern_const: theory -> xstring -> string
    57   val extern_const: theory -> string -> xstring
    58   val intern_sort: theory -> sort -> sort
    59   val extern_sort: theory -> sort -> sort
    60   val intern_typ: theory -> typ -> typ
    61   val extern_typ: theory -> typ -> typ
    62   val intern_term: theory -> term -> term
    63   val extern_term: (string -> xstring) -> theory -> term -> term
    64   val intern_tycons: theory -> typ -> typ
    65   val arity_number: theory -> string -> int
    66   val arity_sorts: theory -> string -> sort -> sort list
    67   val certify_class: theory -> class -> class
    68   val certify_sort: theory -> sort -> sort
    69   val certify_typ: theory -> typ -> typ
    70   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    71   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    72   val certify_term: theory -> term -> term * typ * int
    73   val certify_prop: theory -> term -> term * typ * int
    74   val cert_term: theory -> term -> term
    75   val cert_prop: theory -> term -> term
    76   val no_frees: Pretty.pp -> term -> term
    77   val no_vars: Pretty.pp -> term -> term
    78   val cert_def: Proof.context -> term -> (string * typ) * term
    79   val read_class: theory -> xstring -> class
    80   val read_arity: theory -> xstring * string list * string -> arity
    81   val cert_arity: theory -> arity -> arity
    82   val add_defsort: string -> theory -> theory
    83   val add_defsort_i: sort -> theory -> theory
    84   val add_types: (bstring * int * mixfix) list -> theory -> theory
    85   val add_nonterminals: bstring list -> theory -> theory
    86   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    87   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    88   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    89   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    90   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    91   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    92   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    93   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    94   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    95   val declare_const: Properties.T -> (Name.binding * typ) * mixfix -> theory -> term * theory
    96   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    97   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    98   val add_abbrev: string -> Properties.T -> Name.binding * term -> theory -> (term * term) * theory
    99   val revert_abbrev: string -> string -> theory -> theory
   100   val add_const_constraint: string * typ option -> theory -> theory
   101   val primitive_class: string * class list -> theory -> theory
   102   val primitive_classrel: class * class -> theory -> theory
   103   val primitive_arity: arity -> theory -> theory
   104   val add_trfuns:
   105     (string * (ast list -> ast)) list *
   106     (string * (term list -> term)) list *
   107     (string * (term list -> term)) list *
   108     (string * (ast list -> ast)) list -> theory -> theory
   109   val add_trfunsT:
   110     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   111   val add_advanced_trfuns:
   112     (string * (Proof.context -> ast list -> ast)) list *
   113     (string * (Proof.context -> term list -> term)) list *
   114     (string * (Proof.context -> term list -> term)) list *
   115     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   116   val add_advanced_trfunsT:
   117     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   118   val add_tokentrfuns:
   119     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   120   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   121     -> theory -> theory
   122   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   123   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   124   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   125   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   126   val add_path: string -> theory -> theory
   127   val parent_path: theory -> theory
   128   val root_path: theory -> theory
   129   val absolute_path: theory -> theory
   130   val local_path: theory -> theory
   131   val no_base_names: theory -> theory
   132   val qualified_names: theory -> theory
   133   val sticky_prefix: string -> theory -> theory
   134   val restore_naming: theory -> theory -> theory
   135   val hide_class: bool -> string -> theory -> theory
   136   val hide_type: bool -> string -> theory -> theory
   137   val hide_const: bool -> string -> theory -> theory
   138 end
   139 
   140 structure Sign: SIGN =
   141 struct
   142 
   143 (** datatype sign **)
   144 
   145 datatype sign = Sign of
   146  {naming: NameSpace.naming,     (*common naming conventions*)
   147   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   148   tsig: Type.tsig,              (*order-sorted signature of types*)
   149   consts: Consts.T};            (*polymorphic constants*)
   150 
   151 fun make_sign (naming, syn, tsig, consts) =
   152   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   153 
   154 structure SignData = TheoryDataFun
   155 (
   156   type T = sign;
   157   val copy = I;
   158   fun extend (Sign {syn, tsig, consts, ...}) =
   159     make_sign (NameSpace.default_naming, syn, tsig, consts);
   160 
   161   val empty =
   162     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   163 
   164   fun merge pp (sign1, sign2) =
   165     let
   166       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   167       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   168 
   169       val naming = NameSpace.default_naming;
   170       val syn = Syntax.merge_syntaxes syn1 syn2;
   171       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   172       val consts = Consts.merge (consts1, consts2);
   173     in make_sign (naming, syn, tsig, consts) end;
   174 );
   175 
   176 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   177 
   178 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   179   make_sign (f (naming, syn, tsig, consts)));
   180 
   181 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   182 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   183 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   184 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   185 
   186 
   187 (* naming *)
   188 
   189 val naming_of = #naming o rep_sg;
   190 val base_name = NameSpace.base;
   191 
   192 val full_name = NameSpace.full o naming_of;
   193 val full_binding = NameSpace.full_binding o naming_of;
   194 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   195 val declare_name = NameSpace.declare o naming_of;
   196 
   197 
   198 (* syntax *)
   199 
   200 val syn_of = #syn o rep_sg;
   201 
   202 
   203 (* type signature *)
   204 
   205 val tsig_of = #tsig o rep_sg;
   206 
   207 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   208 val all_classes = Sorts.all_classes o classes_of;
   209 val super_classes = Sorts.super_classes o classes_of;
   210 val minimize_sort = Sorts.minimize_sort o classes_of;
   211 val complete_sort = Sorts.complete_sort o classes_of;
   212 
   213 val defaultS = Type.defaultS o tsig_of;
   214 val subsort = Type.subsort o tsig_of;
   215 val of_sort = Type.of_sort o tsig_of;
   216 val witness_sorts = Type.witness_sorts o tsig_of;
   217 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   218 
   219 val typ_instance = Type.typ_instance o tsig_of;
   220 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   221 val typ_match = Type.typ_match o tsig_of;
   222 val typ_unify = Type.unify o tsig_of;
   223 
   224 
   225 (* polymorphic constants *)
   226 
   227 val consts_of = #consts o rep_sg;
   228 val the_const_constraint = Consts.the_constraint o consts_of;
   229 val the_const_type = Consts.the_type o consts_of;
   230 val const_type = try o the_const_type;
   231 val const_monomorphic = Consts.is_monomorphic o consts_of;
   232 val const_syntax_name = Consts.syntax_name o consts_of;
   233 val const_typargs = Consts.typargs o consts_of;
   234 val const_instance = Consts.instance o consts_of;
   235 
   236 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   237 
   238 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   239 val declared_const = can o the_const_constraint;
   240 
   241 
   242 
   243 (** intern / extern names **)
   244 
   245 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   246 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   247 val const_space = Consts.space_of o consts_of;
   248 
   249 val intern_class = NameSpace.intern o class_space;
   250 val extern_class = NameSpace.extern o class_space;
   251 val intern_type = NameSpace.intern o type_space;
   252 val extern_type = NameSpace.extern o type_space;
   253 val intern_const = NameSpace.intern o const_space;
   254 val extern_const = NameSpace.extern o const_space;
   255 
   256 val intern_sort = map o intern_class;
   257 val extern_sort = map o extern_class;
   258 
   259 local
   260 
   261 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   262   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   263   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   264 
   265 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   266   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   267   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   268   | map_term _ _ _ (t as Bound _) = t
   269   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   270   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   271 
   272 val add_classesT = Term.fold_atyps
   273   (fn TFree (_, S) => fold (insert (op =)) S
   274     | TVar (_, S) => fold (insert (op =)) S
   275     | _ => I);
   276 
   277 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   278   | add_tyconsT _ = I;
   279 
   280 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   281 
   282 fun mapping add_names f t =
   283   let
   284     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   285     val tab = map_filter f' (add_names t []);
   286     fun get x = the_default x (AList.lookup (op =) tab x);
   287   in get end;
   288 
   289 fun typ_mapping f g thy T =
   290   T |> map_typ
   291     (mapping add_classesT (f thy) T)
   292     (mapping add_tyconsT (g thy) T);
   293 
   294 fun term_mapping f g h thy t =
   295   t |> map_term
   296     (mapping (Term.fold_types add_classesT) (f thy) t)
   297     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   298     (mapping add_consts (h thy) t);
   299 
   300 in
   301 
   302 val intern_typ = typ_mapping intern_class intern_type;
   303 val extern_typ = typ_mapping extern_class extern_type;
   304 val intern_term = term_mapping intern_class intern_type intern_const;
   305 fun extern_term h = term_mapping extern_class extern_type (K h);
   306 val intern_tycons = typ_mapping (K I) intern_type;
   307 
   308 end;
   309 
   310 
   311 
   312 (** certify entities **)    (*exception TYPE*)
   313 
   314 (* certify wrt. type signature *)
   315 
   316 val arity_number = Type.arity_number o tsig_of;
   317 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   318 
   319 val certify_class         = Type.cert_class o tsig_of;
   320 val certify_sort          = Type.cert_sort o tsig_of;
   321 val certify_typ           = Type.cert_typ o tsig_of;
   322 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   323 
   324 
   325 (* certify term/prop *)
   326 
   327 local
   328 
   329 fun type_check pp tm =
   330   let
   331     fun err_appl why bs t T u U =
   332       let
   333         val xs = map Free bs;           (*we do not rename here*)
   334         val t' = subst_bounds (xs, t);
   335         val u' = subst_bounds (xs, u);
   336         val msg = cat_lines
   337           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   338       in raise TYPE (msg, [T, U], [t', u']) end;
   339 
   340     fun typ_of (_, Const (_, T)) = T
   341       | typ_of (_, Free  (_, T)) = T
   342       | typ_of (_, Var (_, T)) = T
   343       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   344           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   345       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   346       | typ_of (bs, t $ u) =
   347           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   348             (case T of
   349               Type ("fun", [T1, T2]) =>
   350                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   351             | _ => err_appl "Operator not of function type" bs t T u U)
   352           end;
   353   in typ_of ([], tm) end;
   354 
   355 fun err msg = raise TYPE (msg, [], []);
   356 
   357 fun check_vars (t $ u) = (check_vars t; check_vars u)
   358   | check_vars (Abs (_, _, t)) = check_vars t
   359   | check_vars (Free (x, _)) =
   360       if NameSpace.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   361   | check_vars (Var (xi as (_, i), _)) =
   362       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   363   | check_vars _ = ();
   364 
   365 in
   366 
   367 fun certify' prop pp do_expand consts thy tm =
   368   let
   369     val _ = check_vars tm;
   370     val tm' = Term.map_types (certify_typ thy) tm;
   371     val T = type_check pp tm';
   372     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   373     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   374   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   375 
   376 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   377 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   378 
   379 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   380 val cert_term = #1 oo certify_term;
   381 val cert_prop = #1 oo certify_prop;
   382 
   383 end;
   384 
   385 
   386 (* specifications *)
   387 
   388 fun no_variables kind add addT mk mkT pp tm =
   389   (case (add tm [], addT tm []) of
   390     ([], []) => tm
   391   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   392       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   393        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   394 
   395 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   396 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   397 
   398 fun cert_def ctxt tm =
   399   let val ((lhs, rhs), _) = tm
   400     |> no_vars (Syntax.pp ctxt)
   401     |> Logic.strip_imp_concl
   402     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   403   in (Term.dest_Const (Term.head_of lhs), rhs) end
   404   handle TERM (msg, _) => error msg;
   405 
   406 
   407 
   408 (** read and certify entities **)    (*exception ERROR*)
   409 
   410 (* classes *)
   411 
   412 fun read_class thy c = certify_class thy (intern_class thy c)
   413   handle TYPE (msg, _, _) => error msg;
   414 
   415 
   416 (* type arities *)
   417 
   418 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   419   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   420   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   421 
   422 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   423 val cert_arity = prep_arity (K I) certify_sort;
   424 
   425 
   426 
   427 (** signature extension functions **)  (*exception ERROR/TYPE*)
   428 
   429 (* add default sort *)
   430 
   431 fun gen_add_defsort prep_sort s thy =
   432   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   433 
   434 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   435 val add_defsort_i = gen_add_defsort certify_sort;
   436 
   437 
   438 (* add type constructors *)
   439 
   440 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   441   let
   442     val syn' = Syntax.update_type_gram types syn;
   443     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   444     val tags = [(Markup.theory_nameN, Context.theory_name thy)];
   445     val tsig' = fold (Type.add_type naming tags) decls tsig;
   446   in (naming, syn', tsig', consts) end);
   447 
   448 
   449 (* add nonterminals *)
   450 
   451 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   452   let
   453     val syn' = Syntax.update_consts ns syn;
   454     val tsig' = fold (Type.add_nonterminal naming []) ns tsig;
   455   in (naming, syn', tsig', consts) end);
   456 
   457 
   458 (* add type abbreviations *)
   459 
   460 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   461   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   462     let
   463       val ctxt = ProofContext.init thy;
   464       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   465       val a' = Syntax.type_name a mx;
   466       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   467         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   468       val tsig' = Type.add_abbrev naming [] abbr tsig;
   469     in (naming, syn', tsig', consts) end);
   470 
   471 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   472 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   473 
   474 
   475 (* modify syntax *)
   476 
   477 fun gen_syntax change_gram parse_typ mode args thy =
   478   let
   479     val ctxt = ProofContext.init thy;
   480     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   481       handle ERROR msg =>
   482         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   483   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   484 
   485 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   486 
   487 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   488 val add_modesyntax_i = gen_add_syntax (K I);
   489 val add_syntax = add_modesyntax Syntax.mode_default;
   490 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   491 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   492 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   493 
   494 fun notation add mode args thy =
   495   let
   496     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   497     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   498       | const_syntax _ = NONE;
   499   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   500 
   501 
   502 (* add constants *)
   503 
   504 local
   505 
   506 fun gen_add_consts parse_typ authentic tags raw_args thy =
   507   let
   508     val ctxt = ProofContext.init thy;
   509     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   510     fun prep (raw_b, raw_T, raw_mx) =
   511       let
   512         val (mx_name, mx) = Syntax.const_mixfix (Name.name_of raw_b) raw_mx;
   513         val b = Name.map_name (K mx_name) raw_b;
   514         val c = full_binding thy b;
   515         val c_syn = if authentic then Syntax.constN ^ c else Name.name_of b;
   516         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   517           cat_error msg ("in declaration of constant " ^ quote (Name.display b));
   518         val T' = Logic.varifyT T;
   519       in ((b, T'), (c_syn, T', mx), Const (c, T)) end;
   520     val args = map prep raw_args;
   521     val tags' = tags |> Properties.put (Markup.theory_nameN, Context.theory_name thy);
   522   in
   523     thy
   524     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   525     |> add_syntax_i (map #2 args)
   526     |> pair (map #3 args)
   527   end;
   528 
   529 fun bindify (name, T, mx) = (Name.binding name, T, mx);
   530 
   531 in
   532 
   533 fun add_consts args = snd o gen_add_consts Syntax.parse_typ false [] (map bindify args);
   534 fun add_consts_i args = snd o gen_add_consts (K I) false [] (map bindify args);
   535 
   536 fun declare_const tags ((b, T), mx) thy =
   537   let
   538     val pos = Name.pos_of b;
   539     val tags' = Position.default_properties pos tags;
   540     val ([const as Const (c, _)], thy') = gen_add_consts (K I) true tags' [(b, T, mx)] thy;
   541     val _ = Position.report (Markup.const_decl c) pos;
   542   in (const, thy') end;
   543 
   544 end;
   545 
   546 
   547 (* abbreviations *)
   548 
   549 fun add_abbrev mode tags (b, raw_t) thy =
   550   let
   551     val pp = Syntax.pp_global thy;
   552     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   553     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   554       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Name.display b));
   555     val (res, consts') = consts_of thy
   556       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (b, t);
   557   in (res, thy |> map_consts (K consts')) end;
   558 
   559 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   560 
   561 
   562 (* add constraints *)
   563 
   564 fun add_const_constraint (c, opt_T) thy =
   565   let
   566     fun prepT raw_T =
   567       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   568       in cert_term thy (Const (c, T)); T end
   569       handle TYPE (msg, _, _) => error msg;
   570   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   571 
   572 
   573 (* primitive classes and arities *)
   574 
   575 fun primitive_class (bclass, classes) thy =
   576   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   577     let
   578       val syn' = Syntax.update_consts [bclass] syn;
   579       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   580     in (naming, syn', tsig', consts) end)
   581   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   582 
   583 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   584 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   585 
   586 
   587 (* add translation functions *)
   588 
   589 local
   590 
   591 fun mk trs = map Syntax.mk_trfun trs;
   592 
   593 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   594   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   595 
   596 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   597 
   598 in
   599 
   600 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   601 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   602 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   603 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   604 
   605 end;
   606 
   607 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   608 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   609 
   610 
   611 (* translation rules *)
   612 
   613 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   614   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   615   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   616 
   617 val add_trrules = gen_trrules Syntax.update_trrules;
   618 val del_trrules = gen_trrules Syntax.remove_trrules;
   619 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   620 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   621 
   622 
   623 (* naming *)
   624 
   625 val add_path        = map_naming o NameSpace.add_path;
   626 val no_base_names   = map_naming NameSpace.no_base_names;
   627 val qualified_names = map_naming NameSpace.qualified_names;
   628 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   629 val restore_naming  = map_naming o K o naming_of;
   630 
   631 val parent_path   = add_path "..";
   632 val root_path     = add_path "/";
   633 val absolute_path = add_path "//";
   634 
   635 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   636 
   637 
   638 (* hide names *)
   639 
   640 val hide_class = map_tsig oo Type.hide_class;
   641 val hide_type = map_tsig oo Type.hide_type;
   642 val hide_const = map_consts oo Consts.hide;
   643 
   644 end;