summary |
shortlog |
changelog |
graph |
tags |
branches |
files |
changeset |
file |
revisions |
annotate |
diff |
raw

src/HOL/Library/Permutation.thy

author | paulson <lp15@cam.ac.uk> |

Mon Feb 22 14:37:56 2016 +0000 (2016-02-22) | |

changeset 62379 | 340738057c8c |

parent 61699 | a81dc5c4d6a9 |

child 63310 | caaacf37943f |

permissions | -rw-r--r-- |

An assortment of useful lemmas about sums, norm, etc. Also: norm_conv_dist [symmetric] is now a simprule!

1 (* Title: HOL/Library/Permutation.thy

2 Author: Lawrence C Paulson and Thomas M Rasmussen and Norbert Voelker

3 *)

5 section \<open>Permutations\<close>

7 theory Permutation

8 imports Multiset

9 begin

11 inductive perm :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool" ("_ <~~> _" [50, 50] 50) (* FIXME proper infix, without ambiguity!? *)

12 where

13 Nil [intro!]: "[] <~~> []"

14 | swap [intro!]: "y # x # l <~~> x # y # l"

15 | Cons [intro!]: "xs <~~> ys \<Longrightarrow> z # xs <~~> z # ys"

16 | trans [intro]: "xs <~~> ys \<Longrightarrow> ys <~~> zs \<Longrightarrow> xs <~~> zs"

18 proposition perm_refl [iff]: "l <~~> l"

19 by (induct l) auto

22 subsection \<open>Some examples of rule induction on permutations\<close>

24 proposition xperm_empty_imp: "[] <~~> ys \<Longrightarrow> ys = []"

25 by (induct xs == "[] :: 'a list" ys pred: perm) simp_all

28 text \<open>\medskip This more general theorem is easier to understand!\<close>

30 proposition perm_length: "xs <~~> ys \<Longrightarrow> length xs = length ys"

31 by (induct pred: perm) simp_all

33 proposition perm_empty_imp: "[] <~~> xs \<Longrightarrow> xs = []"

34 by (drule perm_length) auto

36 proposition perm_sym: "xs <~~> ys \<Longrightarrow> ys <~~> xs"

37 by (induct pred: perm) auto

40 subsection \<open>Ways of making new permutations\<close>

42 text \<open>We can insert the head anywhere in the list.\<close>

44 proposition perm_append_Cons: "a # xs @ ys <~~> xs @ a # ys"

45 by (induct xs) auto

47 proposition perm_append_swap: "xs @ ys <~~> ys @ xs"

48 by (induct xs) (auto intro: perm_append_Cons)

50 proposition perm_append_single: "a # xs <~~> xs @ [a]"

51 by (rule perm.trans [OF _ perm_append_swap]) simp

53 proposition perm_rev: "rev xs <~~> xs"

54 by (induct xs) (auto intro!: perm_append_single intro: perm_sym)

56 proposition perm_append1: "xs <~~> ys \<Longrightarrow> l @ xs <~~> l @ ys"

57 by (induct l) auto

59 proposition perm_append2: "xs <~~> ys \<Longrightarrow> xs @ l <~~> ys @ l"

60 by (blast intro!: perm_append_swap perm_append1)

63 subsection \<open>Further results\<close>

65 proposition perm_empty [iff]: "[] <~~> xs \<longleftrightarrow> xs = []"

66 by (blast intro: perm_empty_imp)

68 proposition perm_empty2 [iff]: "xs <~~> [] \<longleftrightarrow> xs = []"

69 apply auto

70 apply (erule perm_sym [THEN perm_empty_imp])

71 done

73 proposition perm_sing_imp: "ys <~~> xs \<Longrightarrow> xs = [y] \<Longrightarrow> ys = [y]"

74 by (induct pred: perm) auto

76 proposition perm_sing_eq [iff]: "ys <~~> [y] \<longleftrightarrow> ys = [y]"

77 by (blast intro: perm_sing_imp)

79 proposition perm_sing_eq2 [iff]: "[y] <~~> ys \<longleftrightarrow> ys = [y]"

80 by (blast dest: perm_sym)

83 subsection \<open>Removing elements\<close>

85 proposition perm_remove: "x \<in> set ys \<Longrightarrow> ys <~~> x # remove1 x ys"

86 by (induct ys) auto

89 text \<open>\medskip Congruence rule\<close>

