src/HOL/Complete_Partial_Order.thy
author paulson <lp15@cam.ac.uk>
Mon Feb 22 14:37:56 2016 +0000 (2016-02-22)
changeset 62379 340738057c8c
parent 62093 bd73a2279fcd
child 63612 7195acc2fe93
permissions -rw-r--r--
An assortment of useful lemmas about sums, norm, etc. Also: norm_conv_dist [symmetric] is now a simprule!
     1 (* Title:    HOL/Complete_Partial_Order.thy
     2    Author:   Brian Huffman, Portland State University
     3    Author:   Alexander Krauss, TU Muenchen
     4 *)
     5 
     6 section \<open>Chain-complete partial orders and their fixpoints\<close>
     7 
     8 theory Complete_Partial_Order
     9 imports Product_Type
    10 begin
    11 
    12 subsection \<open>Monotone functions\<close>
    13 
    14 text \<open>Dictionary-passing version of @{const Orderings.mono}.\<close>
    15 
    16 definition monotone :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> bool"
    17 where "monotone orda ordb f \<longleftrightarrow> (\<forall>x y. orda x y \<longrightarrow> ordb (f x) (f y))"
    18 
    19 lemma monotoneI[intro?]: "(\<And>x y. orda x y \<Longrightarrow> ordb (f x) (f y))
    20  \<Longrightarrow> monotone orda ordb f"
    21 unfolding monotone_def by iprover
    22 
    23 lemma monotoneD[dest?]: "monotone orda ordb f \<Longrightarrow> orda x y \<Longrightarrow> ordb (f x) (f y)"
    24 unfolding monotone_def by iprover
    25 
    26 
    27 subsection \<open>Chains\<close>
    28 
    29 text \<open>A chain is a totally-ordered set. Chains are parameterized over
    30   the order for maximal flexibility, since type classes are not enough.
    31 \<close>
    32 
    33 definition
    34   chain :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
    35 where
    36   "chain ord S \<longleftrightarrow> (\<forall>x\<in>S. \<forall>y\<in>S. ord x y \<or> ord y x)"
    37 
    38 lemma chainI:
    39   assumes "\<And>x y. x \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> ord x y \<or> ord y x"
    40   shows "chain ord S"
    41 using assms unfolding chain_def by fast
    42 
    43 lemma chainD:
    44   assumes "chain ord S" and "x \<in> S" and "y \<in> S"
    45   shows "ord x y \<or> ord y x"
    46 using assms unfolding chain_def by fast
    47 
    48 lemma chainE:
    49   assumes "chain ord S" and "x \<in> S" and "y \<in> S"
    50   obtains "ord x y" | "ord y x"
    51 using assms unfolding chain_def by fast
    52 
    53 lemma chain_empty: "chain ord {}"
    54 by(simp add: chain_def)
    55 
    56 lemma chain_equality: "chain op = A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x = y)"
    57 by(auto simp add: chain_def)
    58 
    59 lemma chain_subset:
    60   "\<lbrakk> chain ord A; B \<subseteq> A \<rbrakk>
    61   \<Longrightarrow> chain ord B"
    62 by(rule chainI)(blast dest: chainD)
    63 
    64 lemma chain_imageI: 
    65   assumes chain: "chain le_a Y"
    66   and mono: "\<And>x y. \<lbrakk> x \<in> Y; y \<in> Y; le_a x y \<rbrakk> \<Longrightarrow> le_b (f x) (f y)"
    67   shows "chain le_b (f ` Y)"
    68 by(blast intro: chainI dest: chainD[OF chain] mono)
    69 
    70 subsection \<open>Chain-complete partial orders\<close>
    71 
    72 text \<open>
    73   A ccpo has a least upper bound for any chain.  In particular, the
    74   empty set is a chain, so every ccpo must have a bottom element.
    75 \<close>
    76 
    77 class ccpo = order + Sup +
    78   assumes ccpo_Sup_upper: "\<lbrakk>chain (op \<le>) A; x \<in> A\<rbrakk> \<Longrightarrow> x \<le> Sup A"
    79   assumes ccpo_Sup_least: "\<lbrakk>chain (op \<le>) A; \<And>x. x \<in> A \<Longrightarrow> x \<le> z\<rbrakk> \<Longrightarrow> Sup A \<le> z"
    80 begin
    81 
    82 lemma chain_singleton: "Complete_Partial_Order.chain op \<le> {x}"
    83 by(rule chainI) simp
    84 
    85 lemma ccpo_Sup_singleton [simp]: "\<Squnion>{x} = x"
    86 by(rule antisym)(auto intro: ccpo_Sup_least ccpo_Sup_upper simp add: chain_singleton)
    87 
    88 subsection \<open>Transfinite iteration of a function\<close>
    89 
    90 context notes [[inductive_internals]] begin
    91 
    92 inductive_set iterates :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a set"
    93 for f :: "'a \<Rightarrow> 'a"
    94 where
    95   step: "x \<in> iterates f \<Longrightarrow> f x \<in> iterates f"
    96 | Sup: "chain (op \<le>) M \<Longrightarrow> \<forall>x\<in>M. x \<in> iterates f \<Longrightarrow> Sup M \<in> iterates f"
    97 
    98 end
    99 
   100 lemma iterates_le_f:
   101   "x \<in> iterates f \<Longrightarrow> monotone (op \<le>) (op \<le>) f \<Longrightarrow> x \<le> f x"
   102 by (induct x rule: iterates.induct)
   103   (force dest: monotoneD intro!: ccpo_Sup_upper ccpo_Sup_least)+
   104 
   105 lemma chain_iterates:
   106   assumes f: "monotone (op \<le>) (op \<le>) f"
   107   shows "chain (op \<le>) (iterates f)" (is "chain _ ?C")
   108 proof (rule chainI)
   109   fix x y assume "x \<in> ?C" "y \<in> ?C"
   110   then show "x \<le> y \<or> y \<le> x"
   111   proof (induct x arbitrary: y rule: iterates.induct)
   112     fix x y assume y: "y \<in> ?C"
   113     and IH: "\<And>z. z \<in> ?C \<Longrightarrow> x \<le> z \<or> z \<le> x"
   114     from y show "f x \<le> y \<or> y \<le> f x"
   115     proof (induct y rule: iterates.induct)
   116       case (step y) with IH f show ?case by (auto dest: monotoneD)
   117     next
   118       case (Sup M)
   119       then have chM: "chain (op \<le>) M"
   120         and IH': "\<And>z. z \<in> M \<Longrightarrow> f x \<le> z \<or> z \<le> f x" by auto
   121       show "f x \<le> Sup M \<or> Sup M \<le> f x"
   122       proof (cases "\<exists>z\<in>M. f x \<le> z")
   123         case True then have "f x \<le> Sup M"
   124           apply rule
   125           apply (erule order_trans)
   126           by (rule ccpo_Sup_upper[OF chM])
   127         thus ?thesis ..
   128       next
   129         case False with IH'
   130         show ?thesis by (auto intro: ccpo_Sup_least[OF chM])
   131       qed
   132     qed
   133   next
   134     case (Sup M y)
   135     show ?case
   136     proof (cases "\<exists>x\<in>M. y \<le> x")
   137       case True then have "y \<le> Sup M"
   138         apply rule
   139         apply (erule order_trans)
   140         by (rule ccpo_Sup_upper[OF Sup(1)])
   141       thus ?thesis ..
   142     next
   143       case False with Sup
   144       show ?thesis by (auto intro: ccpo_Sup_least)
   145     qed
   146   qed
   147 qed
   148 
   149 lemma bot_in_iterates: "Sup {} \<in> iterates f"
   150 by(auto intro: iterates.Sup simp add: chain_empty)
   151 
   152 subsection \<open>Fixpoint combinator\<close>
   153 
   154 definition
   155   fixp :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a"
   156 where
   157   "fixp f = Sup (iterates f)"
   158 
   159 lemma iterates_fixp:
   160   assumes f: "monotone (op \<le>) (op \<le>) f" shows "fixp f \<in> iterates f"
   161 unfolding fixp_def
   162 by (simp add: iterates.Sup chain_iterates f)
   163 
   164 lemma fixp_unfold:
   165   assumes f: "monotone (op \<le>) (op \<le>) f"
   166   shows "fixp f = f (fixp f)"
   167 proof (rule antisym)
   168   show "fixp f \<le> f (fixp f)"
   169     by (intro iterates_le_f iterates_fixp f)
   170   have "f (fixp f) \<le> Sup (iterates f)"
   171     by (intro ccpo_Sup_upper chain_iterates f iterates.step iterates_fixp)
   172   thus "f (fixp f) \<le> fixp f"
   173     unfolding fixp_def .
   174 qed
   175 
   176 lemma fixp_lowerbound:
   177   assumes f: "monotone (op \<le>) (op \<le>) f" and z: "f z \<le> z" shows "fixp f \<le> z"
   178 unfolding fixp_def
   179 proof (rule ccpo_Sup_least[OF chain_iterates[OF f]])
   180   fix x assume "x \<in> iterates f"
   181   thus "x \<le> z"
   182   proof (induct x rule: iterates.induct)
   183     fix x assume "x \<le> z" with f have "f x \<le> f z" by (rule monotoneD)
   184     also note z finally show "f x \<le> z" .
   185   qed (auto intro: ccpo_Sup_least)
   186 qed
   187 
   188 end
   189 
   190 subsection \<open>Fixpoint induction\<close>
   191 
   192 setup \<open>Sign.map_naming (Name_Space.mandatory_path "ccpo")\<close>
   193 
   194 definition admissible :: "('a set \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
   195 where "admissible lub ord P = (\<forall>A. chain ord A \<longrightarrow> (A \<noteq> {}) \<longrightarrow> (\<forall>x\<in>A. P x) \<longrightarrow> P (lub A))"
   196 
   197 lemma admissibleI:
   198   assumes "\<And>A. chain ord A \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<forall>x\<in>A. P x \<Longrightarrow> P (lub A)"
   199   shows "ccpo.admissible lub ord P"
   200 using assms unfolding ccpo.admissible_def by fast
   201 
   202 lemma admissibleD:
   203   assumes "ccpo.admissible lub ord P"
   204   assumes "chain ord A"
   205   assumes "A \<noteq> {}"
   206   assumes "\<And>x. x \<in> A \<Longrightarrow> P x"
   207   shows "P (lub A)"
   208 using assms by (auto simp: ccpo.admissible_def)
   209 
   210 setup \<open>Sign.map_naming Name_Space.parent_path\<close>
   211 
   212 lemma (in ccpo) fixp_induct:
   213   assumes adm: "ccpo.admissible Sup (op \<le>) P"
   214   assumes mono: "monotone (op \<le>) (op \<le>) f"
   215   assumes bot: "P (Sup {})"
   216   assumes step: "\<And>x. P x \<Longrightarrow> P (f x)"
   217   shows "P (fixp f)"
   218 unfolding fixp_def using adm chain_iterates[OF mono]
   219 proof (rule ccpo.admissibleD)
   220   show "iterates f \<noteq> {}" using bot_in_iterates by auto
   221   fix x assume "x \<in> iterates f"
   222   thus "P x"
   223     by (induct rule: iterates.induct)
   224       (case_tac "M = {}", auto intro: step bot ccpo.admissibleD adm)
   225 qed
   226 
   227 lemma admissible_True: "ccpo.admissible lub ord (\<lambda>x. True)"
   228 unfolding ccpo.admissible_def by simp
   229 
   230 (*lemma admissible_False: "\<not> ccpo.admissible lub ord (\<lambda>x. False)"
   231 unfolding ccpo.admissible_def chain_def by simp
   232 *)
   233 lemma admissible_const: "ccpo.admissible lub ord (\<lambda>x. t)"
   234 by(auto intro: ccpo.admissibleI)
   235 
   236 lemma admissible_conj:
   237   assumes "ccpo.admissible lub ord (\<lambda>x. P x)"
   238   assumes "ccpo.admissible lub ord (\<lambda>x. Q x)"
   239   shows "ccpo.admissible lub ord (\<lambda>x. P x \<and> Q x)"
   240 using assms unfolding ccpo.admissible_def by simp
   241 
   242 lemma admissible_all:
   243   assumes "\<And>y. ccpo.admissible lub ord (\<lambda>x. P x y)"
   244   shows "ccpo.admissible lub ord (\<lambda>x. \<forall>y. P x y)"
   245 using assms unfolding ccpo.admissible_def by fast
   246 
   247 lemma admissible_ball:
   248   assumes "\<And>y. y \<in> A \<Longrightarrow> ccpo.admissible lub ord (\<lambda>x. P x y)"
   249   shows "ccpo.admissible lub ord (\<lambda>x. \<forall>y\<in>A. P x y)"
   250 using assms unfolding ccpo.admissible_def by fast
   251 
   252 lemma chain_compr: "chain ord A \<Longrightarrow> chain ord {x \<in> A. P x}"
   253 unfolding chain_def by fast
   254 
   255 context ccpo begin
   256 
   257 lemma admissible_disj_lemma:
   258   assumes A: "chain (op \<le>)A"
   259   assumes P: "\<forall>x\<in>A. \<exists>y\<in>A. x \<le> y \<and> P y"
   260   shows "Sup A = Sup {x \<in> A. P x}"
   261 proof (rule antisym)
   262   have *: "chain (op \<le>) {x \<in> A. P x}"
   263     by (rule chain_compr [OF A])
   264   show "Sup A \<le> Sup {x \<in> A. P x}"
   265     apply (rule ccpo_Sup_least [OF A])
   266     apply (drule P [rule_format], clarify)
   267     apply (erule order_trans)
   268     apply (simp add: ccpo_Sup_upper [OF *])
   269     done
   270   show "Sup {x \<in> A. P x} \<le> Sup A"
   271     apply (rule ccpo_Sup_least [OF *])
   272     apply clarify
   273     apply (simp add: ccpo_Sup_upper [OF A])
   274     done
   275 qed
   276 
   277 lemma admissible_disj:
   278   fixes P Q :: "'a \<Rightarrow> bool"
   279   assumes P: "ccpo.admissible Sup (op \<le>) (\<lambda>x. P x)"
   280   assumes Q: "ccpo.admissible Sup (op \<le>) (\<lambda>x. Q x)"
   281   shows "ccpo.admissible Sup (op \<le>) (\<lambda>x. P x \<or> Q x)"
   282 proof (rule ccpo.admissibleI)
   283   fix A :: "'a set" assume A: "chain (op \<le>) A"
   284   assume "A \<noteq> {}"
   285     and "\<forall>x\<in>A. P x \<or> Q x"
   286   hence "(\<exists>x\<in>A. P x) \<and> (\<forall>x\<in>A. \<exists>y\<in>A. x \<le> y \<and> P y) \<or> (\<exists>x\<in>A. Q x) \<and> (\<forall>x\<in>A. \<exists>y\<in>A. x \<le> y \<and> Q y)"
   287     using chainD[OF A] by blast
   288   hence "(\<exists>x. x \<in> A \<and> P x) \<and> Sup A = Sup {x \<in> A. P x} \<or> (\<exists>x. x \<in> A \<and> Q x) \<and> Sup A = Sup {x \<in> A. Q x}"
   289     using admissible_disj_lemma [OF A] by blast
   290   thus "P (Sup A) \<or> Q (Sup A)"
   291     apply (rule disjE, simp_all)
   292     apply (rule disjI1, rule ccpo.admissibleD [OF P chain_compr [OF A]], simp, simp)
   293     apply (rule disjI2, rule ccpo.admissibleD [OF Q chain_compr [OF A]], simp, simp)
   294     done
   295 qed
   296 
   297 end
   298 
   299 instance complete_lattice \<subseteq> ccpo
   300   by standard (fast intro: Sup_upper Sup_least)+
   301 
   302 lemma lfp_eq_fixp:
   303   assumes f: "mono f" shows "lfp f = fixp f"
   304 proof (rule antisym)
   305   from f have f': "monotone (op \<le>) (op \<le>) f"
   306     unfolding mono_def monotone_def .
   307   show "lfp f \<le> fixp f"
   308     by (rule lfp_lowerbound, subst fixp_unfold [OF f'], rule order_refl)
   309   show "fixp f \<le> lfp f"
   310     by (rule fixp_lowerbound [OF f'], subst lfp_unfold [OF f], rule order_refl)
   311 qed
   312 
   313 hide_const (open) iterates fixp
   314 
   315 end