src/HOL/Nat.thy
author webertj
Mon Mar 07 19:30:53 2005 +0100 (2005-03-07)
changeset 15584 3478bb4f93ff
parent 15539 333a88244569
child 15921 b6e345548913
permissions -rw-r--r--
refute_params: default value itself=1 added (for type classes)
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Wellfounded_Recursion Ring_and_Field
    13 begin
    14 
    15 subsection {* Type @{text ind} *}
    16 
    17 typedecl ind
    18 
    19 consts
    20   Zero_Rep      :: ind
    21   Suc_Rep       :: "ind => ind"
    22 
    23 axioms
    24   -- {* the axiom of infinity in 2 parts *}
    25   inj_Suc_Rep:          "inj Suc_Rep"
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 
    28 
    29 subsection {* Type nat *}
    30 
    31 text {* Type definition *}
    32 
    33 consts
    34   Nat :: "ind set"
    35 
    36 inductive Nat
    37 intros
    38   Zero_RepI: "Zero_Rep : Nat"
    39   Suc_RepI: "i : Nat ==> Suc_Rep i : Nat"
    40 
    41 global
    42 
    43 typedef (open Nat)
    44   nat = Nat by (rule exI, rule Nat.Zero_RepI)
    45 
    46 instance nat :: "{ord, zero, one}" ..
    47 
    48 
    49 text {* Abstract constants and syntax *}
    50 
    51 consts
    52   Suc :: "nat => nat"
    53   pred_nat :: "(nat * nat) set"
    54 
    55 local
    56 
    57 defs
    58   Zero_nat_def: "0 == Abs_Nat Zero_Rep"
    59   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    60   One_nat_def [simp]: "1 == Suc 0"
    61 
    62   -- {* nat operations *}
    63   pred_nat_def: "pred_nat == {(m, n). n = Suc m}"
    64 
    65   less_def: "m < n == (m, n) : trancl pred_nat"
    66 
    67   le_def: "m \<le> (n::nat) == ~ (n < m)"
    68 
    69 
    70 text {* Induction *}
    71 
    72 theorem nat_induct: "P 0 ==> (!!n. P n ==> P (Suc n)) ==> P n"
    73   apply (unfold Zero_nat_def Suc_def)
    74   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    75   apply (erule Rep_Nat [THEN Nat.induct])
    76   apply (rules elim: Abs_Nat_inverse [THEN subst])
    77   done
    78 
    79 text {* Distinctness of constructors *}
    80 
    81 lemma Suc_not_Zero [iff]: "Suc m \<noteq> 0"
    82   by (simp add: Zero_nat_def Suc_def Abs_Nat_inject Rep_Nat Suc_RepI Zero_RepI
    83                 Suc_Rep_not_Zero_Rep) 
    84 
    85 lemma Zero_not_Suc [iff]: "0 \<noteq> Suc m"
    86   by (rule not_sym, rule Suc_not_Zero not_sym)
    87 
    88 lemma Suc_neq_Zero: "Suc m = 0 ==> R"
    89   by (rule notE, rule Suc_not_Zero)
    90 
    91 lemma Zero_neq_Suc: "0 = Suc m ==> R"
    92   by (rule Suc_neq_Zero, erule sym)
    93 
    94 text {* Injectiveness of @{term Suc} *}
    95 
    96 lemma inj_Suc: "inj_on Suc N"
    97   by (simp add: Suc_def inj_on_def Abs_Nat_inject Rep_Nat Suc_RepI 
    98                 inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject) 
    99 
   100 lemma Suc_inject: "Suc x = Suc y ==> x = y"
   101   by (rule inj_Suc [THEN injD])
   102 
   103 lemma Suc_Suc_eq [iff]: "(Suc m = Suc n) = (m = n)"
   104   by (rule inj_Suc [THEN inj_eq])
   105 
   106 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
   107   by auto
   108 
   109 text {* @{typ nat} is a datatype *}
   110 
   111 rep_datatype nat
   112   distinct  Suc_not_Zero Zero_not_Suc
   113   inject    Suc_Suc_eq
   114   induction nat_induct
   115 
   116 lemma n_not_Suc_n: "n \<noteq> Suc n"
   117   by (induct n) simp_all
   118 
   119 lemma Suc_n_not_n: "Suc t \<noteq> t"
   120   by (rule not_sym, rule n_not_Suc_n)
   121 
   122 text {* A special form of induction for reasoning
   123   about @{term "m < n"} and @{term "m - n"} *}
   124 
   125 theorem diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   126     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   127   apply (rule_tac x = m in spec)
   128   apply (induct n)
   129   prefer 2
   130   apply (rule allI)
   131   apply (induct_tac x, rules+)
   132   done
   133 
   134 subsection {* Basic properties of "less than" *}
   135 
   136 lemma wf_pred_nat: "wf pred_nat"
   137   apply (unfold wf_def pred_nat_def, clarify)
   138   apply (induct_tac x, blast+)
   139   done
   140 
   141 lemma wf_less: "wf {(x, y::nat). x < y}"
   142   apply (unfold less_def)
   143   apply (rule wf_pred_nat [THEN wf_trancl, THEN wf_subset], blast)
   144   done
   145 
   146 lemma less_eq: "((m, n) : pred_nat^+) = (m < n)"
   147   apply (unfold less_def)
   148   apply (rule refl)
   149   done
   150 
   151 subsubsection {* Introduction properties *}
   152 
   153 lemma less_trans: "i < j ==> j < k ==> i < (k::nat)"
   154   apply (unfold less_def)
   155   apply (rule trans_trancl [THEN transD], assumption+)
   156   done
   157 
   158 lemma lessI [iff]: "n < Suc n"
   159   apply (unfold less_def pred_nat_def)
   160   apply (simp add: r_into_trancl)
   161   done
   162 
   163 lemma less_SucI: "i < j ==> i < Suc j"
   164   apply (rule less_trans, assumption)
   165   apply (rule lessI)
   166   done
   167 
   168 lemma zero_less_Suc [iff]: "0 < Suc n"
   169   apply (induct n)
   170   apply (rule lessI)
   171   apply (erule less_trans)
   172   apply (rule lessI)
   173   done
   174 
   175 subsubsection {* Elimination properties *}
   176 
   177 lemma less_not_sym: "n < m ==> ~ m < (n::nat)"
   178   apply (unfold less_def)
   179   apply (blast intro: wf_pred_nat wf_trancl [THEN wf_asym])
   180   done
   181 
   182 lemma less_asym:
   183   assumes h1: "(n::nat) < m" and h2: "~ P ==> m < n" shows P
   184   apply (rule contrapos_np)
   185   apply (rule less_not_sym)
   186   apply (rule h1)
   187   apply (erule h2)
   188   done
   189 
   190 lemma less_not_refl: "~ n < (n::nat)"
   191   apply (unfold less_def)
   192   apply (rule wf_pred_nat [THEN wf_trancl, THEN wf_not_refl])
   193   done
   194 
   195 lemma less_irrefl [elim!]: "(n::nat) < n ==> R"
   196   by (rule notE, rule less_not_refl)
   197 
   198 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)" by blast
   199 
   200 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   201   by (rule not_sym, rule less_not_refl2)
   202 
   203 lemma lessE:
   204   assumes major: "i < k"
   205   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   206   shows P
   207   apply (rule major [unfolded less_def pred_nat_def, THEN tranclE], simp_all)
   208   apply (erule p1)
   209   apply (rule p2)
   210   apply (simp add: less_def pred_nat_def, assumption)
   211   done
   212 
   213 lemma not_less0 [iff]: "~ n < (0::nat)"
   214   by (blast elim: lessE)
   215 
   216 lemma less_zeroE: "(n::nat) < 0 ==> R"
   217   by (rule notE, rule not_less0)
   218 
   219 lemma less_SucE: assumes major: "m < Suc n"
   220   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   221   apply (rule major [THEN lessE])
   222   apply (rule eq, blast)
   223   apply (rule less, blast)
   224   done
   225 
   226 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   227   by (blast elim!: less_SucE intro: less_trans)
   228 
   229 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   230   by (simp add: less_Suc_eq)
   231 
   232 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   233   by (simp add: less_Suc_eq)
   234 
   235 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   236   by (induct n) (fast elim: less_trans lessE)+
   237 
   238 text {* "Less than" is a linear ordering *}
   239 lemma less_linear: "m < n | m = n | n < (m::nat)"
   240   apply (induct m)
   241   apply (induct n)
   242   apply (rule refl [THEN disjI1, THEN disjI2])
   243   apply (rule zero_less_Suc [THEN disjI1])
   244   apply (blast intro: Suc_mono less_SucI elim: lessE)
   245   done
   246 
   247 text {* "Less than" is antisymmetric, sort of *}
   248 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   249 apply(simp only:less_Suc_eq)
   250 apply blast
   251 done
   252 
   253 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   254   using less_linear by blast
   255 
   256 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   257   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   258   shows "P n m"
   259   apply (rule less_linear [THEN disjE])
   260   apply (erule_tac [2] disjE)
   261   apply (erule lessCase)
   262   apply (erule sym [THEN eqCase])
   263   apply (erule major)
   264   done
   265 
   266 
   267 subsubsection {* Inductive (?) properties *}
   268 
   269 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   270   apply (simp add: nat_neq_iff)
   271   apply (blast elim!: less_irrefl less_SucE elim: less_asym)
   272   done
   273 
   274 lemma Suc_lessD: "Suc m < n ==> m < n"
   275   apply (induct n)
   276   apply (fast intro!: lessI [THEN less_SucI] elim: less_trans lessE)+
   277   done
   278 
   279 lemma Suc_lessE: assumes major: "Suc i < k"
   280   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   281   apply (rule major [THEN lessE])
   282   apply (erule lessI [THEN minor])
   283   apply (erule Suc_lessD [THEN minor], assumption)
   284   done
   285 
   286 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   287   by (blast elim: lessE dest: Suc_lessD)
   288 
   289 lemma Suc_less_eq [iff]: "(Suc m < Suc n) = (m < n)"
   290   apply (rule iffI)
   291   apply (erule Suc_less_SucD)
   292   apply (erule Suc_mono)
   293   done
   294 
   295 lemma less_trans_Suc:
   296   assumes le: "i < j" shows "j < k ==> Suc i < k"
   297   apply (induct k, simp_all)
   298   apply (insert le)
   299   apply (simp add: less_Suc_eq)
   300   apply (blast dest: Suc_lessD)
   301   done
   302 
   303 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   304 lemma not_less_eq: "(~ m < n) = (n < Suc m)"
   305 by (rule_tac m = m and n = n in diff_induct, simp_all)
   306 
   307 text {* Complete induction, aka course-of-values induction *}
   308 lemma nat_less_induct:
   309   assumes prem: "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   310   apply (rule_tac a=n in wf_induct)
   311   apply (rule wf_pred_nat [THEN wf_trancl])
   312   apply (rule prem)
   313   apply (unfold less_def, assumption)
   314   done
   315 
   316 lemmas less_induct = nat_less_induct [rule_format, case_names less]
   317 
   318 subsection {* Properties of "less than or equal" *}
   319 
   320 text {* Was @{text le_eq_less_Suc}, but this orientation is more useful *}
   321 lemma less_Suc_eq_le: "(m < Suc n) = (m \<le> n)"
   322   by (unfold le_def, rule not_less_eq [symmetric])
   323 
   324 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   325   by (rule less_Suc_eq_le [THEN iffD2])
   326 
   327 lemma le0 [iff]: "(0::nat) \<le> n"
   328   by (unfold le_def, rule not_less0)
   329 
   330 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   331   by (simp add: le_def)
   332 
   333 lemma le_0_eq [iff]: "((i::nat) \<le> 0) = (i = 0)"
   334   by (induct i) (simp_all add: le_def)
   335 
   336 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   337   by (simp del: less_Suc_eq_le add: less_Suc_eq_le [symmetric] less_Suc_eq)
   338 
   339 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   340   by (drule le_Suc_eq [THEN iffD1], rules+)
   341 
   342 lemma leI: "~ n < m ==> m \<le> (n::nat)" by (simp add: le_def)
   343 
   344 lemma leD: "m \<le> n ==> ~ n < (m::nat)"
   345   by (simp add: le_def)
   346 
   347 lemmas leE = leD [elim_format]
   348 
   349 lemma not_less_iff_le: "(~ n < m) = (m \<le> (n::nat))"
   350   by (blast intro: leI elim: leE)
   351 
   352 lemma not_leE: "~ m \<le> n ==> n<(m::nat)"
   353   by (simp add: le_def)
   354 
   355 lemma not_le_iff_less: "(~ n \<le> m) = (m < (n::nat))"
   356   by (simp add: le_def)
   357 
   358 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   359   apply (simp add: le_def less_Suc_eq)
   360   apply (blast elim!: less_irrefl less_asym)
   361   done -- {* formerly called lessD *}
   362 
   363 lemma Suc_leD: "Suc(m) \<le> n ==> m \<le> n"
   364   by (simp add: le_def less_Suc_eq)
   365 
   366 text {* Stronger version of @{text Suc_leD} *}
   367 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   368   apply (simp add: le_def less_Suc_eq)
   369   using less_linear
   370   apply blast
   371   done
   372 
   373 lemma Suc_le_eq: "(Suc m \<le> n) = (m < n)"
   374   by (blast intro: Suc_leI Suc_le_lessD)
   375 
   376 lemma le_SucI: "m \<le> n ==> m \<le> Suc n"
   377   by (unfold le_def) (blast dest: Suc_lessD)
   378 
   379 lemma less_imp_le: "m < n ==> m \<le> (n::nat)"
   380   by (unfold le_def) (blast elim: less_asym)
   381 
   382 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   383 lemmas le_simps = less_imp_le less_Suc_eq_le Suc_le_eq
   384 
   385 
   386 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   387 
   388 lemma le_imp_less_or_eq: "m \<le> n ==> m < n | m = (n::nat)"
   389   apply (unfold le_def)
   390   using less_linear
   391   apply (blast elim: less_irrefl less_asym)
   392   done
   393 
   394 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   395   apply (unfold le_def)
   396   using less_linear
   397   apply (blast elim!: less_irrefl elim: less_asym)
   398   done
   399 
   400 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   401   by (rules intro: less_or_eq_imp_le le_imp_less_or_eq)
   402 
   403 text {* Useful with @{text Blast}. *}
   404 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   405   by (rule less_or_eq_imp_le, rule disjI2)
   406 
   407 lemma le_refl: "n \<le> (n::nat)"
   408   by (simp add: le_eq_less_or_eq)
   409 
   410 lemma le_less_trans: "[| i \<le> j; j < k |] ==> i < (k::nat)"
   411   by (blast dest!: le_imp_less_or_eq intro: less_trans)
   412 
   413 lemma less_le_trans: "[| i < j; j \<le> k |] ==> i < (k::nat)"
   414   by (blast dest!: le_imp_less_or_eq intro: less_trans)
   415 
   416 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   417   by (blast dest!: le_imp_less_or_eq intro: less_or_eq_imp_le less_trans)
   418 
   419 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   420   by (blast dest!: le_imp_less_or_eq elim!: less_irrefl elim: less_asym)
   421 
   422 lemma Suc_le_mono [iff]: "(Suc n \<le> Suc m) = (n \<le> m)"
   423   by (simp add: le_simps)
   424 
   425 text {* Axiom @{text order_less_le} of class @{text order}: *}
   426 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   427   by (simp add: le_def nat_neq_iff) (blast elim!: less_asym)
   428 
   429 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   430   by (rule iffD2, rule nat_less_le, rule conjI)
   431 
   432 text {* Axiom @{text linorder_linear} of class @{text linorder}: *}
   433 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   434   apply (simp add: le_eq_less_or_eq)
   435   using less_linear
   436   apply blast
   437   done
   438 
   439 text {* Type {@typ nat} is a wellfounded linear order *}
   440 
   441 instance nat :: "{order, linorder, wellorder}"
   442   by intro_classes
   443     (assumption |
   444       rule le_refl le_trans le_anti_sym nat_less_le nat_le_linear wf_less)+
   445 
   446 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   447   by (blast elim!: less_SucE)
   448 
   449 text {*
   450   Rewrite @{term "n < Suc m"} to @{term "n = m"}
   451   if @{term "~ n < m"} or @{term "m \<le> n"} hold.
   452   Not suitable as default simprules because they often lead to looping
   453 *}
   454 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   455   by (rule not_less_less_Suc_eq, rule leD)
   456 
   457 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   458 
   459 
   460 text {*
   461   Re-orientation of the equations @{text "0 = x"} and @{text "1 = x"}. 
   462   No longer added as simprules (they loop) 
   463   but via @{text reorient_simproc} in Bin
   464 *}
   465 
   466 text {* Polymorphic, not just for @{typ nat} *}
   467 lemma zero_reorient: "(0 = x) = (x = 0)"
   468   by auto
   469 
   470 lemma one_reorient: "(1 = x) = (x = 1)"
   471   by auto
   472 
   473 subsection {* Arithmetic operators *}
   474 
   475 axclass power < type
   476 
   477 consts
   478   power :: "('a::power) => nat => 'a"            (infixr "^" 80)
   479 
   480 
   481 text {* arithmetic operators @{text "+ -"} and @{text "*"} *}
   482 
   483 instance nat :: "{plus, minus, times, power}" ..
   484 
   485 text {* size of a datatype value; overloaded *}
   486 consts size :: "'a => nat"
   487 
   488 primrec
   489   add_0:    "0 + n = n"
   490   add_Suc:  "Suc m + n = Suc (m + n)"
   491 
   492 primrec
   493   diff_0:   "m - 0 = m"
   494   diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   495 
   496 primrec
   497   mult_0:   "0 * n = 0"
   498   mult_Suc: "Suc m * n = n + (m * n)"
   499 
   500 text {* These two rules ease the use of primitive recursion. 
   501 NOTE USE OF @{text "=="} *}
   502 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   503   by simp
   504 
   505 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   506   by simp
   507 
   508 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   509   by (case_tac n) simp_all
   510 
   511 lemma gr_implies_not0: "!!n::nat. m<n ==> n \<noteq> 0"
   512   by (case_tac n) simp_all
   513 
   514 lemma neq0_conv [iff]: "!!n::nat. (n \<noteq> 0) = (0 < n)"
   515   by (case_tac n) simp_all
   516 
   517 text {* This theorem is useful with @{text blast} *}
   518 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   519   by (rule iffD1, rule neq0_conv, rules)
   520 
   521 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   522   by (fast intro: not0_implies_Suc)
   523 
   524 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   525   apply (rule iffI)
   526   apply (rule ccontr, simp_all)
   527   done
   528 
   529 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   530   by (induct m') simp_all
   531 
   532 text {* Useful in certain inductive arguments *}
   533 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   534   by (case_tac m) simp_all
   535 
   536 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   537   apply (rule nat_less_induct)
   538   apply (case_tac n)
   539   apply (case_tac [2] nat)
   540   apply (blast intro: less_trans)+
   541   done
   542 
   543 subsection {* @{text LEAST} theorems for type @{typ nat}*}
   544 
   545 lemma Least_Suc:
   546      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   547   apply (case_tac "n", auto)
   548   apply (frule LeastI)
   549   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   550   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   551   apply (erule_tac [2] Least_le)
   552   apply (case_tac "LEAST x. P x", auto)
   553   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   554   apply (blast intro: order_antisym)
   555   done
   556 
   557 lemma Least_Suc2:
   558      "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   559   by (erule (1) Least_Suc [THEN ssubst], simp)
   560 
   561 
   562 
   563 subsection {* @{term min} and @{term max} *}
   564 
   565 lemma min_0L [simp]: "min 0 n = (0::nat)"
   566   by (rule min_leastL) simp
   567 
   568 lemma min_0R [simp]: "min n 0 = (0::nat)"
   569   by (rule min_leastR) simp
   570 
   571 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   572   by (simp add: min_of_mono)
   573 
   574 lemma max_0L [simp]: "max 0 n = (n::nat)"
   575   by (rule max_leastL) simp
   576 
   577 lemma max_0R [simp]: "max n 0 = (n::nat)"
   578   by (rule max_leastR) simp
   579 
   580 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   581   by (simp add: max_of_mono)
   582 
   583 
   584 subsection {* Basic rewrite rules for the arithmetic operators *}
   585 
   586 text {* Difference *}
   587 
   588 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   589   by (induct n) simp_all
   590 
   591 lemma diff_Suc_Suc [simp, code]: "Suc(m) - Suc(n) = m - n"
   592   by (induct n) simp_all
   593 
   594 
   595 text {*
   596   Could be (and is, below) generalized in various ways
   597   However, none of the generalizations are currently in the simpset,
   598   and I dread to think what happens if I put them in
   599 *}
   600 lemma Suc_pred [simp]: "0 < n ==> Suc (n - Suc 0) = n"
   601   by (simp split add: nat.split)
   602 
   603 declare diff_Suc [simp del, code del]
   604 
   605 
   606 subsection {* Addition *}
   607 
   608 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   609   by (induct m) simp_all
   610 
   611 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   612   by (induct m) simp_all
   613 
   614 lemma [code]: "Suc m + n = m + Suc n" by simp
   615 
   616 
   617 text {* Associative law for addition *}
   618 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   619   by (induct m) simp_all
   620 
   621 text {* Commutative law for addition *}
   622 lemma nat_add_commute: "m + n = n + (m::nat)"
   623   by (induct m) simp_all
   624 
   625 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   626   apply (rule mk_left_commute [of "op +"])
   627   apply (rule nat_add_assoc)
   628   apply (rule nat_add_commute)
   629   done
   630 
   631 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   632   by (induct k) simp_all
   633 
   634 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   635   by (induct k) simp_all
   636 
   637 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   638   by (induct k) simp_all
   639 
   640 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   641   by (induct k) simp_all
   642 
   643 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   644 
   645 lemma add_is_0 [iff]: "!!m::nat. (m + n = 0) = (m = 0 & n = 0)"
   646   by (case_tac m) simp_all
   647 
   648 lemma add_is_1: "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   649   by (case_tac m) simp_all
   650 
   651 lemma one_is_add: "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   652   by (rule trans, rule eq_commute, rule add_is_1)
   653 
   654 lemma add_gr_0 [iff]: "!!m::nat. (0 < m + n) = (0 < m | 0 < n)"
   655   by (simp del: neq0_conv add: neq0_conv [symmetric])
   656 
   657 lemma add_eq_self_zero: "!!m::nat. m + n = m ==> n = 0"
   658   apply (drule add_0_right [THEN ssubst])
   659   apply (simp add: nat_add_assoc del: add_0_right)
   660   done
   661 
   662 
   663 subsection {* Multiplication *}
   664 
   665 text {* right annihilation in product *}
   666 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   667   by (induct m) simp_all
   668 
   669 text {* right successor law for multiplication *}
   670 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   671   by (induct m) (simp_all add: nat_add_left_commute)
   672 
   673 text {* Commutative law for multiplication *}
   674 lemma nat_mult_commute: "m * n = n * (m::nat)"
   675   by (induct m) simp_all
   676 
   677 text {* addition distributes over multiplication *}
   678 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   679   by (induct m) (simp_all add: nat_add_assoc nat_add_left_commute)
   680 
   681 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   682   by (induct m) (simp_all add: nat_add_assoc)
   683 
   684 text {* Associative law for multiplication *}
   685 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   686   by (induct m) (simp_all add: add_mult_distrib)
   687 
   688 
   689 text{*The naturals form a @{text comm_semiring_1_cancel}*}
   690 instance nat :: comm_semiring_1_cancel
   691 proof
   692   fix i j k :: nat
   693   show "(i + j) + k = i + (j + k)" by (rule nat_add_assoc)
   694   show "i + j = j + i" by (rule nat_add_commute)
   695   show "0 + i = i" by simp
   696   show "(i * j) * k = i * (j * k)" by (rule nat_mult_assoc)
   697   show "i * j = j * i" by (rule nat_mult_commute)
   698   show "1 * i = i" by simp
   699   show "(i + j) * k = i * k + j * k" by (simp add: add_mult_distrib)
   700   show "0 \<noteq> (1::nat)" by simp
   701   assume "k+i = k+j" thus "i=j" by simp
   702 qed
   703 
   704 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   705   apply (induct m)
   706   apply (induct_tac [2] n, simp_all)
   707   done
   708 
   709 subsection {* Monotonicity of Addition *}
   710 
   711 text {* strict, in 1st argument *}
   712 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   713   by (induct k) simp_all
   714 
   715 text {* strict, in both arguments *}
   716 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   717   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   718   apply (induct j, simp_all)
   719   done
   720 
   721 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   722 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   723   apply (induct n)
   724   apply (simp_all add: order_le_less)
   725   apply (blast elim!: less_SucE 
   726                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   727   done
   728 
   729 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   730 lemma mult_less_mono2: "(i::nat) < j ==> 0 < k ==> k * i < k * j"
   731   apply (erule_tac m1 = 0 in less_imp_Suc_add [THEN exE], simp)
   732   apply (induct_tac x) 
   733   apply (simp_all add: add_less_mono)
   734   done
   735 
   736 
   737 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   738 instance nat :: ordered_semidom
   739 proof
   740   fix i j k :: nat
   741   show "0 < (1::nat)" by simp
   742   show "i \<le> j ==> k + i \<le> k + j" by simp
   743   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   744 qed
   745 
   746 lemma nat_mult_1: "(1::nat) * n = n"
   747   by simp
   748 
   749 lemma nat_mult_1_right: "n * (1::nat) = n"
   750   by simp
   751 
   752 
   753 subsection {* Additional theorems about "less than" *}
   754 
   755 text {* A [clumsy] way of lifting @{text "<"}
   756   monotonicity to @{text "\<le>"} monotonicity *}
   757 lemma less_mono_imp_le_mono:
   758   assumes lt_mono: "!!i j::nat. i < j ==> f i < f j"
   759   and le: "i \<le> j" shows "f i \<le> ((f j)::nat)" using le
   760   apply (simp add: order_le_less)
   761   apply (blast intro!: lt_mono)
   762   done
   763 
   764 text {* non-strict, in 1st argument *}
   765 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   766   by (rule add_right_mono)
   767 
   768 text {* non-strict, in both arguments *}
   769 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   770   by (rule add_mono)
   771 
   772 lemma le_add2: "n \<le> ((m + n)::nat)"
   773   by (insert add_right_mono [of 0 m n], simp) 
   774 
   775 lemma le_add1: "n \<le> ((n + m)::nat)"
   776   by (simp add: add_commute, rule le_add2)
   777 
   778 lemma less_add_Suc1: "i < Suc (i + m)"
   779   by (rule le_less_trans, rule le_add1, rule lessI)
   780 
   781 lemma less_add_Suc2: "i < Suc (m + i)"
   782   by (rule le_less_trans, rule le_add2, rule lessI)
   783 
   784 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   785   by (rules intro!: less_add_Suc1 less_imp_Suc_add)
   786 
   787 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   788   by (rule le_trans, assumption, rule le_add1)
   789 
   790 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   791   by (rule le_trans, assumption, rule le_add2)
   792 
   793 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   794   by (rule less_le_trans, assumption, rule le_add1)
   795 
   796 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   797   by (rule less_le_trans, assumption, rule le_add2)
   798 
   799 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   800   apply (rule le_less_trans [of _ "i+j"]) 
   801   apply (simp_all add: le_add1)
   802   done
   803 
   804 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   805   apply (rule notI)
   806   apply (erule add_lessD1 [THEN less_irrefl])
   807   done
   808 
   809 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   810   by (simp add: add_commute not_add_less1)
   811 
   812 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   813   apply (rule order_trans [of _ "m+k"]) 
   814   apply (simp_all add: le_add1)
   815   done
   816 
   817 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   818   apply (simp add: add_commute)
   819   apply (erule add_leD1)
   820   done
   821 
   822 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   823   by (blast dest: add_leD1 add_leD2)
   824 
   825 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   826 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   827   by (force simp del: add_Suc_right
   828     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   829 
   830 
   831 
   832 subsection {* Difference *}
   833 
   834 lemma diff_self_eq_0 [simp]: "(m::nat) - m = 0"
   835   by (induct m) simp_all
   836 
   837 text {* Addition is the inverse of subtraction:
   838   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   839 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   840   by (induct m n rule: diff_induct) simp_all
   841 
   842 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   843   by (simp add: add_diff_inverse not_less_iff_le)
   844 
   845 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   846   by (simp add: le_add_diff_inverse add_commute)
   847 
   848 
   849 subsection {* More results about difference *}
   850 
   851 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   852   by (induct m n rule: diff_induct) simp_all
   853 
   854 lemma diff_less_Suc: "m - n < Suc m"
   855   apply (induct m n rule: diff_induct)
   856   apply (erule_tac [3] less_SucE)
   857   apply (simp_all add: less_Suc_eq)
   858   done
   859 
   860 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   861   by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   862 
   863 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   864   by (rule le_less_trans, rule diff_le_self)
   865 
   866 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   867   by (induct i j rule: diff_induct) simp_all
   868 
   869 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   870   by (simp add: diff_diff_left)
   871 
   872 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   873   apply (case_tac "n", safe)
   874   apply (simp add: le_simps)
   875   done
   876 
   877 text {* This and the next few suggested by Florian Kammueller *}
   878 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   879   by (simp add: diff_diff_left add_commute)
   880 
   881 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   882   by (induct j k rule: diff_induct) simp_all
   883 
   884 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   885   by (simp add: add_commute diff_add_assoc)
   886 
   887 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   888   by (induct n) simp_all
   889 
   890 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   891   by (simp add: diff_add_assoc)
   892 
   893 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   894   apply safe
   895   apply (simp_all add: diff_add_inverse2)
   896   done
   897 
   898 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   899   by (induct m n rule: diff_induct) simp_all
   900 
   901 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   902   by (rule iffD2, rule diff_is_0_eq)
   903 
   904 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
   905   by (induct m n rule: diff_induct) simp_all
   906 
   907 lemma less_imp_add_positive: "i < j  ==> \<exists>k::nat. 0 < k & i + k = j"
   908   apply (rule_tac x = "j - i" in exI)
   909   apply (simp (no_asm_simp) add: add_diff_inverse less_not_sym)
   910   done
   911 
   912 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
   913   apply (induct k i rule: diff_induct)
   914   apply (simp_all (no_asm))
   915   apply rules
   916   done
   917 
   918 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
   919   apply (rule diff_self_eq_0 [THEN subst])
   920   apply (rule zero_induct_lemma, rules+)
   921   done
   922 
   923 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   924   by (induct k) simp_all
   925 
   926 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   927   by (simp add: diff_cancel add_commute)
   928 
   929 lemma diff_add_0: "n - (n + m) = (0::nat)"
   930   by (induct n) simp_all
   931 
   932 
   933 text {* Difference distributes over multiplication *}
   934 
   935 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   936   by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   937 
   938 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   939   by (simp add: diff_mult_distrib mult_commute [of k])
   940   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   941 
   942 lemmas nat_distrib =
   943   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   944 
   945 
   946 subsection {* Monotonicity of Multiplication *}
   947 
   948 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
   949   by (simp add: mult_right_mono) 
   950 
   951 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
   952   by (simp add: mult_left_mono) 
   953 
   954 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
   955 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
   956   by (simp add: mult_mono) 
   957 
   958 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
   959   by (simp add: mult_strict_right_mono) 
   960 
   961 text{*Differs from the standard @{text zero_less_mult_iff} in that
   962       there are no negative numbers.*}
   963 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
   964   apply (induct m)
   965   apply (case_tac [2] n, simp_all)
   966   done
   967 
   968 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
   969   apply (induct m)
   970   apply (case_tac [2] n, simp_all)
   971   done
   972 
   973 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   974   apply (induct m, simp)
   975   apply (induct n, simp, fastsimp)
   976   done
   977 
   978 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   979   apply (rule trans)
   980   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   981   done
   982 
   983 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
   984   apply (safe intro!: mult_less_mono1)
   985   apply (case_tac k, auto)
   986   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
   987   apply (blast intro: mult_le_mono1)
   988   done
   989 
   990 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
   991   by (simp add: mult_commute [of k])
   992 
   993 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
   994 by (simp add: linorder_not_less [symmetric], auto)
   995 
   996 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
   997 by (simp add: linorder_not_less [symmetric], auto)
   998 
   999 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
  1000   apply (cut_tac less_linear, safe, auto)
  1001   apply (drule mult_less_mono1, assumption, simp)+
  1002   done
  1003 
  1004 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
  1005   by (simp add: mult_commute [of k])
  1006 
  1007 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1008   by (subst mult_less_cancel1) simp
  1009 
  1010 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1011   by (subst mult_le_cancel1) simp
  1012 
  1013 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
  1014   by (subst mult_cancel1) simp
  1015 
  1016 text {* Lemma for @{text gcd} *}
  1017 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1018   apply (drule sym)
  1019   apply (rule disjCI)
  1020   apply (rule nat_less_cases, erule_tac [2] _)
  1021   apply (fastsimp elim!: less_SucE)
  1022   apply (fastsimp dest: mult_less_mono2)
  1023   done
  1024 
  1025 
  1026 end