src/HOL/Equiv_Relations.thy
 author nipkow Thu Dec 22 17:57:09 2005 +0100 (2005-12-22) changeset 18493 343da052b961 parent 18490 434e34392c40 child 19323 ec5cd5b1804c permissions -rw-r--r--
more lemmas
     1 (*  ID:         $Id$

     2     Authors:    Lawrence C Paulson, Cambridge University Computer Laboratory

     3     Copyright   1996  University of Cambridge

     4 *)

     5

     6 header {* Equivalence Relations in Higher-Order Set Theory *}

     7

     8 theory Equiv_Relations

     9 imports Relation Finite_Set

    10 begin

    11

    12 subsection {* Equivalence relations *}

    13

    14 locale equiv =

    15   fixes A and r

    16   assumes refl: "refl A r"

    17     and sym: "sym r"

    18     and trans: "trans r"

    19

    20 text {*

    21   Suppes, Theorem 70: @{text r} is an equiv relation iff @{text "r\<inverse> O

    22   r = r"}.

    23

    24   First half: @{text "equiv A r ==> r\<inverse> O r = r"}.

    25 *}

    26

    27 lemma sym_trans_comp_subset:

    28     "sym r ==> trans r ==> r\<inverse> O r \<subseteq> r"

    29   by (unfold trans_def sym_def converse_def) blast

    30

    31 lemma refl_comp_subset: "refl A r ==> r \<subseteq> r\<inverse> O r"

    32   by (unfold refl_def) blast

    33

    34 lemma equiv_comp_eq: "equiv A r ==> r\<inverse> O r = r"

    35   apply (unfold equiv_def)

    36   apply clarify

    37   apply (rule equalityI)

    38    apply (iprover intro: sym_trans_comp_subset refl_comp_subset)+

    39   done

    40

    41 text {* Second half. *}

    42

    43 lemma comp_equivI:

    44     "r\<inverse> O r = r ==> Domain r = A ==> equiv A r"

    45   apply (unfold equiv_def refl_def sym_def trans_def)

    46   apply (erule equalityE)

    47   apply (subgoal_tac "\<forall>x y. (x, y) \<in> r --> (y, x) \<in> r")

    48    apply fast

    49   apply fast

    50   done

    51

    52

    53 subsection {* Equivalence classes *}

    54

    55 lemma equiv_class_subset:

    56   "equiv A r ==> (a, b) \<in> r ==> r{a} \<subseteq> r{b}"

    57   -- {* lemma for the next result *}

    58   by (unfold equiv_def trans_def sym_def) blast

    59

    60 theorem equiv_class_eq: "equiv A r ==> (a, b) \<in> r ==> r{a} = r{b}"

    61   apply (assumption | rule equalityI equiv_class_subset)+

    62   apply (unfold equiv_def sym_def)

    63   apply blast

    64   done

    65

    66 lemma equiv_class_self: "equiv A r ==> a \<in> A ==> a \<in> r{a}"

    67   by (unfold equiv_def refl_def) blast

    68

    69 lemma subset_equiv_class:

    70     "equiv A r ==> r{b} \<subseteq> r{a} ==> b \<in> A ==> (a,b) \<in> r"

    71   -- {* lemma for the next result *}

    72   by (unfold equiv_def refl_def) blast

    73

    74 lemma eq_equiv_class:

    75     "r{a} = r{b} ==> equiv A r ==> b \<in> A ==> (a, b) \<in> r"

    76   by (iprover intro: equalityD2 subset_equiv_class)

    77

    78 lemma equiv_class_nondisjoint:

    79     "equiv A r ==> x \<in> (r{a} \<inter> r{b}) ==> (a, b) \<in> r"

    80   by (unfold equiv_def trans_def sym_def) blast

    81

    82 lemma equiv_type: "equiv A r ==> r \<subseteq> A \<times> A"

    83   by (unfold equiv_def refl_def) blast

    84

    85 theorem equiv_class_eq_iff:

    86   "equiv A r ==> ((x, y) \<in> r) = (r{x} = r{y} & x \<in> A & y \<in> A)"

    87   by (blast intro!: equiv_class_eq dest: eq_equiv_class equiv_type)

    88

    89 theorem eq_equiv_class_iff:

    90   "equiv A r ==> x \<in> A ==> y \<in> A ==> (r{x} = r{y}) = ((x, y) \<in> r)"

    91   by (blast intro!: equiv_class_eq dest: eq_equiv_class equiv_type)

    92

    93

    94 subsection {* Quotients *}

    95

    96 constdefs

    97   quotient :: "['a set, ('a*'a) set] => 'a set set"  (infixl "'/'/" 90)

    98   "A//r == \<Union>x \<in> A. {r{x}}"  -- {* set of equiv classes *}

    99

   100 lemma quotientI: "x \<in> A ==> r{x} \<in> A//r"

   101   by (unfold quotient_def) blast

   102

   103 lemma quotientE:

   104   "X \<in> A//r ==> (!!x. X = r{x} ==> x \<in> A ==> P) ==> P"

   105   by (unfold quotient_def) blast

   106

   107 lemma Union_quotient: "equiv A r ==> Union (A//r) = A"

   108   by (unfold equiv_def refl_def quotient_def) blast

   109

   110 lemma quotient_disj:

   111   "equiv A r ==> X \<in> A//r ==> Y \<in> A//r ==> X = Y | (X \<inter> Y = {})"

   112   apply (unfold quotient_def)

   113   apply clarify

   114   apply (rule equiv_class_eq)

   115    apply assumption

   116   apply (unfold equiv_def trans_def sym_def)

   117   apply blast

   118   done

   119

   120 lemma quotient_eqI:

   121   "[|equiv A r; X \<in> A//r; Y \<in> A//r; x \<in> X; y \<in> Y; (x,y) \<in> r|] ==> X = Y"

   122   apply (clarify elim!: quotientE)

   123   apply (rule equiv_class_eq, assumption)

   124   apply (unfold equiv_def sym_def trans_def, blast)

   125   done

   126

   127 lemma quotient_eq_iff:

   128   "[|equiv A r; X \<in> A//r; Y \<in> A//r; x \<in> X; y \<in> Y|] ==> (X = Y) = ((x,y) \<in> r)"

   129   apply (rule iffI)

   130    prefer 2 apply (blast del: equalityI intro: quotient_eqI)

   131   apply (clarify elim!: quotientE)

   132   apply (unfold equiv_def sym_def trans_def, blast)

   133   done

   134

   135 lemma eq_equiv_class_iff2:

   136   "\<lbrakk> equiv A r; x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> ({x}//r = {y}//r) = ((x,y) : r)"

   137 by(simp add:quotient_def eq_equiv_class_iff)

   138

   139

   140 lemma quotient_empty [simp]: "{}//r = {}"

   141 by(simp add: quotient_def)

   142

   143 lemma quotient_is_empty [iff]: "(A//r = {}) = (A = {})"

   144 by(simp add: quotient_def)

   145

   146 lemma quotient_is_empty2 [iff]: "({} = A//r) = (A = {})"

   147 by(simp add: quotient_def)

   148

   149

   150 lemma singleton_quotient: "{x}//r = {r  {x}}"

   151 by(simp add:quotient_def)

   152

   153 lemma quotient_diff1:

   154   "\<lbrakk> inj_on (%a. {a}//r) A; a \<in> A \<rbrakk> \<Longrightarrow> (A - {a})//r = A//r - {a}//r"

   155 apply(simp add:quotient_def inj_on_def)

   156 apply blast

   157 done

   158

   159 subsection {* Defining unary operations upon equivalence classes *}

   160

   161 text{*A congruence-preserving function*}

   162 locale congruent =

   163   fixes r and f

   164   assumes congruent: "(y,z) \<in> r ==> f y = f z"

   165

   166 syntax

   167   RESPECTS ::"['a => 'b, ('a * 'a) set] => bool"  (infixr "respects" 80)

   168

   169 translations

   170   "f respects r" == "congruent r f"

   171

   172

   173 lemma UN_constant_eq: "a \<in> A ==> \<forall>y \<in> A. f y = c ==> (\<Union>y \<in> A. f(y))=c"

   174   -- {* lemma required to prove @{text UN_equiv_class} *}

   175   by auto

   176

   177 lemma UN_equiv_class:

   178   "equiv A r ==> f respects r ==> a \<in> A

   179     ==> (\<Union>x \<in> r{a}. f x) = f a"

   180   -- {* Conversion rule *}

   181   apply (rule equiv_class_self [THEN UN_constant_eq], assumption+)

   182   apply (unfold equiv_def congruent_def sym_def)

   183   apply (blast del: equalityI)

   184   done

   185

   186 lemma UN_equiv_class_type:

   187   "equiv A r ==> f respects r ==> X \<in> A//r ==>

   188     (!!x. x \<in> A ==> f x \<in> B) ==> (\<Union>x \<in> X. f x) \<in> B"

   189   apply (unfold quotient_def)

   190   apply clarify

   191   apply (subst UN_equiv_class)

   192      apply auto

   193   done

   194

   195 text {*

   196   Sufficient conditions for injectiveness.  Could weaken premises!

   197   major premise could be an inclusion; bcong could be @{text "!!y. y \<in>

   198   A ==> f y \<in> B"}.

   199 *}

   200

   201 lemma UN_equiv_class_inject:

   202   "equiv A r ==> f respects r ==>

   203     (\<Union>x \<in> X. f x) = (\<Union>y \<in> Y. f y) ==> X \<in> A//r ==> Y \<in> A//r

   204     ==> (!!x y. x \<in> A ==> y \<in> A ==> f x = f y ==> (x, y) \<in> r)

   205     ==> X = Y"

   206   apply (unfold quotient_def)

   207   apply clarify

   208   apply (rule equiv_class_eq)

   209    apply assumption

   210   apply (subgoal_tac "f x = f xa")

   211    apply blast

   212   apply (erule box_equals)

   213    apply (assumption | rule UN_equiv_class)+

   214   done

   215

   216

   217 subsection {* Defining binary operations upon equivalence classes *}

   218

   219 text{*A congruence-preserving function of two arguments*}

   220 locale congruent2 =

   221   fixes r1 and r2 and f

   222   assumes congruent2:

   223     "(y1,z1) \<in> r1 ==> (y2,z2) \<in> r2 ==> f y1 y2 = f z1 z2"

   224

   225 text{*Abbreviation for the common case where the relations are identical*}

   226 syntax

   227   RESPECTS2 ::"['a => 'b, ('a * 'a) set] => bool"  (infixr "respects2 " 80)

   228

   229 translations

   230   "f respects2 r" => "congruent2 r r f"

   231

   232 lemma congruent2_implies_congruent:

   233     "equiv A r1 ==> congruent2 r1 r2 f ==> a \<in> A ==> congruent r2 (f a)"

   234   by (unfold congruent_def congruent2_def equiv_def refl_def) blast

   235

   236 lemma congruent2_implies_congruent_UN:

   237   "equiv A1 r1 ==> equiv A2 r2 ==> congruent2 r1 r2 f ==> a \<in> A2 ==>

   238     congruent r1 (\<lambda>x1. \<Union>x2 \<in> r2{a}. f x1 x2)"

   239   apply (unfold congruent_def)

   240   apply clarify

   241   apply (rule equiv_type [THEN subsetD, THEN SigmaE2], assumption+)

   242   apply (simp add: UN_equiv_class congruent2_implies_congruent)

   243   apply (unfold congruent2_def equiv_def refl_def)

   244   apply (blast del: equalityI)

   245   done

   246

   247 lemma UN_equiv_class2:

   248   "equiv A1 r1 ==> equiv A2 r2 ==> congruent2 r1 r2 f ==> a1 \<in> A1 ==> a2 \<in> A2

   249     ==> (\<Union>x1 \<in> r1{a1}. \<Union>x2 \<in> r2{a2}. f x1 x2) = f a1 a2"

   250   by (simp add: UN_equiv_class congruent2_implies_congruent

   251     congruent2_implies_congruent_UN)

   252

   253 lemma UN_equiv_class_type2:

   254   "equiv A1 r1 ==> equiv A2 r2 ==> congruent2 r1 r2 f

   255     ==> X1 \<in> A1//r1 ==> X2 \<in> A2//r2

   256     ==> (!!x1 x2. x1 \<in> A1 ==> x2 \<in> A2 ==> f x1 x2 \<in> B)

   257     ==> (\<Union>x1 \<in> X1. \<Union>x2 \<in> X2. f x1 x2) \<in> B"

   258   apply (unfold quotient_def)

   259   apply clarify

   260   apply (blast intro: UN_equiv_class_type congruent2_implies_congruent_UN

   261     congruent2_implies_congruent quotientI)

   262   done

   263

   264 lemma UN_UN_split_split_eq:

   265   "(\<Union>(x1, x2) \<in> X. \<Union>(y1, y2) \<in> Y. A x1 x2 y1 y2) =

   266     (\<Union>x \<in> X. \<Union>y \<in> Y. (\<lambda>(x1, x2). (\<lambda>(y1, y2). A x1 x2 y1 y2) y) x)"

   267   -- {* Allows a natural expression of binary operators, *}

   268   -- {* without explicit calls to @{text split} *}

   269   by auto

   270

   271 lemma congruent2I:

   272   "equiv A1 r1 ==> equiv A2 r2

   273     ==> (!!y z w. w \<in> A2 ==> (y,z) \<in> r1 ==> f y w = f z w)

   274     ==> (!!y z w. w \<in> A1 ==> (y,z) \<in> r2 ==> f w y = f w z)

   275     ==> congruent2 r1 r2 f"

   276   -- {* Suggested by John Harrison -- the two subproofs may be *}

   277   -- {* \emph{much} simpler than the direct proof. *}

   278   apply (unfold congruent2_def equiv_def refl_def)

   279   apply clarify

   280   apply (blast intro: trans)

   281   done

   282

   283 lemma congruent2_commuteI:

   284   assumes equivA: "equiv A r"

   285     and commute: "!!y z. y \<in> A ==> z \<in> A ==> f y z = f z y"

   286     and congt: "!!y z w. w \<in> A ==> (y,z) \<in> r ==> f w y = f w z"

   287   shows "f respects2 r"

   288   apply (rule congruent2I [OF equivA equivA])

   289    apply (rule commute [THEN trans])

   290      apply (rule_tac  commute [THEN trans, symmetric])

   291        apply (rule_tac  sym)

   292        apply (assumption | rule congt |

   293          erule equivA [THEN equiv_type, THEN subsetD, THEN SigmaE2])+

   294   done

   295

   296

   297 subsection {* Cardinality results *}

   298

   299 text {*Suggested by Florian Kamm�ller*}

   300

   301 lemma finite_quotient: "finite A ==> r \<subseteq> A \<times> A ==> finite (A//r)"

   302   -- {* recall @{thm equiv_type} *}

   303   apply (rule finite_subset)

   304    apply (erule_tac  finite_Pow_iff [THEN iffD2])

   305   apply (unfold quotient_def)

   306   apply blast

   307   done

   308

   309 lemma finite_equiv_class:

   310   "finite A ==> r \<subseteq> A \<times> A ==> X \<in> A//r ==> finite X"

   311   apply (unfold quotient_def)

   312   apply (rule finite_subset)

   313    prefer 2 apply assumption

   314   apply blast

   315   done

   316

   317 lemma equiv_imp_dvd_card:

   318   "finite A ==> equiv A r ==> \<forall>X \<in> A//r. k dvd card X

   319     ==> k dvd card A"

   320   apply (rule Union_quotient [THEN subst])

   321    apply assumption

   322   apply (rule dvd_partition)

   323      prefer 3 apply (blast dest: quotient_disj)

   324     apply (simp_all add: Union_quotient equiv_type)

   325   done

   326

   327 lemma card_quotient_disjoint:

   328  "\<lbrakk> finite A; inj_on (\<lambda>x. {x} // r) A \<rbrakk> \<Longrightarrow> card(A//r) = card A"

   329 apply(simp add:quotient_def)

   330 apply(subst card_UN_disjoint)

   331    apply assumption

   332   apply simp

   333  apply(fastsimp simp add:inj_on_def)

   334 apply (simp add:setsum_constant)

   335 done

   336

   337 ML

   338 {*

   339 val UN_UN_split_split_eq = thm "UN_UN_split_split_eq";

   340 val UN_constant_eq = thm "UN_constant_eq";

   341 val UN_equiv_class = thm "UN_equiv_class";

   342 val UN_equiv_class2 = thm "UN_equiv_class2";

   343 val UN_equiv_class_inject = thm "UN_equiv_class_inject";

   344 val UN_equiv_class_type = thm "UN_equiv_class_type";

   345 val UN_equiv_class_type2 = thm "UN_equiv_class_type2";

   346 val Union_quotient = thm "Union_quotient";

   347 val comp_equivI = thm "comp_equivI";

   348 val congruent2I = thm "congruent2I";

   349 val congruent2_commuteI = thm "congruent2_commuteI";

   350 val congruent2_def = thm "congruent2_def";

   351 val congruent2_implies_congruent = thm "congruent2_implies_congruent";

   352 val congruent2_implies_congruent_UN = thm "congruent2_implies_congruent_UN";

   353 val congruent_def = thm "congruent_def";

   354 val eq_equiv_class = thm "eq_equiv_class";

   355 val eq_equiv_class_iff = thm "eq_equiv_class_iff";

   356 val equiv_class_eq = thm "equiv_class_eq";

   357 val equiv_class_eq_iff = thm "equiv_class_eq_iff";

   358 val equiv_class_nondisjoint = thm "equiv_class_nondisjoint";

   359 val equiv_class_self = thm "equiv_class_self";

   360 val equiv_comp_eq = thm "equiv_comp_eq";

   361 val equiv_def = thm "equiv_def";

   362 val equiv_imp_dvd_card = thm "equiv_imp_dvd_card";

   363 val equiv_type = thm "equiv_type";

   364 val finite_equiv_class = thm "finite_equiv_class";

   365 val finite_quotient = thm "finite_quotient";

   366 val quotientE = thm "quotientE";

   367 val quotientI = thm "quotientI";

   368 val quotient_def = thm "quotient_def";

   369 val quotient_disj = thm "quotient_disj";

   370 val refl_comp_subset = thm "refl_comp_subset";

   371 val subset_equiv_class = thm "subset_equiv_class";

   372 val sym_trans_comp_subset = thm "sym_trans_comp_subset";

   373 *}

   374

   375 end