src/Pure/config.ML
author wenzelm
Sun May 12 18:22:44 2013 +0200 (2013-05-12)
changeset 51947 3301612c4893
parent 47814 53668571d300
child 51990 cc66addbba6d
permissions -rw-r--r--
support for system options as context-sensitive config options;
     1 (*  Title:      Pure/config.ML
     2     Author:     Makarius
     3 
     4 Configuration options as values within the local context.
     5 *)
     6 
     7 signature CONFIG =
     8 sig
     9   datatype value = Bool of bool | Int of int | Real of real | String of string
    10   val print_value: value -> string
    11   val print_type: value -> string
    12   type 'a T
    13   type raw = value T
    14   val bool: raw -> bool T
    15   val int: raw -> int T
    16   val real: raw -> real T
    17   val string: raw -> string T
    18   val get: Proof.context -> 'a T -> 'a
    19   val map: 'a T -> ('a -> 'a) -> Proof.context -> Proof.context
    20   val put: 'a T -> 'a -> Proof.context -> Proof.context
    21   val get_global: theory -> 'a T -> 'a
    22   val map_global: 'a T -> ('a -> 'a) -> theory -> theory
    23   val put_global: 'a T -> 'a -> theory -> theory
    24   val get_generic: Context.generic -> 'a T -> 'a
    25   val map_generic: 'a T -> ('a -> 'a) -> Context.generic -> Context.generic
    26   val put_generic: 'a T -> 'a -> Context.generic -> Context.generic
    27   val declare_generic: {global: bool} -> string -> (Context.generic -> value) -> raw
    28   val declare_global: string -> (Context.generic -> value) -> raw
    29   val declare: string -> (Context.generic -> value) -> raw
    30   val declare_option: string -> raw
    31   val name_of: 'a T -> string
    32 end;
    33 
    34 structure Config: CONFIG =
    35 struct
    36 
    37 (* simple values *)
    38 
    39 datatype value =
    40   Bool of bool |
    41   Int of int |
    42   Real of real |
    43   String of string;
    44 
    45 fun print_value (Bool true) = "true"
    46   | print_value (Bool false) = "false"
    47   | print_value (Int i) = signed_string_of_int i
    48   | print_value (Real x) = signed_string_of_real x
    49   | print_value (String s) = quote s;
    50 
    51 fun print_type (Bool _) = "bool"
    52   | print_type (Int _) = "int"
    53   | print_type (Real _) = "real"
    54   | print_type (String _) = "string";
    55 
    56 fun same_type (Bool _) (Bool _) = true
    57   | same_type (Int _) (Int _) = true
    58   | same_type (Real _) (Real _) = true
    59   | same_type (String _) (String _) = true
    60   | same_type _ _ = false;
    61 
    62 fun type_check name f value =
    63   let
    64     val value' = f value;
    65     val _ = same_type value value' orelse
    66       error ("Ill-typed configuration option " ^ quote name ^ ": " ^
    67         print_type value ^ " expected,\nbut " ^ print_type value' ^ " was found");
    68   in value' end;
    69 
    70 
    71 (* abstract configuration options *)
    72 
    73 datatype 'a T = Config of
    74  {name: string,
    75   get_value: Context.generic -> 'a,
    76   map_value: ('a -> 'a) -> Context.generic -> Context.generic};
    77 
    78 type raw = value T;
    79 
    80 fun coerce make dest (Config {name, get_value, map_value}) = Config
    81  {name = name,
    82   get_value = dest o get_value,
    83   map_value = fn f => map_value (make o f o dest)};
    84 
    85 val bool = coerce Bool (fn Bool b => b);
    86 val int = coerce Int (fn Int i => i);
    87 val real = coerce Real (fn Real x => x);
    88 val string = coerce String (fn String s => s);
    89 
    90 fun get_generic context (Config {get_value, ...}) = get_value context;
    91 fun map_generic (Config {map_value, ...}) f context = map_value f context;
    92 fun put_generic config value = map_generic config (K value);
    93 
    94 fun get_ctxt ctxt = get_generic (Context.Proof ctxt);
    95 fun map_ctxt config f = Context.proof_map (map_generic config f);
    96 fun put_ctxt config value = map_ctxt config (K value);
    97 
    98 fun get_global thy = get_generic (Context.Theory thy);
    99 fun map_global config f = Context.theory_map (map_generic config f);
   100 fun put_global config value = map_global config (K value);
   101 
   102 
   103 (* context information *)
   104 
   105 structure Value = Generic_Data
   106 (
   107   type T = value Inttab.table;
   108   val empty = Inttab.empty;
   109   val extend = I;
   110   fun merge data = Inttab.merge (K true) data;
   111 );
   112 
   113 fun declare_generic {global} name default =
   114   let
   115     val id = serial ();
   116 
   117     fun get_value context =
   118       (case Inttab.lookup (Value.get context) id of
   119         SOME value => value
   120       | NONE => default context);
   121 
   122     fun update_value f context =
   123       Value.map (Inttab.update (id, type_check name f (get_value context))) context;
   124 
   125     fun map_value f (context as Context.Proof ctxt) =
   126           let val context' = update_value f context in
   127             if global andalso
   128               Context_Position.is_visible ctxt andalso
   129               print_value (get_value (Context.Theory (Context.theory_of context'))) <>
   130                 print_value (get_value context')
   131             then
   132               (Context_Position.if_visible ctxt warning
   133                 ("Ignoring local change of global option " ^ quote name); context)
   134             else context'
   135           end
   136       | map_value f context = update_value f context;
   137   in Config {name = name, get_value = get_value, map_value = map_value} end;
   138 
   139 val declare_global = declare_generic {global = true};
   140 val declare = declare_generic {global = false};
   141 
   142 fun declare_option name =
   143   let
   144     val typ = Options.default_typ name;
   145     val default =
   146       if typ = Options.boolT then fn _ => Bool (Options.default_bool name)
   147       else if typ = Options.intT then fn _ => Int (Options.default_int name)
   148       else if typ = Options.realT then fn _ => Real (Options.default_real name)
   149       else if typ = Options.stringT then fn _ => String (Options.default_string name)
   150       else error ("Unknown type for option " ^ quote name ^ " : " ^ quote typ);
   151   in declare name default end;
   152 
   153 fun name_of (Config {name, ...}) = name;
   154 
   155 
   156 (*final declarations of this structure!*)
   157 val get = get_ctxt;
   158 val map = map_ctxt;
   159 val put = put_ctxt;
   160 
   161 end;