src/HOL/Nat.thy
author wenzelm
Tue Jun 10 19:15:21 2008 +0200 (2008-06-10)
changeset 27129 336807f865ce
parent 27104 791607529f6d
child 27213 2c7a628ccdcf
permissions -rw-r--r--
added nat_induct_tac (works without context);
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = Nat
    47   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc ::   "nat => nat"
    51   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code func del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   apply (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    67     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    68   done
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 rep_datatype "0 \<Colon> nat" Suc
    74   apply (unfold Zero_nat_def Suc_def)
    75      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    76      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    77      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    78     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    79       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    80       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    81       inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    82   done
    83 
    84 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    85   -- {* for backward compatibility -- naming of variables differs *}
    86   fixes n
    87   assumes "P 0"
    88     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    89   shows "P n"
    90   using assms by (rule nat.induct) 
    91 
    92 ML {*
    93   fun nat_induct_tac n = res_inst_tac [("n", n)] @{thm nat_induct}
    94 *}
    95 
    96 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    97 
    98 lemmas nat_rec_0 = nat.recs(1)
    99   and nat_rec_Suc = nat.recs(2)
   100 
   101 lemmas nat_case_0 = nat.cases(1)
   102   and nat_case_Suc = nat.cases(2)
   103    
   104 
   105 text {* Injectiveness and distinctness lemmas *}
   106 
   107 lemma inj_Suc[simp]: "inj_on Suc N"
   108   by (simp add: inj_on_def)
   109 
   110 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   111 by (rule notE, rule Suc_not_Zero)
   112 
   113 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   114 by (rule Suc_neq_Zero, erule sym)
   115 
   116 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   117 by (rule inj_Suc [THEN injD])
   118 
   119 lemma n_not_Suc_n: "n \<noteq> Suc n"
   120 by (induct n) simp_all
   121 
   122 lemma Suc_n_not_n: "Suc n \<noteq> n"
   123 by (rule not_sym, rule n_not_Suc_n)
   124 
   125 text {* A special form of induction for reasoning
   126   about @{term "m < n"} and @{term "m - n"} *}
   127 
   128 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   129     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   130   apply (rule_tac x = m in spec)
   131   apply (induct n)
   132   prefer 2
   133   apply (rule allI)
   134   apply (induct_tac x, iprover+)
   135   done
   136 
   137 
   138 subsection {* Arithmetic operators *}
   139 
   140 instantiation nat :: "{minus, comm_monoid_add}"
   141 begin
   142 
   143 primrec plus_nat
   144 where
   145   add_0:      "0 + n = (n\<Colon>nat)"
   146   | add_Suc:  "Suc m + n = Suc (m + n)"
   147 
   148 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   149   by (induct m) simp_all
   150 
   151 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   152   by (induct m) simp_all
   153 
   154 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   155   by simp
   156 
   157 primrec minus_nat
   158 where
   159   diff_0:     "m - 0 = (m\<Colon>nat)"
   160   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   161 
   162 declare diff_Suc [simp del, code del]
   163 
   164 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   165   by (induct n) (simp_all add: diff_Suc)
   166 
   167 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   168   by (induct n) (simp_all add: diff_Suc)
   169 
   170 instance proof
   171   fix n m q :: nat
   172   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   173   show "n + m = m + n" by (induct n) simp_all
   174   show "0 + n = n" by simp
   175 qed
   176 
   177 end
   178 
   179 instantiation nat :: comm_semiring_1_cancel
   180 begin
   181 
   182 definition
   183   One_nat_def [simp]: "1 = Suc 0"
   184 
   185 primrec times_nat
   186 where
   187   mult_0:     "0 * n = (0\<Colon>nat)"
   188   | mult_Suc: "Suc m * n = n + (m * n)"
   189 
   190 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   191   by (induct m) simp_all
   192 
   193 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   194   by (induct m) (simp_all add: add_left_commute)
   195 
   196 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   197   by (induct m) (simp_all add: add_assoc)
   198 
   199 instance proof
   200   fix n m q :: nat
   201   show "0 \<noteq> (1::nat)" by simp
   202   show "1 * n = n" by simp
   203   show "n * m = m * n" by (induct n) simp_all
   204   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   205   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   206   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   207 qed
   208 
   209 end
   210 
   211 subsubsection {* Addition *}
   212 
   213 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   214   by (rule add_assoc)
   215 
   216 lemma nat_add_commute: "m + n = n + (m::nat)"
   217   by (rule add_commute)
   218 
   219 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   220   by (rule add_left_commute)
   221 
   222 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   223   by (rule add_left_cancel)
   224 
   225 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   226   by (rule add_right_cancel)
   227 
   228 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   229 
   230 lemma add_is_0 [iff]:
   231   fixes m n :: nat
   232   shows "(m + n = 0) = (m = 0 & n = 0)"
   233   by (cases m) simp_all
   234 
   235 lemma add_is_1:
   236   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   237   by (cases m) simp_all
   238 
   239 lemma one_is_add:
   240   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   241   by (rule trans, rule eq_commute, rule add_is_1)
   242 
   243 lemma add_eq_self_zero:
   244   fixes m n :: nat
   245   shows "m + n = m \<Longrightarrow> n = 0"
   246   by (induct m) simp_all
   247 
   248 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   249   apply (induct k)
   250    apply simp
   251   apply(drule comp_inj_on[OF _ inj_Suc])
   252   apply (simp add:o_def)
   253   done
   254 
   255 
   256 subsubsection {* Difference *}
   257 
   258 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   259   by (induct m) simp_all
   260 
   261 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   262   by (induct i j rule: diff_induct) simp_all
   263 
   264 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   265   by (simp add: diff_diff_left)
   266 
   267 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   268   by (simp add: diff_diff_left add_commute)
   269 
   270 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   271   by (induct n) simp_all
   272 
   273 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   274   by (simp add: diff_add_inverse add_commute [of m n])
   275 
   276 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   277   by (induct k) simp_all
   278 
   279 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   280   by (simp add: diff_cancel add_commute)
   281 
   282 lemma diff_add_0: "n - (n + m) = (0::nat)"
   283   by (induct n) simp_all
   284 
   285 text {* Difference distributes over multiplication *}
   286 
   287 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   288 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   289 
   290 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   291 by (simp add: diff_mult_distrib mult_commute [of k])
   292   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   293 
   294 
   295 subsubsection {* Multiplication *}
   296 
   297 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   298   by (rule mult_assoc)
   299 
   300 lemma nat_mult_commute: "m * n = n * (m::nat)"
   301   by (rule mult_commute)
   302 
   303 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   304   by (rule right_distrib)
   305 
   306 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   307   by (induct m) auto
   308 
   309 lemmas nat_distrib =
   310   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   311 
   312 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   313   apply (induct m)
   314    apply simp
   315   apply (induct n)
   316    apply auto
   317   done
   318 
   319 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   320   apply (rule trans)
   321   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   322   done
   323 
   324 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   325 proof -
   326   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   327   proof (induct n arbitrary: m)
   328     case 0 then show "m = 0" by simp
   329   next
   330     case (Suc n) then show "m = Suc n"
   331       by (cases m) (simp_all add: eq_commute [of "0"])
   332   qed
   333   then show ?thesis by auto
   334 qed
   335 
   336 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   337   by (simp add: mult_commute)
   338 
   339 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   340   by (subst mult_cancel1) simp
   341 
   342 
   343 subsection {* Orders on @{typ nat} *}
   344 
   345 subsubsection {* Operation definition *}
   346 
   347 instantiation nat :: linorder
   348 begin
   349 
   350 primrec less_eq_nat where
   351   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   352   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   353 
   354 declare less_eq_nat.simps [simp del, code del]
   355 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   356 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   357 
   358 definition less_nat where
   359   less_eq_Suc_le [code func del]: "n < m \<longleftrightarrow> Suc n \<le> m"
   360 
   361 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   362   by (simp add: less_eq_nat.simps(2))
   363 
   364 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   365   unfolding less_eq_Suc_le ..
   366 
   367 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   368   by (induct n) (simp_all add: less_eq_nat.simps(2))
   369 
   370 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   371   by (simp add: less_eq_Suc_le)
   372 
   373 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   374   by simp
   375 
   376 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   377   by (simp add: less_eq_Suc_le)
   378 
   379 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   380   by (simp add: less_eq_Suc_le)
   381 
   382 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   383   by (induct m arbitrary: n)
   384     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   385 
   386 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   387   by (cases n) (auto intro: le_SucI)
   388 
   389 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   390   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   391 
   392 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   393   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   394 
   395 instance
   396 proof
   397   fix n m :: nat
   398   have less_imp_le: "n < m \<Longrightarrow> n \<le> m"
   399     unfolding less_eq_Suc_le by (erule Suc_leD)
   400   have irrefl: "\<not> m < m" by (induct m) auto
   401   have strict: "n \<le> m \<Longrightarrow> n \<noteq> m \<Longrightarrow> n < m"
   402   proof (induct n arbitrary: m)
   403     case 0 then show ?case
   404       by (cases m) (simp_all add: less_eq_Suc_le)
   405   next
   406     case (Suc n) then show ?case
   407       by (cases m) (simp_all add: less_eq_Suc_le)
   408   qed
   409   show "n < m \<longleftrightarrow> n \<le> m \<and> n \<noteq> m"
   410     by (auto simp add: irrefl intro: less_imp_le strict)
   411 next
   412   fix n :: nat show "n \<le> n" by (induct n) simp_all
   413 next
   414   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   415   then show "n = m"
   416     by (induct n arbitrary: m)
   417       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   418 next
   419   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   420   then show "n \<le> q"
   421   proof (induct n arbitrary: m q)
   422     case 0 show ?case by simp
   423   next
   424     case (Suc n) then show ?case
   425       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   426         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   427         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   428   qed
   429 next
   430   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   431     by (induct n arbitrary: m)
   432       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   433 qed
   434 
   435 end
   436 
   437 subsubsection {* Introduction properties *}
   438 
   439 lemma lessI [iff]: "n < Suc n"
   440   by (simp add: less_Suc_eq_le)
   441 
   442 lemma zero_less_Suc [iff]: "0 < Suc n"
   443   by (simp add: less_Suc_eq_le)
   444 
   445 
   446 subsubsection {* Elimination properties *}
   447 
   448 lemma less_not_refl: "~ n < (n::nat)"
   449   by (rule order_less_irrefl)
   450 
   451 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   452   by (rule not_sym) (rule less_imp_neq) 
   453 
   454 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   455   by (rule less_imp_neq)
   456 
   457 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   458   by (rule notE, rule less_not_refl)
   459 
   460 lemma less_zeroE: "(n::nat) < 0 ==> R"
   461   by (rule notE) (rule not_less0)
   462 
   463 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   464   unfolding less_Suc_eq_le le_less ..
   465 
   466 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   467   by (simp add: less_Suc_eq)
   468 
   469 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   470   by (simp add: less_Suc_eq)
   471 
   472 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   473   by simp
   474 
   475 text {* "Less than" is antisymmetric, sort of *}
   476 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   477   unfolding not_less less_Suc_eq_le by (rule antisym)
   478 
   479 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   480   by (rule linorder_neq_iff)
   481 
   482 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   483   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   484   shows "P n m"
   485   apply (rule less_linear [THEN disjE])
   486   apply (erule_tac [2] disjE)
   487   apply (erule lessCase)
   488   apply (erule sym [THEN eqCase])
   489   apply (erule major)
   490   done
   491 
   492 
   493 subsubsection {* Inductive (?) properties *}
   494 
   495 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   496   unfolding less_eq_Suc_le [of m] le_less by simp 
   497 
   498 lemma lessE:
   499   assumes major: "i < k"
   500   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   501   shows P
   502 proof -
   503   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   504     unfolding less_eq_Suc_le by (induct k) simp_all
   505   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   506     by (clarsimp simp add: less_le)
   507   with p1 p2 show P by auto
   508 qed
   509 
   510 lemma less_SucE: assumes major: "m < Suc n"
   511   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   512   apply (rule major [THEN lessE])
   513   apply (rule eq, blast)
   514   apply (rule less, blast)
   515   done
   516 
   517 lemma Suc_lessE: assumes major: "Suc i < k"
   518   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   519   apply (rule major [THEN lessE])
   520   apply (erule lessI [THEN minor])
   521   apply (erule Suc_lessD [THEN minor], assumption)
   522   done
   523 
   524 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   525   by simp
   526 
   527 lemma less_trans_Suc:
   528   assumes le: "i < j" shows "j < k ==> Suc i < k"
   529   apply (induct k, simp_all)
   530   apply (insert le)
   531   apply (simp add: less_Suc_eq)
   532   apply (blast dest: Suc_lessD)
   533   done
   534 
   535 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   536 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   537   unfolding not_less less_Suc_eq_le ..
   538 
   539 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   540   unfolding not_le Suc_le_eq ..
   541 
   542 text {* Properties of "less than or equal" *}
   543 
   544 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   545   unfolding less_Suc_eq_le .
   546 
   547 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   548   unfolding not_le less_Suc_eq_le ..
   549 
   550 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   551   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   552 
   553 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   554   by (drule le_Suc_eq [THEN iffD1], iprover+)
   555 
   556 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   557   unfolding Suc_le_eq .
   558 
   559 text {* Stronger version of @{text Suc_leD} *}
   560 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   561   unfolding Suc_le_eq .
   562 
   563 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   564   unfolding less_eq_Suc_le by (rule Suc_leD)
   565 
   566 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   567 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   568 
   569 
   570 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   571 
   572 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   573   unfolding le_less .
   574 
   575 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   576   by (rule le_less)
   577 
   578 text {* Useful with @{text blast}. *}
   579 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   580   by auto
   581 
   582 lemma le_refl: "n \<le> (n::nat)"
   583   by simp
   584 
   585 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   586   by (rule order_trans)
   587 
   588 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   589   by (rule antisym)
   590 
   591 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   592   by (rule less_le)
   593 
   594 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   595   unfolding less_le ..
   596 
   597 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   598   by (rule linear)
   599 
   600 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   601 
   602 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   603   unfolding less_Suc_eq_le by auto
   604 
   605 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   606   unfolding not_less by (rule le_less_Suc_eq)
   607 
   608 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   609 
   610 text {* These two rules ease the use of primitive recursion.
   611 NOTE USE OF @{text "=="} *}
   612 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   613 by simp
   614 
   615 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   616 by simp
   617 
   618 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   619 by (cases n) simp_all
   620 
   621 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   622 by (cases n) simp_all
   623 
   624 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   625 by (cases n) simp_all
   626 
   627 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   628 by (cases n) simp_all
   629 
   630 text {* This theorem is useful with @{text blast} *}
   631 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   632 by (rule neq0_conv[THEN iffD1], iprover)
   633 
   634 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   635 by (fast intro: not0_implies_Suc)
   636 
   637 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   638 using neq0_conv by blast
   639 
   640 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   641 by (induct m') simp_all
   642 
   643 text {* Useful in certain inductive arguments *}
   644 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   645 by (cases m) simp_all
   646 
   647 
   648 subsubsection {* @{term min} and @{term max} *}
   649 
   650 lemma mono_Suc: "mono Suc"
   651 by (rule monoI) simp
   652 
   653 lemma min_0L [simp]: "min 0 n = (0::nat)"
   654 by (rule min_leastL) simp
   655 
   656 lemma min_0R [simp]: "min n 0 = (0::nat)"
   657 by (rule min_leastR) simp
   658 
   659 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   660 by (simp add: mono_Suc min_of_mono)
   661 
   662 lemma min_Suc1:
   663    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   664 by (simp split: nat.split)
   665 
   666 lemma min_Suc2:
   667    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   668 by (simp split: nat.split)
   669 
   670 lemma max_0L [simp]: "max 0 n = (n::nat)"
   671 by (rule max_leastL) simp
   672 
   673 lemma max_0R [simp]: "max n 0 = (n::nat)"
   674 by (rule max_leastR) simp
   675 
   676 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   677 by (simp add: mono_Suc max_of_mono)
   678 
   679 lemma max_Suc1:
   680    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   681 by (simp split: nat.split)
   682 
   683 lemma max_Suc2:
   684    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   685 by (simp split: nat.split)
   686 
   687 
   688 subsubsection {* Monotonicity of Addition *}
   689 
   690 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   691 by (simp add: diff_Suc split: nat.split)
   692 
   693 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   694 by (induct k) simp_all
   695 
   696 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   697 by (induct k) simp_all
   698 
   699 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   700 by(auto dest:gr0_implies_Suc)
   701 
   702 text {* strict, in 1st argument *}
   703 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   704 by (induct k) simp_all
   705 
   706 text {* strict, in both arguments *}
   707 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   708   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   709   apply (induct j, simp_all)
   710   done
   711 
   712 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   713 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   714   apply (induct n)
   715   apply (simp_all add: order_le_less)
   716   apply (blast elim!: less_SucE
   717                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   718   done
   719 
   720 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   721 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   722 apply(auto simp: gr0_conv_Suc)
   723 apply (induct_tac m)
   724 apply (simp_all add: add_less_mono)
   725 done
   726 
   727 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   728 instance nat :: ordered_semidom
   729 proof
   730   fix i j k :: nat
   731   show "0 < (1::nat)" by simp
   732   show "i \<le> j ==> k + i \<le> k + j" by simp
   733   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   734 qed
   735 
   736 lemma nat_mult_1: "(1::nat) * n = n"
   737 by simp
   738 
   739 lemma nat_mult_1_right: "n * (1::nat) = n"
   740 by simp
   741 
   742 
   743 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   744 
   745 text {* Complete induction, aka course-of-values induction *}
   746 
   747 lemma less_induct [case_names less]:
   748   fixes P :: "nat \<Rightarrow> bool"
   749   assumes step: "\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x"
   750   shows "P a"
   751 proof - 
   752   have "\<And>z. z\<le>a \<Longrightarrow> P z"
   753   proof (induct a)
   754     case (0 z)
   755     have "P 0" by (rule step) auto
   756     thus ?case using 0 by auto
   757   next
   758     case (Suc x z)
   759     then have "z \<le> x \<or> z = Suc x" by (simp add: le_Suc_eq)
   760     thus ?case
   761     proof
   762       assume "z \<le> x" thus "P z" by (rule Suc(1))
   763     next
   764       assume z: "z = Suc x"
   765       show "P z"
   766         by (rule step) (rule Suc(1), simp add: z le_simps)
   767     qed
   768   qed
   769   thus ?thesis by auto
   770 qed
   771 
   772 lemma nat_less_induct:
   773   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   774   using assms less_induct by blast
   775 
   776 lemma measure_induct_rule [case_names less]:
   777   fixes f :: "'a \<Rightarrow> nat"
   778   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   779   shows "P a"
   780 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   781 
   782 text {* old style induction rules: *}
   783 lemma measure_induct:
   784   fixes f :: "'a \<Rightarrow> nat"
   785   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   786   by (rule measure_induct_rule [of f P a]) iprover
   787 
   788 lemma full_nat_induct:
   789   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   790   shows "P n"
   791   by (rule less_induct) (auto intro: step simp:le_simps)
   792 
   793 text{*An induction rule for estabilishing binary relations*}
   794 lemma less_Suc_induct:
   795   assumes less:  "i < j"
   796      and  step:  "!!i. P i (Suc i)"
   797      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   798   shows "P i j"
   799 proof -
   800   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   801   have "P i (Suc (i + k))"
   802   proof (induct k)
   803     case 0
   804     show ?case by (simp add: step)
   805   next
   806     case (Suc k)
   807     thus ?case by (auto intro: assms)
   808   qed
   809   thus "P i j" by (simp add: j)
   810 qed
   811 
   812 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   813   apply (rule nat_less_induct)
   814   apply (case_tac n)
   815   apply (case_tac [2] nat)
   816   apply (blast intro: less_trans)+
   817   done
   818 
   819 text {* The method of infinite descent, frequently used in number theory.
   820 Provided by Roelof Oosterhuis.
   821 $P(n)$ is true for all $n\in\mathbb{N}$ if
   822 \begin{itemize}
   823   \item case ``0'': given $n=0$ prove $P(n)$,
   824   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   825         a smaller integer $m$ such that $\neg P(m)$.
   826 \end{itemize} *}
   827 
   828 text{* A compact version without explicit base case: *}
   829 lemma infinite_descent:
   830   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   831 by (induct n rule: less_induct, auto)
   832 
   833 lemma infinite_descent0[case_names 0 smaller]: 
   834   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   835 by (rule infinite_descent) (case_tac "n>0", auto)
   836 
   837 text {*
   838 Infinite descent using a mapping to $\mathbb{N}$:
   839 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   840 \begin{itemize}
   841 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   842 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   843 \end{itemize}
   844 NB: the proof also shows how to use the previous lemma. *}
   845 
   846 corollary infinite_descent0_measure [case_names 0 smaller]:
   847   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   848     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   849   shows "P x"
   850 proof -
   851   obtain n where "n = V x" by auto
   852   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   853   proof (induct n rule: infinite_descent0)
   854     case 0 -- "i.e. $V(x) = 0$"
   855     with A0 show "P x" by auto
   856   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   857     case (smaller n)
   858     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   859     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   860     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   861     then show ?case by auto
   862   qed
   863   ultimately show "P x" by auto
   864 qed
   865 
   866 text{* Again, without explicit base case: *}
   867 lemma infinite_descent_measure:
   868 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   869 proof -
   870   from assms obtain n where "n = V x" by auto
   871   moreover have "!!x. V x = n \<Longrightarrow> P x"
   872   proof (induct n rule: infinite_descent, auto)
   873     fix x assume "\<not> P x"
   874     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   875   qed
   876   ultimately show "P x" by auto
   877 qed
   878 
   879 text {* A [clumsy] way of lifting @{text "<"}
   880   monotonicity to @{text "\<le>"} monotonicity *}
   881 lemma less_mono_imp_le_mono:
   882   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   883 by (simp add: order_le_less) (blast)
   884 
   885 
   886 text {* non-strict, in 1st argument *}
   887 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   888 by (rule add_right_mono)
   889 
   890 text {* non-strict, in both arguments *}
   891 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   892 by (rule add_mono)
   893 
   894 lemma le_add2: "n \<le> ((m + n)::nat)"
   895 by (insert add_right_mono [of 0 m n], simp)
   896 
   897 lemma le_add1: "n \<le> ((n + m)::nat)"
   898 by (simp add: add_commute, rule le_add2)
   899 
   900 lemma less_add_Suc1: "i < Suc (i + m)"
   901 by (rule le_less_trans, rule le_add1, rule lessI)
   902 
   903 lemma less_add_Suc2: "i < Suc (m + i)"
   904 by (rule le_less_trans, rule le_add2, rule lessI)
   905 
   906 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   907 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   908 
   909 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   910 by (rule le_trans, assumption, rule le_add1)
   911 
   912 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   913 by (rule le_trans, assumption, rule le_add2)
   914 
   915 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   916 by (rule less_le_trans, assumption, rule le_add1)
   917 
   918 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   919 by (rule less_le_trans, assumption, rule le_add2)
   920 
   921 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   922 apply (rule le_less_trans [of _ "i+j"])
   923 apply (simp_all add: le_add1)
   924 done
   925 
   926 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   927 apply (rule notI)
   928 apply (drule add_lessD1)
   929 apply (erule less_irrefl [THEN notE])
   930 done
   931 
   932 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   933 by (simp add: add_commute)
   934 
   935 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   936 apply (rule order_trans [of _ "m+k"])
   937 apply (simp_all add: le_add1)
   938 done
   939 
   940 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   941 apply (simp add: add_commute)
   942 apply (erule add_leD1)
   943 done
   944 
   945 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   946 by (blast dest: add_leD1 add_leD2)
   947 
   948 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   949 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   950 by (force simp del: add_Suc_right
   951     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   952 
   953 
   954 subsubsection {* More results about difference *}
   955 
   956 text {* Addition is the inverse of subtraction:
   957   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   958 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   959 by (induct m n rule: diff_induct) simp_all
   960 
   961 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   962 by (simp add: add_diff_inverse linorder_not_less)
   963 
   964 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   965 by (simp add: add_commute)
   966 
   967 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   968 by (induct m n rule: diff_induct) simp_all
   969 
   970 lemma diff_less_Suc: "m - n < Suc m"
   971 apply (induct m n rule: diff_induct)
   972 apply (erule_tac [3] less_SucE)
   973 apply (simp_all add: less_Suc_eq)
   974 done
   975 
   976 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   977 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   978 
   979 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
   980   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
   981 
   982 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   983 by (rule le_less_trans, rule diff_le_self)
   984 
   985 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   986 by (cases n) (auto simp add: le_simps)
   987 
   988 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   989 by (induct j k rule: diff_induct) simp_all
   990 
   991 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   992 by (simp add: add_commute diff_add_assoc)
   993 
   994 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   995 by (auto simp add: diff_add_inverse2)
   996 
   997 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   998 by (induct m n rule: diff_induct) simp_all
   999 
  1000 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1001 by (rule iffD2, rule diff_is_0_eq)
  1002 
  1003 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1004 by (induct m n rule: diff_induct) simp_all
  1005 
  1006 lemma less_imp_add_positive:
  1007   assumes "i < j"
  1008   shows "\<exists>k::nat. 0 < k & i + k = j"
  1009 proof
  1010   from assms show "0 < j - i & i + (j - i) = j"
  1011     by (simp add: order_less_imp_le)
  1012 qed
  1013 
  1014 text {* a nice rewrite for bounded subtraction *}
  1015 lemma nat_minus_add_max:
  1016   fixes n m :: nat
  1017   shows "n - m + m = max n m"
  1018     by (simp add: max_def not_le order_less_imp_le)
  1019 
  1020 lemma nat_diff_split:
  1021   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1022     -- {* elimination of @{text -} on @{text nat} *}
  1023 by (cases "a < b")
  1024   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1025     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1026 
  1027 lemma nat_diff_split_asm:
  1028   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1029     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1030 by (auto split: nat_diff_split)
  1031 
  1032 
  1033 subsubsection {* Monotonicity of Multiplication *}
  1034 
  1035 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1036 by (simp add: mult_right_mono)
  1037 
  1038 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1039 by (simp add: mult_left_mono)
  1040 
  1041 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1042 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1043 by (simp add: mult_mono)
  1044 
  1045 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1046 by (simp add: mult_strict_right_mono)
  1047 
  1048 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1049       there are no negative numbers.*}
  1050 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1051   apply (induct m)
  1052    apply simp
  1053   apply (case_tac n)
  1054    apply simp_all
  1055   done
  1056 
  1057 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
  1058   apply (induct m)
  1059    apply simp
  1060   apply (case_tac n)
  1061    apply simp_all
  1062   done
  1063 
  1064 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1065   apply (safe intro!: mult_less_mono1)
  1066   apply (case_tac k, auto)
  1067   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1068   apply (blast intro: mult_le_mono1)
  1069   done
  1070 
  1071 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1072 by (simp add: mult_commute [of k])
  1073 
  1074 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1075 by (simp add: linorder_not_less [symmetric], auto)
  1076 
  1077 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1078 by (simp add: linorder_not_less [symmetric], auto)
  1079 
  1080 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1081 by (subst mult_less_cancel1) simp
  1082 
  1083 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1084 by (subst mult_le_cancel1) simp
  1085 
  1086 lemma le_square: "m \<le> m * (m::nat)"
  1087   by (cases m) (auto intro: le_add1)
  1088 
  1089 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1090   by (cases m) (auto intro: le_add1)
  1091 
  1092 text {* Lemma for @{text gcd} *}
  1093 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1094   apply (drule sym)
  1095   apply (rule disjCI)
  1096   apply (rule nat_less_cases, erule_tac [2] _)
  1097    apply (drule_tac [2] mult_less_mono2)
  1098     apply (auto)
  1099   done
  1100 
  1101 text {* the lattice order on @{typ nat} *}
  1102 
  1103 instantiation nat :: distrib_lattice
  1104 begin
  1105 
  1106 definition
  1107   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1108 
  1109 definition
  1110   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1111 
  1112 instance by intro_classes
  1113   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1114     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1115 
  1116 end
  1117 
  1118 
  1119 subsection {* Embedding of the Naturals into any
  1120   @{text semiring_1}: @{term of_nat} *}
  1121 
  1122 context semiring_1
  1123 begin
  1124 
  1125 primrec
  1126   of_nat :: "nat \<Rightarrow> 'a"
  1127 where
  1128   of_nat_0:     "of_nat 0 = 0"
  1129   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1130 
  1131 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1132   by simp
  1133 
  1134 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1135   by (induct m) (simp_all add: add_ac)
  1136 
  1137 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1138   by (induct m) (simp_all add: add_ac left_distrib)
  1139 
  1140 definition
  1141   of_nat_aux :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1142 where
  1143   [code func del]: "of_nat_aux n i = of_nat n + i"
  1144 
  1145 lemma of_nat_aux_code [code]:
  1146   "of_nat_aux 0 i = i"
  1147   "of_nat_aux (Suc n) i = of_nat_aux n (i + 1)" -- {* tail recursive *}
  1148   by (simp_all add: of_nat_aux_def add_ac)
  1149 
  1150 lemma of_nat_code [code]:
  1151   "of_nat n = of_nat_aux n 0"
  1152   by (simp add: of_nat_aux_def)
  1153 
  1154 end
  1155 
  1156 text{*Class for unital semirings with characteristic zero.
  1157  Includes non-ordered rings like the complex numbers.*}
  1158 
  1159 class semiring_char_0 = semiring_1 +
  1160   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1161 begin
  1162 
  1163 text{*Special cases where either operand is zero*}
  1164 
  1165 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1166   by (rule of_nat_eq_iff [of 0, simplified])
  1167 
  1168 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1169   by (rule of_nat_eq_iff [of _ 0, simplified])
  1170 
  1171 lemma inj_of_nat: "inj of_nat"
  1172   by (simp add: inj_on_def)
  1173 
  1174 end
  1175 
  1176 context ordered_semidom
  1177 begin
  1178 
  1179 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1180   apply (induct m, simp_all)
  1181   apply (erule order_trans)
  1182   apply (rule ord_le_eq_trans [OF _ add_commute])
  1183   apply (rule less_add_one [THEN less_imp_le])
  1184   done
  1185 
  1186 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1187   apply (induct m n rule: diff_induct, simp_all)
  1188   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1189   done
  1190 
  1191 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1192   apply (induct m n rule: diff_induct, simp_all)
  1193   apply (insert zero_le_imp_of_nat)
  1194   apply (force simp add: not_less [symmetric])
  1195   done
  1196 
  1197 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1198   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1199 
  1200 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1201   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1202 
  1203 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1204 
  1205 subclass semiring_char_0
  1206   by unfold_locales (simp add: eq_iff order_eq_iff)
  1207 
  1208 text{*Special cases where either operand is zero*}
  1209 
  1210 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1211   by (rule of_nat_le_iff [of 0, simplified])
  1212 
  1213 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1214   by (rule of_nat_le_iff [of _ 0, simplified])
  1215 
  1216 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1217   by (rule of_nat_less_iff [of 0, simplified])
  1218 
  1219 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1220   by (rule of_nat_less_iff [of _ 0, simplified])
  1221 
  1222 end
  1223 
  1224 context ring_1
  1225 begin
  1226 
  1227 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1228   by (simp add: compare_rls of_nat_add [symmetric])
  1229 
  1230 end
  1231 
  1232 context ordered_idom
  1233 begin
  1234 
  1235 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1236   unfolding abs_if by auto
  1237 
  1238 end
  1239 
  1240 lemma of_nat_id [simp]: "of_nat n = n"
  1241   by (induct n) auto
  1242 
  1243 lemma of_nat_eq_id [simp]: "of_nat = id"
  1244   by (auto simp add: expand_fun_eq)
  1245 
  1246 
  1247 subsection {* The Set of Natural Numbers *}
  1248 
  1249 context semiring_1
  1250 begin
  1251 
  1252 definition
  1253   Nats  :: "'a set" where
  1254   [code func del]: "Nats = range of_nat"
  1255 
  1256 notation (xsymbols)
  1257   Nats  ("\<nat>")
  1258 
  1259 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1260   by (simp add: Nats_def)
  1261 
  1262 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1263 apply (simp add: Nats_def)
  1264 apply (rule range_eqI)
  1265 apply (rule of_nat_0 [symmetric])
  1266 done
  1267 
  1268 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1269 apply (simp add: Nats_def)
  1270 apply (rule range_eqI)
  1271 apply (rule of_nat_1 [symmetric])
  1272 done
  1273 
  1274 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1275 apply (auto simp add: Nats_def)
  1276 apply (rule range_eqI)
  1277 apply (rule of_nat_add [symmetric])
  1278 done
  1279 
  1280 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1281 apply (auto simp add: Nats_def)
  1282 apply (rule range_eqI)
  1283 apply (rule of_nat_mult [symmetric])
  1284 done
  1285 
  1286 end
  1287 
  1288 
  1289 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1290 
  1291 lemma subst_equals:
  1292   assumes 1: "t = s" and 2: "u = t"
  1293   shows "u = s"
  1294   using 2 1 by (rule trans)
  1295 
  1296 use "arith_data.ML"
  1297 declaration {* K ArithData.setup *}
  1298 
  1299 use "Tools/lin_arith.ML"
  1300 declaration {* K LinArith.setup *}
  1301 
  1302 lemmas [arith_split] = nat_diff_split split_min split_max
  1303 
  1304 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1305 
  1306 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1307 by arith
  1308 
  1309 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1310 by arith
  1311 
  1312 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1313 by arith
  1314 
  1315 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1316 by arith
  1317 
  1318 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1319 by arith
  1320 
  1321 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1322 by arith
  1323 
  1324 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1325   second premise n\<le>m*)
  1326 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1327 by arith
  1328 
  1329 text {* Simplification of relational expressions involving subtraction *}
  1330 
  1331 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1332 by (simp split add: nat_diff_split)
  1333 
  1334 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1335 by (auto split add: nat_diff_split)
  1336 
  1337 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1338 by (auto split add: nat_diff_split)
  1339 
  1340 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1341 by (auto split add: nat_diff_split)
  1342 
  1343 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1344 
  1345 (* Monotonicity of subtraction in first argument *)
  1346 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1347 by (simp split add: nat_diff_split)
  1348 
  1349 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1350 by (simp split add: nat_diff_split)
  1351 
  1352 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1353 by (simp split add: nat_diff_split)
  1354 
  1355 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1356 by (simp split add: nat_diff_split)
  1357 
  1358 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1359 unfolding min_def by auto
  1360 
  1361 lemma inj_on_diff_nat: 
  1362   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1363   shows "inj_on (\<lambda>n. n - k) N"
  1364 proof (rule inj_onI)
  1365   fix x y
  1366   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1367   with k_le_n have "x - k + k = y - k + k" by auto
  1368   with a k_le_n show "x = y" by auto
  1369 qed
  1370 
  1371 text{*Rewriting to pull differences out*}
  1372 
  1373 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1374 by arith
  1375 
  1376 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1377 by arith
  1378 
  1379 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1380 by arith
  1381 
  1382 text{*Lemmas for ex/Factorization*}
  1383 
  1384 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1385 by (cases m) auto
  1386 
  1387 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1388 by (cases m) auto
  1389 
  1390 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1391 by (cases m) auto
  1392 
  1393 text {* Specialized induction principles that work "backwards": *}
  1394 
  1395 lemma inc_induct[consumes 1, case_names base step]:
  1396   assumes less: "i <= j"
  1397   assumes base: "P j"
  1398   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1399   shows "P i"
  1400   using less
  1401 proof (induct d=="j - i" arbitrary: i)
  1402   case (0 i)
  1403   hence "i = j" by simp
  1404   with base show ?case by simp
  1405 next
  1406   case (Suc d i)
  1407   hence "i < j" "P (Suc i)"
  1408     by simp_all
  1409   thus "P i" by (rule step)
  1410 qed
  1411 
  1412 lemma strict_inc_induct[consumes 1, case_names base step]:
  1413   assumes less: "i < j"
  1414   assumes base: "!!i. j = Suc i ==> P i"
  1415   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1416   shows "P i"
  1417   using less
  1418 proof (induct d=="j - i - 1" arbitrary: i)
  1419   case (0 i)
  1420   with `i < j` have "j = Suc i" by simp
  1421   with base show ?case by simp
  1422 next
  1423   case (Suc d i)
  1424   hence "i < j" "P (Suc i)"
  1425     by simp_all
  1426   thus "P i" by (rule step)
  1427 qed
  1428 
  1429 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1430   using inc_induct[of "k - i" k P, simplified] by blast
  1431 
  1432 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1433   using inc_induct[of 0 k P] by blast
  1434 
  1435 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1436   by auto
  1437 
  1438 (*The others are
  1439       i - j - k = i - (j + k),
  1440       k \<le> j ==> j - k + i = j + i - k,
  1441       k \<le> j ==> i + (j - k) = i + j - k *)
  1442 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1443 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1444 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1445 
  1446 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1447 Least_Suc}, since there appears to be no need.*}
  1448 
  1449 subsection {* size of a datatype value *}
  1450 
  1451 class size = type +
  1452   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1453 
  1454 end