src/HOL/Ring_and_Field.thy
author webertj
Mon Mar 07 19:30:53 2005 +0100 (2005-03-07)
changeset 15584 3478bb4f93ff
parent 15580 900291ee0af8
child 15769 38c8ea8521e7
permissions -rw-r--r--
refute_params: default value itself=1 added (for type classes)
     1 (*  Title:   HOL/Ring_and_Field.thy
     2     ID:      $Id$
     3     Author:  Gertrud Bauer, Steven Obua, Lawrence C Paulson and Markus Wenzel
     4 *)
     5 
     6 header {* (Ordered) Rings and Fields *}
     7 
     8 theory Ring_and_Field
     9 imports OrderedGroup
    10 begin
    11 
    12 text {*
    13   The theory of partially ordered rings is taken from the books:
    14   \begin{itemize}
    15   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
    16   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
    17   \end{itemize}
    18   Most of the used notions can also be looked up in 
    19   \begin{itemize}
    20   \item \url{http://www.mathworld.com} by Eric Weisstein et. al.
    21   \item \emph{Algebra I} by van der Waerden, Springer.
    22   \end{itemize}
    23 *}
    24 
    25 axclass semiring \<subseteq> ab_semigroup_add, semigroup_mult
    26   left_distrib: "(a + b) * c = a * c + b * c"
    27   right_distrib: "a * (b + c) = a * b + a * c"
    28 
    29 axclass semiring_0 \<subseteq> semiring, comm_monoid_add
    30 
    31 axclass semiring_0_cancel \<subseteq> semiring_0, cancel_ab_semigroup_add
    32 
    33 axclass comm_semiring \<subseteq> ab_semigroup_add, ab_semigroup_mult  
    34   mult_commute: "a * b = b * a"
    35   distrib: "(a + b) * c = a * c + b * c"
    36 
    37 instance comm_semiring \<subseteq> semiring
    38 proof
    39   fix a b c :: 'a
    40   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    41   have "a * (b + c) = (b + c) * a" by (simp add: mult_ac)
    42   also have "... = b * a + c * a" by (simp only: distrib)
    43   also have "... = a * b + a * c" by (simp add: mult_ac)
    44   finally show "a * (b + c) = a * b + a * c" by blast
    45 qed
    46 
    47 axclass comm_semiring_0 \<subseteq> comm_semiring, comm_monoid_add
    48 
    49 instance comm_semiring_0 \<subseteq> semiring_0 ..
    50 
    51 axclass comm_semiring_0_cancel \<subseteq> comm_semiring_0, cancel_ab_semigroup_add
    52 
    53 instance comm_semiring_0_cancel \<subseteq> semiring_0_cancel ..
    54 
    55 axclass axclass_0_neq_1 \<subseteq> zero, one
    56   zero_neq_one [simp]: "0 \<noteq> 1"
    57 
    58 axclass semiring_1 \<subseteq> axclass_0_neq_1, semiring_0, monoid_mult
    59 
    60 axclass comm_semiring_1 \<subseteq> axclass_0_neq_1, comm_semiring_0, comm_monoid_mult (* previously almost_semiring *)
    61 
    62 instance comm_semiring_1 \<subseteq> semiring_1 ..
    63 
    64 axclass axclass_no_zero_divisors \<subseteq> zero, times
    65   no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
    66 
    67 axclass semiring_1_cancel \<subseteq> semiring_1, cancel_ab_semigroup_add
    68 
    69 instance semiring_1_cancel \<subseteq> semiring_0_cancel ..
    70 
    71 axclass comm_semiring_1_cancel \<subseteq> comm_semiring_1, cancel_ab_semigroup_add (* previously semiring *)
    72 
    73 instance comm_semiring_1_cancel \<subseteq> semiring_1_cancel ..
    74 
    75 instance comm_semiring_1_cancel \<subseteq> comm_semiring_0_cancel ..
    76 
    77 axclass ring \<subseteq> semiring, ab_group_add
    78 
    79 instance ring \<subseteq> semiring_0_cancel ..
    80 
    81 axclass comm_ring \<subseteq> comm_semiring_0, ab_group_add
    82 
    83 instance comm_ring \<subseteq> ring ..
    84 
    85 instance comm_ring \<subseteq> comm_semiring_0_cancel ..
    86 
    87 axclass ring_1 \<subseteq> ring, semiring_1
    88 
    89 instance ring_1 \<subseteq> semiring_1_cancel ..
    90 
    91 axclass comm_ring_1 \<subseteq> comm_ring, comm_semiring_1 (* previously ring *)
    92 
    93 instance comm_ring_1 \<subseteq> ring_1 ..
    94 
    95 instance comm_ring_1 \<subseteq> comm_semiring_1_cancel ..
    96 
    97 axclass idom \<subseteq> comm_ring_1, axclass_no_zero_divisors
    98 
    99 axclass field \<subseteq> comm_ring_1, inverse
   100   left_inverse [simp]: "a \<noteq> 0 ==> inverse a * a = 1"
   101   divide_inverse:      "a / b = a * inverse b"
   102 
   103 lemma mult_zero_left [simp]: "0 * a = (0::'a::semiring_0_cancel)"
   104 proof -
   105   have "0*a + 0*a = 0*a + 0"
   106     by (simp add: left_distrib [symmetric])
   107   thus ?thesis 
   108     by (simp only: add_left_cancel)
   109 qed
   110 
   111 lemma mult_zero_right [simp]: "a * 0 = (0::'a::semiring_0_cancel)"
   112 proof -
   113   have "a*0 + a*0 = a*0 + 0"
   114     by (simp add: right_distrib [symmetric])
   115   thus ?thesis 
   116     by (simp only: add_left_cancel)
   117 qed
   118 
   119 lemma field_mult_eq_0_iff [simp]: "(a*b = (0::'a::field)) = (a = 0 | b = 0)"
   120 proof cases
   121   assume "a=0" thus ?thesis by simp
   122 next
   123   assume anz [simp]: "a\<noteq>0"
   124   { assume "a * b = 0"
   125     hence "inverse a * (a * b) = 0" by simp
   126     hence "b = 0"  by (simp (no_asm_use) add: mult_assoc [symmetric])}
   127   thus ?thesis by force
   128 qed
   129 
   130 instance field \<subseteq> idom
   131 by (intro_classes, simp)
   132   
   133 axclass division_by_zero \<subseteq> zero, inverse
   134   inverse_zero [simp]: "inverse 0 = 0"
   135 
   136 subsection {* Distribution rules *}
   137 
   138 theorems ring_distrib = right_distrib left_distrib
   139 
   140 text{*For the @{text combine_numerals} simproc*}
   141 lemma combine_common_factor:
   142      "a*e + (b*e + c) = (a+b)*e + (c::'a::semiring)"
   143 by (simp add: left_distrib add_ac)
   144 
   145 lemma minus_mult_left: "- (a * b) = (-a) * (b::'a::ring)"
   146 apply (rule equals_zero_I)
   147 apply (simp add: left_distrib [symmetric]) 
   148 done
   149 
   150 lemma minus_mult_right: "- (a * b) = a * -(b::'a::ring)"
   151 apply (rule equals_zero_I)
   152 apply (simp add: right_distrib [symmetric]) 
   153 done
   154 
   155 lemma minus_mult_minus [simp]: "(- a) * (- b) = a * (b::'a::ring)"
   156   by (simp add: minus_mult_left [symmetric] minus_mult_right [symmetric])
   157 
   158 lemma minus_mult_commute: "(- a) * b = a * (- b::'a::ring)"
   159   by (simp add: minus_mult_left [symmetric] minus_mult_right [symmetric])
   160 
   161 lemma right_diff_distrib: "a * (b - c) = a * b - a * (c::'a::ring)"
   162 by (simp add: right_distrib diff_minus 
   163               minus_mult_left [symmetric] minus_mult_right [symmetric]) 
   164 
   165 lemma left_diff_distrib: "(a - b) * c = a * c - b * (c::'a::ring)"
   166 by (simp add: left_distrib diff_minus 
   167               minus_mult_left [symmetric] minus_mult_right [symmetric]) 
   168 
   169 axclass pordered_semiring \<subseteq> semiring_0, pordered_ab_semigroup_add 
   170   mult_left_mono: "a <= b \<Longrightarrow> 0 <= c \<Longrightarrow> c * a <= c * b"
   171   mult_right_mono: "a <= b \<Longrightarrow> 0 <= c \<Longrightarrow> a * c <= b * c"
   172 
   173 axclass pordered_cancel_semiring \<subseteq> pordered_semiring, cancel_ab_semigroup_add
   174 
   175 instance pordered_cancel_semiring \<subseteq> semiring_0_cancel ..
   176 
   177 axclass ordered_semiring_strict \<subseteq> semiring_0, ordered_cancel_ab_semigroup_add
   178   mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   179   mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   180 
   181 instance ordered_semiring_strict \<subseteq> semiring_0_cancel ..
   182 
   183 instance ordered_semiring_strict \<subseteq> pordered_cancel_semiring
   184 apply intro_classes
   185 apply (case_tac "a < b & 0 < c")
   186 apply (auto simp add: mult_strict_left_mono order_less_le)
   187 apply (auto simp add: mult_strict_left_mono order_le_less)
   188 apply (simp add: mult_strict_right_mono)
   189 done
   190 
   191 axclass pordered_comm_semiring \<subseteq> comm_semiring_0, pordered_ab_semigroup_add
   192   mult_mono: "a <= b \<Longrightarrow> 0 <= c \<Longrightarrow> c * a <= c * b"
   193 
   194 axclass pordered_cancel_comm_semiring \<subseteq> pordered_comm_semiring, cancel_ab_semigroup_add
   195 
   196 instance pordered_cancel_comm_semiring \<subseteq> pordered_comm_semiring ..
   197 
   198 axclass ordered_comm_semiring_strict \<subseteq> comm_semiring_0, ordered_cancel_ab_semigroup_add
   199   mult_strict_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   200 
   201 instance pordered_comm_semiring \<subseteq> pordered_semiring
   202 by (intro_classes, insert mult_mono, simp_all add: mult_commute, blast+)
   203 
   204 instance pordered_cancel_comm_semiring \<subseteq> pordered_cancel_semiring ..
   205 
   206 instance ordered_comm_semiring_strict \<subseteq> ordered_semiring_strict
   207 by (intro_classes, insert mult_strict_mono, simp_all add: mult_commute, blast+)
   208 
   209 instance ordered_comm_semiring_strict \<subseteq> pordered_cancel_comm_semiring
   210 apply (intro_classes)
   211 apply (case_tac "a < b & 0 < c")
   212 apply (auto simp add: mult_strict_left_mono order_less_le)
   213 apply (auto simp add: mult_strict_left_mono order_le_less)
   214 done
   215 
   216 axclass pordered_ring \<subseteq> ring, pordered_semiring 
   217 
   218 instance pordered_ring \<subseteq> pordered_ab_group_add ..
   219 
   220 instance pordered_ring \<subseteq> pordered_cancel_semiring ..
   221 
   222 axclass lordered_ring \<subseteq> pordered_ring, lordered_ab_group_abs
   223 
   224 instance lordered_ring \<subseteq> lordered_ab_group_meet ..
   225 
   226 instance lordered_ring \<subseteq> lordered_ab_group_join ..
   227 
   228 axclass axclass_abs_if \<subseteq> minus, ord, zero
   229   abs_if: "abs a = (if (a < 0) then (-a) else a)"
   230 
   231 axclass ordered_ring_strict \<subseteq> ring, ordered_semiring_strict, axclass_abs_if
   232 
   233 instance ordered_ring_strict \<subseteq> lordered_ab_group ..
   234 
   235 instance ordered_ring_strict \<subseteq> lordered_ring
   236 by (intro_classes, simp add: abs_if join_eq_if)
   237 
   238 axclass pordered_comm_ring \<subseteq> comm_ring, pordered_comm_semiring
   239 
   240 axclass ordered_semidom \<subseteq> comm_semiring_1_cancel, ordered_comm_semiring_strict (* previously ordered_semiring *)
   241   zero_less_one [simp]: "0 < 1"
   242 
   243 axclass ordered_idom \<subseteq> comm_ring_1, ordered_comm_semiring_strict, axclass_abs_if (* previously ordered_ring *)
   244 
   245 instance ordered_idom \<subseteq> ordered_ring_strict ..
   246 
   247 axclass ordered_field \<subseteq> field, ordered_idom
   248 
   249 lemma eq_add_iff1:
   250      "(a*e + c = b*e + d) = ((a-b)*e + c = (d::'a::ring))"
   251 apply (simp add: diff_minus left_distrib)
   252 apply (simp add: diff_minus left_distrib add_ac)
   253 apply (simp add: compare_rls minus_mult_left [symmetric])
   254 done
   255 
   256 lemma eq_add_iff2:
   257      "(a*e + c = b*e + d) = (c = (b-a)*e + (d::'a::ring))"
   258 apply (simp add: diff_minus left_distrib add_ac)
   259 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   260 done
   261 
   262 lemma less_add_iff1:
   263      "(a*e + c < b*e + d) = ((a-b)*e + c < (d::'a::pordered_ring))"
   264 apply (simp add: diff_minus left_distrib add_ac)
   265 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   266 done
   267 
   268 lemma less_add_iff2:
   269      "(a*e + c < b*e + d) = (c < (b-a)*e + (d::'a::pordered_ring))"
   270 apply (simp add: diff_minus left_distrib add_ac)
   271 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   272 done
   273 
   274 lemma le_add_iff1:
   275      "(a*e + c \<le> b*e + d) = ((a-b)*e + c \<le> (d::'a::pordered_ring))"
   276 apply (simp add: diff_minus left_distrib add_ac)
   277 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   278 done
   279 
   280 lemma le_add_iff2:
   281      "(a*e + c \<le> b*e + d) = (c \<le> (b-a)*e + (d::'a::pordered_ring))"
   282 apply (simp add: diff_minus left_distrib add_ac)
   283 apply (simp add: compare_rls minus_mult_left [symmetric]) 
   284 done
   285 
   286 subsection {* Ordering Rules for Multiplication *}
   287 
   288 lemma mult_left_le_imp_le:
   289      "[|c*a \<le> c*b; 0 < c|] ==> a \<le> (b::'a::ordered_semiring_strict)"
   290   by (force simp add: mult_strict_left_mono linorder_not_less [symmetric])
   291  
   292 lemma mult_right_le_imp_le:
   293      "[|a*c \<le> b*c; 0 < c|] ==> a \<le> (b::'a::ordered_semiring_strict)"
   294   by (force simp add: mult_strict_right_mono linorder_not_less [symmetric])
   295 
   296 lemma mult_left_less_imp_less:
   297      "[|c*a < c*b; 0 \<le> c|] ==> a < (b::'a::ordered_semiring_strict)"
   298   by (force simp add: mult_left_mono linorder_not_le [symmetric])
   299  
   300 lemma mult_right_less_imp_less:
   301      "[|a*c < b*c; 0 \<le> c|] ==> a < (b::'a::ordered_semiring_strict)"
   302   by (force simp add: mult_right_mono linorder_not_le [symmetric])
   303 
   304 lemma mult_strict_left_mono_neg:
   305      "[|b < a; c < 0|] ==> c * a < c * (b::'a::ordered_ring_strict)"
   306 apply (drule mult_strict_left_mono [of _ _ "-c"])
   307 apply (simp_all add: minus_mult_left [symmetric]) 
   308 done
   309 
   310 lemma mult_left_mono_neg:
   311      "[|b \<le> a; c \<le> 0|] ==> c * a \<le>  c * (b::'a::pordered_ring)"
   312 apply (drule mult_left_mono [of _ _ "-c"])
   313 apply (simp_all add: minus_mult_left [symmetric]) 
   314 done
   315 
   316 lemma mult_strict_right_mono_neg:
   317      "[|b < a; c < 0|] ==> a * c < b * (c::'a::ordered_ring_strict)"
   318 apply (drule mult_strict_right_mono [of _ _ "-c"])
   319 apply (simp_all add: minus_mult_right [symmetric]) 
   320 done
   321 
   322 lemma mult_right_mono_neg:
   323      "[|b \<le> a; c \<le> 0|] ==> a * c \<le>  (b::'a::pordered_ring) * c"
   324 apply (drule mult_right_mono [of _ _ "-c"])
   325 apply (simp)
   326 apply (simp_all add: minus_mult_right [symmetric]) 
   327 done
   328 
   329 subsection{* Products of Signs *}
   330 
   331 lemma mult_pos: "[| (0::'a::ordered_semiring_strict) < a; 0 < b |] ==> 0 < a*b"
   332 by (drule mult_strict_left_mono [of 0 b], auto)
   333 
   334 lemma mult_pos_le: "[| (0::'a::pordered_cancel_semiring) \<le> a; 0 \<le> b |] ==> 0 \<le> a*b"
   335 by (drule mult_left_mono [of 0 b], auto)
   336 
   337 lemma mult_pos_neg: "[| (0::'a::ordered_semiring_strict) < a; b < 0 |] ==> a*b < 0"
   338 by (drule mult_strict_left_mono [of b 0], auto)
   339 
   340 lemma mult_pos_neg_le: "[| (0::'a::pordered_cancel_semiring) \<le> a; b \<le> 0 |] ==> a*b \<le> 0"
   341 by (drule mult_left_mono [of b 0], auto)
   342 
   343 lemma mult_pos_neg2: "[| (0::'a::ordered_semiring_strict) < a; b < 0 |] ==> b*a < 0" 
   344 by (drule mult_strict_right_mono[of b 0], auto)
   345 
   346 lemma mult_pos_neg2_le: "[| (0::'a::pordered_cancel_semiring) \<le> a; b \<le> 0 |] ==> b*a \<le> 0" 
   347 by (drule mult_right_mono[of b 0], auto)
   348 
   349 lemma mult_neg: "[| a < (0::'a::ordered_ring_strict); b < 0 |] ==> 0 < a*b"
   350 by (drule mult_strict_right_mono_neg, auto)
   351 
   352 lemma mult_neg_le: "[| a \<le> (0::'a::pordered_ring); b \<le> 0 |] ==> 0 \<le> a*b"
   353 by (drule mult_right_mono_neg[of a 0 b ], auto)
   354 
   355 lemma zero_less_mult_pos:
   356      "[| 0 < a*b; 0 < a|] ==> 0 < (b::'a::ordered_semiring_strict)"
   357 apply (case_tac "b\<le>0") 
   358  apply (auto simp add: order_le_less linorder_not_less)
   359 apply (drule_tac mult_pos_neg [of a b]) 
   360  apply (auto dest: order_less_not_sym)
   361 done
   362 
   363 lemma zero_less_mult_pos2:
   364      "[| 0 < b*a; 0 < a|] ==> 0 < (b::'a::ordered_semiring_strict)"
   365 apply (case_tac "b\<le>0") 
   366  apply (auto simp add: order_le_less linorder_not_less)
   367 apply (drule_tac mult_pos_neg2 [of a b]) 
   368  apply (auto dest: order_less_not_sym)
   369 done
   370 
   371 lemma zero_less_mult_iff:
   372      "((0::'a::ordered_ring_strict) < a*b) = (0 < a & 0 < b | a < 0 & b < 0)"
   373 apply (auto simp add: order_le_less linorder_not_less mult_pos mult_neg)
   374 apply (blast dest: zero_less_mult_pos) 
   375 apply (blast dest: zero_less_mult_pos2)
   376 done
   377 
   378 text{*A field has no "zero divisors", and this theorem holds without the
   379       assumption of an ordering.  See @{text field_mult_eq_0_iff} below.*}
   380 lemma mult_eq_0_iff [simp]: "(a*b = (0::'a::ordered_ring_strict)) = (a = 0 | b = 0)"
   381 apply (case_tac "a < 0")
   382 apply (auto simp add: linorder_not_less order_le_less linorder_neq_iff)
   383 apply (force dest: mult_strict_right_mono_neg mult_strict_right_mono)+
   384 done
   385 
   386 lemma zero_le_mult_iff:
   387      "((0::'a::ordered_ring_strict) \<le> a*b) = (0 \<le> a & 0 \<le> b | a \<le> 0 & b \<le> 0)"
   388 by (auto simp add: eq_commute [of 0] order_le_less linorder_not_less
   389                    zero_less_mult_iff)
   390 
   391 lemma mult_less_0_iff:
   392      "(a*b < (0::'a::ordered_ring_strict)) = (0 < a & b < 0 | a < 0 & 0 < b)"
   393 apply (insert zero_less_mult_iff [of "-a" b]) 
   394 apply (force simp add: minus_mult_left[symmetric]) 
   395 done
   396 
   397 lemma mult_le_0_iff:
   398      "(a*b \<le> (0::'a::ordered_ring_strict)) = (0 \<le> a & b \<le> 0 | a \<le> 0 & 0 \<le> b)"
   399 apply (insert zero_le_mult_iff [of "-a" b]) 
   400 apply (force simp add: minus_mult_left[symmetric]) 
   401 done
   402 
   403 lemma split_mult_pos_le: "(0 \<le> a & 0 \<le> b) | (a \<le> 0 & b \<le> 0) \<Longrightarrow> 0 \<le> a * (b::_::pordered_ring)"
   404 by (auto simp add: mult_pos_le mult_neg_le)
   405 
   406 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> (0::_::pordered_cancel_semiring)" 
   407 by (auto simp add: mult_pos_neg_le mult_pos_neg2_le)
   408 
   409 lemma zero_le_square: "(0::'a::ordered_ring_strict) \<le> a*a"
   410 by (simp add: zero_le_mult_iff linorder_linear) 
   411 
   412 text{*Proving axiom @{text zero_less_one} makes all @{text ordered_semidom}
   413       theorems available to members of @{term ordered_idom} *}
   414 
   415 instance ordered_idom \<subseteq> ordered_semidom
   416 proof
   417   have "(0::'a) \<le> 1*1" by (rule zero_le_square)
   418   thus "(0::'a) < 1" by (simp add: order_le_less) 
   419 qed
   420 
   421 instance ordered_ring_strict \<subseteq> axclass_no_zero_divisors 
   422 by (intro_classes, simp)
   423 
   424 instance ordered_idom \<subseteq> idom ..
   425 
   426 text{*All three types of comparision involving 0 and 1 are covered.*}
   427 
   428 declare zero_neq_one [THEN not_sym, simp]
   429 
   430 lemma zero_le_one [simp]: "(0::'a::ordered_semidom) \<le> 1"
   431   by (rule zero_less_one [THEN order_less_imp_le]) 
   432 
   433 lemma not_one_le_zero [simp]: "~ (1::'a::ordered_semidom) \<le> 0"
   434 by (simp add: linorder_not_le) 
   435 
   436 lemma not_one_less_zero [simp]: "~ (1::'a::ordered_semidom) < 0"
   437 by (simp add: linorder_not_less) 
   438 
   439 subsection{*More Monotonicity*}
   440 
   441 text{*Strict monotonicity in both arguments*}
   442 lemma mult_strict_mono:
   443      "[|a<b; c<d; 0<b; 0\<le>c|] ==> a * c < b * (d::'a::ordered_semiring_strict)"
   444 apply (case_tac "c=0")
   445  apply (simp add: mult_pos) 
   446 apply (erule mult_strict_right_mono [THEN order_less_trans])
   447  apply (force simp add: order_le_less) 
   448 apply (erule mult_strict_left_mono, assumption)
   449 done
   450 
   451 text{*This weaker variant has more natural premises*}
   452 lemma mult_strict_mono':
   453      "[| a<b; c<d; 0 \<le> a; 0 \<le> c|] ==> a * c < b * (d::'a::ordered_semiring_strict)"
   454 apply (rule mult_strict_mono)
   455 apply (blast intro: order_le_less_trans)+
   456 done
   457 
   458 lemma mult_mono:
   459      "[|a \<le> b; c \<le> d; 0 \<le> b; 0 \<le> c|] 
   460       ==> a * c  \<le>  b * (d::'a::pordered_semiring)"
   461 apply (erule mult_right_mono [THEN order_trans], assumption)
   462 apply (erule mult_left_mono, assumption)
   463 done
   464 
   465 lemma less_1_mult: "[| 1 < m; 1 < n |] ==> 1 < m*(n::'a::ordered_semidom)"
   466 apply (insert mult_strict_mono [of 1 m 1 n]) 
   467 apply (simp add:  order_less_trans [OF zero_less_one]) 
   468 done
   469 
   470 subsection{*Cancellation Laws for Relationships With a Common Factor*}
   471 
   472 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   473    also with the relations @{text "\<le>"} and equality.*}
   474 
   475 text{*These ``disjunction'' versions produce two cases when the comparison is
   476  an assumption, but effectively four when the comparison is a goal.*}
   477 
   478 lemma mult_less_cancel_right_disj:
   479     "(a*c < b*c) = ((0 < c & a < b) | (c < 0 & b < (a::'a::ordered_ring_strict)))"
   480 apply (case_tac "c = 0")
   481 apply (auto simp add: linorder_neq_iff mult_strict_right_mono 
   482                       mult_strict_right_mono_neg)
   483 apply (auto simp add: linorder_not_less 
   484                       linorder_not_le [symmetric, of "a*c"]
   485                       linorder_not_le [symmetric, of a])
   486 apply (erule_tac [!] notE)
   487 apply (auto simp add: order_less_imp_le mult_right_mono 
   488                       mult_right_mono_neg)
   489 done
   490 
   491 lemma mult_less_cancel_left_disj:
   492     "(c*a < c*b) = ((0 < c & a < b) | (c < 0 & b < (a::'a::ordered_ring_strict)))"
   493 apply (case_tac "c = 0")
   494 apply (auto simp add: linorder_neq_iff mult_strict_left_mono 
   495                       mult_strict_left_mono_neg)
   496 apply (auto simp add: linorder_not_less 
   497                       linorder_not_le [symmetric, of "c*a"]
   498                       linorder_not_le [symmetric, of a])
   499 apply (erule_tac [!] notE)
   500 apply (auto simp add: order_less_imp_le mult_left_mono 
   501                       mult_left_mono_neg)
   502 done
   503 
   504 
   505 text{*The ``conjunction of implication'' lemmas produce two cases when the
   506 comparison is a goal, but give four when the comparison is an assumption.*}
   507 
   508 lemma mult_less_cancel_right:
   509   fixes c :: "'a :: ordered_ring_strict"
   510   shows      "(a*c < b*c) = ((0 \<le> c --> a < b) & (c \<le> 0 --> b < a))"
   511 by (insert mult_less_cancel_right_disj [of a c b], auto)
   512 
   513 lemma mult_less_cancel_left:
   514   fixes c :: "'a :: ordered_ring_strict"
   515   shows      "(c*a < c*b) = ((0 \<le> c --> a < b) & (c \<le> 0 --> b < a))"
   516 by (insert mult_less_cancel_left_disj [of c a b], auto)
   517 
   518 lemma mult_le_cancel_right:
   519      "(a*c \<le> b*c) = ((0<c --> a\<le>b) & (c<0 --> b \<le> (a::'a::ordered_ring_strict)))"
   520 by (simp add: linorder_not_less [symmetric] mult_less_cancel_right_disj)
   521 
   522 lemma mult_le_cancel_left:
   523      "(c*a \<le> c*b) = ((0<c --> a\<le>b) & (c<0 --> b \<le> (a::'a::ordered_ring_strict)))"
   524 by (simp add: linorder_not_less [symmetric] mult_less_cancel_left_disj)
   525 
   526 lemma mult_less_imp_less_left:
   527       assumes less: "c*a < c*b" and nonneg: "0 \<le> c"
   528       shows "a < (b::'a::ordered_semiring_strict)"
   529 proof (rule ccontr)
   530   assume "~ a < b"
   531   hence "b \<le> a" by (simp add: linorder_not_less)
   532   hence "c*b \<le> c*a" by (rule mult_left_mono)
   533   with this and less show False 
   534     by (simp add: linorder_not_less [symmetric])
   535 qed
   536 
   537 lemma mult_less_imp_less_right:
   538   assumes less: "a*c < b*c" and nonneg: "0 <= c"
   539   shows "a < (b::'a::ordered_semiring_strict)"
   540 proof (rule ccontr)
   541   assume "~ a < b"
   542   hence "b \<le> a" by (simp add: linorder_not_less)
   543   hence "b*c \<le> a*c" by (rule mult_right_mono)
   544   with this and less show False 
   545     by (simp add: linorder_not_less [symmetric])
   546 qed  
   547 
   548 text{*Cancellation of equalities with a common factor*}
   549 lemma mult_cancel_right [simp]:
   550      "(a*c = b*c) = (c = (0::'a::ordered_ring_strict) | a=b)"
   551 apply (cut_tac linorder_less_linear [of 0 c])
   552 apply (force dest: mult_strict_right_mono_neg mult_strict_right_mono
   553              simp add: linorder_neq_iff)
   554 done
   555 
   556 text{*These cancellation theorems require an ordering. Versions are proved
   557       below that work for fields without an ordering.*}
   558 lemma mult_cancel_left [simp]:
   559      "(c*a = c*b) = (c = (0::'a::ordered_ring_strict) | a=b)"
   560 apply (cut_tac linorder_less_linear [of 0 c])
   561 apply (force dest: mult_strict_left_mono_neg mult_strict_left_mono
   562              simp add: linorder_neq_iff)
   563 done
   564 
   565 
   566 subsubsection{*Special Cancellation Simprules for Multiplication*}
   567 
   568 text{*These also produce two cases when the comparison is a goal.*}
   569 
   570 lemma mult_le_cancel_right1:
   571   fixes c :: "'a :: ordered_idom"
   572   shows "(c \<le> b*c) = ((0<c --> 1\<le>b) & (c<0 --> b \<le> 1))"
   573 by (insert mult_le_cancel_right [of 1 c b], simp)
   574 
   575 lemma mult_le_cancel_right2:
   576   fixes c :: "'a :: ordered_idom"
   577   shows "(a*c \<le> c) = ((0<c --> a\<le>1) & (c<0 --> 1 \<le> a))"
   578 by (insert mult_le_cancel_right [of a c 1], simp)
   579 
   580 lemma mult_le_cancel_left1:
   581   fixes c :: "'a :: ordered_idom"
   582   shows "(c \<le> c*b) = ((0<c --> 1\<le>b) & (c<0 --> b \<le> 1))"
   583 by (insert mult_le_cancel_left [of c 1 b], simp)
   584 
   585 lemma mult_le_cancel_left2:
   586   fixes c :: "'a :: ordered_idom"
   587   shows "(c*a \<le> c) = ((0<c --> a\<le>1) & (c<0 --> 1 \<le> a))"
   588 by (insert mult_le_cancel_left [of c a 1], simp)
   589 
   590 lemma mult_less_cancel_right1:
   591   fixes c :: "'a :: ordered_idom"
   592   shows "(c < b*c) = ((0 \<le> c --> 1<b) & (c \<le> 0 --> b < 1))"
   593 by (insert mult_less_cancel_right [of 1 c b], simp)
   594 
   595 lemma mult_less_cancel_right2:
   596   fixes c :: "'a :: ordered_idom"
   597   shows "(a*c < c) = ((0 \<le> c --> a<1) & (c \<le> 0 --> 1 < a))"
   598 by (insert mult_less_cancel_right [of a c 1], simp)
   599 
   600 lemma mult_less_cancel_left1:
   601   fixes c :: "'a :: ordered_idom"
   602   shows "(c < c*b) = ((0 \<le> c --> 1<b) & (c \<le> 0 --> b < 1))"
   603 by (insert mult_less_cancel_left [of c 1 b], simp)
   604 
   605 lemma mult_less_cancel_left2:
   606   fixes c :: "'a :: ordered_idom"
   607   shows "(c*a < c) = ((0 \<le> c --> a<1) & (c \<le> 0 --> 1 < a))"
   608 by (insert mult_less_cancel_left [of c a 1], simp)
   609 
   610 lemma mult_cancel_right1 [simp]:
   611 fixes c :: "'a :: ordered_idom"
   612   shows "(c = b*c) = (c = 0 | b=1)"
   613 by (insert mult_cancel_right [of 1 c b], force)
   614 
   615 lemma mult_cancel_right2 [simp]:
   616 fixes c :: "'a :: ordered_idom"
   617   shows "(a*c = c) = (c = 0 | a=1)"
   618 by (insert mult_cancel_right [of a c 1], simp)
   619  
   620 lemma mult_cancel_left1 [simp]:
   621 fixes c :: "'a :: ordered_idom"
   622   shows "(c = c*b) = (c = 0 | b=1)"
   623 by (insert mult_cancel_left [of c 1 b], force)
   624 
   625 lemma mult_cancel_left2 [simp]:
   626 fixes c :: "'a :: ordered_idom"
   627   shows "(c*a = c) = (c = 0 | a=1)"
   628 by (insert mult_cancel_left [of c a 1], simp)
   629 
   630 
   631 text{*Simprules for comparisons where common factors can be cancelled.*}
   632 lemmas mult_compare_simps =
   633     mult_le_cancel_right mult_le_cancel_left
   634     mult_le_cancel_right1 mult_le_cancel_right2
   635     mult_le_cancel_left1 mult_le_cancel_left2
   636     mult_less_cancel_right mult_less_cancel_left
   637     mult_less_cancel_right1 mult_less_cancel_right2
   638     mult_less_cancel_left1 mult_less_cancel_left2
   639     mult_cancel_right mult_cancel_left
   640     mult_cancel_right1 mult_cancel_right2
   641     mult_cancel_left1 mult_cancel_left2
   642 
   643 
   644 text{*This list of rewrites decides ring equalities by ordered rewriting.*}
   645 lemmas ring_eq_simps =  
   646 (*  mult_ac*)
   647   left_distrib right_distrib left_diff_distrib right_diff_distrib
   648   group_eq_simps
   649 (*  add_ac
   650   add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   651   diff_eq_eq eq_diff_eq *)
   652     
   653 subsection {* Fields *}
   654 
   655 lemma right_inverse [simp]:
   656       assumes not0: "a \<noteq> 0" shows "a * inverse (a::'a::field) = 1"
   657 proof -
   658   have "a * inverse a = inverse a * a" by (simp add: mult_ac)
   659   also have "... = 1" using not0 by simp
   660   finally show ?thesis .
   661 qed
   662 
   663 lemma right_inverse_eq: "b \<noteq> 0 ==> (a / b = 1) = (a = (b::'a::field))"
   664 proof
   665   assume neq: "b \<noteq> 0"
   666   {
   667     hence "a = (a / b) * b" by (simp add: divide_inverse mult_ac)
   668     also assume "a / b = 1"
   669     finally show "a = b" by simp
   670   next
   671     assume "a = b"
   672     with neq show "a / b = 1" by (simp add: divide_inverse)
   673   }
   674 qed
   675 
   676 lemma nonzero_inverse_eq_divide: "a \<noteq> 0 ==> inverse (a::'a::field) = 1/a"
   677 by (simp add: divide_inverse)
   678 
   679 lemma divide_self: "a \<noteq> 0 ==> a / (a::'a::field) = 1"
   680   by (simp add: divide_inverse)
   681 
   682 lemma divide_zero [simp]: "a / 0 = (0::'a::{field,division_by_zero})"
   683 by (simp add: divide_inverse)
   684 
   685 lemma divide_self_if [simp]:
   686      "a / (a::'a::{field,division_by_zero}) = (if a=0 then 0 else 1)"
   687   by (simp add: divide_self)
   688 
   689 lemma divide_zero_left [simp]: "0/a = (0::'a::field)"
   690 by (simp add: divide_inverse)
   691 
   692 lemma inverse_eq_divide: "inverse (a::'a::field) = 1/a"
   693 by (simp add: divide_inverse)
   694 
   695 lemma add_divide_distrib: "(a+b)/(c::'a::field) = a/c + b/c"
   696 by (simp add: divide_inverse left_distrib) 
   697 
   698 
   699 text{*Compared with @{text mult_eq_0_iff}, this version removes the requirement
   700       of an ordering.*}
   701 lemma field_mult_eq_0_iff [simp]: "(a*b = (0::'a::field)) = (a = 0 | b = 0)"
   702 proof cases
   703   assume "a=0" thus ?thesis by simp
   704 next
   705   assume anz [simp]: "a\<noteq>0"
   706   { assume "a * b = 0"
   707     hence "inverse a * (a * b) = 0" by simp
   708     hence "b = 0"  by (simp (no_asm_use) add: mult_assoc [symmetric])}
   709   thus ?thesis by force
   710 qed
   711 
   712 text{*Cancellation of equalities with a common factor*}
   713 lemma field_mult_cancel_right_lemma:
   714       assumes cnz: "c \<noteq> (0::'a::field)"
   715 	  and eq:  "a*c = b*c"
   716 	 shows "a=b"
   717 proof -
   718   have "(a * c) * inverse c = (b * c) * inverse c"
   719     by (simp add: eq)
   720   thus "a=b"
   721     by (simp add: mult_assoc cnz)
   722 qed
   723 
   724 lemma field_mult_cancel_right [simp]:
   725      "(a*c = b*c) = (c = (0::'a::field) | a=b)"
   726 proof cases
   727   assume "c=0" thus ?thesis by simp
   728 next
   729   assume "c\<noteq>0" 
   730   thus ?thesis by (force dest: field_mult_cancel_right_lemma)
   731 qed
   732 
   733 lemma field_mult_cancel_left [simp]:
   734      "(c*a = c*b) = (c = (0::'a::field) | a=b)"
   735   by (simp add: mult_commute [of c] field_mult_cancel_right) 
   736 
   737 lemma nonzero_imp_inverse_nonzero: "a \<noteq> 0 ==> inverse a \<noteq> (0::'a::field)"
   738 proof
   739   assume ianz: "inverse a = 0"
   740   assume "a \<noteq> 0"
   741   hence "1 = a * inverse a" by simp
   742   also have "... = 0" by (simp add: ianz)
   743   finally have "1 = (0::'a::field)" .
   744   thus False by (simp add: eq_commute)
   745 qed
   746 
   747 
   748 subsection{*Basic Properties of @{term inverse}*}
   749 
   750 lemma inverse_zero_imp_zero: "inverse a = 0 ==> a = (0::'a::field)"
   751 apply (rule ccontr) 
   752 apply (blast dest: nonzero_imp_inverse_nonzero) 
   753 done
   754 
   755 lemma inverse_nonzero_imp_nonzero:
   756    "inverse a = 0 ==> a = (0::'a::field)"
   757 apply (rule ccontr) 
   758 apply (blast dest: nonzero_imp_inverse_nonzero) 
   759 done
   760 
   761 lemma inverse_nonzero_iff_nonzero [simp]:
   762    "(inverse a = 0) = (a = (0::'a::{field,division_by_zero}))"
   763 by (force dest: inverse_nonzero_imp_nonzero) 
   764 
   765 lemma nonzero_inverse_minus_eq:
   766       assumes [simp]: "a\<noteq>0"  shows "inverse(-a) = -inverse(a::'a::field)"
   767 proof -
   768   have "-a * inverse (- a) = -a * - inverse a"
   769     by simp
   770   thus ?thesis 
   771     by (simp only: field_mult_cancel_left, simp)
   772 qed
   773 
   774 lemma inverse_minus_eq [simp]:
   775    "inverse(-a) = -inverse(a::'a::{field,division_by_zero})";
   776 proof cases
   777   assume "a=0" thus ?thesis by (simp add: inverse_zero)
   778 next
   779   assume "a\<noteq>0" 
   780   thus ?thesis by (simp add: nonzero_inverse_minus_eq)
   781 qed
   782 
   783 lemma nonzero_inverse_eq_imp_eq:
   784       assumes inveq: "inverse a = inverse b"
   785 	  and anz:  "a \<noteq> 0"
   786 	  and bnz:  "b \<noteq> 0"
   787 	 shows "a = (b::'a::field)"
   788 proof -
   789   have "a * inverse b = a * inverse a"
   790     by (simp add: inveq)
   791   hence "(a * inverse b) * b = (a * inverse a) * b"
   792     by simp
   793   thus "a = b"
   794     by (simp add: mult_assoc anz bnz)
   795 qed
   796 
   797 lemma inverse_eq_imp_eq:
   798      "inverse a = inverse b ==> a = (b::'a::{field,division_by_zero})"
   799 apply (case_tac "a=0 | b=0") 
   800  apply (force dest!: inverse_zero_imp_zero
   801               simp add: eq_commute [of "0::'a"])
   802 apply (force dest!: nonzero_inverse_eq_imp_eq) 
   803 done
   804 
   805 lemma inverse_eq_iff_eq [simp]:
   806      "(inverse a = inverse b) = (a = (b::'a::{field,division_by_zero}))"
   807 by (force dest!: inverse_eq_imp_eq) 
   808 
   809 lemma nonzero_inverse_inverse_eq:
   810       assumes [simp]: "a \<noteq> 0"  shows "inverse(inverse (a::'a::field)) = a"
   811   proof -
   812   have "(inverse (inverse a) * inverse a) * a = a" 
   813     by (simp add: nonzero_imp_inverse_nonzero)
   814   thus ?thesis
   815     by (simp add: mult_assoc)
   816   qed
   817 
   818 lemma inverse_inverse_eq [simp]:
   819      "inverse(inverse (a::'a::{field,division_by_zero})) = a"
   820   proof cases
   821     assume "a=0" thus ?thesis by simp
   822   next
   823     assume "a\<noteq>0" 
   824     thus ?thesis by (simp add: nonzero_inverse_inverse_eq)
   825   qed
   826 
   827 lemma inverse_1 [simp]: "inverse 1 = (1::'a::field)"
   828   proof -
   829   have "inverse 1 * 1 = (1::'a::field)" 
   830     by (rule left_inverse [OF zero_neq_one [symmetric]])
   831   thus ?thesis  by simp
   832   qed
   833 
   834 lemma inverse_unique: 
   835   assumes ab: "a*b = 1"
   836   shows "inverse a = (b::'a::field)"
   837 proof -
   838   have "a \<noteq> 0" using ab by auto
   839   moreover have "inverse a * (a * b) = inverse a" by (simp add: ab) 
   840   ultimately show ?thesis by (simp add: mult_assoc [symmetric]) 
   841 qed
   842 
   843 lemma nonzero_inverse_mult_distrib: 
   844       assumes anz: "a \<noteq> 0"
   845           and bnz: "b \<noteq> 0"
   846       shows "inverse(a*b) = inverse(b) * inverse(a::'a::field)"
   847   proof -
   848   have "inverse(a*b) * (a * b) * inverse(b) = inverse(b)" 
   849     by (simp add: field_mult_eq_0_iff anz bnz)
   850   hence "inverse(a*b) * a = inverse(b)" 
   851     by (simp add: mult_assoc bnz)
   852   hence "inverse(a*b) * a * inverse(a) = inverse(b) * inverse(a)" 
   853     by simp
   854   thus ?thesis
   855     by (simp add: mult_assoc anz)
   856   qed
   857 
   858 text{*This version builds in division by zero while also re-orienting
   859       the right-hand side.*}
   860 lemma inverse_mult_distrib [simp]:
   861      "inverse(a*b) = inverse(a) * inverse(b::'a::{field,division_by_zero})"
   862   proof cases
   863     assume "a \<noteq> 0 & b \<noteq> 0" 
   864     thus ?thesis  by (simp add: nonzero_inverse_mult_distrib mult_commute)
   865   next
   866     assume "~ (a \<noteq> 0 & b \<noteq> 0)" 
   867     thus ?thesis  by force
   868   qed
   869 
   870 text{*There is no slick version using division by zero.*}
   871 lemma inverse_add:
   872      "[|a \<noteq> 0;  b \<noteq> 0|]
   873       ==> inverse a + inverse b = (a+b) * inverse a * inverse (b::'a::field)"
   874 apply (simp add: left_distrib mult_assoc)
   875 apply (simp add: mult_commute [of "inverse a"]) 
   876 apply (simp add: mult_assoc [symmetric] add_commute)
   877 done
   878 
   879 lemma inverse_divide [simp]:
   880       "inverse (a/b) = b / (a::'a::{field,division_by_zero})"
   881   by (simp add: divide_inverse mult_commute)
   882 
   883 lemma nonzero_mult_divide_cancel_left:
   884   assumes [simp]: "b\<noteq>0" and [simp]: "c\<noteq>0" 
   885     shows "(c*a)/(c*b) = a/(b::'a::field)"
   886 proof -
   887   have "(c*a)/(c*b) = c * a * (inverse b * inverse c)"
   888     by (simp add: field_mult_eq_0_iff divide_inverse 
   889                   nonzero_inverse_mult_distrib)
   890   also have "... =  a * inverse b * (inverse c * c)"
   891     by (simp only: mult_ac)
   892   also have "... =  a * inverse b"
   893     by simp
   894     finally show ?thesis 
   895     by (simp add: divide_inverse)
   896 qed
   897 
   898 lemma mult_divide_cancel_left:
   899      "c\<noteq>0 ==> (c*a) / (c*b) = a / (b::'a::{field,division_by_zero})"
   900 apply (case_tac "b = 0")
   901 apply (simp_all add: nonzero_mult_divide_cancel_left)
   902 done
   903 
   904 lemma nonzero_mult_divide_cancel_right:
   905      "[|b\<noteq>0; c\<noteq>0|] ==> (a*c) / (b*c) = a/(b::'a::field)"
   906 by (simp add: mult_commute [of _ c] nonzero_mult_divide_cancel_left) 
   907 
   908 lemma mult_divide_cancel_right:
   909      "c\<noteq>0 ==> (a*c) / (b*c) = a / (b::'a::{field,division_by_zero})"
   910 apply (case_tac "b = 0")
   911 apply (simp_all add: nonzero_mult_divide_cancel_right)
   912 done
   913 
   914 (*For ExtractCommonTerm*)
   915 lemma mult_divide_cancel_eq_if:
   916      "(c*a) / (c*b) = 
   917       (if c=0 then 0 else a / (b::'a::{field,division_by_zero}))"
   918   by (simp add: mult_divide_cancel_left)
   919 
   920 lemma divide_1 [simp]: "a/1 = (a::'a::field)"
   921   by (simp add: divide_inverse)
   922 
   923 lemma times_divide_eq_right: "a * (b/c) = (a*b) / (c::'a::field)"
   924 by (simp add: divide_inverse mult_assoc)
   925 
   926 lemma times_divide_eq_left: "(b/c) * a = (b*a) / (c::'a::field)"
   927 by (simp add: divide_inverse mult_ac)
   928 
   929 lemma divide_divide_eq_right [simp]:
   930      "a / (b/c) = (a*c) / (b::'a::{field,division_by_zero})"
   931 by (simp add: divide_inverse mult_ac)
   932 
   933 lemma divide_divide_eq_left [simp]:
   934      "(a / b) / (c::'a::{field,division_by_zero}) = a / (b*c)"
   935 by (simp add: divide_inverse mult_assoc)
   936 
   937 
   938 subsubsection{*Special Cancellation Simprules for Division*}
   939 
   940 lemma mult_divide_cancel_left_if [simp]:
   941   fixes c :: "'a :: {field,division_by_zero}"
   942   shows "(c*a) / (c*b) = (if c=0 then 0 else a/b)"
   943 by (simp add: mult_divide_cancel_left)
   944 
   945 lemma mult_divide_cancel_right_if [simp]:
   946   fixes c :: "'a :: {field,division_by_zero}"
   947   shows "(a*c) / (b*c) = (if c=0 then 0 else a/b)"
   948 by (simp add: mult_divide_cancel_right)
   949 
   950 lemma mult_divide_cancel_left_if1 [simp]:
   951   fixes c :: "'a :: {field,division_by_zero}"
   952   shows "c / (c*b) = (if c=0 then 0 else 1/b)"
   953 apply (insert mult_divide_cancel_left_if [of c 1 b]) 
   954 apply (simp del: mult_divide_cancel_left_if)
   955 done
   956 
   957 lemma mult_divide_cancel_left_if2 [simp]:
   958   fixes c :: "'a :: {field,division_by_zero}"
   959   shows "(c*a) / c = (if c=0 then 0 else a)" 
   960 apply (insert mult_divide_cancel_left_if [of c a 1]) 
   961 apply (simp del: mult_divide_cancel_left_if)
   962 done
   963 
   964 lemma mult_divide_cancel_right_if1 [simp]:
   965   fixes c :: "'a :: {field,division_by_zero}"
   966   shows "c / (b*c) = (if c=0 then 0 else 1/b)"
   967 apply (insert mult_divide_cancel_right_if [of 1 c b]) 
   968 apply (simp del: mult_divide_cancel_right_if)
   969 done
   970 
   971 lemma mult_divide_cancel_right_if2 [simp]:
   972   fixes c :: "'a :: {field,division_by_zero}"
   973   shows "(a*c) / c = (if c=0 then 0 else a)" 
   974 apply (insert mult_divide_cancel_right_if [of a c 1]) 
   975 apply (simp del: mult_divide_cancel_right_if)
   976 done
   977 
   978 text{*Two lemmas for cancelling the denominator*}
   979 
   980 lemma times_divide_self_right [simp]: 
   981   fixes a :: "'a :: {field,division_by_zero}"
   982   shows "a * (b/a) = (if a=0 then 0 else b)"
   983 by (simp add: times_divide_eq_right)
   984 
   985 lemma times_divide_self_left [simp]: 
   986   fixes a :: "'a :: {field,division_by_zero}"
   987   shows "(b/a) * a = (if a=0 then 0 else b)"
   988 by (simp add: times_divide_eq_left)
   989 
   990 
   991 subsection {* Division and Unary Minus *}
   992 
   993 lemma nonzero_minus_divide_left: "b \<noteq> 0 ==> - (a/b) = (-a) / (b::'a::field)"
   994 by (simp add: divide_inverse minus_mult_left)
   995 
   996 lemma nonzero_minus_divide_right: "b \<noteq> 0 ==> - (a/b) = a / -(b::'a::field)"
   997 by (simp add: divide_inverse nonzero_inverse_minus_eq minus_mult_right)
   998 
   999 lemma nonzero_minus_divide_divide: "b \<noteq> 0 ==> (-a)/(-b) = a / (b::'a::field)"
  1000 by (simp add: divide_inverse nonzero_inverse_minus_eq)
  1001 
  1002 lemma minus_divide_left: "- (a/b) = (-a) / (b::'a::field)"
  1003 by (simp add: divide_inverse minus_mult_left [symmetric])
  1004 
  1005 lemma minus_divide_right: "- (a/b) = a / -(b::'a::{field,division_by_zero})"
  1006 by (simp add: divide_inverse minus_mult_right [symmetric])
  1007 
  1008 
  1009 text{*The effect is to extract signs from divisions*}
  1010 declare minus_divide_left  [symmetric, simp]
  1011 declare minus_divide_right [symmetric, simp]
  1012 
  1013 text{*Also, extract signs from products*}
  1014 declare minus_mult_left [symmetric, simp]
  1015 declare minus_mult_right [symmetric, simp]
  1016 
  1017 lemma minus_divide_divide [simp]:
  1018      "(-a)/(-b) = a / (b::'a::{field,division_by_zero})"
  1019 apply (case_tac "b=0", simp) 
  1020 apply (simp add: nonzero_minus_divide_divide) 
  1021 done
  1022 
  1023 lemma diff_divide_distrib: "(a-b)/(c::'a::field) = a/c - b/c"
  1024 by (simp add: diff_minus add_divide_distrib) 
  1025 
  1026 
  1027 subsection {* Ordered Fields *}
  1028 
  1029 lemma positive_imp_inverse_positive: 
  1030       assumes a_gt_0: "0 < a"  shows "0 < inverse (a::'a::ordered_field)"
  1031   proof -
  1032   have "0 < a * inverse a" 
  1033     by (simp add: a_gt_0 [THEN order_less_imp_not_eq2] zero_less_one)
  1034   thus "0 < inverse a" 
  1035     by (simp add: a_gt_0 [THEN order_less_not_sym] zero_less_mult_iff)
  1036   qed
  1037 
  1038 lemma negative_imp_inverse_negative:
  1039      "a < 0 ==> inverse a < (0::'a::ordered_field)"
  1040   by (insert positive_imp_inverse_positive [of "-a"], 
  1041       simp add: nonzero_inverse_minus_eq order_less_imp_not_eq) 
  1042 
  1043 lemma inverse_le_imp_le:
  1044       assumes invle: "inverse a \<le> inverse b"
  1045 	  and apos:  "0 < a"
  1046 	 shows "b \<le> (a::'a::ordered_field)"
  1047   proof (rule classical)
  1048   assume "~ b \<le> a"
  1049   hence "a < b"
  1050     by (simp add: linorder_not_le)
  1051   hence bpos: "0 < b"
  1052     by (blast intro: apos order_less_trans)
  1053   hence "a * inverse a \<le> a * inverse b"
  1054     by (simp add: apos invle order_less_imp_le mult_left_mono)
  1055   hence "(a * inverse a) * b \<le> (a * inverse b) * b"
  1056     by (simp add: bpos order_less_imp_le mult_right_mono)
  1057   thus "b \<le> a"
  1058     by (simp add: mult_assoc apos bpos order_less_imp_not_eq2)
  1059   qed
  1060 
  1061 lemma inverse_positive_imp_positive:
  1062       assumes inv_gt_0: "0 < inverse a"
  1063           and [simp]:   "a \<noteq> 0"
  1064         shows "0 < (a::'a::ordered_field)"
  1065   proof -
  1066   have "0 < inverse (inverse a)"
  1067     by (rule positive_imp_inverse_positive)
  1068   thus "0 < a"
  1069     by (simp add: nonzero_inverse_inverse_eq)
  1070   qed
  1071 
  1072 lemma inverse_positive_iff_positive [simp]:
  1073       "(0 < inverse a) = (0 < (a::'a::{ordered_field,division_by_zero}))"
  1074 apply (case_tac "a = 0", simp)
  1075 apply (blast intro: inverse_positive_imp_positive positive_imp_inverse_positive)
  1076 done
  1077 
  1078 lemma inverse_negative_imp_negative:
  1079       assumes inv_less_0: "inverse a < 0"
  1080           and [simp]:   "a \<noteq> 0"
  1081         shows "a < (0::'a::ordered_field)"
  1082   proof -
  1083   have "inverse (inverse a) < 0"
  1084     by (rule negative_imp_inverse_negative)
  1085   thus "a < 0"
  1086     by (simp add: nonzero_inverse_inverse_eq)
  1087   qed
  1088 
  1089 lemma inverse_negative_iff_negative [simp]:
  1090       "(inverse a < 0) = (a < (0::'a::{ordered_field,division_by_zero}))"
  1091 apply (case_tac "a = 0", simp)
  1092 apply (blast intro: inverse_negative_imp_negative negative_imp_inverse_negative)
  1093 done
  1094 
  1095 lemma inverse_nonnegative_iff_nonnegative [simp]:
  1096       "(0 \<le> inverse a) = (0 \<le> (a::'a::{ordered_field,division_by_zero}))"
  1097 by (simp add: linorder_not_less [symmetric])
  1098 
  1099 lemma inverse_nonpositive_iff_nonpositive [simp]:
  1100       "(inverse a \<le> 0) = (a \<le> (0::'a::{ordered_field,division_by_zero}))"
  1101 by (simp add: linorder_not_less [symmetric])
  1102 
  1103 
  1104 subsection{*Anti-Monotonicity of @{term inverse}*}
  1105 
  1106 lemma less_imp_inverse_less:
  1107       assumes less: "a < b"
  1108 	  and apos:  "0 < a"
  1109 	shows "inverse b < inverse (a::'a::ordered_field)"
  1110   proof (rule ccontr)
  1111   assume "~ inverse b < inverse a"
  1112   hence "inverse a \<le> inverse b"
  1113     by (simp add: linorder_not_less)
  1114   hence "~ (a < b)"
  1115     by (simp add: linorder_not_less inverse_le_imp_le [OF _ apos])
  1116   thus False
  1117     by (rule notE [OF _ less])
  1118   qed
  1119 
  1120 lemma inverse_less_imp_less:
  1121    "[|inverse a < inverse b; 0 < a|] ==> b < (a::'a::ordered_field)"
  1122 apply (simp add: order_less_le [of "inverse a"] order_less_le [of "b"])
  1123 apply (force dest!: inverse_le_imp_le nonzero_inverse_eq_imp_eq) 
  1124 done
  1125 
  1126 text{*Both premises are essential. Consider -1 and 1.*}
  1127 lemma inverse_less_iff_less [simp]:
  1128      "[|0 < a; 0 < b|] 
  1129       ==> (inverse a < inverse b) = (b < (a::'a::ordered_field))"
  1130 by (blast intro: less_imp_inverse_less dest: inverse_less_imp_less) 
  1131 
  1132 lemma le_imp_inverse_le:
  1133    "[|a \<le> b; 0 < a|] ==> inverse b \<le> inverse (a::'a::ordered_field)"
  1134   by (force simp add: order_le_less less_imp_inverse_less)
  1135 
  1136 lemma inverse_le_iff_le [simp]:
  1137      "[|0 < a; 0 < b|] 
  1138       ==> (inverse a \<le> inverse b) = (b \<le> (a::'a::ordered_field))"
  1139 by (blast intro: le_imp_inverse_le dest: inverse_le_imp_le) 
  1140 
  1141 
  1142 text{*These results refer to both operands being negative.  The opposite-sign
  1143 case is trivial, since inverse preserves signs.*}
  1144 lemma inverse_le_imp_le_neg:
  1145    "[|inverse a \<le> inverse b; b < 0|] ==> b \<le> (a::'a::ordered_field)"
  1146   apply (rule classical) 
  1147   apply (subgoal_tac "a < 0") 
  1148    prefer 2 apply (force simp add: linorder_not_le intro: order_less_trans) 
  1149   apply (insert inverse_le_imp_le [of "-b" "-a"])
  1150   apply (simp add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
  1151   done
  1152 
  1153 lemma less_imp_inverse_less_neg:
  1154    "[|a < b; b < 0|] ==> inverse b < inverse (a::'a::ordered_field)"
  1155   apply (subgoal_tac "a < 0") 
  1156    prefer 2 apply (blast intro: order_less_trans) 
  1157   apply (insert less_imp_inverse_less [of "-b" "-a"])
  1158   apply (simp add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
  1159   done
  1160 
  1161 lemma inverse_less_imp_less_neg:
  1162    "[|inverse a < inverse b; b < 0|] ==> b < (a::'a::ordered_field)"
  1163   apply (rule classical) 
  1164   apply (subgoal_tac "a < 0") 
  1165    prefer 2
  1166    apply (force simp add: linorder_not_less intro: order_le_less_trans) 
  1167   apply (insert inverse_less_imp_less [of "-b" "-a"])
  1168   apply (simp add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
  1169   done
  1170 
  1171 lemma inverse_less_iff_less_neg [simp]:
  1172      "[|a < 0; b < 0|] 
  1173       ==> (inverse a < inverse b) = (b < (a::'a::ordered_field))"
  1174   apply (insert inverse_less_iff_less [of "-b" "-a"])
  1175   apply (simp del: inverse_less_iff_less 
  1176 	      add: order_less_imp_not_eq nonzero_inverse_minus_eq) 
  1177   done
  1178 
  1179 lemma le_imp_inverse_le_neg:
  1180    "[|a \<le> b; b < 0|] ==> inverse b \<le> inverse (a::'a::ordered_field)"
  1181   by (force simp add: order_le_less less_imp_inverse_less_neg)
  1182 
  1183 lemma inverse_le_iff_le_neg [simp]:
  1184      "[|a < 0; b < 0|] 
  1185       ==> (inverse a \<le> inverse b) = (b \<le> (a::'a::ordered_field))"
  1186 by (blast intro: le_imp_inverse_le_neg dest: inverse_le_imp_le_neg) 
  1187 
  1188 
  1189 subsection{*Inverses and the Number One*}
  1190 
  1191 lemma one_less_inverse_iff:
  1192     "(1 < inverse x) = (0 < x & x < (1::'a::{ordered_field,division_by_zero}))"proof cases
  1193   assume "0 < x"
  1194     with inverse_less_iff_less [OF zero_less_one, of x]
  1195     show ?thesis by simp
  1196 next
  1197   assume notless: "~ (0 < x)"
  1198   have "~ (1 < inverse x)"
  1199   proof
  1200     assume "1 < inverse x"
  1201     also with notless have "... \<le> 0" by (simp add: linorder_not_less)
  1202     also have "... < 1" by (rule zero_less_one) 
  1203     finally show False by auto
  1204   qed
  1205   with notless show ?thesis by simp
  1206 qed
  1207 
  1208 lemma inverse_eq_1_iff [simp]:
  1209     "(inverse x = 1) = (x = (1::'a::{field,division_by_zero}))"
  1210 by (insert inverse_eq_iff_eq [of x 1], simp) 
  1211 
  1212 lemma one_le_inverse_iff:
  1213    "(1 \<le> inverse x) = (0 < x & x \<le> (1::'a::{ordered_field,division_by_zero}))"
  1214 by (force simp add: order_le_less one_less_inverse_iff zero_less_one 
  1215                     eq_commute [of 1]) 
  1216 
  1217 lemma inverse_less_1_iff:
  1218    "(inverse x < 1) = (x \<le> 0 | 1 < (x::'a::{ordered_field,division_by_zero}))"
  1219 by (simp add: linorder_not_le [symmetric] one_le_inverse_iff) 
  1220 
  1221 lemma inverse_le_1_iff:
  1222    "(inverse x \<le> 1) = (x \<le> 0 | 1 \<le> (x::'a::{ordered_field,division_by_zero}))"
  1223 by (simp add: linorder_not_less [symmetric] one_less_inverse_iff) 
  1224 
  1225 
  1226 subsection{*Division and Signs*}
  1227 
  1228 lemma zero_less_divide_iff:
  1229      "((0::'a::{ordered_field,division_by_zero}) < a/b) = (0 < a & 0 < b | a < 0 & b < 0)"
  1230 by (simp add: divide_inverse zero_less_mult_iff)
  1231 
  1232 lemma divide_less_0_iff:
  1233      "(a/b < (0::'a::{ordered_field,division_by_zero})) = 
  1234       (0 < a & b < 0 | a < 0 & 0 < b)"
  1235 by (simp add: divide_inverse mult_less_0_iff)
  1236 
  1237 lemma zero_le_divide_iff:
  1238      "((0::'a::{ordered_field,division_by_zero}) \<le> a/b) =
  1239       (0 \<le> a & 0 \<le> b | a \<le> 0 & b \<le> 0)"
  1240 by (simp add: divide_inverse zero_le_mult_iff)
  1241 
  1242 lemma divide_le_0_iff:
  1243      "(a/b \<le> (0::'a::{ordered_field,division_by_zero})) =
  1244       (0 \<le> a & b \<le> 0 | a \<le> 0 & 0 \<le> b)"
  1245 by (simp add: divide_inverse mult_le_0_iff)
  1246 
  1247 lemma divide_eq_0_iff [simp]:
  1248      "(a/b = 0) = (a=0 | b=(0::'a::{field,division_by_zero}))"
  1249 by (simp add: divide_inverse field_mult_eq_0_iff)
  1250 
  1251 
  1252 subsection{*Simplification of Inequalities Involving Literal Divisors*}
  1253 
  1254 lemma pos_le_divide_eq: "0 < (c::'a::ordered_field) ==> (a \<le> b/c) = (a*c \<le> b)"
  1255 proof -
  1256   assume less: "0<c"
  1257   hence "(a \<le> b/c) = (a*c \<le> (b/c)*c)"
  1258     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1259   also have "... = (a*c \<le> b)"
  1260     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1261   finally show ?thesis .
  1262 qed
  1263 
  1264 
  1265 lemma neg_le_divide_eq: "c < (0::'a::ordered_field) ==> (a \<le> b/c) = (b \<le> a*c)"
  1266 proof -
  1267   assume less: "c<0"
  1268   hence "(a \<le> b/c) = ((b/c)*c \<le> a*c)"
  1269     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1270   also have "... = (b \<le> a*c)"
  1271     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1272   finally show ?thesis .
  1273 qed
  1274 
  1275 lemma le_divide_eq:
  1276   "(a \<le> b/c) = 
  1277    (if 0 < c then a*c \<le> b
  1278              else if c < 0 then b \<le> a*c
  1279              else  a \<le> (0::'a::{ordered_field,division_by_zero}))"
  1280 apply (case_tac "c=0", simp) 
  1281 apply (force simp add: pos_le_divide_eq neg_le_divide_eq linorder_neq_iff) 
  1282 done
  1283 
  1284 lemma pos_divide_le_eq: "0 < (c::'a::ordered_field) ==> (b/c \<le> a) = (b \<le> a*c)"
  1285 proof -
  1286   assume less: "0<c"
  1287   hence "(b/c \<le> a) = ((b/c)*c \<le> a*c)"
  1288     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1289   also have "... = (b \<le> a*c)"
  1290     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1291   finally show ?thesis .
  1292 qed
  1293 
  1294 lemma neg_divide_le_eq: "c < (0::'a::ordered_field) ==> (b/c \<le> a) = (a*c \<le> b)"
  1295 proof -
  1296   assume less: "c<0"
  1297   hence "(b/c \<le> a) = (a*c \<le> (b/c)*c)"
  1298     by (simp add: mult_le_cancel_right order_less_not_sym [OF less])
  1299   also have "... = (a*c \<le> b)"
  1300     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1301   finally show ?thesis .
  1302 qed
  1303 
  1304 lemma divide_le_eq:
  1305   "(b/c \<le> a) = 
  1306    (if 0 < c then b \<le> a*c
  1307              else if c < 0 then a*c \<le> b
  1308              else 0 \<le> (a::'a::{ordered_field,division_by_zero}))"
  1309 apply (case_tac "c=0", simp) 
  1310 apply (force simp add: pos_divide_le_eq neg_divide_le_eq linorder_neq_iff) 
  1311 done
  1312 
  1313 
  1314 lemma pos_less_divide_eq:
  1315      "0 < (c::'a::ordered_field) ==> (a < b/c) = (a*c < b)"
  1316 proof -
  1317   assume less: "0<c"
  1318   hence "(a < b/c) = (a*c < (b/c)*c)"
  1319     by (simp add: mult_less_cancel_right_disj order_less_not_sym [OF less])
  1320   also have "... = (a*c < b)"
  1321     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1322   finally show ?thesis .
  1323 qed
  1324 
  1325 lemma neg_less_divide_eq:
  1326  "c < (0::'a::ordered_field) ==> (a < b/c) = (b < a*c)"
  1327 proof -
  1328   assume less: "c<0"
  1329   hence "(a < b/c) = ((b/c)*c < a*c)"
  1330     by (simp add: mult_less_cancel_right_disj order_less_not_sym [OF less])
  1331   also have "... = (b < a*c)"
  1332     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1333   finally show ?thesis .
  1334 qed
  1335 
  1336 lemma less_divide_eq:
  1337   "(a < b/c) = 
  1338    (if 0 < c then a*c < b
  1339              else if c < 0 then b < a*c
  1340              else  a < (0::'a::{ordered_field,division_by_zero}))"
  1341 apply (case_tac "c=0", simp) 
  1342 apply (force simp add: pos_less_divide_eq neg_less_divide_eq linorder_neq_iff) 
  1343 done
  1344 
  1345 lemma pos_divide_less_eq:
  1346      "0 < (c::'a::ordered_field) ==> (b/c < a) = (b < a*c)"
  1347 proof -
  1348   assume less: "0<c"
  1349   hence "(b/c < a) = ((b/c)*c < a*c)"
  1350     by (simp add: mult_less_cancel_right_disj order_less_not_sym [OF less])
  1351   also have "... = (b < a*c)"
  1352     by (simp add: order_less_imp_not_eq2 [OF less] divide_inverse mult_assoc) 
  1353   finally show ?thesis .
  1354 qed
  1355 
  1356 lemma neg_divide_less_eq:
  1357  "c < (0::'a::ordered_field) ==> (b/c < a) = (a*c < b)"
  1358 proof -
  1359   assume less: "c<0"
  1360   hence "(b/c < a) = (a*c < (b/c)*c)"
  1361     by (simp add: mult_less_cancel_right_disj order_less_not_sym [OF less])
  1362   also have "... = (a*c < b)"
  1363     by (simp add: order_less_imp_not_eq [OF less] divide_inverse mult_assoc) 
  1364   finally show ?thesis .
  1365 qed
  1366 
  1367 lemma divide_less_eq:
  1368   "(b/c < a) = 
  1369    (if 0 < c then b < a*c
  1370              else if c < 0 then a*c < b
  1371              else 0 < (a::'a::{ordered_field,division_by_zero}))"
  1372 apply (case_tac "c=0", simp) 
  1373 apply (force simp add: pos_divide_less_eq neg_divide_less_eq linorder_neq_iff) 
  1374 done
  1375 
  1376 lemma nonzero_eq_divide_eq: "c\<noteq>0 ==> ((a::'a::field) = b/c) = (a*c = b)"
  1377 proof -
  1378   assume [simp]: "c\<noteq>0"
  1379   have "(a = b/c) = (a*c = (b/c)*c)"
  1380     by (simp add: field_mult_cancel_right)
  1381   also have "... = (a*c = b)"
  1382     by (simp add: divide_inverse mult_assoc) 
  1383   finally show ?thesis .
  1384 qed
  1385 
  1386 lemma eq_divide_eq:
  1387   "((a::'a::{field,division_by_zero}) = b/c) = (if c\<noteq>0 then a*c = b else a=0)"
  1388 by (simp add: nonzero_eq_divide_eq) 
  1389 
  1390 lemma nonzero_divide_eq_eq: "c\<noteq>0 ==> (b/c = (a::'a::field)) = (b = a*c)"
  1391 proof -
  1392   assume [simp]: "c\<noteq>0"
  1393   have "(b/c = a) = ((b/c)*c = a*c)"
  1394     by (simp add: field_mult_cancel_right)
  1395   also have "... = (b = a*c)"
  1396     by (simp add: divide_inverse mult_assoc) 
  1397   finally show ?thesis .
  1398 qed
  1399 
  1400 lemma divide_eq_eq:
  1401   "(b/c = (a::'a::{field,division_by_zero})) = (if c\<noteq>0 then b = a*c else a=0)"
  1402 by (force simp add: nonzero_divide_eq_eq) 
  1403 
  1404 
  1405 subsection{*Cancellation Laws for Division*}
  1406 
  1407 lemma divide_cancel_right [simp]:
  1408      "(a/c = b/c) = (c = 0 | a = (b::'a::{field,division_by_zero}))"
  1409 apply (case_tac "c=0", simp) 
  1410 apply (simp add: divide_inverse field_mult_cancel_right) 
  1411 done
  1412 
  1413 lemma divide_cancel_left [simp]:
  1414      "(c/a = c/b) = (c = 0 | a = (b::'a::{field,division_by_zero}))" 
  1415 apply (case_tac "c=0", simp) 
  1416 apply (simp add: divide_inverse field_mult_cancel_left) 
  1417 done
  1418 
  1419 subsection {* Division and the Number One *}
  1420 
  1421 text{*Simplify expressions equated with 1*}
  1422 lemma divide_eq_1_iff [simp]:
  1423      "(a/b = 1) = (b \<noteq> 0 & a = (b::'a::{field,division_by_zero}))"
  1424 apply (case_tac "b=0", simp) 
  1425 apply (simp add: right_inverse_eq) 
  1426 done
  1427 
  1428 
  1429 lemma one_eq_divide_iff [simp]:
  1430      "(1 = a/b) = (b \<noteq> 0 & a = (b::'a::{field,division_by_zero}))"
  1431 by (simp add: eq_commute [of 1])  
  1432 
  1433 lemma zero_eq_1_divide_iff [simp]:
  1434      "((0::'a::{ordered_field,division_by_zero}) = 1/a) = (a = 0)"
  1435 apply (case_tac "a=0", simp) 
  1436 apply (auto simp add: nonzero_eq_divide_eq) 
  1437 done
  1438 
  1439 lemma one_divide_eq_0_iff [simp]:
  1440      "(1/a = (0::'a::{ordered_field,division_by_zero})) = (a = 0)"
  1441 apply (case_tac "a=0", simp) 
  1442 apply (insert zero_neq_one [THEN not_sym]) 
  1443 apply (auto simp add: nonzero_divide_eq_eq) 
  1444 done
  1445 
  1446 text{*Simplify expressions such as @{text "0 < 1/x"} to @{text "0 < x"}*}
  1447 declare zero_less_divide_iff [of "1", simp]
  1448 declare divide_less_0_iff [of "1", simp]
  1449 declare zero_le_divide_iff [of "1", simp]
  1450 declare divide_le_0_iff [of "1", simp]
  1451 
  1452 
  1453 subsection {* Ordering Rules for Division *}
  1454 
  1455 lemma divide_strict_right_mono:
  1456      "[|a < b; 0 < c|] ==> a / c < b / (c::'a::ordered_field)"
  1457 by (simp add: order_less_imp_not_eq2 divide_inverse mult_strict_right_mono 
  1458               positive_imp_inverse_positive) 
  1459 
  1460 lemma divide_right_mono:
  1461      "[|a \<le> b; 0 \<le> c|] ==> a/c \<le> b/(c::'a::{ordered_field,division_by_zero})"
  1462   by (force simp add: divide_strict_right_mono order_le_less) 
  1463 
  1464 
  1465 text{*The last premise ensures that @{term a} and @{term b} 
  1466       have the same sign*}
  1467 lemma divide_strict_left_mono:
  1468        "[|b < a; 0 < c; 0 < a*b|] ==> c / a < c / (b::'a::ordered_field)"
  1469 by (force simp add: zero_less_mult_iff divide_inverse mult_strict_left_mono 
  1470       order_less_imp_not_eq order_less_imp_not_eq2  
  1471       less_imp_inverse_less less_imp_inverse_less_neg) 
  1472 
  1473 lemma divide_left_mono:
  1474      "[|b \<le> a; 0 \<le> c; 0 < a*b|] ==> c / a \<le> c / (b::'a::ordered_field)"
  1475   apply (subgoal_tac "a \<noteq> 0 & b \<noteq> 0") 
  1476    prefer 2 
  1477    apply (force simp add: zero_less_mult_iff order_less_imp_not_eq) 
  1478   apply (case_tac "c=0", simp add: divide_inverse)
  1479   apply (force simp add: divide_strict_left_mono order_le_less) 
  1480   done
  1481 
  1482 lemma divide_strict_left_mono_neg:
  1483      "[|a < b; c < 0; 0 < a*b|] ==> c / a < c / (b::'a::ordered_field)"
  1484   apply (subgoal_tac "a \<noteq> 0 & b \<noteq> 0") 
  1485    prefer 2 
  1486    apply (force simp add: zero_less_mult_iff order_less_imp_not_eq) 
  1487   apply (drule divide_strict_left_mono [of _ _ "-c"]) 
  1488    apply (simp_all add: mult_commute nonzero_minus_divide_left [symmetric]) 
  1489   done
  1490 
  1491 lemma divide_strict_right_mono_neg:
  1492      "[|b < a; c < 0|] ==> a / c < b / (c::'a::ordered_field)"
  1493 apply (drule divide_strict_right_mono [of _ _ "-c"], simp) 
  1494 apply (simp add: order_less_imp_not_eq nonzero_minus_divide_right [symmetric]) 
  1495 done
  1496 
  1497 
  1498 subsection {* Ordered Fields are Dense *}
  1499 
  1500 lemma less_add_one: "a < (a+1::'a::ordered_semidom)"
  1501 proof -
  1502   have "a+0 < (a+1::'a::ordered_semidom)"
  1503     by (blast intro: zero_less_one add_strict_left_mono) 
  1504   thus ?thesis by simp
  1505 qed
  1506 
  1507 lemma zero_less_two: "0 < (1+1::'a::ordered_semidom)"
  1508   by (blast intro: order_less_trans zero_less_one less_add_one) 
  1509 
  1510 lemma less_half_sum: "a < b ==> a < (a+b) / (1+1::'a::ordered_field)"
  1511 by (simp add: zero_less_two pos_less_divide_eq right_distrib) 
  1512 
  1513 lemma gt_half_sum: "a < b ==> (a+b)/(1+1::'a::ordered_field) < b"
  1514 by (simp add: zero_less_two pos_divide_less_eq right_distrib) 
  1515 
  1516 lemma dense: "a < b ==> \<exists>r::'a::ordered_field. a < r & r < b"
  1517 by (blast intro!: less_half_sum gt_half_sum)
  1518 
  1519 
  1520 lemmas times_divide_eq = times_divide_eq_right times_divide_eq_left
  1521 
  1522 text{*It's not obvious whether these should be simprules or not. 
  1523   Their effect is to gather terms into one big fraction, like
  1524   a*b*c / x*y*z. The rationale for that is unclear, but many proofs 
  1525   seem to need them.*}
  1526 
  1527 declare times_divide_eq [simp]
  1528 
  1529 
  1530 subsection {* Absolute Value *}
  1531 
  1532 lemma abs_one [simp]: "abs 1 = (1::'a::ordered_idom)"
  1533   by (simp add: abs_if zero_less_one [THEN order_less_not_sym]) 
  1534 
  1535 lemma abs_le_mult: "abs (a * b) \<le> (abs a) * (abs (b::'a::lordered_ring))" 
  1536 proof -
  1537   let ?x = "pprt a * pprt b - pprt a * nprt b - nprt a * pprt b + nprt a * nprt b"
  1538   let ?y = "pprt a * pprt b + pprt a * nprt b + nprt a * pprt b + nprt a * nprt b"
  1539   have a: "(abs a) * (abs b) = ?x"
  1540     by (simp only: abs_prts[of a] abs_prts[of b] ring_eq_simps)
  1541   {
  1542     fix u v :: 'a
  1543     have bh: "\<lbrakk>u = a; v = b\<rbrakk> \<Longrightarrow> 
  1544               u * v = pprt a * pprt b + pprt a * nprt b + 
  1545                       nprt a * pprt b + nprt a * nprt b"
  1546       apply (subst prts[of u], subst prts[of v])
  1547       apply (simp add: left_distrib right_distrib add_ac) 
  1548       done
  1549   }
  1550   note b = this[OF refl[of a] refl[of b]]
  1551   note addm = add_mono[of "0::'a" _ "0::'a", simplified]
  1552   note addm2 = add_mono[of _ "0::'a" _ "0::'a", simplified]
  1553   have xy: "- ?x <= ?y"
  1554     apply (simp)
  1555     apply (rule_tac y="0::'a" in order_trans)
  1556     apply (rule addm2)+
  1557     apply (simp_all add: mult_pos_le mult_neg_le)
  1558     apply (rule addm)+
  1559     apply (simp_all add: mult_pos_le mult_neg_le)
  1560     done
  1561   have yx: "?y <= ?x"
  1562     apply (simp add: add_ac)
  1563     apply (rule_tac y=0 in order_trans)
  1564     apply (rule addm2, (simp add: mult_pos_neg_le mult_pos_neg2_le)+)
  1565     apply (rule addm, (simp add: mult_pos_neg_le mult_pos_neg2_le)+)
  1566     done
  1567   have i1: "a*b <= abs a * abs b" by (simp only: a b yx)
  1568   have i2: "- (abs a * abs b) <= a*b" by (simp only: a b xy)
  1569   show ?thesis
  1570     apply (rule abs_leI)
  1571     apply (simp add: i1)
  1572     apply (simp add: i2[simplified minus_le_iff])
  1573     done
  1574 qed
  1575 
  1576 lemma abs_eq_mult: 
  1577   assumes "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0)"
  1578   shows "abs (a*b) = abs a * abs (b::'a::lordered_ring)"
  1579 proof -
  1580   have s: "(0 <= a*b) | (a*b <= 0)"
  1581     apply (auto)    
  1582     apply (rule_tac split_mult_pos_le)
  1583     apply (rule_tac contrapos_np[of "a*b <= 0"])
  1584     apply (simp)
  1585     apply (rule_tac split_mult_neg_le)
  1586     apply (insert prems)
  1587     apply (blast)
  1588     done
  1589   have mulprts: "a * b = (pprt a + nprt a) * (pprt b + nprt b)"
  1590     by (simp add: prts[symmetric])
  1591   show ?thesis
  1592   proof cases
  1593     assume "0 <= a * b"
  1594     then show ?thesis
  1595       apply (simp_all add: mulprts abs_prts)
  1596       apply (insert prems)
  1597       apply (auto simp add: 
  1598 	ring_eq_simps 
  1599 	iff2imp[OF zero_le_iff_zero_nprt] iff2imp[OF le_zero_iff_zero_pprt]
  1600 	iff2imp[OF le_zero_iff_pprt_id] iff2imp[OF zero_le_iff_nprt_id])
  1601 	apply(drule (1) mult_pos_neg_le[of a b], simp)
  1602 	apply(drule (1) mult_pos_neg2_le[of b a], simp)
  1603       done
  1604   next
  1605     assume "~(0 <= a*b)"
  1606     with s have "a*b <= 0" by simp
  1607     then show ?thesis
  1608       apply (simp_all add: mulprts abs_prts)
  1609       apply (insert prems)
  1610       apply (auto simp add: ring_eq_simps)
  1611       apply(drule (1) mult_pos_le[of a b],simp)
  1612       apply(drule (1) mult_neg_le[of a b],simp)
  1613       done
  1614   qed
  1615 qed
  1616 
  1617 lemma abs_mult: "abs (a * b) = abs a * abs (b::'a::ordered_idom)" 
  1618 by (simp add: abs_eq_mult linorder_linear)
  1619 
  1620 lemma abs_mult_self: "abs a * abs a = a * (a::'a::ordered_idom)"
  1621 by (simp add: abs_if) 
  1622 
  1623 lemma nonzero_abs_inverse:
  1624      "a \<noteq> 0 ==> abs (inverse (a::'a::ordered_field)) = inverse (abs a)"
  1625 apply (auto simp add: linorder_neq_iff abs_if nonzero_inverse_minus_eq 
  1626                       negative_imp_inverse_negative)
  1627 apply (blast intro: positive_imp_inverse_positive elim: order_less_asym) 
  1628 done
  1629 
  1630 lemma abs_inverse [simp]:
  1631      "abs (inverse (a::'a::{ordered_field,division_by_zero})) = 
  1632       inverse (abs a)"
  1633 apply (case_tac "a=0", simp) 
  1634 apply (simp add: nonzero_abs_inverse) 
  1635 done
  1636 
  1637 lemma nonzero_abs_divide:
  1638      "b \<noteq> 0 ==> abs (a / (b::'a::ordered_field)) = abs a / abs b"
  1639 by (simp add: divide_inverse abs_mult nonzero_abs_inverse) 
  1640 
  1641 lemma abs_divide [simp]:
  1642      "abs (a / (b::'a::{ordered_field,division_by_zero})) = abs a / abs b"
  1643 apply (case_tac "b=0", simp) 
  1644 apply (simp add: nonzero_abs_divide) 
  1645 done
  1646 
  1647 lemma abs_mult_less:
  1648      "[| abs a < c; abs b < d |] ==> abs a * abs b < c*(d::'a::ordered_idom)"
  1649 proof -
  1650   assume ac: "abs a < c"
  1651   hence cpos: "0<c" by (blast intro: order_le_less_trans abs_ge_zero)
  1652   assume "abs b < d"
  1653   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1654 qed
  1655 
  1656 lemma eq_minus_self_iff: "(a = -a) = (a = (0::'a::ordered_idom))"
  1657 by (force simp add: order_eq_iff le_minus_self_iff minus_le_self_iff)
  1658 
  1659 lemma less_minus_self_iff: "(a < -a) = (a < (0::'a::ordered_idom))"
  1660 by (simp add: order_less_le le_minus_self_iff eq_minus_self_iff)
  1661 
  1662 lemma abs_less_iff: "(abs a < b) = (a < b & -a < (b::'a::ordered_idom))" 
  1663 apply (simp add: order_less_le abs_le_iff)  
  1664 apply (auto simp add: abs_if minus_le_self_iff eq_minus_self_iff)
  1665 apply (simp add: le_minus_self_iff linorder_neq_iff) 
  1666 done
  1667 
  1668 lemma linprog_dual_estimate:
  1669   assumes
  1670   "A * x \<le> (b::'a::lordered_ring)"
  1671   "0 \<le> y"
  1672   "abs (A - A') \<le> \<delta>A"
  1673   "b \<le> b'"
  1674   "abs (c - c') \<le> \<delta>c"
  1675   "abs x \<le> r"
  1676   shows
  1677   "c * x \<le> y * b' + (y * \<delta>A + abs (y * A' - c') + \<delta>c) * r"
  1678 proof -
  1679   from prems have 1: "y * b <= y * b'" by (simp add: mult_left_mono)
  1680   from prems have 2: "y * (A * x) <= y * b" by (simp add: mult_left_mono) 
  1681   have 3: "y * (A * x) = c * x + (y * (A - A') + (y * A' - c') + (c'-c)) * x" by (simp add: ring_eq_simps)  
  1682   from 1 2 3 have 4: "c * x + (y * (A - A') + (y * A' - c') + (c'-c)) * x <= y * b'" by simp
  1683   have 5: "c * x <= y * b' + abs((y * (A - A') + (y * A' - c') + (c'-c)) * x)"
  1684     by (simp only: 4 estimate_by_abs)  
  1685   have 6: "abs((y * (A - A') + (y * A' - c') + (c'-c)) * x) <= abs (y * (A - A') + (y * A' - c') + (c'-c)) * abs x"
  1686     by (simp add: abs_le_mult)
  1687   have 7: "(abs (y * (A - A') + (y * A' - c') + (c'-c))) * abs x <= (abs (y * (A-A') + (y*A'-c')) + abs(c'-c)) * abs x"
  1688     by (simp add: abs_triangle_ineq mult_right_mono)
  1689   have 8: " (abs (y * (A-A') + (y*A'-c')) + abs(c'-c)) * abs x <=  (abs (y * (A-A')) + abs (y*A'-c') + abs(c'-c)) * abs x"
  1690     by (simp add: abs_triangle_ineq mult_right_mono)    
  1691   have 9: "(abs (y * (A-A')) + abs (y*A'-c') + abs(c'-c)) * abs x <= (abs y * abs (A-A') + abs (y*A'-c') + abs (c'-c)) * abs x"
  1692     by (simp add: abs_le_mult mult_right_mono)  
  1693   have 10: "c'-c = -(c-c')" by (simp add: ring_eq_simps)
  1694   have 11: "abs (c'-c) = abs (c-c')" 
  1695     by (subst 10, subst abs_minus_cancel, simp)
  1696   have 12: "(abs y * abs (A-A') + abs (y*A'-c') + abs (c'-c)) * abs x <= (abs y * abs (A-A') + abs (y*A'-c') + \<delta>c) * abs x"
  1697     by (simp add: 11 prems mult_right_mono)
  1698   have 13: "(abs y * abs (A-A') + abs (y*A'-c') + \<delta>c) * abs x <= (abs y * \<delta>A + abs (y*A'-c') + \<delta>c) * abs x"
  1699     by (simp add: prems mult_right_mono mult_left_mono)  
  1700   have r: "(abs y * \<delta>A + abs (y*A'-c') + \<delta>c) * abs x <=  (abs y * \<delta>A + abs (y*A'-c') + \<delta>c) * r"
  1701     apply (rule mult_left_mono)
  1702     apply (simp add: prems)
  1703     apply (rule_tac add_mono[of "0::'a" _ "0", simplified])+
  1704     apply (rule mult_left_mono[of "0" "\<delta>A", simplified])
  1705     apply (simp_all)
  1706     apply (rule order_trans[where y="abs (A-A')"], simp_all add: prems)
  1707     apply (rule order_trans[where y="abs (c-c')"], simp_all add: prems)
  1708     done    
  1709   from 6 7 8 9 12 13 r have 14:" abs((y * (A - A') + (y * A' - c') + (c'-c)) * x) <=(abs y * \<delta>A + abs (y*A'-c') + \<delta>c) * r"     
  1710     by (simp)
  1711   show ?thesis 
  1712     apply (rule_tac le_add_right_mono[of _ _ "abs((y * (A - A') + (y * A' - c') + (c'-c)) * x)"])
  1713     apply (simp_all add: 5 14[simplified abs_of_ge_0[of y, simplified prems]])
  1714     done
  1715 qed
  1716 
  1717 lemma le_ge_imp_abs_diff_1:
  1718   assumes
  1719   "A1 <= (A::'a::lordered_ring)"
  1720   "A <= A2" 
  1721   shows "abs (A-A1) <= A2-A1"
  1722 proof -
  1723   have "0 <= A - A1"    
  1724   proof -
  1725     have 1: "A - A1 = A + (- A1)" by simp
  1726     show ?thesis by (simp only: 1 add_right_mono[of A1 A "-A1", simplified, simplified prems])
  1727   qed
  1728   then have "abs (A-A1) = A-A1" by (rule abs_of_ge_0)
  1729   with prems show "abs (A-A1) <= (A2-A1)" by simp
  1730 qed
  1731 
  1732 lemma mult_le_prts:
  1733   assumes
  1734   "a1 <= (a::'a::lordered_ring)"
  1735   "a <= a2"
  1736   "b1 <= b"
  1737   "b <= b2"
  1738   shows
  1739   "a * b <= pprt a2 * pprt b2 + pprt a1 * nprt b2 + nprt a2 * pprt b1 + nprt a1 * nprt b1"
  1740 proof - 
  1741   have "a * b = (pprt a + nprt a) * (pprt b + nprt b)" 
  1742     apply (subst prts[symmetric])+
  1743     apply simp
  1744     done
  1745   then have "a * b = pprt a * pprt b + pprt a * nprt b + nprt a * pprt b + nprt a * nprt b"
  1746     by (simp add: ring_eq_simps)
  1747   moreover have "pprt a * pprt b <= pprt a2 * pprt b2"
  1748     by (simp_all add: prems mult_mono)
  1749   moreover have "pprt a * nprt b <= pprt a1 * nprt b2"
  1750   proof -
  1751     have "pprt a * nprt b <= pprt a * nprt b2"
  1752       by (simp add: mult_left_mono prems)
  1753     moreover have "pprt a * nprt b2 <= pprt a1 * nprt b2"
  1754       by (simp add: mult_right_mono_neg prems)
  1755     ultimately show ?thesis
  1756       by simp
  1757   qed
  1758   moreover have "nprt a * pprt b <= nprt a2 * pprt b1"
  1759   proof - 
  1760     have "nprt a * pprt b <= nprt a2 * pprt b"
  1761       by (simp add: mult_right_mono prems)
  1762     moreover have "nprt a2 * pprt b <= nprt a2 * pprt b1"
  1763       by (simp add: mult_left_mono_neg prems)
  1764     ultimately show ?thesis
  1765       by simp
  1766   qed
  1767   moreover have "nprt a * nprt b <= nprt a1 * nprt b1"
  1768   proof -
  1769     have "nprt a * nprt b <= nprt a * nprt b1"
  1770       by (simp add: mult_left_mono_neg prems)
  1771     moreover have "nprt a * nprt b1 <= nprt a1 * nprt b1"
  1772       by (simp add: mult_right_mono_neg prems)
  1773     ultimately show ?thesis
  1774       by simp
  1775   qed
  1776   ultimately show ?thesis
  1777     by - (rule add_mono | simp)+
  1778 qed
  1779     
  1780 lemma mult_le_dual_prts: 
  1781   assumes
  1782   "A * x \<le> (b::'a::lordered_ring)"
  1783   "0 \<le> y"
  1784   "A1 \<le> A"
  1785   "A \<le> A2"
  1786   "c1 \<le> c"
  1787   "c \<le> c2"
  1788   "r1 \<le> x"
  1789   "x \<le> r2"
  1790   shows
  1791   "c * x \<le> y * b + (let s1 = c1 - y * A2; s2 = c2 - y * A1 in pprt s2 * pprt r2 + pprt s1 * nprt r2 + nprt s2 * pprt r1 + nprt s1 * nprt r1)"
  1792   (is "_ <= _ + ?C")
  1793 proof -
  1794   from prems have "y * (A * x) <= y * b" by (simp add: mult_left_mono) 
  1795   moreover have "y * (A * x) = c * x + (y * A - c) * x" by (simp add: ring_eq_simps)  
  1796   ultimately have "c * x + (y * A - c) * x <= y * b" by simp
  1797   then have "c * x <= y * b - (y * A - c) * x" by (simp add: le_diff_eq)
  1798   then have cx: "c * x <= y * b + (c - y * A) * x" by (simp add: ring_eq_simps)
  1799   have s2: "c - y * A <= c2 - y * A1"
  1800     by (simp add: diff_def prems add_mono mult_left_mono)
  1801   have s1: "c1 - y * A2 <= c - y * A"
  1802     by (simp add: diff_def prems add_mono mult_left_mono)
  1803   have prts: "(c - y * A) * x <= ?C"
  1804     apply (simp add: Let_def)
  1805     apply (rule mult_le_prts)
  1806     apply (simp_all add: prems s1 s2)
  1807     done
  1808   then have "y * b + (c - y * A) * x <= y * b + ?C"
  1809     by simp
  1810   with cx show ?thesis
  1811     by(simp only:)
  1812 qed
  1813 
  1814 ML {*
  1815 val left_distrib = thm "left_distrib";
  1816 val right_distrib = thm "right_distrib";
  1817 val mult_commute = thm "mult_commute";
  1818 val distrib = thm "distrib";
  1819 val zero_neq_one = thm "zero_neq_one";
  1820 val no_zero_divisors = thm "no_zero_divisors";
  1821 val left_inverse = thm "left_inverse";
  1822 val divide_inverse = thm "divide_inverse";
  1823 val mult_zero_left = thm "mult_zero_left";
  1824 val mult_zero_right = thm "mult_zero_right";
  1825 val field_mult_eq_0_iff = thm "field_mult_eq_0_iff";
  1826 val inverse_zero = thm "inverse_zero";
  1827 val ring_distrib = thms "ring_distrib";
  1828 val combine_common_factor = thm "combine_common_factor";
  1829 val minus_mult_left = thm "minus_mult_left";
  1830 val minus_mult_right = thm "minus_mult_right";
  1831 val minus_mult_minus = thm "minus_mult_minus";
  1832 val minus_mult_commute = thm "minus_mult_commute";
  1833 val right_diff_distrib = thm "right_diff_distrib";
  1834 val left_diff_distrib = thm "left_diff_distrib";
  1835 val mult_left_mono = thm "mult_left_mono";
  1836 val mult_right_mono = thm "mult_right_mono";
  1837 val mult_strict_left_mono = thm "mult_strict_left_mono";
  1838 val mult_strict_right_mono = thm "mult_strict_right_mono";
  1839 val mult_mono = thm "mult_mono";
  1840 val mult_strict_mono = thm "mult_strict_mono";
  1841 val abs_if = thm "abs_if";
  1842 val zero_less_one = thm "zero_less_one";
  1843 val eq_add_iff1 = thm "eq_add_iff1";
  1844 val eq_add_iff2 = thm "eq_add_iff2";
  1845 val less_add_iff1 = thm "less_add_iff1";
  1846 val less_add_iff2 = thm "less_add_iff2";
  1847 val le_add_iff1 = thm "le_add_iff1";
  1848 val le_add_iff2 = thm "le_add_iff2";
  1849 val mult_left_le_imp_le = thm "mult_left_le_imp_le";
  1850 val mult_right_le_imp_le = thm "mult_right_le_imp_le";
  1851 val mult_left_less_imp_less = thm "mult_left_less_imp_less";
  1852 val mult_right_less_imp_less = thm "mult_right_less_imp_less";
  1853 val mult_strict_left_mono_neg = thm "mult_strict_left_mono_neg";
  1854 val mult_left_mono_neg = thm "mult_left_mono_neg";
  1855 val mult_strict_right_mono_neg = thm "mult_strict_right_mono_neg";
  1856 val mult_right_mono_neg = thm "mult_right_mono_neg";
  1857 val mult_pos = thm "mult_pos";
  1858 val mult_pos_le = thm "mult_pos_le";
  1859 val mult_pos_neg = thm "mult_pos_neg";
  1860 val mult_pos_neg_le = thm "mult_pos_neg_le";
  1861 val mult_pos_neg2 = thm "mult_pos_neg2";
  1862 val mult_pos_neg2_le = thm "mult_pos_neg2_le";
  1863 val mult_neg = thm "mult_neg";
  1864 val mult_neg_le = thm "mult_neg_le";
  1865 val zero_less_mult_pos = thm "zero_less_mult_pos";
  1866 val zero_less_mult_pos2 = thm "zero_less_mult_pos2";
  1867 val zero_less_mult_iff = thm "zero_less_mult_iff";
  1868 val mult_eq_0_iff = thm "mult_eq_0_iff";
  1869 val zero_le_mult_iff = thm "zero_le_mult_iff";
  1870 val mult_less_0_iff = thm "mult_less_0_iff";
  1871 val mult_le_0_iff = thm "mult_le_0_iff";
  1872 val split_mult_pos_le = thm "split_mult_pos_le";
  1873 val split_mult_neg_le = thm "split_mult_neg_le";
  1874 val zero_le_square = thm "zero_le_square";
  1875 val zero_le_one = thm "zero_le_one";
  1876 val not_one_le_zero = thm "not_one_le_zero";
  1877 val not_one_less_zero = thm "not_one_less_zero";
  1878 val mult_left_mono_neg = thm "mult_left_mono_neg";
  1879 val mult_right_mono_neg = thm "mult_right_mono_neg";
  1880 val mult_strict_mono = thm "mult_strict_mono";
  1881 val mult_strict_mono' = thm "mult_strict_mono'";
  1882 val mult_mono = thm "mult_mono";
  1883 val less_1_mult = thm "less_1_mult";
  1884 val mult_less_cancel_right_disj = thm "mult_less_cancel_right_disj";
  1885 val mult_less_cancel_left_disj = thm "mult_less_cancel_left_disj";
  1886 val mult_less_cancel_right = thm "mult_less_cancel_right";
  1887 val mult_less_cancel_left = thm "mult_less_cancel_left";
  1888 val mult_le_cancel_right = thm "mult_le_cancel_right";
  1889 val mult_le_cancel_left = thm "mult_le_cancel_left";
  1890 val mult_less_imp_less_left = thm "mult_less_imp_less_left";
  1891 val mult_less_imp_less_right = thm "mult_less_imp_less_right";
  1892 val mult_cancel_right = thm "mult_cancel_right";
  1893 val mult_cancel_left = thm "mult_cancel_left";
  1894 val ring_eq_simps = thms "ring_eq_simps";
  1895 val right_inverse = thm "right_inverse";
  1896 val right_inverse_eq = thm "right_inverse_eq";
  1897 val nonzero_inverse_eq_divide = thm "nonzero_inverse_eq_divide";
  1898 val divide_self = thm "divide_self";
  1899 val divide_zero = thm "divide_zero";
  1900 val divide_zero_left = thm "divide_zero_left";
  1901 val inverse_eq_divide = thm "inverse_eq_divide";
  1902 val add_divide_distrib = thm "add_divide_distrib";
  1903 val field_mult_eq_0_iff = thm "field_mult_eq_0_iff";
  1904 val field_mult_cancel_right_lemma = thm "field_mult_cancel_right_lemma";
  1905 val field_mult_cancel_right = thm "field_mult_cancel_right";
  1906 val field_mult_cancel_left = thm "field_mult_cancel_left";
  1907 val nonzero_imp_inverse_nonzero = thm "nonzero_imp_inverse_nonzero";
  1908 val inverse_zero_imp_zero = thm "inverse_zero_imp_zero";
  1909 val inverse_nonzero_imp_nonzero = thm "inverse_nonzero_imp_nonzero";
  1910 val inverse_nonzero_iff_nonzero = thm "inverse_nonzero_iff_nonzero";
  1911 val nonzero_inverse_minus_eq = thm "nonzero_inverse_minus_eq";
  1912 val inverse_minus_eq = thm "inverse_minus_eq";
  1913 val nonzero_inverse_eq_imp_eq = thm "nonzero_inverse_eq_imp_eq";
  1914 val inverse_eq_imp_eq = thm "inverse_eq_imp_eq";
  1915 val inverse_eq_iff_eq = thm "inverse_eq_iff_eq";
  1916 val nonzero_inverse_inverse_eq = thm "nonzero_inverse_inverse_eq";
  1917 val inverse_inverse_eq = thm "inverse_inverse_eq";
  1918 val inverse_1 = thm "inverse_1";
  1919 val nonzero_inverse_mult_distrib = thm "nonzero_inverse_mult_distrib";
  1920 val inverse_mult_distrib = thm "inverse_mult_distrib";
  1921 val inverse_add = thm "inverse_add";
  1922 val inverse_divide = thm "inverse_divide";
  1923 val nonzero_mult_divide_cancel_left = thm "nonzero_mult_divide_cancel_left";
  1924 val mult_divide_cancel_left = thm "mult_divide_cancel_left";
  1925 val nonzero_mult_divide_cancel_right = thm "nonzero_mult_divide_cancel_right";
  1926 val mult_divide_cancel_right = thm "mult_divide_cancel_right";
  1927 val mult_divide_cancel_eq_if = thm "mult_divide_cancel_eq_if";
  1928 val divide_1 = thm "divide_1";
  1929 val times_divide_eq_right = thm "times_divide_eq_right";
  1930 val times_divide_eq_left = thm "times_divide_eq_left";
  1931 val divide_divide_eq_right = thm "divide_divide_eq_right";
  1932 val divide_divide_eq_left = thm "divide_divide_eq_left";
  1933 val nonzero_minus_divide_left = thm "nonzero_minus_divide_left";
  1934 val nonzero_minus_divide_right = thm "nonzero_minus_divide_right";
  1935 val nonzero_minus_divide_divide = thm "nonzero_minus_divide_divide";
  1936 val minus_divide_left = thm "minus_divide_left";
  1937 val minus_divide_right = thm "minus_divide_right";
  1938 val minus_divide_divide = thm "minus_divide_divide";
  1939 val diff_divide_distrib = thm "diff_divide_distrib";
  1940 val positive_imp_inverse_positive = thm "positive_imp_inverse_positive";
  1941 val negative_imp_inverse_negative = thm "negative_imp_inverse_negative";
  1942 val inverse_le_imp_le = thm "inverse_le_imp_le";
  1943 val inverse_positive_imp_positive = thm "inverse_positive_imp_positive";
  1944 val inverse_positive_iff_positive = thm "inverse_positive_iff_positive";
  1945 val inverse_negative_imp_negative = thm "inverse_negative_imp_negative";
  1946 val inverse_negative_iff_negative = thm "inverse_negative_iff_negative";
  1947 val inverse_nonnegative_iff_nonnegative = thm "inverse_nonnegative_iff_nonnegative";
  1948 val inverse_nonpositive_iff_nonpositive = thm "inverse_nonpositive_iff_nonpositive";
  1949 val less_imp_inverse_less = thm "less_imp_inverse_less";
  1950 val inverse_less_imp_less = thm "inverse_less_imp_less";
  1951 val inverse_less_iff_less = thm "inverse_less_iff_less";
  1952 val le_imp_inverse_le = thm "le_imp_inverse_le";
  1953 val inverse_le_iff_le = thm "inverse_le_iff_le";
  1954 val inverse_le_imp_le_neg = thm "inverse_le_imp_le_neg";
  1955 val less_imp_inverse_less_neg = thm "less_imp_inverse_less_neg";
  1956 val inverse_less_imp_less_neg = thm "inverse_less_imp_less_neg";
  1957 val inverse_less_iff_less_neg = thm "inverse_less_iff_less_neg";
  1958 val le_imp_inverse_le_neg = thm "le_imp_inverse_le_neg";
  1959 val inverse_le_iff_le_neg = thm "inverse_le_iff_le_neg";
  1960 val one_less_inverse_iff = thm "one_less_inverse_iff";
  1961 val inverse_eq_1_iff = thm "inverse_eq_1_iff";
  1962 val one_le_inverse_iff = thm "one_le_inverse_iff";
  1963 val inverse_less_1_iff = thm "inverse_less_1_iff";
  1964 val inverse_le_1_iff = thm "inverse_le_1_iff";
  1965 val zero_less_divide_iff = thm "zero_less_divide_iff";
  1966 val divide_less_0_iff = thm "divide_less_0_iff";
  1967 val zero_le_divide_iff = thm "zero_le_divide_iff";
  1968 val divide_le_0_iff = thm "divide_le_0_iff";
  1969 val divide_eq_0_iff = thm "divide_eq_0_iff";
  1970 val pos_le_divide_eq = thm "pos_le_divide_eq";
  1971 val neg_le_divide_eq = thm "neg_le_divide_eq";
  1972 val le_divide_eq = thm "le_divide_eq";
  1973 val pos_divide_le_eq = thm "pos_divide_le_eq";
  1974 val neg_divide_le_eq = thm "neg_divide_le_eq";
  1975 val divide_le_eq = thm "divide_le_eq";
  1976 val pos_less_divide_eq = thm "pos_less_divide_eq";
  1977 val neg_less_divide_eq = thm "neg_less_divide_eq";
  1978 val less_divide_eq = thm "less_divide_eq";
  1979 val pos_divide_less_eq = thm "pos_divide_less_eq";
  1980 val neg_divide_less_eq = thm "neg_divide_less_eq";
  1981 val divide_less_eq = thm "divide_less_eq";
  1982 val nonzero_eq_divide_eq = thm "nonzero_eq_divide_eq";
  1983 val eq_divide_eq = thm "eq_divide_eq";
  1984 val nonzero_divide_eq_eq = thm "nonzero_divide_eq_eq";
  1985 val divide_eq_eq = thm "divide_eq_eq";
  1986 val divide_cancel_right = thm "divide_cancel_right";
  1987 val divide_cancel_left = thm "divide_cancel_left";
  1988 val divide_eq_1_iff = thm "divide_eq_1_iff";
  1989 val one_eq_divide_iff = thm "one_eq_divide_iff";
  1990 val zero_eq_1_divide_iff = thm "zero_eq_1_divide_iff";
  1991 val one_divide_eq_0_iff = thm "one_divide_eq_0_iff";
  1992 val divide_strict_right_mono = thm "divide_strict_right_mono";
  1993 val divide_right_mono = thm "divide_right_mono";
  1994 val divide_strict_left_mono = thm "divide_strict_left_mono";
  1995 val divide_left_mono = thm "divide_left_mono";
  1996 val divide_strict_left_mono_neg = thm "divide_strict_left_mono_neg";
  1997 val divide_strict_right_mono_neg = thm "divide_strict_right_mono_neg";
  1998 val less_add_one = thm "less_add_one";
  1999 val zero_less_two = thm "zero_less_two";
  2000 val less_half_sum = thm "less_half_sum";
  2001 val gt_half_sum = thm "gt_half_sum";
  2002 val dense = thm "dense";
  2003 val abs_one = thm "abs_one";
  2004 val abs_le_mult = thm "abs_le_mult";
  2005 val abs_eq_mult = thm "abs_eq_mult";
  2006 val abs_mult = thm "abs_mult";
  2007 val abs_mult_self = thm "abs_mult_self";
  2008 val nonzero_abs_inverse = thm "nonzero_abs_inverse";
  2009 val abs_inverse = thm "abs_inverse";
  2010 val nonzero_abs_divide = thm "nonzero_abs_divide";
  2011 val abs_divide = thm "abs_divide";
  2012 val abs_mult_less = thm "abs_mult_less";
  2013 val eq_minus_self_iff = thm "eq_minus_self_iff";
  2014 val less_minus_self_iff = thm "less_minus_self_iff";
  2015 val abs_less_iff = thm "abs_less_iff";
  2016 *}
  2017 
  2018 end