91 proposition perm_remove_perm: "xs <~~> ys \<Longrightarrow> remove1 z xs <~~> remove1 z ys"

92 by (induct pred: perm) auto

94 proposition remove_hd [simp]: "remove1 z (z # xs) = xs"

95 by auto

97 proposition cons_perm_imp_perm: "z # xs <~~> z # ys \<Longrightarrow> xs <~~> ys"

98 by (drule_tac z = z in perm_remove_perm) auto

100 proposition cons_perm_eq [iff]: "z#xs <~~> z#ys \<longleftrightarrow> xs <~~> ys"

101 by (blast intro: cons_perm_imp_perm)

103 proposition append_perm_imp_perm: "zs @ xs <~~> zs @ ys \<Longrightarrow> xs <~~> ys"

104 by (induct zs arbitrary: xs ys rule: rev_induct) auto

106 proposition perm_append1_eq [iff]: "zs @ xs <~~> zs @ ys \<longleftrightarrow> xs <~~> ys"

107 by (blast intro: append_perm_imp_perm perm_append1)

109 proposition perm_append2_eq [iff]: "xs @ zs <~~> ys @ zs \<longleftrightarrow> xs <~~> ys"

110 apply (safe intro!: perm_append2)

111 apply (rule append_perm_imp_perm)

112 apply (rule perm_append_swap [THEN perm.trans])

113 \<comment> \<open>the previous step helps this \<open>blast\<close> call succeed quickly\<close>

114 apply (blast intro: perm_append_swap)

115 done

117 theorem mset_eq_perm: "mset xs = mset ys \<longleftrightarrow> xs <~~> ys"

118 apply (rule iffI)

119 apply (erule_tac [2] perm.induct)

120 apply (simp_all add: union_ac)

121 apply (erule rev_mp)

122 apply (rule_tac x=ys in spec)

123 apply (induct_tac xs)

124 apply auto

125 apply (erule_tac x = "remove1 a x" in allE)

126 apply (drule sym)

127 apply simp

128 apply (subgoal_tac "a \<in> set x")

129 apply (drule_tac z = a in perm.Cons)

130 apply (erule perm.trans)

131 apply (rule perm_sym)

132 apply (erule perm_remove)

133 apply (drule_tac f=set_mset in arg_cong)

134 apply simp

135 done

137 proposition mset_le_perm_append: "mset xs \<le># mset ys \<longleftrightarrow> (\<exists>zs. xs @ zs <~~> ys)"

138 apply (auto simp: mset_eq_perm[THEN sym] mset_le_exists_conv)

139 apply (insert surj_mset)

140 apply (drule surjD)

141 apply (blast intro: sym)+

142 done

144 proposition perm_set_eq: "xs <~~> ys \<Longrightarrow> set xs = set ys"

145 by (metis mset_eq_perm mset_eq_setD)

147 proposition perm_distinct_iff: "xs <~~> ys \<Longrightarrow> distinct xs = distinct ys"

148 apply (induct pred: perm)

149 apply simp_all

150 apply fastforce

151 apply (metis perm_set_eq)

152 done

154 theorem eq_set_perm_remdups: "set xs = set ys \<Longrightarrow> remdups xs <~~> remdups ys"

155 apply (induct xs arbitrary: ys rule: length_induct)

156 apply (case_tac "remdups xs")

157 apply simp_all

158 apply (subgoal_tac "a \<in> set (remdups ys)")

159 prefer 2 apply (metis list.set(2) insert_iff set_remdups)

160 apply (drule split_list) apply (elim exE conjE)

161 apply (drule_tac x = list in spec) apply (erule impE) prefer 2

162 apply (drule_tac x = "ysa @ zs" in spec) apply (erule impE) prefer 2

163 apply simp

164 apply (subgoal_tac "a # list <~~> a # ysa @ zs")

165 apply (metis Cons_eq_appendI perm_append_Cons trans)

166 apply (metis Cons Cons_eq_appendI distinct.simps(2)

167 distinct_remdups distinct_remdups_id perm_append_swap perm_distinct_iff)

