src/HOL/SetInterval.thy
author nipkow
Mon Aug 31 14:09:42 2009 +0200 (2009-08-31)
changeset 32456 341c83339aeb
parent 32436 10cd49e0c067
child 32596 bd68c04dace1
permissions -rw-r--r--
tuned the simp rules for Int involving insert and intervals.
     1 (*  Title:      HOL/SetInterval.thy
     2     Author:     Tobias Nipkow and Clemens Ballarin
     3                 Additions by Jeremy Avigad in March 2004
     4     Copyright   2000  TU Muenchen
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 *)
     8 
     9 header {* Set intervals *}
    10 
    11 theory SetInterval
    12 imports Int
    13 begin
    14 
    15 context ord
    16 begin
    17 definition
    18   lessThan    :: "'a => 'a set"	("(1{..<_})") where
    19   "{..<u} == {x. x < u}"
    20 
    21 definition
    22   atMost      :: "'a => 'a set"	("(1{.._})") where
    23   "{..u} == {x. x \<le> u}"
    24 
    25 definition
    26   greaterThan :: "'a => 'a set"	("(1{_<..})") where
    27   "{l<..} == {x. l<x}"
    28 
    29 definition
    30   atLeast     :: "'a => 'a set"	("(1{_..})") where
    31   "{l..} == {x. l\<le>x}"
    32 
    33 definition
    34   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    35   "{l<..<u} == {l<..} Int {..<u}"
    36 
    37 definition
    38   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    39   "{l..<u} == {l..} Int {..<u}"
    40 
    41 definition
    42   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    43   "{l<..u} == {l<..} Int {..u}"
    44 
    45 definition
    46   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    47   "{l..u} == {l..} Int {..u}"
    48 
    49 end
    50 
    51 
    52 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    53 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    54 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    55 
    56 syntax
    57   "@UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    58   "@UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    59   "@INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    60   "@INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    61 
    62 syntax (xsymbols)
    63   "@UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    64   "@UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    65   "@INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    66   "@INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    67 
    68 syntax (latex output)
    69   "@UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" 10)
    70   "@UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" 10)
    71   "@INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" 10)
    72   "@INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" 10)
    73 
    74 translations
    75   "UN i<=n. A"  == "UN i:{..n}. A"
    76   "UN i<n. A"   == "UN i:{..<n}. A"
    77   "INT i<=n. A" == "INT i:{..n}. A"
    78   "INT i<n. A"  == "INT i:{..<n}. A"
    79 
    80 
    81 subsection {* Various equivalences *}
    82 
    83 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    84 by (simp add: lessThan_def)
    85 
    86 lemma Compl_lessThan [simp]:
    87     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    88 apply (auto simp add: lessThan_def atLeast_def)
    89 done
    90 
    91 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    92 by auto
    93 
    94 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    95 by (simp add: greaterThan_def)
    96 
    97 lemma Compl_greaterThan [simp]:
    98     "!!k:: 'a::linorder. -greaterThan k = atMost k"
    99   by (auto simp add: greaterThan_def atMost_def)
   100 
   101 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   102 apply (subst Compl_greaterThan [symmetric])
   103 apply (rule double_complement)
   104 done
   105 
   106 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   107 by (simp add: atLeast_def)
   108 
   109 lemma Compl_atLeast [simp]:
   110     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   111   by (auto simp add: lessThan_def atLeast_def)
   112 
   113 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   114 by (simp add: atMost_def)
   115 
   116 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   117 by (blast intro: order_antisym)
   118 
   119 
   120 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   121 
   122 lemma atLeast_subset_iff [iff]:
   123      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   124 by (blast intro: order_trans)
   125 
   126 lemma atLeast_eq_iff [iff]:
   127      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   128 by (blast intro: order_antisym order_trans)
   129 
   130 lemma greaterThan_subset_iff [iff]:
   131      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   132 apply (auto simp add: greaterThan_def)
   133  apply (subst linorder_not_less [symmetric], blast)
   134 done
   135 
   136 lemma greaterThan_eq_iff [iff]:
   137      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   138 apply (rule iffI)
   139  apply (erule equalityE)
   140  apply simp_all
   141 done
   142 
   143 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   144 by (blast intro: order_trans)
   145 
   146 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   147 by (blast intro: order_antisym order_trans)
   148 
   149 lemma lessThan_subset_iff [iff]:
   150      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   151 apply (auto simp add: lessThan_def)
   152  apply (subst linorder_not_less [symmetric], blast)
   153 done
   154 
   155 lemma lessThan_eq_iff [iff]:
   156      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   157 apply (rule iffI)
   158  apply (erule equalityE)
   159  apply simp_all
   160 done
   161 
   162 
   163 subsection {*Two-sided intervals*}
   164 
   165 context ord
   166 begin
   167 
   168 lemma greaterThanLessThan_iff [simp,noatp]:
   169   "(i : {l<..<u}) = (l < i & i < u)"
   170 by (simp add: greaterThanLessThan_def)
   171 
   172 lemma atLeastLessThan_iff [simp,noatp]:
   173   "(i : {l..<u}) = (l <= i & i < u)"
   174 by (simp add: atLeastLessThan_def)
   175 
   176 lemma greaterThanAtMost_iff [simp,noatp]:
   177   "(i : {l<..u}) = (l < i & i <= u)"
   178 by (simp add: greaterThanAtMost_def)
   179 
   180 lemma atLeastAtMost_iff [simp,noatp]:
   181   "(i : {l..u}) = (l <= i & i <= u)"
   182 by (simp add: atLeastAtMost_def)
   183 
   184 text {* The above four lemmas could be declared as iffs. Unfortunately this
   185 breaks many proofs. Since it only helps blast, it is better to leave well
   186 alone *}
   187 
   188 end
   189 
   190 subsubsection{* Emptyness, singletons, subset *}
   191 
   192 context order
   193 begin
   194 
   195 lemma atLeastatMost_empty[simp]:
   196   "b < a \<Longrightarrow> {a..b} = {}"
   197 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   198 
   199 lemma atLeastatMost_empty_iff[simp]:
   200   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   201 by auto (blast intro: order_trans)
   202 
   203 lemma atLeastatMost_empty_iff2[simp]:
   204   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   205 by auto (blast intro: order_trans)
   206 
   207 lemma atLeastLessThan_empty[simp]:
   208   "b <= a \<Longrightarrow> {a..<b} = {}"
   209 by(auto simp: atLeastLessThan_def)
   210 
   211 lemma atLeastLessThan_empty_iff[simp]:
   212   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   213 by auto (blast intro: le_less_trans)
   214 
   215 lemma atLeastLessThan_empty_iff2[simp]:
   216   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   217 by auto (blast intro: le_less_trans)
   218 
   219 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   220 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   221 
   222 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   223 by auto (blast intro: less_le_trans)
   224 
   225 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   226 by auto (blast intro: less_le_trans)
   227 
   228 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   229 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   230 
   231 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   232 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   233 
   234 lemma atLeastatMost_subset_iff[simp]:
   235   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   236 unfolding atLeastAtMost_def atLeast_def atMost_def
   237 by (blast intro: order_trans)
   238 
   239 lemma atLeastatMost_psubset_iff:
   240   "{a..b} < {c..d} \<longleftrightarrow>
   241    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   242 by(simp add: psubset_eq expand_set_eq less_le_not_le)(blast intro: order_trans)
   243 
   244 end
   245 
   246 lemma (in linorder) atLeastLessThan_subset_iff:
   247   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   248 apply (auto simp:subset_eq Ball_def)
   249 apply(frule_tac x=a in spec)
   250 apply(erule_tac x=d in allE)
   251 apply (simp add: less_imp_le)
   252 done
   253 
   254 subsubsection {* Intersection *}
   255 
   256 context linorder
   257 begin
   258 
   259 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   260 by auto
   261 
   262 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   263 by auto
   264 
   265 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   266 by auto
   267 
   268 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   269 by auto
   270 
   271 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   272 by auto
   273 
   274 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   275 by auto
   276 
   277 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   278 by auto
   279 
   280 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   281 by auto
   282 
   283 end
   284 
   285 
   286 subsection {* Intervals of natural numbers *}
   287 
   288 subsubsection {* The Constant @{term lessThan} *}
   289 
   290 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   291 by (simp add: lessThan_def)
   292 
   293 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   294 by (simp add: lessThan_def less_Suc_eq, blast)
   295 
   296 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   297 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   298 
   299 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   300 by blast
   301 
   302 subsubsection {* The Constant @{term greaterThan} *}
   303 
   304 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   305 apply (simp add: greaterThan_def)
   306 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   307 done
   308 
   309 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   310 apply (simp add: greaterThan_def)
   311 apply (auto elim: linorder_neqE)
   312 done
   313 
   314 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   315 by blast
   316 
   317 subsubsection {* The Constant @{term atLeast} *}
   318 
   319 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   320 by (unfold atLeast_def UNIV_def, simp)
   321 
   322 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   323 apply (simp add: atLeast_def)
   324 apply (simp add: Suc_le_eq)
   325 apply (simp add: order_le_less, blast)
   326 done
   327 
   328 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   329   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   330 
   331 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   332 by blast
   333 
   334 subsubsection {* The Constant @{term atMost} *}
   335 
   336 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   337 by (simp add: atMost_def)
   338 
   339 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   340 apply (simp add: atMost_def)
   341 apply (simp add: less_Suc_eq order_le_less, blast)
   342 done
   343 
   344 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   345 by blast
   346 
   347 subsubsection {* The Constant @{term atLeastLessThan} *}
   348 
   349 text{*The orientation of the following 2 rules is tricky. The lhs is
   350 defined in terms of the rhs.  Hence the chosen orientation makes sense
   351 in this theory --- the reverse orientation complicates proofs (eg
   352 nontermination). But outside, when the definition of the lhs is rarely
   353 used, the opposite orientation seems preferable because it reduces a
   354 specific concept to a more general one. *}
   355 
   356 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   357 by(simp add:lessThan_def atLeastLessThan_def)
   358 
   359 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   360 by(simp add:atMost_def atLeastAtMost_def)
   361 
   362 declare atLeast0LessThan[symmetric, code_unfold]
   363         atLeast0AtMost[symmetric, code_unfold]
   364 
   365 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   366 by (simp add: atLeastLessThan_def)
   367 
   368 subsubsection {* Intervals of nats with @{term Suc} *}
   369 
   370 text{*Not a simprule because the RHS is too messy.*}
   371 lemma atLeastLessThanSuc:
   372     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   373 by (auto simp add: atLeastLessThan_def)
   374 
   375 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   376 by (auto simp add: atLeastLessThan_def)
   377 (*
   378 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   379 by (induct k, simp_all add: atLeastLessThanSuc)
   380 
   381 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   382 by (auto simp add: atLeastLessThan_def)
   383 *)
   384 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   385   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   386 
   387 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   388   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   389     greaterThanAtMost_def)
   390 
   391 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   392   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   393     greaterThanLessThan_def)
   394 
   395 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   396 by (auto simp add: atLeastAtMost_def)
   397 
   398 subsubsection {* Image *}
   399 
   400 lemma image_add_atLeastAtMost:
   401   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   402 proof
   403   show "?A \<subseteq> ?B" by auto
   404 next
   405   show "?B \<subseteq> ?A"
   406   proof
   407     fix n assume a: "n : ?B"
   408     hence "n - k : {i..j}" by auto
   409     moreover have "n = (n - k) + k" using a by auto
   410     ultimately show "n : ?A" by blast
   411   qed
   412 qed
   413 
   414 lemma image_add_atLeastLessThan:
   415   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   416 proof
   417   show "?A \<subseteq> ?B" by auto
   418 next
   419   show "?B \<subseteq> ?A"
   420   proof
   421     fix n assume a: "n : ?B"
   422     hence "n - k : {i..<j}" by auto
   423     moreover have "n = (n - k) + k" using a by auto
   424     ultimately show "n : ?A" by blast
   425   qed
   426 qed
   427 
   428 corollary image_Suc_atLeastAtMost[simp]:
   429   "Suc ` {i..j} = {Suc i..Suc j}"
   430 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   431 
   432 corollary image_Suc_atLeastLessThan[simp]:
   433   "Suc ` {i..<j} = {Suc i..<Suc j}"
   434 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   435 
   436 lemma image_add_int_atLeastLessThan:
   437     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   438   apply (auto simp add: image_def)
   439   apply (rule_tac x = "x - l" in bexI)
   440   apply auto
   441   done
   442 
   443 
   444 subsubsection {* Finiteness *}
   445 
   446 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   447   by (induct k) (simp_all add: lessThan_Suc)
   448 
   449 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   450   by (induct k) (simp_all add: atMost_Suc)
   451 
   452 lemma finite_greaterThanLessThan [iff]:
   453   fixes l :: nat shows "finite {l<..<u}"
   454 by (simp add: greaterThanLessThan_def)
   455 
   456 lemma finite_atLeastLessThan [iff]:
   457   fixes l :: nat shows "finite {l..<u}"
   458 by (simp add: atLeastLessThan_def)
   459 
   460 lemma finite_greaterThanAtMost [iff]:
   461   fixes l :: nat shows "finite {l<..u}"
   462 by (simp add: greaterThanAtMost_def)
   463 
   464 lemma finite_atLeastAtMost [iff]:
   465   fixes l :: nat shows "finite {l..u}"
   466 by (simp add: atLeastAtMost_def)
   467 
   468 text {* A bounded set of natural numbers is finite. *}
   469 lemma bounded_nat_set_is_finite:
   470   "(ALL i:N. i < (n::nat)) ==> finite N"
   471 apply (rule finite_subset)
   472  apply (rule_tac [2] finite_lessThan, auto)
   473 done
   474 
   475 text {* A set of natural numbers is finite iff it is bounded. *}
   476 lemma finite_nat_set_iff_bounded:
   477   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   478 proof
   479   assume f:?F  show ?B
   480     using Max_ge[OF `?F`, simplified less_Suc_eq_le[symmetric]] by blast
   481 next
   482   assume ?B show ?F using `?B` by(blast intro:bounded_nat_set_is_finite)
   483 qed
   484 
   485 lemma finite_nat_set_iff_bounded_le:
   486   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
   487 apply(simp add:finite_nat_set_iff_bounded)
   488 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
   489 done
   490 
   491 lemma finite_less_ub:
   492      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   493 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   494 
   495 text{* Any subset of an interval of natural numbers the size of the
   496 subset is exactly that interval. *}
   497 
   498 lemma subset_card_intvl_is_intvl:
   499   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   500 proof cases
   501   assume "finite A"
   502   thus "PROP ?P"
   503   proof(induct A rule:finite_linorder_max_induct)
   504     case empty thus ?case by auto
   505   next
   506     case (insert A b)
   507     moreover hence "b ~: A" by auto
   508     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   509       using `b ~: A` insert by fastsimp+
   510     ultimately show ?case by auto
   511   qed
   512 next
   513   assume "~finite A" thus "PROP ?P" by simp
   514 qed
   515 
   516 
   517 subsubsection {* Cardinality *}
   518 
   519 lemma card_lessThan [simp]: "card {..<u} = u"
   520   by (induct u, simp_all add: lessThan_Suc)
   521 
   522 lemma card_atMost [simp]: "card {..u} = Suc u"
   523   by (simp add: lessThan_Suc_atMost [THEN sym])
   524 
   525 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   526   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   527   apply (erule ssubst, rule card_lessThan)
   528   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   529   apply (erule subst)
   530   apply (rule card_image)
   531   apply (simp add: inj_on_def)
   532   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   533   apply (rule_tac x = "x - l" in exI)
   534   apply arith
   535   done
   536 
   537 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   538   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   539 
   540 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   541   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   542 
   543 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   544   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   545 
   546 lemma ex_bij_betw_nat_finite:
   547   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   548 apply(drule finite_imp_nat_seg_image_inj_on)
   549 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   550 done
   551 
   552 lemma ex_bij_betw_finite_nat:
   553   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   554 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   555 
   556 lemma finite_same_card_bij:
   557   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
   558 apply(drule ex_bij_betw_finite_nat)
   559 apply(drule ex_bij_betw_nat_finite)
   560 apply(auto intro!:bij_betw_trans)
   561 done
   562 
   563 lemma ex_bij_betw_nat_finite_1:
   564   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
   565 by (rule finite_same_card_bij) auto
   566 
   567 
   568 subsection {* Intervals of integers *}
   569 
   570 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   571   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   572 
   573 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   574   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   575 
   576 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   577     "{l+1..<u} = {l<..<u::int}"
   578   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   579 
   580 subsubsection {* Finiteness *}
   581 
   582 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   583     {(0::int)..<u} = int ` {..<nat u}"
   584   apply (unfold image_def lessThan_def)
   585   apply auto
   586   apply (rule_tac x = "nat x" in exI)
   587   apply (auto simp add: zless_nat_conj zless_nat_eq_int_zless [THEN sym])
   588   done
   589 
   590 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   591   apply (case_tac "0 \<le> u")
   592   apply (subst image_atLeastZeroLessThan_int, assumption)
   593   apply (rule finite_imageI)
   594   apply auto
   595   done
   596 
   597 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   598   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   599   apply (erule subst)
   600   apply (rule finite_imageI)
   601   apply (rule finite_atLeastZeroLessThan_int)
   602   apply (rule image_add_int_atLeastLessThan)
   603   done
   604 
   605 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   606   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   607 
   608 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   609   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   610 
   611 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   612   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   613 
   614 
   615 subsubsection {* Cardinality *}
   616 
   617 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   618   apply (case_tac "0 \<le> u")
   619   apply (subst image_atLeastZeroLessThan_int, assumption)
   620   apply (subst card_image)
   621   apply (auto simp add: inj_on_def)
   622   done
   623 
   624 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   625   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   626   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   627   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   628   apply (erule subst)
   629   apply (rule card_image)
   630   apply (simp add: inj_on_def)
   631   apply (rule image_add_int_atLeastLessThan)
   632   done
   633 
   634 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   635 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   636 apply (auto simp add: algebra_simps)
   637 done
   638 
   639 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   640 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   641 
   642 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   643 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   644 
   645 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   646 proof -
   647   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   648   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   649 qed
   650 
   651 lemma card_less:
   652 assumes zero_in_M: "0 \<in> M"
   653 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   654 proof -
   655   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   656   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   657 qed
   658 
   659 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   660 apply (rule card_bij_eq [of "Suc" _ _ "\<lambda>x. x - Suc 0"])
   661 apply simp
   662 apply fastsimp
   663 apply auto
   664 apply (rule inj_on_diff_nat)
   665 apply auto
   666 apply (case_tac x)
   667 apply auto
   668 apply (case_tac xa)
   669 apply auto
   670 apply (case_tac xa)
   671 apply auto
   672 done
   673 
   674 lemma card_less_Suc:
   675   assumes zero_in_M: "0 \<in> M"
   676     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   677 proof -
   678   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   679   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   680     by (auto simp only: insert_Diff)
   681   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   682   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   683     apply (subst card_insert)
   684     apply simp_all
   685     apply (subst b)
   686     apply (subst card_less_Suc2[symmetric])
   687     apply simp_all
   688     done
   689   with c show ?thesis by simp
   690 qed
   691 
   692 
   693 subsection {*Lemmas useful with the summation operator setsum*}
   694 
   695 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   696 
   697 subsubsection {* Disjoint Unions *}
   698 
   699 text {* Singletons and open intervals *}
   700 
   701 lemma ivl_disj_un_singleton:
   702   "{l::'a::linorder} Un {l<..} = {l..}"
   703   "{..<u} Un {u::'a::linorder} = {..u}"
   704   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   705   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   706   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   707   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   708 by auto
   709 
   710 text {* One- and two-sided intervals *}
   711 
   712 lemma ivl_disj_un_one:
   713   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   714   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   715   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   716   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   717   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   718   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   719   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   720   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   721 by auto
   722 
   723 text {* Two- and two-sided intervals *}
   724 
   725 lemma ivl_disj_un_two:
   726   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   727   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   728   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   729   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   730   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   731   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   732   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   733   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   734 by auto
   735 
   736 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   737 
   738 subsubsection {* Disjoint Intersections *}
   739 
   740 text {* One- and two-sided intervals *}
   741 
   742 lemma ivl_disj_int_one:
   743   "{..l::'a::order} Int {l<..<u} = {}"
   744   "{..<l} Int {l..<u} = {}"
   745   "{..l} Int {l<..u} = {}"
   746   "{..<l} Int {l..u} = {}"
   747   "{l<..u} Int {u<..} = {}"
   748   "{l<..<u} Int {u..} = {}"
   749   "{l..u} Int {u<..} = {}"
   750   "{l..<u} Int {u..} = {}"
   751   by auto
   752 
   753 text {* Two- and two-sided intervals *}
   754 
   755 lemma ivl_disj_int_two:
   756   "{l::'a::order<..<m} Int {m..<u} = {}"
   757   "{l<..m} Int {m<..<u} = {}"
   758   "{l..<m} Int {m..<u} = {}"
   759   "{l..m} Int {m<..<u} = {}"
   760   "{l<..<m} Int {m..u} = {}"
   761   "{l<..m} Int {m<..u} = {}"
   762   "{l..<m} Int {m..u} = {}"
   763   "{l..m} Int {m<..u} = {}"
   764   by auto
   765 
   766 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
   767 
   768 subsubsection {* Some Differences *}
   769 
   770 lemma ivl_diff[simp]:
   771  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   772 by(auto)
   773 
   774 
   775 subsubsection {* Some Subset Conditions *}
   776 
   777 lemma ivl_subset [simp,noatp]:
   778  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   779 apply(auto simp:linorder_not_le)
   780 apply(rule ccontr)
   781 apply(insert linorder_le_less_linear[of i n])
   782 apply(clarsimp simp:linorder_not_le)
   783 apply(fastsimp)
   784 done
   785 
   786 
   787 subsection {* Summation indexed over intervals *}
   788 
   789 syntax
   790   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   791   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   792   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   793   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   794 syntax (xsymbols)
   795   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   796   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   797   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   798   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   799 syntax (HTML output)
   800   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   801   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   802   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   803   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   804 syntax (latex_sum output)
   805   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   806  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   807   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   808  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   809   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   810  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   811   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   812  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   813 
   814 translations
   815   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
   816   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
   817   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
   818   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
   819 
   820 text{* The above introduces some pretty alternative syntaxes for
   821 summation over intervals:
   822 \begin{center}
   823 \begin{tabular}{lll}
   824 Old & New & \LaTeX\\
   825 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   826 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   827 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   828 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   829 \end{tabular}
   830 \end{center}
   831 The left column shows the term before introduction of the new syntax,
   832 the middle column shows the new (default) syntax, and the right column
   833 shows a special syntax. The latter is only meaningful for latex output
   834 and has to be activated explicitly by setting the print mode to
   835 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   836 antiquotations). It is not the default \LaTeX\ output because it only
   837 works well with italic-style formulae, not tt-style.
   838 
   839 Note that for uniformity on @{typ nat} it is better to use
   840 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   841 not provide all lemmas available for @{term"{m..<n}"} also in the
   842 special form for @{term"{..<n}"}. *}
   843 
   844 text{* This congruence rule should be used for sums over intervals as
   845 the standard theorem @{text[source]setsum_cong} does not work well
   846 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   847 the context. *}
   848 
   849 lemma setsum_ivl_cong:
   850  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   851  setsum f {a..<b} = setsum g {c..<d}"
   852 by(rule setsum_cong, simp_all)
   853 
   854 (* FIXME why are the following simp rules but the corresponding eqns
   855 on intervals are not? *)
   856 
   857 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   858 by (simp add:atMost_Suc add_ac)
   859 
   860 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   861 by (simp add:lessThan_Suc add_ac)
   862 
   863 lemma setsum_cl_ivl_Suc[simp]:
   864   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   865 by (auto simp:add_ac atLeastAtMostSuc_conv)
   866 
   867 lemma setsum_op_ivl_Suc[simp]:
   868   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   869 by (auto simp:add_ac atLeastLessThanSuc)
   870 (*
   871 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   872     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   873 by (auto simp:add_ac atLeastAtMostSuc_conv)
   874 *)
   875 
   876 lemma setsum_head:
   877   fixes n :: nat
   878   assumes mn: "m <= n" 
   879   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   880 proof -
   881   from mn
   882   have "{m..n} = {m} \<union> {m<..n}"
   883     by (auto intro: ivl_disj_un_singleton)
   884   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   885     by (simp add: atLeast0LessThan)
   886   also have "\<dots> = ?rhs" by simp
   887   finally show ?thesis .
   888 qed
   889 
   890 lemma setsum_head_Suc:
   891   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
   892 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
   893 
   894 lemma setsum_head_upt_Suc:
   895   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
   896 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
   897 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
   898 done
   899 
   900 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
   901   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
   902 proof-
   903   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using `m \<le> n+1` by auto
   904   thus ?thesis by (auto simp: ivl_disj_int setsum_Un_disjoint
   905     atLeastSucAtMost_greaterThanAtMost)
   906 qed
   907 
   908 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   909   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   910 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   911 
   912 lemma setsum_diff_nat_ivl:
   913 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   914 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   915   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   916 using setsum_add_nat_ivl [of m n p f,symmetric]
   917 apply (simp add: add_ac)
   918 done
   919 
   920 lemma setsum_natinterval_difff:
   921   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
   922   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
   923           (if m <= n then f m - f(n + 1) else 0)"
   924 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
   925 
   926 lemmas setsum_restrict_set' = setsum_restrict_set[unfolded Int_def]
   927 
   928 lemma setsum_setsum_restrict:
   929   "finite S \<Longrightarrow> finite T \<Longrightarrow> setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y\<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
   930   by (simp add: setsum_restrict_set'[unfolded mem_def] mem_def)
   931      (rule setsum_commute)
   932 
   933 lemma setsum_image_gen: assumes fS: "finite S"
   934   shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
   935 proof-
   936   { fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto }
   937   hence "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S"
   938     by simp
   939   also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
   940     by (rule setsum_setsum_restrict[OF fS finite_imageI[OF fS]])
   941   finally show ?thesis .
   942 qed
   943 
   944 lemma setsum_multicount_gen:
   945   assumes "finite s" "finite t" "\<forall>j\<in>t. (card {i\<in>s. R i j} = k j)"
   946   shows "setsum (\<lambda>i. (card {j\<in>t. R i j})) s = setsum k t" (is "?l = ?r")
   947 proof-
   948   have "?l = setsum (\<lambda>i. setsum (\<lambda>x.1) {j\<in>t. R i j}) s" by auto
   949   also have "\<dots> = ?r" unfolding setsum_setsum_restrict[OF assms(1-2)]
   950     using assms(3) by auto
   951   finally show ?thesis .
   952 qed
   953 
   954 lemma setsum_multicount:
   955   assumes "finite S" "finite T" "\<forall>j\<in>T. (card {i\<in>S. R i j} = k)"
   956   shows "setsum (\<lambda>i. card {j\<in>T. R i j}) S = k * card T" (is "?l = ?r")
   957 proof-
   958   have "?l = setsum (\<lambda>i. k) T" by(rule setsum_multicount_gen)(auto simp:assms)
   959   also have "\<dots> = ?r" by(simp add: setsum_constant mult_commute)
   960   finally show ?thesis by auto
   961 qed
   962 
   963 
   964 subsection{* Shifting bounds *}
   965 
   966 lemma setsum_shift_bounds_nat_ivl:
   967   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
   968 by (induct "n", auto simp:atLeastLessThanSuc)
   969 
   970 lemma setsum_shift_bounds_cl_nat_ivl:
   971   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
   972 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
   973 apply (simp add:image_add_atLeastAtMost o_def)
   974 done
   975 
   976 corollary setsum_shift_bounds_cl_Suc_ivl:
   977   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
   978 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
   979 
   980 corollary setsum_shift_bounds_Suc_ivl:
   981   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
   982 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
   983 
   984 lemma setsum_shift_lb_Suc0_0:
   985   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
   986 by(simp add:setsum_head_Suc)
   987 
   988 lemma setsum_shift_lb_Suc0_0_upt:
   989   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
   990 apply(cases k)apply simp
   991 apply(simp add:setsum_head_upt_Suc)
   992 done
   993 
   994 subsection {* The formula for geometric sums *}
   995 
   996 lemma geometric_sum:
   997   "x ~= 1 ==> (\<Sum>i=0..<n. x ^ i) =
   998   (x ^ n - 1) / (x - 1::'a::{field})"
   999 by (induct "n") (simp_all add:field_simps power_Suc)
  1000 
  1001 subsection {* The formula for arithmetic sums *}
  1002 
  1003 lemma gauss_sum:
  1004   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
  1005    of_nat n*((of_nat n)+1)"
  1006 proof (induct n)
  1007   case 0
  1008   show ?case by simp
  1009 next
  1010   case (Suc n)
  1011   then show ?case by (simp add: algebra_simps)
  1012 qed
  1013 
  1014 theorem arith_series_general:
  1015   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1016   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1017 proof cases
  1018   assume ngt1: "n > 1"
  1019   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1020   have
  1021     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1022      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1023     by (rule setsum_addf)
  1024   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1025   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1026     unfolding One_nat_def
  1027     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt mult_ac)
  1028   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
  1029     by (simp add: left_distrib right_distrib)
  1030   also from ngt1 have "{1..<n} = {1..n - 1}"
  1031     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1032   also from ngt1
  1033   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
  1034     by (simp only: mult_ac gauss_sum [of "n - 1"], unfold One_nat_def)
  1035        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
  1036   finally show ?thesis by (simp add: algebra_simps)
  1037 next
  1038   assume "\<not>(n > 1)"
  1039   hence "n = 1 \<or> n = 0" by auto
  1040   thus ?thesis by (auto simp: algebra_simps)
  1041 qed
  1042 
  1043 lemma arith_series_nat:
  1044   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1045 proof -
  1046   have
  1047     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1048     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1049     by (rule arith_series_general)
  1050   thus ?thesis
  1051     unfolding One_nat_def by (auto simp add: of_nat_id)
  1052 qed
  1053 
  1054 lemma arith_series_int:
  1055   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1056   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1057 proof -
  1058   have
  1059     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1060     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1061     by (rule arith_series_general)
  1062   thus ?thesis by simp
  1063 qed
  1064 
  1065 lemma sum_diff_distrib:
  1066   fixes P::"nat\<Rightarrow>nat"
  1067   shows
  1068   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
  1069   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
  1070 proof (induct n)
  1071   case 0 show ?case by simp
  1072 next
  1073   case (Suc n)
  1074 
  1075   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
  1076   let ?rhs = "\<Sum>x<n. P x - Q x"
  1077 
  1078   from Suc have "?lhs = ?rhs" by simp
  1079   moreover
  1080   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
  1081   moreover
  1082   from Suc have
  1083     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
  1084     by (subst diff_diff_left[symmetric],
  1085         subst diff_add_assoc2)
  1086        (auto simp: diff_add_assoc2 intro: setsum_mono)
  1087   ultimately
  1088   show ?case by simp
  1089 qed
  1090 
  1091 subsection {* Products indexed over intervals *}
  1092 
  1093 syntax
  1094   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1095   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1096   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1097   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1098 syntax (xsymbols)
  1099   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1100   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1101   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1102   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1103 syntax (HTML output)
  1104   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1105   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1106   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1107   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1108 syntax (latex_prod output)
  1109   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1110  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1111   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1112  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1113   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1114  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1115   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1116  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1117 
  1118 translations
  1119   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1120   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1121   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1122   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1123 
  1124 end