src/HOL/Fun.thy
author paulson <lp15@cam.ac.uk>
Mon Feb 22 14:37:56 2016 +0000 (2016-02-22)
changeset 62379 340738057c8c
parent 61955 e96292f32c3c
child 62390 842917225d56
permissions -rw-r--r--
An assortment of useful lemmas about sums, norm, etc. Also: norm_conv_dist [symmetric] is now a simprule!
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Author:     Andrei Popescu, TU Muenchen
     4     Copyright   1994, 2012
     5 *)
     6 
     7 section \<open>Notions about functions\<close>
     8 
     9 theory Fun
    10 imports Set
    11 keywords "functor" :: thy_goal
    12 begin
    13 
    14 lemma apply_inverse:
    15   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    16   by auto
    17 
    18 text\<open>Uniqueness, so NOT the axiom of choice.\<close>
    19 lemma uniq_choice: "\<forall>x. \<exists>!y. Q x y \<Longrightarrow> \<exists>f. \<forall>x. Q x (f x)"
    20   by (force intro: theI')
    21 
    22 lemma b_uniq_choice: "\<forall>x\<in>S. \<exists>!y. Q x y \<Longrightarrow> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    23   by (force intro: theI')
    24 
    25 subsection \<open>The Identity Function \<open>id\<close>\<close>
    26 
    27 definition id :: "'a \<Rightarrow> 'a" where
    28   "id = (\<lambda>x. x)"
    29 
    30 lemma id_apply [simp]: "id x = x"
    31   by (simp add: id_def)
    32 
    33 lemma image_id [simp]: "image id = id"
    34   by (simp add: id_def fun_eq_iff)
    35 
    36 lemma vimage_id [simp]: "vimage id = id"
    37   by (simp add: id_def fun_eq_iff)
    38 
    39 code_printing
    40   constant id \<rightharpoonup> (Haskell) "id"
    41 
    42 
    43 subsection \<open>The Composition Operator \<open>f \<circ> g\<close>\<close>
    44 
    45 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c"  (infixl "\<circ>" 55)
    46   where "f \<circ> g = (\<lambda>x. f (g x))"
    47 
    48 notation (ASCII)
    49   comp  (infixl "o" 55)
    50 
    51 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    52   by (simp add: comp_def)
    53 
    54 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    55   by (simp add: fun_eq_iff)
    56 
    57 lemma id_comp [simp]: "id o g = g"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma comp_id [simp]: "f o id = f"
    61   by (simp add: fun_eq_iff)
    62 
    63 lemma comp_eq_dest:
    64   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    65   by (simp add: fun_eq_iff)
    66 
    67 lemma comp_eq_elim:
    68   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    69   by (simp add: fun_eq_iff)
    70 
    71 lemma comp_eq_dest_lhs: "a o b = c \<Longrightarrow> a (b v) = c v"
    72   by clarsimp
    73 
    74 lemma comp_eq_id_dest: "a o b = id o c \<Longrightarrow> a (b v) = c v"
    75   by clarsimp
    76 
    77 lemma image_comp:
    78   "f ` (g ` r) = (f o g) ` r"
    79   by auto
    80 
    81 lemma vimage_comp:
    82   "f -` (g -` x) = (g \<circ> f) -` x"
    83   by auto
    84 
    85 lemma image_eq_imp_comp: "f ` A = g ` B \<Longrightarrow> (h o f) ` A = (h o g) ` B"
    86   by (auto simp: comp_def elim!: equalityE)
    87 
    88 lemma image_bind: "f ` (Set.bind A g) = Set.bind A (op ` f \<circ> g)"
    89 by(auto simp add: Set.bind_def)
    90 
    91 lemma bind_image: "Set.bind (f ` A) g = Set.bind A (g \<circ> f)"
    92 by(auto simp add: Set.bind_def)
    93 
    94 lemma (in group_add) minus_comp_minus [simp]:
    95   "uminus \<circ> uminus = id"
    96   by (simp add: fun_eq_iff)
    97 
    98 lemma (in boolean_algebra) minus_comp_minus [simp]:
    99   "uminus \<circ> uminus = id"
   100   by (simp add: fun_eq_iff)
   101 
   102 code_printing
   103   constant comp \<rightharpoonup> (SML) infixl 5 "o" and (Haskell) infixr 9 "."
   104 
   105 
   106 subsection \<open>The Forward Composition Operator \<open>fcomp\<close>\<close>
   107 
   108 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
   109   "f \<circ>> g = (\<lambda>x. g (f x))"
   110 
   111 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   112   by (simp add: fcomp_def)
   113 
   114 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   115   by (simp add: fcomp_def)
   116 
   117 lemma id_fcomp [simp]: "id \<circ>> g = g"
   118   by (simp add: fcomp_def)
   119 
   120 lemma fcomp_id [simp]: "f \<circ>> id = f"
   121   by (simp add: fcomp_def)
   122 
   123 lemma fcomp_comp: "fcomp f g = comp g f" 
   124   by (simp add: ext)
   125 
   126 code_printing
   127   constant fcomp \<rightharpoonup> (Eval) infixl 1 "#>"
   128 
   129 no_notation fcomp (infixl "\<circ>>" 60)
   130 
   131 
   132 subsection \<open>Mapping functions\<close>
   133 
   134 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   135   "map_fun f g h = g \<circ> h \<circ> f"
   136 
   137 lemma map_fun_apply [simp]:
   138   "map_fun f g h x = g (h (f x))"
   139   by (simp add: map_fun_def)
   140 
   141 
   142 subsection \<open>Injectivity and Bijectivity\<close>
   143 
   144 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where \<comment> "injective"
   145   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   146 
   147 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where \<comment> "bijective"
   148   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   149 
   150 text\<open>A common special case: functions injective, surjective or bijective over
   151 the entire domain type.\<close>
   152 
   153 abbreviation
   154   "inj f \<equiv> inj_on f UNIV"
   155 
   156 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where \<comment> "surjective"
   157   "surj f \<equiv> (range f = UNIV)"
   158 
   159 abbreviation
   160   "bij f \<equiv> bij_betw f UNIV UNIV"
   161 
   162 text\<open>The negated case:\<close>
   163 translations
   164 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   165 
   166 lemma injI:
   167   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   168   shows "inj f"
   169   using assms unfolding inj_on_def by auto
   170 
   171 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   172   by (unfold inj_on_def, blast)
   173 
   174 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   175 by (simp add: inj_on_def)
   176 
   177 lemma inj_on_eq_iff: "\<lbrakk>inj_on f A; x \<in> A; y \<in> A\<rbrakk> \<Longrightarrow> (f x = f y) = (x = y)"
   178 by (force simp add: inj_on_def)
   179 
   180 lemma inj_on_cong:
   181   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   182 unfolding inj_on_def by auto
   183 
   184 lemma inj_on_strict_subset:
   185   "inj_on f B \<Longrightarrow> A \<subset> B \<Longrightarrow> f ` A \<subset> f ` B"
   186   unfolding inj_on_def by blast
   187 
   188 lemma inj_comp:
   189   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   190   by (simp add: inj_on_def)
   191 
   192 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   193   by (simp add: inj_on_def fun_eq_iff)
   194 
   195 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   196 by (simp add: inj_on_eq_iff)
   197 
   198 lemma inj_on_id[simp]: "inj_on id A"
   199   by (simp add: inj_on_def)
   200 
   201 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   202 by (simp add: inj_on_def)
   203 
   204 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   205 unfolding inj_on_def by blast
   206 
   207 lemma surj_id: "surj id"
   208 by simp
   209 
   210 lemma bij_id[simp]: "bij id"
   211 by (simp add: bij_betw_def)
   212 
   213 lemma inj_onI:
   214     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   215 by (simp add: inj_on_def)
   216 
   217 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   218 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   219 
   220 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   221 by (unfold inj_on_def, blast)
   222 
   223 lemma comp_inj_on:
   224      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   225 by (simp add: comp_def inj_on_def)
   226 
   227 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   228   by (simp add: inj_on_def) blast
   229 
   230 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   231   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   232 apply(unfold inj_on_def)
   233 apply blast
   234 done
   235 
   236 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   237 by (unfold inj_on_def, blast)
   238 
   239 lemma inj_singleton: "inj (%s. {s})"
   240 by (simp add: inj_on_def)
   241 
   242 lemma inj_on_empty[iff]: "inj_on f {}"
   243 by(simp add: inj_on_def)
   244 
   245 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   246 by (unfold inj_on_def, blast)
   247 
   248 lemma inj_on_Un:
   249  "inj_on f (A Un B) =
   250   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   251 apply(unfold inj_on_def)
   252 apply (blast intro:sym)
   253 done
   254 
   255 lemma inj_on_insert[iff]:
   256   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   257 apply(unfold inj_on_def)
   258 apply (blast intro:sym)
   259 done
   260 
   261 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   262 apply(unfold inj_on_def)
   263 apply (blast)
   264 done
   265 
   266 lemma comp_inj_on_iff:
   267   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   268 by(auto simp add: comp_inj_on inj_on_def)
   269 
   270 lemma inj_on_imageI2:
   271   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   272 by(auto simp add: comp_inj_on inj_on_def)
   273 
   274 lemma inj_img_insertE:
   275   assumes "inj_on f A"
   276   assumes "x \<notin> B" and "insert x B = f ` A"
   277   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   278     and "x = f x'" and "B = f ` A'"
   279 proof -
   280   from assms have "x \<in> f ` A" by auto
   281   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   282   then have "A = insert x' (A - {x'})" by auto
   283   with assms * have "B = f ` (A - {x'})"
   284     by (auto dest: inj_on_contraD)
   285   have "x' \<notin> A - {x'}" by simp
   286   from \<open>x' \<notin> A - {x'}\<close> \<open>A = insert x' (A - {x'})\<close> \<open>x = f x'\<close> \<open>B = image f (A - {x'})\<close>
   287   show ?thesis ..
   288 qed
   289 
   290 lemma linorder_injI:
   291   assumes hyp: "\<And>x y. x < (y::'a::linorder) \<Longrightarrow> f x \<noteq> f y"
   292   shows "inj f"
   293   \<comment> \<open>Courtesy of Stephan Merz\<close>
   294 proof (rule inj_onI)
   295   fix x y
   296   assume f_eq: "f x = f y"
   297   show "x = y" by (rule linorder_cases) (auto dest: hyp simp: f_eq)
   298 qed
   299 
   300 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   301   by auto
   302 
   303 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   304   using *[symmetric] by auto
   305 
   306 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   307   by (simp add: surj_def)
   308 
   309 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   310   by (simp add: surj_def, blast)
   311 
   312 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   313 apply (simp add: comp_def surj_def, clarify)
   314 apply (drule_tac x = y in spec, clarify)
   315 apply (drule_tac x = x in spec, blast)
   316 done
   317 
   318 lemma bij_betw_imageI:
   319   "\<lbrakk> inj_on f A; f ` A = B \<rbrakk> \<Longrightarrow> bij_betw f A B"
   320 unfolding bij_betw_def by clarify
   321 
   322 lemma bij_betw_imp_surj_on: "bij_betw f A B \<Longrightarrow> f ` A = B"
   323   unfolding bij_betw_def by clarify
   324 
   325 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   326   unfolding bij_betw_def by auto
   327 
   328 lemma bij_betw_empty1:
   329   assumes "bij_betw f {} A"
   330   shows "A = {}"
   331 using assms unfolding bij_betw_def by blast
   332 
   333 lemma bij_betw_empty2:
   334   assumes "bij_betw f A {}"
   335   shows "A = {}"
   336 using assms unfolding bij_betw_def by blast
   337 
   338 lemma inj_on_imp_bij_betw:
   339   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   340 unfolding bij_betw_def by simp
   341 
   342 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   343   unfolding bij_betw_def ..
   344 
   345 lemma bijI: "[| inj f; surj f |] ==> bij f"
   346 by (simp add: bij_def)
   347 
   348 lemma bij_is_inj: "bij f ==> inj f"
   349 by (simp add: bij_def)
   350 
   351 lemma bij_is_surj: "bij f ==> surj f"
   352 by (simp add: bij_def)
   353 
   354 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   355 by (simp add: bij_betw_def)
   356 
   357 lemma bij_betw_trans:
   358   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   359 by(auto simp add:bij_betw_def comp_inj_on)
   360 
   361 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   362   by (rule bij_betw_trans)
   363 
   364 lemma bij_betw_comp_iff:
   365   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   366 by(auto simp add: bij_betw_def inj_on_def)
   367 
   368 lemma bij_betw_comp_iff2:
   369   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   370   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   371 using assms
   372 proof(auto simp add: bij_betw_comp_iff)
   373   assume *: "bij_betw (f' \<circ> f) A A''"
   374   thus "bij_betw f A A'"
   375   using IM
   376   proof(auto simp add: bij_betw_def)
   377     assume "inj_on (f' \<circ> f) A"
   378     thus "inj_on f A" using inj_on_imageI2 by blast
   379   next
   380     fix a' assume **: "a' \<in> A'"
   381     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   382     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   383     unfolding bij_betw_def by force
   384     hence "f a \<in> A'" using IM by auto
   385     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   386     thus "a' \<in> f ` A" using 1 by auto
   387   qed
   388 qed
   389 
   390 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   391 proof -
   392   have i: "inj_on f A" and s: "f ` A = B"
   393     using assms by(auto simp:bij_betw_def)
   394   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   395   { fix a b assume P: "?P b a"
   396     hence ex1: "\<exists>a. ?P b a" using s by blast
   397     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   398     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   399   } note g = this
   400   have "inj_on ?g B"
   401   proof(rule inj_onI)
   402     fix x y assume "x:B" "y:B" "?g x = ?g y"
   403     from s \<open>x:B\<close> obtain a1 where a1: "?P x a1" by blast
   404     from s \<open>y:B\<close> obtain a2 where a2: "?P y a2" by blast
   405     from g[OF a1] a1 g[OF a2] a2 \<open>?g x = ?g y\<close> show "x=y" by simp
   406   qed
   407   moreover have "?g ` B = A"
   408   proof(auto simp: image_def)
   409     fix b assume "b:B"
   410     with s obtain a where P: "?P b a" by blast
   411     thus "?g b \<in> A" using g[OF P] by auto
   412   next
   413     fix a assume "a:A"
   414     then obtain b where P: "?P b a" using s by blast
   415     then have "b:B" using s by blast
   416     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   417   qed
   418   ultimately show ?thesis by(auto simp:bij_betw_def)
   419 qed
   420 
   421 lemma bij_betw_cong:
   422   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   423 unfolding bij_betw_def inj_on_def by force
   424 
   425 lemma bij_betw_id[intro, simp]:
   426   "bij_betw id A A"
   427 unfolding bij_betw_def id_def by auto
   428 
   429 lemma bij_betw_id_iff:
   430   "bij_betw id A B \<longleftrightarrow> A = B"
   431 by(auto simp add: bij_betw_def)
   432 
   433 lemma bij_betw_combine:
   434   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   435   shows "bij_betw f (A \<union> C) (B \<union> D)"
   436   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   437 
   438 lemma bij_betw_subset:
   439   assumes BIJ: "bij_betw f A A'" and
   440           SUB: "B \<le> A" and IM: "f ` B = B'"
   441   shows "bij_betw f B B'"
   442 using assms
   443 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   444 
   445 lemma bij_pointE:
   446   assumes "bij f"
   447   obtains x where "y = f x" and "\<And>x'. y = f x' \<Longrightarrow> x' = x"
   448 proof -
   449   from assms have "inj f" by (rule bij_is_inj)
   450   moreover from assms have "surj f" by (rule bij_is_surj)
   451   then have "y \<in> range f" by simp
   452   ultimately have "\<exists>!x. y = f x" by (simp add: range_ex1_eq)
   453   with that show thesis by blast
   454 qed
   455 
   456 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   457 by simp
   458 
   459 lemma surj_vimage_empty:
   460   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   461   using surj_image_vimage_eq[OF \<open>surj f\<close>, of A]
   462   by (intro iffI) fastforce+
   463 
   464 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   465 by (simp add: inj_on_def, blast)
   466 
   467 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   468 by (blast intro: sym)
   469 
   470 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   471 by (unfold inj_on_def, blast)
   472 
   473 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   474 apply (unfold bij_def)
   475 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   476 done
   477 
   478 lemma inj_on_image_eq_iff: "\<lbrakk> inj_on f C; A \<subseteq> C; B \<subseteq> C \<rbrakk> \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   479 by(fastforce simp add: inj_on_def)
   480 
   481 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   482 by(erule inj_on_image_eq_iff) simp_all
   483 
   484 lemma inj_on_image_Int:
   485    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   486   by (simp add: inj_on_def, blast)
   487 
   488 lemma inj_on_image_set_diff:
   489    "[| inj_on f C;  A-B \<subseteq> C;  B \<subseteq> C |] ==> f`(A-B) = f`A - f`B"
   490   by (simp add: inj_on_def, blast)
   491 
   492 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   493   by (simp add: inj_on_def, blast)
   494 
   495 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   496 by (simp add: inj_on_def, blast)
   497 
   498 lemma inj_on_image_mem_iff: "\<lbrakk>inj_on f B; a \<in> B; A \<subseteq> B\<rbrakk> \<Longrightarrow> f a \<in> f`A \<longleftrightarrow> a \<in> A"
   499   by (auto simp: inj_on_def)
   500 
   501 (*FIXME DELETE*)
   502 lemma inj_on_image_mem_iff_alt: "inj_on f B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f a \<in> f`A \<Longrightarrow> a \<in> B \<Longrightarrow> a \<in> A"
   503   by (blast dest: inj_onD)
   504 
   505 lemma inj_image_mem_iff: "inj f \<Longrightarrow> f a \<in> f`A \<longleftrightarrow> a \<in> A"
   506   by (blast dest: injD)
   507 
   508 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   509   by (blast dest: injD)
   510 
   511 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   512   by (blast dest: injD)
   513 
   514 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   515 by auto
   516 
   517 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   518 by (auto simp add: inj_on_def)
   519 
   520 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   521 apply (simp add: bij_def)
   522 apply (rule equalityI)
   523 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   524 done
   525 
   526 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   527   \<comment> \<open>The inverse image of a singleton under an injective function
   528          is included in a singleton.\<close>
   529   apply (auto simp add: inj_on_def)
   530   apply (blast intro: the_equality [symmetric])
   531   done
   532 
   533 lemma inj_on_vimage_singleton:
   534   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   535   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   536 
   537 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   538   by (auto intro!: inj_onI)
   539 
   540 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   541   by (auto intro!: inj_onI dest: strict_mono_eq)
   542 
   543 lemma bij_betw_byWitness:
   544 assumes LEFT: "\<forall>a \<in> A. f'(f a) = a" and
   545         RIGHT: "\<forall>a' \<in> A'. f(f' a') = a'" and
   546         IM1: "f ` A \<le> A'" and IM2: "f' ` A' \<le> A"
   547 shows "bij_betw f A A'"
   548 using assms
   549 proof(unfold bij_betw_def inj_on_def, safe)
   550   fix a b assume *: "a \<in> A" "b \<in> A" and **: "f a = f b"
   551   have "a = f'(f a) \<and> b = f'(f b)" using * LEFT by simp
   552   with ** show "a = b" by simp
   553 next
   554   fix a' assume *: "a' \<in> A'"
   555   hence "f' a' \<in> A" using IM2 by blast
   556   moreover
   557   have "a' = f(f' a')" using * RIGHT by simp
   558   ultimately show "a' \<in> f ` A" by blast
   559 qed
   560 
   561 corollary notIn_Un_bij_betw:
   562 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'" and
   563        BIJ: "bij_betw f A A'"
   564 shows "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   565 proof-
   566   have "bij_betw f {b} {f b}"
   567   unfolding bij_betw_def inj_on_def by simp
   568   with assms show ?thesis
   569   using bij_betw_combine[of f A A' "{b}" "{f b}"] by blast
   570 qed
   571 
   572 lemma notIn_Un_bij_betw3:
   573 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'"
   574 shows "bij_betw f A A' = bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   575 proof
   576   assume "bij_betw f A A'"
   577   thus "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   578   using assms notIn_Un_bij_betw[of b A f A'] by blast
   579 next
   580   assume *: "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   581   have "f ` A = A'"
   582   proof(auto)
   583     fix a assume **: "a \<in> A"
   584     hence "f a \<in> A' \<union> {f b}" using * unfolding bij_betw_def by blast
   585     moreover
   586     {assume "f a = f b"
   587      hence "a = b" using * ** unfolding bij_betw_def inj_on_def by blast
   588      with NIN ** have False by blast
   589     }
   590     ultimately show "f a \<in> A'" by blast
   591   next
   592     fix a' assume **: "a' \<in> A'"
   593     hence "a' \<in> f`(A \<union> {b})"
   594     using * by (auto simp add: bij_betw_def)
   595     then obtain a where 1: "a \<in> A \<union> {b} \<and> f a = a'" by blast
   596     moreover
   597     {assume "a = b" with 1 ** NIN' have False by blast
   598     }
   599     ultimately have "a \<in> A" by blast
   600     with 1 show "a' \<in> f ` A" by blast
   601   qed
   602   thus "bij_betw f A A'" using * bij_betw_subset[of f "A \<union> {b}" _ A] by blast
   603 qed
   604 
   605 
   606 subsection\<open>Function Updating\<close>
   607 
   608 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   609   "fun_upd f a b == % x. if x=a then b else f x"
   610 
   611 nonterminal updbinds and updbind
   612 
   613 syntax
   614   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   615   ""         :: "updbind => updbinds"             ("_")
   616   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   617   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   618 
   619 translations
   620   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   621   "f(x:=y)" == "CONST fun_upd f x y"
   622 
   623 (* Hint: to define the sum of two functions (or maps), use case_sum.
   624          A nice infix syntax could be defined by
   625 notation
   626   case_sum  (infixr "'(+')"80)
   627 *)
   628 
   629 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   630 apply (simp add: fun_upd_def, safe)
   631 apply (erule subst)
   632 apply (rule_tac [2] ext, auto)
   633 done
   634 
   635 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   636   by (simp only: fun_upd_idem_iff)
   637 
   638 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   639   by (simp only: fun_upd_idem)
   640 
   641 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   642 by (simp add: fun_upd_def)
   643 
   644 (* fun_upd_apply supersedes these two,   but they are useful
   645    if fun_upd_apply is intentionally removed from the simpset *)
   646 lemma fun_upd_same: "(f(x:=y)) x = y"
   647 by simp
   648 
   649 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   650 by simp
   651 
   652 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   653 by (simp add: fun_eq_iff)
   654 
   655 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   656 by (rule ext, auto)
   657 
   658 lemma inj_on_fun_updI:
   659   "inj_on f A \<Longrightarrow> y \<notin> f ` A \<Longrightarrow> inj_on (f(x := y)) A"
   660   by (fastforce simp: inj_on_def)
   661 
   662 lemma fun_upd_image:
   663      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   664 by auto
   665 
   666 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   667   by auto
   668 
   669 lemma fun_upd_eqD: "f(x := y) = g(x := z) \<Longrightarrow> y = z"
   670 by(simp add: fun_eq_iff split: split_if_asm)
   671 
   672 subsection \<open>\<open>override_on\<close>\<close>
   673 
   674 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   675   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   676 
   677 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   678 by(simp add:override_on_def)
   679 
   680 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   681 by(simp add:override_on_def)
   682 
   683 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   684 by(simp add:override_on_def)
   685 
   686 
   687 subsection \<open>\<open>swap\<close>\<close>
   688 
   689 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   690 where
   691   "swap a b f = f (a := f b, b:= f a)"
   692 
   693 lemma swap_apply [simp]:
   694   "swap a b f a = f b"
   695   "swap a b f b = f a"
   696   "c \<noteq> a \<Longrightarrow> c \<noteq> b \<Longrightarrow> swap a b f c = f c"
   697   by (simp_all add: swap_def)
   698 
   699 lemma swap_self [simp]:
   700   "swap a a f = f"
   701   by (simp add: swap_def)
   702 
   703 lemma swap_commute:
   704   "swap a b f = swap b a f"
   705   by (simp add: fun_upd_def swap_def fun_eq_iff)
   706 
   707 lemma swap_nilpotent [simp]:
   708   "swap a b (swap a b f) = f"
   709   by (rule ext, simp add: fun_upd_def swap_def)
   710 
   711 lemma swap_comp_involutory [simp]:
   712   "swap a b \<circ> swap a b = id"
   713   by (rule ext) simp
   714 
   715 lemma swap_triple:
   716   assumes "a \<noteq> c" and "b \<noteq> c"
   717   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   718   using assms by (simp add: fun_eq_iff swap_def)
   719 
   720 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   721   by (rule ext, simp add: fun_upd_def swap_def)
   722 
   723 lemma swap_image_eq [simp]:
   724   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   725 proof -
   726   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   727     using assms by (auto simp: image_iff swap_def)
   728   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   729   with subset[of f] show ?thesis by auto
   730 qed
   731 
   732 lemma inj_on_imp_inj_on_swap:
   733   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   734   by (simp add: inj_on_def swap_def, blast)
   735 
   736 lemma inj_on_swap_iff [simp]:
   737   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   738 proof
   739   assume "inj_on (swap a b f) A"
   740   with A have "inj_on (swap a b (swap a b f)) A"
   741     by (iprover intro: inj_on_imp_inj_on_swap)
   742   thus "inj_on f A" by simp
   743 next
   744   assume "inj_on f A"
   745   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   746 qed
   747 
   748 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   749   by simp
   750 
   751 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   752   by simp
   753 
   754 lemma bij_betw_swap_iff [simp]:
   755   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   756   by (auto simp: bij_betw_def)
   757 
   758 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   759   by simp
   760 
   761 hide_const (open) swap
   762 
   763 
   764 subsection \<open>Inversion of injective functions\<close>
   765 
   766 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   767   "the_inv_into A f == %x. THE y. y : A & f y = x"
   768 
   769 lemma the_inv_into_f_f:
   770   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   771 apply (simp add: the_inv_into_def inj_on_def)
   772 apply blast
   773 done
   774 
   775 lemma f_the_inv_into_f:
   776   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   777 apply (simp add: the_inv_into_def)
   778 apply (rule the1I2)
   779  apply(blast dest: inj_onD)
   780 apply blast
   781 done
   782 
   783 lemma the_inv_into_into:
   784   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   785 apply (simp add: the_inv_into_def)
   786 apply (rule the1I2)
   787  apply(blast dest: inj_onD)
   788 apply blast
   789 done
   790 
   791 lemma the_inv_into_onto[simp]:
   792   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   793 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   794 
   795 lemma the_inv_into_f_eq:
   796   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   797   apply (erule subst)
   798   apply (erule the_inv_into_f_f, assumption)
   799   done
   800 
   801 lemma the_inv_into_comp:
   802   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   803   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   804 apply (rule the_inv_into_f_eq)
   805   apply (fast intro: comp_inj_on)
   806  apply (simp add: f_the_inv_into_f the_inv_into_into)
   807 apply (simp add: the_inv_into_into)
   808 done
   809 
   810 lemma inj_on_the_inv_into:
   811   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   812 by (auto intro: inj_onI simp: the_inv_into_f_f)
   813 
   814 lemma bij_betw_the_inv_into:
   815   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   816 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   817 
   818 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   819   "the_inv f \<equiv> the_inv_into UNIV f"
   820 
   821 lemma the_inv_f_f:
   822   assumes "inj f"
   823   shows "the_inv f (f x) = x" using assms UNIV_I
   824   by (rule the_inv_into_f_f)
   825 
   826 
   827 subsection \<open>Cantor's Paradox\<close>
   828 
   829 lemma Cantors_paradox:
   830   "\<not>(\<exists>f. f ` A = Pow A)"
   831 proof clarify
   832   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   833   let ?X = "{a \<in> A. a \<notin> f a}"
   834   have "?X \<in> Pow A" unfolding Pow_def by auto
   835   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   836   thus False by best
   837 qed
   838 
   839 subsection \<open>Setup\<close>
   840 
   841 subsubsection \<open>Proof tools\<close>
   842 
   843 text \<open>simplifies terms of the form
   844   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...)\<close>
   845 
   846 simproc_setup fun_upd2 ("f(v := w, x := y)") = \<open>fn _ =>
   847 let
   848   fun gen_fun_upd NONE T _ _ = NONE
   849     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   850   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   851   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   852     let
   853       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   854             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   855         | find t = NONE
   856     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   857 
   858   val ss = simpset_of @{context}
   859 
   860   fun proc ctxt ct =
   861     let
   862       val t = Thm.term_of ct
   863     in
   864       case find_double t of
   865         (T, NONE) => NONE
   866       | (T, SOME rhs) =>
   867           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   868             (fn _ =>
   869               resolve_tac ctxt [eq_reflection] 1 THEN
   870               resolve_tac ctxt @{thms ext} 1 THEN
   871               simp_tac (put_simpset ss ctxt) 1))
   872     end
   873 in proc end
   874 \<close>
   875 
   876 
   877 subsubsection \<open>Functorial structure of types\<close>
   878 
   879 ML_file "Tools/functor.ML"
   880 
   881 functor map_fun: map_fun
   882   by (simp_all add: fun_eq_iff)
   883 
   884 functor vimage
   885   by (simp_all add: fun_eq_iff vimage_comp)
   886 
   887 text \<open>Legacy theorem names\<close>
   888 
   889 lemmas o_def = comp_def
   890 lemmas o_apply = comp_apply
   891 lemmas o_assoc = comp_assoc [symmetric]
   892 lemmas id_o = id_comp
   893 lemmas o_id = comp_id
   894 lemmas o_eq_dest = comp_eq_dest
   895 lemmas o_eq_elim = comp_eq_elim
   896 lemmas o_eq_dest_lhs = comp_eq_dest_lhs
   897 lemmas o_eq_id_dest = comp_eq_id_dest
   898 
   899 end
   900