src/HOL/Library/Float.thy
author hoelzl
Thu Apr 19 22:13:46 2012 +0200 (2012-04-19)
changeset 47615 341fd902ef1c
parent 47608 572d7e51de4d
child 47621 4cf6011fb884
permissions -rw-r--r--
transfer now handles Let
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Johannes Hölzl, Fabian Immler
     3     Copyright   2012  TU München
     4 *)
     5 
     6 header {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main "~~/src/HOL/Library/Lattice_Algebras"
    10 begin
    11 
    12 typedef float = "{m * 2 powr e | (m :: int) (e :: int). True }"
    13   morphisms real_of_float float_of
    14   by auto
    15 
    16 defs (overloaded)
    17   real_of_float_def[code_unfold]: "real \<equiv> real_of_float"
    18 
    19 lemma type_definition_float': "type_definition real float_of float"
    20   using type_definition_float unfolding real_of_float_def .
    21 
    22 setup_lifting (no_abs_code) type_definition_float'
    23 
    24 lemmas float_of_inject[simp]
    25 
    26 declare [[coercion "real :: float \<Rightarrow> real"]]
    27 
    28 lemma real_of_float_eq:
    29   fixes f1 f2 :: float shows "f1 = f2 \<longleftrightarrow> real f1 = real f2"
    30   unfolding real_of_float_def real_of_float_inject ..
    31 
    32 lemma float_of_real[simp]: "float_of (real x) = x"
    33   unfolding real_of_float_def by (rule real_of_float_inverse)
    34 
    35 lemma real_float[simp]: "x \<in> float \<Longrightarrow> real (float_of x) = x"
    36   unfolding real_of_float_def by (rule float_of_inverse)
    37 
    38 subsection {* Real operations preserving the representation as floating point number *}
    39 
    40 lemma floatI: fixes m e :: int shows "m * 2 powr e = x \<Longrightarrow> x \<in> float"
    41   by (auto simp: float_def)
    42 
    43 lemma zero_float[simp]: "0 \<in> float" by (auto simp: float_def)
    44 lemma one_float[simp]: "1 \<in> float" by (intro floatI[of 1 0]) simp
    45 lemma numeral_float[simp]: "numeral i \<in> float" by (intro floatI[of "numeral i" 0]) simp  
    46 lemma neg_numeral_float[simp]: "neg_numeral i \<in> float" by (intro floatI[of "neg_numeral i" 0]) simp
    47 lemma real_of_int_float[simp]: "real (x :: int) \<in> float" by (intro floatI[of x 0]) simp
    48 lemma real_of_nat_float[simp]: "real (x :: nat) \<in> float" by (intro floatI[of x 0]) simp
    49 lemma two_powr_int_float[simp]: "2 powr (real (i::int)) \<in> float" by (intro floatI[of 1 i]) simp
    50 lemma two_powr_nat_float[simp]: "2 powr (real (i::nat)) \<in> float" by (intro floatI[of 1 i]) simp
    51 lemma two_powr_minus_int_float[simp]: "2 powr - (real (i::int)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    52 lemma two_powr_minus_nat_float[simp]: "2 powr - (real (i::nat)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    53 lemma two_powr_numeral_float[simp]: "2 powr numeral i \<in> float" by (intro floatI[of 1 "numeral i"]) simp
    54 lemma two_powr_neg_numeral_float[simp]: "2 powr neg_numeral i \<in> float" by (intro floatI[of 1 "neg_numeral i"]) simp
    55 lemma two_pow_float[simp]: "2 ^ n \<in> float" by (intro floatI[of 1 "n"]) (simp add: powr_realpow)
    56 lemma real_of_float_float[simp]: "real (f::float) \<in> float" by (cases f) simp
    57 
    58 lemma plus_float[simp]: "r \<in> float \<Longrightarrow> p \<in> float \<Longrightarrow> r + p \<in> float"
    59   unfolding float_def
    60 proof (safe, simp)
    61   fix e1 m1 e2 m2 :: int
    62   { fix e1 m1 e2 m2 :: int assume "e1 \<le> e2"
    63     then have "m1 * 2 powr e1 + m2 * 2 powr e2 = (m1 + m2 * 2 ^ nat (e2 - e1)) * 2 powr e1"
    64       by (simp add: powr_realpow[symmetric] powr_divide2[symmetric] field_simps)
    65     then have "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    66       by blast }
    67   note * = this
    68   show "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    69   proof (cases e1 e2 rule: linorder_le_cases)
    70     assume "e2 \<le> e1" from *[OF this, of m2 m1] show ?thesis by (simp add: ac_simps)
    71   qed (rule *)
    72 qed
    73 
    74 lemma uminus_float[simp]: "x \<in> float \<Longrightarrow> -x \<in> float"
    75   apply (auto simp: float_def)
    76   apply (rule_tac x="-x" in exI)
    77   apply (rule_tac x="xa" in exI)
    78   apply (simp add: field_simps)
    79   done
    80 
    81 lemma times_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x * y \<in> float"
    82   apply (auto simp: float_def)
    83   apply (rule_tac x="x * xa" in exI)
    84   apply (rule_tac x="xb + xc" in exI)
    85   apply (simp add: powr_add)
    86   done
    87 
    88 lemma minus_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x - y \<in> float"
    89   unfolding ab_diff_minus by (intro uminus_float plus_float)
    90 
    91 lemma abs_float[simp]: "x \<in> float \<Longrightarrow> abs x \<in> float"
    92   by (cases x rule: linorder_cases[of 0]) auto
    93 
    94 lemma sgn_of_float[simp]: "x \<in> float \<Longrightarrow> sgn x \<in> float"
    95   by (cases x rule: linorder_cases[of 0]) (auto intro!: uminus_float)
    96 
    97 lemma div_power_2_float[simp]: "x \<in> float \<Longrightarrow> x / 2^d \<in> float"
    98   apply (auto simp add: float_def)
    99   apply (rule_tac x="x" in exI)
   100   apply (rule_tac x="xa - d" in exI)
   101   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   102   done
   103 
   104 lemma div_power_2_int_float[simp]: "x \<in> float \<Longrightarrow> x / (2::int)^d \<in> float"
   105   apply (auto simp add: float_def)
   106   apply (rule_tac x="x" in exI)
   107   apply (rule_tac x="xa - d" in exI)
   108   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   109   done
   110 
   111 lemma div_numeral_Bit0_float[simp]:
   112   assumes x: "x / numeral n \<in> float" shows "x / (numeral (Num.Bit0 n)) \<in> float"
   113 proof -
   114   have "(x / numeral n) / 2^1 \<in> float"
   115     by (intro x div_power_2_float)
   116   also have "(x / numeral n) / 2^1 = x / (numeral (Num.Bit0 n))"
   117     by (induct n) auto
   118   finally show ?thesis .
   119 qed
   120 
   121 lemma div_neg_numeral_Bit0_float[simp]:
   122   assumes x: "x / numeral n \<in> float" shows "x / (neg_numeral (Num.Bit0 n)) \<in> float"
   123 proof -
   124   have "- (x / numeral (Num.Bit0 n)) \<in> float" using x by simp
   125   also have "- (x / numeral (Num.Bit0 n)) = x / neg_numeral (Num.Bit0 n)"
   126     unfolding neg_numeral_def by (simp del: minus_numeral)
   127   finally show ?thesis .
   128 qed
   129 
   130 lift_definition Float :: "int \<Rightarrow> int \<Rightarrow> float" is "\<lambda>(m::int) (e::int). m * 2 powr e" by simp
   131 declare Float.rep_eq[simp]
   132 
   133 code_datatype Float
   134 
   135 subsection {* Arithmetic operations on floating point numbers *}
   136 
   137 instantiation float :: "{ring_1, linorder, linordered_ring, linordered_idom, numeral, equal}"
   138 begin
   139 
   140 lift_definition zero_float :: float is 0 by simp
   141 declare zero_float.rep_eq[simp]
   142 lift_definition one_float :: float is 1 by simp
   143 declare one_float.rep_eq[simp]
   144 lift_definition plus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op +" by simp
   145 declare plus_float.rep_eq[simp]
   146 lift_definition times_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op *" by simp
   147 declare times_float.rep_eq[simp]
   148 lift_definition minus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op -" by simp
   149 declare minus_float.rep_eq[simp]
   150 lift_definition uminus_float :: "float \<Rightarrow> float" is "uminus" by simp
   151 declare uminus_float.rep_eq[simp]
   152 
   153 lift_definition abs_float :: "float \<Rightarrow> float" is abs by simp
   154 declare abs_float.rep_eq[simp]
   155 lift_definition sgn_float :: "float \<Rightarrow> float" is sgn by simp
   156 declare sgn_float.rep_eq[simp]
   157 
   158 lift_definition equal_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op = :: real \<Rightarrow> real \<Rightarrow> bool" ..
   159 
   160 lift_definition less_eq_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op \<le>" ..
   161 declare less_eq_float.rep_eq[simp]
   162 lift_definition less_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op <" ..
   163 declare less_float.rep_eq[simp]
   164 
   165 instance
   166   proof qed (transfer, fastforce simp add: field_simps intro: mult_left_mono mult_right_mono)+
   167 end
   168 
   169 lemma real_of_float_power[simp]: fixes f::float shows "real (f^n) = real f^n"
   170   by (induct n) simp_all
   171 
   172 lemma fixes x y::float 
   173   shows real_of_float_min: "real (min x y) = min (real x) (real y)"
   174     and real_of_float_max: "real (max x y) = max (real x) (real y)"
   175   by (simp_all add: min_def max_def)
   176 
   177 instance float :: dense_linorder
   178 proof
   179   fix a b :: float
   180   show "\<exists>c. a < c"
   181     apply (intro exI[of _ "a + 1"])
   182     apply transfer
   183     apply simp
   184     done
   185   show "\<exists>c. c < a"
   186     apply (intro exI[of _ "a - 1"])
   187     apply transfer
   188     apply simp
   189     done
   190   assume "a < b"
   191   then show "\<exists>c. a < c \<and> c < b"
   192     apply (intro exI[of _ "(a + b) * Float 1 -1"])
   193     apply transfer
   194     apply (simp add: powr_neg_numeral) 
   195     done
   196 qed
   197 
   198 instantiation float :: lattice_ab_group_add
   199 begin
   200 
   201 definition inf_float::"float\<Rightarrow>float\<Rightarrow>float"
   202 where "inf_float a b = min a b"
   203 
   204 definition sup_float::"float\<Rightarrow>float\<Rightarrow>float"
   205 where "sup_float a b = max a b"
   206 
   207 instance
   208   by default
   209      (transfer, simp_all add: inf_float_def sup_float_def real_of_float_min real_of_float_max)+
   210 end
   211 
   212 lemma float_numeral[simp]: "real (numeral x :: float) = numeral x"
   213   apply (induct x)
   214   apply simp
   215   apply (simp_all only: numeral_Bit0 numeral_Bit1 real_of_float_eq real_float
   216                   plus_float.rep_eq one_float.rep_eq plus_float numeral_float one_float)
   217   done
   218 
   219 lemma transfer_numeral [transfer_rule]: 
   220   "fun_rel (op =) cr_float (numeral :: _ \<Rightarrow> real) (numeral :: _ \<Rightarrow> float)"
   221   unfolding fun_rel_def cr_float_def by (simp add: real_of_float_def[symmetric])
   222 
   223 lemma float_neg_numeral[simp]: "real (neg_numeral x :: float) = neg_numeral x"
   224   by (simp add: minus_numeral[symmetric] del: minus_numeral)
   225 
   226 lemma transfer_neg_numeral [transfer_rule]: 
   227   "fun_rel (op =) cr_float (neg_numeral :: _ \<Rightarrow> real) (neg_numeral :: _ \<Rightarrow> float)"
   228   unfolding fun_rel_def cr_float_def by (simp add: real_of_float_def[symmetric])
   229 
   230 lemma
   231   shows float_of_numeral[simp]: "numeral k = float_of (numeral k)"
   232     and float_of_neg_numeral[simp]: "neg_numeral k = float_of (neg_numeral k)"
   233   unfolding real_of_float_eq by simp_all
   234 
   235 subsection {* Represent floats as unique mantissa and exponent *}
   236 
   237 lemma int_induct_abs[case_names less]:
   238   fixes j :: int
   239   assumes H: "\<And>n. (\<And>i. \<bar>i\<bar> < \<bar>n\<bar> \<Longrightarrow> P i) \<Longrightarrow> P n"
   240   shows "P j"
   241 proof (induct "nat \<bar>j\<bar>" arbitrary: j rule: less_induct)
   242   case less show ?case by (rule H[OF less]) simp
   243 qed
   244 
   245 lemma int_cancel_factors:
   246   fixes n :: int assumes "1 < r" shows "n = 0 \<or> (\<exists>k i. n = k * r ^ i \<and> \<not> r dvd k)"
   247 proof (induct n rule: int_induct_abs)
   248   case (less n)
   249   { fix m assume n: "n \<noteq> 0" "n = m * r"
   250     then have "\<bar>m \<bar> < \<bar>n\<bar>"
   251       by (metis abs_dvd_iff abs_ge_self assms comm_semiring_1_class.normalizing_semiring_rules(7)
   252                 dvd_imp_le_int dvd_refl dvd_triv_right linorder_neq_iff linorder_not_le
   253                 mult_eq_0_iff zdvd_mult_cancel1)
   254     from less[OF this] n have "\<exists>k i. n = k * r ^ Suc i \<and> \<not> r dvd k" by auto }
   255   then show ?case
   256     by (metis comm_semiring_1_class.normalizing_semiring_rules(12,7) dvdE power_0)
   257 qed
   258 
   259 lemma mult_powr_eq_mult_powr_iff_asym:
   260   fixes m1 m2 e1 e2 :: int
   261   assumes m1: "\<not> 2 dvd m1" and "e1 \<le> e2"
   262   shows "m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   263 proof
   264   have "m1 \<noteq> 0" using m1 unfolding dvd_def by auto
   265   assume eq: "m1 * 2 powr e1 = m2 * 2 powr e2"
   266   with `e1 \<le> e2` have "m1 = m2 * 2 powr nat (e2 - e1)"
   267     by (simp add: powr_divide2[symmetric] field_simps)
   268   also have "\<dots> = m2 * 2^nat (e2 - e1)"
   269     by (simp add: powr_realpow)
   270   finally have m1_eq: "m1 = m2 * 2^nat (e2 - e1)"
   271     unfolding real_of_int_inject .
   272   with m1 have "m1 = m2"
   273     by (cases "nat (e2 - e1)") (auto simp add: dvd_def)
   274   then show "m1 = m2 \<and> e1 = e2"
   275     using eq `m1 \<noteq> 0` by (simp add: powr_inj)
   276 qed simp
   277 
   278 lemma mult_powr_eq_mult_powr_iff:
   279   fixes m1 m2 e1 e2 :: int
   280   shows "\<not> 2 dvd m1 \<Longrightarrow> \<not> 2 dvd m2 \<Longrightarrow> m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   281   using mult_powr_eq_mult_powr_iff_asym[of m1 e1 e2 m2]
   282   using mult_powr_eq_mult_powr_iff_asym[of m2 e2 e1 m1]
   283   by (cases e1 e2 rule: linorder_le_cases) auto
   284 
   285 lemma floatE_normed:
   286   assumes x: "x \<in> float"
   287   obtains (zero) "x = 0"
   288    | (powr) m e :: int where "x = m * 2 powr e" "\<not> 2 dvd m" "x \<noteq> 0"
   289 proof atomize_elim
   290   { assume "x \<noteq> 0"
   291     from x obtain m e :: int where x: "x = m * 2 powr e" by (auto simp: float_def)
   292     with `x \<noteq> 0` int_cancel_factors[of 2 m] obtain k i where "m = k * 2 ^ i" "\<not> 2 dvd k"
   293       by auto
   294     with `\<not> 2 dvd k` x have "\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m"
   295       by (rule_tac exI[of _ "k"], rule_tac exI[of _ "e + int i"])
   296          (simp add: powr_add powr_realpow) }
   297   then show "x = 0 \<or> (\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m \<and> x \<noteq> 0)"
   298     by blast
   299 qed
   300 
   301 lemma float_normed_cases:
   302   fixes f :: float
   303   obtains (zero) "f = 0"
   304    | (powr) m e :: int where "real f = m * 2 powr e" "\<not> 2 dvd m" "f \<noteq> 0"
   305 proof (atomize_elim, induct f)
   306   case (float_of y) then show ?case
   307     by (cases rule: floatE_normed) (auto simp: zero_float_def)
   308 qed
   309 
   310 definition mantissa :: "float \<Rightarrow> int" where
   311   "mantissa f = fst (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   312    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   313 
   314 definition exponent :: "float \<Rightarrow> int" where
   315   "exponent f = snd (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   316    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   317 
   318 lemma 
   319   shows exponent_0[simp]: "exponent (float_of 0) = 0" (is ?E)
   320     and mantissa_0[simp]: "mantissa (float_of 0) = 0" (is ?M)
   321 proof -
   322   have "\<And>p::int \<times> int. fst p = 0 \<and> snd p = 0 \<longleftrightarrow> p = (0, 0)" by auto
   323   then show ?E ?M
   324     by (auto simp add: mantissa_def exponent_def zero_float_def)
   325 qed
   326 
   327 lemma
   328   shows mantissa_exponent: "real f = mantissa f * 2 powr exponent f" (is ?E)
   329     and mantissa_not_dvd: "f \<noteq> (float_of 0) \<Longrightarrow> \<not> 2 dvd mantissa f" (is "_ \<Longrightarrow> ?D")
   330 proof cases
   331   assume [simp]: "f \<noteq> (float_of 0)"
   332   have "f = mantissa f * 2 powr exponent f \<and> \<not> 2 dvd mantissa f"
   333   proof (cases f rule: float_normed_cases)
   334     case (powr m e)
   335     then have "\<exists>p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   336      \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p)"
   337       by auto
   338     then show ?thesis
   339       unfolding exponent_def mantissa_def
   340       by (rule someI2_ex) (simp add: zero_float_def)
   341   qed (simp add: zero_float_def)
   342   then show ?E ?D by auto
   343 qed simp
   344 
   345 lemma mantissa_noteq_0: "f \<noteq> float_of 0 \<Longrightarrow> mantissa f \<noteq> 0"
   346   using mantissa_not_dvd[of f] by auto
   347 
   348 lemma 
   349   fixes m e :: int
   350   defines "f \<equiv> float_of (m * 2 powr e)"
   351   assumes dvd: "\<not> 2 dvd m"
   352   shows mantissa_float: "mantissa f = m" (is "?M")
   353     and exponent_float: "m \<noteq> 0 \<Longrightarrow> exponent f = e" (is "_ \<Longrightarrow> ?E")
   354 proof cases
   355   assume "m = 0" with dvd show "mantissa f = m" by auto
   356 next
   357   assume "m \<noteq> 0"
   358   then have f_not_0: "f \<noteq> float_of 0" by (simp add: f_def)
   359   from mantissa_exponent[of f]
   360   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   361     by (auto simp add: f_def)
   362   then show "?M" "?E"
   363     using mantissa_not_dvd[OF f_not_0] dvd
   364     by (auto simp: mult_powr_eq_mult_powr_iff)
   365 qed
   366 
   367 subsection {* Compute arithmetic operations *}
   368 
   369 lemma real_of_float_Float[code]: "real_of_float (Float m e) =
   370   (if e \<ge> 0 then m * 2 ^ nat e else m * inverse (2 ^ nat (- e)))"
   371 by (auto simp add: powr_realpow[symmetric] powr_minus real_of_float_def[symmetric])
   372 
   373 lemma Float_mantissa_exponent: "Float (mantissa f) (exponent f) = f"
   374   unfolding real_of_float_eq mantissa_exponent[of f] by simp
   375 
   376 lemma Float_cases[case_names Float, cases type: float]:
   377   fixes f :: float
   378   obtains (Float) m e :: int where "f = Float m e"
   379   using Float_mantissa_exponent[symmetric]
   380   by (atomize_elim) auto
   381 
   382 lemma denormalize_shift:
   383   assumes f_def: "f \<equiv> Float m e" and not_0: "f \<noteq> float_of 0"
   384   obtains i where "m = mantissa f * 2 ^ i" "e = exponent f - i"
   385 proof
   386   from mantissa_exponent[of f] f_def
   387   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   388     by simp
   389   then have eq: "m = mantissa f * 2 powr (exponent f - e)"
   390     by (simp add: powr_divide2[symmetric] field_simps)
   391   moreover
   392   have "e \<le> exponent f"
   393   proof (rule ccontr)
   394     assume "\<not> e \<le> exponent f"
   395     then have pos: "exponent f < e" by simp
   396     then have "2 powr (exponent f - e) = 2 powr - real (e - exponent f)"
   397       by simp
   398     also have "\<dots> = 1 / 2^nat (e - exponent f)"
   399       using pos by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
   400     finally have "m * 2^nat (e - exponent f) = real (mantissa f)"
   401       using eq by simp
   402     then have "mantissa f = m * 2^nat (e - exponent f)"
   403       unfolding real_of_int_inject by simp
   404     with `exponent f < e` have "2 dvd mantissa f"
   405       apply (intro dvdI[where k="m * 2^(nat (e-exponent f)) div 2"])
   406       apply (cases "nat (e - exponent f)")
   407       apply auto
   408       done
   409     then show False using mantissa_not_dvd[OF not_0] by simp
   410   qed
   411   ultimately have "real m = mantissa f * 2^nat (exponent f - e)"
   412     by (simp add: powr_realpow[symmetric])
   413   with `e \<le> exponent f`
   414   show "m = mantissa f * 2 ^ nat (exponent f - e)" "e = exponent f - nat (exponent f - e)"
   415     unfolding real_of_int_inject by auto
   416 qed
   417 
   418 lemma compute_zero[code_unfold, code]: "0 = Float 0 0"
   419   by transfer simp
   420 
   421 lemma compute_one[code_unfold, code]: "1 = Float 1 0"
   422   by transfer simp
   423 
   424 definition normfloat :: "float \<Rightarrow> float" where
   425   [simp]: "normfloat x = x"
   426 
   427 lemma compute_normfloat[code]: "normfloat (Float m e) =
   428   (if m mod 2 = 0 \<and> m \<noteq> 0 then normfloat (Float (m div 2) (e + 1))
   429                            else if m = 0 then 0 else Float m e)"
   430   unfolding normfloat_def
   431   by transfer (auto simp add: powr_add zmod_eq_0_iff)
   432 
   433 lemma compute_float_numeral[code_abbrev]: "Float (numeral k) 0 = numeral k"
   434   by transfer simp
   435 
   436 lemma compute_float_neg_numeral[code_abbrev]: "Float (neg_numeral k) 0 = neg_numeral k"
   437   by transfer simp
   438 
   439 lemma compute_float_uminus[code]: "- Float m1 e1 = Float (- m1) e1"
   440   by transfer simp
   441 
   442 lemma compute_float_times[code]: "Float m1 e1 * Float m2 e2 = Float (m1 * m2) (e1 + e2)"
   443   by transfer (simp add: field_simps powr_add)
   444 
   445 lemma compute_float_plus[code]: "Float m1 e1 + Float m2 e2 =
   446   (if e1 \<le> e2 then Float (m1 + m2 * 2^nat (e2 - e1)) e1
   447               else Float (m2 + m1 * 2^nat (e1 - e2)) e2)"
   448   by transfer (simp add: field_simps powr_realpow[symmetric] powr_divide2[symmetric])
   449 
   450 lemma compute_float_minus[code]: fixes f g::float shows "f - g = f + (-g)"
   451   by simp
   452 
   453 lemma compute_float_sgn[code]: "sgn (Float m1 e1) = (if 0 < m1 then 1 else if m1 < 0 then -1 else 0)"
   454   by transfer (simp add: sgn_times)
   455 
   456 lift_definition is_float_pos :: "float \<Rightarrow> bool" is "op < 0 :: real \<Rightarrow> bool" ..
   457 
   458 lemma compute_is_float_pos[code]: "is_float_pos (Float m e) \<longleftrightarrow> 0 < m"
   459   by transfer (auto simp add: zero_less_mult_iff not_le[symmetric, of _ 0])
   460 
   461 lemma compute_float_less[code]: "a < b \<longleftrightarrow> is_float_pos (b - a)"
   462   by transfer (simp add: field_simps)
   463 
   464 lift_definition is_float_nonneg :: "float \<Rightarrow> bool" is "op \<le> 0 :: real \<Rightarrow> bool" ..
   465 
   466 lemma compute_is_float_nonneg[code]: "is_float_nonneg (Float m e) \<longleftrightarrow> 0 \<le> m"
   467   by transfer (auto simp add: zero_le_mult_iff not_less[symmetric, of _ 0])
   468 
   469 lemma compute_float_le[code]: "a \<le> b \<longleftrightarrow> is_float_nonneg (b - a)"
   470   by transfer (simp add: field_simps)
   471 
   472 lift_definition is_float_zero :: "float \<Rightarrow> bool"  is "op = 0 :: real \<Rightarrow> bool" by simp
   473 
   474 lemma compute_is_float_zero[code]: "is_float_zero (Float m e) \<longleftrightarrow> 0 = m"
   475   by transfer (auto simp add: is_float_zero_def)
   476 
   477 lemma compute_float_abs[code]: "abs (Float m e) = Float (abs m) e"
   478   by transfer (simp add: abs_mult)
   479 
   480 lemma compute_float_eq[code]: "equal_class.equal f g = is_float_zero (f - g)"
   481   by transfer simp
   482 
   483 subsection {* Rounding Real numbers *}
   484 
   485 definition round_down :: "int \<Rightarrow> real \<Rightarrow> real" where
   486   "round_down prec x = floor (x * 2 powr prec) * 2 powr -prec"
   487 
   488 definition round_up :: "int \<Rightarrow> real \<Rightarrow> real" where
   489   "round_up prec x = ceiling (x * 2 powr prec) * 2 powr -prec"
   490 
   491 lemma round_down_float[simp]: "round_down prec x \<in> float"
   492   unfolding round_down_def
   493   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   494 
   495 lemma round_up_float[simp]: "round_up prec x \<in> float"
   496   unfolding round_up_def
   497   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   498 
   499 lemma round_up: "x \<le> round_up prec x"
   500   by (simp add: powr_minus_divide le_divide_eq round_up_def)
   501 
   502 lemma round_down: "round_down prec x \<le> x"
   503   by (simp add: powr_minus_divide divide_le_eq round_down_def)
   504 
   505 lemma round_up_0[simp]: "round_up p 0 = 0"
   506   unfolding round_up_def by simp
   507 
   508 lemma round_down_0[simp]: "round_down p 0 = 0"
   509   unfolding round_down_def by simp
   510 
   511 lemma round_up_diff_round_down:
   512   "round_up prec x - round_down prec x \<le> 2 powr -prec"
   513 proof -
   514   have "round_up prec x - round_down prec x =
   515     (ceiling (x * 2 powr prec) - floor (x * 2 powr prec)) * 2 powr -prec"
   516     by (simp add: round_up_def round_down_def field_simps)
   517   also have "\<dots> \<le> 1 * 2 powr -prec"
   518     by (rule mult_mono)
   519        (auto simp del: real_of_int_diff
   520              simp: real_of_int_diff[symmetric] real_of_int_le_one_cancel_iff ceiling_diff_floor_le_1)
   521   finally show ?thesis by simp
   522 qed
   523 
   524 lemma round_down_shift: "round_down p (x * 2 powr k) = 2 powr k * round_down (p + k) x"
   525   unfolding round_down_def
   526   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   527     (simp add: powr_add[symmetric])
   528 
   529 lemma round_up_shift: "round_up p (x * 2 powr k) = 2 powr k * round_up (p + k) x"
   530   unfolding round_up_def
   531   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   532     (simp add: powr_add[symmetric])
   533 
   534 subsection {* Rounding Floats *}
   535 
   536 lift_definition float_up :: "int \<Rightarrow> float \<Rightarrow> float" is round_up by simp
   537 declare float_up.rep_eq[simp]
   538 
   539 lemma float_up_correct:
   540   shows "real (float_up e f) - real f \<in> {0..2 powr -e}"
   541 unfolding atLeastAtMost_iff
   542 proof
   543   have "round_up e f - f \<le> round_up e f - round_down e f" using round_down by simp
   544   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   545   finally show "real (float_up e f) - real f \<le> 2 powr real (- e)"
   546     by simp
   547 qed (simp add: algebra_simps round_up)
   548 
   549 lift_definition float_down :: "int \<Rightarrow> float \<Rightarrow> float" is round_down by simp
   550 declare float_down.rep_eq[simp]
   551 
   552 lemma float_down_correct:
   553   shows "real f - real (float_down e f) \<in> {0..2 powr -e}"
   554 unfolding atLeastAtMost_iff
   555 proof
   556   have "f - round_down e f \<le> round_up e f - round_down e f" using round_up by simp
   557   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   558   finally show "real f - real (float_down e f) \<le> 2 powr real (- e)"
   559     by simp
   560 qed (simp add: algebra_simps round_down)
   561 
   562 lemma compute_float_down[code]:
   563   "float_down p (Float m e) =
   564     (if p + e < 0 then Float (m div 2^nat (-(p + e))) (-p) else Float m e)"
   565 proof cases
   566   assume "p + e < 0"
   567   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   568     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   569   also have "... = 1 / 2 powr p / 2 powr e"
   570     unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   571   finally show ?thesis
   572     using `p + e < 0`
   573     by transfer (simp add: ac_simps round_down_def floor_divide_eq_div[symmetric])
   574 next
   575   assume "\<not> p + e < 0"
   576   then have r: "real e + real p = real (nat (e + p))" by simp
   577   have r: "\<lfloor>(m * 2 powr e) * 2 powr real p\<rfloor> = (m * 2 powr e) * 2 powr real p"
   578     by (auto intro: exI[where x="m*2^nat (e+p)"]
   579              simp add: ac_simps powr_add[symmetric] r powr_realpow)
   580   with `\<not> p + e < 0` show ?thesis
   581     by transfer
   582        (auto simp add: round_down_def field_simps powr_add powr_minus inverse_eq_divide)
   583 qed
   584 
   585 lemma ceil_divide_floor_conv:
   586 assumes "b \<noteq> 0"
   587 shows "\<lceil>real a / real b\<rceil> = (if b dvd a then a div b else \<lfloor>real a / real b\<rfloor> + 1)"
   588 proof cases
   589   assume "\<not> b dvd a"
   590   hence "a mod b \<noteq> 0" by auto
   591   hence ne: "real (a mod b) / real b \<noteq> 0" using `b \<noteq> 0` by auto
   592   have "\<lceil>real a / real b\<rceil> = \<lfloor>real a / real b\<rfloor> + 1"
   593   apply (rule ceiling_eq) apply (auto simp: floor_divide_eq_div[symmetric])
   594   proof -
   595     have "real \<lfloor>real a / real b\<rfloor> \<le> real a / real b" by simp
   596     moreover have "real \<lfloor>real a / real b\<rfloor> \<noteq> real a / real b"
   597     apply (subst (2) real_of_int_div_aux) unfolding floor_divide_eq_div using ne `b \<noteq> 0` by auto
   598     ultimately show "real \<lfloor>real a / real b\<rfloor> < real a / real b" by arith
   599   qed
   600   thus ?thesis using `\<not> b dvd a` by simp
   601 qed (simp add: ceiling_def real_of_int_minus[symmetric] divide_minus_left[symmetric]
   602   floor_divide_eq_div dvd_neg_div del: divide_minus_left real_of_int_minus)
   603 
   604 lemma compute_float_up[code]:
   605   "float_up p (Float m e) =
   606     (let P = 2^nat (-(p + e)); r = m mod P in
   607       if p + e < 0 then Float (m div P + (if r = 0 then 0 else 1)) (-p) else Float m e)"
   608 proof cases
   609   assume "p + e < 0"
   610   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   611     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   612   also have "... = 1 / 2 powr p / 2 powr e"
   613   unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   614   finally have twopow_rewrite:
   615     "real ((2::int) ^ nat (- (p + e))) = 1 / 2 powr real p / 2 powr real e" .
   616   with `p + e < 0` have powr_rewrite:
   617     "2 powr real e * 2 powr real p = 1 / real ((2::int) ^ nat (- (p + e)))"
   618     unfolding powr_divide2 by simp
   619   show ?thesis
   620   proof cases
   621     assume "2^nat (-(p + e)) dvd m"
   622     with `p + e < 0` twopow_rewrite show ?thesis
   623       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div dvd_eq_mod_eq_0)
   624   next
   625     assume ndvd: "\<not> 2 ^ nat (- (p + e)) dvd m"
   626     have one_div: "real m * (1 / real ((2::int) ^ nat (- (p + e)))) =
   627       real m / real ((2::int) ^ nat (- (p + e)))"
   628       by (simp add: field_simps)
   629     have "real \<lceil>real m * (2 powr real e * 2 powr real p)\<rceil> =
   630       real \<lfloor>real m * (2 powr real e * 2 powr real p)\<rfloor> + 1"
   631       using ndvd unfolding powr_rewrite one_div
   632       by (subst ceil_divide_floor_conv) (auto simp: field_simps)
   633     thus ?thesis using `p + e < 0` twopow_rewrite
   634       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div[symmetric])
   635   qed
   636 next
   637   assume "\<not> p + e < 0"
   638   then have r1: "real e + real p = real (nat (e + p))" by simp
   639   have r: "\<lceil>(m * 2 powr e) * 2 powr real p\<rceil> = (m * 2 powr e) * 2 powr real p"
   640     by (auto simp add: ac_simps powr_add[symmetric] r1 powr_realpow
   641       intro: exI[where x="m*2^nat (e+p)"])
   642   then show ?thesis using `\<not> p + e < 0`
   643     by transfer
   644        (simp add: round_up_def floor_divide_eq_div field_simps powr_add powr_minus inverse_eq_divide)
   645 qed
   646 
   647 lemmas real_of_ints =
   648   real_of_int_zero
   649   real_of_one
   650   real_of_int_add
   651   real_of_int_minus
   652   real_of_int_diff
   653   real_of_int_mult
   654   real_of_int_power
   655   real_numeral
   656 lemmas real_of_nats =
   657   real_of_nat_zero
   658   real_of_nat_one
   659   real_of_nat_1
   660   real_of_nat_add
   661   real_of_nat_mult
   662   real_of_nat_power
   663 
   664 lemmas int_of_reals = real_of_ints[symmetric]
   665 lemmas nat_of_reals = real_of_nats[symmetric]
   666 
   667 lemma two_real_int: "(2::real) = real (2::int)" by simp
   668 lemma two_real_nat: "(2::real) = real (2::nat)" by simp
   669 
   670 lemma mult_cong: "a = c ==> b = d ==> a*b = c*d" by simp
   671 
   672 subsection {* Compute bitlen of integers *}
   673 
   674 definition bitlen :: "int \<Rightarrow> int" where
   675   "bitlen a = (if a > 0 then \<lfloor>log 2 a\<rfloor> + 1 else 0)"
   676 
   677 lemma bitlen_nonneg: "0 \<le> bitlen x"
   678 proof -
   679   {
   680     assume "0 > x"
   681     have "-1 = log 2 (inverse 2)" by (subst log_inverse) simp_all
   682     also have "... < log 2 (-x)" using `0 > x` by auto
   683     finally have "-1 < log 2 (-x)" .
   684   } thus "0 \<le> bitlen x" unfolding bitlen_def by (auto intro!: add_nonneg_nonneg)
   685 qed
   686 
   687 lemma bitlen_bounds:
   688   assumes "x > 0"
   689   shows "2 ^ nat (bitlen x - 1) \<le> x \<and> x < 2 ^ nat (bitlen x)"
   690 proof
   691   have "(2::real) ^ nat \<lfloor>log 2 (real x)\<rfloor> = 2 powr real (floor (log 2 (real x)))"
   692     using powr_realpow[symmetric, of 2 "nat \<lfloor>log 2 (real x)\<rfloor>"] `x > 0`
   693     using real_nat_eq_real[of "floor (log 2 (real x))"]
   694     by simp
   695   also have "... \<le> 2 powr log 2 (real x)"
   696     by simp
   697   also have "... = real x"
   698     using `0 < x` by simp
   699   finally have "2 ^ nat \<lfloor>log 2 (real x)\<rfloor> \<le> real x" by simp
   700   thus "2 ^ nat (bitlen x - 1) \<le> x" using `x > 0`
   701     by (simp add: bitlen_def)
   702 next
   703   have "x \<le> 2 powr (log 2 x)" using `x > 0` by simp
   704   also have "... < 2 ^ nat (\<lfloor>log 2 (real x)\<rfloor> + 1)"
   705     apply (simp add: powr_realpow[symmetric])
   706     using `x > 0` by simp
   707   finally show "x < 2 ^ nat (bitlen x)" using `x > 0`
   708     by (simp add: bitlen_def ac_simps int_of_reals del: real_of_ints)
   709 qed
   710 
   711 lemma bitlen_pow2[simp]:
   712   assumes "b > 0"
   713   shows "bitlen (b * 2 ^ c) = bitlen b + c"
   714 proof -
   715   from assms have "b * 2 ^ c > 0" by (auto intro: mult_pos_pos)
   716   thus ?thesis
   717     using floor_add[of "log 2 b" c] assms
   718     by (auto simp add: log_mult log_nat_power bitlen_def)
   719 qed
   720 
   721 lemma bitlen_Float:
   722 fixes m e
   723 defines "f \<equiv> Float m e"
   724 shows "bitlen (\<bar>mantissa f\<bar>) + exponent f = (if m = 0 then 0 else bitlen \<bar>m\<bar> + e)"
   725 proof cases
   726   assume "m \<noteq> 0"
   727   hence "f \<noteq> float_of 0"
   728     unfolding real_of_float_eq by (simp add: f_def)
   729   hence "mantissa f \<noteq> 0"
   730     by (simp add: mantissa_noteq_0)
   731   moreover
   732   from f_def[THEN denormalize_shift, OF `f \<noteq> float_of 0`] guess i .
   733   ultimately show ?thesis by (simp add: abs_mult)
   734 qed (simp add: f_def bitlen_def Float_def)
   735 
   736 lemma compute_bitlen[code]:
   737   shows "bitlen x = (if x > 0 then bitlen (x div 2) + 1 else 0)"
   738 proof -
   739   { assume "2 \<le> x"
   740     then have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 (x - x mod 2)\<rfloor>"
   741       by (simp add: log_mult zmod_zdiv_equality')
   742     also have "\<dots> = \<lfloor>log 2 (real x)\<rfloor>"
   743     proof cases
   744       assume "x mod 2 = 0" then show ?thesis by simp
   745     next
   746       def n \<equiv> "\<lfloor>log 2 (real x)\<rfloor>"
   747       then have "0 \<le> n"
   748         using `2 \<le> x` by simp
   749       assume "x mod 2 \<noteq> 0"
   750       with `2 \<le> x` have "x mod 2 = 1" "\<not> 2 dvd x" by (auto simp add: dvd_eq_mod_eq_0)
   751       with `2 \<le> x` have "x \<noteq> 2^nat n" by (cases "nat n") auto
   752       moreover
   753       { have "real (2^nat n :: int) = 2 powr (nat n)"
   754           by (simp add: powr_realpow)
   755         also have "\<dots> \<le> 2 powr (log 2 x)"
   756           using `2 \<le> x` by (simp add: n_def del: powr_log_cancel)
   757         finally have "2^nat n \<le> x" using `2 \<le> x` by simp }
   758       ultimately have "2^nat n \<le> x - 1" by simp
   759       then have "2^nat n \<le> real (x - 1)"
   760         unfolding real_of_int_le_iff[symmetric] by simp
   761       { have "n = \<lfloor>log 2 (2^nat n)\<rfloor>"
   762           using `0 \<le> n` by (simp add: log_nat_power)
   763         also have "\<dots> \<le> \<lfloor>log 2 (x - 1)\<rfloor>"
   764           using `2^nat n \<le> real (x - 1)` `0 \<le> n` `2 \<le> x` by (auto intro: floor_mono)
   765         finally have "n \<le> \<lfloor>log 2 (x - 1)\<rfloor>" . }
   766       moreover have "\<lfloor>log 2 (x - 1)\<rfloor> \<le> n"
   767         using `2 \<le> x` by (auto simp add: n_def intro!: floor_mono)
   768       ultimately show "\<lfloor>log 2 (x - x mod 2)\<rfloor> = \<lfloor>log 2 x\<rfloor>"
   769         unfolding n_def `x mod 2 = 1` by auto
   770     qed
   771     finally have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 x\<rfloor>" . }
   772   moreover
   773   { assume "x < 2" "0 < x"
   774     then have "x = 1" by simp
   775     then have "\<lfloor>log 2 (real x)\<rfloor> = 0" by simp }
   776   ultimately show ?thesis
   777     unfolding bitlen_def
   778     by (auto simp: pos_imp_zdiv_pos_iff not_le)
   779 qed
   780 
   781 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   782   shows "0 \<le> e + (bitlen m - 1)"
   783 proof -
   784   have "0 < Float m e" using assms by auto
   785   hence "0 < m" using powr_gt_zero[of 2 e]
   786     by (auto simp: zero_less_mult_iff)
   787   hence "m \<noteq> 0" by auto
   788   show ?thesis
   789   proof (cases "0 \<le> e")
   790     case True thus ?thesis using `0 < m`  by (simp add: bitlen_def)
   791   next
   792     have "(1::int) < 2" by simp
   793     case False let ?S = "2^(nat (-e))"
   794     have "inverse (2 ^ nat (- e)) = 2 powr e" using assms False powr_realpow[of 2 "nat (-e)"]
   795       by (auto simp: powr_minus field_simps inverse_eq_divide)
   796     hence "1 \<le> real m * inverse ?S" using assms False powr_realpow[of 2 "nat (-e)"]
   797       by (auto simp: powr_minus)
   798     hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   799     hence "?S \<le> real m" unfolding mult_assoc by auto
   800     hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   801     from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   802     have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric] by (rule order_le_less_trans)
   803     hence "-e < bitlen m" using False by auto
   804     thus ?thesis by auto
   805   qed
   806 qed
   807 
   808 lemma bitlen_div: assumes "0 < m" shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   809 proof -
   810   let ?B = "2^nat(bitlen m - 1)"
   811 
   812   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   813   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   814   thus "1 \<le> real m / ?B" by auto
   815 
   816   have "m \<noteq> 0" using assms by auto
   817   have "0 \<le> bitlen m - 1" using `0 < m` by (auto simp: bitlen_def)
   818 
   819   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   820   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using `0 < m` by (auto simp: bitlen_def)
   821   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   822   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   823   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   824   thus "real m / ?B < 2" by auto
   825 qed
   826 
   827 subsection {* Approximation of positive rationals *}
   828 
   829 lemma zdiv_zmult_twopow_eq: fixes a b::int shows "a div b div (2 ^ n) = a div (b * 2 ^ n)"
   830 by (simp add: zdiv_zmult2_eq)
   831 
   832 lemma div_mult_twopow_eq: fixes a b::nat shows "a div ((2::nat) ^ n) div b = a div (b * 2 ^ n)"
   833   by (cases "b=0") (simp_all add: div_mult2_eq[symmetric] ac_simps)
   834 
   835 lemma real_div_nat_eq_floor_of_divide:
   836   fixes a b::nat
   837   shows "a div b = real (floor (a/b))"
   838 by (metis floor_divide_eq_div real_of_int_of_nat_eq zdiv_int)
   839 
   840 definition "rat_precision prec x y = int prec - (bitlen x - bitlen y)"
   841 
   842 lift_definition lapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   843   is "\<lambda>prec (x::nat) (y::nat). round_down (rat_precision prec x y) (x / y)" by simp
   844 
   845 lemma compute_lapprox_posrat[code]:
   846   fixes prec x y 
   847   shows "lapprox_posrat prec x y = 
   848    (let 
   849        l = rat_precision prec x y;
   850        d = if 0 \<le> l then x * 2^nat l div y else x div 2^nat (- l) div y
   851     in normfloat (Float d (- l)))"
   852     unfolding div_mult_twopow_eq normfloat_def
   853     by transfer
   854        (simp add: round_down_def powr_int real_div_nat_eq_floor_of_divide field_simps Let_def
   855              del: two_powr_minus_int_float)
   856 
   857 lift_definition rapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   858   is "\<lambda>prec (x::nat) (y::nat). round_up (rat_precision prec x y) (x / y)" by simp
   859 
   860 (* TODO: optimize using zmod_zmult2_eq, pdivmod ? *)
   861 lemma compute_rapprox_posrat[code]:
   862   fixes prec x y
   863   defines "l \<equiv> rat_precision prec x y"
   864   shows "rapprox_posrat prec x y = (let
   865      l = l ;
   866      X = if 0 \<le> l then (x * 2^nat l, y) else (x, y * 2^nat(-l)) ;
   867      d = fst X div snd X ;
   868      m = fst X mod snd X
   869    in normfloat (Float (d + (if m = 0 \<or> y = 0 then 0 else 1)) (- l)))"
   870 proof (cases "y = 0")
   871   assume "y = 0" thus ?thesis unfolding normfloat_def by transfer simp
   872 next
   873   assume "y \<noteq> 0"
   874   show ?thesis
   875   proof (cases "0 \<le> l")
   876     assume "0 \<le> l"
   877     def x' == "x * 2 ^ nat l"
   878     have "int x * 2 ^ nat l = x'" by (simp add: x'_def int_mult int_power)
   879     moreover have "real x * 2 powr real l = real x'"
   880       by (simp add: powr_realpow[symmetric] `0 \<le> l` x'_def)
   881     ultimately show ?thesis
   882       unfolding normfloat_def
   883       using ceil_divide_floor_conv[of y x'] powr_realpow[of 2 "nat l"] `0 \<le> l` `y \<noteq> 0`
   884         l_def[symmetric, THEN meta_eq_to_obj_eq]
   885       by transfer
   886          (simp add: floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0 round_up_def)
   887    next
   888     assume "\<not> 0 \<le> l"
   889     def y' == "y * 2 ^ nat (- l)"
   890     from `y \<noteq> 0` have "y' \<noteq> 0" by (simp add: y'_def)
   891     have "int y * 2 ^ nat (- l) = y'" by (simp add: y'_def int_mult int_power)
   892     moreover have "real x * real (2::int) powr real l / real y = x / real y'"
   893       using `\<not> 0 \<le> l`
   894       by (simp add: powr_realpow[symmetric] powr_minus y'_def field_simps inverse_eq_divide)
   895     ultimately show ?thesis
   896       unfolding normfloat_def
   897       using ceil_divide_floor_conv[of y' x] `\<not> 0 \<le> l` `y' \<noteq> 0` `y \<noteq> 0`
   898         l_def[symmetric, THEN meta_eq_to_obj_eq]
   899       by transfer
   900          (simp add: round_up_def ceil_divide_floor_conv floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0)
   901   qed
   902 qed
   903 
   904 lemma rat_precision_pos:
   905   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   906   shows "rat_precision n (int x) (int y) > 0"
   907 proof -
   908   { assume "0 < x" hence "log 2 x + 1 = log 2 (2 * x)" by (simp add: log_mult) }
   909   hence "bitlen (int x) < bitlen (int y)" using assms
   910     by (simp add: bitlen_def del: floor_add_one)
   911       (auto intro!: floor_mono simp add: floor_add_one[symmetric] simp del: floor_add floor_add_one)
   912   thus ?thesis
   913     using assms by (auto intro!: pos_add_strict simp add: field_simps rat_precision_def)
   914 qed
   915 
   916 lemma power_aux: assumes "x > 0" shows "(2::int) ^ nat (x - 1) \<le> 2 ^ nat x - 1"
   917 proof -
   918   def y \<equiv> "nat (x - 1)" moreover
   919   have "(2::int) ^ y \<le> (2 ^ (y + 1)) - 1" by simp
   920   ultimately show ?thesis using assms by simp
   921 qed
   922 
   923 lemma rapprox_posrat_less1:
   924   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   925   shows "real (rapprox_posrat n x y) < 1"
   926 proof -
   927   have powr1: "2 powr real (rat_precision n (int x) (int y)) = 
   928     2 ^ nat (rat_precision n (int x) (int y))" using rat_precision_pos[of x y n] assms
   929     by (simp add: powr_realpow[symmetric])
   930   have "x * 2 powr real (rat_precision n (int x) (int y)) / y = (x / y) *
   931      2 powr real (rat_precision n (int x) (int y))" by simp
   932   also have "... < (1 / 2) * 2 powr real (rat_precision n (int x) (int y))"
   933     apply (rule mult_strict_right_mono) by (insert assms) auto
   934   also have "\<dots> = 2 powr real (rat_precision n (int x) (int y) - 1)"
   935     by (simp add: powr_add diff_def powr_neg_numeral)
   936   also have "\<dots> = 2 ^ nat (rat_precision n (int x) (int y) - 1)"
   937     using rat_precision_pos[of x y n] assms by (simp add: powr_realpow[symmetric])
   938   also have "\<dots> \<le> 2 ^ nat (rat_precision n (int x) (int y)) - 1"
   939     unfolding int_of_reals real_of_int_le_iff
   940     using rat_precision_pos[OF assms] by (rule power_aux)
   941   finally show ?thesis
   942     apply (transfer fixing: n x y)
   943     apply (simp add: round_up_def field_simps powr_minus inverse_eq_divide powr1)
   944     unfolding int_of_reals real_of_int_less_iff
   945     apply (simp add: ceiling_less_eq)
   946     done
   947 qed
   948 
   949 lift_definition lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   950   "\<lambda>prec (x::int) (y::int). round_down (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   951 
   952 lemma compute_lapprox_rat[code]:
   953   "lapprox_rat prec x y =
   954     (if y = 0 then 0
   955     else if 0 \<le> x then
   956       (if 0 < y then lapprox_posrat prec (nat x) (nat y)
   957       else - (rapprox_posrat prec (nat x) (nat (-y)))) 
   958       else (if 0 < y
   959         then - (rapprox_posrat prec (nat (-x)) (nat y))
   960         else lapprox_posrat prec (nat (-x)) (nat (-y))))"
   961   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
   962 
   963 lift_definition rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   964   "\<lambda>prec (x::int) (y::int). round_up (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   965 
   966 lemma compute_rapprox_rat[code]:
   967   "rapprox_rat prec x y =
   968     (if y = 0 then 0
   969     else if 0 \<le> x then
   970       (if 0 < y then rapprox_posrat prec (nat x) (nat y)
   971       else - (lapprox_posrat prec (nat x) (nat (-y)))) 
   972       else (if 0 < y
   973         then - (lapprox_posrat prec (nat (-x)) (nat y))
   974         else rapprox_posrat prec (nat (-x)) (nat (-y))))"
   975   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
   976 
   977 subsection {* Division *}
   978 
   979 lift_definition float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
   980   "\<lambda>(prec::nat) a b. round_down (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
   981 
   982 lemma compute_float_divl[code]:
   983   "float_divl prec (Float m1 s1) (Float m2 s2) = lapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
   984 proof cases
   985   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
   986   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
   987   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
   988   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
   989     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
   990   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
   991     by (simp add: field_simps powr_divide2[symmetric])
   992 
   993   show ?thesis
   994     using not_0 
   995     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_down_shift, simp add: field_simps)
   996 qed (transfer, auto)
   997 
   998 lift_definition float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
   999   "\<lambda>(prec::nat) a b. round_up (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
  1000 
  1001 lemma compute_float_divr[code]:
  1002   "float_divr prec (Float m1 s1) (Float m2 s2) = rapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1003 proof cases
  1004   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1005   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1006   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1007   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1008     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1009   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1010     by (simp add: field_simps powr_divide2[symmetric])
  1011 
  1012   show ?thesis
  1013     using not_0 
  1014     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_up_shift, simp add: field_simps)
  1015 qed (transfer, auto)
  1016 
  1017 subsection {* Lemmas needed by Approximate *}
  1018 
  1019 lemma Float_num[simp]: shows
  1020    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
  1021    "real (Float 1 -1) = 1/2" and "real (Float 1 -2) = 1/4" and "real (Float 1 -3) = 1/8" and
  1022    "real (Float -1 0) = -1" and "real (Float (number_of n) 0) = number_of n"
  1023 using two_powr_int_float[of 2] two_powr_int_float[of "-1"] two_powr_int_float[of "-2"] two_powr_int_float[of "-3"]
  1024 using powr_realpow[of 2 2] powr_realpow[of 2 3]
  1025 using powr_minus[of 2 1] powr_minus[of 2 2] powr_minus[of 2 3]
  1026 by auto
  1027 
  1028 lemma real_of_Float_int[simp]: "real (Float n 0) = real n" by simp
  1029 
  1030 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
  1031 
  1032 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
  1033 by arith
  1034 
  1035 lemma lapprox_rat:
  1036   shows "real (lapprox_rat prec x y) \<le> real x / real y"
  1037   using round_down by (simp add: lapprox_rat_def)
  1038 
  1039 lemma mult_div_le: fixes a b:: int assumes "b > 0" shows "a \<ge> b * (a div b)"
  1040 proof -
  1041   from zmod_zdiv_equality'[of a b]
  1042   have "a = b * (a div b) + a mod b" by simp
  1043   also have "... \<ge> b * (a div b) + 0" apply (rule add_left_mono) apply (rule pos_mod_sign)
  1044   using assms by simp
  1045   finally show ?thesis by simp
  1046 qed
  1047 
  1048 lemma lapprox_rat_nonneg:
  1049   fixes n x y
  1050   defines "p == int n - ((bitlen \<bar>x\<bar>) - (bitlen \<bar>y\<bar>))"
  1051   assumes "0 \<le> x" "0 < y"
  1052   shows "0 \<le> real (lapprox_rat n x y)"
  1053 using assms unfolding lapprox_rat_def p_def[symmetric] round_down_def real_of_int_minus[symmetric]
  1054    powr_int[of 2, simplified]
  1055   by (auto simp add: inverse_eq_divide intro!: mult_nonneg_nonneg divide_nonneg_pos mult_pos_pos)
  1056 
  1057 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1058   using round_up by (simp add: rapprox_rat_def)
  1059 
  1060 lemma rapprox_rat_le1:
  1061   fixes n x y
  1062   assumes xy: "0 \<le> x" "0 < y" "x \<le> y"
  1063   shows "real (rapprox_rat n x y) \<le> 1"
  1064 proof -
  1065   have "bitlen \<bar>x\<bar> \<le> bitlen \<bar>y\<bar>"
  1066     using xy unfolding bitlen_def by (auto intro!: floor_mono)
  1067   then have "0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>" by (simp add: rat_precision_def)
  1068   have "real \<lceil>real x / real y * 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>
  1069       \<le> real \<lceil>2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>"
  1070     using xy by (auto intro!: ceiling_mono simp: field_simps)
  1071   also have "\<dots> = 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"
  1072     using `0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>`
  1073     by (auto intro!: exI[of _ "2^nat (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"] simp: powr_int)
  1074   finally show ?thesis
  1075     by (simp add: rapprox_rat_def round_up_def)
  1076        (simp add: powr_minus inverse_eq_divide)
  1077 qed
  1078 
  1079 lemma rapprox_rat_nonneg_neg: 
  1080   "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1081   unfolding rapprox_rat_def round_up_def
  1082   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff)
  1083 
  1084 lemma rapprox_rat_neg:
  1085   "x < 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1086   unfolding rapprox_rat_def round_up_def
  1087   by (auto simp: field_simps mult_le_0_iff)
  1088 
  1089 lemma rapprox_rat_nonpos_pos:
  1090   "x \<le> 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1091   unfolding rapprox_rat_def round_up_def
  1092   by (auto simp: field_simps mult_le_0_iff)
  1093 
  1094 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1095   by transfer (simp add: round_down)
  1096 
  1097 lemma float_divl_lower_bound:
  1098   "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> 0 \<le> real (float_divl prec x y)"
  1099   by transfer (simp add: round_down_def zero_le_mult_iff zero_le_divide_iff)
  1100 
  1101 lemma exponent_1: "exponent 1 = 0"
  1102   using exponent_float[of 1 0] by (simp add: one_float_def)
  1103 
  1104 lemma mantissa_1: "mantissa 1 = 1"
  1105   using mantissa_float[of 1 0] by (simp add: one_float_def)
  1106 
  1107 lemma bitlen_1: "bitlen 1 = 1"
  1108   by (simp add: bitlen_def)
  1109 
  1110 lemma mantissa_eq_zero_iff: "mantissa x = 0 \<longleftrightarrow> x = 0"
  1111 proof
  1112   assume "mantissa x = 0" hence z: "0 = real x" using mantissa_exponent by simp
  1113   show "x = 0" by (simp add: zero_float_def z)
  1114 qed (simp add: zero_float_def)
  1115 
  1116 lemma float_upper_bound: "x \<le> 2 powr (bitlen \<bar>mantissa x\<bar> + exponent x)"
  1117 proof (cases "x = 0", simp)
  1118   assume "x \<noteq> 0" hence "mantissa x \<noteq> 0" using mantissa_eq_zero_iff by auto
  1119   have "x = mantissa x * 2 powr (exponent x)" by (rule mantissa_exponent)
  1120   also have "mantissa x \<le> \<bar>mantissa x\<bar>" by simp
  1121   also have "... \<le> 2 powr (bitlen \<bar>mantissa x\<bar>)"
  1122     using bitlen_bounds[of "\<bar>mantissa x\<bar>"] bitlen_nonneg `mantissa x \<noteq> 0`
  1123     by (simp add: powr_int) (simp only: two_real_int int_of_reals real_of_int_abs[symmetric]
  1124       real_of_int_le_iff less_imp_le)
  1125   finally show ?thesis by (simp add: powr_add)
  1126 qed
  1127 
  1128 lemma float_divl_pos_less1_bound:
  1129   "0 < real x \<Longrightarrow> real x < 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real (float_divl prec 1 x)"
  1130 proof transfer
  1131   fix prec :: nat and x :: real assume x: "0 < x" "x < 1" "x \<in> float" and prec: "1 \<le> prec"
  1132   def p \<equiv> "int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor>" 
  1133   show "1 \<le> round_down (int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - \<lfloor>log 2 \<bar>1\<bar>\<rfloor>) (1 / x) "
  1134   proof cases
  1135     assume nonneg: "0 \<le> p"
  1136     hence "2 powr real (p) = floor (real ((2::int) ^ nat p)) * floor (1::real)"
  1137       by (simp add: powr_int del: real_of_int_power) simp
  1138     also have "floor (1::real) \<le> floor (1 / x)" using x prec by simp
  1139     also have "floor (real ((2::int) ^ nat p)) * floor (1 / x) \<le>
  1140       floor (real ((2::int) ^ nat p) * (1 / x))"
  1141       by (rule le_mult_floor) (auto simp: x prec less_imp_le)
  1142     finally have "2 powr real p \<le> floor (2 powr nat p / x)" by (simp add: powr_realpow)
  1143     thus ?thesis unfolding p_def[symmetric]
  1144       using x prec nonneg by (simp add: powr_minus inverse_eq_divide round_down_def)
  1145   next
  1146     assume neg: "\<not> 0 \<le> p"
  1147 
  1148     have "x = 2 powr (log 2 x)"
  1149       using x by simp
  1150     also have "2 powr (log 2 x) \<le> 2 powr p"
  1151     proof (rule powr_mono)
  1152       have "log 2 x \<le> \<lceil>log 2 x\<rceil>"
  1153         by simp
  1154       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + 1"
  1155         using ceiling_diff_floor_le_1[of "log 2 x"] by simp
  1156       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + prec"
  1157         using prec by simp
  1158       finally show "log 2 x \<le> real p"
  1159         using x by (simp add: p_def)
  1160     qed simp
  1161     finally have x_le: "x \<le> 2 powr p" .
  1162 
  1163     from neg have "2 powr real p \<le> 2 powr 0"
  1164       by (intro powr_mono) auto
  1165     also have "\<dots> \<le> \<lfloor>2 powr 0\<rfloor>" by simp
  1166     also have "\<dots> \<le> \<lfloor>2 powr real p / x\<rfloor>" unfolding real_of_int_le_iff
  1167       using x x_le by (intro floor_mono) (simp add:  pos_le_divide_eq mult_pos_pos)
  1168     finally show ?thesis
  1169       using prec x unfolding p_def[symmetric]
  1170       by (simp add: round_down_def powr_minus_divide pos_le_divide_eq mult_pos_pos)
  1171   qed
  1172 qed
  1173 
  1174 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1175   using round_up by transfer simp
  1176 
  1177 lemma float_divr_pos_less1_lower_bound: assumes "0 < x" and "x < 1" shows "1 \<le> float_divr prec 1 x"
  1178 proof -
  1179   have "1 \<le> 1 / real x" using `0 < x` and `x < 1` by auto
  1180   also have "\<dots> \<le> real (float_divr prec 1 x)" using float_divr[where x=1 and y=x] by auto
  1181   finally show ?thesis by auto
  1182 qed
  1183 
  1184 lemma float_divr_nonpos_pos_upper_bound:
  1185   "real x \<le> 0 \<Longrightarrow> 0 < real y \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1186   by transfer (auto simp: field_simps mult_le_0_iff divide_le_0_iff round_up_def)
  1187 
  1188 lemma float_divr_nonneg_neg_upper_bound:
  1189   "0 \<le> real x \<Longrightarrow> real y < 0 \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1190   by transfer (auto simp: field_simps mult_le_0_iff zero_le_mult_iff divide_le_0_iff round_up_def)
  1191 
  1192 lift_definition float_round_up :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1193   "\<lambda>(prec::nat) x. round_up (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1194 
  1195 lemma float_round_up: "real x \<le> real (float_round_up prec x)"
  1196   using round_up by transfer simp
  1197 
  1198 lift_definition float_round_down :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1199   "\<lambda>(prec::nat) x. round_down (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1200 
  1201 lemma float_round_down: "real (float_round_down prec x) \<le> real x"
  1202   using round_down by transfer simp
  1203 
  1204 lemma floor_add2[simp]: "\<lfloor> real i + x \<rfloor> = i + \<lfloor> x \<rfloor>"
  1205   using floor_add[of x i] by (simp del: floor_add add: ac_simps)
  1206 
  1207 lemma compute_float_round_down[code]:
  1208   "float_round_down prec (Float m e) = (let d = bitlen (abs m) - int prec in
  1209     if 0 < d then let P = 2^nat d ; n = m div P in Float n (e + d)
  1210              else Float m e)"
  1211   using compute_float_down[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1212   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1213 
  1214 lemma compute_float_round_up[code]:
  1215   "float_round_up prec (Float m e) = (let d = (bitlen (abs m) - int prec) in
  1216      if 0 < d then let P = 2^nat d ; n = m div P ; r = m mod P
  1217                    in Float (n + (if r = 0 then 0 else 1)) (e + d)
  1218               else Float m e)"
  1219   using compute_float_up[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1220   unfolding Let_def
  1221   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1222 
  1223 lemma Float_le_zero_iff: "Float a b \<le> 0 \<longleftrightarrow> a \<le> 0"
  1224  apply (auto simp: zero_float_def mult_le_0_iff)
  1225  using powr_gt_zero[of 2 b] by simp
  1226 
  1227 (* TODO: how to use as code equation? -> pprt_float?! *)
  1228 lemma compute_pprt[code]: "pprt (Float a e) = (if a <= 0 then 0 else (Float a e))"
  1229 unfolding pprt_def sup_float_def max_def Float_le_zero_iff ..
  1230 
  1231 (* TODO: how to use as code equation? *)
  1232 lemma compute_nprt[code]: "nprt (Float a e) = (if a <= 0 then (Float a e) else 0)"
  1233 unfolding nprt_def inf_float_def min_def Float_le_zero_iff ..
  1234 
  1235 lemma of_float_pprt[simp]: fixes a::float shows "real (pprt a) = pprt (real a)"
  1236   unfolding pprt_def sup_float_def max_def sup_real_def by auto
  1237 
  1238 lemma of_float_nprt[simp]: fixes a::float shows "real (nprt a) = nprt (real a)"
  1239   unfolding nprt_def inf_float_def min_def inf_real_def by auto
  1240 
  1241 lift_definition int_floor_fl :: "float \<Rightarrow> int" is floor by simp
  1242 
  1243 lemma compute_int_floor_fl[code]:
  1244   "int_floor_fl (Float m e) = (if 0 \<le> e then m * 2 ^ nat e else m div (2 ^ (nat (-e))))"
  1245   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1246 
  1247 lift_definition floor_fl :: "float \<Rightarrow> float" is "\<lambda>x. real (floor x)" by simp
  1248 
  1249 lemma compute_floor_fl[code]:
  1250   "floor_fl (Float m e) = (if 0 \<le> e then Float m e else Float (m div (2 ^ (nat (-e)))) 0)"
  1251   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1252 
  1253 lemma floor_fl: "real (floor_fl x) \<le> real x" by transfer simp
  1254 
  1255 lemma int_floor_fl: "real (int_floor_fl x) \<le> real x" by transfer simp
  1256 
  1257 lemma floor_pos_exp: "exponent (floor_fl x) \<ge> 0"
  1258 proof cases
  1259   assume nzero: "floor_fl x \<noteq> float_of 0"
  1260   have "floor_fl x = Float \<lfloor>real x\<rfloor> 0" by transfer simp
  1261   from denormalize_shift[OF this[THEN eq_reflection] nzero] guess i . note i = this
  1262   thus ?thesis by simp
  1263 qed (simp add: floor_fl_def)
  1264 
  1265 end
  1266