src/HOL/BNF_Greatest_Fixpoint.thy
author paulson <lp15@cam.ac.uk>
Mon Feb 22 14:37:56 2016 +0000 (2016-02-22)
changeset 62379 340738057c8c
parent 61943 7fba644ed827
child 62905 52c5a25e0c96
permissions -rw-r--r--
An assortment of useful lemmas about sums, norm, etc. Also: norm_conv_dist [symmetric] is now a simprule!
     1 (*  Title:      HOL/BNF_Greatest_Fixpoint.thy
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Author:     Lorenz Panny, TU Muenchen
     4     Author:     Jasmin Blanchette, TU Muenchen
     5     Copyright   2012, 2013, 2014
     6 
     7 Greatest fixpoint (codatatype) operation on bounded natural functors.
     8 *)
     9 
    10 section \<open>Greatest Fixpoint (Codatatype) Operation on Bounded Natural Functors\<close>
    11 
    12 theory BNF_Greatest_Fixpoint
    13 imports BNF_Fixpoint_Base String
    14 keywords
    15   "codatatype" :: thy_decl and
    16   "primcorecursive" :: thy_goal and
    17   "primcorec" :: thy_decl
    18 begin
    19 
    20 setup \<open>Sign.const_alias @{binding proj} @{const_name Equiv_Relations.proj}\<close>
    21 
    22 lemma one_pointE: "\<lbrakk>\<And>x. s = x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
    23   by simp
    24 
    25 lemma obj_sumE: "\<lbrakk>\<forall>x. s = Inl x \<longrightarrow> P; \<forall>x. s = Inr x \<longrightarrow> P\<rbrakk> \<Longrightarrow> P"
    26   by (cases s) auto
    27 
    28 lemma not_TrueE: "\<not> True \<Longrightarrow> P"
    29   by (erule notE, rule TrueI)
    30 
    31 lemma neq_eq_eq_contradict: "\<lbrakk>t \<noteq> u; s = t; s = u\<rbrakk> \<Longrightarrow> P"
    32   by fast
    33 
    34 lemma case_sum_expand_Inr: "f o Inl = g \<Longrightarrow> f x = case_sum g (f o Inr) x"
    35   by (auto split: sum.splits)
    36 
    37 lemma case_sum_expand_Inr': "f o Inl = g \<Longrightarrow> h = f o Inr \<longleftrightarrow> case_sum g h = f"
    38   apply rule
    39    apply (rule ext, force split: sum.split)
    40   by (rule ext, metis case_sum_o_inj(2))
    41 
    42 lemma converse_Times: "(A \<times> B) ^-1 = B \<times> A"
    43   by fast
    44 
    45 lemma equiv_proj:
    46   assumes e: "equiv A R" and m: "z \<in> R"
    47   shows "(proj R o fst) z = (proj R o snd) z"
    48 proof -
    49   from m have z: "(fst z, snd z) \<in> R" by auto
    50   with e have "\<And>x. (fst z, x) \<in> R \<Longrightarrow> (snd z, x) \<in> R" "\<And>x. (snd z, x) \<in> R \<Longrightarrow> (fst z, x) \<in> R"
    51     unfolding equiv_def sym_def trans_def by blast+
    52   then show ?thesis unfolding proj_def[abs_def] by auto
    53 qed
    54 
    55 (* Operators: *)
    56 definition image2 where "image2 A f g = {(f a, g a) | a. a \<in> A}"
    57 
    58 lemma Id_on_Gr: "Id_on A = Gr A id"
    59   unfolding Id_on_def Gr_def by auto
    60 
    61 lemma image2_eqI: "\<lbrakk>b = f x; c = g x; x \<in> A\<rbrakk> \<Longrightarrow> (b, c) \<in> image2 A f g"
    62   unfolding image2_def by auto
    63 
    64 lemma IdD: "(a, b) \<in> Id \<Longrightarrow> a = b"
    65   by auto
    66 
    67 lemma image2_Gr: "image2 A f g = (Gr A f)^-1 O (Gr A g)"
    68   unfolding image2_def Gr_def by auto
    69 
    70 lemma GrD1: "(x, fx) \<in> Gr A f \<Longrightarrow> x \<in> A"
    71   unfolding Gr_def by simp
    72 
    73 lemma GrD2: "(x, fx) \<in> Gr A f \<Longrightarrow> f x = fx"
    74   unfolding Gr_def by simp
    75 
    76 lemma Gr_incl: "Gr A f \<subseteq> A \<times> B \<longleftrightarrow> f ` A \<subseteq> B"
    77   unfolding Gr_def by auto
    78 
    79 lemma subset_Collect_iff: "B \<subseteq> A \<Longrightarrow> (B \<subseteq> {x \<in> A. P x}) = (\<forall>x \<in> B. P x)"
    80   by blast
    81 
    82 lemma subset_CollectI: "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> Q x \<Longrightarrow> P x) \<Longrightarrow> ({x \<in> B. Q x} \<subseteq> {x \<in> A. P x})"
    83   by blast
    84 
    85 lemma in_rel_Collect_case_prod_eq: "in_rel (Collect (case_prod X)) = X"
    86   unfolding fun_eq_iff by auto
    87 
    88 lemma Collect_case_prod_in_rel_leI: "X \<subseteq> Y \<Longrightarrow> X \<subseteq> Collect (case_prod (in_rel Y))"
    89   by auto
    90 
    91 lemma Collect_case_prod_in_rel_leE: "X \<subseteq> Collect (case_prod (in_rel Y)) \<Longrightarrow> (X \<subseteq> Y \<Longrightarrow> R) \<Longrightarrow> R"
    92   by force
    93 
    94 lemma conversep_in_rel: "(in_rel R)\<inverse>\<inverse> = in_rel (R\<inverse>)"
    95   unfolding fun_eq_iff by auto
    96 
    97 lemma relcompp_in_rel: "in_rel R OO in_rel S = in_rel (R O S)"
    98   unfolding fun_eq_iff by auto
    99 
   100 lemma in_rel_Gr: "in_rel (Gr A f) = Grp A f"
   101   unfolding Gr_def Grp_def fun_eq_iff by auto
   102 
   103 definition relImage where
   104   "relImage R f \<equiv> {(f a1, f a2) | a1 a2. (a1,a2) \<in> R}"
   105 
   106 definition relInvImage where
   107   "relInvImage A R f \<equiv> {(a1, a2) | a1 a2. a1 \<in> A \<and> a2 \<in> A \<and> (f a1, f a2) \<in> R}"
   108 
   109 lemma relImage_Gr:
   110   "\<lbrakk>R \<subseteq> A \<times> A\<rbrakk> \<Longrightarrow> relImage R f = (Gr A f)^-1 O R O Gr A f"
   111   unfolding relImage_def Gr_def relcomp_def by auto
   112 
   113 lemma relInvImage_Gr: "\<lbrakk>R \<subseteq> B \<times> B\<rbrakk> \<Longrightarrow> relInvImage A R f = Gr A f O R O (Gr A f)^-1"
   114   unfolding Gr_def relcomp_def image_def relInvImage_def by auto
   115 
   116 lemma relImage_mono:
   117   "R1 \<subseteq> R2 \<Longrightarrow> relImage R1 f \<subseteq> relImage R2 f"
   118   unfolding relImage_def by auto
   119 
   120 lemma relInvImage_mono:
   121   "R1 \<subseteq> R2 \<Longrightarrow> relInvImage A R1 f \<subseteq> relInvImage A R2 f"
   122   unfolding relInvImage_def by auto
   123 
   124 lemma relInvImage_Id_on:
   125   "(\<And>a1 a2. f a1 = f a2 \<longleftrightarrow> a1 = a2) \<Longrightarrow> relInvImage A (Id_on B) f \<subseteq> Id"
   126   unfolding relInvImage_def Id_on_def by auto
   127 
   128 lemma relInvImage_UNIV_relImage:
   129   "R \<subseteq> relInvImage UNIV (relImage R f) f"
   130   unfolding relInvImage_def relImage_def by auto
   131 
   132 lemma relImage_proj:
   133   assumes "equiv A R"
   134   shows "relImage R (proj R) \<subseteq> Id_on (A//R)"
   135   unfolding relImage_def Id_on_def
   136   using proj_iff[OF assms] equiv_class_eq_iff[OF assms]
   137   by (auto simp: proj_preserves)
   138 
   139 lemma relImage_relInvImage:
   140   assumes "R \<subseteq> f ` A \<times> f ` A"
   141   shows "relImage (relInvImage A R f) f = R"
   142   using assms unfolding relImage_def relInvImage_def by fast
   143 
   144 lemma subst_Pair: "P x y \<Longrightarrow> a = (x, y) \<Longrightarrow> P (fst a) (snd a)"
   145   by simp
   146 
   147 lemma fst_diag_id: "(fst \<circ> (%x. (x, x))) z = id z" by simp
   148 lemma snd_diag_id: "(snd \<circ> (%x. (x, x))) z = id z" by simp
   149 
   150 lemma fst_diag_fst: "fst o ((\<lambda>x. (x, x)) o fst) = fst" by auto
   151 lemma snd_diag_fst: "snd o ((\<lambda>x. (x, x)) o fst) = fst" by auto
   152 lemma fst_diag_snd: "fst o ((\<lambda>x. (x, x)) o snd) = snd" by auto
   153 lemma snd_diag_snd: "snd o ((\<lambda>x. (x, x)) o snd) = snd" by auto
   154 
   155 definition Succ where "Succ Kl kl = {k . kl @ [k] \<in> Kl}"
   156 definition Shift where "Shift Kl k = {kl. k # kl \<in> Kl}"
   157 definition shift where "shift lab k = (\<lambda>kl. lab (k # kl))"
   158 
   159 lemma empty_Shift: "\<lbrakk>[] \<in> Kl; k \<in> Succ Kl []\<rbrakk> \<Longrightarrow> [] \<in> Shift Kl k"
   160   unfolding Shift_def Succ_def by simp
   161 
   162 lemma SuccD: "k \<in> Succ Kl kl \<Longrightarrow> kl @ [k] \<in> Kl"
   163   unfolding Succ_def by simp
   164 
   165 lemmas SuccE = SuccD[elim_format]
   166 
   167 lemma SuccI: "kl @ [k] \<in> Kl \<Longrightarrow> k \<in> Succ Kl kl"
   168   unfolding Succ_def by simp
   169 
   170 lemma ShiftD: "kl \<in> Shift Kl k \<Longrightarrow> k # kl \<in> Kl"
   171   unfolding Shift_def by simp
   172 
   173 lemma Succ_Shift: "Succ (Shift Kl k) kl = Succ Kl (k # kl)"
   174   unfolding Succ_def Shift_def by auto
   175 
   176 lemma length_Cons: "length (x # xs) = Suc (length xs)"
   177   by simp
   178 
   179 lemma length_append_singleton: "length (xs @ [x]) = Suc (length xs)"
   180   by simp
   181 
   182 (*injection into the field of a cardinal*)
   183 definition "toCard_pred A r f \<equiv> inj_on f A \<and> f ` A \<subseteq> Field r \<and> Card_order r"
   184 definition "toCard A r \<equiv> SOME f. toCard_pred A r f"
   185 
   186 lemma ex_toCard_pred:
   187   "\<lbrakk>|A| \<le>o r; Card_order r\<rbrakk> \<Longrightarrow> \<exists> f. toCard_pred A r f"
   188   unfolding toCard_pred_def
   189   using card_of_ordLeq[of A "Field r"]
   190     ordLeq_ordIso_trans[OF _ card_of_unique[of "Field r" r], of "|A|"]
   191   by blast
   192 
   193 lemma toCard_pred_toCard:
   194   "\<lbrakk>|A| \<le>o r; Card_order r\<rbrakk> \<Longrightarrow> toCard_pred A r (toCard A r)"
   195   unfolding toCard_def using someI_ex[OF ex_toCard_pred] .
   196 
   197 lemma toCard_inj: "\<lbrakk>|A| \<le>o r; Card_order r; x \<in> A; y \<in> A\<rbrakk> \<Longrightarrow> toCard A r x = toCard A r y \<longleftrightarrow> x = y"
   198   using toCard_pred_toCard unfolding inj_on_def toCard_pred_def by blast
   199 
   200 definition "fromCard A r k \<equiv> SOME b. b \<in> A \<and> toCard A r b = k"
   201 
   202 lemma fromCard_toCard:
   203   "\<lbrakk>|A| \<le>o r; Card_order r; b \<in> A\<rbrakk> \<Longrightarrow> fromCard A r (toCard A r b) = b"
   204   unfolding fromCard_def by (rule some_equality) (auto simp add: toCard_inj)
   205 
   206 lemma Inl_Field_csum: "a \<in> Field r \<Longrightarrow> Inl a \<in> Field (r +c s)"
   207   unfolding Field_card_of csum_def by auto
   208 
   209 lemma Inr_Field_csum: "a \<in> Field s \<Longrightarrow> Inr a \<in> Field (r +c s)"
   210   unfolding Field_card_of csum_def by auto
   211 
   212 lemma rec_nat_0_imp: "f = rec_nat f1 (%n rec. f2 n rec) \<Longrightarrow> f 0 = f1"
   213   by auto
   214 
   215 lemma rec_nat_Suc_imp: "f = rec_nat f1 (%n rec. f2 n rec) \<Longrightarrow> f (Suc n) = f2 n (f n)"
   216   by auto
   217 
   218 lemma rec_list_Nil_imp: "f = rec_list f1 (%x xs rec. f2 x xs rec) \<Longrightarrow> f [] = f1"
   219   by auto
   220 
   221 lemma rec_list_Cons_imp: "f = rec_list f1 (%x xs rec. f2 x xs rec) \<Longrightarrow> f (x # xs) = f2 x xs (f xs)"
   222   by auto
   223 
   224 lemma not_arg_cong_Inr: "x \<noteq> y \<Longrightarrow> Inr x \<noteq> Inr y"
   225   by simp
   226 
   227 definition image2p where
   228   "image2p f g R = (\<lambda>x y. \<exists>x' y'. R x' y' \<and> f x' = x \<and> g y' = y)"
   229 
   230 lemma image2pI: "R x y \<Longrightarrow> image2p f g R (f x) (g y)"
   231   unfolding image2p_def by blast
   232 
   233 lemma image2pE: "\<lbrakk>image2p f g R fx gy; (\<And>x y. fx = f x \<Longrightarrow> gy = g y \<Longrightarrow> R x y \<Longrightarrow> P)\<rbrakk> \<Longrightarrow> P"
   234   unfolding image2p_def by blast
   235 
   236 lemma rel_fun_iff_geq_image2p: "rel_fun R S f g = (image2p f g R \<le> S)"
   237   unfolding rel_fun_def image2p_def by auto
   238 
   239 lemma rel_fun_image2p: "rel_fun R (image2p f g R) f g"
   240   unfolding rel_fun_def image2p_def by auto
   241 
   242 
   243 subsection \<open>Equivalence relations, quotients, and Hilbert's choice\<close>
   244 
   245 lemma equiv_Eps_in:
   246 "\<lbrakk>equiv A r; X \<in> A//r\<rbrakk> \<Longrightarrow> Eps (%x. x \<in> X) \<in> X"
   247   apply (rule someI2_ex)
   248   using in_quotient_imp_non_empty by blast
   249 
   250 lemma equiv_Eps_preserves:
   251   assumes ECH: "equiv A r" and X: "X \<in> A//r"
   252   shows "Eps (%x. x \<in> X) \<in> A"
   253   apply (rule in_mono[rule_format])
   254    using assms apply (rule in_quotient_imp_subset)
   255   by (rule equiv_Eps_in) (rule assms)+
   256 
   257 lemma proj_Eps:
   258   assumes "equiv A r" and "X \<in> A//r"
   259   shows "proj r (Eps (%x. x \<in> X)) = X"
   260 unfolding proj_def
   261 proof auto
   262   fix x assume x: "x \<in> X"
   263   thus "(Eps (%x. x \<in> X), x) \<in> r" using assms equiv_Eps_in in_quotient_imp_in_rel by fast
   264 next
   265   fix x assume "(Eps (%x. x \<in> X),x) \<in> r"
   266   thus "x \<in> X" using in_quotient_imp_closed[OF assms equiv_Eps_in[OF assms]] by fast
   267 qed
   268 
   269 definition univ where "univ f X == f (Eps (%x. x \<in> X))"
   270 
   271 lemma univ_commute:
   272 assumes ECH: "equiv A r" and RES: "f respects r" and x: "x \<in> A"
   273 shows "(univ f) (proj r x) = f x"
   274 proof (unfold univ_def)
   275   have prj: "proj r x \<in> A//r" using x proj_preserves by fast
   276   hence "Eps (%y. y \<in> proj r x) \<in> A" using ECH equiv_Eps_preserves by fast
   277   moreover have "proj r (Eps (%y. y \<in> proj r x)) = proj r x" using ECH prj proj_Eps by fast
   278   ultimately have "(x, Eps (%y. y \<in> proj r x)) \<in> r" using x ECH proj_iff by fast
   279   thus "f (Eps (%y. y \<in> proj r x)) = f x" using RES unfolding congruent_def by fastforce
   280 qed
   281 
   282 lemma univ_preserves:
   283   assumes ECH: "equiv A r" and RES: "f respects r" and PRES: "\<forall>x \<in> A. f x \<in> B"
   284   shows "\<forall>X \<in> A//r. univ f X \<in> B"
   285 proof
   286   fix X assume "X \<in> A//r"
   287   then obtain x where x: "x \<in> A" and X: "X = proj r x" using ECH proj_image[of r A] by blast
   288   hence "univ f X = f x" using ECH RES univ_commute by fastforce
   289   thus "univ f X \<in> B" using x PRES by simp
   290 qed
   291 
   292 ML_file "Tools/BNF/bnf_gfp_util.ML"
   293 ML_file "Tools/BNF/bnf_gfp_tactics.ML"
   294 ML_file "Tools/BNF/bnf_gfp.ML"
   295 ML_file "Tools/BNF/bnf_gfp_rec_sugar_tactics.ML"
   296 ML_file "Tools/BNF/bnf_gfp_rec_sugar.ML"
   297 
   298 end