168 apply (subgoal_tac "set (a # list) =

169 set (ysa @ a # zs) \<and> distinct (a # list) \<and> distinct (ysa @ a # zs)")

170 apply (fastforce simp add: insert_ident)

171 apply (metis distinct_remdups set_remdups)

172 apply (subgoal_tac "length (remdups xs) < Suc (length xs)")

173 apply simp

174 apply (subgoal_tac "length (remdups xs) \<le> length xs")

175 apply simp

176 apply (rule length_remdups_leq)

177 done

179 proposition perm_remdups_iff_eq_set: "remdups x <~~> remdups y \<longleftrightarrow> set x = set y"

180 by (metis List.set_remdups perm_set_eq eq_set_perm_remdups)

182 theorem permutation_Ex_bij:

183 assumes "xs <~~> ys"

184 shows "\<exists>f. bij_betw f {..<length xs} {..<length ys} \<and> (\<forall>i<length xs. xs ! i = ys ! (f i))"

185 using assms

186 proof induct

187 case Nil

188 then show ?case

189 unfolding bij_betw_def by simp

190 next

191 case (swap y x l)

192 show ?case

193 proof (intro exI[of _ "Fun.swap 0 1 id"] conjI allI impI)

194 show "bij_betw (Fun.swap 0 1 id) {..<length (y # x # l)} {..<length (x # y # l)}"

195 by (auto simp: bij_betw_def)

196 fix i

197 assume "i < length (y # x # l)"

198 show "(y # x # l) ! i = (x # y # l) ! (Fun.swap 0 1 id) i"

199 by (cases i) (auto simp: Fun.swap_def gr0_conv_Suc)

200 qed

201 next

202 case (Cons xs ys z)

203 then obtain f where bij: "bij_betw f {..<length xs} {..<length ys}"

204 and perm: "\<forall>i<length xs. xs ! i = ys ! (f i)"

205 by blast

206 let ?f = "\<lambda>i. case i of Suc n \<Rightarrow> Suc (f n) | 0 \<Rightarrow> 0"

207 show ?case

208 proof (intro exI[of _ ?f] allI conjI impI)

209 have *: "{..<length (z#xs)} = {0} \<union> Suc ` {..<length xs}"

210 "{..<length (z#ys)} = {0} \<union> Suc ` {..<length ys}"

211 by (simp_all add: lessThan_Suc_eq_insert_0)

212 show "bij_betw ?f {..<length (z#xs)} {..<length (z#ys)}"

213 unfolding *

214 proof (rule bij_betw_combine)

215 show "bij_betw ?f (Suc ` {..<length xs}) (Suc ` {..<length ys})"

216 using bij unfolding bij_betw_def

217 by (auto intro!: inj_onI imageI dest: inj_onD simp: image_comp comp_def)

218 qed (auto simp: bij_betw_def)

219 fix i

220 assume "i < length (z # xs)"

221 then show "(z # xs) ! i = (z # ys) ! (?f i)"

222 using perm by (cases i) auto

223 qed

224 next

225 case (trans xs ys zs)

226 then obtain f g

227 where bij: "bij_betw f {..<length xs} {..<length ys}" "bij_betw g {..<length ys} {..<length zs}"

228 and perm: "\<forall>i<length xs. xs ! i = ys ! (f i)" "\<forall>i<length ys. ys ! i = zs ! (g i)"

229 by blast

230 show ?case

231 proof (intro exI[of _ "g \<circ> f"] conjI allI impI)

232 show "bij_betw (g \<circ> f) {..<length xs} {..<length zs}"

233 using bij by (rule bij_betw_trans)

234 fix i

235 assume "i < length xs"

236 with bij have "f i < length ys"

237 unfolding bij_betw_def by force

238 with \<open>i < length xs\<close> show "xs ! i = zs ! (g \<circ> f) i"

239 using trans(1,3)[THEN perm_length] perm by auto

240 qed

241 qed

243 proposition perm_finite: "finite {B. B <~~> A}"

244 proof (rule finite_subset[where B="{xs. set xs \<subseteq> set A \<and> length xs \<le> length A}"])

245 show "finite {xs. set xs \<subseteq> set A \<and> length xs \<le> length A}"

246 apply (cases A, simp)

247 apply (rule card_ge_0_finite)

248 apply (auto simp: card_lists_length_le)

249 done

250 next

251 show "{B. B <~~> A} \<subseteq> {xs. set xs \<subseteq> set A \<and> length xs \<le> length A}"

252 by (clarsimp simp add: perm_length perm_set_eq)

253 qed

255 proposition perm_swap:

256 assumes "i < length xs" "j < length xs"

257 shows "xs[i := xs ! j, j := xs ! i] <~~> xs"

258 using assms by (simp add: mset_eq_perm[symmetric] mset_swap)

260 end