src/Pure/library.ML
author wenzelm
Wed Jul 06 10:41:38 2005 +0200 (2005-07-06)
changeset 16705 33f38450cab6
parent 16694 f8ca69762221
child 16721 e2427ea379a9
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |-> |>> ||> |>>> ||>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    26   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    29   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    30   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    31   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    34   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    35   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    36 
    37   (*old options -- invalidated*)
    38   datatype invalid = None of invalid
    39   exception OPTION of invalid
    40 
    41   (*options*)
    42   val the: 'a option -> 'a
    43   val if_none: 'a option -> 'a -> 'a
    44   val is_some: 'a option -> bool
    45   val is_none: 'a option -> bool
    46 
    47   exception ERROR
    48   val try: ('a -> 'b) -> 'a -> 'b option
    49   val can: ('a -> 'b) -> 'a -> bool
    50   datatype 'a result = Result of 'a | Exn of exn
    51   val capture: ('a -> 'b) -> 'a -> 'b result
    52   val release: 'a result -> 'a
    53   val get_result: 'a result -> 'a option
    54   val get_exn: 'a result -> exn option
    55 
    56   (*pairs*)
    57   val pair: 'a -> 'b -> 'a * 'b
    58   val rpair: 'a -> 'b -> 'b * 'a
    59   val fst: 'a * 'b -> 'a
    60   val snd: 'a * 'b -> 'b
    61   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    62   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    63   val swap: 'a * 'b -> 'b * 'a
    64   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    65   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    66   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    67 
    68   (*booleans*)
    69   val equal: ''a -> ''a -> bool
    70   val not_equal: ''a -> ''a -> bool
    71   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    72   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    73   val exists: ('a -> bool) -> 'a list -> bool
    74   val forall: ('a -> bool) -> 'a list -> bool
    75   val set: bool ref -> bool
    76   val reset: bool ref -> bool
    77   val toggle: bool ref -> bool
    78   val change: 'a ref -> ('a -> 'a) -> unit
    79   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    80   val conditional: bool -> (unit -> unit) -> unit
    81 
    82   (*lists*)
    83   exception UnequalLengths
    84   val cons: 'a -> 'a list -> 'a list
    85   val single: 'a -> 'a list
    86   val append: 'a list -> 'a list -> 'a list
    87   val apply: ('a -> 'a) list -> 'a -> 'a
    88   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    89   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
    91   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    92   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    93   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    94   val unflat: 'a list list -> 'b list -> 'b list list
    95   val splitAt: int * 'a list -> 'a list * 'a list
    96   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    97   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    98   val split_last: 'a list -> 'a list * 'a
    99   val nth_update: 'a -> int * 'a list -> 'a list
   100   val find_index: ('a -> bool) -> 'a list -> int
   101   val find_index_eq: ''a -> ''a list -> int
   102   val find_first: ('a -> bool) -> 'a list -> 'a option
   103   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   104   val separate: 'a -> 'a list -> 'a list
   105   val replicate: int -> 'a -> 'a list
   106   val multiply: 'a list * 'a list list -> 'a list list
   107   val product: 'a list -> 'b list -> ('a * 'b) list
   108   val filter: ('a -> bool) -> 'a list -> 'a list
   109   val filter_out: ('a -> bool) -> 'a list -> 'a list
   110   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   111   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   112   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   114   val ~~ : 'a list * 'b list -> ('a * 'b) list
   115   val split_list: ('a * 'b) list -> 'a list * 'b list
   116   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   117   val prefix: ''a list * ''a list -> bool
   118   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   119   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   120   val prefixes1: 'a list -> 'a list list
   121   val suffixes1: 'a list -> 'a list list
   122 
   123   (*integers*)
   124   val gcd: IntInf.int * IntInf.int -> IntInf.int
   125   val lcm: IntInf.int * IntInf.int -> IntInf.int
   126   val inc: int ref -> int
   127   val dec: int ref -> int
   128   val upto: int * int -> int list
   129   val downto: int * int -> int list
   130   val downto0: int list * int -> bool
   131   val radixpand: int * int -> int list
   132   val radixstring: int * string * int -> string
   133   val string_of_int: int -> string
   134   val string_of_indexname: string * int -> string
   135   val read_radixint: int * string list -> int * string list
   136   val read_int: string list -> int * string list
   137   val oct_char: string -> string
   138 
   139   (*rational numbers*)
   140   type rat
   141   exception RAT of string
   142   val rep_rat: rat -> IntInf.int * IntInf.int
   143   val ratadd: rat * rat -> rat
   144   val ratmul: rat * rat -> rat
   145   val ratinv: rat -> rat
   146   val int_ratdiv: IntInf.int * IntInf.int -> rat
   147   val ratneg: rat -> rat
   148   val rat_of_int: int -> rat
   149   val rat_of_intinf: IntInf.int -> rat
   150 
   151   (*strings*)
   152   val nth_elem_string: int * string -> string
   153   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   154   val exists_string: (string -> bool) -> string -> bool
   155   val forall_string: (string -> bool) -> string -> bool
   156   val enclose: string -> string -> string -> string
   157   val unenclose: string -> string
   158   val quote: string -> string
   159   val space_implode: string -> string list -> string
   160   val commas: string list -> string
   161   val commas_quote: string list -> string
   162   val cat_lines: string list -> string
   163   val space_explode: string -> string -> string list
   164   val split_lines: string -> string list
   165   val prefix_lines: string -> string -> string
   166   val untabify: string list -> string list
   167   val suffix: string -> string -> string
   168   val unsuffix: string -> string -> string
   169   val unprefix: string -> string -> string
   170   val replicate_string: int -> string -> string
   171   val translate_string: (string -> string) -> string -> string
   172 
   173   (*lists as sets -- see also Pure/General/ord_list.ML*)
   174   val mem: ''a * ''a list -> bool
   175   val mem_int: int * int list -> bool
   176   val mem_string: string * string list -> bool
   177   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   178   val ins: ''a * ''a list -> ''a list
   179   val ins_int: int * int list -> int list
   180   val ins_string: string * string list -> string list
   181   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   182   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   183   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   184   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   185   val union: ''a list * ''a list -> ''a list
   186   val union_int: int list * int list -> int list
   187   val union_string: string list * string list -> string list
   188   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   189   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   190   val inter: ''a list * ''a list -> ''a list
   191   val inter_int: int list * int list -> int list
   192   val inter_string: string list * string list -> string list
   193   val subset: ''a list * ''a list -> bool
   194   val subset_int: int list * int list -> bool
   195   val subset_string: string list * string list -> bool
   196   val eq_set: ''a list * ''a list -> bool
   197   val eq_set_string: string list * string list -> bool
   198   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   199   val \ : ''a list * ''a -> ''a list
   200   val \\ : ''a list * ''a list -> ''a list
   201   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   202   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   203   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   204   val distinct: ''a list -> ''a list
   205   val findrep: ''a list -> ''a list
   206   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   207   val duplicates: ''a list -> ''a list
   208 
   209   (*association lists*)
   210   val assoc: (''a * 'b) list * ''a -> 'b option
   211   val assoc_int: (int * 'a) list * int -> 'a option
   212   val assoc_string: (string * 'a) list * string -> 'a option
   213   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   214   val assocs: (''a * 'b list) list -> ''a -> 'b list
   215   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   216   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   217   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   218   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   219 
   220   (*lists as tables*)
   221   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   222   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   223   val merge_lists: ''a list -> ''a list -> ''a list
   224   val merge_lists': ''a list -> ''a list -> ''a list
   225   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   226   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   227 
   228   (*balanced trees*)
   229   exception Balance
   230   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   231   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   232   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   233 
   234   (*orders*)
   235   val rev_order: order -> order
   236   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   237   val int_ord: int * int -> order
   238   val string_ord: string * string -> order
   239   val fast_string_ord: string * string -> order
   240   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   241   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   242   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   243   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   244   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   245   val sort_strings: string list -> string list
   246   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   247   val unique_strings: string list -> string list
   248 
   249   (*random numbers*)
   250   exception RANDOM
   251   val random: unit -> real
   252   val random_range: int -> int -> int
   253   val one_of: 'a list -> 'a
   254   val frequency: (int * 'a) list -> 'a
   255 
   256   (*current directory*)
   257   val cd: string -> unit
   258   val pwd: unit -> string
   259 
   260   (*misc*)
   261   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   262   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   263   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   264   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   265   val gensym: string -> string
   266   val scanwords: (string -> bool) -> string list -> string list
   267   type stamp
   268   val stamp: unit -> stamp
   269   type serial
   270   val serial: unit -> serial
   271   structure Object: sig type T end
   272 end;
   273 
   274 signature LIBRARY =
   275 sig
   276   include BASIC_LIBRARY
   277   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   278   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   279   val take: int * 'a list -> 'a list
   280   val drop: int * 'a list -> 'a list
   281   val nth_elem: int * 'a list -> 'a
   282   val last_elem: 'a list -> 'a
   283   val flat: 'a list list -> 'a list
   284   val seq: ('a -> unit) -> 'a list -> unit
   285   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   286   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   287 end;
   288 
   289 structure Library: LIBRARY =
   290 struct
   291 
   292 
   293 (** functions **)
   294 
   295 (*handy combinators*)
   296 fun curry f x y = f (x, y);
   297 fun uncurry f (x, y) = f x y;
   298 fun I x = x;
   299 fun K x = fn y => x;
   300 
   301 (*reverse application and structured results*)
   302 fun x |> f = f x;
   303 fun (x, y) |-> f = f x y;
   304 fun (x, y) |>> f = (f x, y);
   305 fun (x, y) ||> f = (x, f y);
   306 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   307 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   308 
   309 (*application of (infix) operator to its left or right argument*)
   310 fun apl (x, f) y = f (x, y);
   311 fun apr (f, y) x = f (x, y);
   312 
   313 (*function exponentiation: f(...(f x)...) with n applications of f*)
   314 fun funpow n f x =
   315   let fun rep (0, x) = x
   316         | rep (n, x) = rep (n - 1, f x)
   317   in rep (n, x) end;
   318 
   319 (*concatenation: 2 and 3 args*)
   320 fun (f oo g) x y = f (g x y);
   321 fun (f ooo g) x y z = f (g x y z);
   322 fun (f oooo g) x y z w = f (g x y z w);
   323 
   324 
   325 
   326 (** options **)
   327 
   328 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   329 datatype invalid = None of invalid;
   330 exception OPTION of invalid;
   331 
   332 val the = Option.valOf;
   333 
   334 (*strict!*)
   335 fun if_none NONE y = y
   336   | if_none (SOME x) _ = x;
   337 
   338 fun is_some (SOME _) = true
   339   | is_some NONE = false;
   340 
   341 fun is_none (SOME _) = false
   342   | is_none NONE = true;
   343 
   344 
   345 (* exception handling *)
   346 
   347 exception ERROR;
   348 
   349 fun try f x = SOME (f x)
   350   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   351 
   352 fun can f x = is_some (try f x);
   353 
   354 
   355 datatype 'a result =
   356   Result of 'a |
   357   Exn of exn;
   358 
   359 fun capture f x = Result (f x) handle e => Exn e;
   360 
   361 fun release (Result y) = y
   362   | release (Exn e) = raise e;
   363 
   364 fun get_result (Result x) = SOME x
   365   | get_result _ = NONE;
   366 
   367 fun get_exn (Exn exn) = SOME exn
   368   | get_exn _ = NONE;
   369 
   370 
   371 
   372 (** pairs **)
   373 
   374 fun pair x y = (x, y);
   375 fun rpair x y = (y, x);
   376 
   377 fun fst (x, y) = x;
   378 fun snd (x, y) = y;
   379 
   380 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   381 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   382 
   383 fun swap (x, y) = (y, x);
   384 
   385 (*apply function to components*)
   386 fun apfst f (x, y) = (f x, y);
   387 fun apsnd f (x, y) = (x, f y);
   388 fun pairself f (x, y) = (f x, f y);
   389 
   390 
   391 
   392 (** booleans **)
   393 
   394 (* equality *)
   395 
   396 fun equal x y = x = y;
   397 fun not_equal x y = x <> y;
   398 
   399 
   400 (* operators for combining predicates *)
   401 
   402 fun (p orf q) = fn x => p x orelse q x;
   403 fun (p andf q) = fn x => p x andalso q x;
   404 
   405 
   406 (* predicates on lists *)
   407 
   408 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   409 fun exists (pred: 'a -> bool) : 'a list -> bool =
   410   let fun boolf [] = false
   411         | boolf (x :: xs) = pred x orelse boolf xs
   412   in boolf end;
   413 
   414 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   415 fun forall (pred: 'a -> bool) : 'a list -> bool =
   416   let fun boolf [] = true
   417         | boolf (x :: xs) = pred x andalso boolf xs
   418   in boolf end;
   419 
   420 
   421 (* flags *)
   422 
   423 fun set flag = (flag := true; true);
   424 fun reset flag = (flag := false; false);
   425 fun toggle flag = (flag := not (! flag); ! flag);
   426 
   427 fun change r f = r := f (! r);
   428 
   429 (*temporarily set flag, handling exceptions*)
   430 fun setmp flag value f x =
   431   let
   432     val orig_value = ! flag;
   433     fun return y = (flag := orig_value; y);
   434   in
   435     flag := value;
   436     return (f x handle exn => (return (); raise exn))
   437   end;
   438 
   439 
   440 (* conditional execution *)
   441 
   442 fun conditional b f = if b then f () else ();
   443 
   444 
   445 
   446 (** lists **)
   447 
   448 exception UnequalLengths;
   449 
   450 fun cons x xs = x :: xs;
   451 fun single x = [x];
   452 
   453 fun append xs ys = xs @ ys;
   454 
   455 fun apply [] x = x
   456   | apply (f :: fs) x = apply fs (f x);
   457 
   458 
   459 (* fold *)
   460 
   461 fun fold f =
   462   let
   463     fun fold_aux [] y = y
   464       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   465   in fold_aux end;
   466 
   467 fun fold_rev f =
   468   let
   469     fun fold_aux [] y = y
   470       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   471   in fold_aux end;
   472 
   473 fun fold_map f = 
   474   let
   475     fun fold_aux [] y = ([], y)
   476       | fold_aux (x :: xs) y =
   477           let
   478             val (x', y') = f x y;
   479             val (xs', y'') = fold_aux xs y';
   480           in (x' :: xs', y'') end;
   481   in fold_aux end;
   482 
   483 (*the following versions of fold are designed to fit nicely with infixes*)
   484 
   485 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   486     for operators that associate to the left (TAIL RECURSIVE)*)
   487 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   488   let fun itl (e, [])  = e
   489         | itl (e, a::l) = itl (f(e, a), l)
   490   in  itl end;
   491 
   492 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   493     for operators that associate to the right (not tail recursive)*)
   494 fun foldr f (l, e) =
   495   let fun itr [] = e
   496         | itr (a::l) = f(a, itr l)
   497   in  itr l  end;
   498 
   499 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   500     for n > 0, operators that associate to the right (not tail recursive)*)
   501 fun foldr1 f l =
   502   let fun itr [x] = x
   503         | itr (x::l) = f(x, itr l)
   504   in  itr l  end;
   505 
   506 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   507 
   508 fun foldl_map f =
   509   let
   510     fun fold_aux (x, []) = (x, [])
   511       | fold_aux (x, y :: ys) =
   512           let
   513             val (x', y') = f (x, y);
   514             val (x'', ys') = fold_aux (x', ys);
   515           in (x'', y' :: ys') end;
   516   in fold_aux end;
   517 
   518 
   519 (* basic list functions *)
   520 
   521 (*take the first n elements from a list*)
   522 fun take (n, []) = []
   523   | take (n, x :: xs) =
   524       if n > 0 then x :: take (n - 1, xs) else [];
   525 
   526 (*drop the first n elements from a list*)
   527 fun drop (n, []) = []
   528   | drop (n, x :: xs) =
   529       if n > 0 then drop (n - 1, xs) else x :: xs;
   530 
   531 fun splitAt(n,[]) = ([],[])
   532   | splitAt(n,xs as x::ys) =
   533       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   534       else ([],xs)
   535 
   536 fun dropwhile P [] = []
   537   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   538 
   539 (*return nth element of a list, where 0 designates the first element;
   540   raise EXCEPTION if list too short*)
   541 fun nth_elem (i,xs) = List.nth(xs,i);
   542 
   543 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   544   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   545   | map_nth_elem _ _ [] = raise Subscript;
   546 
   547 (*last element of a list*)
   548 val last_elem = List.last;
   549 
   550 (*rear decomposition*)
   551 fun split_last [] = raise Empty
   552   | split_last [x] = ([], x)
   553   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   554 
   555 (*update nth element*)
   556 fun nth_update x n_xs =
   557     (case splitAt n_xs of
   558       (_,[]) => raise Subscript
   559     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   560 
   561 (*find the position of an element in a list*)
   562 fun find_index pred =
   563   let fun find _ [] = ~1
   564         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   565   in find 0 end;
   566 
   567 fun find_index_eq x = find_index (equal x);
   568 
   569 (*find first element satisfying predicate*)
   570 fun find_first _ [] = NONE
   571   | find_first pred (x :: xs) =
   572       if pred x then SOME x else find_first pred xs;
   573 
   574 (*get first element by lookup function*)
   575 fun get_first _ [] = NONE
   576   | get_first f (x :: xs) =
   577       (case f x of
   578         NONE => get_first f xs
   579       | some => some);
   580 
   581 (*flatten a list of lists to a list*)
   582 val flat = List.concat;
   583 
   584 fun unflat (xs :: xss) ys =
   585       let val (ps,qs) = splitAt(length xs,ys)
   586       in ps :: unflat xss qs end
   587   | unflat [] [] = []
   588   | unflat _ _ = raise UnequalLengths;
   589 
   590 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   591   (proc x1; ...; proc xn) for side effects*)
   592 val seq = List.app;
   593 
   594 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   595 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   596   | separate _ xs = xs;
   597 
   598 (*make the list [x, x, ..., x] of length n*)
   599 fun replicate n (x: 'a) : 'a list =
   600   let fun rep (0, xs) = xs
   601         | rep (n, xs) = rep (n - 1, x :: xs)
   602   in
   603     if n < 0 then raise Subscript
   604     else rep (n, [])
   605   end;
   606 
   607 fun translate_string f = String.translate (f o String.str);
   608 
   609 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   610 fun multiply ([], _) = []
   611   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   612 
   613 (*direct product*)
   614 fun product _ [] = []
   615   | product [] _ = []
   616   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   617 
   618 
   619 (* filter *)
   620 
   621 (*copy the list preserving elements that satisfy the predicate*)
   622 val filter = List.filter;
   623 fun filter_out f = filter (not o f);
   624 val mapfilter = List.mapPartial;
   625 
   626 
   627 (* lists of pairs *)
   628 
   629 exception UnequalLengths;
   630 
   631 fun map2 _ ([], []) = []
   632   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   633   | map2 _ _ = raise UnequalLengths;
   634 
   635 fun exists2 _ ([], []) = false
   636   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   637   | exists2 _ _ = raise UnequalLengths;
   638 
   639 fun forall2 _ ([], []) = true
   640   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   641   | forall2 _ _ = raise UnequalLengths;
   642 
   643 fun seq2 _ ([], []) = ()
   644   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   645   | seq2 _ _ = raise UnequalLengths;
   646 
   647 (*combine two lists forming a list of pairs:
   648   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   649 fun [] ~~ [] = []
   650   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   651   | _ ~~ _ = raise UnequalLengths;
   652 
   653 (*inverse of ~~; the old 'split':
   654   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   655 val split_list = ListPair.unzip;
   656 
   657 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   658 
   659 
   660 (* prefixes, suffixes *)
   661 
   662 fun [] prefix _ = true
   663   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   664   | _ prefix _ = false;
   665 
   666 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   667    where xi is the first element that does not satisfy the predicate*)
   668 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   669   let fun take (rxs, []) = (rev rxs, [])
   670         | take (rxs, x :: xs) =
   671             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   672   in  take([], xs)  end;
   673 
   674 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   675    where xi is the last element that does not satisfy the predicate*)
   676 fun take_suffix _ [] = ([], [])
   677   | take_suffix pred (x :: xs) =
   678       (case take_suffix pred xs of
   679         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   680       | (prfx, sffx) => (x :: prfx, sffx));
   681 
   682 fun prefixes1 [] = []
   683   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   684 
   685 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   686 
   687 
   688 
   689 (** integers **)
   690 
   691 fun gcd (x, y) =
   692   let fun gxd x y : IntInf.int =
   693     if y = 0 then x else gxd y (x mod y)
   694   in if x < y then gxd y x else gxd x y end;
   695 
   696 fun lcm (x, y) = (x * y) div gcd (x, y);
   697 
   698 fun inc i = (i := ! i + 1; ! i);
   699 fun dec i = (i := ! i - 1; ! i);
   700 
   701 
   702 (* lists of integers *)
   703 
   704 (*make the list [from, from + 1, ..., to]*)
   705 fun (from upto to) =
   706   if from > to then [] else from :: ((from + 1) upto to);
   707 
   708 (*make the list [from, from - 1, ..., to]*)
   709 fun (from downto to) =
   710   if from < to then [] else from :: ((from - 1) downto to);
   711 
   712 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   713 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   714   | downto0 ([], n) = n = ~1;
   715 
   716 
   717 (* convert integers to strings *)
   718 
   719 (*expand the number in the given base;
   720   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   721 fun radixpand (base, num) : int list =
   722   let
   723     fun radix (n, tail) =
   724       if n < base then n :: tail
   725       else radix (n div base, (n mod base) :: tail)
   726   in radix (num, []) end;
   727 
   728 (*expands a number into a string of characters starting from "zerochar";
   729   example: radixstring (2, "0", 8) gives "1000"*)
   730 fun radixstring (base, zerochar, num) =
   731   let val offset = ord zerochar;
   732       fun chrof n = chr (offset + n)
   733   in implode (map chrof (radixpand (base, num))) end;
   734 
   735 
   736 val string_of_int = Int.toString;
   737 
   738 fun string_of_indexname (a,0) = a
   739   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   740 
   741 
   742 (* read integers *)
   743 
   744 fun read_radixint (radix: int, cs) : int * string list =
   745   let val zero = ord"0"
   746       val limit = zero+radix
   747       fun scan (num,[]) = (num,[])
   748         | scan (num, c::cs) =
   749               if  zero <= ord c  andalso  ord c < limit
   750               then scan(radix*num + ord c - zero, cs)
   751               else (num, c::cs)
   752   in  scan(0,cs)  end;
   753 
   754 fun read_int cs = read_radixint (10, cs);
   755 
   756 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   757 
   758 
   759 
   760 (** strings **)
   761 
   762 (* functions tuned for strings, avoiding explode *)
   763 
   764 fun nth_elem_string (i, str) =
   765   (case try String.substring (str, i, 1) of
   766     SOME s => s
   767   | NONE => raise Subscript);
   768 
   769 fun fold_string f str x0 =
   770   let
   771     val n = size str;
   772     fun iter (x, i) =
   773       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   774   in iter (x0, 0) end;
   775 
   776 fun exists_string pred str =
   777   let
   778     val n = size str;
   779     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   780   in ex 0 end;
   781 
   782 fun forall_string pred = not o exists_string (not o pred);
   783 
   784 (*enclose in brackets*)
   785 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   786 fun unenclose str = String.substring (str, 1, size str - 2);
   787 
   788 (*simple quoting (does not escape special chars)*)
   789 val quote = enclose "\"" "\"";
   790 
   791 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   792 fun space_implode a bs = implode (separate a bs);
   793 
   794 val commas = space_implode ", ";
   795 val commas_quote = commas o map quote;
   796 
   797 (*concatenate messages, one per line, into a string*)
   798 val cat_lines = space_implode "\n";
   799 
   800 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   801 fun space_explode _ "" = []
   802   | space_explode sep str =
   803       let
   804         fun expl chs =
   805           (case take_prefix (not_equal sep) chs of
   806             (cs, []) => [implode cs]
   807           | (cs, _ :: cs') => implode cs :: expl cs');
   808       in expl (explode str) end;
   809 
   810 val split_lines = space_explode "\n";
   811 
   812 fun prefix_lines "" txt = txt
   813   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   814 
   815 fun untabify chs =
   816   let
   817     val tab_width = 8;
   818 
   819     fun untab (_, "\n") = (0, ["\n"])
   820       | untab (pos, "\t") =
   821           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   822       | untab (pos, c) = (pos + 1, [c]);
   823   in
   824     if not (exists (equal "\t") chs) then chs
   825     else flat (#2 (foldl_map untab (0, chs)))
   826   end;
   827 
   828 fun suffix sffx s = s ^ sffx;
   829 
   830 fun unsuffix sffx s =
   831   let val m = size sffx; val n = size s - m in
   832     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   833     else raise Fail "unsuffix"
   834   end;
   835 
   836 fun unprefix prfx s =
   837   let val m = size prfx; val n = size s - m in
   838     if String.isPrefix prfx s then String.substring (s, m, n)
   839     else raise Fail "unprefix"
   840   end;
   841 
   842 fun replicate_string 0 _ = ""
   843   | replicate_string 1 a = a
   844   | replicate_string k a =
   845       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   846       else replicate_string (k div 2) (a ^ a) ^ a;
   847 
   848 
   849 
   850 (** lists as sets -- see also Pure/General/ord_list.ML **)
   851 
   852 (*membership in a list*)
   853 fun x mem [] = false
   854   | x mem (y :: ys) = x = y orelse x mem ys;
   855 
   856 (*membership in a list, optimized version for ints*)
   857 fun (x:int) mem_int [] = false
   858   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   859 
   860 (*membership in a list, optimized version for strings*)
   861 fun (x:string) mem_string [] = false
   862   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   863 
   864 (*generalized membership test*)
   865 fun gen_mem eq (x, []) = false
   866   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   867 
   868 (*member, insert, and remove -- with canonical argument order*)
   869 fun member eq xs x = gen_mem eq (x, xs);
   870 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   871 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   872 
   873 (*insertion into list if not already there*)
   874 fun (x ins xs) = if x mem xs then xs else x :: xs;
   875 
   876 (*insertion into list, optimized version for ints*)
   877 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   878 
   879 (*insertion into list, optimized version for strings*)
   880 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   881 
   882 (*generalized insertion*)
   883 fun gen_ins eq (x, xs) = insert eq x xs;
   884 
   885 (*union of sets represented as lists: no repetitions*)
   886 fun xs union [] = xs
   887   | [] union ys = ys
   888   | (x :: xs) union ys = xs union (x ins ys);
   889 
   890 (*union of sets, optimized version for ints*)
   891 fun (xs:int list) union_int [] = xs
   892   | [] union_int ys = ys
   893   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   894 
   895 (*union of sets, optimized version for strings*)
   896 fun (xs:string list) union_string [] = xs
   897   | [] union_string ys = ys
   898   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   899 
   900 (*generalized union*)
   901 fun gen_union eq (xs, []) = xs
   902   | gen_union eq ([], ys) = ys
   903   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   904 
   905 
   906 (*intersection*)
   907 fun [] inter ys = []
   908   | (x :: xs) inter ys =
   909       if x mem ys then x :: (xs inter ys) else xs inter ys;
   910 
   911 (*intersection, optimized version for ints*)
   912 fun ([]:int list) inter_int ys = []
   913   | (x :: xs) inter_int ys =
   914       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   915 
   916 (*intersection, optimized version for strings *)
   917 fun ([]:string list) inter_string ys = []
   918   | (x :: xs) inter_string ys =
   919       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   920 
   921 (*generalized intersection*)
   922 fun gen_inter eq ([], ys) = []
   923   | gen_inter eq (x::xs, ys) =
   924       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   925                            else      gen_inter eq (xs, ys);
   926 
   927 
   928 (*subset*)
   929 fun [] subset ys = true
   930   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   931 
   932 (*subset, optimized version for ints*)
   933 fun ([]: int list) subset_int ys = true
   934   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   935 
   936 (*subset, optimized version for strings*)
   937 fun ([]: string list) subset_string ys = true
   938   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   939 
   940 (*set equality*)
   941 fun eq_set (xs, ys) =
   942   xs = ys orelse (xs subset ys andalso ys subset xs);
   943 
   944 (*set equality for strings*)
   945 fun eq_set_string ((xs: string list), ys) =
   946   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   947 
   948 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   949 
   950 
   951 (*removing an element from a list WITHOUT duplicates*)
   952 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   953   | [] \ x = [];
   954 
   955 fun ys \\ xs = foldl (op \) (ys,xs);
   956 
   957 (*removing an element from a list -- possibly WITH duplicates*)
   958 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   959 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   960 
   961 (*makes a list of the distinct members of the input; preserves order, takes
   962   first of equal elements*)
   963 fun gen_distinct eq lst =
   964   let
   965     val memb = gen_mem eq;
   966 
   967     fun dist (rev_seen, []) = rev rev_seen
   968       | dist (rev_seen, x :: xs) =
   969           if memb (x, rev_seen) then dist (rev_seen, xs)
   970           else dist (x :: rev_seen, xs);
   971   in
   972     dist ([], lst)
   973   end;
   974 
   975 fun distinct l = gen_distinct (op =) l;
   976 
   977 
   978 (*returns the tail beginning with the first repeated element, or []*)
   979 fun findrep [] = []
   980   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   981 
   982 
   983 (*returns a list containing all repeated elements exactly once; preserves
   984   order, takes first of equal elements*)
   985 fun gen_duplicates eq lst =
   986   let
   987     val memb = gen_mem eq;
   988 
   989     fun dups (rev_dups, []) = rev rev_dups
   990       | dups (rev_dups, x :: xs) =
   991           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   992             dups (rev_dups, xs)
   993           else dups (x :: rev_dups, xs);
   994   in
   995     dups ([], lst)
   996   end;
   997 
   998 fun duplicates l = gen_duplicates (op =) l;
   999 
  1000 
  1001 
  1002 (** association lists **)
  1003 
  1004 (*association list lookup*)
  1005 fun assoc ([], key) = NONE
  1006   | assoc ((keyi, xi) :: pairs, key) =
  1007       if key = keyi then SOME xi else assoc (pairs, key);
  1008 
  1009 (*association list lookup, optimized version for ints*)
  1010 fun assoc_int ([], (key:int)) = NONE
  1011   | assoc_int ((keyi, xi) :: pairs, key) =
  1012       if key = keyi then SOME xi else assoc_int (pairs, key);
  1013 
  1014 (*association list lookup, optimized version for strings*)
  1015 fun assoc_string ([], (key:string)) = NONE
  1016   | assoc_string ((keyi, xi) :: pairs, key) =
  1017       if key = keyi then SOME xi else assoc_string (pairs, key);
  1018 
  1019 (*association list lookup, optimized version for string*ints*)
  1020 fun assoc_string_int ([], (key:string*int)) = NONE
  1021   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1022       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1023 
  1024 fun assocs ps x =
  1025   (case assoc (ps, x) of
  1026     NONE => []
  1027   | SOME ys => ys);
  1028 
  1029 (*two-fold association list lookup*)
  1030 fun assoc2 (aal, (key1, key2)) =
  1031   (case assoc (aal, key1) of
  1032     SOME al => assoc (al, key2)
  1033   | NONE => NONE);
  1034 
  1035 (*generalized association list lookup*)
  1036 fun gen_assoc eq ([], key) = NONE
  1037   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1038       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1039 
  1040 (*association list update*)
  1041 fun overwrite (al, p as (key, _)) =
  1042   let fun over ((q as (keyi, _)) :: pairs) =
  1043             if keyi = key then p :: pairs else q :: (over pairs)
  1044         | over [] = [p]
  1045   in over al end;
  1046 
  1047 fun gen_overwrite eq (al, p as (key, _)) =
  1048   let fun over ((q as (keyi, _)) :: pairs) =
  1049             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1050         | over [] = [p]
  1051   in over al end;
  1052 
  1053 
  1054 (* lists as tables *)
  1055 
  1056 fun gen_merge_lists _ xs [] = xs
  1057   | gen_merge_lists _ [] ys = ys
  1058   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1059 
  1060 fun gen_merge_lists' _ xs [] = xs
  1061   | gen_merge_lists' _ [] ys = ys
  1062   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1063 
  1064 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1065 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1066 fun merge_alists al = gen_merge_lists eq_fst al;
  1067 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1068 
  1069 
  1070 
  1071 (** balanced trees **)
  1072 
  1073 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1074 
  1075 (*balanced folding; avoids deep nesting*)
  1076 fun fold_bal f [x] = x
  1077   | fold_bal f [] = raise Balance
  1078   | fold_bal f xs =
  1079       let val (ps,qs) = splitAt(length xs div 2, xs)
  1080       in  f (fold_bal f ps, fold_bal f qs)  end;
  1081 
  1082 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1083 fun access_bal (f, g, x) n i =
  1084   let fun acc n i =     (*1<=i<=n*)
  1085           if n=1 then x else
  1086           let val n2 = n div 2
  1087           in  if i<=n2 then f (acc n2 i)
  1088                        else g (acc (n-n2) (i-n2))
  1089           end
  1090   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1091 
  1092 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1093 fun accesses_bal (f, g, x) n =
  1094   let fun acc n =
  1095           if n=1 then [x] else
  1096           let val n2 = n div 2
  1097               val acc2 = acc n2
  1098           in  if n-n2=n2 then map f acc2 @ map g acc2
  1099                          else map f acc2 @ map g (acc (n-n2)) end
  1100   in  if 1<=n then acc n else raise Balance  end;
  1101 
  1102 
  1103 
  1104 (** orders **)
  1105 
  1106 fun rev_order LESS = GREATER
  1107   | rev_order EQUAL = EQUAL
  1108   | rev_order GREATER = LESS;
  1109 
  1110 (*assume rel is a linear strict order*)
  1111 fun make_ord rel (x, y) =
  1112   if rel (x, y) then LESS
  1113   else if rel (y, x) then GREATER
  1114   else EQUAL;
  1115 
  1116 val int_ord = Int.compare;
  1117 val string_ord = String.compare;
  1118 
  1119 fun fast_string_ord (s1, s2) =
  1120   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1121 
  1122 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1123   | option_ord _ (NONE, NONE) = EQUAL
  1124   | option_ord _ (NONE, SOME _) = LESS
  1125   | option_ord _ (SOME _, NONE) = GREATER;
  1126 
  1127 (*lexicographic product*)
  1128 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1129   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1130 
  1131 (*dictionary order -- in general NOT well-founded!*)
  1132 fun dict_ord _ ([], []) = EQUAL
  1133   | dict_ord _ ([], _ :: _) = LESS
  1134   | dict_ord _ (_ :: _, []) = GREATER
  1135   | dict_ord elem_ord (x :: xs, y :: ys) =
  1136       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1137 
  1138 (*lexicographic product of lists*)
  1139 fun list_ord elem_ord (xs, ys) =
  1140   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1141 
  1142 
  1143 (* sorting *)
  1144 
  1145 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1146 fun sort ord =
  1147   let
  1148     fun qsort xs =
  1149       let val len = length xs in
  1150         if len <= 1 then xs
  1151         else
  1152           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1153             qsort lts @ eqs @ qsort gts
  1154           end
  1155       end
  1156     and part _ [] = ([], [], [])
  1157       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1158     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1159       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1160       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1161   in qsort end;
  1162 
  1163 (*sort strings*)
  1164 val sort_strings = sort string_ord;
  1165 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1166 
  1167 fun unique_strings ([]: string list) = []
  1168   | unique_strings [x] = [x]
  1169   | unique_strings (x :: y :: ys) =
  1170       if x = y then unique_strings (y :: ys)
  1171       else x :: unique_strings (y :: ys);
  1172 
  1173 
  1174 (** random numbers **)
  1175 
  1176 exception RANDOM;
  1177 
  1178 fun rmod x y = x - y * Real.realFloor (x / y);
  1179 
  1180 local
  1181   val a = 16807.0;
  1182   val m = 2147483647.0;
  1183   val random_seed = ref 1.0;
  1184 in
  1185 
  1186 fun random () =
  1187   let val r = rmod (a * !random_seed) m
  1188   in (random_seed := r; r) end;
  1189 
  1190 end;
  1191 
  1192 fun random_range l h =
  1193   if h < l orelse l < 0 then raise RANDOM
  1194   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1195 
  1196 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1197 
  1198 fun frequency xs =
  1199   let
  1200     val sum = foldl op + (0, map fst xs);
  1201     fun pick n ((k, x) :: xs) =
  1202       if n <= k then x else pick (n - k) xs
  1203   in pick (random_range 1 sum) xs end;
  1204 
  1205 
  1206 (** current directory **)
  1207 
  1208 val cd = OS.FileSys.chDir;
  1209 val pwd = OS.FileSys.getDir;
  1210 
  1211 
  1212 
  1213 (** rational numbers **)
  1214 
  1215 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1216 
  1217 exception RAT of string;
  1218 
  1219 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1220 
  1221 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1222   let val absp = abs p
  1223       val m = gcd(absp,q)
  1224   in Rat(a = (0 <= p), absp div m, q div m) end;
  1225 
  1226 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1227   let val den = lcm(q,s)
  1228       val p = p*(den div q) and r = r*(den div s)
  1229       val num = (if a then p else ~p) + (if b then r else ~r)
  1230   in ratnorm(true,num,den) end;
  1231 
  1232 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1233 
  1234 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1235 
  1236 fun int_ratdiv(p,q) =
  1237   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1238 
  1239 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1240 
  1241 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1242 
  1243 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1244 
  1245 
  1246 (** misc **)
  1247 
  1248 (*use the keyfun to make a list of (x, key) pairs*)
  1249 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1250   let fun keypair x = (x, keyfun x)
  1251   in map keypair end;
  1252 
  1253 (*given a list of (x, key) pairs and a searchkey
  1254   return the list of xs from each pair whose key equals searchkey*)
  1255 fun keyfilter [] searchkey = []
  1256   | keyfilter ((x, key) :: pairs) searchkey =
  1257       if key = searchkey then x :: keyfilter pairs searchkey
  1258       else keyfilter pairs searchkey;
  1259 
  1260 
  1261 (*Partition list into elements that satisfy predicate and those that don't.
  1262   Preserves order of elements in both lists.*)
  1263 val partition = List.partition;
  1264 
  1265 
  1266 fun partition_eq (eq:'a * 'a -> bool) =
  1267     let fun part [] = []
  1268           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1269                            in (x::xs)::(part xs') end
  1270     in part end;
  1271 
  1272 
  1273 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1274    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1275 fun partition_list p i j =
  1276   let fun part k xs =
  1277             if k>j then
  1278               (case xs of [] => []
  1279                          | _ => raise Fail "partition_list")
  1280             else
  1281             let val (ns, rest) = partition (p k) xs;
  1282             in  ns :: part(k+1)rest  end
  1283   in  part i end;
  1284 
  1285 
  1286 (* generating identifiers *)
  1287 
  1288 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1289 local
  1290 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1291 fun char i =      if i<26 then chr (ord "A" + i)
  1292              else if i<52 then chr (ord "a" + i - 26)
  1293              else if i<62 then chr (ord"0" + i - 52)
  1294              else if i=62 then "_"
  1295              else  (*i=63*)    "'";
  1296 
  1297 val charVec = Vector.tabulate (64, char);
  1298 
  1299 fun newid n =
  1300   let
  1301   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1302 
  1303 val seedr = ref 0;
  1304 
  1305 in
  1306 
  1307 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1308 
  1309 end;
  1310 
  1311 
  1312 (* lexical scanning *)
  1313 
  1314 (*scan a list of characters into "words" composed of "letters" (recognized by
  1315   is_let) and separated by any number of non-"letters"*)
  1316 fun scanwords is_let cs =
  1317   let fun scan1 [] = []
  1318         | scan1 cs =
  1319             let val (lets, rest) = take_prefix is_let cs
  1320             in implode lets :: scanwords is_let rest end;
  1321   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1322 
  1323 
  1324 (* stamps and serial numbers *)
  1325 
  1326 type stamp = unit ref;
  1327 val stamp: unit -> stamp = ref;
  1328 
  1329 type serial = int;
  1330 local val count = ref 0
  1331 in fun serial () = inc count end;
  1332 
  1333 
  1334 (* generic objects *)
  1335 
  1336 (*note that the builtin exception datatype may be extended by new
  1337   constructors at any time*)
  1338 structure Object = struct type T = exn end;
  1339 
  1340 end;
  1341 
  1342 structure BasicLibrary: BASIC_LIBRARY = Library;
  1343 open BasicLibrary;