src/Pure/library.ML
author wenzelm
Sat Apr 16 18:55:51 2005 +0200 (2005-04-16)
changeset 15745 33bb955b2e73
parent 15696 1da4ce092c0b
child 15760 1ca99038c847
permissions -rw-r--r--
added gen_remove, remove;
usual arrangement BasicLibrary: BASIC_LIBRARY and Library: LIBRARY;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Munich
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*stamps*)
    35   type stamp
    36   val stamp: unit -> stamp
    37 
    38   (*options*)
    39   val is_none: 'a option -> bool
    40 
    41   (*old options -- invalidated*)
    42   datatype invalid = None of invalid
    43   exception OPTION of invalid
    44 
    45   exception ERROR
    46   val try: ('a -> 'b) -> 'a -> 'b option
    47   val can: ('a -> 'b) -> 'a -> bool
    48   datatype 'a result = Result of 'a | Exn of exn
    49   val capture: ('a -> 'b) -> 'a -> 'b result
    50   val release: 'a result -> 'a
    51   val get_result: 'a result -> 'a option
    52   val get_exn: 'a result -> exn option
    53 
    54   (*pairs*)
    55   val pair: 'a -> 'b -> 'a * 'b
    56   val rpair: 'a -> 'b -> 'b * 'a
    57   val fst: 'a * 'b -> 'a
    58   val snd: 'a * 'b -> 'b
    59   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    60   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78   val conditional: bool -> (unit -> unit) -> unit
    79 
    80   (*lists*)
    81   exception UnequalLengths
    82   val cons: 'a -> 'a list -> 'a list
    83   val single: 'a -> 'a list
    84   val append: 'a list -> 'a list -> 'a list
    85   val apply: ('a -> 'a) list -> 'a -> 'a
    86   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    87   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    88   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    89   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    90   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val unflat: 'a list list -> 'b list -> 'b list list
    92   val splitAt: int * 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val split_last: 'a list -> 'a list * 'a
    96   val nth_update: 'a -> int * 'a list -> 'a list
    97   val find_index: ('a -> bool) -> 'a list -> int
    98   val find_index_eq: ''a -> ''a list -> int
    99   val find_first: ('a -> bool) -> 'a list -> 'a option
   100   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   101   val separate: 'a -> 'a list -> 'a list
   102   val replicate: int -> 'a -> 'a list
   103   val multiply: 'a list * 'a list list -> 'a list list
   104   val product: 'a list -> 'b list -> ('a * 'b) list
   105   val filter_out: ('a -> bool) -> 'a list -> 'a list
   106   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   107   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   108   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val prefix: ''a list * ''a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val gcd: int * int -> int
   121   val lcm: int * int -> int
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val downto0: int list * int -> bool
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131     (* CB: note alternative Syntax.string_of_vname has nicer syntax *)
   132   val read_radixint: int * string list -> int * string list
   133   val read_int: string list -> int * string list
   134   val oct_char: string -> string
   135 
   136   (*rational numbers*)
   137   type rat
   138   exception RAT of string
   139   val rep_rat: rat -> int * int
   140   val ratadd: rat * rat -> rat
   141   val ratmul: rat * rat -> rat
   142   val ratinv: rat -> rat
   143   val int_ratdiv: int * int -> rat
   144   val ratneg: rat -> rat
   145   val rat_of_int: int -> rat
   146 
   147   (*strings*)
   148   val nth_elem_string: int * string -> string
   149   val foldl_string: ('a * string -> 'a) -> 'a * string -> 'a
   150   val exists_string: (string -> bool) -> string -> bool
   151   val enclose: string -> string -> string -> string
   152   val unenclose: string -> string
   153   val quote: string -> string
   154   val space_implode: string -> string list -> string
   155   val commas: string list -> string
   156   val commas_quote: string list -> string
   157   val cat_lines: string list -> string
   158   val space_explode: string -> string -> string list
   159   val split_lines: string -> string list
   160   val prefix_lines: string -> string -> string
   161   val untabify: string list -> string list
   162   val suffix: string -> string -> string
   163   val unsuffix: string -> string -> string
   164   val unprefix: string -> string -> string
   165   val replicate_string: int -> string -> string
   166   val translate_string: (string -> string) -> string -> string
   167 
   168   (*lists as sets*)
   169   val mem: ''a * ''a list -> bool
   170   val mem_int: int * int list -> bool
   171   val mem_string: string * string list -> bool
   172   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   173   val ins: ''a * ''a list -> ''a list
   174   val ins_int: int * int list -> int list
   175   val ins_string: string * string list -> string list
   176   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   177   val union: ''a list * ''a list -> ''a list
   178   val union_int: int list * int list -> int list
   179   val union_string: string list * string list -> string list
   180   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   181   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   182   val inter: ''a list * ''a list -> ''a list
   183   val inter_int: int list * int list -> int list
   184   val inter_string: string list * string list -> string list
   185   val subset: ''a list * ''a list -> bool
   186   val subset_int: int list * int list -> bool
   187   val subset_string: string list * string list -> bool
   188   val eq_set: ''a list * ''a list -> bool
   189   val eq_set_string: string list * string list -> bool
   190   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   191   val \ : ''a list * ''a -> ''a list
   192   val \\ : ''a list * ''a list -> ''a list
   193   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   194   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   195   val gen_remove: ('a * 'b -> bool) -> 'b -> 'a list -> 'a list
   196   val remove: ''a -> ''a list -> ''a list
   197   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   198   val distinct: ''a list -> ''a list
   199   val findrep: ''a list -> ''a list
   200   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   201   val duplicates: ''a list -> ''a list
   202 
   203   (*association lists*)
   204   val assoc: (''a * 'b) list * ''a -> 'b option
   205   val assoc_int: (int * 'a) list * int -> 'a option
   206   val assoc_string: (string * 'a) list * string -> 'a option
   207   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   208   val assocs: (''a * 'b list) list -> ''a -> 'b list
   209   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   210   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   211   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   212   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   213 
   214   (*lists as tables*)
   215   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   216   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   217   val merge_lists: ''a list -> ''a list -> ''a list
   218   val merge_lists': ''a list -> ''a list -> ''a list
   219   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   220   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   221 
   222   (*balanced trees*)
   223   exception Balance
   224   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   225   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   226   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   227 
   228   (*orders*)
   229   val rev_order: order -> order
   230   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   231   val int_ord: int * int -> order
   232   val string_ord: string * string -> order
   233   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   234   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   235   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   236   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   237   val sort_strings: string list -> string list
   238   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   239   val unique_strings: string list -> string list
   240 
   241   (*random numbers*)
   242   exception RANDOM
   243   val random: unit -> real
   244   val random_range: int -> int -> int
   245   val one_of: 'a list -> 'a
   246   val frequency: (int * 'a) list -> 'a
   247 
   248   (*current directory*)
   249   val cd: string -> unit
   250   val pwd: unit -> string
   251 
   252   (*misc*)
   253   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   254   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   255   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   256   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   257   val gensym: string -> string
   258   val scanwords: (string -> bool) -> string list -> string list
   259 end;
   260 
   261 signature LIBRARY =
   262 sig
   263   include BASIC_LIBRARY
   264 
   265   val the: 'a option -> 'a
   266   val if_none: 'a option -> 'a -> 'a
   267   val is_some: 'a option -> bool
   268   val apsome: ('a -> 'b) -> 'a option -> 'b option
   269 
   270   val rev_append: 'a list -> 'a list -> 'a list
   271   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   272   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   273   val take: int * 'a list -> 'a list
   274   val drop: int * 'a list -> 'a list
   275   val nth_elem: int * 'a list -> 'a
   276   val last_elem: 'a list -> 'a
   277   val flat: 'a list list -> 'a list
   278   val seq: ('a -> unit) -> 'a list -> unit
   279   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   280   val filter: ('a -> bool) -> 'a list -> 'a list
   281   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   282 end;
   283 
   284 structure Library: LIBRARY =
   285 struct
   286 
   287 
   288 (** functions **)
   289 
   290 (*handy combinators*)
   291 fun curry f x y = f (x, y);
   292 fun uncurry f (x, y) = f x y;
   293 fun I x = x;
   294 fun K x y = x;
   295 
   296 (*reverse apply*)
   297 fun (x |> f) = f x;
   298 fun ((x, y) |>> f) = (f x, y);
   299 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   300 
   301 (*application of (infix) operator to its left or right argument*)
   302 fun apl (x, f) y = f (x, y);
   303 fun apr (f, y) x = f (x, y);
   304 
   305 (*function exponentiation: f(...(f x)...) with n applications of f*)
   306 fun funpow n f x =
   307   let fun rep (0, x) = x
   308         | rep (n, x) = rep (n - 1, f x)
   309   in rep (n, x) end;
   310 
   311 (*concatenation: 2 and 3 args*)
   312 fun (f oo g) x y = f (g x y);
   313 fun (f ooo g) x y z = f (g x y z);
   314 fun (f oooo g) x y z w = f (g x y z w);
   315 
   316 
   317 
   318 (** stamps **)
   319 
   320 type stamp = unit ref;
   321 val stamp: unit -> stamp = ref;
   322 
   323 
   324 
   325 (** options **)
   326 
   327 val the = valOf;
   328 fun if_none opt a = getOpt (opt, a);
   329 val is_some = isSome;
   330 fun is_none opt = not (isSome opt);
   331 val apsome = Option.map;
   332 
   333 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   334 datatype invalid = None of invalid;
   335 exception OPTION of invalid;
   336 
   337 
   338 (* exception handling *)
   339 
   340 exception ERROR;
   341 
   342 fun try f x = SOME (f x)
   343   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   344 
   345 fun can f x = is_some (try f x);
   346 
   347 
   348 datatype 'a result =
   349   Result of 'a |
   350   Exn of exn;
   351 
   352 fun capture f x = Result (f x) handle e => Exn e;
   353 
   354 fun release (Result y) = y
   355   | release (Exn e) = raise e;
   356 
   357 fun get_result (Result x) = SOME x
   358   | get_result _ = NONE;
   359 
   360 fun get_exn (Exn exn) = SOME exn
   361   | get_exn _ = NONE;
   362 
   363 
   364 
   365 (** pairs **)
   366 
   367 fun pair x y = (x, y);
   368 fun rpair x y = (y, x);
   369 
   370 fun fst (x, y) = x;
   371 fun snd (x, y) = y;
   372 
   373 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   374 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   375 
   376 fun swap (x, y) = (y, x);
   377 
   378 (*apply function to components*)
   379 fun apfst f (x, y) = (f x, y);
   380 fun apsnd f (x, y) = (x, f y);
   381 fun pairself f (x, y) = (f x, f y);
   382 
   383 
   384 
   385 (** booleans **)
   386 
   387 (* equality *)
   388 
   389 fun equal x y = x = y;
   390 fun not_equal x y = x <> y;
   391 
   392 
   393 (* operators for combining predicates *)
   394 
   395 fun (p orf q) = fn x => p x orelse q x;
   396 fun (p andf q) = fn x => p x andalso q x;
   397 
   398 
   399 (* predicates on lists *)
   400 
   401 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   402 fun exists (pred: 'a -> bool) : 'a list -> bool =
   403   let fun boolf [] = false
   404         | boolf (x :: xs) = pred x orelse boolf xs
   405   in boolf end;
   406 
   407 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   408 fun forall (pred: 'a -> bool) : 'a list -> bool =
   409   let fun boolf [] = true
   410         | boolf (x :: xs) = pred x andalso boolf xs
   411   in boolf end;
   412 
   413 
   414 (* flags *)
   415 
   416 fun set flag = (flag := true; true);
   417 fun reset flag = (flag := false; false);
   418 fun toggle flag = (flag := not (! flag); ! flag);
   419 
   420 fun change r f = r := f (! r);
   421 
   422 (*temporarily set flag, handling exceptions*)
   423 fun setmp flag value f x =
   424   let
   425     val orig_value = ! flag;
   426     fun return y = (flag := orig_value; y);
   427   in
   428     flag := value;
   429     return (f x handle exn => (return (); raise exn))
   430   end;
   431 
   432 
   433 (* conditional execution *)
   434 
   435 fun conditional b f = if b then f () else ();
   436 
   437 
   438 
   439 (** lists **)
   440 
   441 exception UnequalLengths;
   442 
   443 fun cons x xs = x :: xs;
   444 fun single x = [x];
   445 
   446 fun append xs ys = xs @ ys;
   447 
   448 (* tail recursive version *)
   449 fun rev_append xs ys = List.revAppend(xs,ys);
   450 
   451 fun apply [] x = x
   452   | apply (f :: fs) x = apply fs (f x);
   453 
   454 
   455 (* fold *)
   456 
   457 (*the following versions of fold are designed to fit nicely with infixes*)
   458 
   459 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   460     for operators that associate to the left (TAIL RECURSIVE)*)
   461 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   462   let fun itl (e, [])  = e
   463         | itl (e, a::l) = itl (f(e, a), l)
   464   in  itl end;
   465 
   466 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   467     for operators that associate to the right (not tail recursive)*)
   468 fun foldr f (l, e) =
   469   let fun itr [] = e
   470         | itr (a::l) = f(a, itr l)
   471   in  itr l  end;
   472 
   473 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   474     for n > 0, operators that associate to the right (not tail recursive)*)
   475 fun foldr1 f l =
   476   let fun itr [x] = x
   477         | itr (x::l) = f(x, itr l)
   478   in  itr l  end;
   479 
   480 fun fold f xs y = foldl (fn (y', x) => f x y') (y, xs);
   481 fun fold_rev f xs y = foldr (fn (x, y') => f x y') (xs, y);
   482 
   483 fun foldl_map _ (x, []) = (x, [])
   484   | foldl_map f (x, y :: ys) =
   485       let
   486         val (x', y') = f (x, y);
   487         val (x'', ys') = foldl_map f (x', ys);
   488       in (x'', y' :: ys') end;
   489 
   490 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   491 
   492 (* basic list functions *)
   493 
   494 (*take the first n elements from a list*)
   495 fun take (n, []) = []
   496   | take (n, x :: xs) =
   497       if n > 0 then x :: take (n - 1, xs) else [];
   498 
   499 (*drop the first n elements from a list*)
   500 fun drop (n, []) = []
   501   | drop (n, x :: xs) =
   502       if n > 0 then drop (n - 1, xs) else x :: xs;
   503 
   504 fun splitAt(n,[]) = ([],[])
   505   | splitAt(n,xs as x::ys) =
   506       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   507       else ([],xs)
   508 
   509 fun dropwhile P [] = []
   510   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   511 
   512 (*return nth element of a list, where 0 designates the first element;
   513   raise EXCEPTION if list too short*)
   514 fun nth_elem (i,xs) = List.nth(xs,i);
   515 
   516 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   517   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   518   | map_nth_elem _ _ [] = raise Subscript;
   519 
   520 (*last element of a list*)
   521 val last_elem = List.last;
   522 
   523 (*rear decomposition*)
   524 fun split_last [] = raise Empty
   525   | split_last [x] = ([], x)
   526   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   527 
   528 (*update nth element*)
   529 fun nth_update x n_xs =
   530     (case splitAt n_xs of
   531       (_,[]) => raise Subscript
   532     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   533 
   534 (*find the position of an element in a list*)
   535 fun find_index pred =
   536   let fun find _ [] = ~1
   537         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   538   in find 0 end;
   539 
   540 fun find_index_eq x = find_index (equal x);
   541 
   542 (*find first element satisfying predicate*)
   543 fun find_first _ [] = NONE
   544   | find_first pred (x :: xs) =
   545       if pred x then SOME x else find_first pred xs;
   546 
   547 (*get first element by lookup function*)
   548 fun get_first _ [] = NONE
   549   | get_first f (x :: xs) =
   550       (case f x of
   551         NONE => get_first f xs
   552       | some => some);
   553 
   554 (*flatten a list of lists to a list*)
   555 val flat = List.concat;
   556 
   557 fun unflat (xs :: xss) ys =
   558       let val (ps,qs) = splitAt(length xs,ys)
   559       in ps :: unflat xss qs end
   560   | unflat [] [] = []
   561   | unflat _ _ = raise UnequalLengths;
   562 
   563 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   564   (proc x1; ...; proc xn) for side effects*)
   565 val seq = List.app;
   566 
   567 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   568 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   569   | separate _ xs = xs;
   570 
   571 (*make the list [x, x, ..., x] of length n*)
   572 fun replicate n (x: 'a) : 'a list =
   573   let fun rep (0, xs) = xs
   574         | rep (n, xs) = rep (n - 1, x :: xs)
   575   in
   576     if n < 0 then raise Subscript
   577     else rep (n, [])
   578   end;
   579 
   580 fun translate_string f = String.translate (f o String.str);
   581 
   582 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   583 fun multiply ([], _) = []
   584   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   585 
   586 (*direct product*)
   587 fun product _ [] = []
   588   | product [] _ = []
   589   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   590 
   591 
   592 (* filter *)
   593 
   594 (*copy the list preserving elements that satisfy the predicate*)
   595 val filter = List.filter;
   596 fun filter_out f = filter (not o f);
   597 val mapfilter = List.mapPartial;
   598 
   599 
   600 (* lists of pairs *)
   601 
   602 exception UnequalLengths;
   603 
   604 fun map2 _ ([], []) = []
   605   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   606   | map2 _ _ = raise UnequalLengths;
   607 
   608 fun exists2 _ ([], []) = false
   609   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   610   | exists2 _ _ = raise UnequalLengths;
   611 
   612 fun forall2 _ ([], []) = true
   613   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   614   | forall2 _ _ = raise UnequalLengths;
   615 
   616 fun seq2 _ ([], []) = ()
   617   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   618   | seq2 _ _ = raise UnequalLengths;
   619 
   620 (*combine two lists forming a list of pairs:
   621   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   622 fun [] ~~ [] = []
   623   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   624   | _ ~~ _ = raise UnequalLengths;
   625 
   626 (*inverse of ~~; the old 'split':
   627   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   628 val split_list = ListPair.unzip;
   629 
   630 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   631 
   632 
   633 (* prefixes, suffixes *)
   634 
   635 fun [] prefix _ = true
   636   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   637   | _ prefix _ = false;
   638 
   639 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   640    where xi is the first element that does not satisfy the predicate*)
   641 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   642   let fun take (rxs, []) = (rev rxs, [])
   643         | take (rxs, x :: xs) =
   644             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   645   in  take([], xs)  end;
   646 
   647 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   648    where xi is the last element that does not satisfy the predicate*)
   649 fun take_suffix _ [] = ([], [])
   650   | take_suffix pred (x :: xs) =
   651       (case take_suffix pred xs of
   652         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   653       | (prfx, sffx) => (x :: prfx, sffx));
   654 
   655 fun prefixes1 [] = []
   656   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   657 
   658 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   659 
   660 
   661 
   662 (** integers **)
   663 
   664 fun gcd(x,y) =
   665   let fun gxd x y =
   666     if y = 0 then x else gxd y (x mod y)
   667   in if x < y then gxd y x else gxd x y end;
   668 
   669 fun lcm(x,y) = (x * y) div gcd(x,y);
   670 
   671 fun inc i = (i := ! i + 1; ! i);
   672 fun dec i = (i := ! i - 1; ! i);
   673 
   674 
   675 (* lists of integers *)
   676 
   677 (*make the list [from, from + 1, ..., to]*)
   678 fun (from upto to) =
   679   if from > to then [] else from :: ((from + 1) upto to);
   680 
   681 (*make the list [from, from - 1, ..., to]*)
   682 fun (from downto to) =
   683   if from < to then [] else from :: ((from - 1) downto to);
   684 
   685 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   686 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   687   | downto0 ([], n) = n = ~1;
   688 
   689 
   690 (* convert integers to strings *)
   691 
   692 (*expand the number in the given base;
   693   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   694 fun radixpand (base, num) : int list =
   695   let
   696     fun radix (n, tail) =
   697       if n < base then n :: tail
   698       else radix (n div base, (n mod base) :: tail)
   699   in radix (num, []) end;
   700 
   701 (*expands a number into a string of characters starting from "zerochar";
   702   example: radixstring (2, "0", 8) gives "1000"*)
   703 fun radixstring (base, zerochar, num) =
   704   let val offset = ord zerochar;
   705       fun chrof n = chr (offset + n)
   706   in implode (map chrof (radixpand (base, num))) end;
   707 
   708 
   709 val string_of_int = Int.toString;
   710 
   711 fun string_of_indexname (a,0) = a
   712   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   713 
   714 
   715 (* read integers *)
   716 
   717 fun read_radixint (radix: int, cs) : int * string list =
   718   let val zero = ord"0"
   719       val limit = zero+radix
   720       fun scan (num,[]) = (num,[])
   721         | scan (num, c::cs) =
   722               if  zero <= ord c  andalso  ord c < limit
   723               then scan(radix*num + ord c - zero, cs)
   724               else (num, c::cs)
   725   in  scan(0,cs)  end;
   726 
   727 fun read_int cs = read_radixint (10, cs);
   728 
   729 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   730 
   731 
   732 
   733 (** strings **)
   734 
   735 (*functions tuned for strings, avoiding explode*)
   736 
   737 fun nth_elem_string (i, str) =
   738   (case try String.substring (str, i, 1) of
   739     SOME s => s
   740   | NONE => raise Subscript);
   741 
   742 fun foldl_string f (x0, str) =
   743   let
   744     val n = size str;
   745     fun fold (x, i) =
   746       if i < n then fold (f (x, String.substring (str, i, 1)), i + 1) else x;
   747   in fold (x0, 0) end;
   748 
   749 fun exists_string pred str =
   750   let
   751     val n = size str;
   752     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   753   in ex 0 end;
   754 
   755 (*enclose in brackets*)
   756 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   757 fun unenclose str = String.substring (str, 1, size str - 2);
   758 
   759 (*simple quoting (does not escape special chars)*)
   760 val quote = enclose "\"" "\"";
   761 
   762 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   763 fun space_implode a bs = implode (separate a bs);
   764 
   765 val commas = space_implode ", ";
   766 val commas_quote = commas o map quote;
   767 
   768 (*concatenate messages, one per line, into a string*)
   769 val cat_lines = space_implode "\n";
   770 
   771 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   772 fun space_explode _ "" = []
   773   | space_explode sep str =
   774       let
   775         fun expl chs =
   776           (case take_prefix (not_equal sep) chs of
   777             (cs, []) => [implode cs]
   778           | (cs, _ :: cs') => implode cs :: expl cs');
   779       in expl (explode str) end;
   780 
   781 val split_lines = space_explode "\n";
   782 
   783 fun prefix_lines "" txt = txt
   784   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   785 
   786 (*untabify*)
   787 fun untabify chs =
   788   let
   789     val tab_width = 8;
   790 
   791     fun untab (_, "\n") = (0, ["\n"])
   792       | untab (pos, "\t") =
   793           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   794       | untab (pos, c) = (pos + 1, [c]);
   795   in
   796     if not (exists (equal "\t") chs) then chs
   797     else flat (#2 (foldl_map untab (0, chs)))
   798   end;
   799 
   800 (*append suffix*)
   801 fun suffix sfx s = s ^ sfx;
   802 
   803 (*remove suffix*)
   804 fun unsuffix sfx s =
   805   let
   806     val cs = explode s;
   807     val prfx_len = size s - size sfx;
   808   in
   809     if prfx_len >= 0 andalso implode (drop (prfx_len, cs)) = sfx then
   810       implode (take (prfx_len, cs))
   811     else raise Fail "unsuffix"
   812   end;
   813 
   814 (*remove prefix*)
   815 fun unprefix prfx s =
   816   let val (prfx', sfx) = splitAt (size prfx, explode s)
   817   in
   818     if implode prfx' = prfx then implode sfx
   819     else raise Fail "unprefix"
   820   end;
   821 
   822 fun replicate_string 0 _ = ""
   823   | replicate_string 1 a = a
   824   | replicate_string k a =
   825       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   826       else replicate_string (k div 2) (a ^ a) ^ a;
   827 
   828 
   829 
   830 (** lists as sets **)
   831 
   832 (*membership in a list*)
   833 fun x mem [] = false
   834   | x mem (y :: ys) = x = y orelse x mem ys;
   835 
   836 (*membership in a list, optimized version for ints*)
   837 fun (x:int) mem_int [] = false
   838   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   839 
   840 (*membership in a list, optimized version for strings*)
   841 fun (x:string) mem_string [] = false
   842   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   843 
   844 (*generalized membership test*)
   845 fun gen_mem eq (x, []) = false
   846   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   847 
   848 
   849 (*insertion into list if not already there*)
   850 fun (x ins xs) = if x mem xs then xs else x :: xs;
   851 
   852 (*insertion into list, optimized version for ints*)
   853 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   854 
   855 (*insertion into list, optimized version for strings*)
   856 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   857 
   858 (*generalized insertion*)
   859 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   860 
   861 
   862 (*union of sets represented as lists: no repetitions*)
   863 fun xs union [] = xs
   864   | [] union ys = ys
   865   | (x :: xs) union ys = xs union (x ins ys);
   866 
   867 (*union of sets, optimized version for ints*)
   868 fun (xs:int list) union_int [] = xs
   869   | [] union_int ys = ys
   870   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   871 
   872 (*union of sets, optimized version for strings*)
   873 fun (xs:string list) union_string [] = xs
   874   | [] union_string ys = ys
   875   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   876 
   877 (*generalized union*)
   878 fun gen_union eq (xs, []) = xs
   879   | gen_union eq ([], ys) = ys
   880   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   881 
   882 
   883 (*intersection*)
   884 fun [] inter ys = []
   885   | (x :: xs) inter ys =
   886       if x mem ys then x :: (xs inter ys) else xs inter ys;
   887 
   888 (*intersection, optimized version for ints*)
   889 fun ([]:int list) inter_int ys = []
   890   | (x :: xs) inter_int ys =
   891       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   892 
   893 (*intersection, optimized version for strings *)
   894 fun ([]:string list) inter_string ys = []
   895   | (x :: xs) inter_string ys =
   896       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   897 
   898 (*generalized intersection*)
   899 fun gen_inter eq ([], ys) = []
   900   | gen_inter eq (x::xs, ys) =
   901       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   902                            else      gen_inter eq (xs, ys);
   903 
   904 
   905 (*subset*)
   906 fun [] subset ys = true
   907   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   908 
   909 (*subset, optimized version for ints*)
   910 fun ([]:int list) subset_int ys = true
   911   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   912 
   913 (*subset, optimized version for strings*)
   914 fun ([]:string list) subset_string ys = true
   915   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   916 
   917 (*set equality*)
   918 fun eq_set (xs, ys) =
   919   xs = ys orelse (xs subset ys andalso ys subset xs);
   920 
   921 (*set equality for strings*)
   922 fun eq_set_string ((xs:string list), ys) =
   923   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   924 
   925 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   926 
   927 
   928 (*removing an element from a list WITHOUT duplicates*)
   929 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   930   | [] \ x = [];
   931 
   932 fun ys \\ xs = foldl (op \) (ys,xs);
   933 
   934 (*removing an element from a list -- possibly WITH duplicates*)
   935 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   936 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   937 
   938 fun gen_remove eq x xs = gen_rem eq (xs, x);
   939 fun remove x xs = gen_rem (op =) (xs, x);
   940 
   941 (*makes a list of the distinct members of the input; preserves order, takes
   942   first of equal elements*)
   943 fun gen_distinct eq lst =
   944   let
   945     val memb = gen_mem eq;
   946 
   947     fun dist (rev_seen, []) = rev rev_seen
   948       | dist (rev_seen, x :: xs) =
   949           if memb (x, rev_seen) then dist (rev_seen, xs)
   950           else dist (x :: rev_seen, xs);
   951   in
   952     dist ([], lst)
   953   end;
   954 
   955 fun distinct l = gen_distinct (op =) l;
   956 
   957 
   958 (*returns the tail beginning with the first repeated element, or []*)
   959 fun findrep [] = []
   960   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   961 
   962 
   963 (*returns a list containing all repeated elements exactly once; preserves
   964   order, takes first of equal elements*)
   965 fun gen_duplicates eq lst =
   966   let
   967     val memb = gen_mem eq;
   968 
   969     fun dups (rev_dups, []) = rev rev_dups
   970       | dups (rev_dups, x :: xs) =
   971           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   972             dups (rev_dups, xs)
   973           else dups (x :: rev_dups, xs);
   974   in
   975     dups ([], lst)
   976   end;
   977 
   978 fun duplicates l = gen_duplicates (op =) l;
   979 
   980 
   981 
   982 (** association lists **)
   983 
   984 (*association list lookup*)
   985 fun assoc ([], key) = NONE
   986   | assoc ((keyi, xi) :: pairs, key) =
   987       if key = keyi then SOME xi else assoc (pairs, key);
   988 
   989 (*association list lookup, optimized version for ints*)
   990 fun assoc_int ([], (key:int)) = NONE
   991   | assoc_int ((keyi, xi) :: pairs, key) =
   992       if key = keyi then SOME xi else assoc_int (pairs, key);
   993 
   994 (*association list lookup, optimized version for strings*)
   995 fun assoc_string ([], (key:string)) = NONE
   996   | assoc_string ((keyi, xi) :: pairs, key) =
   997       if key = keyi then SOME xi else assoc_string (pairs, key);
   998 
   999 (*association list lookup, optimized version for string*ints*)
  1000 fun assoc_string_int ([], (key:string*int)) = NONE
  1001   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1002       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1003 
  1004 fun assocs ps x =
  1005   (case assoc (ps, x) of
  1006     NONE => []
  1007   | SOME ys => ys);
  1008 
  1009 (*two-fold association list lookup*)
  1010 fun assoc2 (aal, (key1, key2)) =
  1011   (case assoc (aal, key1) of
  1012     SOME al => assoc (al, key2)
  1013   | NONE => NONE);
  1014 
  1015 (*generalized association list lookup*)
  1016 fun gen_assoc eq ([], key) = NONE
  1017   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1018       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1019 
  1020 (*association list update*)
  1021 fun overwrite (al, p as (key, _)) =
  1022   let fun over ((q as (keyi, _)) :: pairs) =
  1023             if keyi = key then p :: pairs else q :: (over pairs)
  1024         | over [] = [p]
  1025   in over al end;
  1026 
  1027 fun gen_overwrite eq (al, p as (key, _)) =
  1028   let fun over ((q as (keyi, _)) :: pairs) =
  1029             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1030         | over [] = [p]
  1031   in over al end;
  1032 
  1033 
  1034 (* lists as tables *)
  1035 
  1036 fun gen_merge_lists _ xs [] = xs
  1037   | gen_merge_lists _ [] ys = ys
  1038   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1039 
  1040 fun gen_merge_lists' _ xs [] = xs
  1041   | gen_merge_lists' _ [] ys = ys
  1042   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1043 
  1044 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1045 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1046 fun merge_alists al = gen_merge_lists eq_fst al;
  1047 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1048 
  1049 
  1050 
  1051 (** balanced trees **)
  1052 
  1053 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1054 
  1055 (*balanced folding; avoids deep nesting*)
  1056 fun fold_bal f [x] = x
  1057   | fold_bal f [] = raise Balance
  1058   | fold_bal f xs =
  1059       let val (ps,qs) = splitAt(length xs div 2, xs)
  1060       in  f (fold_bal f ps, fold_bal f qs)  end;
  1061 
  1062 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1063 fun access_bal (f, g, x) n i =
  1064   let fun acc n i =     (*1<=i<=n*)
  1065           if n=1 then x else
  1066           let val n2 = n div 2
  1067           in  if i<=n2 then f (acc n2 i)
  1068                        else g (acc (n-n2) (i-n2))
  1069           end
  1070   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1071 
  1072 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1073 fun accesses_bal (f, g, x) n =
  1074   let fun acc n =
  1075           if n=1 then [x] else
  1076           let val n2 = n div 2
  1077               val acc2 = acc n2
  1078           in  if n-n2=n2 then map f acc2 @ map g acc2
  1079                          else map f acc2 @ map g (acc (n-n2)) end
  1080   in  if 1<=n then acc n else raise Balance  end;
  1081 
  1082 
  1083 
  1084 (** orders **)
  1085 
  1086 fun rev_order LESS = GREATER
  1087   | rev_order EQUAL = EQUAL
  1088   | rev_order GREATER = LESS;
  1089 
  1090 (*assume rel is a linear strict order*)
  1091 fun make_ord rel (x, y) =
  1092   if rel (x, y) then LESS
  1093   else if rel (y, x) then GREATER
  1094   else EQUAL;
  1095 
  1096 val int_ord = Int.compare;
  1097 val string_ord = String.compare;
  1098 
  1099 (*lexicographic product*)
  1100 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1101   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1102 
  1103 (*dictionary order -- in general NOT well-founded!*)
  1104 fun dict_ord _ ([], []) = EQUAL
  1105   | dict_ord _ ([], _ :: _) = LESS
  1106   | dict_ord _ (_ :: _, []) = GREATER
  1107   | dict_ord elem_ord (x :: xs, y :: ys) =
  1108       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1109 
  1110 (*lexicographic product of lists*)
  1111 fun list_ord elem_ord (xs, ys) =
  1112   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
  1113 
  1114 
  1115 (* sorting *)
  1116 
  1117 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1118 fun sort ord =
  1119   let
  1120     fun qsort xs =
  1121       let val len = length xs in
  1122         if len <= 1 then xs
  1123         else
  1124           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1125             qsort lts @ eqs @ qsort gts
  1126           end
  1127       end
  1128     and part _ [] = ([], [], [])
  1129       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1130     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1131       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1132       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1133   in qsort end;
  1134 
  1135 (*sort strings*)
  1136 val sort_strings = sort string_ord;
  1137 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1138 
  1139 fun unique_strings ([]: string list) = []
  1140   | unique_strings [x] = [x]
  1141   | unique_strings (x :: y :: ys) =
  1142       if x = y then unique_strings (y :: ys)
  1143       else x :: unique_strings (y :: ys);
  1144 
  1145 
  1146 (** random numbers **)
  1147 
  1148 exception RANDOM;
  1149 
  1150 fun rmod x y = x - y * Real.realFloor (x / y);
  1151 
  1152 local
  1153   val a = 16807.0;
  1154   val m = 2147483647.0;
  1155   val random_seed = ref 1.0;
  1156 in
  1157 
  1158 fun random () =
  1159   let val r = rmod (a * !random_seed) m
  1160   in (random_seed := r; r) end;
  1161 
  1162 end;
  1163 
  1164 fun random_range l h =
  1165   if h < l orelse l < 0 then raise RANDOM
  1166   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1167 
  1168 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1169 
  1170 fun frequency xs =
  1171   let
  1172     val sum = foldl op + (0, map fst xs);
  1173     fun pick n ((k, x) :: xs) =
  1174       if n <= k then x else pick (n - k) xs
  1175   in pick (random_range 1 sum) xs end;
  1176 
  1177 
  1178 (** current directory **)
  1179 
  1180 val cd = OS.FileSys.chDir;
  1181 val pwd = OS.FileSys.getDir;
  1182 
  1183 
  1184 
  1185 (** rational numbers **)
  1186 
  1187 datatype rat = Rat of bool * int * int
  1188 
  1189 exception RAT of string;
  1190 
  1191 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1192 
  1193 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1194   let val absp = abs p
  1195       val m = gcd(absp,q)
  1196   in Rat(a = (0 <= p), absp div m, q div m) end;
  1197 
  1198 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1199   let val den = lcm(q,s)
  1200       val p = p*(den div q) and r = r*(den div s)
  1201       val num = (if a then p else ~p) + (if b then r else ~r)
  1202   in ratnorm(true,num,den) end;
  1203 
  1204 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1205 
  1206 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1207 
  1208 fun int_ratdiv(p,q) =
  1209   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1210 
  1211 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1212 
  1213 fun rat_of_int i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1214 
  1215 
  1216 (** misc **)
  1217 
  1218 (*use the keyfun to make a list of (x, key) pairs*)
  1219 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1220   let fun keypair x = (x, keyfun x)
  1221   in map keypair end;
  1222 
  1223 (*given a list of (x, key) pairs and a searchkey
  1224   return the list of xs from each pair whose key equals searchkey*)
  1225 fun keyfilter [] searchkey = []
  1226   | keyfilter ((x, key) :: pairs) searchkey =
  1227       if key = searchkey then x :: keyfilter pairs searchkey
  1228       else keyfilter pairs searchkey;
  1229 
  1230 
  1231 (*Partition list into elements that satisfy predicate and those that don't.
  1232   Preserves order of elements in both lists.*)
  1233 val partition = List.partition;
  1234 
  1235 
  1236 fun partition_eq (eq:'a * 'a -> bool) =
  1237     let fun part [] = []
  1238           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1239                            in (x::xs)::(part xs') end
  1240     in part end;
  1241 
  1242 
  1243 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1244    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1245 fun partition_list p i j =
  1246   let fun part k xs =
  1247             if k>j then
  1248               (case xs of [] => []
  1249                          | _ => raise Fail "partition_list")
  1250             else
  1251             let val (ns, rest) = partition (p k) xs;
  1252             in  ns :: part(k+1)rest  end
  1253   in  part i end;
  1254 
  1255 
  1256 (* generating identifiers *)
  1257 
  1258 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1259 local
  1260 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1261 fun char i =      if i<26 then chr (ord "A" + i)
  1262              else if i<52 then chr (ord "a" + i - 26)
  1263              else if i<62 then chr (ord"0" + i - 52)
  1264              else if i=62 then "_"
  1265              else  (*i=63*)    "'";
  1266 
  1267 val charVec = Vector.tabulate (64, char);
  1268 
  1269 fun newid n =
  1270   let
  1271   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1272 
  1273 val seedr = ref 0;
  1274 
  1275 in
  1276 
  1277 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1278 
  1279 end;
  1280 
  1281 
  1282 (* lexical scanning *)
  1283 
  1284 (*scan a list of characters into "words" composed of "letters" (recognized by
  1285   is_let) and separated by any number of non-"letters"*)
  1286 fun scanwords is_let cs =
  1287   let fun scan1 [] = []
  1288         | scan1 cs =
  1289             let val (lets, rest) = take_prefix is_let cs
  1290             in implode lets :: scanwords is_let rest end;
  1291   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1292 
  1293 
  1294 end;
  1295 
  1296 structure BasicLibrary: BASIC_LIBRARY = Library;
  1297 open BasicLibrary;