src/HOL/Limits.thy
author paulson <lp15@cam.ac.uk>
Mon Feb 22 14:37:56 2016 +0000 (2016-02-22)
changeset 62379 340738057c8c
parent 62369 acfc4ad7b76a
child 62381 a6479cb85944
child 62390 842917225d56
permissions -rw-r--r--
An assortment of useful lemmas about sums, norm, etc. Also: norm_conv_dist [symmetric] is now a simprule!
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11 imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter" where
    17   "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 corollary eventually_at_infinity_pos:
    25    "eventually p at_infinity \<longleftrightarrow> (\<exists>b. 0 < b \<and> (\<forall>x. norm x \<ge> b \<longrightarrow> p x))"
    26 apply (simp add: eventually_at_infinity, auto)
    27 apply (case_tac "b \<le> 0")
    28 using norm_ge_zero order_trans zero_less_one apply blast
    29 apply (force simp:)
    30 done
    31 
    32 lemma at_infinity_eq_at_top_bot:
    33   "(at_infinity :: real filter) = sup at_top at_bot"
    34   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    35                    eventually_at_top_linorder eventually_at_bot_linorder)
    36   apply safe
    37   apply (rule_tac x="b" in exI, simp)
    38   apply (rule_tac x="- b" in exI, simp)
    39   apply (rule_tac x="max (- Na) N" in exI, auto simp: abs_real_def)
    40   done
    41 
    42 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    43   unfolding at_infinity_eq_at_top_bot by simp
    44 
    45 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    46   unfolding at_infinity_eq_at_top_bot by simp
    47 
    48 lemma filterlim_at_top_imp_at_infinity:
    49   fixes f :: "_ \<Rightarrow> real"
    50   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    51   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    52 
    53 lemma lim_infinity_imp_sequentially:
    54   "(f \<longlongrightarrow> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) \<longlongrightarrow> l) sequentially"
    55 by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    56 
    57 
    58 subsubsection \<open>Boundedness\<close>
    59 
    60 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    61   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    62 
    63 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    64   "Bseq X \<equiv> Bfun X sequentially"
    65 
    66 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    67 
    68 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    69   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    70 
    71 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    72   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    73 
    74 lemma Bfun_def:
    75   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    76   unfolding Bfun_metric_def norm_conv_dist
    77 proof safe
    78   fix y K assume K: "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    79   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    80     by (intro always_eventually) (metis dist_commute dist_triangle)
    81   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    82     by eventually_elim auto
    83   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    84     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    85 qed (force simp del: norm_conv_dist [symmetric])
    86 
    87 lemma BfunI:
    88   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    89 unfolding Bfun_def
    90 proof (intro exI conjI allI)
    91   show "0 < max K 1" by simp
    92 next
    93   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    94     using K by (rule eventually_mono, simp)
    95 qed
    96 
    97 lemma BfunE:
    98   assumes "Bfun f F"
    99   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   100 using assms unfolding Bfun_def by blast
   101 
   102 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   103   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   104   apply (erule_tac x=1 in allE)
   105   apply simp
   106   apply safe
   107   apply (rule_tac x="X M" in exI)
   108   apply (rule_tac x=1 in exI)
   109   apply (erule_tac x=M in allE)
   110   apply simp
   111   apply (rule_tac x=M in exI)
   112   apply (auto simp: dist_commute)
   113   done
   114 
   115 
   116 subsubsection \<open>Bounded Sequences\<close>
   117 
   118 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   119   by (intro BfunI) (auto simp: eventually_sequentially)
   120 
   121 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   122   by (intro BfunI) (auto simp: eventually_sequentially)
   123 
   124 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   125   unfolding Bfun_def eventually_sequentially
   126 proof safe
   127   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   128   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   129     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   130        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   131 qed auto
   132 
   133 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   134 unfolding Bseq_def by auto
   135 
   136 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   137 by (simp add: Bseq_def)
   138 
   139 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   140 by (auto simp add: Bseq_def)
   141 
   142 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   143 proof (elim BseqE, intro bdd_aboveI2)
   144   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   145     by (auto elim!: allE[of _ n])
   146 qed
   147 
   148 lemma Bseq_bdd_above':
   149   "Bseq (X::nat \<Rightarrow> 'a :: real_normed_vector) \<Longrightarrow> bdd_above (range (\<lambda>n. norm (X n)))"
   150 proof (elim BseqE, intro bdd_aboveI2)
   151   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "norm (X n) \<le> K"
   152     by (auto elim!: allE[of _ n])
   153 qed
   154 
   155 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   156 proof (elim BseqE, intro bdd_belowI2)
   157   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   158     by (auto elim!: allE[of _ n])
   159 qed
   160 
   161 lemma Bseq_eventually_mono:
   162   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) sequentially" "Bseq g"
   163   shows   "Bseq f"
   164 proof -
   165   from assms(1) obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> norm (f n) \<le> norm (g n)"
   166     by (auto simp: eventually_at_top_linorder)
   167   moreover from assms(2) obtain K where K: "\<And>n. norm (g n) \<le> K" by (blast elim!: BseqE)
   168   ultimately have "norm (f n) \<le> max K (Max {norm (f n) |n. n < N})" for n
   169     apply (cases "n < N")
   170     apply (rule max.coboundedI2, rule Max.coboundedI, auto) []
   171     apply (rule max.coboundedI1, force intro: order.trans[OF N K])
   172     done
   173   thus ?thesis by (blast intro: BseqI')
   174 qed
   175 
   176 lemma lemma_NBseq_def:
   177   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   178 proof safe
   179   fix K :: real
   180   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   181   then have "K \<le> real (Suc n)" by auto
   182   moreover assume "\<forall>m. norm (X m) \<le> K"
   183   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   184     by (blast intro: order_trans)
   185   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   186 next
   187   show "\<And>N. \<forall>n. norm (X n) \<le> real (Suc N) \<Longrightarrow> \<exists>K>0. \<forall>n. norm (X n) \<le> K"
   188     using of_nat_0_less_iff by blast
   189 qed
   190 
   191 text\<open>alternative definition for Bseq\<close>
   192 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   193 apply (simp add: Bseq_def)
   194 apply (simp (no_asm) add: lemma_NBseq_def)
   195 done
   196 
   197 lemma lemma_NBseq_def2:
   198      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   199 apply (subst lemma_NBseq_def, auto)
   200 apply (rule_tac x = "Suc N" in exI)
   201 apply (rule_tac [2] x = N in exI)
   202 apply (auto simp add: of_nat_Suc)
   203  prefer 2 apply (blast intro: order_less_imp_le)
   204 apply (drule_tac x = n in spec, simp)
   205 done
   206 
   207 (* yet another definition for Bseq *)
   208 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   209 by (simp add: Bseq_def lemma_NBseq_def2)
   210 
   211 subsubsection\<open>A Few More Equivalence Theorems for Boundedness\<close>
   212 
   213 text\<open>alternative formulation for boundedness\<close>
   214 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   215 apply (unfold Bseq_def, safe)
   216 apply (rule_tac [2] x = "k + norm x" in exI)
   217 apply (rule_tac x = K in exI, simp)
   218 apply (rule exI [where x = 0], auto)
   219 apply (erule order_less_le_trans, simp)
   220 apply (drule_tac x=n in spec)
   221 apply (drule order_trans [OF norm_triangle_ineq2])
   222 apply simp
   223 done
   224 
   225 text\<open>alternative formulation for boundedness\<close>
   226 lemma Bseq_iff3:
   227   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   228 proof
   229   assume ?P
   230   then obtain K
   231     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   232   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   233   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   234     by (auto intro: order_trans norm_triangle_ineq4)
   235   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   236     by simp
   237   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   238 next
   239   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   240 qed
   241 
   242 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   243 apply (simp add: Bseq_def)
   244 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   245 apply (drule_tac x = n in spec, arith)
   246 done
   247 
   248 
   249 subsubsection\<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   250 
   251 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   252   by (simp add: Bseq_def)
   253 
   254 lemma Bseq_add:
   255   assumes "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   256   shows   "Bseq (\<lambda>x. f x + c)"
   257 proof -
   258   from assms obtain K where K: "\<And>x. norm (f x) \<le> K" unfolding Bseq_def by blast
   259   {
   260     fix x :: nat
   261     have "norm (f x + c) \<le> norm (f x) + norm c" by (rule norm_triangle_ineq)
   262     also have "norm (f x) \<le> K" by (rule K)
   263     finally have "norm (f x + c) \<le> K + norm c" by simp
   264   }
   265   thus ?thesis by (rule BseqI')
   266 qed
   267 
   268 lemma Bseq_add_iff: "Bseq (\<lambda>x. f x + c) \<longleftrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   269   using Bseq_add[of f c] Bseq_add[of "\<lambda>x. f x + c" "-c"] by auto
   270 
   271 lemma Bseq_mult:
   272   assumes "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_field)"
   273   assumes "Bseq (g :: nat \<Rightarrow> 'a :: real_normed_field)"
   274   shows   "Bseq (\<lambda>x. f x * g x)"
   275 proof -
   276   from assms obtain K1 K2 where K: "\<And>x. norm (f x) \<le> K1" "K1 > 0" "\<And>x. norm (g x) \<le> K2" "K2 > 0"
   277     unfolding Bseq_def by blast
   278   hence "\<And>x. norm (f x * g x) \<le> K1 * K2" by (auto simp: norm_mult intro!: mult_mono)
   279   thus ?thesis by (rule BseqI')
   280 qed
   281 
   282 lemma Bfun_const [simp]: "Bfun (\<lambda>_. c) F"
   283   unfolding Bfun_metric_def by (auto intro!: exI[of _ c] exI[of _ "1::real"])
   284 
   285 lemma Bseq_cmult_iff: "(c :: 'a :: real_normed_field) \<noteq> 0 \<Longrightarrow> Bseq (\<lambda>x. c * f x) \<longleftrightarrow> Bseq f"
   286 proof
   287   assume "c \<noteq> 0" "Bseq (\<lambda>x. c * f x)"
   288   find_theorems "Bfun (\<lambda>_. ?c) _"
   289   from Bfun_const this(2) have "Bseq (\<lambda>x. inverse c * (c * f x))" by (rule Bseq_mult)
   290   with \<open>c \<noteq> 0\<close> show "Bseq f" by (simp add: divide_simps)
   291 qed (intro Bseq_mult Bfun_const)
   292 
   293 lemma Bseq_subseq: "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector) \<Longrightarrow> Bseq (\<lambda>x. f (g x))"
   294   unfolding Bseq_def by auto
   295 
   296 lemma Bseq_Suc_iff: "Bseq (\<lambda>n. f (Suc n)) \<longleftrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   297   using Bseq_offset[of f 1] by (auto intro: Bseq_subseq)
   298 
   299 lemma increasing_Bseq_subseq_iff:
   300   assumes "\<And>x y. x \<le> y \<Longrightarrow> norm (f x :: 'a :: real_normed_vector) \<le> norm (f y)" "subseq g"
   301   shows   "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   302 proof
   303   assume "Bseq (\<lambda>x. f (g x))"
   304   then obtain K where K: "\<And>x. norm (f (g x)) \<le> K" unfolding Bseq_def by auto
   305   {
   306     fix x :: nat
   307     from filterlim_subseq[OF assms(2)] obtain y where "g y \<ge> x"
   308       by (auto simp: filterlim_at_top eventually_at_top_linorder)
   309     hence "norm (f x) \<le> norm (f (g y))" using assms(1) by blast
   310     also have "norm (f (g y)) \<le> K" by (rule K)
   311     finally have "norm (f x) \<le> K" .
   312   }
   313   thus "Bseq f" by (rule BseqI')
   314 qed (insert Bseq_subseq[of f g], simp_all)
   315 
   316 lemma nonneg_incseq_Bseq_subseq_iff:
   317   assumes "\<And>x. f x \<ge> 0" "incseq (f :: nat \<Rightarrow> real)" "subseq g"
   318   shows   "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   319   using assms by (intro increasing_Bseq_subseq_iff) (auto simp: incseq_def)
   320 
   321 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   322   apply (simp add: subset_eq)
   323   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   324   apply (erule_tac x=n in allE)
   325   apply auto
   326   done
   327 
   328 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   329   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   330 
   331 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   332   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   333 
   334 subsection \<open>Bounded Monotonic Sequences\<close>
   335 
   336 subsubsection\<open>A Bounded and Monotonic Sequence Converges\<close>
   337 
   338 (* TODO: delete *)
   339 (* FIXME: one use in NSA/HSEQ.thy *)
   340 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X \<longlonglongrightarrow> L)"
   341   apply (rule_tac x="X m" in exI)
   342   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   343   unfolding eventually_sequentially
   344   apply blast
   345   done
   346 
   347 subsection \<open>Convergence to Zero\<close>
   348 
   349 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   350   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   351 
   352 lemma ZfunI:
   353   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   354   unfolding Zfun_def by simp
   355 
   356 lemma ZfunD:
   357   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   358   unfolding Zfun_def by simp
   359 
   360 lemma Zfun_ssubst:
   361   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   362   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   363 
   364 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   365   unfolding Zfun_def by simp
   366 
   367 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   368   unfolding Zfun_def by simp
   369 
   370 lemma Zfun_imp_Zfun:
   371   assumes f: "Zfun f F"
   372   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   373   shows "Zfun (\<lambda>x. g x) F"
   374 proof (cases)
   375   assume K: "0 < K"
   376   show ?thesis
   377   proof (rule ZfunI)
   378     fix r::real assume "0 < r"
   379     hence "0 < r / K" using K by simp
   380     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   381       using ZfunD [OF f] by blast
   382     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   383     proof eventually_elim
   384       case (elim x)
   385       hence "norm (f x) * K < r"
   386         by (simp add: pos_less_divide_eq K)
   387       thus ?case
   388         by (simp add: order_le_less_trans [OF elim(1)])
   389     qed
   390   qed
   391 next
   392   assume "\<not> 0 < K"
   393   hence K: "K \<le> 0" by (simp only: not_less)
   394   show ?thesis
   395   proof (rule ZfunI)
   396     fix r :: real
   397     assume "0 < r"
   398     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   399     proof eventually_elim
   400       case (elim x)
   401       also have "norm (f x) * K \<le> norm (f x) * 0"
   402         using K norm_ge_zero by (rule mult_left_mono)
   403       finally show ?case
   404         using \<open>0 < r\<close> by simp
   405     qed
   406   qed
   407 qed
   408 
   409 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   410   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   411 
   412 lemma Zfun_add:
   413   assumes f: "Zfun f F" and g: "Zfun g F"
   414   shows "Zfun (\<lambda>x. f x + g x) F"
   415 proof (rule ZfunI)
   416   fix r::real assume "0 < r"
   417   hence r: "0 < r / 2" by simp
   418   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   419     using f r by (rule ZfunD)
   420   moreover
   421   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   422     using g r by (rule ZfunD)
   423   ultimately
   424   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   425   proof eventually_elim
   426     case (elim x)
   427     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   428       by (rule norm_triangle_ineq)
   429     also have "\<dots> < r/2 + r/2"
   430       using elim by (rule add_strict_mono)
   431     finally show ?case
   432       by simp
   433   qed
   434 qed
   435 
   436 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   437   unfolding Zfun_def by simp
   438 
   439 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   440   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   441 
   442 lemma (in bounded_linear) Zfun:
   443   assumes g: "Zfun g F"
   444   shows "Zfun (\<lambda>x. f (g x)) F"
   445 proof -
   446   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   447     using bounded by blast
   448   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   449     by simp
   450   with g show ?thesis
   451     by (rule Zfun_imp_Zfun)
   452 qed
   453 
   454 lemma (in bounded_bilinear) Zfun:
   455   assumes f: "Zfun f F"
   456   assumes g: "Zfun g F"
   457   shows "Zfun (\<lambda>x. f x ** g x) F"
   458 proof (rule ZfunI)
   459   fix r::real assume r: "0 < r"
   460   obtain K where K: "0 < K"
   461     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   462     using pos_bounded by blast
   463   from K have K': "0 < inverse K"
   464     by (rule positive_imp_inverse_positive)
   465   have "eventually (\<lambda>x. norm (f x) < r) F"
   466     using f r by (rule ZfunD)
   467   moreover
   468   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   469     using g K' by (rule ZfunD)
   470   ultimately
   471   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   472   proof eventually_elim
   473     case (elim x)
   474     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   475       by (rule norm_le)
   476     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   477       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   478     also from K have "r * inverse K * K = r"
   479       by simp
   480     finally show ?case .
   481   qed
   482 qed
   483 
   484 lemma (in bounded_bilinear) Zfun_left:
   485   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   486   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   487 
   488 lemma (in bounded_bilinear) Zfun_right:
   489   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   490   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   491 
   492 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   493 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   494 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   495 
   496 lemma tendsto_Zfun_iff: "(f \<longlongrightarrow> a) F = Zfun (\<lambda>x. f x - a) F"
   497   by (simp only: tendsto_iff Zfun_def dist_norm)
   498 
   499 lemma tendsto_0_le: "\<lbrakk>(f \<longlongrightarrow> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk>
   500                      \<Longrightarrow> (g \<longlongrightarrow> 0) F"
   501   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   502 
   503 subsubsection \<open>Distance and norms\<close>
   504 
   505 lemma tendsto_dist [tendsto_intros]:
   506   fixes l m :: "'a :: metric_space"
   507   assumes f: "(f \<longlongrightarrow> l) F" and g: "(g \<longlongrightarrow> m) F"
   508   shows "((\<lambda>x. dist (f x) (g x)) \<longlongrightarrow> dist l m) F"
   509 proof (rule tendstoI)
   510   fix e :: real assume "0 < e"
   511   hence e2: "0 < e/2" by simp
   512   from tendstoD [OF f e2] tendstoD [OF g e2]
   513   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   514   proof (eventually_elim)
   515     case (elim x)
   516     then show "dist (dist (f x) (g x)) (dist l m) < e"
   517       unfolding dist_real_def
   518       using dist_triangle2 [of "f x" "g x" "l"]
   519       using dist_triangle2 [of "g x" "l" "m"]
   520       using dist_triangle3 [of "l" "m" "f x"]
   521       using dist_triangle [of "f x" "m" "g x"]
   522       by arith
   523   qed
   524 qed
   525 
   526 lemma continuous_dist[continuous_intros]:
   527   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   528   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   529   unfolding continuous_def by (rule tendsto_dist)
   530 
   531 lemma continuous_on_dist[continuous_intros]:
   532   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   533   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   534   unfolding continuous_on_def by (auto intro: tendsto_dist)
   535 
   536 lemma tendsto_norm [tendsto_intros]:
   537   "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> norm a) F"
   538   unfolding norm_conv_dist by (intro tendsto_intros)
   539 
   540 lemma continuous_norm [continuous_intros]:
   541   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   542   unfolding continuous_def by (rule tendsto_norm)
   543 
   544 lemma continuous_on_norm [continuous_intros]:
   545   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   546   unfolding continuous_on_def by (auto intro: tendsto_norm)
   547 
   548 lemma tendsto_norm_zero:
   549   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F"
   550   by (drule tendsto_norm, simp)
   551 
   552 lemma tendsto_norm_zero_cancel:
   553   "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   554   unfolding tendsto_iff dist_norm by simp
   555 
   556 lemma tendsto_norm_zero_iff:
   557   "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   558   unfolding tendsto_iff dist_norm by simp
   559 
   560 lemma tendsto_rabs [tendsto_intros]:
   561   "(f \<longlongrightarrow> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> \<bar>l\<bar>) F"
   562   by (fold real_norm_def, rule tendsto_norm)
   563 
   564 lemma continuous_rabs [continuous_intros]:
   565   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   566   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   567 
   568 lemma continuous_on_rabs [continuous_intros]:
   569   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   570   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   571 
   572 lemma tendsto_rabs_zero:
   573   "(f \<longlongrightarrow> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> 0) F"
   574   by (fold real_norm_def, rule tendsto_norm_zero)
   575 
   576 lemma tendsto_rabs_zero_cancel:
   577   "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   578   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   579 
   580 lemma tendsto_rabs_zero_iff:
   581   "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   582   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   583 
   584 subsection \<open>Topological Monoid\<close>
   585 
   586 class topological_monoid_add = topological_space + monoid_add +
   587   assumes tendsto_add_Pair: "LIM x (nhds a \<times>\<^sub>F nhds b). fst x + snd x :> nhds (a + b)"
   588 
   589 class topological_comm_monoid_add = topological_monoid_add + comm_monoid_add
   590 
   591 lemma tendsto_add [tendsto_intros]:
   592   fixes a b :: "'a::topological_monoid_add"
   593   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> a + b) F"
   594   using filterlim_compose[OF tendsto_add_Pair, of "\<lambda>x. (f x, g x)" a b F]
   595   by (simp add: nhds_prod[symmetric] tendsto_Pair)
   596 
   597 lemma continuous_add [continuous_intros]:
   598   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   599   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   600   unfolding continuous_def by (rule tendsto_add)
   601 
   602 lemma continuous_on_add [continuous_intros]:
   603   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   604   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   605   unfolding continuous_on_def by (auto intro: tendsto_add)
   606 
   607 lemma tendsto_add_zero:
   608   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   609   shows "\<lbrakk>(f \<longlongrightarrow> 0) F; (g \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> 0) F"
   610   by (drule (1) tendsto_add, simp)
   611 
   612 lemma tendsto_setsum [tendsto_intros]:
   613   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::topological_comm_monoid_add"
   614   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> a i) F"
   615   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) \<longlongrightarrow> (\<Sum>i\<in>S. a i)) F"
   616 proof (cases "finite S")
   617   assume "finite S" thus ?thesis using assms
   618     by (induct, simp, simp add: tendsto_add)
   619 qed simp
   620 
   621 lemma continuous_setsum [continuous_intros]:
   622   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
   623   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   624   unfolding continuous_def by (rule tendsto_setsum)
   625 
   626 lemma continuous_on_setsum [continuous_intros]:
   627   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::topological_comm_monoid_add"
   628   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   629   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   630 
   631 instance nat :: topological_comm_monoid_add
   632   proof qed (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   633 
   634 instance int :: topological_comm_monoid_add
   635   proof qed (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   636 
   637 subsubsection \<open>Addition and subtraction\<close>
   638 
   639 instance real_normed_vector < topological_comm_monoid_add
   640 proof
   641   fix a b :: 'a show "((\<lambda>x. fst x + snd x) \<longlongrightarrow> a + b) (nhds a \<times>\<^sub>F nhds b)"
   642     unfolding tendsto_Zfun_iff add_diff_add
   643     using tendsto_fst[OF filterlim_ident, of "(a,b)"] tendsto_snd[OF filterlim_ident, of "(a,b)"]
   644     by (intro Zfun_add)
   645        (auto simp add: tendsto_Zfun_iff[symmetric] nhds_prod[symmetric] intro!: tendsto_fst)
   646 qed
   647 
   648 lemma tendsto_minus [tendsto_intros]:
   649   fixes a :: "'a::real_normed_vector"
   650   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> - a) F"
   651   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   652 
   653 lemma continuous_minus [continuous_intros]:
   654   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   655   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   656   unfolding continuous_def by (rule tendsto_minus)
   657 
   658 lemma continuous_on_minus [continuous_intros]:
   659   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   660   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   661   unfolding continuous_on_def by (auto intro: tendsto_minus)
   662 
   663 lemma tendsto_minus_cancel:
   664   fixes a :: "'a::real_normed_vector"
   665   shows "((\<lambda>x. - f x) \<longlongrightarrow> - a) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
   666   by (drule tendsto_minus, simp)
   667 
   668 lemma tendsto_minus_cancel_left:
   669     "(f \<longlongrightarrow> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> y) F"
   670   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   671   by auto
   672 
   673 lemma tendsto_diff [tendsto_intros]:
   674   fixes a b :: "'a::real_normed_vector"
   675   shows "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> a - b) F"
   676   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   677 
   678 lemma continuous_diff [continuous_intros]:
   679   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   680   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   681   unfolding continuous_def by (rule tendsto_diff)
   682 
   683 lemma continuous_on_diff [continuous_intros]:
   684   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   685   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   686   unfolding continuous_on_def by (auto intro: tendsto_diff)
   687 
   688 lemma continuous_on_op_minus: "continuous_on (s::'a::real_normed_vector set) (op - x)"
   689   by (rule continuous_intros | simp)+
   690 
   691 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   692 
   693 subsubsection \<open>Linear operators and multiplication\<close>
   694 
   695 lemma linear_times:
   696   fixes c::"'a::real_algebra" shows "linear (\<lambda>x. c * x)"
   697   by (auto simp: linearI distrib_left)
   698 
   699 lemma (in bounded_linear) tendsto:
   700   "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> f a) F"
   701   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   702 
   703 lemma (in bounded_linear) continuous:
   704   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   705   using tendsto[of g _ F] by (auto simp: continuous_def)
   706 
   707 lemma (in bounded_linear) continuous_on:
   708   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   709   using tendsto[of g] by (auto simp: continuous_on_def)
   710 
   711 lemma (in bounded_linear) tendsto_zero:
   712   "(g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> 0) F"
   713   by (drule tendsto, simp only: zero)
   714 
   715 lemma (in bounded_bilinear) tendsto:
   716   "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) \<longlongrightarrow> a ** b) F"
   717   by (simp only: tendsto_Zfun_iff prod_diff_prod
   718                  Zfun_add Zfun Zfun_left Zfun_right)
   719 
   720 lemma (in bounded_bilinear) continuous:
   721   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   722   using tendsto[of f _ F g] by (auto simp: continuous_def)
   723 
   724 lemma (in bounded_bilinear) continuous_on:
   725   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   726   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   727 
   728 lemma (in bounded_bilinear) tendsto_zero:
   729   assumes f: "(f \<longlongrightarrow> 0) F"
   730   assumes g: "(g \<longlongrightarrow> 0) F"
   731   shows "((\<lambda>x. f x ** g x) \<longlongrightarrow> 0) F"
   732   using tendsto [OF f g] by (simp add: zero_left)
   733 
   734 lemma (in bounded_bilinear) tendsto_left_zero:
   735   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) \<longlongrightarrow> 0) F"
   736   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   737 
   738 lemma (in bounded_bilinear) tendsto_right_zero:
   739   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) \<longlongrightarrow> 0) F"
   740   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   741 
   742 lemmas tendsto_of_real [tendsto_intros] =
   743   bounded_linear.tendsto [OF bounded_linear_of_real]
   744 
   745 lemmas tendsto_scaleR [tendsto_intros] =
   746   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   747 
   748 lemmas tendsto_mult [tendsto_intros] =
   749   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   750 
   751 lemma tendsto_mult_left:
   752   fixes c::"'a::real_normed_algebra"
   753   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. c * (f x)) \<longlongrightarrow> c * l) F"
   754 by (rule tendsto_mult [OF tendsto_const])
   755 
   756 lemma tendsto_mult_right:
   757   fixes c::"'a::real_normed_algebra"
   758   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. (f x) * c) \<longlongrightarrow> l * c) F"
   759 by (rule tendsto_mult [OF _ tendsto_const])
   760 
   761 lemmas continuous_of_real [continuous_intros] =
   762   bounded_linear.continuous [OF bounded_linear_of_real]
   763 
   764 lemmas continuous_scaleR [continuous_intros] =
   765   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   766 
   767 lemmas continuous_mult [continuous_intros] =
   768   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   769 
   770 lemmas continuous_on_of_real [continuous_intros] =
   771   bounded_linear.continuous_on [OF bounded_linear_of_real]
   772 
   773 lemmas continuous_on_scaleR [continuous_intros] =
   774   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   775 
   776 lemmas continuous_on_mult [continuous_intros] =
   777   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   778 
   779 lemmas tendsto_mult_zero =
   780   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   781 
   782 lemmas tendsto_mult_left_zero =
   783   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   784 
   785 lemmas tendsto_mult_right_zero =
   786   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   787 
   788 lemma tendsto_power [tendsto_intros]:
   789   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   790   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> a ^ n) F"
   791   by (induct n) (simp_all add: tendsto_mult)
   792 
   793 lemma continuous_power [continuous_intros]:
   794   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   795   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   796   unfolding continuous_def by (rule tendsto_power)
   797 
   798 lemma continuous_on_power [continuous_intros]:
   799   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   800   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   801   unfolding continuous_on_def by (auto intro: tendsto_power)
   802 
   803 lemma tendsto_setprod [tendsto_intros]:
   804   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   805   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> L i) F"
   806   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) \<longlongrightarrow> (\<Prod>i\<in>S. L i)) F"
   807 proof (cases "finite S")
   808   assume "finite S" thus ?thesis using assms
   809     by (induct, simp, simp add: tendsto_mult)
   810 qed simp
   811 
   812 lemma continuous_setprod [continuous_intros]:
   813   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   814   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   815   unfolding continuous_def by (rule tendsto_setprod)
   816 
   817 lemma continuous_on_setprod [continuous_intros]:
   818   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   819   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   820   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   821 
   822 lemma tendsto_of_real_iff:
   823   "((\<lambda>x. of_real (f x) :: 'a :: real_normed_div_algebra) \<longlongrightarrow> of_real c) F \<longleftrightarrow> (f \<longlongrightarrow> c) F"
   824   unfolding tendsto_iff by simp
   825 
   826 lemma tendsto_add_const_iff:
   827   "((\<lambda>x. c + f x :: 'a :: real_normed_vector) \<longlongrightarrow> c + d) F \<longleftrightarrow> (f \<longlongrightarrow> d) F"
   828   using tendsto_add[OF tendsto_const[of c], of f d]
   829         tendsto_add[OF tendsto_const[of "-c"], of "\<lambda>x. c + f x" "c + d"] by auto
   830 
   831 
   832 subsubsection \<open>Inverse and division\<close>
   833 
   834 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   835   assumes f: "Zfun f F"
   836   assumes g: "Bfun g F"
   837   shows "Zfun (\<lambda>x. f x ** g x) F"
   838 proof -
   839   obtain K where K: "0 \<le> K"
   840     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   841     using nonneg_bounded by blast
   842   obtain B where B: "0 < B"
   843     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   844     using g by (rule BfunE)
   845   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   846   using norm_g proof eventually_elim
   847     case (elim x)
   848     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   849       by (rule norm_le)
   850     also have "\<dots> \<le> norm (f x) * B * K"
   851       by (intro mult_mono' order_refl norm_g norm_ge_zero
   852                 mult_nonneg_nonneg K elim)
   853     also have "\<dots> = norm (f x) * (B * K)"
   854       by (rule mult.assoc)
   855     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   856   qed
   857   with f show ?thesis
   858     by (rule Zfun_imp_Zfun)
   859 qed
   860 
   861 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   862   assumes f: "Bfun f F"
   863   assumes g: "Zfun g F"
   864   shows "Zfun (\<lambda>x. f x ** g x) F"
   865   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   866 
   867 lemma Bfun_inverse_lemma:
   868   fixes x :: "'a::real_normed_div_algebra"
   869   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   870   apply (subst nonzero_norm_inverse, clarsimp)
   871   apply (erule (1) le_imp_inverse_le)
   872   done
   873 
   874 lemma Bfun_inverse:
   875   fixes a :: "'a::real_normed_div_algebra"
   876   assumes f: "(f \<longlongrightarrow> a) F"
   877   assumes a: "a \<noteq> 0"
   878   shows "Bfun (\<lambda>x. inverse (f x)) F"
   879 proof -
   880   from a have "0 < norm a" by simp
   881   hence "\<exists>r>0. r < norm a" by (rule dense)
   882   then obtain r where r1: "0 < r" and r2: "r < norm a" by blast
   883   have "eventually (\<lambda>x. dist (f x) a < r) F"
   884     using tendstoD [OF f r1] by blast
   885   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   886   proof eventually_elim
   887     case (elim x)
   888     hence 1: "norm (f x - a) < r"
   889       by (simp add: dist_norm)
   890     hence 2: "f x \<noteq> 0" using r2 by auto
   891     hence "norm (inverse (f x)) = inverse (norm (f x))"
   892       by (rule nonzero_norm_inverse)
   893     also have "\<dots> \<le> inverse (norm a - r)"
   894     proof (rule le_imp_inverse_le)
   895       show "0 < norm a - r" using r2 by simp
   896     next
   897       have "norm a - norm (f x) \<le> norm (a - f x)"
   898         by (rule norm_triangle_ineq2)
   899       also have "\<dots> = norm (f x - a)"
   900         by (rule norm_minus_commute)
   901       also have "\<dots> < r" using 1 .
   902       finally show "norm a - r \<le> norm (f x)" by simp
   903     qed
   904     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   905   qed
   906   thus ?thesis by (rule BfunI)
   907 qed
   908 
   909 lemma tendsto_inverse [tendsto_intros]:
   910   fixes a :: "'a::real_normed_div_algebra"
   911   assumes f: "(f \<longlongrightarrow> a) F"
   912   assumes a: "a \<noteq> 0"
   913   shows "((\<lambda>x. inverse (f x)) \<longlongrightarrow> inverse a) F"
   914 proof -
   915   from a have "0 < norm a" by simp
   916   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   917     by (rule tendstoD)
   918   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   919     unfolding dist_norm by (auto elim!: eventually_mono)
   920   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   921     - (inverse (f x) * (f x - a) * inverse a)) F"
   922     by (auto elim!: eventually_mono simp: inverse_diff_inverse)
   923   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   924     by (intro Zfun_minus Zfun_mult_left
   925       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   926       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   927   ultimately show ?thesis
   928     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   929 qed
   930 
   931 lemma continuous_inverse:
   932   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   933   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   934   shows "continuous F (\<lambda>x. inverse (f x))"
   935   using assms unfolding continuous_def by (rule tendsto_inverse)
   936 
   937 lemma continuous_at_within_inverse[continuous_intros]:
   938   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   939   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   940   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   941   using assms unfolding continuous_within by (rule tendsto_inverse)
   942 
   943 lemma isCont_inverse[continuous_intros, simp]:
   944   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   945   assumes "isCont f a" and "f a \<noteq> 0"
   946   shows "isCont (\<lambda>x. inverse (f x)) a"
   947   using assms unfolding continuous_at by (rule tendsto_inverse)
   948 
   949 lemma continuous_on_inverse[continuous_intros]:
   950   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   951   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   952   shows "continuous_on s (\<lambda>x. inverse (f x))"
   953   using assms unfolding continuous_on_def by (blast intro: tendsto_inverse)
   954 
   955 lemma tendsto_divide [tendsto_intros]:
   956   fixes a b :: "'a::real_normed_field"
   957   shows "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F; b \<noteq> 0\<rbrakk>
   958     \<Longrightarrow> ((\<lambda>x. f x / g x) \<longlongrightarrow> a / b) F"
   959   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   960 
   961 lemma continuous_divide:
   962   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   963   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   964   shows "continuous F (\<lambda>x. (f x) / (g x))"
   965   using assms unfolding continuous_def by (rule tendsto_divide)
   966 
   967 lemma continuous_at_within_divide[continuous_intros]:
   968   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   969   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   970   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   971   using assms unfolding continuous_within by (rule tendsto_divide)
   972 
   973 lemma isCont_divide[continuous_intros, simp]:
   974   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   975   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   976   shows "isCont (\<lambda>x. (f x) / g x) a"
   977   using assms unfolding continuous_at by (rule tendsto_divide)
   978 
   979 lemma continuous_on_divide[continuous_intros]:
   980   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   981   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   982   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   983   using assms unfolding continuous_on_def by (blast intro: tendsto_divide)
   984 
   985 lemma tendsto_sgn [tendsto_intros]:
   986   fixes l :: "'a::real_normed_vector"
   987   shows "\<lbrakk>(f \<longlongrightarrow> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) \<longlongrightarrow> sgn l) F"
   988   unfolding sgn_div_norm by (simp add: tendsto_intros)
   989 
   990 lemma continuous_sgn:
   991   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   992   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   993   shows "continuous F (\<lambda>x. sgn (f x))"
   994   using assms unfolding continuous_def by (rule tendsto_sgn)
   995 
   996 lemma continuous_at_within_sgn[continuous_intros]:
   997   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   998   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   999   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
  1000   using assms unfolding continuous_within by (rule tendsto_sgn)
  1001 
  1002 lemma isCont_sgn[continuous_intros]:
  1003   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1004   assumes "isCont f a" and "f a \<noteq> 0"
  1005   shows "isCont (\<lambda>x. sgn (f x)) a"
  1006   using assms unfolding continuous_at by (rule tendsto_sgn)
  1007 
  1008 lemma continuous_on_sgn[continuous_intros]:
  1009   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1010   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
  1011   shows "continuous_on s (\<lambda>x. sgn (f x))"
  1012   using assms unfolding continuous_on_def by (blast intro: tendsto_sgn)
  1013 
  1014 lemma filterlim_at_infinity:
  1015   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
  1016   assumes "0 \<le> c"
  1017   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
  1018   unfolding filterlim_iff eventually_at_infinity
  1019 proof safe
  1020   fix P :: "'a \<Rightarrow> bool" and b
  1021   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
  1022     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
  1023   have "max b (c + 1) > c" by auto
  1024   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
  1025     by auto
  1026   then show "eventually (\<lambda>x. P (f x)) F"
  1027   proof eventually_elim
  1028     fix x assume "max b (c + 1) \<le> norm (f x)"
  1029     with P show "P (f x)" by auto
  1030   qed
  1031 qed force
  1032 
  1033 lemma not_tendsto_and_filterlim_at_infinity:
  1034   assumes "F \<noteq> bot"
  1035   assumes "(f \<longlongrightarrow> (c :: 'a :: real_normed_vector)) F"
  1036   assumes "filterlim f at_infinity F"
  1037   shows   False
  1038 proof -
  1039   from tendstoD[OF assms(2), of "1/2"]
  1040     have "eventually (\<lambda>x. dist (f x) c < 1/2) F" by simp
  1041   moreover from filterlim_at_infinity[of "norm c" f F] assms(3)
  1042     have "eventually (\<lambda>x. norm (f x) \<ge> norm c + 1) F" by simp
  1043   ultimately have "eventually (\<lambda>x. False) F"
  1044   proof eventually_elim
  1045     fix x assume A: "dist (f x) c < 1/2" and B: "norm (f x) \<ge> norm c + 1"
  1046     note B
  1047     also have "norm (f x) = dist (f x) 0" by simp
  1048     also have "... \<le> dist (f x) c + dist c 0" by (rule dist_triangle)
  1049     finally show False using A by simp
  1050   qed
  1051   with assms show False by simp
  1052 qed
  1053 
  1054 lemma filterlim_at_infinity_imp_not_convergent:
  1055   assumes "filterlim f at_infinity sequentially"
  1056   shows   "\<not>convergent f"
  1057   by (rule notI, rule not_tendsto_and_filterlim_at_infinity[OF _ _ assms])
  1058      (simp_all add: convergent_LIMSEQ_iff)
  1059 
  1060 lemma filterlim_at_infinity_imp_eventually_ne:
  1061   assumes "filterlim f at_infinity F"
  1062   shows   "eventually (\<lambda>z. f z \<noteq> c) F"
  1063 proof -
  1064   have "norm c + 1 > 0" by (intro add_nonneg_pos) simp_all
  1065   with filterlim_at_infinity[OF order.refl, of f F] assms
  1066     have "eventually (\<lambda>z. norm (f z) \<ge> norm c + 1) F" by blast
  1067   thus ?thesis by eventually_elim auto
  1068 qed
  1069 
  1070 lemma tendsto_of_nat [tendsto_intros]:
  1071   "filterlim (of_nat :: nat \<Rightarrow> 'a :: real_normed_algebra_1) at_infinity sequentially"
  1072 proof (subst filterlim_at_infinity[OF order.refl], intro allI impI)
  1073   fix r :: real assume r: "r > 0"
  1074   def n \<equiv> "nat \<lceil>r\<rceil>"
  1075   from r have n: "\<forall>m\<ge>n. of_nat m \<ge> r" unfolding n_def by linarith
  1076   from eventually_ge_at_top[of n] show "eventually (\<lambda>m. norm (of_nat m :: 'a) \<ge> r) sequentially"
  1077     by eventually_elim (insert n, simp_all)
  1078 qed
  1079 
  1080 
  1081 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
  1082 
  1083 text \<open>
  1084 
  1085 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
  1086 @{term "at_right x"} and also @{term "at_right 0"}.
  1087 
  1088 \<close>
  1089 
  1090 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
  1091 
  1092 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
  1093   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
  1094      (auto intro!: tendsto_eq_intros filterlim_ident)
  1095 
  1096 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
  1097   by (rule filtermap_fun_inverse[where g=uminus])
  1098      (auto intro!: tendsto_eq_intros filterlim_ident)
  1099 
  1100 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
  1101   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1102 
  1103 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
  1104   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1105 
  1106 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
  1107   using filtermap_at_right_shift[of "-a" 0] by simp
  1108 
  1109 lemma filterlim_at_right_to_0:
  1110   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
  1111   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
  1112 
  1113 lemma eventually_at_right_to_0:
  1114   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
  1115   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
  1116 
  1117 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
  1118   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1119 
  1120 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
  1121   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1122 
  1123 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
  1124   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1125 
  1126 lemma filterlim_at_left_to_right:
  1127   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
  1128   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
  1129 
  1130 lemma eventually_at_left_to_right:
  1131   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
  1132   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
  1133 
  1134 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1135   unfolding filterlim_at_top eventually_at_bot_dense
  1136   by (metis leI minus_less_iff order_less_asym)
  1137 
  1138 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1139   unfolding filterlim_at_bot eventually_at_top_dense
  1140   by (metis leI less_minus_iff order_less_asym)
  1141 
  1142 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
  1143   by (rule filtermap_fun_inverse[symmetric, of uminus])
  1144      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
  1145 
  1146 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
  1147   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
  1148 
  1149 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
  1150   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
  1151 
  1152 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
  1153   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
  1154 
  1155 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1156   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1157   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1158   by auto
  1159 
  1160 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1161   unfolding filterlim_uminus_at_top by simp
  1162 
  1163 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1164   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1165 proof safe
  1166   fix Z :: real assume [arith]: "0 < Z"
  1167   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1168     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1169   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1170     by (auto elim!: eventually_mono simp: inverse_eq_divide field_simps)
  1171 qed
  1172 
  1173 lemma tendsto_inverse_0:
  1174   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
  1175   shows "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1176   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1177 proof safe
  1178   fix r :: real assume "0 < r"
  1179   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1180   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1181     fix x :: 'a
  1182     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
  1183     also assume *: "inverse (r / 2) \<le> norm x"
  1184     finally show "norm (inverse x) < r"
  1185       using * \<open>0 < r\<close> by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1186   qed
  1187 qed
  1188 
  1189 lemma tendsto_add_filterlim_at_infinity:
  1190   assumes "(f \<longlongrightarrow> (c :: 'b :: real_normed_vector)) (F :: 'a filter)"
  1191   assumes "filterlim g at_infinity F"
  1192   shows   "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1193 proof (subst filterlim_at_infinity[OF order_refl], safe)
  1194   fix r :: real assume r: "r > 0"
  1195   from assms(1) have "((\<lambda>x. norm (f x)) \<longlongrightarrow> norm c) F" by (rule tendsto_norm)
  1196   hence "eventually (\<lambda>x. norm (f x) < norm c + 1) F" by (rule order_tendstoD) simp_all
  1197   moreover from r have "r + norm c + 1 > 0" by (intro add_pos_nonneg) simp_all
  1198   with assms(2) have "eventually (\<lambda>x. norm (g x) \<ge> r + norm c + 1) F"
  1199     unfolding filterlim_at_infinity[OF order_refl] by (elim allE[of _ "r + norm c + 1"]) simp_all
  1200   ultimately show "eventually (\<lambda>x. norm (f x + g x) \<ge> r) F"
  1201   proof eventually_elim
  1202     fix x :: 'a assume A: "norm (f x) < norm c + 1" and B: "r + norm c + 1 \<le> norm (g x)"
  1203     from A B have "r \<le> norm (g x) - norm (f x)" by simp
  1204     also have "norm (g x) - norm (f x) \<le> norm (g x + f x)" by (rule norm_diff_ineq)
  1205     finally show "r \<le> norm (f x + g x)" by (simp add: add_ac)
  1206   qed
  1207 qed
  1208 
  1209 lemma tendsto_add_filterlim_at_infinity':
  1210   assumes "filterlim f at_infinity F"
  1211   assumes "(g \<longlongrightarrow> (c :: 'b :: real_normed_vector)) (F :: 'a filter)"
  1212   shows   "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1213   by (subst add.commute) (rule tendsto_add_filterlim_at_infinity assms)+
  1214 
  1215 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1216   unfolding filterlim_at
  1217   by (auto simp: eventually_at_top_dense)
  1218      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1219 
  1220 lemma filterlim_inverse_at_top:
  1221   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1222   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1223      (simp add: filterlim_def eventually_filtermap eventually_mono at_within_def le_principal)
  1224 
  1225 lemma filterlim_inverse_at_bot_neg:
  1226   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1227   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1228 
  1229 lemma filterlim_inverse_at_bot:
  1230   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1231   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1232   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1233 
  1234 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1235   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1236      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1237 
  1238 lemma eventually_at_right_to_top:
  1239   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1240   unfolding at_right_to_top eventually_filtermap ..
  1241 
  1242 lemma filterlim_at_right_to_top:
  1243   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1244   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1245 
  1246 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1247   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1248 
  1249 lemma eventually_at_top_to_right:
  1250   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1251   unfolding at_top_to_right eventually_filtermap ..
  1252 
  1253 lemma filterlim_at_top_to_right:
  1254   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1255   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1256 
  1257 lemma filterlim_inverse_at_infinity:
  1258   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1259   shows "filterlim inverse at_infinity (at (0::'a))"
  1260   unfolding filterlim_at_infinity[OF order_refl]
  1261 proof safe
  1262   fix r :: real assume "0 < r"
  1263   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1264     unfolding eventually_at norm_inverse
  1265     by (intro exI[of _ "inverse r"])
  1266        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1267 qed
  1268 
  1269 lemma filterlim_inverse_at_iff:
  1270   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
  1271   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1272   unfolding filterlim_def filtermap_filtermap[symmetric]
  1273 proof
  1274   assume "filtermap g F \<le> at_infinity"
  1275   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1276     by (rule filtermap_mono)
  1277   also have "\<dots> \<le> at 0"
  1278     using tendsto_inverse_0[where 'a='b]
  1279     by (auto intro!: exI[of _ 1]
  1280              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1281   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1282 next
  1283   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1284   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1285     by (rule filtermap_mono)
  1286   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1287     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1288 qed
  1289 
  1290 lemma tendsto_mult_filterlim_at_infinity:
  1291   assumes "F \<noteq> bot" "(f \<longlongrightarrow> (c :: 'a :: real_normed_field)) F" "c \<noteq> 0"
  1292   assumes "filterlim g at_infinity F"
  1293   shows   "filterlim (\<lambda>x. f x * g x) at_infinity F"
  1294 proof -
  1295   have "((\<lambda>x. inverse (f x) * inverse (g x)) \<longlongrightarrow> inverse c * 0) F"
  1296     by (intro tendsto_mult tendsto_inverse assms filterlim_compose[OF tendsto_inverse_0])
  1297   hence "filterlim (\<lambda>x. inverse (f x) * inverse (g x)) (at (inverse c * 0)) F"
  1298     unfolding filterlim_at using assms
  1299     by (auto intro: filterlim_at_infinity_imp_eventually_ne tendsto_imp_eventually_ne eventually_conj)
  1300   thus ?thesis by (subst filterlim_inverse_at_iff[symmetric]) simp_all
  1301 qed
  1302 
  1303 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) \<longlongrightarrow> 0) F"
  1304  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1305 
  1306 lemma mult_nat_left_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. c * x :: nat) at_top sequentially"
  1307   by (rule filterlim_subseq) (auto simp: subseq_def)
  1308 
  1309 lemma mult_nat_right_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. x * c :: nat) at_top sequentially"
  1310   by (rule filterlim_subseq) (auto simp: subseq_def)
  1311 
  1312 lemma at_to_infinity:
  1313   fixes x :: "'a :: {real_normed_field,field}"
  1314   shows "(at (0::'a)) = filtermap inverse at_infinity"
  1315 proof (rule antisym)
  1316   have "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1317     by (fact tendsto_inverse_0)
  1318   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1319     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1320     apply (rule_tac x="1" in exI, auto)
  1321     done
  1322 next
  1323   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1324     using filterlim_inverse_at_infinity unfolding filterlim_def
  1325     by (rule filtermap_mono)
  1326   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1327     by (simp add: filtermap_ident filtermap_filtermap)
  1328 qed
  1329 
  1330 lemma lim_at_infinity_0:
  1331   fixes l :: "'a :: {real_normed_field,field}"
  1332   shows "(f \<longlongrightarrow> l) at_infinity \<longleftrightarrow> ((f o inverse) \<longlongrightarrow> l) (at (0::'a))"
  1333 by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1334 
  1335 lemma lim_zero_infinity:
  1336   fixes l :: "'a :: {real_normed_field,field}"
  1337   shows "((\<lambda>x. f(1 / x)) \<longlongrightarrow> l) (at (0::'a)) \<Longrightarrow> (f \<longlongrightarrow> l) at_infinity"
  1338 by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1339 
  1340 
  1341 text \<open>
  1342 
  1343 We only show rules for multiplication and addition when the functions are either against a real
  1344 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1345 
  1346 \<close>
  1347 
  1348 lemma filterlim_tendsto_pos_mult_at_top:
  1349   assumes f: "(f \<longlongrightarrow> c) F" and c: "0 < c"
  1350   assumes g: "LIM x F. g x :> at_top"
  1351   shows "LIM x F. (f x * g x :: real) :> at_top"
  1352   unfolding filterlim_at_top_gt[where c=0]
  1353 proof safe
  1354   fix Z :: real assume "0 < Z"
  1355   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1356     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_mono
  1357              simp: dist_real_def abs_real_def split: split_if_asm)
  1358   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1359     unfolding filterlim_at_top by auto
  1360   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1361   proof eventually_elim
  1362     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1363     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1364       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1365     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1366        by simp
  1367   qed
  1368 qed
  1369 
  1370 lemma filterlim_at_top_mult_at_top:
  1371   assumes f: "LIM x F. f x :> at_top"
  1372   assumes g: "LIM x F. g x :> at_top"
  1373   shows "LIM x F. (f x * g x :: real) :> at_top"
  1374   unfolding filterlim_at_top_gt[where c=0]
  1375 proof safe
  1376   fix Z :: real assume "0 < Z"
  1377   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1378     unfolding filterlim_at_top by auto
  1379   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1380     unfolding filterlim_at_top by auto
  1381   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1382   proof eventually_elim
  1383     fix x assume "1 \<le> f x" "Z \<le> g x"
  1384     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1385       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1386     then show "Z \<le> f x * g x"
  1387        by simp
  1388   qed
  1389 qed
  1390 
  1391 lemma filterlim_tendsto_pos_mult_at_bot:
  1392   assumes "(f \<longlongrightarrow> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1393   shows "LIM x F. f x * g x :> at_bot"
  1394   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1395   unfolding filterlim_uminus_at_bot by simp
  1396 
  1397 lemma filterlim_tendsto_neg_mult_at_bot:
  1398   assumes c: "(f \<longlongrightarrow> c) F" "(c::real) < 0" and g: "filterlim g at_top F"
  1399   shows "LIM x F. f x * g x :> at_bot"
  1400   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1401   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1402 
  1403 lemma filterlim_pow_at_top:
  1404   fixes f :: "real \<Rightarrow> real"
  1405   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1406   shows "LIM x F. (f x)^n :: real :> at_top"
  1407 using \<open>0 < n\<close> proof (induct n)
  1408   case (Suc n) with f show ?case
  1409     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1410 qed simp
  1411 
  1412 lemma filterlim_pow_at_bot_even:
  1413   fixes f :: "real \<Rightarrow> real"
  1414   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1415   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1416 
  1417 lemma filterlim_pow_at_bot_odd:
  1418   fixes f :: "real \<Rightarrow> real"
  1419   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1420   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1421 
  1422 lemma filterlim_tendsto_add_at_top:
  1423   assumes f: "(f \<longlongrightarrow> c) F"
  1424   assumes g: "LIM x F. g x :> at_top"
  1425   shows "LIM x F. (f x + g x :: real) :> at_top"
  1426   unfolding filterlim_at_top_gt[where c=0]
  1427 proof safe
  1428   fix Z :: real assume "0 < Z"
  1429   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1430     by (auto dest!: tendstoD[where e=1] elim!: eventually_mono simp: dist_real_def)
  1431   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1432     unfolding filterlim_at_top by auto
  1433   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1434     by eventually_elim simp
  1435 qed
  1436 
  1437 lemma LIM_at_top_divide:
  1438   fixes f g :: "'a \<Rightarrow> real"
  1439   assumes f: "(f \<longlongrightarrow> a) F" "0 < a"
  1440   assumes g: "(g \<longlongrightarrow> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1441   shows "LIM x F. f x / g x :> at_top"
  1442   unfolding divide_inverse
  1443   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1444 
  1445 lemma filterlim_at_top_add_at_top:
  1446   assumes f: "LIM x F. f x :> at_top"
  1447   assumes g: "LIM x F. g x :> at_top"
  1448   shows "LIM x F. (f x + g x :: real) :> at_top"
  1449   unfolding filterlim_at_top_gt[where c=0]
  1450 proof safe
  1451   fix Z :: real assume "0 < Z"
  1452   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1453     unfolding filterlim_at_top by auto
  1454   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1455     unfolding filterlim_at_top by auto
  1456   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1457     by eventually_elim simp
  1458 qed
  1459 
  1460 lemma tendsto_divide_0:
  1461   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1462   assumes f: "(f \<longlongrightarrow> c) F"
  1463   assumes g: "LIM x F. g x :> at_infinity"
  1464   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1465   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1466 
  1467 lemma linear_plus_1_le_power:
  1468   fixes x :: real
  1469   assumes x: "0 \<le> x"
  1470   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1471 proof (induct n)
  1472   case (Suc n)
  1473   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1474     by (simp add: field_simps of_nat_Suc x)
  1475   also have "\<dots> \<le> (x + 1)^Suc n"
  1476     using Suc x by (simp add: mult_left_mono)
  1477   finally show ?case .
  1478 qed simp
  1479 
  1480 lemma filterlim_realpow_sequentially_gt1:
  1481   fixes x :: "'a :: real_normed_div_algebra"
  1482   assumes x[arith]: "1 < norm x"
  1483   shows "LIM n sequentially. x ^ n :> at_infinity"
  1484 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1485   fix y :: real assume "0 < y"
  1486   have "0 < norm x - 1" by simp
  1487   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1488   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1489   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1490   also have "\<dots> = norm x ^ N" by simp
  1491   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1492     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1493   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1494     unfolding eventually_sequentially
  1495     by (auto simp: norm_power)
  1496 qed simp
  1497 
  1498 
  1499 subsection \<open>Limits of Sequences\<close>
  1500 
  1501 lemma [trans]: "X = Y \<Longrightarrow> Y \<longlonglongrightarrow> z \<Longrightarrow> X \<longlonglongrightarrow> z"
  1502   by simp
  1503 
  1504 lemma LIMSEQ_iff:
  1505   fixes L :: "'a::real_normed_vector"
  1506   shows "(X \<longlonglongrightarrow> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1507 unfolding lim_sequentially dist_norm ..
  1508 
  1509 lemma LIMSEQ_I:
  1510   fixes L :: "'a::real_normed_vector"
  1511   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1512 by (simp add: LIMSEQ_iff)
  1513 
  1514 lemma LIMSEQ_D:
  1515   fixes L :: "'a::real_normed_vector"
  1516   shows "\<lbrakk>X \<longlonglongrightarrow> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1517 by (simp add: LIMSEQ_iff)
  1518 
  1519 lemma LIMSEQ_linear: "\<lbrakk> X \<longlonglongrightarrow> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) \<longlonglongrightarrow> x"
  1520   unfolding tendsto_def eventually_sequentially
  1521   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1522 
  1523 lemma Bseq_inverse_lemma:
  1524   fixes x :: "'a::real_normed_div_algebra"
  1525   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1526 apply (subst nonzero_norm_inverse, clarsimp)
  1527 apply (erule (1) le_imp_inverse_le)
  1528 done
  1529 
  1530 lemma Bseq_inverse:
  1531   fixes a :: "'a::real_normed_div_algebra"
  1532   shows "\<lbrakk>X \<longlonglongrightarrow> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1533   by (rule Bfun_inverse)
  1534 
  1535 text\<open>Transformation of limit.\<close>
  1536 
  1537 lemma eventually_at2:
  1538   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
  1539   unfolding eventually_at by auto
  1540 
  1541 lemma Lim_transform:
  1542   fixes a b :: "'a::real_normed_vector"
  1543   shows "\<lbrakk>(g \<longlongrightarrow> a) F; ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> (f \<longlongrightarrow> a) F"
  1544   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1545 
  1546 lemma Lim_transform2:
  1547   fixes a b :: "'a::real_normed_vector"
  1548   shows "\<lbrakk>(f \<longlongrightarrow> a) F; ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> (g \<longlongrightarrow> a) F"
  1549   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1550 
  1551 proposition Lim_transform_eq:
  1552   fixes a :: "'a::real_normed_vector"
  1553   shows "((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F \<longleftrightarrow> (g \<longlongrightarrow> a) F"
  1554 using Lim_transform Lim_transform2 by blast
  1555 
  1556 lemma Lim_transform_eventually:
  1557   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> (g \<longlongrightarrow> l) net"
  1558   apply (rule topological_tendstoI)
  1559   apply (drule (2) topological_tendstoD)
  1560   apply (erule (1) eventually_elim2, simp)
  1561   done
  1562 
  1563 lemma Lim_transform_within:
  1564   assumes "(f \<longlongrightarrow> l) (at x within S)"
  1565     and "0 < d"
  1566     and "\<And>x'. \<lbrakk>x'\<in>S; 0 < dist x' x; dist x' x < d\<rbrakk> \<Longrightarrow> f x' = g x'"
  1567   shows "(g \<longlongrightarrow> l) (at x within S)"
  1568 proof (rule Lim_transform_eventually)
  1569   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1570     using assms by (auto simp: eventually_at)
  1571   show "(f \<longlongrightarrow> l) (at x within S)" by fact
  1572 qed
  1573 
  1574 text\<open>Common case assuming being away from some crucial point like 0.\<close>
  1575 
  1576 lemma Lim_transform_away_within:
  1577   fixes a b :: "'a::t1_space"
  1578   assumes "a \<noteq> b"
  1579     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1580     and "(f \<longlongrightarrow> l) (at a within S)"
  1581   shows "(g \<longlongrightarrow> l) (at a within S)"
  1582 proof (rule Lim_transform_eventually)
  1583   show "(f \<longlongrightarrow> l) (at a within S)" by fact
  1584   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1585     unfolding eventually_at_topological
  1586     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1587 qed
  1588 
  1589 lemma Lim_transform_away_at:
  1590   fixes a b :: "'a::t1_space"
  1591   assumes ab: "a\<noteq>b"
  1592     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1593     and fl: "(f \<longlongrightarrow> l) (at a)"
  1594   shows "(g \<longlongrightarrow> l) (at a)"
  1595   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1596 
  1597 text\<open>Alternatively, within an open set.\<close>
  1598 
  1599 lemma Lim_transform_within_open:
  1600   assumes "(f \<longlongrightarrow> l) (at a within T)"
  1601     and "open s" and "a \<in> s"
  1602     and "\<And>x. \<lbrakk>x\<in>s; x \<noteq> a\<rbrakk> \<Longrightarrow> f x = g x"
  1603   shows "(g \<longlongrightarrow> l) (at a within T)"
  1604 proof (rule Lim_transform_eventually)
  1605   show "eventually (\<lambda>x. f x = g x) (at a within T)"
  1606     unfolding eventually_at_topological
  1607     using assms by auto
  1608   show "(f \<longlongrightarrow> l) (at a within T)" by fact
  1609 qed
  1610 
  1611 text\<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1612 
  1613 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1614 
  1615 lemma Lim_cong_within(*[cong add]*):
  1616   assumes "a = b"
  1617     and "x = y"
  1618     and "S = T"
  1619     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1620   shows "(f \<longlongrightarrow> x) (at a within S) \<longleftrightarrow> (g \<longlongrightarrow> y) (at b within T)"
  1621   unfolding tendsto_def eventually_at_topological
  1622   using assms by simp
  1623 
  1624 lemma Lim_cong_at(*[cong add]*):
  1625   assumes "a = b" "x = y"
  1626     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1627   shows "((\<lambda>x. f x) \<longlongrightarrow> x) (at a) \<longleftrightarrow> ((g \<longlongrightarrow> y) (at a))"
  1628   unfolding tendsto_def eventually_at_topological
  1629   using assms by simp
  1630 text\<open>An unbounded sequence's inverse tends to 0\<close>
  1631 
  1632 lemma LIMSEQ_inverse_zero:
  1633   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) \<longlonglongrightarrow> 0"
  1634   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1635   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1636   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1637   done
  1638 
  1639 text\<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity\<close>
  1640 
  1641 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) \<longlonglongrightarrow> 0"
  1642   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1643             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1644 
  1645 text\<open>The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1646 infinity is now easily proved\<close>
  1647 
  1648 lemma LIMSEQ_inverse_real_of_nat_add:
  1649      "(%n. r + inverse(real(Suc n))) \<longlonglongrightarrow> r"
  1650   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1651 
  1652 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1653      "(%n. r + -inverse(real(Suc n))) \<longlonglongrightarrow> r"
  1654   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1655   by auto
  1656 
  1657 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1658      "(%n. r*( 1 + -inverse(real(Suc n)))) \<longlonglongrightarrow> r"
  1659   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1660   by auto
  1661 
  1662 lemma lim_inverse_n: "((\<lambda>n. inverse(of_nat n)) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1663   using lim_1_over_n by (simp add: inverse_eq_divide)
  1664 
  1665 lemma LIMSEQ_Suc_n_over_n: "(\<lambda>n. of_nat (Suc n) / of_nat n :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1666 proof (rule Lim_transform_eventually)
  1667   show "eventually (\<lambda>n. 1 + inverse (of_nat n :: 'a) = of_nat (Suc n) / of_nat n) sequentially"
  1668     using eventually_gt_at_top[of "0::nat"] by eventually_elim (simp add: field_simps)
  1669   have "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1 + 0"
  1670     by (intro tendsto_add tendsto_const lim_inverse_n)
  1671   thus "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1" by simp
  1672 qed
  1673 
  1674 lemma LIMSEQ_n_over_Suc_n: "(\<lambda>n. of_nat n / of_nat (Suc n) :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1675 proof (rule Lim_transform_eventually)
  1676   show "eventually (\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a) =
  1677                         of_nat n / of_nat (Suc n)) sequentially"
  1678     using eventually_gt_at_top[of "0::nat"]
  1679     by eventually_elim (simp add: field_simps del: of_nat_Suc)
  1680   have "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> inverse 1"
  1681     by (intro tendsto_inverse LIMSEQ_Suc_n_over_n) simp_all
  1682   thus "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> 1" by simp
  1683 qed
  1684 
  1685 subsection \<open>Convergence on sequences\<close>
  1686 
  1687 lemma convergent_cong:
  1688   assumes "eventually (\<lambda>x. f x = g x) sequentially"
  1689   shows   "convergent f \<longleftrightarrow> convergent g"
  1690   unfolding convergent_def by (subst filterlim_cong[OF refl refl assms]) (rule refl)
  1691 
  1692 lemma convergent_Suc_iff: "convergent (\<lambda>n. f (Suc n)) \<longleftrightarrow> convergent f"
  1693   by (auto simp: convergent_def LIMSEQ_Suc_iff)
  1694 
  1695 lemma convergent_ignore_initial_segment: "convergent (\<lambda>n. f (n + m)) = convergent f"
  1696 proof (induction m arbitrary: f)
  1697   case (Suc m)
  1698   have "convergent (\<lambda>n. f (n + Suc m)) \<longleftrightarrow> convergent (\<lambda>n. f (Suc n + m))" by simp
  1699   also have "\<dots> \<longleftrightarrow> convergent (\<lambda>n. f (n + m))" by (rule convergent_Suc_iff)
  1700   also have "\<dots> \<longleftrightarrow> convergent f" by (rule Suc)
  1701   finally show ?case .
  1702 qed simp_all
  1703 
  1704 lemma convergent_add:
  1705   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1706   assumes "convergent (\<lambda>n. X n)"
  1707   assumes "convergent (\<lambda>n. Y n)"
  1708   shows "convergent (\<lambda>n. X n + Y n)"
  1709   using assms unfolding convergent_def by (blast intro: tendsto_add)
  1710 
  1711 lemma convergent_setsum:
  1712   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1713   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1714   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1715 proof (cases "finite A")
  1716   case True from this and assms show ?thesis
  1717     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1718 qed (simp add: convergent_const)
  1719 
  1720 lemma (in bounded_linear) convergent:
  1721   assumes "convergent (\<lambda>n. X n)"
  1722   shows "convergent (\<lambda>n. f (X n))"
  1723   using assms unfolding convergent_def by (blast intro: tendsto)
  1724 
  1725 lemma (in bounded_bilinear) convergent:
  1726   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1727   shows "convergent (\<lambda>n. X n ** Y n)"
  1728   using assms unfolding convergent_def by (blast intro: tendsto)
  1729 
  1730 lemma convergent_minus_iff:
  1731   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1732   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1733 apply (simp add: convergent_def)
  1734 apply (auto dest: tendsto_minus)
  1735 apply (drule tendsto_minus, auto)
  1736 done
  1737 
  1738 lemma convergent_diff:
  1739   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1740   assumes "convergent (\<lambda>n. X n)"
  1741   assumes "convergent (\<lambda>n. Y n)"
  1742   shows "convergent (\<lambda>n. X n - Y n)"
  1743   using assms unfolding convergent_def by (blast intro: tendsto_diff)
  1744 
  1745 lemma convergent_norm:
  1746   assumes "convergent f"
  1747   shows   "convergent (\<lambda>n. norm (f n))"
  1748 proof -
  1749   from assms have "f \<longlonglongrightarrow> lim f" by (simp add: convergent_LIMSEQ_iff)
  1750   hence "(\<lambda>n. norm (f n)) \<longlonglongrightarrow> norm (lim f)" by (rule tendsto_norm)
  1751   thus ?thesis by (auto simp: convergent_def)
  1752 qed
  1753 
  1754 lemma convergent_of_real:
  1755   "convergent f \<Longrightarrow> convergent (\<lambda>n. of_real (f n) :: 'a :: real_normed_algebra_1)"
  1756   unfolding convergent_def by (blast intro!: tendsto_of_real)
  1757 
  1758 lemma convergent_add_const_iff:
  1759   "convergent (\<lambda>n. c + f n :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1760 proof
  1761   assume "convergent (\<lambda>n. c + f n)"
  1762   from convergent_diff[OF this convergent_const[of c]] show "convergent f" by simp
  1763 next
  1764   assume "convergent f"
  1765   from convergent_add[OF convergent_const[of c] this] show "convergent (\<lambda>n. c + f n)" by simp
  1766 qed
  1767 
  1768 lemma convergent_add_const_right_iff:
  1769   "convergent (\<lambda>n. f n + c :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1770   using convergent_add_const_iff[of c f] by (simp add: add_ac)
  1771 
  1772 lemma convergent_diff_const_right_iff:
  1773   "convergent (\<lambda>n. f n - c :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1774   using convergent_add_const_right_iff[of f "-c"] by (simp add: add_ac)
  1775 
  1776 lemma convergent_mult:
  1777   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
  1778   assumes "convergent (\<lambda>n. X n)"
  1779   assumes "convergent (\<lambda>n. Y n)"
  1780   shows "convergent (\<lambda>n. X n * Y n)"
  1781   using assms unfolding convergent_def by (blast intro: tendsto_mult)
  1782 
  1783 lemma convergent_mult_const_iff:
  1784   assumes "c \<noteq> 0"
  1785   shows   "convergent (\<lambda>n. c * f n :: 'a :: real_normed_field) \<longleftrightarrow> convergent f"
  1786 proof
  1787   assume "convergent (\<lambda>n. c * f n)"
  1788   from assms convergent_mult[OF this convergent_const[of "inverse c"]]
  1789     show "convergent f" by (simp add: field_simps)
  1790 next
  1791   assume "convergent f"
  1792   from convergent_mult[OF convergent_const[of c] this] show "convergent (\<lambda>n. c * f n)" by simp
  1793 qed
  1794 
  1795 lemma convergent_mult_const_right_iff:
  1796   assumes "c \<noteq> 0"
  1797   shows   "convergent (\<lambda>n. (f n :: 'a :: real_normed_field) * c) \<longleftrightarrow> convergent f"
  1798   using convergent_mult_const_iff[OF assms, of f] by (simp add: mult_ac)
  1799 
  1800 lemma convergent_imp_Bseq: "convergent f \<Longrightarrow> Bseq f"
  1801   by (simp add: Cauchy_Bseq convergent_Cauchy)
  1802 
  1803 
  1804 text \<open>A monotone sequence converges to its least upper bound.\<close>
  1805 
  1806 lemma LIMSEQ_incseq_SUP:
  1807   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1808   assumes u: "bdd_above (range X)"
  1809   assumes X: "incseq X"
  1810   shows "X \<longlonglongrightarrow> (SUP i. X i)"
  1811   by (rule order_tendstoI)
  1812      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1813 
  1814 lemma LIMSEQ_decseq_INF:
  1815   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1816   assumes u: "bdd_below (range X)"
  1817   assumes X: "decseq X"
  1818   shows "X \<longlonglongrightarrow> (INF i. X i)"
  1819   by (rule order_tendstoI)
  1820      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1821 
  1822 text\<open>Main monotonicity theorem\<close>
  1823 
  1824 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1825   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1826 
  1827 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1828   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1829 
  1830 lemma monoseq_imp_convergent_iff_Bseq: "monoseq (f :: nat \<Rightarrow> real) \<Longrightarrow> convergent f \<longleftrightarrow> Bseq f"
  1831   using Bseq_monoseq_convergent[of f] convergent_imp_Bseq[of f] by blast
  1832 
  1833 lemma Bseq_monoseq_convergent'_inc:
  1834   "Bseq (\<lambda>n. f (n + M) :: real) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<le> f n) \<Longrightarrow> convergent f"
  1835   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  1836      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  1837 
  1838 lemma Bseq_monoseq_convergent'_dec:
  1839   "Bseq (\<lambda>n. f (n + M) :: real) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<ge> f n) \<Longrightarrow> convergent f"
  1840   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  1841      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  1842 
  1843 lemma Cauchy_iff:
  1844   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1845   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1846   unfolding Cauchy_def dist_norm ..
  1847 
  1848 lemma CauchyI:
  1849   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1850   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1851 by (simp add: Cauchy_iff)
  1852 
  1853 lemma CauchyD:
  1854   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1855   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1856 by (simp add: Cauchy_iff)
  1857 
  1858 lemma incseq_convergent:
  1859   fixes X :: "nat \<Rightarrow> real"
  1860   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1861   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. X i \<le> L"
  1862 proof atomize_elim
  1863   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  1864   obtain L where "X \<longlonglongrightarrow> L"
  1865     by (auto simp: convergent_def monoseq_def incseq_def)
  1866   with \<open>incseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. X i \<le> L)"
  1867     by (auto intro!: exI[of _ L] incseq_le)
  1868 qed
  1869 
  1870 lemma decseq_convergent:
  1871   fixes X :: "nat \<Rightarrow> real"
  1872   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1873   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. L \<le> X i"
  1874 proof atomize_elim
  1875   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  1876   obtain L where "X \<longlonglongrightarrow> L"
  1877     by (auto simp: convergent_def monoseq_def decseq_def)
  1878   with \<open>decseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. L \<le> X i)"
  1879     by (auto intro!: exI[of _ L] decseq_le)
  1880 qed
  1881 
  1882 subsubsection \<open>Cauchy Sequences are Bounded\<close>
  1883 
  1884 text\<open>A Cauchy sequence is bounded -- this is the standard
  1885   proof mechanization rather than the nonstandard proof\<close>
  1886 
  1887 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1888           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1889 apply (clarify, drule spec, drule (1) mp)
  1890 apply (simp only: norm_minus_commute)
  1891 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1892 apply simp
  1893 done
  1894 
  1895 subsection \<open>Power Sequences\<close>
  1896 
  1897 text\<open>The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1898 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1899   also fact that bounded and monotonic sequence converges.\<close>
  1900 
  1901 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1902 apply (simp add: Bseq_def)
  1903 apply (rule_tac x = 1 in exI)
  1904 apply (simp add: power_abs)
  1905 apply (auto dest: power_mono)
  1906 done
  1907 
  1908 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1909 apply (clarify intro!: mono_SucI2)
  1910 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1911 done
  1912 
  1913 lemma convergent_realpow:
  1914   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1915 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1916 
  1917 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) \<longlonglongrightarrow> 0"
  1918   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1919 
  1920 lemma LIMSEQ_realpow_zero:
  1921   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  1922 proof cases
  1923   assume "0 \<le> x" and "x \<noteq> 0"
  1924   hence x0: "0 < x" by simp
  1925   assume x1: "x < 1"
  1926   from x0 x1 have "1 < inverse x"
  1927     by (rule one_less_inverse)
  1928   hence "(\<lambda>n. inverse (inverse x ^ n)) \<longlonglongrightarrow> 0"
  1929     by (rule LIMSEQ_inverse_realpow_zero)
  1930   thus ?thesis by (simp add: power_inverse)
  1931 qed (rule LIMSEQ_imp_Suc, simp)
  1932 
  1933 lemma LIMSEQ_power_zero:
  1934   fixes x :: "'a::{real_normed_algebra_1}"
  1935   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  1936 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1937 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1938 apply (simp add: power_abs norm_power_ineq)
  1939 done
  1940 
  1941 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) \<longlonglongrightarrow> 0"
  1942   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1943 
  1944 text\<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}\<close>
  1945 
  1946 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) \<longlonglongrightarrow> 0"
  1947   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1948 
  1949 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) \<longlonglongrightarrow> 0"
  1950   by (rule LIMSEQ_power_zero) simp
  1951 
  1952 
  1953 subsection \<open>Limits of Functions\<close>
  1954 
  1955 lemma LIM_eq:
  1956   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1957   shows "f \<midarrow>a\<rightarrow> L =
  1958      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1959 by (simp add: LIM_def dist_norm)
  1960 
  1961 lemma LIM_I:
  1962   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1963   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1964       ==> f \<midarrow>a\<rightarrow> L"
  1965 by (simp add: LIM_eq)
  1966 
  1967 lemma LIM_D:
  1968   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1969   shows "[| f \<midarrow>a\<rightarrow> L; 0<r |]
  1970       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1971 by (simp add: LIM_eq)
  1972 
  1973 lemma LIM_offset:
  1974   fixes a :: "'a::real_normed_vector"
  1975   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>x. f (x + k)) \<midarrow>(a - k)\<rightarrow> L"
  1976   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1977 
  1978 lemma LIM_offset_zero:
  1979   fixes a :: "'a::real_normed_vector"
  1980   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  1981 by (drule_tac k="a" in LIM_offset, simp add: add.commute)
  1982 
  1983 lemma LIM_offset_zero_cancel:
  1984   fixes a :: "'a::real_normed_vector"
  1985   shows "(\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  1986 by (drule_tac k="- a" in LIM_offset, simp)
  1987 
  1988 lemma LIM_offset_zero_iff:
  1989   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1990   shows  "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  1991   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1992 
  1993 lemma LIM_zero:
  1994   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1995   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. f x - l) \<longlongrightarrow> 0) F"
  1996 unfolding tendsto_iff dist_norm by simp
  1997 
  1998 lemma LIM_zero_cancel:
  1999   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2000   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> l) F"
  2001 unfolding tendsto_iff dist_norm by simp
  2002 
  2003 lemma LIM_zero_iff:
  2004   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  2005   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F = (f \<longlongrightarrow> l) F"
  2006 unfolding tendsto_iff dist_norm by simp
  2007 
  2008 lemma LIM_imp_LIM:
  2009   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2010   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  2011   assumes f: "f \<midarrow>a\<rightarrow> l"
  2012   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  2013   shows "g \<midarrow>a\<rightarrow> m"
  2014   by (rule metric_LIM_imp_LIM [OF f],
  2015     simp add: dist_norm le)
  2016 
  2017 lemma LIM_equal2:
  2018   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2019   assumes 1: "0 < R"
  2020   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  2021   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  2022 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  2023 
  2024 lemma LIM_compose2:
  2025   fixes a :: "'a::real_normed_vector"
  2026   assumes f: "f \<midarrow>a\<rightarrow> b"
  2027   assumes g: "g \<midarrow>b\<rightarrow> c"
  2028   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  2029   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  2030 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  2031 
  2032 lemma real_LIM_sandwich_zero:
  2033   fixes f g :: "'a::topological_space \<Rightarrow> real"
  2034   assumes f: "f \<midarrow>a\<rightarrow> 0"
  2035   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  2036   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  2037   shows "g \<midarrow>a\<rightarrow> 0"
  2038 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  2039   fix x assume x: "x \<noteq> a"
  2040   have "norm (g x - 0) = g x" by (simp add: 1 x)
  2041   also have "g x \<le> f x" by (rule 2 [OF x])
  2042   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  2043   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  2044   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  2045 qed
  2046 
  2047 
  2048 subsection \<open>Continuity\<close>
  2049 
  2050 lemma LIM_isCont_iff:
  2051   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2052   shows "(f \<midarrow>a\<rightarrow> f a) = ((\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> f a)"
  2053 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  2054 
  2055 lemma isCont_iff:
  2056   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2057   shows "isCont f x = (\<lambda>h. f (x + h)) \<midarrow>0\<rightarrow> f x"
  2058 by (simp add: isCont_def LIM_isCont_iff)
  2059 
  2060 lemma isCont_LIM_compose2:
  2061   fixes a :: "'a::real_normed_vector"
  2062   assumes f [unfolded isCont_def]: "isCont f a"
  2063   assumes g: "g \<midarrow>f a\<rightarrow> l"
  2064   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  2065   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  2066 by (rule LIM_compose2 [OF f g inj])
  2067 
  2068 
  2069 lemma isCont_norm [simp]:
  2070   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2071   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  2072   by (fact continuous_norm)
  2073 
  2074 lemma isCont_rabs [simp]:
  2075   fixes f :: "'a::t2_space \<Rightarrow> real"
  2076   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  2077   by (fact continuous_rabs)
  2078 
  2079 lemma isCont_add [simp]:
  2080   fixes f :: "'a::t2_space \<Rightarrow> 'b::topological_monoid_add"
  2081   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  2082   by (fact continuous_add)
  2083 
  2084 lemma isCont_minus [simp]:
  2085   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2086   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  2087   by (fact continuous_minus)
  2088 
  2089 lemma isCont_diff [simp]:
  2090   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2091   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  2092   by (fact continuous_diff)
  2093 
  2094 lemma isCont_mult [simp]:
  2095   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  2096   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  2097   by (fact continuous_mult)
  2098 
  2099 lemma (in bounded_linear) isCont:
  2100   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  2101   by (fact continuous)
  2102 
  2103 lemma (in bounded_bilinear) isCont:
  2104   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  2105   by (fact continuous)
  2106 
  2107 lemmas isCont_scaleR [simp] =
  2108   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  2109 
  2110 lemmas isCont_of_real [simp] =
  2111   bounded_linear.isCont [OF bounded_linear_of_real]
  2112 
  2113 lemma isCont_power [simp]:
  2114   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  2115   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  2116   by (fact continuous_power)
  2117 
  2118 lemma isCont_setsum [simp]:
  2119   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
  2120   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  2121   by (auto intro: continuous_setsum)
  2122 
  2123 subsection \<open>Uniform Continuity\<close>
  2124 
  2125 definition
  2126   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  2127   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  2128 
  2129 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  2130 by (simp add: isUCont_def isCont_def LIM_def, force)
  2131 
  2132 lemma isUCont_Cauchy:
  2133   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2134 unfolding isUCont_def
  2135 apply (rule metric_CauchyI)
  2136 apply (drule_tac x=e in spec, safe)
  2137 apply (drule_tac e=s in metric_CauchyD, safe)
  2138 apply (rule_tac x=M in exI, simp)
  2139 done
  2140 
  2141 lemma (in bounded_linear) isUCont: "isUCont f"
  2142 unfolding isUCont_def dist_norm
  2143 proof (intro allI impI)
  2144   fix r::real assume r: "0 < r"
  2145   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  2146     using pos_bounded by blast
  2147   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  2148   proof (rule exI, safe)
  2149     from r K show "0 < r / K" by simp
  2150   next
  2151     fix x y :: 'a
  2152     assume xy: "norm (x - y) < r / K"
  2153     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  2154     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  2155     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  2156     finally show "norm (f x - f y) < r" .
  2157   qed
  2158 qed
  2159 
  2160 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2161 by (rule isUCont [THEN isUCont_Cauchy])
  2162 
  2163 lemma LIM_less_bound:
  2164   fixes f :: "real \<Rightarrow> real"
  2165   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  2166   shows "0 \<le> f x"
  2167 proof (rule tendsto_le_const)
  2168   show "(f \<longlongrightarrow> f x) (at_left x)"
  2169     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  2170   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  2171     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  2172 qed simp
  2173 
  2174 
  2175 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  2176 
  2177 lemma nested_sequence_unique:
  2178   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) \<longlonglongrightarrow> 0"
  2179   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f \<longlonglongrightarrow> l) \<and> ((\<forall>n. l \<le> g n) \<and> g \<longlonglongrightarrow> l)"
  2180 proof -
  2181   have "incseq f" unfolding incseq_Suc_iff by fact
  2182   have "decseq g" unfolding decseq_Suc_iff by fact
  2183 
  2184   { fix n
  2185     from \<open>decseq g\<close> have "g n \<le> g 0" by (rule decseqD) simp
  2186     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f n \<le> g 0" by auto }
  2187   then obtain u where "f \<longlonglongrightarrow> u" "\<forall>i. f i \<le> u"
  2188     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  2189   moreover
  2190   { fix n
  2191     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  2192     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f 0 \<le> g n" by simp }
  2193   then obtain l where "g \<longlonglongrightarrow> l" "\<forall>i. l \<le> g i"
  2194     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  2195   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f \<longlonglongrightarrow> u\<close> \<open>g \<longlonglongrightarrow> l\<close>]]
  2196   ultimately show ?thesis by auto
  2197 qed
  2198 
  2199 lemma Bolzano[consumes 1, case_names trans local]:
  2200   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  2201   assumes [arith]: "a \<le> b"
  2202   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  2203   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  2204   shows "P a b"
  2205 proof -
  2206   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  2207   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  2208   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  2209     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  2210     by (simp_all add: l_def u_def bisect_def split: prod.split)
  2211 
  2212   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  2213 
  2214   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l \<longlonglongrightarrow> x) \<and> ((\<forall>n. x \<le> u n) \<and> u \<longlonglongrightarrow> x)"
  2215   proof (safe intro!: nested_sequence_unique)
  2216     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  2217   next
  2218     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  2219     then show "(\<lambda>n. l n - u n) \<longlonglongrightarrow> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  2220   qed fact
  2221   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l \<longlonglongrightarrow> x" "u \<longlonglongrightarrow> x" by auto
  2222   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  2223     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  2224 
  2225   show "P a b"
  2226   proof (rule ccontr)
  2227     assume "\<not> P a b"
  2228     { fix n have "\<not> P (l n) (u n)"
  2229       proof (induct n)
  2230         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  2231       qed (simp add: \<open>\<not> P a b\<close>) }
  2232     moreover
  2233     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  2234         using \<open>0 < d\<close> \<open>l \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2235       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  2236         using \<open>0 < d\<close> \<open>u \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2237       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  2238       proof eventually_elim
  2239         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  2240         from add_strict_mono[OF this] have "u n - l n < d" by simp
  2241         with x show "P (l n) (u n)" by (rule d)
  2242       qed }
  2243     ultimately show False by simp
  2244   qed
  2245 qed
  2246 
  2247 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  2248 proof (cases "a \<le> b", rule compactI)
  2249   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  2250   def T == "{a .. b}"
  2251   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  2252   proof (induct rule: Bolzano)
  2253     case (trans a b c)
  2254     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  2255     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  2256       by (auto simp: *)
  2257     with trans show ?case
  2258       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  2259   next
  2260     case (local x)
  2261     then have "x \<in> \<Union>C" using C by auto
  2262     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  2263     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  2264       by (auto simp: open_dist dist_real_def subset_eq Ball_def abs_less_iff)
  2265     with \<open>c \<in> C\<close> show ?case
  2266       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  2267   qed
  2268 qed simp
  2269 
  2270 
  2271 lemma continuous_image_closed_interval:
  2272   fixes a b and f :: "real \<Rightarrow> real"
  2273   defines "S \<equiv> {a..b}"
  2274   assumes "a \<le> b" and f: "continuous_on S f"
  2275   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  2276 proof -
  2277   have S: "compact S" "S \<noteq> {}"
  2278     using \<open>a \<le> b\<close> by (auto simp: S_def)
  2279   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  2280     using continuous_attains_sup[OF S f] by auto
  2281   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  2282     using continuous_attains_inf[OF S f] by auto
  2283   moreover have "connected (f`S)"
  2284     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  2285   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  2286     by (auto simp: connected_iff_interval)
  2287   then show ?thesis
  2288     by auto
  2289 qed
  2290 
  2291 lemma open_Collect_positive:
  2292  fixes f :: "'a::t2_space \<Rightarrow> real"
  2293  assumes f: "continuous_on s f"
  2294  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  2295  using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  2296  by (auto simp: Int_def field_simps)
  2297 
  2298 lemma open_Collect_less_Int:
  2299  fixes f g :: "'a::t2_space \<Rightarrow> real"
  2300  assumes f: "continuous_on s f" and g: "continuous_on s g"
  2301  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  2302  using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  2303 
  2304 
  2305 subsection \<open>Boundedness of continuous functions\<close>
  2306 
  2307 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  2308 
  2309 lemma isCont_eq_Ub:
  2310   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2311   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2312     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2313   using continuous_attains_sup[of "{a .. b}" f]
  2314   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2315 
  2316 lemma isCont_eq_Lb:
  2317   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2318   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2319     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2320   using continuous_attains_inf[of "{a .. b}" f]
  2321   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2322 
  2323 lemma isCont_bounded:
  2324   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2325   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  2326   using isCont_eq_Ub[of a b f] by auto
  2327 
  2328 lemma isCont_has_Ub:
  2329   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2330   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2331     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  2332   using isCont_eq_Ub[of a b f] by auto
  2333 
  2334 (*HOL style here: object-level formulations*)
  2335 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  2336       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2337       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2338   by (blast intro: IVT)
  2339 
  2340 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  2341       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2342       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2343   by (blast intro: IVT2)
  2344 
  2345 lemma isCont_Lb_Ub:
  2346   fixes f :: "real \<Rightarrow> real"
  2347   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2348   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2349                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2350 proof -
  2351   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2352     using isCont_eq_Ub[OF assms] by auto
  2353   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2354     using isCont_eq_Lb[OF assms] by auto
  2355   show ?thesis
  2356     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2357     apply (rule_tac x="f L" in exI)
  2358     apply (rule_tac x="f M" in exI)
  2359     apply (cases "L \<le> M")
  2360     apply (simp, metis order_trans)
  2361     apply (simp, metis order_trans)
  2362     done
  2363 qed
  2364 
  2365 
  2366 text\<open>Continuity of inverse function\<close>
  2367 
  2368 lemma isCont_inverse_function:
  2369   fixes f g :: "real \<Rightarrow> real"
  2370   assumes d: "0 < d"
  2371       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2372       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2373   shows "isCont g (f x)"
  2374 proof -
  2375   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  2376 
  2377   have f: "continuous_on ?D f"
  2378     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2379   then have g: "continuous_on (f`?D) g"
  2380     using inj by (intro continuous_on_inv) auto
  2381 
  2382   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2383     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2384   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2385     by (rule continuous_on_subset)
  2386   moreover
  2387   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2388     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2389   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2390     by auto
  2391   ultimately
  2392   show ?thesis
  2393     by (simp add: continuous_on_eq_continuous_at)
  2394 qed
  2395 
  2396 lemma isCont_inverse_function2:
  2397   fixes f g :: "real \<Rightarrow> real" shows
  2398   "\<lbrakk>a < x; x < b;
  2399     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2400     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2401    \<Longrightarrow> isCont g (f x)"
  2402 apply (rule isCont_inverse_function
  2403        [where f=f and d="min (x - a) (b - x)"])
  2404 apply (simp_all add: abs_le_iff)
  2405 done
  2406 
  2407 (* need to rename second isCont_inverse *)
  2408 
  2409 lemma isCont_inv_fun:
  2410   fixes f g :: "real \<Rightarrow> real"
  2411   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;
  2412          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]
  2413       ==> isCont g (f x)"
  2414 by (rule isCont_inverse_function)
  2415 
  2416 text\<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110\<close>
  2417 lemma LIM_fun_gt_zero:
  2418   fixes f :: "real \<Rightarrow> real"
  2419   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2420 apply (drule (1) LIM_D, clarify)
  2421 apply (rule_tac x = s in exI)
  2422 apply (simp add: abs_less_iff)
  2423 done
  2424 
  2425 lemma LIM_fun_less_zero:
  2426   fixes f :: "real \<Rightarrow> real"
  2427   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2428 apply (drule LIM_D [where r="-l"], simp, clarify)
  2429 apply (rule_tac x = s in exI)
  2430 apply (simp add: abs_less_iff)
  2431 done
  2432 
  2433 lemma LIM_fun_not_zero:
  2434   fixes f :: "real \<Rightarrow> real"
  2435   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2436   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2437 
  2438 end