src/HOL/Library/Float.thy
author hoelzl
Thu Apr 26 14:42:50 2012 +0200 (2012-04-26)
changeset 47780 3357688660ff
parent 47621 4cf6011fb884
child 47937 70375fa2679d
permissions -rw-r--r--
add code equation for real_of_float
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Johannes Hölzl, Fabian Immler
     3     Copyright   2012  TU München
     4 *)
     5 
     6 header {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main "~~/src/HOL/Library/Lattice_Algebras"
    10 begin
    11 
    12 typedef float = "{m * 2 powr e | (m :: int) (e :: int). True }"
    13   morphisms real_of_float float_of
    14   by auto
    15 
    16 defs (overloaded)
    17   real_of_float_def[code_unfold]: "real \<equiv> real_of_float"
    18 
    19 lemma type_definition_float': "type_definition real float_of float"
    20   using type_definition_float unfolding real_of_float_def .
    21 
    22 setup_lifting (no_abs_code) type_definition_float'
    23 
    24 lemmas float_of_inject[simp]
    25 
    26 declare [[coercion "real :: float \<Rightarrow> real"]]
    27 
    28 lemma real_of_float_eq:
    29   fixes f1 f2 :: float shows "f1 = f2 \<longleftrightarrow> real f1 = real f2"
    30   unfolding real_of_float_def real_of_float_inject ..
    31 
    32 lemma float_of_real[simp]: "float_of (real x) = x"
    33   unfolding real_of_float_def by (rule real_of_float_inverse)
    34 
    35 lemma real_float[simp]: "x \<in> float \<Longrightarrow> real (float_of x) = x"
    36   unfolding real_of_float_def by (rule float_of_inverse)
    37 
    38 subsection {* Real operations preserving the representation as floating point number *}
    39 
    40 lemma floatI: fixes m e :: int shows "m * 2 powr e = x \<Longrightarrow> x \<in> float"
    41   by (auto simp: float_def)
    42 
    43 lemma zero_float[simp]: "0 \<in> float" by (auto simp: float_def)
    44 lemma one_float[simp]: "1 \<in> float" by (intro floatI[of 1 0]) simp
    45 lemma numeral_float[simp]: "numeral i \<in> float" by (intro floatI[of "numeral i" 0]) simp  
    46 lemma neg_numeral_float[simp]: "neg_numeral i \<in> float" by (intro floatI[of "neg_numeral i" 0]) simp
    47 lemma real_of_int_float[simp]: "real (x :: int) \<in> float" by (intro floatI[of x 0]) simp
    48 lemma real_of_nat_float[simp]: "real (x :: nat) \<in> float" by (intro floatI[of x 0]) simp
    49 lemma two_powr_int_float[simp]: "2 powr (real (i::int)) \<in> float" by (intro floatI[of 1 i]) simp
    50 lemma two_powr_nat_float[simp]: "2 powr (real (i::nat)) \<in> float" by (intro floatI[of 1 i]) simp
    51 lemma two_powr_minus_int_float[simp]: "2 powr - (real (i::int)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    52 lemma two_powr_minus_nat_float[simp]: "2 powr - (real (i::nat)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    53 lemma two_powr_numeral_float[simp]: "2 powr numeral i \<in> float" by (intro floatI[of 1 "numeral i"]) simp
    54 lemma two_powr_neg_numeral_float[simp]: "2 powr neg_numeral i \<in> float" by (intro floatI[of 1 "neg_numeral i"]) simp
    55 lemma two_pow_float[simp]: "2 ^ n \<in> float" by (intro floatI[of 1 "n"]) (simp add: powr_realpow)
    56 lemma real_of_float_float[simp]: "real (f::float) \<in> float" by (cases f) simp
    57 
    58 lemma plus_float[simp]: "r \<in> float \<Longrightarrow> p \<in> float \<Longrightarrow> r + p \<in> float"
    59   unfolding float_def
    60 proof (safe, simp)
    61   fix e1 m1 e2 m2 :: int
    62   { fix e1 m1 e2 m2 :: int assume "e1 \<le> e2"
    63     then have "m1 * 2 powr e1 + m2 * 2 powr e2 = (m1 + m2 * 2 ^ nat (e2 - e1)) * 2 powr e1"
    64       by (simp add: powr_realpow[symmetric] powr_divide2[symmetric] field_simps)
    65     then have "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    66       by blast }
    67   note * = this
    68   show "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    69   proof (cases e1 e2 rule: linorder_le_cases)
    70     assume "e2 \<le> e1" from *[OF this, of m2 m1] show ?thesis by (simp add: ac_simps)
    71   qed (rule *)
    72 qed
    73 
    74 lemma uminus_float[simp]: "x \<in> float \<Longrightarrow> -x \<in> float"
    75   apply (auto simp: float_def)
    76   apply (rule_tac x="-x" in exI)
    77   apply (rule_tac x="xa" in exI)
    78   apply (simp add: field_simps)
    79   done
    80 
    81 lemma times_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x * y \<in> float"
    82   apply (auto simp: float_def)
    83   apply (rule_tac x="x * xa" in exI)
    84   apply (rule_tac x="xb + xc" in exI)
    85   apply (simp add: powr_add)
    86   done
    87 
    88 lemma minus_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x - y \<in> float"
    89   unfolding ab_diff_minus by (intro uminus_float plus_float)
    90 
    91 lemma abs_float[simp]: "x \<in> float \<Longrightarrow> abs x \<in> float"
    92   by (cases x rule: linorder_cases[of 0]) auto
    93 
    94 lemma sgn_of_float[simp]: "x \<in> float \<Longrightarrow> sgn x \<in> float"
    95   by (cases x rule: linorder_cases[of 0]) (auto intro!: uminus_float)
    96 
    97 lemma div_power_2_float[simp]: "x \<in> float \<Longrightarrow> x / 2^d \<in> float"
    98   apply (auto simp add: float_def)
    99   apply (rule_tac x="x" in exI)
   100   apply (rule_tac x="xa - d" in exI)
   101   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   102   done
   103 
   104 lemma div_power_2_int_float[simp]: "x \<in> float \<Longrightarrow> x / (2::int)^d \<in> float"
   105   apply (auto simp add: float_def)
   106   apply (rule_tac x="x" in exI)
   107   apply (rule_tac x="xa - d" in exI)
   108   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   109   done
   110 
   111 lemma div_numeral_Bit0_float[simp]:
   112   assumes x: "x / numeral n \<in> float" shows "x / (numeral (Num.Bit0 n)) \<in> float"
   113 proof -
   114   have "(x / numeral n) / 2^1 \<in> float"
   115     by (intro x div_power_2_float)
   116   also have "(x / numeral n) / 2^1 = x / (numeral (Num.Bit0 n))"
   117     by (induct n) auto
   118   finally show ?thesis .
   119 qed
   120 
   121 lemma div_neg_numeral_Bit0_float[simp]:
   122   assumes x: "x / numeral n \<in> float" shows "x / (neg_numeral (Num.Bit0 n)) \<in> float"
   123 proof -
   124   have "- (x / numeral (Num.Bit0 n)) \<in> float" using x by simp
   125   also have "- (x / numeral (Num.Bit0 n)) = x / neg_numeral (Num.Bit0 n)"
   126     unfolding neg_numeral_def by (simp del: minus_numeral)
   127   finally show ?thesis .
   128 qed
   129 
   130 lift_definition Float :: "int \<Rightarrow> int \<Rightarrow> float" is "\<lambda>(m::int) (e::int). m * 2 powr e" by simp
   131 declare Float.rep_eq[simp]
   132 
   133 lemma compute_real_of_float[code]:
   134   "real_of_float (Float m e) = (if e \<ge> 0 then m * 2 ^ nat e else m / 2 ^ (nat (-e)))"
   135 by (simp add: real_of_float_def[symmetric] powr_int)
   136 
   137 code_datatype Float
   138 
   139 subsection {* Arithmetic operations on floating point numbers *}
   140 
   141 instantiation float :: "{ring_1, linorder, linordered_ring, linordered_idom, numeral, equal}"
   142 begin
   143 
   144 lift_definition zero_float :: float is 0 by simp
   145 declare zero_float.rep_eq[simp]
   146 lift_definition one_float :: float is 1 by simp
   147 declare one_float.rep_eq[simp]
   148 lift_definition plus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op +" by simp
   149 declare plus_float.rep_eq[simp]
   150 lift_definition times_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op *" by simp
   151 declare times_float.rep_eq[simp]
   152 lift_definition minus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op -" by simp
   153 declare minus_float.rep_eq[simp]
   154 lift_definition uminus_float :: "float \<Rightarrow> float" is "uminus" by simp
   155 declare uminus_float.rep_eq[simp]
   156 
   157 lift_definition abs_float :: "float \<Rightarrow> float" is abs by simp
   158 declare abs_float.rep_eq[simp]
   159 lift_definition sgn_float :: "float \<Rightarrow> float" is sgn by simp
   160 declare sgn_float.rep_eq[simp]
   161 
   162 lift_definition equal_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op = :: real \<Rightarrow> real \<Rightarrow> bool" ..
   163 
   164 lift_definition less_eq_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op \<le>" ..
   165 declare less_eq_float.rep_eq[simp]
   166 lift_definition less_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op <" ..
   167 declare less_float.rep_eq[simp]
   168 
   169 instance
   170   proof qed (transfer, fastforce simp add: field_simps intro: mult_left_mono mult_right_mono)+
   171 end
   172 
   173 lemma real_of_float_power[simp]: fixes f::float shows "real (f^n) = real f^n"
   174   by (induct n) simp_all
   175 
   176 lemma fixes x y::float 
   177   shows real_of_float_min: "real (min x y) = min (real x) (real y)"
   178     and real_of_float_max: "real (max x y) = max (real x) (real y)"
   179   by (simp_all add: min_def max_def)
   180 
   181 instance float :: dense_linorder
   182 proof
   183   fix a b :: float
   184   show "\<exists>c. a < c"
   185     apply (intro exI[of _ "a + 1"])
   186     apply transfer
   187     apply simp
   188     done
   189   show "\<exists>c. c < a"
   190     apply (intro exI[of _ "a - 1"])
   191     apply transfer
   192     apply simp
   193     done
   194   assume "a < b"
   195   then show "\<exists>c. a < c \<and> c < b"
   196     apply (intro exI[of _ "(a + b) * Float 1 -1"])
   197     apply transfer
   198     apply (simp add: powr_neg_numeral) 
   199     done
   200 qed
   201 
   202 instantiation float :: lattice_ab_group_add
   203 begin
   204 
   205 definition inf_float::"float\<Rightarrow>float\<Rightarrow>float"
   206 where "inf_float a b = min a b"
   207 
   208 definition sup_float::"float\<Rightarrow>float\<Rightarrow>float"
   209 where "sup_float a b = max a b"
   210 
   211 instance
   212   by default
   213      (transfer, simp_all add: inf_float_def sup_float_def real_of_float_min real_of_float_max)+
   214 end
   215 
   216 lemma float_numeral[simp]: "real (numeral x :: float) = numeral x"
   217   apply (induct x)
   218   apply simp
   219   apply (simp_all only: numeral_Bit0 numeral_Bit1 real_of_float_eq real_float
   220                   plus_float.rep_eq one_float.rep_eq plus_float numeral_float one_float)
   221   done
   222 
   223 lemma transfer_numeral [transfer_rule]: 
   224   "fun_rel (op =) cr_float (numeral :: _ \<Rightarrow> real) (numeral :: _ \<Rightarrow> float)"
   225   unfolding fun_rel_def cr_float_def by simp
   226 
   227 lemma float_neg_numeral[simp]: "real (neg_numeral x :: float) = neg_numeral x"
   228   by (simp add: minus_numeral[symmetric] del: minus_numeral)
   229 
   230 lemma transfer_neg_numeral [transfer_rule]: 
   231   "fun_rel (op =) cr_float (neg_numeral :: _ \<Rightarrow> real) (neg_numeral :: _ \<Rightarrow> float)"
   232   unfolding fun_rel_def cr_float_def by simp
   233 
   234 lemma
   235   shows float_of_numeral[simp]: "numeral k = float_of (numeral k)"
   236     and float_of_neg_numeral[simp]: "neg_numeral k = float_of (neg_numeral k)"
   237   unfolding real_of_float_eq by simp_all
   238 
   239 subsection {* Represent floats as unique mantissa and exponent *}
   240 
   241 lemma int_induct_abs[case_names less]:
   242   fixes j :: int
   243   assumes H: "\<And>n. (\<And>i. \<bar>i\<bar> < \<bar>n\<bar> \<Longrightarrow> P i) \<Longrightarrow> P n"
   244   shows "P j"
   245 proof (induct "nat \<bar>j\<bar>" arbitrary: j rule: less_induct)
   246   case less show ?case by (rule H[OF less]) simp
   247 qed
   248 
   249 lemma int_cancel_factors:
   250   fixes n :: int assumes "1 < r" shows "n = 0 \<or> (\<exists>k i. n = k * r ^ i \<and> \<not> r dvd k)"
   251 proof (induct n rule: int_induct_abs)
   252   case (less n)
   253   { fix m assume n: "n \<noteq> 0" "n = m * r"
   254     then have "\<bar>m \<bar> < \<bar>n\<bar>"
   255       by (metis abs_dvd_iff abs_ge_self assms comm_semiring_1_class.normalizing_semiring_rules(7)
   256                 dvd_imp_le_int dvd_refl dvd_triv_right linorder_neq_iff linorder_not_le
   257                 mult_eq_0_iff zdvd_mult_cancel1)
   258     from less[OF this] n have "\<exists>k i. n = k * r ^ Suc i \<and> \<not> r dvd k" by auto }
   259   then show ?case
   260     by (metis comm_semiring_1_class.normalizing_semiring_rules(12,7) dvdE power_0)
   261 qed
   262 
   263 lemma mult_powr_eq_mult_powr_iff_asym:
   264   fixes m1 m2 e1 e2 :: int
   265   assumes m1: "\<not> 2 dvd m1" and "e1 \<le> e2"
   266   shows "m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   267 proof
   268   have "m1 \<noteq> 0" using m1 unfolding dvd_def by auto
   269   assume eq: "m1 * 2 powr e1 = m2 * 2 powr e2"
   270   with `e1 \<le> e2` have "m1 = m2 * 2 powr nat (e2 - e1)"
   271     by (simp add: powr_divide2[symmetric] field_simps)
   272   also have "\<dots> = m2 * 2^nat (e2 - e1)"
   273     by (simp add: powr_realpow)
   274   finally have m1_eq: "m1 = m2 * 2^nat (e2 - e1)"
   275     unfolding real_of_int_inject .
   276   with m1 have "m1 = m2"
   277     by (cases "nat (e2 - e1)") (auto simp add: dvd_def)
   278   then show "m1 = m2 \<and> e1 = e2"
   279     using eq `m1 \<noteq> 0` by (simp add: powr_inj)
   280 qed simp
   281 
   282 lemma mult_powr_eq_mult_powr_iff:
   283   fixes m1 m2 e1 e2 :: int
   284   shows "\<not> 2 dvd m1 \<Longrightarrow> \<not> 2 dvd m2 \<Longrightarrow> m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   285   using mult_powr_eq_mult_powr_iff_asym[of m1 e1 e2 m2]
   286   using mult_powr_eq_mult_powr_iff_asym[of m2 e2 e1 m1]
   287   by (cases e1 e2 rule: linorder_le_cases) auto
   288 
   289 lemma floatE_normed:
   290   assumes x: "x \<in> float"
   291   obtains (zero) "x = 0"
   292    | (powr) m e :: int where "x = m * 2 powr e" "\<not> 2 dvd m" "x \<noteq> 0"
   293 proof atomize_elim
   294   { assume "x \<noteq> 0"
   295     from x obtain m e :: int where x: "x = m * 2 powr e" by (auto simp: float_def)
   296     with `x \<noteq> 0` int_cancel_factors[of 2 m] obtain k i where "m = k * 2 ^ i" "\<not> 2 dvd k"
   297       by auto
   298     with `\<not> 2 dvd k` x have "\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m"
   299       by (rule_tac exI[of _ "k"], rule_tac exI[of _ "e + int i"])
   300          (simp add: powr_add powr_realpow) }
   301   then show "x = 0 \<or> (\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m \<and> x \<noteq> 0)"
   302     by blast
   303 qed
   304 
   305 lemma float_normed_cases:
   306   fixes f :: float
   307   obtains (zero) "f = 0"
   308    | (powr) m e :: int where "real f = m * 2 powr e" "\<not> 2 dvd m" "f \<noteq> 0"
   309 proof (atomize_elim, induct f)
   310   case (float_of y) then show ?case
   311     by (cases rule: floatE_normed) (auto simp: zero_float_def)
   312 qed
   313 
   314 definition mantissa :: "float \<Rightarrow> int" where
   315   "mantissa f = fst (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   316    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   317 
   318 definition exponent :: "float \<Rightarrow> int" where
   319   "exponent f = snd (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   320    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   321 
   322 lemma 
   323   shows exponent_0[simp]: "exponent (float_of 0) = 0" (is ?E)
   324     and mantissa_0[simp]: "mantissa (float_of 0) = 0" (is ?M)
   325 proof -
   326   have "\<And>p::int \<times> int. fst p = 0 \<and> snd p = 0 \<longleftrightarrow> p = (0, 0)" by auto
   327   then show ?E ?M
   328     by (auto simp add: mantissa_def exponent_def zero_float_def)
   329 qed
   330 
   331 lemma
   332   shows mantissa_exponent: "real f = mantissa f * 2 powr exponent f" (is ?E)
   333     and mantissa_not_dvd: "f \<noteq> (float_of 0) \<Longrightarrow> \<not> 2 dvd mantissa f" (is "_ \<Longrightarrow> ?D")
   334 proof cases
   335   assume [simp]: "f \<noteq> (float_of 0)"
   336   have "f = mantissa f * 2 powr exponent f \<and> \<not> 2 dvd mantissa f"
   337   proof (cases f rule: float_normed_cases)
   338     case (powr m e)
   339     then have "\<exists>p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   340      \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p)"
   341       by auto
   342     then show ?thesis
   343       unfolding exponent_def mantissa_def
   344       by (rule someI2_ex) (simp add: zero_float_def)
   345   qed (simp add: zero_float_def)
   346   then show ?E ?D by auto
   347 qed simp
   348 
   349 lemma mantissa_noteq_0: "f \<noteq> float_of 0 \<Longrightarrow> mantissa f \<noteq> 0"
   350   using mantissa_not_dvd[of f] by auto
   351 
   352 lemma 
   353   fixes m e :: int
   354   defines "f \<equiv> float_of (m * 2 powr e)"
   355   assumes dvd: "\<not> 2 dvd m"
   356   shows mantissa_float: "mantissa f = m" (is "?M")
   357     and exponent_float: "m \<noteq> 0 \<Longrightarrow> exponent f = e" (is "_ \<Longrightarrow> ?E")
   358 proof cases
   359   assume "m = 0" with dvd show "mantissa f = m" by auto
   360 next
   361   assume "m \<noteq> 0"
   362   then have f_not_0: "f \<noteq> float_of 0" by (simp add: f_def)
   363   from mantissa_exponent[of f]
   364   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   365     by (auto simp add: f_def)
   366   then show "?M" "?E"
   367     using mantissa_not_dvd[OF f_not_0] dvd
   368     by (auto simp: mult_powr_eq_mult_powr_iff)
   369 qed
   370 
   371 subsection {* Compute arithmetic operations *}
   372 
   373 lemma Float_mantissa_exponent: "Float (mantissa f) (exponent f) = f"
   374   unfolding real_of_float_eq mantissa_exponent[of f] by simp
   375 
   376 lemma Float_cases[case_names Float, cases type: float]:
   377   fixes f :: float
   378   obtains (Float) m e :: int where "f = Float m e"
   379   using Float_mantissa_exponent[symmetric]
   380   by (atomize_elim) auto
   381 
   382 lemma denormalize_shift:
   383   assumes f_def: "f \<equiv> Float m e" and not_0: "f \<noteq> float_of 0"
   384   obtains i where "m = mantissa f * 2 ^ i" "e = exponent f - i"
   385 proof
   386   from mantissa_exponent[of f] f_def
   387   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   388     by simp
   389   then have eq: "m = mantissa f * 2 powr (exponent f - e)"
   390     by (simp add: powr_divide2[symmetric] field_simps)
   391   moreover
   392   have "e \<le> exponent f"
   393   proof (rule ccontr)
   394     assume "\<not> e \<le> exponent f"
   395     then have pos: "exponent f < e" by simp
   396     then have "2 powr (exponent f - e) = 2 powr - real (e - exponent f)"
   397       by simp
   398     also have "\<dots> = 1 / 2^nat (e - exponent f)"
   399       using pos by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
   400     finally have "m * 2^nat (e - exponent f) = real (mantissa f)"
   401       using eq by simp
   402     then have "mantissa f = m * 2^nat (e - exponent f)"
   403       unfolding real_of_int_inject by simp
   404     with `exponent f < e` have "2 dvd mantissa f"
   405       apply (intro dvdI[where k="m * 2^(nat (e-exponent f)) div 2"])
   406       apply (cases "nat (e - exponent f)")
   407       apply auto
   408       done
   409     then show False using mantissa_not_dvd[OF not_0] by simp
   410   qed
   411   ultimately have "real m = mantissa f * 2^nat (exponent f - e)"
   412     by (simp add: powr_realpow[symmetric])
   413   with `e \<le> exponent f`
   414   show "m = mantissa f * 2 ^ nat (exponent f - e)" "e = exponent f - nat (exponent f - e)"
   415     unfolding real_of_int_inject by auto
   416 qed
   417 
   418 lemma compute_float_zero[code_unfold, code]: "0 = Float 0 0"
   419   by transfer simp
   420 hide_fact (open) compute_float_zero
   421 
   422 lemma compute_float_one[code_unfold, code]: "1 = Float 1 0"
   423   by transfer simp
   424 hide_fact (open) compute_float_one
   425 
   426 definition normfloat :: "float \<Rightarrow> float" where
   427   [simp]: "normfloat x = x"
   428 
   429 lemma compute_normfloat[code]: "normfloat (Float m e) =
   430   (if m mod 2 = 0 \<and> m \<noteq> 0 then normfloat (Float (m div 2) (e + 1))
   431                            else if m = 0 then 0 else Float m e)"
   432   unfolding normfloat_def
   433   by transfer (auto simp add: powr_add zmod_eq_0_iff)
   434 hide_fact (open) compute_normfloat
   435 
   436 lemma compute_float_numeral[code_abbrev]: "Float (numeral k) 0 = numeral k"
   437   by transfer simp
   438 hide_fact (open) compute_float_numeral
   439 
   440 lemma compute_float_neg_numeral[code_abbrev]: "Float (neg_numeral k) 0 = neg_numeral k"
   441   by transfer simp
   442 hide_fact (open) compute_float_neg_numeral
   443 
   444 lemma compute_float_uminus[code]: "- Float m1 e1 = Float (- m1) e1"
   445   by transfer simp
   446 hide_fact (open) compute_float_uminus
   447 
   448 lemma compute_float_times[code]: "Float m1 e1 * Float m2 e2 = Float (m1 * m2) (e1 + e2)"
   449   by transfer (simp add: field_simps powr_add)
   450 hide_fact (open) compute_float_times
   451 
   452 lemma compute_float_plus[code]: "Float m1 e1 + Float m2 e2 =
   453   (if e1 \<le> e2 then Float (m1 + m2 * 2^nat (e2 - e1)) e1
   454               else Float (m2 + m1 * 2^nat (e1 - e2)) e2)"
   455   by transfer (simp add: field_simps powr_realpow[symmetric] powr_divide2[symmetric])
   456 hide_fact (open) compute_float_plus
   457 
   458 lemma compute_float_minus[code]: fixes f g::float shows "f - g = f + (-g)"
   459   by simp
   460 hide_fact (open) compute_float_minus
   461 
   462 lemma compute_float_sgn[code]: "sgn (Float m1 e1) = (if 0 < m1 then 1 else if m1 < 0 then -1 else 0)"
   463   by transfer (simp add: sgn_times)
   464 hide_fact (open) compute_float_sgn
   465 
   466 lift_definition is_float_pos :: "float \<Rightarrow> bool" is "op < 0 :: real \<Rightarrow> bool" ..
   467 
   468 lemma compute_is_float_pos[code]: "is_float_pos (Float m e) \<longleftrightarrow> 0 < m"
   469   by transfer (auto simp add: zero_less_mult_iff not_le[symmetric, of _ 0])
   470 hide_fact (open) compute_is_float_pos
   471 
   472 lemma compute_float_less[code]: "a < b \<longleftrightarrow> is_float_pos (b - a)"
   473   by transfer (simp add: field_simps)
   474 hide_fact (open) compute_float_less
   475 
   476 lift_definition is_float_nonneg :: "float \<Rightarrow> bool" is "op \<le> 0 :: real \<Rightarrow> bool" ..
   477 
   478 lemma compute_is_float_nonneg[code]: "is_float_nonneg (Float m e) \<longleftrightarrow> 0 \<le> m"
   479   by transfer (auto simp add: zero_le_mult_iff not_less[symmetric, of _ 0])
   480 hide_fact (open) compute_is_float_nonneg
   481 
   482 lemma compute_float_le[code]: "a \<le> b \<longleftrightarrow> is_float_nonneg (b - a)"
   483   by transfer (simp add: field_simps)
   484 hide_fact (open) compute_float_le
   485 
   486 lift_definition is_float_zero :: "float \<Rightarrow> bool"  is "op = 0 :: real \<Rightarrow> bool" by simp
   487 
   488 lemma compute_is_float_zero[code]: "is_float_zero (Float m e) \<longleftrightarrow> 0 = m"
   489   by transfer (auto simp add: is_float_zero_def)
   490 hide_fact (open) compute_is_float_zero
   491 
   492 lemma compute_float_abs[code]: "abs (Float m e) = Float (abs m) e"
   493   by transfer (simp add: abs_mult)
   494 hide_fact (open) compute_float_abs
   495 
   496 lemma compute_float_eq[code]: "equal_class.equal f g = is_float_zero (f - g)"
   497   by transfer simp
   498 hide_fact (open) compute_float_eq
   499 
   500 subsection {* Rounding Real numbers *}
   501 
   502 definition round_down :: "int \<Rightarrow> real \<Rightarrow> real" where
   503   "round_down prec x = floor (x * 2 powr prec) * 2 powr -prec"
   504 
   505 definition round_up :: "int \<Rightarrow> real \<Rightarrow> real" where
   506   "round_up prec x = ceiling (x * 2 powr prec) * 2 powr -prec"
   507 
   508 lemma round_down_float[simp]: "round_down prec x \<in> float"
   509   unfolding round_down_def
   510   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   511 
   512 lemma round_up_float[simp]: "round_up prec x \<in> float"
   513   unfolding round_up_def
   514   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   515 
   516 lemma round_up: "x \<le> round_up prec x"
   517   by (simp add: powr_minus_divide le_divide_eq round_up_def)
   518 
   519 lemma round_down: "round_down prec x \<le> x"
   520   by (simp add: powr_minus_divide divide_le_eq round_down_def)
   521 
   522 lemma round_up_0[simp]: "round_up p 0 = 0"
   523   unfolding round_up_def by simp
   524 
   525 lemma round_down_0[simp]: "round_down p 0 = 0"
   526   unfolding round_down_def by simp
   527 
   528 lemma round_up_diff_round_down:
   529   "round_up prec x - round_down prec x \<le> 2 powr -prec"
   530 proof -
   531   have "round_up prec x - round_down prec x =
   532     (ceiling (x * 2 powr prec) - floor (x * 2 powr prec)) * 2 powr -prec"
   533     by (simp add: round_up_def round_down_def field_simps)
   534   also have "\<dots> \<le> 1 * 2 powr -prec"
   535     by (rule mult_mono)
   536        (auto simp del: real_of_int_diff
   537              simp: real_of_int_diff[symmetric] real_of_int_le_one_cancel_iff ceiling_diff_floor_le_1)
   538   finally show ?thesis by simp
   539 qed
   540 
   541 lemma round_down_shift: "round_down p (x * 2 powr k) = 2 powr k * round_down (p + k) x"
   542   unfolding round_down_def
   543   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   544     (simp add: powr_add[symmetric])
   545 
   546 lemma round_up_shift: "round_up p (x * 2 powr k) = 2 powr k * round_up (p + k) x"
   547   unfolding round_up_def
   548   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   549     (simp add: powr_add[symmetric])
   550 
   551 subsection {* Rounding Floats *}
   552 
   553 lift_definition float_up :: "int \<Rightarrow> float \<Rightarrow> float" is round_up by simp
   554 declare float_up.rep_eq[simp]
   555 
   556 lemma float_up_correct:
   557   shows "real (float_up e f) - real f \<in> {0..2 powr -e}"
   558 unfolding atLeastAtMost_iff
   559 proof
   560   have "round_up e f - f \<le> round_up e f - round_down e f" using round_down by simp
   561   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   562   finally show "real (float_up e f) - real f \<le> 2 powr real (- e)"
   563     by simp
   564 qed (simp add: algebra_simps round_up)
   565 
   566 lift_definition float_down :: "int \<Rightarrow> float \<Rightarrow> float" is round_down by simp
   567 declare float_down.rep_eq[simp]
   568 
   569 lemma float_down_correct:
   570   shows "real f - real (float_down e f) \<in> {0..2 powr -e}"
   571 unfolding atLeastAtMost_iff
   572 proof
   573   have "f - round_down e f \<le> round_up e f - round_down e f" using round_up by simp
   574   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   575   finally show "real f - real (float_down e f) \<le> 2 powr real (- e)"
   576     by simp
   577 qed (simp add: algebra_simps round_down)
   578 
   579 lemma compute_float_down[code]:
   580   "float_down p (Float m e) =
   581     (if p + e < 0 then Float (m div 2^nat (-(p + e))) (-p) else Float m e)"
   582 proof cases
   583   assume "p + e < 0"
   584   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   585     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   586   also have "... = 1 / 2 powr p / 2 powr e"
   587     unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   588   finally show ?thesis
   589     using `p + e < 0`
   590     by transfer (simp add: ac_simps round_down_def floor_divide_eq_div[symmetric])
   591 next
   592   assume "\<not> p + e < 0"
   593   then have r: "real e + real p = real (nat (e + p))" by simp
   594   have r: "\<lfloor>(m * 2 powr e) * 2 powr real p\<rfloor> = (m * 2 powr e) * 2 powr real p"
   595     by (auto intro: exI[where x="m*2^nat (e+p)"]
   596              simp add: ac_simps powr_add[symmetric] r powr_realpow)
   597   with `\<not> p + e < 0` show ?thesis
   598     by transfer
   599        (auto simp add: round_down_def field_simps powr_add powr_minus inverse_eq_divide)
   600 qed
   601 hide_fact (open) compute_float_down
   602 
   603 lemma ceil_divide_floor_conv:
   604 assumes "b \<noteq> 0"
   605 shows "\<lceil>real a / real b\<rceil> = (if b dvd a then a div b else \<lfloor>real a / real b\<rfloor> + 1)"
   606 proof cases
   607   assume "\<not> b dvd a"
   608   hence "a mod b \<noteq> 0" by auto
   609   hence ne: "real (a mod b) / real b \<noteq> 0" using `b \<noteq> 0` by auto
   610   have "\<lceil>real a / real b\<rceil> = \<lfloor>real a / real b\<rfloor> + 1"
   611   apply (rule ceiling_eq) apply (auto simp: floor_divide_eq_div[symmetric])
   612   proof -
   613     have "real \<lfloor>real a / real b\<rfloor> \<le> real a / real b" by simp
   614     moreover have "real \<lfloor>real a / real b\<rfloor> \<noteq> real a / real b"
   615     apply (subst (2) real_of_int_div_aux) unfolding floor_divide_eq_div using ne `b \<noteq> 0` by auto
   616     ultimately show "real \<lfloor>real a / real b\<rfloor> < real a / real b" by arith
   617   qed
   618   thus ?thesis using `\<not> b dvd a` by simp
   619 qed (simp add: ceiling_def real_of_int_minus[symmetric] divide_minus_left[symmetric]
   620   floor_divide_eq_div dvd_neg_div del: divide_minus_left real_of_int_minus)
   621 
   622 lemma compute_float_up[code]:
   623   "float_up p (Float m e) =
   624     (let P = 2^nat (-(p + e)); r = m mod P in
   625       if p + e < 0 then Float (m div P + (if r = 0 then 0 else 1)) (-p) else Float m e)"
   626 proof cases
   627   assume "p + e < 0"
   628   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   629     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   630   also have "... = 1 / 2 powr p / 2 powr e"
   631   unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   632   finally have twopow_rewrite:
   633     "real ((2::int) ^ nat (- (p + e))) = 1 / 2 powr real p / 2 powr real e" .
   634   with `p + e < 0` have powr_rewrite:
   635     "2 powr real e * 2 powr real p = 1 / real ((2::int) ^ nat (- (p + e)))"
   636     unfolding powr_divide2 by simp
   637   show ?thesis
   638   proof cases
   639     assume "2^nat (-(p + e)) dvd m"
   640     with `p + e < 0` twopow_rewrite show ?thesis
   641       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div dvd_eq_mod_eq_0)
   642   next
   643     assume ndvd: "\<not> 2 ^ nat (- (p + e)) dvd m"
   644     have one_div: "real m * (1 / real ((2::int) ^ nat (- (p + e)))) =
   645       real m / real ((2::int) ^ nat (- (p + e)))"
   646       by (simp add: field_simps)
   647     have "real \<lceil>real m * (2 powr real e * 2 powr real p)\<rceil> =
   648       real \<lfloor>real m * (2 powr real e * 2 powr real p)\<rfloor> + 1"
   649       using ndvd unfolding powr_rewrite one_div
   650       by (subst ceil_divide_floor_conv) (auto simp: field_simps)
   651     thus ?thesis using `p + e < 0` twopow_rewrite
   652       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div[symmetric])
   653   qed
   654 next
   655   assume "\<not> p + e < 0"
   656   then have r1: "real e + real p = real (nat (e + p))" by simp
   657   have r: "\<lceil>(m * 2 powr e) * 2 powr real p\<rceil> = (m * 2 powr e) * 2 powr real p"
   658     by (auto simp add: ac_simps powr_add[symmetric] r1 powr_realpow
   659       intro: exI[where x="m*2^nat (e+p)"])
   660   then show ?thesis using `\<not> p + e < 0`
   661     by transfer
   662        (simp add: round_up_def floor_divide_eq_div field_simps powr_add powr_minus inverse_eq_divide)
   663 qed
   664 hide_fact (open) compute_float_up
   665 
   666 lemmas real_of_ints =
   667   real_of_int_zero
   668   real_of_one
   669   real_of_int_add
   670   real_of_int_minus
   671   real_of_int_diff
   672   real_of_int_mult
   673   real_of_int_power
   674   real_numeral
   675 lemmas real_of_nats =
   676   real_of_nat_zero
   677   real_of_nat_one
   678   real_of_nat_1
   679   real_of_nat_add
   680   real_of_nat_mult
   681   real_of_nat_power
   682 
   683 lemmas int_of_reals = real_of_ints[symmetric]
   684 lemmas nat_of_reals = real_of_nats[symmetric]
   685 
   686 lemma two_real_int: "(2::real) = real (2::int)" by simp
   687 lemma two_real_nat: "(2::real) = real (2::nat)" by simp
   688 
   689 lemma mult_cong: "a = c ==> b = d ==> a*b = c*d" by simp
   690 
   691 subsection {* Compute bitlen of integers *}
   692 
   693 definition bitlen :: "int \<Rightarrow> int" where
   694   "bitlen a = (if a > 0 then \<lfloor>log 2 a\<rfloor> + 1 else 0)"
   695 
   696 lemma bitlen_nonneg: "0 \<le> bitlen x"
   697 proof -
   698   {
   699     assume "0 > x"
   700     have "-1 = log 2 (inverse 2)" by (subst log_inverse) simp_all
   701     also have "... < log 2 (-x)" using `0 > x` by auto
   702     finally have "-1 < log 2 (-x)" .
   703   } thus "0 \<le> bitlen x" unfolding bitlen_def by (auto intro!: add_nonneg_nonneg)
   704 qed
   705 
   706 lemma bitlen_bounds:
   707   assumes "x > 0"
   708   shows "2 ^ nat (bitlen x - 1) \<le> x \<and> x < 2 ^ nat (bitlen x)"
   709 proof
   710   have "(2::real) ^ nat \<lfloor>log 2 (real x)\<rfloor> = 2 powr real (floor (log 2 (real x)))"
   711     using powr_realpow[symmetric, of 2 "nat \<lfloor>log 2 (real x)\<rfloor>"] `x > 0`
   712     using real_nat_eq_real[of "floor (log 2 (real x))"]
   713     by simp
   714   also have "... \<le> 2 powr log 2 (real x)"
   715     by simp
   716   also have "... = real x"
   717     using `0 < x` by simp
   718   finally have "2 ^ nat \<lfloor>log 2 (real x)\<rfloor> \<le> real x" by simp
   719   thus "2 ^ nat (bitlen x - 1) \<le> x" using `x > 0`
   720     by (simp add: bitlen_def)
   721 next
   722   have "x \<le> 2 powr (log 2 x)" using `x > 0` by simp
   723   also have "... < 2 ^ nat (\<lfloor>log 2 (real x)\<rfloor> + 1)"
   724     apply (simp add: powr_realpow[symmetric])
   725     using `x > 0` by simp
   726   finally show "x < 2 ^ nat (bitlen x)" using `x > 0`
   727     by (simp add: bitlen_def ac_simps int_of_reals del: real_of_ints)
   728 qed
   729 
   730 lemma bitlen_pow2[simp]:
   731   assumes "b > 0"
   732   shows "bitlen (b * 2 ^ c) = bitlen b + c"
   733 proof -
   734   from assms have "b * 2 ^ c > 0" by (auto intro: mult_pos_pos)
   735   thus ?thesis
   736     using floor_add[of "log 2 b" c] assms
   737     by (auto simp add: log_mult log_nat_power bitlen_def)
   738 qed
   739 
   740 lemma bitlen_Float:
   741 fixes m e
   742 defines "f \<equiv> Float m e"
   743 shows "bitlen (\<bar>mantissa f\<bar>) + exponent f = (if m = 0 then 0 else bitlen \<bar>m\<bar> + e)"
   744 proof cases
   745   assume "m \<noteq> 0"
   746   hence "f \<noteq> float_of 0"
   747     unfolding real_of_float_eq by (simp add: f_def)
   748   hence "mantissa f \<noteq> 0"
   749     by (simp add: mantissa_noteq_0)
   750   moreover
   751   from f_def[THEN denormalize_shift, OF `f \<noteq> float_of 0`] guess i .
   752   ultimately show ?thesis by (simp add: abs_mult)
   753 qed (simp add: f_def bitlen_def Float_def)
   754 
   755 lemma compute_bitlen[code]:
   756   shows "bitlen x = (if x > 0 then bitlen (x div 2) + 1 else 0)"
   757 proof -
   758   { assume "2 \<le> x"
   759     then have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 (x - x mod 2)\<rfloor>"
   760       by (simp add: log_mult zmod_zdiv_equality')
   761     also have "\<dots> = \<lfloor>log 2 (real x)\<rfloor>"
   762     proof cases
   763       assume "x mod 2 = 0" then show ?thesis by simp
   764     next
   765       def n \<equiv> "\<lfloor>log 2 (real x)\<rfloor>"
   766       then have "0 \<le> n"
   767         using `2 \<le> x` by simp
   768       assume "x mod 2 \<noteq> 0"
   769       with `2 \<le> x` have "x mod 2 = 1" "\<not> 2 dvd x" by (auto simp add: dvd_eq_mod_eq_0)
   770       with `2 \<le> x` have "x \<noteq> 2^nat n" by (cases "nat n") auto
   771       moreover
   772       { have "real (2^nat n :: int) = 2 powr (nat n)"
   773           by (simp add: powr_realpow)
   774         also have "\<dots> \<le> 2 powr (log 2 x)"
   775           using `2 \<le> x` by (simp add: n_def del: powr_log_cancel)
   776         finally have "2^nat n \<le> x" using `2 \<le> x` by simp }
   777       ultimately have "2^nat n \<le> x - 1" by simp
   778       then have "2^nat n \<le> real (x - 1)"
   779         unfolding real_of_int_le_iff[symmetric] by simp
   780       { have "n = \<lfloor>log 2 (2^nat n)\<rfloor>"
   781           using `0 \<le> n` by (simp add: log_nat_power)
   782         also have "\<dots> \<le> \<lfloor>log 2 (x - 1)\<rfloor>"
   783           using `2^nat n \<le> real (x - 1)` `0 \<le> n` `2 \<le> x` by (auto intro: floor_mono)
   784         finally have "n \<le> \<lfloor>log 2 (x - 1)\<rfloor>" . }
   785       moreover have "\<lfloor>log 2 (x - 1)\<rfloor> \<le> n"
   786         using `2 \<le> x` by (auto simp add: n_def intro!: floor_mono)
   787       ultimately show "\<lfloor>log 2 (x - x mod 2)\<rfloor> = \<lfloor>log 2 x\<rfloor>"
   788         unfolding n_def `x mod 2 = 1` by auto
   789     qed
   790     finally have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 x\<rfloor>" . }
   791   moreover
   792   { assume "x < 2" "0 < x"
   793     then have "x = 1" by simp
   794     then have "\<lfloor>log 2 (real x)\<rfloor> = 0" by simp }
   795   ultimately show ?thesis
   796     unfolding bitlen_def
   797     by (auto simp: pos_imp_zdiv_pos_iff not_le)
   798 qed
   799 hide_fact (open) compute_bitlen
   800 
   801 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   802   shows "0 \<le> e + (bitlen m - 1)"
   803 proof -
   804   have "0 < Float m e" using assms by auto
   805   hence "0 < m" using powr_gt_zero[of 2 e]
   806     by (auto simp: zero_less_mult_iff)
   807   hence "m \<noteq> 0" by auto
   808   show ?thesis
   809   proof (cases "0 \<le> e")
   810     case True thus ?thesis using `0 < m`  by (simp add: bitlen_def)
   811   next
   812     have "(1::int) < 2" by simp
   813     case False let ?S = "2^(nat (-e))"
   814     have "inverse (2 ^ nat (- e)) = 2 powr e" using assms False powr_realpow[of 2 "nat (-e)"]
   815       by (auto simp: powr_minus field_simps inverse_eq_divide)
   816     hence "1 \<le> real m * inverse ?S" using assms False powr_realpow[of 2 "nat (-e)"]
   817       by (auto simp: powr_minus)
   818     hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   819     hence "?S \<le> real m" unfolding mult_assoc by auto
   820     hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   821     from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   822     have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric] by (rule order_le_less_trans)
   823     hence "-e < bitlen m" using False by auto
   824     thus ?thesis by auto
   825   qed
   826 qed
   827 
   828 lemma bitlen_div: assumes "0 < m" shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   829 proof -
   830   let ?B = "2^nat(bitlen m - 1)"
   831 
   832   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   833   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   834   thus "1 \<le> real m / ?B" by auto
   835 
   836   have "m \<noteq> 0" using assms by auto
   837   have "0 \<le> bitlen m - 1" using `0 < m` by (auto simp: bitlen_def)
   838 
   839   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   840   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using `0 < m` by (auto simp: bitlen_def)
   841   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   842   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   843   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   844   thus "real m / ?B < 2" by auto
   845 qed
   846 
   847 subsection {* Approximation of positive rationals *}
   848 
   849 lemma zdiv_zmult_twopow_eq: fixes a b::int shows "a div b div (2 ^ n) = a div (b * 2 ^ n)"
   850 by (simp add: zdiv_zmult2_eq)
   851 
   852 lemma div_mult_twopow_eq: fixes a b::nat shows "a div ((2::nat) ^ n) div b = a div (b * 2 ^ n)"
   853   by (cases "b=0") (simp_all add: div_mult2_eq[symmetric] ac_simps)
   854 
   855 lemma real_div_nat_eq_floor_of_divide:
   856   fixes a b::nat
   857   shows "a div b = real (floor (a/b))"
   858 by (metis floor_divide_eq_div real_of_int_of_nat_eq zdiv_int)
   859 
   860 definition "rat_precision prec x y = int prec - (bitlen x - bitlen y)"
   861 
   862 lift_definition lapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   863   is "\<lambda>prec (x::nat) (y::nat). round_down (rat_precision prec x y) (x / y)" by simp
   864 
   865 lemma compute_lapprox_posrat[code]:
   866   fixes prec x y 
   867   shows "lapprox_posrat prec x y = 
   868    (let 
   869        l = rat_precision prec x y;
   870        d = if 0 \<le> l then x * 2^nat l div y else x div 2^nat (- l) div y
   871     in normfloat (Float d (- l)))"
   872     unfolding div_mult_twopow_eq normfloat_def
   873     by transfer
   874        (simp add: round_down_def powr_int real_div_nat_eq_floor_of_divide field_simps Let_def
   875              del: two_powr_minus_int_float)
   876 hide_fact (open) compute_lapprox_posrat
   877 
   878 lift_definition rapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   879   is "\<lambda>prec (x::nat) (y::nat). round_up (rat_precision prec x y) (x / y)" by simp
   880 
   881 (* TODO: optimize using zmod_zmult2_eq, pdivmod ? *)
   882 lemma compute_rapprox_posrat[code]:
   883   fixes prec x y
   884   defines "l \<equiv> rat_precision prec x y"
   885   shows "rapprox_posrat prec x y = (let
   886      l = l ;
   887      X = if 0 \<le> l then (x * 2^nat l, y) else (x, y * 2^nat(-l)) ;
   888      d = fst X div snd X ;
   889      m = fst X mod snd X
   890    in normfloat (Float (d + (if m = 0 \<or> y = 0 then 0 else 1)) (- l)))"
   891 proof (cases "y = 0")
   892   assume "y = 0" thus ?thesis unfolding normfloat_def by transfer simp
   893 next
   894   assume "y \<noteq> 0"
   895   show ?thesis
   896   proof (cases "0 \<le> l")
   897     assume "0 \<le> l"
   898     def x' == "x * 2 ^ nat l"
   899     have "int x * 2 ^ nat l = x'" by (simp add: x'_def int_mult int_power)
   900     moreover have "real x * 2 powr real l = real x'"
   901       by (simp add: powr_realpow[symmetric] `0 \<le> l` x'_def)
   902     ultimately show ?thesis
   903       unfolding normfloat_def
   904       using ceil_divide_floor_conv[of y x'] powr_realpow[of 2 "nat l"] `0 \<le> l` `y \<noteq> 0`
   905         l_def[symmetric, THEN meta_eq_to_obj_eq]
   906       by transfer
   907          (simp add: floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0 round_up_def)
   908    next
   909     assume "\<not> 0 \<le> l"
   910     def y' == "y * 2 ^ nat (- l)"
   911     from `y \<noteq> 0` have "y' \<noteq> 0" by (simp add: y'_def)
   912     have "int y * 2 ^ nat (- l) = y'" by (simp add: y'_def int_mult int_power)
   913     moreover have "real x * real (2::int) powr real l / real y = x / real y'"
   914       using `\<not> 0 \<le> l`
   915       by (simp add: powr_realpow[symmetric] powr_minus y'_def field_simps inverse_eq_divide)
   916     ultimately show ?thesis
   917       unfolding normfloat_def
   918       using ceil_divide_floor_conv[of y' x] `\<not> 0 \<le> l` `y' \<noteq> 0` `y \<noteq> 0`
   919         l_def[symmetric, THEN meta_eq_to_obj_eq]
   920       by transfer
   921          (simp add: round_up_def ceil_divide_floor_conv floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0)
   922   qed
   923 qed
   924 hide_fact (open) compute_rapprox_posrat
   925 
   926 lemma rat_precision_pos:
   927   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   928   shows "rat_precision n (int x) (int y) > 0"
   929 proof -
   930   { assume "0 < x" hence "log 2 x + 1 = log 2 (2 * x)" by (simp add: log_mult) }
   931   hence "bitlen (int x) < bitlen (int y)" using assms
   932     by (simp add: bitlen_def del: floor_add_one)
   933       (auto intro!: floor_mono simp add: floor_add_one[symmetric] simp del: floor_add floor_add_one)
   934   thus ?thesis
   935     using assms by (auto intro!: pos_add_strict simp add: field_simps rat_precision_def)
   936 qed
   937 
   938 lemma power_aux: assumes "x > 0" shows "(2::int) ^ nat (x - 1) \<le> 2 ^ nat x - 1"
   939 proof -
   940   def y \<equiv> "nat (x - 1)" moreover
   941   have "(2::int) ^ y \<le> (2 ^ (y + 1)) - 1" by simp
   942   ultimately show ?thesis using assms by simp
   943 qed
   944 
   945 lemma rapprox_posrat_less1:
   946   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   947   shows "real (rapprox_posrat n x y) < 1"
   948 proof -
   949   have powr1: "2 powr real (rat_precision n (int x) (int y)) = 
   950     2 ^ nat (rat_precision n (int x) (int y))" using rat_precision_pos[of x y n] assms
   951     by (simp add: powr_realpow[symmetric])
   952   have "x * 2 powr real (rat_precision n (int x) (int y)) / y = (x / y) *
   953      2 powr real (rat_precision n (int x) (int y))" by simp
   954   also have "... < (1 / 2) * 2 powr real (rat_precision n (int x) (int y))"
   955     apply (rule mult_strict_right_mono) by (insert assms) auto
   956   also have "\<dots> = 2 powr real (rat_precision n (int x) (int y) - 1)"
   957     by (simp add: powr_add diff_def powr_neg_numeral)
   958   also have "\<dots> = 2 ^ nat (rat_precision n (int x) (int y) - 1)"
   959     using rat_precision_pos[of x y n] assms by (simp add: powr_realpow[symmetric])
   960   also have "\<dots> \<le> 2 ^ nat (rat_precision n (int x) (int y)) - 1"
   961     unfolding int_of_reals real_of_int_le_iff
   962     using rat_precision_pos[OF assms] by (rule power_aux)
   963   finally show ?thesis
   964     apply (transfer fixing: n x y)
   965     apply (simp add: round_up_def field_simps powr_minus inverse_eq_divide powr1)
   966     unfolding int_of_reals real_of_int_less_iff
   967     apply (simp add: ceiling_less_eq)
   968     done
   969 qed
   970 
   971 lift_definition lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   972   "\<lambda>prec (x::int) (y::int). round_down (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   973 
   974 lemma compute_lapprox_rat[code]:
   975   "lapprox_rat prec x y =
   976     (if y = 0 then 0
   977     else if 0 \<le> x then
   978       (if 0 < y then lapprox_posrat prec (nat x) (nat y)
   979       else - (rapprox_posrat prec (nat x) (nat (-y)))) 
   980       else (if 0 < y
   981         then - (rapprox_posrat prec (nat (-x)) (nat y))
   982         else lapprox_posrat prec (nat (-x)) (nat (-y))))"
   983   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
   984 hide_fact (open) compute_lapprox_rat
   985 
   986 lift_definition rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   987   "\<lambda>prec (x::int) (y::int). round_up (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   988 
   989 lemma compute_rapprox_rat[code]:
   990   "rapprox_rat prec x y =
   991     (if y = 0 then 0
   992     else if 0 \<le> x then
   993       (if 0 < y then rapprox_posrat prec (nat x) (nat y)
   994       else - (lapprox_posrat prec (nat x) (nat (-y)))) 
   995       else (if 0 < y
   996         then - (lapprox_posrat prec (nat (-x)) (nat y))
   997         else rapprox_posrat prec (nat (-x)) (nat (-y))))"
   998   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
   999 hide_fact (open) compute_rapprox_rat
  1000 
  1001 subsection {* Division *}
  1002 
  1003 lift_definition float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
  1004   "\<lambda>(prec::nat) a b. round_down (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
  1005 
  1006 lemma compute_float_divl[code]:
  1007   "float_divl prec (Float m1 s1) (Float m2 s2) = lapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1008 proof cases
  1009   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1010   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1011   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1012   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1013     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1014   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1015     by (simp add: field_simps powr_divide2[symmetric])
  1016 
  1017   show ?thesis
  1018     using not_0 
  1019     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_down_shift, simp add: field_simps)
  1020 qed (transfer, auto)
  1021 hide_fact (open) compute_float_divl
  1022 
  1023 lift_definition float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
  1024   "\<lambda>(prec::nat) a b. round_up (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
  1025 
  1026 lemma compute_float_divr[code]:
  1027   "float_divr prec (Float m1 s1) (Float m2 s2) = rapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1028 proof cases
  1029   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1030   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1031   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1032   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1033     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1034   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1035     by (simp add: field_simps powr_divide2[symmetric])
  1036 
  1037   show ?thesis
  1038     using not_0 
  1039     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_up_shift, simp add: field_simps)
  1040 qed (transfer, auto)
  1041 hide_fact (open) compute_float_divr
  1042 
  1043 subsection {* Lemmas needed by Approximate *}
  1044 
  1045 lemma Float_num[simp]: shows
  1046    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
  1047    "real (Float 1 -1) = 1/2" and "real (Float 1 -2) = 1/4" and "real (Float 1 -3) = 1/8" and
  1048    "real (Float -1 0) = -1" and "real (Float (number_of n) 0) = number_of n"
  1049 using two_powr_int_float[of 2] two_powr_int_float[of "-1"] two_powr_int_float[of "-2"] two_powr_int_float[of "-3"]
  1050 using powr_realpow[of 2 2] powr_realpow[of 2 3]
  1051 using powr_minus[of 2 1] powr_minus[of 2 2] powr_minus[of 2 3]
  1052 by auto
  1053 
  1054 lemma real_of_Float_int[simp]: "real (Float n 0) = real n" by simp
  1055 
  1056 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
  1057 
  1058 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
  1059 by arith
  1060 
  1061 lemma lapprox_rat:
  1062   shows "real (lapprox_rat prec x y) \<le> real x / real y"
  1063   using round_down by (simp add: lapprox_rat_def)
  1064 
  1065 lemma mult_div_le: fixes a b:: int assumes "b > 0" shows "a \<ge> b * (a div b)"
  1066 proof -
  1067   from zmod_zdiv_equality'[of a b]
  1068   have "a = b * (a div b) + a mod b" by simp
  1069   also have "... \<ge> b * (a div b) + 0" apply (rule add_left_mono) apply (rule pos_mod_sign)
  1070   using assms by simp
  1071   finally show ?thesis by simp
  1072 qed
  1073 
  1074 lemma lapprox_rat_nonneg:
  1075   fixes n x y
  1076   defines "p == int n - ((bitlen \<bar>x\<bar>) - (bitlen \<bar>y\<bar>))"
  1077   assumes "0 \<le> x" "0 < y"
  1078   shows "0 \<le> real (lapprox_rat n x y)"
  1079 using assms unfolding lapprox_rat_def p_def[symmetric] round_down_def real_of_int_minus[symmetric]
  1080    powr_int[of 2, simplified]
  1081   by (auto simp add: inverse_eq_divide intro!: mult_nonneg_nonneg divide_nonneg_pos mult_pos_pos)
  1082 
  1083 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1084   using round_up by (simp add: rapprox_rat_def)
  1085 
  1086 lemma rapprox_rat_le1:
  1087   fixes n x y
  1088   assumes xy: "0 \<le> x" "0 < y" "x \<le> y"
  1089   shows "real (rapprox_rat n x y) \<le> 1"
  1090 proof -
  1091   have "bitlen \<bar>x\<bar> \<le> bitlen \<bar>y\<bar>"
  1092     using xy unfolding bitlen_def by (auto intro!: floor_mono)
  1093   then have "0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>" by (simp add: rat_precision_def)
  1094   have "real \<lceil>real x / real y * 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>
  1095       \<le> real \<lceil>2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>"
  1096     using xy by (auto intro!: ceiling_mono simp: field_simps)
  1097   also have "\<dots> = 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"
  1098     using `0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>`
  1099     by (auto intro!: exI[of _ "2^nat (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"] simp: powr_int)
  1100   finally show ?thesis
  1101     by (simp add: rapprox_rat_def round_up_def)
  1102        (simp add: powr_minus inverse_eq_divide)
  1103 qed
  1104 
  1105 lemma rapprox_rat_nonneg_neg: 
  1106   "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1107   unfolding rapprox_rat_def round_up_def
  1108   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff)
  1109 
  1110 lemma rapprox_rat_neg:
  1111   "x < 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1112   unfolding rapprox_rat_def round_up_def
  1113   by (auto simp: field_simps mult_le_0_iff)
  1114 
  1115 lemma rapprox_rat_nonpos_pos:
  1116   "x \<le> 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1117   unfolding rapprox_rat_def round_up_def
  1118   by (auto simp: field_simps mult_le_0_iff)
  1119 
  1120 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1121   by transfer (simp add: round_down)
  1122 
  1123 lemma float_divl_lower_bound:
  1124   "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> 0 \<le> real (float_divl prec x y)"
  1125   by transfer (simp add: round_down_def zero_le_mult_iff zero_le_divide_iff)
  1126 
  1127 lemma exponent_1: "exponent 1 = 0"
  1128   using exponent_float[of 1 0] by (simp add: one_float_def)
  1129 
  1130 lemma mantissa_1: "mantissa 1 = 1"
  1131   using mantissa_float[of 1 0] by (simp add: one_float_def)
  1132 
  1133 lemma bitlen_1: "bitlen 1 = 1"
  1134   by (simp add: bitlen_def)
  1135 
  1136 lemma mantissa_eq_zero_iff: "mantissa x = 0 \<longleftrightarrow> x = 0"
  1137 proof
  1138   assume "mantissa x = 0" hence z: "0 = real x" using mantissa_exponent by simp
  1139   show "x = 0" by (simp add: zero_float_def z)
  1140 qed (simp add: zero_float_def)
  1141 
  1142 lemma float_upper_bound: "x \<le> 2 powr (bitlen \<bar>mantissa x\<bar> + exponent x)"
  1143 proof (cases "x = 0", simp)
  1144   assume "x \<noteq> 0" hence "mantissa x \<noteq> 0" using mantissa_eq_zero_iff by auto
  1145   have "x = mantissa x * 2 powr (exponent x)" by (rule mantissa_exponent)
  1146   also have "mantissa x \<le> \<bar>mantissa x\<bar>" by simp
  1147   also have "... \<le> 2 powr (bitlen \<bar>mantissa x\<bar>)"
  1148     using bitlen_bounds[of "\<bar>mantissa x\<bar>"] bitlen_nonneg `mantissa x \<noteq> 0`
  1149     by (simp add: powr_int) (simp only: two_real_int int_of_reals real_of_int_abs[symmetric]
  1150       real_of_int_le_iff less_imp_le)
  1151   finally show ?thesis by (simp add: powr_add)
  1152 qed
  1153 
  1154 lemma float_divl_pos_less1_bound:
  1155   "0 < real x \<Longrightarrow> real x < 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real (float_divl prec 1 x)"
  1156 proof transfer
  1157   fix prec :: nat and x :: real assume x: "0 < x" "x < 1" "x \<in> float" and prec: "1 \<le> prec"
  1158   def p \<equiv> "int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor>" 
  1159   show "1 \<le> round_down (int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - \<lfloor>log 2 \<bar>1\<bar>\<rfloor>) (1 / x) "
  1160   proof cases
  1161     assume nonneg: "0 \<le> p"
  1162     hence "2 powr real (p) = floor (real ((2::int) ^ nat p)) * floor (1::real)"
  1163       by (simp add: powr_int del: real_of_int_power) simp
  1164     also have "floor (1::real) \<le> floor (1 / x)" using x prec by simp
  1165     also have "floor (real ((2::int) ^ nat p)) * floor (1 / x) \<le>
  1166       floor (real ((2::int) ^ nat p) * (1 / x))"
  1167       by (rule le_mult_floor) (auto simp: x prec less_imp_le)
  1168     finally have "2 powr real p \<le> floor (2 powr nat p / x)" by (simp add: powr_realpow)
  1169     thus ?thesis unfolding p_def[symmetric]
  1170       using x prec nonneg by (simp add: powr_minus inverse_eq_divide round_down_def)
  1171   next
  1172     assume neg: "\<not> 0 \<le> p"
  1173 
  1174     have "x = 2 powr (log 2 x)"
  1175       using x by simp
  1176     also have "2 powr (log 2 x) \<le> 2 powr p"
  1177     proof (rule powr_mono)
  1178       have "log 2 x \<le> \<lceil>log 2 x\<rceil>"
  1179         by simp
  1180       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + 1"
  1181         using ceiling_diff_floor_le_1[of "log 2 x"] by simp
  1182       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + prec"
  1183         using prec by simp
  1184       finally show "log 2 x \<le> real p"
  1185         using x by (simp add: p_def)
  1186     qed simp
  1187     finally have x_le: "x \<le> 2 powr p" .
  1188 
  1189     from neg have "2 powr real p \<le> 2 powr 0"
  1190       by (intro powr_mono) auto
  1191     also have "\<dots> \<le> \<lfloor>2 powr 0\<rfloor>" by simp
  1192     also have "\<dots> \<le> \<lfloor>2 powr real p / x\<rfloor>" unfolding real_of_int_le_iff
  1193       using x x_le by (intro floor_mono) (simp add:  pos_le_divide_eq mult_pos_pos)
  1194     finally show ?thesis
  1195       using prec x unfolding p_def[symmetric]
  1196       by (simp add: round_down_def powr_minus_divide pos_le_divide_eq mult_pos_pos)
  1197   qed
  1198 qed
  1199 
  1200 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1201   using round_up by transfer simp
  1202 
  1203 lemma float_divr_pos_less1_lower_bound: assumes "0 < x" and "x < 1" shows "1 \<le> float_divr prec 1 x"
  1204 proof -
  1205   have "1 \<le> 1 / real x" using `0 < x` and `x < 1` by auto
  1206   also have "\<dots> \<le> real (float_divr prec 1 x)" using float_divr[where x=1 and y=x] by auto
  1207   finally show ?thesis by auto
  1208 qed
  1209 
  1210 lemma float_divr_nonpos_pos_upper_bound:
  1211   "real x \<le> 0 \<Longrightarrow> 0 < real y \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1212   by transfer (auto simp: field_simps mult_le_0_iff divide_le_0_iff round_up_def)
  1213 
  1214 lemma float_divr_nonneg_neg_upper_bound:
  1215   "0 \<le> real x \<Longrightarrow> real y < 0 \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1216   by transfer (auto simp: field_simps mult_le_0_iff zero_le_mult_iff divide_le_0_iff round_up_def)
  1217 
  1218 lift_definition float_round_up :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1219   "\<lambda>(prec::nat) x. round_up (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1220 
  1221 lemma float_round_up: "real x \<le> real (float_round_up prec x)"
  1222   using round_up by transfer simp
  1223 
  1224 lift_definition float_round_down :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1225   "\<lambda>(prec::nat) x. round_down (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1226 
  1227 lemma float_round_down: "real (float_round_down prec x) \<le> real x"
  1228   using round_down by transfer simp
  1229 
  1230 lemma floor_add2[simp]: "\<lfloor> real i + x \<rfloor> = i + \<lfloor> x \<rfloor>"
  1231   using floor_add[of x i] by (simp del: floor_add add: ac_simps)
  1232 
  1233 lemma compute_float_round_down[code]:
  1234   "float_round_down prec (Float m e) = (let d = bitlen (abs m) - int prec in
  1235     if 0 < d then let P = 2^nat d ; n = m div P in Float n (e + d)
  1236              else Float m e)"
  1237   using Float.compute_float_down[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1238   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1239 hide_fact (open) compute_float_round_down
  1240 
  1241 lemma compute_float_round_up[code]:
  1242   "float_round_up prec (Float m e) = (let d = (bitlen (abs m) - int prec) in
  1243      if 0 < d then let P = 2^nat d ; n = m div P ; r = m mod P
  1244                    in Float (n + (if r = 0 then 0 else 1)) (e + d)
  1245               else Float m e)"
  1246   using Float.compute_float_up[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1247   unfolding Let_def
  1248   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1249 hide_fact (open) compute_float_round_up
  1250 
  1251 lemma Float_le_zero_iff: "Float a b \<le> 0 \<longleftrightarrow> a \<le> 0"
  1252  apply (auto simp: zero_float_def mult_le_0_iff)
  1253  using powr_gt_zero[of 2 b] by simp
  1254 
  1255 lemma real_of_float_pprt[simp]: fixes a::float shows "real (pprt a) = pprt (real a)"
  1256   unfolding pprt_def sup_float_def max_def sup_real_def by auto
  1257 
  1258 lemma real_of_float_nprt[simp]: fixes a::float shows "real (nprt a) = nprt (real a)"
  1259   unfolding nprt_def inf_float_def min_def inf_real_def by auto
  1260 
  1261 lift_definition int_floor_fl :: "float \<Rightarrow> int" is floor by simp
  1262 
  1263 lemma compute_int_floor_fl[code]:
  1264   "int_floor_fl (Float m e) = (if 0 \<le> e then m * 2 ^ nat e else m div (2 ^ (nat (-e))))"
  1265   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1266 hide_fact (open) compute_int_floor_fl
  1267 
  1268 lift_definition floor_fl :: "float \<Rightarrow> float" is "\<lambda>x. real (floor x)" by simp
  1269 
  1270 lemma compute_floor_fl[code]:
  1271   "floor_fl (Float m e) = (if 0 \<le> e then Float m e else Float (m div (2 ^ (nat (-e)))) 0)"
  1272   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1273 hide_fact (open) compute_floor_fl
  1274 
  1275 lemma floor_fl: "real (floor_fl x) \<le> real x" by transfer simp
  1276 
  1277 lemma int_floor_fl: "real (int_floor_fl x) \<le> real x" by transfer simp
  1278 
  1279 lemma floor_pos_exp: "exponent (floor_fl x) \<ge> 0"
  1280 proof cases
  1281   assume nzero: "floor_fl x \<noteq> float_of 0"
  1282   have "floor_fl x = Float \<lfloor>real x\<rfloor> 0" by transfer simp
  1283   from denormalize_shift[OF this[THEN eq_reflection] nzero] guess i . note i = this
  1284   thus ?thesis by simp
  1285 qed (simp add: floor_fl_def)
  1286 
  1287 end
  1288