src/HOL/Complete_Lattices.thy
author paulson <lp15@cam.ac.uk>
Mon Feb 22 14:37:56 2016 +0000 (2016-02-22)
changeset 62379 340738057c8c
parent 62343 24106dc44def
child 62390 842917225d56
permissions -rw-r--r--
An assortment of useful lemmas about sums, norm, etc. Also: norm_conv_dist [symmetric] is now a simprule!
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 section \<open>Complete lattices\<close>
     4 
     5 theory Complete_Lattices
     6 imports Fun
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection \<open>Syntactic infimum and supremum operations\<close>
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 begin
    19 
    20 abbreviation INFIMUM :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a"
    21 where
    22   "INFIMUM A f \<equiv> \<Sqinter>(f ` A)"
    23 
    24 lemma INF_image [simp]:
    25   "INFIMUM (f ` A) g = INFIMUM A (g \<circ> f)"
    26   by (simp add: image_comp)
    27 
    28 lemma INF_identity_eq [simp]:
    29   "INFIMUM A (\<lambda>x. x) = \<Sqinter>A"
    30   by simp
    31 
    32 lemma INF_id_eq [simp]:
    33   "INFIMUM A id = \<Sqinter>A"
    34   by simp
    35 
    36 lemma INF_cong:
    37   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> INFIMUM A C = INFIMUM B D"
    38   by (simp add: image_def)
    39 
    40 lemma strong_INF_cong [cong]:
    41   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> INFIMUM A C = INFIMUM B D"
    42   unfolding simp_implies_def by (fact INF_cong)
    43 
    44 end
    45 
    46 class Sup =
    47   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    48 begin
    49 
    50 abbreviation SUPREMUM :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a"
    51 where
    52   "SUPREMUM A f \<equiv> \<Squnion>(f ` A)"
    53 
    54 lemma SUP_image [simp]:
    55   "SUPREMUM (f ` A) g = SUPREMUM A (g \<circ> f)"
    56   by (simp add: image_comp)
    57 
    58 lemma SUP_identity_eq [simp]:
    59   "SUPREMUM A (\<lambda>x. x) = \<Squnion>A"
    60   by simp
    61 
    62 lemma SUP_id_eq [simp]:
    63   "SUPREMUM A id = \<Squnion>A"
    64   by (simp add: id_def)
    65 
    66 lemma SUP_cong:
    67   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> SUPREMUM A C = SUPREMUM B D"
    68   by (simp add: image_def)
    69 
    70 lemma strong_SUP_cong [cong]:
    71   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> SUPREMUM A C = SUPREMUM B D"
    72   unfolding simp_implies_def by (fact SUP_cong)
    73 
    74 end
    75 
    76 text \<open>
    77   Note: must use names @{const INFIMUM} and @{const SUPREMUM} here instead of
    78   \<open>INF\<close> and \<open>SUP\<close> to allow the following syntax coexist
    79   with the plain constant names.
    80 \<close>
    81 
    82 syntax (ASCII)
    83   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    84   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    85   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    86   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    87 
    88 syntax (output)
    89   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    90   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    91   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    92   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    93 
    94 syntax
    95   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    96   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    97   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    98   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    99 
   100 translations
   101   "\<Sqinter>x y. B"   \<rightleftharpoons> "\<Sqinter>x. \<Sqinter>y. B"
   102   "\<Sqinter>x. B"     \<rightleftharpoons> "CONST INFIMUM CONST UNIV (\<lambda>x. B)"
   103   "\<Sqinter>x. B"     \<rightleftharpoons> "\<Sqinter>x \<in> CONST UNIV. B"
   104   "\<Sqinter>x\<in>A. B"   \<rightleftharpoons> "CONST INFIMUM A (\<lambda>x. B)"
   105   "\<Squnion>x y. B"   \<rightleftharpoons> "\<Squnion>x. \<Squnion>y. B"
   106   "\<Squnion>x. B"     \<rightleftharpoons> "CONST SUPREMUM CONST UNIV (\<lambda>x. B)"
   107   "\<Squnion>x. B"     \<rightleftharpoons> "\<Squnion>x \<in> CONST UNIV. B"
   108   "\<Squnion>x\<in>A. B"   \<rightleftharpoons> "CONST SUPREMUM A (\<lambda>x. B)"
   109 
   110 print_translation \<open>
   111   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFIMUM} @{syntax_const "_INF"},
   112     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPREMUM} @{syntax_const "_SUP"}]
   113 \<close> \<comment> \<open>to avoid eta-contraction of body\<close>
   114 
   115 
   116 subsection \<open>Abstract complete lattices\<close>
   117 
   118 text \<open>A complete lattice always has a bottom and a top,
   119 so we include them into the following type class,
   120 along with assumptions that define bottom and top
   121 in terms of infimum and supremum.\<close>
   122 
   123 class complete_lattice = lattice + Inf + Sup + bot + top +
   124   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
   125      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
   126   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
   127      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
   128   assumes Inf_empty [simp]: "\<Sqinter>{} = \<top>"
   129   assumes Sup_empty [simp]: "\<Squnion>{} = \<bottom>"
   130 begin
   131 
   132 subclass bounded_lattice
   133 proof
   134   fix a
   135   show "\<bottom> \<le> a" by (auto intro: Sup_least simp only: Sup_empty [symmetric])
   136   show "a \<le> \<top>" by (auto intro: Inf_greatest simp only: Inf_empty [symmetric])
   137 qed
   138 
   139 lemma dual_complete_lattice:
   140   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   141   by (auto intro!: class.complete_lattice.intro dual_lattice)
   142     (unfold_locales, (fact Inf_empty Sup_empty
   143         Sup_upper Sup_least Inf_lower Inf_greatest)+)
   144 
   145 end
   146 
   147 context complete_lattice
   148 begin
   149 
   150 lemma Sup_eqI:
   151   "(\<And>y. y \<in> A \<Longrightarrow> y \<le> x) \<Longrightarrow> (\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> \<Squnion>A = x"
   152   by (blast intro: antisym Sup_least Sup_upper)
   153 
   154 lemma Inf_eqI:
   155   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x) \<Longrightarrow> \<Sqinter>A = x"
   156   by (blast intro: antisym Inf_greatest Inf_lower)
   157 
   158 lemma SUP_eqI:
   159   "(\<And>i. i \<in> A \<Longrightarrow> f i \<le> x) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> (\<Squnion>i\<in>A. f i) = x"
   160   using Sup_eqI [of "f ` A" x] by auto
   161 
   162 lemma INF_eqI:
   163   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> f i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<ge> y) \<Longrightarrow> x \<ge> y) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) = x"
   164   using Inf_eqI [of "f ` A" x] by auto
   165 
   166 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   167   using Inf_lower [of _ "f ` A"] by simp
   168 
   169 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   170   using Inf_greatest [of "f ` A"] by auto
   171 
   172 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   173   using Sup_upper [of _ "f ` A"] by simp
   174 
   175 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   176   using Sup_least [of "f ` A"] by auto
   177 
   178 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   179   using Inf_lower [of u A] by auto
   180 
   181 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   182   using INF_lower [of i A f] by auto
   183 
   184 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   185   using Sup_upper [of u A] by auto
   186 
   187 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   188   using SUP_upper [of i A f] by auto
   189 
   190 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   191   by (auto intro: Inf_greatest dest: Inf_lower)
   192 
   193 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   194   using le_Inf_iff [of _ "f ` A"] by simp
   195 
   196 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   197   by (auto intro: Sup_least dest: Sup_upper)
   198 
   199 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   200   using Sup_le_iff [of "f ` A"] by simp
   201 
   202 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   203   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   204 
   205 lemma INF_insert [simp]: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFIMUM A f"
   206   by (simp cong del: strong_INF_cong)
   207 
   208 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   209   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   210 
   211 lemma SUP_insert [simp]: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPREMUM A f"
   212   by (simp cong del: strong_SUP_cong)
   213 
   214 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   215   by (simp cong del: strong_INF_cong)
   216 
   217 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   218   by (simp cong del: strong_SUP_cong)
   219 
   220 lemma Inf_UNIV [simp]:
   221   "\<Sqinter>UNIV = \<bottom>"
   222   by (auto intro!: antisym Inf_lower)
   223 
   224 lemma Sup_UNIV [simp]:
   225   "\<Squnion>UNIV = \<top>"
   226   by (auto intro!: antisym Sup_upper)
   227 
   228 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   229   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   230 
   231 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   232   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   233 
   234 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   235   by (auto intro: Inf_greatest Inf_lower)
   236 
   237 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   238   by (auto intro: Sup_least Sup_upper)
   239 
   240 lemma Inf_mono:
   241   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   242   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   243 proof (rule Inf_greatest)
   244   fix b assume "b \<in> B"
   245   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   246   from \<open>a \<in> A\<close> have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   247   with \<open>a \<sqsubseteq> b\<close> show "\<Sqinter>A \<sqsubseteq> b" by auto
   248 qed
   249 
   250 lemma INF_mono:
   251   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   252   using Inf_mono [of "g ` B" "f ` A"] by auto
   253 
   254 lemma Sup_mono:
   255   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   256   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   257 proof (rule Sup_least)
   258   fix a assume "a \<in> A"
   259   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   260   from \<open>b \<in> B\<close> have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   261   with \<open>a \<sqsubseteq> b\<close> show "a \<sqsubseteq> \<Squnion>B" by auto
   262 qed
   263 
   264 lemma SUP_mono:
   265   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   266   using Sup_mono [of "f ` A" "g ` B"] by auto
   267 
   268 lemma INF_superset_mono:
   269   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   270   \<comment> \<open>The last inclusion is POSITIVE!\<close>
   271   by (blast intro: INF_mono dest: subsetD)
   272 
   273 lemma SUP_subset_mono:
   274   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   275   by (blast intro: SUP_mono dest: subsetD)
   276 
   277 lemma Inf_less_eq:
   278   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   279     and "A \<noteq> {}"
   280   shows "\<Sqinter>A \<sqsubseteq> u"
   281 proof -
   282   from \<open>A \<noteq> {}\<close> obtain v where "v \<in> A" by blast
   283   moreover from \<open>v \<in> A\<close> assms(1) have "v \<sqsubseteq> u" by blast
   284   ultimately show ?thesis by (rule Inf_lower2)
   285 qed
   286 
   287 lemma less_eq_Sup:
   288   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   289     and "A \<noteq> {}"
   290   shows "u \<sqsubseteq> \<Squnion>A"
   291 proof -
   292   from \<open>A \<noteq> {}\<close> obtain v where "v \<in> A" by blast
   293   moreover from \<open>v \<in> A\<close> assms(1) have "u \<sqsubseteq> v" by blast
   294   ultimately show ?thesis by (rule Sup_upper2)
   295 qed
   296 
   297 lemma INF_eq:
   298   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<ge> g j"
   299   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<ge> f i"
   300   shows "INFIMUM A f = INFIMUM B g"
   301   by (intro antisym INF_greatest) (blast intro: INF_lower2 dest: assms)+
   302 
   303 lemma SUP_eq:
   304   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<le> g j"
   305   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<le> f i"
   306   shows "SUPREMUM A f = SUPREMUM B g"
   307   by (intro antisym SUP_least) (blast intro: SUP_upper2 dest: assms)+
   308 
   309 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   310   by (auto intro: Inf_greatest Inf_lower)
   311 
   312 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   313   by (auto intro: Sup_least Sup_upper)
   314 
   315 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   316   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   317 
   318 lemma INF_union:
   319   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   320   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   321 
   322 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   323   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   324 
   325 lemma SUP_union:
   326   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   327   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   328 
   329 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   330   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   331 
   332 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   333 proof (rule antisym)
   334   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   335 next
   336   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   337 qed
   338 
   339 lemma Inf_top_conv [simp]:
   340   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   341   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   342 proof -
   343   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   344   proof
   345     assume "\<forall>x\<in>A. x = \<top>"
   346     then have "A = {} \<or> A = {\<top>}" by auto
   347     then show "\<Sqinter>A = \<top>" by auto
   348   next
   349     assume "\<Sqinter>A = \<top>"
   350     show "\<forall>x\<in>A. x = \<top>"
   351     proof (rule ccontr)
   352       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   353       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   354       then obtain B where "A = insert x B" by blast
   355       with \<open>\<Sqinter>A = \<top>\<close> \<open>x \<noteq> \<top>\<close> show False by simp
   356     qed
   357   qed
   358   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   359 qed
   360 
   361 lemma INF_top_conv [simp]:
   362   "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   363   "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   364   using Inf_top_conv [of "B ` A"] by simp_all
   365 
   366 lemma Sup_bot_conv [simp]:
   367   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   368   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   369   using dual_complete_lattice
   370   by (rule complete_lattice.Inf_top_conv)+
   371 
   372 lemma SUP_bot_conv [simp]:
   373  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   374  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   375   using Sup_bot_conv [of "B ` A"] by simp_all
   376 
   377 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   378   by (auto intro: antisym INF_lower INF_greatest)
   379 
   380 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   381   by (auto intro: antisym SUP_upper SUP_least)
   382 
   383 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   384   by (cases "A = {}") simp_all
   385 
   386 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   387   by (cases "A = {}") simp_all
   388 
   389 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   390   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   391 
   392 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   393   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   394 
   395 lemma INF_absorb:
   396   assumes "k \<in> I"
   397   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   398 proof -
   399   from assms obtain J where "I = insert k J" by blast
   400   then show ?thesis by simp
   401 qed
   402 
   403 lemma SUP_absorb:
   404   assumes "k \<in> I"
   405   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   406 proof -
   407   from assms obtain J where "I = insert k J" by blast
   408   then show ?thesis by simp
   409 qed
   410 
   411 lemma INF_inf_const1:
   412   "I \<noteq> {} \<Longrightarrow> (INF i:I. inf x (f i)) = inf x (INF i:I. f i)"
   413   by (intro antisym INF_greatest inf_mono order_refl INF_lower)
   414      (auto intro: INF_lower2 le_infI2 intro!: INF_mono)
   415 
   416 lemma INF_inf_const2:
   417   "I \<noteq> {} \<Longrightarrow> (INF i:I. inf (f i) x) = inf (INF i:I. f i) x"
   418   using INF_inf_const1[of I x f] by (simp add: inf_commute)
   419 
   420 lemma INF_constant:
   421   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   422   by simp
   423 
   424 lemma SUP_constant:
   425   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   426   by simp
   427 
   428 lemma less_INF_D:
   429   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   430 proof -
   431   note \<open>y < (\<Sqinter>i\<in>A. f i)\<close>
   432   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using \<open>i \<in> A\<close>
   433     by (rule INF_lower)
   434   finally show "y < f i" .
   435 qed
   436 
   437 lemma SUP_lessD:
   438   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   439 proof -
   440   have "f i \<le> (\<Squnion>i\<in>A. f i)" using \<open>i \<in> A\<close>
   441     by (rule SUP_upper)
   442   also note \<open>(\<Squnion>i\<in>A. f i) < y\<close>
   443   finally show "f i < y" .
   444 qed
   445 
   446 lemma INF_UNIV_bool_expand:
   447   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   448   by (simp add: UNIV_bool inf_commute)
   449 
   450 lemma SUP_UNIV_bool_expand:
   451   "(\<Squnion>b. A b) = A True \<squnion> A False"
   452   by (simp add: UNIV_bool sup_commute)
   453 
   454 lemma Inf_le_Sup: "A \<noteq> {} \<Longrightarrow> Inf A \<le> Sup A"
   455   by (blast intro: Sup_upper2 Inf_lower ex_in_conv)
   456 
   457 lemma INF_le_SUP: "A \<noteq> {} \<Longrightarrow> INFIMUM A f \<le> SUPREMUM A f"
   458   using Inf_le_Sup [of "f ` A"] by simp
   459 
   460 lemma INF_eq_const:
   461   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> INFIMUM I f = x"
   462   by (auto intro: INF_eqI)
   463 
   464 lemma SUP_eq_const:
   465   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> SUPREMUM I f = x"
   466   by (auto intro: SUP_eqI)
   467 
   468 lemma INF_eq_iff:
   469   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i \<le> c) \<Longrightarrow> (INFIMUM I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   470   using INF_eq_const [of I f c] INF_lower [of _ I f]
   471   by (auto intro: antisym cong del: strong_INF_cong)
   472 
   473 lemma SUP_eq_iff:
   474   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> c \<le> f i) \<Longrightarrow> (SUPREMUM I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   475   using SUP_eq_const [of I f c] SUP_upper [of _ I f]
   476   by (auto intro: antisym cong del: strong_SUP_cong)
   477 
   478 end
   479 
   480 class complete_distrib_lattice = complete_lattice +
   481   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   482   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   483 begin
   484 
   485 lemma sup_INF:
   486   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   487   unfolding sup_Inf by simp
   488 
   489 lemma inf_SUP:
   490   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   491   unfolding inf_Sup by simp
   492 
   493 lemma dual_complete_distrib_lattice:
   494   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   495   apply (rule class.complete_distrib_lattice.intro)
   496   apply (fact dual_complete_lattice)
   497   apply (rule class.complete_distrib_lattice_axioms.intro)
   498   apply (simp_all add: inf_Sup sup_Inf)
   499   done
   500 
   501 subclass distrib_lattice proof
   502   fix a b c
   503   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   504   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by simp
   505 qed
   506 
   507 lemma Inf_sup:
   508   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   509   by (simp add: sup_Inf sup_commute)
   510 
   511 lemma Sup_inf:
   512   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   513   by (simp add: inf_Sup inf_commute)
   514 
   515 lemma INF_sup: 
   516   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   517   by (simp add: sup_INF sup_commute)
   518 
   519 lemma SUP_inf:
   520   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   521   by (simp add: inf_SUP inf_commute)
   522 
   523 lemma Inf_sup_eq_top_iff:
   524   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   525   by (simp only: Inf_sup INF_top_conv)
   526 
   527 lemma Sup_inf_eq_bot_iff:
   528   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   529   by (simp only: Sup_inf SUP_bot_conv)
   530 
   531 lemma INF_sup_distrib2:
   532   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   533   by (subst INF_commute) (simp add: sup_INF INF_sup)
   534 
   535 lemma SUP_inf_distrib2:
   536   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   537   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   538 
   539 context
   540   fixes f :: "'a \<Rightarrow> 'b::complete_lattice"
   541   assumes "mono f"
   542 begin
   543 
   544 lemma mono_Inf:
   545   shows "f (\<Sqinter>A) \<le> (\<Sqinter>x\<in>A. f x)"
   546   using \<open>mono f\<close> by (auto intro: complete_lattice_class.INF_greatest Inf_lower dest: monoD)
   547 
   548 lemma mono_Sup:
   549   shows "(\<Squnion>x\<in>A. f x) \<le> f (\<Squnion>A)"
   550   using \<open>mono f\<close> by (auto intro: complete_lattice_class.SUP_least Sup_upper dest: monoD)
   551 
   552 lemma mono_INF:
   553   "f (INF i : I. A i) \<le> (INF x : I. f (A x))"
   554   by (intro complete_lattice_class.INF_greatest monoD[OF \<open>mono f\<close>] INF_lower)
   555 
   556 lemma mono_SUP:
   557   "(SUP x : I. f (A x)) \<le> f (SUP i : I. A i)"
   558   by (intro complete_lattice_class.SUP_least monoD[OF \<open>mono f\<close>] SUP_upper)
   559 
   560 end
   561 
   562 end
   563 
   564 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   565 begin
   566 
   567 lemma dual_complete_boolean_algebra:
   568   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   569   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   570 
   571 lemma uminus_Inf:
   572   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   573 proof (rule antisym)
   574   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   575     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   576   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   577     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   578 qed
   579 
   580 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   581   by (simp add: uminus_Inf image_image)
   582 
   583 lemma uminus_Sup:
   584   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   585 proof -
   586   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_INF)
   587   then show ?thesis by simp
   588 qed
   589   
   590 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   591   by (simp add: uminus_Sup image_image)
   592 
   593 end
   594 
   595 class complete_linorder = linorder + complete_lattice
   596 begin
   597 
   598 lemma dual_complete_linorder:
   599   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   600   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   601 
   602 lemma complete_linorder_inf_min: "inf = min"
   603   by (auto intro: antisym simp add: min_def fun_eq_iff)
   604 
   605 lemma complete_linorder_sup_max: "sup = max"
   606   by (auto intro: antisym simp add: max_def fun_eq_iff)
   607 
   608 lemma Inf_less_iff:
   609   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   610   unfolding not_le [symmetric] le_Inf_iff by auto
   611 
   612 lemma INF_less_iff:
   613   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   614   using Inf_less_iff [of "f ` A"] by simp
   615 
   616 lemma less_Sup_iff:
   617   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   618   unfolding not_le [symmetric] Sup_le_iff by auto
   619 
   620 lemma less_SUP_iff:
   621   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   622   using less_Sup_iff [of _ "f ` A"] by simp
   623 
   624 lemma Sup_eq_top_iff [simp]:
   625   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   626 proof
   627   assume *: "\<Squnion>A = \<top>"
   628   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   629   proof (intro allI impI)
   630     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   631       unfolding less_Sup_iff by auto
   632   qed
   633 next
   634   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   635   show "\<Squnion>A = \<top>"
   636   proof (rule ccontr)
   637     assume "\<Squnion>A \<noteq> \<top>"
   638     with top_greatest [of "\<Squnion>A"]
   639     have "\<Squnion>A < \<top>" unfolding le_less by auto
   640     then have "\<Squnion>A < \<Squnion>A"
   641       using * unfolding less_Sup_iff by auto
   642     then show False by auto
   643   qed
   644 qed
   645 
   646 lemma SUP_eq_top_iff [simp]:
   647   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   648   using Sup_eq_top_iff [of "f ` A"] by simp
   649 
   650 lemma Inf_eq_bot_iff [simp]:
   651   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   652   using dual_complete_linorder
   653   by (rule complete_linorder.Sup_eq_top_iff)
   654 
   655 lemma INF_eq_bot_iff [simp]:
   656   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   657   using Inf_eq_bot_iff [of "f ` A"] by simp
   658 
   659 lemma Inf_le_iff: "\<Sqinter>A \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>a\<in>A. y > a)"
   660 proof safe
   661   fix y assume "x \<ge> \<Sqinter>A" "y > x"
   662   then have "y > \<Sqinter>A" by auto
   663   then show "\<exists>a\<in>A. y > a"
   664     unfolding Inf_less_iff .
   665 qed (auto elim!: allE[of _ "\<Sqinter>A"] simp add: not_le[symmetric] Inf_lower)
   666 
   667 lemma INF_le_iff:
   668   "INFIMUM A f \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>i\<in>A. y > f i)"
   669   using Inf_le_iff [of "f ` A"] by simp
   670 
   671 lemma le_Sup_iff: "x \<le> \<Squnion>A \<longleftrightarrow> (\<forall>y<x. \<exists>a\<in>A. y < a)"
   672 proof safe
   673   fix y assume "x \<le> \<Squnion>A" "y < x"
   674   then have "y < \<Squnion>A" by auto
   675   then show "\<exists>a\<in>A. y < a"
   676     unfolding less_Sup_iff .
   677 qed (auto elim!: allE[of _ "\<Squnion>A"] simp add: not_le[symmetric] Sup_upper)
   678 
   679 lemma le_SUP_iff: "x \<le> SUPREMUM A f \<longleftrightarrow> (\<forall>y<x. \<exists>i\<in>A. y < f i)"
   680   using le_Sup_iff [of _ "f ` A"] by simp
   681 
   682 subclass complete_distrib_lattice
   683 proof
   684   fix a and B
   685   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)" and "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   686     by (safe intro!: INF_eqI [symmetric] sup_mono Inf_lower SUP_eqI [symmetric] inf_mono Sup_upper)
   687       (auto simp: not_less [symmetric] Inf_less_iff less_Sup_iff
   688         le_max_iff_disj complete_linorder_sup_max min_le_iff_disj complete_linorder_inf_min)
   689 qed
   690 
   691 end
   692 
   693 
   694 subsection \<open>Complete lattice on @{typ bool}\<close>
   695 
   696 instantiation bool :: complete_lattice
   697 begin
   698 
   699 definition
   700   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   701 
   702 definition
   703   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   704 
   705 instance proof
   706 qed (auto intro: bool_induct)
   707 
   708 end
   709 
   710 lemma not_False_in_image_Ball [simp]:
   711   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   712   by auto
   713 
   714 lemma True_in_image_Bex [simp]:
   715   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   716   by auto
   717 
   718 lemma INF_bool_eq [simp]:
   719   "INFIMUM = Ball"
   720   by (simp add: fun_eq_iff)
   721 
   722 lemma SUP_bool_eq [simp]:
   723   "SUPREMUM = Bex"
   724   by (simp add: fun_eq_iff)
   725 
   726 instance bool :: complete_boolean_algebra proof
   727 qed (auto intro: bool_induct)
   728 
   729 
   730 subsection \<open>Complete lattice on @{typ "_ \<Rightarrow> _"}\<close>
   731 
   732 instantiation "fun" :: (type, Inf) Inf
   733 begin
   734 
   735 definition
   736   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   737 
   738 lemma Inf_apply [simp, code]:
   739   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   740   by (simp add: Inf_fun_def)
   741 
   742 instance ..
   743 
   744 end
   745 
   746 instantiation "fun" :: (type, Sup) Sup
   747 begin
   748 
   749 definition
   750   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   751 
   752 lemma Sup_apply [simp, code]:
   753   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   754   by (simp add: Sup_fun_def)
   755 
   756 instance ..
   757 
   758 end
   759 
   760 instantiation "fun" :: (type, complete_lattice) complete_lattice
   761 begin
   762 
   763 instance proof
   764 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   765 
   766 end
   767 
   768 lemma INF_apply [simp]:
   769   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   770   using Inf_apply [of "f ` A"] by (simp add: comp_def)
   771 
   772 lemma SUP_apply [simp]:
   773   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   774   using Sup_apply [of "f ` A"] by (simp add: comp_def)
   775 
   776 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   777 qed (auto simp add: inf_Sup sup_Inf fun_eq_iff image_image)
   778 
   779 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   780 
   781 
   782 subsection \<open>Complete lattice on unary and binary predicates\<close>
   783 
   784 lemma Inf1_I: 
   785   "(\<And>P. P \<in> A \<Longrightarrow> P a) \<Longrightarrow> (\<Sqinter>A) a"
   786   by auto
   787 
   788 lemma INF1_I:
   789   "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   790   by simp
   791 
   792 lemma INF2_I:
   793   "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   794   by simp
   795 
   796 lemma Inf2_I: 
   797   "(\<And>r. r \<in> A \<Longrightarrow> r a b) \<Longrightarrow> (\<Sqinter>A) a b"
   798   by auto
   799 
   800 lemma Inf1_D:
   801   "(\<Sqinter>A) a \<Longrightarrow> P \<in> A \<Longrightarrow> P a"
   802   by auto
   803 
   804 lemma INF1_D:
   805   "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   806   by simp
   807 
   808 lemma Inf2_D:
   809   "(\<Sqinter>A) a b \<Longrightarrow> r \<in> A \<Longrightarrow> r a b"
   810   by auto
   811 
   812 lemma INF2_D:
   813   "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   814   by simp
   815 
   816 lemma Inf1_E:
   817   assumes "(\<Sqinter>A) a"
   818   obtains "P a" | "P \<notin> A"
   819   using assms by auto
   820 
   821 lemma INF1_E:
   822   assumes "(\<Sqinter>x\<in>A. B x) b"
   823   obtains "B a b" | "a \<notin> A"
   824   using assms by auto
   825 
   826 lemma Inf2_E:
   827   assumes "(\<Sqinter>A) a b"
   828   obtains "r a b" | "r \<notin> A"
   829   using assms by auto
   830 
   831 lemma INF2_E:
   832   assumes "(\<Sqinter>x\<in>A. B x) b c"
   833   obtains "B a b c" | "a \<notin> A"
   834   using assms by auto
   835 
   836 lemma Sup1_I:
   837   "P \<in> A \<Longrightarrow> P a \<Longrightarrow> (\<Squnion>A) a"
   838   by auto
   839 
   840 lemma SUP1_I:
   841   "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   842   by auto
   843 
   844 lemma Sup2_I:
   845   "r \<in> A \<Longrightarrow> r a b \<Longrightarrow> (\<Squnion>A) a b"
   846   by auto
   847 
   848 lemma SUP2_I:
   849   "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   850   by auto
   851 
   852 lemma Sup1_E:
   853   assumes "(\<Squnion>A) a"
   854   obtains P where "P \<in> A" and "P a"
   855   using assms by auto
   856 
   857 lemma SUP1_E:
   858   assumes "(\<Squnion>x\<in>A. B x) b"
   859   obtains x where "x \<in> A" and "B x b"
   860   using assms by auto
   861 
   862 lemma Sup2_E:
   863   assumes "(\<Squnion>A) a b"
   864   obtains r where "r \<in> A" "r a b"
   865   using assms by auto
   866 
   867 lemma SUP2_E:
   868   assumes "(\<Squnion>x\<in>A. B x) b c"
   869   obtains x where "x \<in> A" "B x b c"
   870   using assms by auto
   871 
   872 
   873 subsection \<open>Complete lattice on @{typ "_ set"}\<close>
   874 
   875 instantiation "set" :: (type) complete_lattice
   876 begin
   877 
   878 definition
   879   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   880 
   881 definition
   882   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   883 
   884 instance proof
   885 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def le_fun_def)
   886 
   887 end
   888 
   889 instance "set" :: (type) complete_boolean_algebra
   890 proof
   891 qed (auto simp add: Inf_set_def Sup_set_def image_def)
   892   
   893 
   894 subsubsection \<open>Inter\<close>
   895 
   896 abbreviation Inter :: "'a set set \<Rightarrow> 'a set"  ("\<Inter>_" [900] 900)
   897   where "\<Inter>S \<equiv> \<Sqinter>S"
   898   
   899 lemma Inter_eq:
   900   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   901 proof (rule set_eqI)
   902   fix x
   903   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   904     by auto
   905   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   906     by (simp add: Inf_set_def image_def)
   907 qed
   908 
   909 lemma Inter_iff [simp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   910   by (unfold Inter_eq) blast
   911 
   912 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   913   by (simp add: Inter_eq)
   914 
   915 text \<open>
   916   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   917   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   918   @{prop "X \<in> C"} does not!  This rule is analogous to \<open>spec\<close>.
   919 \<close>
   920 
   921 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   922   by auto
   923 
   924 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   925   \<comment> \<open>``Classical'' elimination rule -- does not require proving
   926     @{prop "X \<in> C"}.\<close>
   927   by (unfold Inter_eq) blast
   928 
   929 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   930   by (fact Inf_lower)
   931 
   932 lemma Inter_subset:
   933   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   934   by (fact Inf_less_eq)
   935 
   936 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> \<Inter>A"
   937   by (fact Inf_greatest)
   938 
   939 lemma Inter_empty: "\<Inter>{} = UNIV"
   940   by (fact Inf_empty) (* already simp *)
   941 
   942 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   943   by (fact Inf_UNIV) (* already simp *)
   944 
   945 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   946   by (fact Inf_insert) (* already simp *)
   947 
   948 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   949   by (fact less_eq_Inf_inter)
   950 
   951 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   952   by (fact Inf_union_distrib)
   953 
   954 lemma Inter_UNIV_conv [simp]:
   955   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   956   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   957   by (fact Inf_top_conv)+
   958 
   959 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   960   by (fact Inf_superset_mono)
   961 
   962 
   963 subsubsection \<open>Intersections of families\<close>
   964 
   965 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set"
   966   where "INTER \<equiv> INFIMUM"
   967 
   968 text \<open>
   969   Note: must use name @{const INTER} here instead of \<open>INT\<close>
   970   to allow the following syntax coexist with the plain constant name.
   971 \<close>
   972 
   973 syntax (ASCII)
   974   "_INTER1"     :: "pttrns \<Rightarrow> 'b set \<Rightarrow> 'b set"           ("(3INT _./ _)" [0, 10] 10)
   975   "_INTER"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   976 
   977 syntax (latex output)
   978   "_INTER1"     :: "pttrns \<Rightarrow> 'b set \<Rightarrow> 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   979   "_INTER"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   980 
   981 syntax
   982   "_INTER1"     :: "pttrns \<Rightarrow> 'b set \<Rightarrow> 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   983   "_INTER"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   984 
   985 translations
   986   "\<Inter>x y. B"  \<rightleftharpoons> "\<Inter>x. \<Inter>y. B"
   987   "\<Inter>x. B"    \<rightleftharpoons> "CONST INTER CONST UNIV (\<lambda>x. B)"
   988   "\<Inter>x. B"    \<rightleftharpoons> "\<Inter>x \<in> CONST UNIV. B"
   989   "\<Inter>x\<in>A. B"  \<rightleftharpoons> "CONST INTER A (\<lambda>x. B)"
   990 
   991 print_translation \<open>
   992   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   993 \<close> \<comment> \<open>to avoid eta-contraction of body\<close>
   994 
   995 lemma INTER_eq:
   996   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   997   by (auto intro!: INF_eqI)
   998 
   999 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
  1000   using Inter_iff [of _ "B ` A"] by simp
  1001 
  1002 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
  1003   by auto
  1004 
  1005 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
  1006   by auto
  1007 
  1008 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
  1009   \<comment> \<open>"Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}.\<close>
  1010   by auto
  1011 
  1012 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1013   by blast
  1014 
  1015 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1016   by blast
  1017 
  1018 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1019   by (fact INF_lower)
  1020 
  1021 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1022   by (fact INF_greatest)
  1023 
  1024 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
  1025   by (fact INF_empty)
  1026 
  1027 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1028   by (fact INF_absorb)
  1029 
  1030 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
  1031   by (fact le_INF_iff)
  1032 
  1033 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1034   by (fact INF_insert)
  1035 
  1036 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1037   by (fact INF_union)
  1038 
  1039 lemma INT_insert_distrib:
  1040   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1041   by blast
  1042 
  1043 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1044   by (fact INF_constant)
  1045 
  1046 lemma INTER_UNIV_conv:
  1047  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1048  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1049   by (fact INF_top_conv)+ (* already simp *)
  1050 
  1051 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
  1052   by (fact INF_UNIV_bool_expand)
  1053 
  1054 lemma INT_anti_mono:
  1055   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1056   \<comment> \<open>The last inclusion is POSITIVE!\<close>
  1057   by (fact INF_superset_mono)
  1058 
  1059 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1060   by blast
  1061 
  1062 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
  1063   by blast
  1064 
  1065 
  1066 subsubsection \<open>Union\<close>
  1067 
  1068 abbreviation Union :: "'a set set \<Rightarrow> 'a set"  ("\<Union>_" [900] 900)
  1069   where "\<Union>S \<equiv> \<Squnion>S"
  1070 
  1071 lemma Union_eq:
  1072   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
  1073 proof (rule set_eqI)
  1074   fix x
  1075   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
  1076     by auto
  1077   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
  1078     by (simp add: Sup_set_def image_def)
  1079 qed
  1080 
  1081 lemma Union_iff [simp]:
  1082   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
  1083   by (unfold Union_eq) blast
  1084 
  1085 lemma UnionI [intro]:
  1086   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
  1087   \<comment> \<open>The order of the premises presupposes that @{term C} is rigid;
  1088     @{term A} may be flexible.\<close>
  1089   by auto
  1090 
  1091 lemma UnionE [elim!]:
  1092   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
  1093   by auto
  1094 
  1095 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
  1096   by (fact Sup_upper)
  1097 
  1098 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
  1099   by (fact Sup_least)
  1100 
  1101 lemma Union_empty: "\<Union>{} = {}"
  1102   by (fact Sup_empty) (* already simp *)
  1103 
  1104 lemma Union_UNIV: "\<Union>UNIV = UNIV"
  1105   by (fact Sup_UNIV) (* already simp *)
  1106 
  1107 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
  1108   by (fact Sup_insert) (* already simp *)
  1109 
  1110 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
  1111   by (fact Sup_union_distrib)
  1112 
  1113 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1114   by (fact Sup_inter_less_eq)
  1115 
  1116 lemma Union_empty_conv: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1117   by (fact Sup_bot_conv) (* already simp *)
  1118 
  1119 lemma empty_Union_conv: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1120   by (fact Sup_bot_conv) (* already simp *)
  1121 
  1122 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1123   by blast
  1124 
  1125 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1126   by blast
  1127 
  1128 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
  1129   by (fact Sup_subset_mono)
  1130 
  1131 
  1132 subsubsection \<open>Unions of families\<close>
  1133 
  1134 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set"
  1135   where "UNION \<equiv> SUPREMUM"
  1136 
  1137 text \<open>
  1138   Note: must use name @{const UNION} here instead of \<open>UN\<close>
  1139   to allow the following syntax coexist with the plain constant name.
  1140 \<close>
  1141 
  1142 syntax (ASCII)
  1143   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
  1144   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
  1145 
  1146 syntax (latex output)
  1147   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
  1148   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
  1149 
  1150 syntax
  1151   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
  1152   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
  1153 
  1154 translations
  1155   "\<Union>x y. B"   \<rightleftharpoons> "\<Union>x. \<Union>y. B"
  1156   "\<Union>x. B"     \<rightleftharpoons> "CONST UNION CONST UNIV (\<lambda>x. B)"
  1157   "\<Union>x. B"     \<rightleftharpoons> "\<Union>x \<in> CONST UNIV. B"
  1158   "\<Union>x\<in>A. B"   \<rightleftharpoons> "CONST UNION A (\<lambda>x. B)"
  1159 
  1160 text \<open>
  1161   Note the difference between ordinary syntax of indexed
  1162   unions and intersections (e.g.\ \<open>\<Union>a\<^sub>1\<in>A\<^sub>1. B\<close>)
  1163   and their \LaTeX\ rendition: @{term"\<Union>a\<^sub>1\<in>A\<^sub>1. B"}.
  1164 \<close>
  1165 
  1166 print_translation \<open>
  1167   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
  1168 \<close> \<comment> \<open>to avoid eta-contraction of body\<close>
  1169 
  1170 lemma UNION_eq:
  1171   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
  1172   by (auto intro!: SUP_eqI)
  1173 
  1174 lemma bind_UNION [code]:
  1175   "Set.bind A f = UNION A f"
  1176   by (simp add: bind_def UNION_eq)
  1177 
  1178 lemma member_bind [simp]:
  1179   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
  1180   by (simp add: bind_UNION)
  1181 
  1182 lemma Union_SetCompr_eq: "\<Union>{f x| x. P x} = {a. \<exists>x. P x \<and> a \<in> f x}"
  1183   by blast
  1184 
  1185 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
  1186   using Union_iff [of _ "B ` A"] by simp
  1187 
  1188 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
  1189   \<comment> \<open>The order of the premises presupposes that @{term A} is rigid;
  1190     @{term b} may be flexible.\<close>
  1191   by auto
  1192 
  1193 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
  1194   by auto
  1195 
  1196 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1197   by (fact SUP_upper)
  1198 
  1199 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1200   by (fact SUP_least)
  1201 
  1202 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1203   by blast
  1204 
  1205 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1206   by blast
  1207 
  1208 lemma UN_empty: "(\<Union>x\<in>{}. B x) = {}"
  1209   by (fact SUP_empty)
  1210 
  1211 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1212   by (fact SUP_bot) (* already simp *)
  1213 
  1214 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1215   by (fact SUP_absorb)
  1216 
  1217 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1218   by (fact SUP_insert)
  1219 
  1220 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1221   by (fact SUP_union)
  1222 
  1223 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1224   by blast
  1225 
  1226 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1227   by (fact SUP_le_iff)
  1228 
  1229 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1230   by (fact SUP_constant)
  1231 
  1232 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1233   by blast
  1234 
  1235 lemma UNION_empty_conv:
  1236   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1237   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1238   by (fact SUP_bot_conv)+ (* already simp *)
  1239 
  1240 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1241   by blast
  1242 
  1243 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1244   by blast
  1245 
  1246 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1247   by blast
  1248 
  1249 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1250   by safe (auto simp add: split_if_mem2)
  1251 
  1252 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1253   by (fact SUP_UNIV_bool_expand)
  1254 
  1255 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1256   by blast
  1257 
  1258 lemma UN_mono:
  1259   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1260     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1261   by (fact SUP_subset_mono)
  1262 
  1263 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1264   by blast
  1265 
  1266 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1267   by blast
  1268 
  1269 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1270   \<comment> \<open>NOT suitable for rewriting\<close>
  1271   by blast
  1272 
  1273 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1274   by blast
  1275 
  1276 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1277   by blast
  1278 
  1279 
  1280 subsubsection \<open>Distributive laws\<close>
  1281 
  1282 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1283   by (fact inf_Sup)
  1284 
  1285 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1286   by (fact sup_Inf)
  1287 
  1288 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1289   by (fact Sup_inf)
  1290 
  1291 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1292   by (rule sym) (rule INF_inf_distrib)
  1293 
  1294 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1295   by (rule sym) (rule SUP_sup_distrib)
  1296 
  1297 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)" \<comment> \<open>FIXME drop\<close>
  1298   by (simp add: INT_Int_distrib)
  1299 
  1300 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)" \<comment> \<open>FIXME drop\<close>
  1301   \<comment> \<open>Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5:\<close>
  1302   \<comment> \<open>Union of a family of unions\<close>
  1303   by (simp add: UN_Un_distrib)
  1304 
  1305 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1306   by (fact sup_INF)
  1307 
  1308 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1309   \<comment> \<open>Halmos, Naive Set Theory, page 35.\<close>
  1310   by (fact inf_SUP)
  1311 
  1312 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1313   by (fact SUP_inf_distrib2)
  1314 
  1315 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1316   by (fact INF_sup_distrib2)
  1317 
  1318 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1319   by (fact Sup_inf_eq_bot_iff)
  1320 
  1321 lemma SUP_UNION: "(SUP x:(UN y:A. g y). f x) = (SUP y:A. SUP x:g y. f x :: _ :: complete_lattice)"
  1322 by(rule order_antisym)(blast intro: SUP_least SUP_upper2)+
  1323 
  1324 subsection \<open>Injections and bijections\<close>
  1325 
  1326 lemma inj_on_Inter:
  1327   "S \<noteq> {} \<Longrightarrow> (\<And>A. A \<in> S \<Longrightarrow> inj_on f A) \<Longrightarrow> inj_on f (\<Inter>S)"
  1328   unfolding inj_on_def by blast
  1329 
  1330 lemma inj_on_INTER:
  1331   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> inj_on f (A i)) \<Longrightarrow> inj_on f (\<Inter>i \<in> I. A i)"
  1332   unfolding inj_on_def by safe simp
  1333 
  1334 lemma inj_on_UNION_chain:
  1335   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1336          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1337   shows "inj_on f (\<Union>i \<in> I. A i)"
  1338 proof -
  1339   {
  1340     fix i j x y
  1341     assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
  1342       and ***: "f x = f y"
  1343     have "x = y"
  1344     proof -
  1345       {
  1346         assume "A i \<le> A j"
  1347         with ** have "x \<in> A j" by auto
  1348         with INJ * ** *** have ?thesis
  1349         by(auto simp add: inj_on_def)
  1350       }
  1351       moreover
  1352       {
  1353         assume "A j \<le> A i"
  1354         with ** have "y \<in> A i" by auto
  1355         with INJ * ** *** have ?thesis
  1356         by(auto simp add: inj_on_def)
  1357       }
  1358       ultimately show ?thesis using CH * by blast
  1359     qed
  1360   }
  1361   then show ?thesis by (unfold inj_on_def UNION_eq) auto
  1362 qed
  1363 
  1364 lemma bij_betw_UNION_chain:
  1365   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1366          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
  1367   shows "bij_betw f (\<Union>i \<in> I. A i) (\<Union>i \<in> I. A' i)"
  1368 proof (unfold bij_betw_def, auto)
  1369   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1370   using BIJ bij_betw_def[of f] by auto
  1371   thus "inj_on f (\<Union>i \<in> I. A i)"
  1372   using CH inj_on_UNION_chain[of I A f] by auto
  1373 next
  1374   fix i x
  1375   assume *: "i \<in> I" "x \<in> A i"
  1376   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
  1377   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
  1378 next
  1379   fix i x'
  1380   assume *: "i \<in> I" "x' \<in> A' i"
  1381   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
  1382   then have "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
  1383     using * by blast
  1384   then show "x' \<in> f ` (\<Union>x\<in>I. A x)" by blast
  1385 qed
  1386 
  1387 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
  1388 lemma image_INT:
  1389    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
  1390     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1391   by (simp add: inj_on_def, auto) blast
  1392 
  1393 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1394   apply (simp add: bij_def)
  1395   apply (simp add: inj_on_def surj_def)
  1396   apply auto
  1397   apply blast
  1398   done
  1399 
  1400 lemma UNION_fun_upd:
  1401   "UNION J (A(i := B)) = UNION (J - {i}) A \<union> (if i \<in> J then B else {})"
  1402   by (auto simp add: set_eq_iff)
  1403   
  1404 
  1405 subsubsection \<open>Complement\<close>
  1406 
  1407 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1408   by (fact uminus_INF)
  1409 
  1410 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1411   by (fact uminus_SUP)
  1412 
  1413 
  1414 subsubsection \<open>Miniscoping and maxiscoping\<close>
  1415 
  1416 text \<open>\medskip Miniscoping: pushing in quantifiers and big Unions
  1417            and Intersections.\<close>
  1418 
  1419 lemma UN_simps [simp]:
  1420   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1421   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1422   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1423   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1424   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1425   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1426   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1427   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1428   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1429   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1430   by auto
  1431 
  1432 lemma INT_simps [simp]:
  1433   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1434   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1435   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1436   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1437   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1438   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1439   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1440   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1441   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1442   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1443   by auto
  1444 
  1445 lemma UN_ball_bex_simps [simp]:
  1446   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1447   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1448   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1449   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1450   by auto
  1451 
  1452 
  1453 text \<open>\medskip Maxiscoping: pulling out big Unions and Intersections.\<close>
  1454 
  1455 lemma UN_extend_simps:
  1456   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1457   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1458   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1459   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1460   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1461   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1462   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1463   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1464   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1465   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1466   by auto
  1467 
  1468 lemma INT_extend_simps:
  1469   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1470   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1471   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1472   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1473   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1474   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1475   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1476   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1477   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1478   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1479   by auto
  1480 
  1481 text \<open>Finally\<close>
  1482 
  1483 no_notation
  1484   less_eq (infix "\<sqsubseteq>" 50) and
  1485   less (infix "\<sqsubset>" 50)
  1486 
  1487 lemmas mem_simps =
  1488   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1489   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1490   \<comment> \<open>Each of these has ALREADY been added \<open>[simp]\<close> above.\<close>
  1491 
  1492 end
  1493