src/Pure/Thy/present.ML
author wenzelm
Thu Nov 02 10:16:22 2017 +0100 (20 months ago)
changeset 66987 352b23c97ac8
parent 66945 b6f787a17fbe
child 67173 e746db6db903
permissions -rw-r--r--
support focus_session, for much faster startup of Isabelle/jEdit;
more options for "isabelle jedit";
     1 (*  Title:      Pure/Thy/present.ML
     2     Author:     Markus Wenzel and Stefan Berghofer, TU Muenchen
     3 
     4 Theory presentation: HTML and PDF-LaTeX documents.
     5 *)
     6 
     7 signature PRESENT =
     8 sig
     9   val theory_qualifier: theory -> string
    10   val document_enabled: string -> bool
    11   val document_variants: string -> (string * string) list
    12   val init: HTML.symbols -> bool -> bool -> Path.T -> string -> string -> (string * string) list ->
    13     (Path.T * Path.T) list -> Path.T -> string * string -> bool -> unit
    14   val finish: unit -> unit
    15   val theory_output: theory -> string -> unit
    16   val begin_theory: int -> (unit -> HTML.text) -> theory -> theory
    17   val display_drafts: Path.T list -> int
    18 end;
    19 
    20 structure Present: PRESENT =
    21 struct
    22 
    23 
    24 (** paths **)
    25 
    26 val tex_ext = Path.ext "tex";
    27 val tex_path = tex_ext o Path.basic;
    28 val html_ext = Path.ext "html";
    29 val html_path = html_ext o Path.basic;
    30 val index_path = Path.basic "index.html";
    31 val readme_html_path = Path.basic "README.html";
    32 val documentN = "document";
    33 val document_path = Path.basic documentN;
    34 val doc_indexN = "session";
    35 val session_graph_path = Path.basic "session_graph.pdf";
    36 
    37 fun show_path path = Path.implode (Path.expand (File.full_path Path.current path));
    38 
    39 
    40 
    41 (** additional theory data **)
    42 
    43 structure Browser_Info = Theory_Data
    44 (
    45   type T = {chapter: string, name: string};
    46   val empty = {chapter = "Unsorted", name = "Unknown"}: T;
    47   fun extend _ = empty;
    48   fun merge _ = empty;
    49 );
    50 
    51 val _ = Theory.setup
    52   (Browser_Info.put {chapter = Context.PureN, name = Context.PureN});
    53 
    54 
    55 
    56 (** global browser info state **)
    57 
    58 (* type theory_info *)
    59 
    60 type theory_info = {tex_source: string, html_source: string};
    61 
    62 fun make_theory_info (tex_source, html_source) =
    63   {tex_source = tex_source, html_source = html_source}: theory_info;
    64 
    65 fun map_theory_info f {tex_source, html_source} =
    66   make_theory_info (f (tex_source, html_source));
    67 
    68 
    69 (* type browser_info *)
    70 
    71 type browser_info =
    72  {theories: theory_info Symtab.table,
    73   tex_index: (int * string) list,
    74   html_index: (int * string) list};
    75 
    76 fun make_browser_info (theories, tex_index, html_index) : browser_info =
    77   {theories = theories, tex_index = tex_index, html_index = html_index};
    78 
    79 val empty_browser_info = make_browser_info (Symtab.empty, [], []);
    80 
    81 fun map_browser_info f {theories, tex_index, html_index} =
    82   make_browser_info (f (theories, tex_index, html_index));
    83 
    84 
    85 (* state *)
    86 
    87 val browser_info = Synchronized.var "browser_info" empty_browser_info;
    88 fun change_browser_info f = Synchronized.change browser_info (map_browser_info f);
    89 
    90 fun init_theory_info name info =
    91   change_browser_info (fn (theories, tex_index, html_index) =>
    92     (Symtab.update (name, info) theories, tex_index, html_index));
    93 
    94 fun change_theory_info name f =
    95   change_browser_info (fn (theories, tex_index, html_index) =>
    96     (case Symtab.lookup theories name of
    97       NONE => error ("Browser info: cannot access theory document " ^ quote name)
    98     | SOME info => (Symtab.update (name, map_theory_info f info) theories, tex_index, html_index)));
    99 
   100 
   101 fun add_tex_index txt =
   102   change_browser_info (fn (theories, tex_index, html_index) =>
   103     (theories, txt :: tex_index, html_index));
   104 
   105 fun add_html_index txt =
   106   change_browser_info (fn (theories, tex_index, html_index) =>
   107     (theories, tex_index, txt :: html_index));
   108 
   109 
   110 
   111 (** global session state **)
   112 
   113 (* session_info *)
   114 
   115 type session_info =
   116   {symbols: HTML.symbols, name: string, chapter: string, info_path: Path.T, info: bool,
   117     doc_format: string, doc_output: Path.T option, doc_files: (Path.T * Path.T) list,
   118     graph_file: Path.T, documents: (string * string) list, verbose: bool, readme: Path.T option};
   119 
   120 fun make_session_info
   121   (symbols, name, chapter, info_path, info, doc_format, doc_output, doc_files,
   122     graph_file, documents, verbose, readme) =
   123   {symbols = symbols, name = name, chapter = chapter, info_path = info_path, info = info,
   124     doc_format = doc_format, doc_output = doc_output, doc_files = doc_files, graph_file = graph_file,
   125     documents = documents, verbose = verbose, readme = readme}: session_info;
   126 
   127 
   128 (* state *)
   129 
   130 val session_info = Unsynchronized.ref (NONE: session_info option);
   131 
   132 fun with_session_info x f = (case ! session_info of NONE => x | SOME info => f info);
   133 
   134 val theory_qualifier = Resources.theory_qualifier o Context.theory_long_name;
   135 
   136 fun is_session_theory thy =
   137   (case ! session_info of
   138     NONE => false
   139   | SOME {name, ...} => name = theory_qualifier thy);
   140 
   141 
   142 (** document preparation **)
   143 
   144 (* options *)
   145 
   146 fun document_enabled s = s <> "" andalso s <> "false";
   147 
   148 fun document_variants str =
   149   let
   150     fun read_variant s =
   151       (case space_explode "=" s of
   152         [name] => (name, "")
   153       | [name, tags] => (name, tags)
   154       | _ => error ("Malformed document variant specification: " ^ quote s));
   155     val variants = map read_variant (space_explode ":" str);
   156     val _ =
   157       (case duplicates (op =) (map #1 variants) of
   158         [] => ()
   159       | dups => error ("Duplicate document variants: " ^ commas_quote dups));
   160   in variants end;
   161 
   162 
   163 (* init session *)
   164 
   165 fun init symbols build info info_path doc document_output doc_variants doc_files graph_file
   166     (chapter, name) verbose =
   167   if not build andalso not info andalso doc = "" then
   168     (Synchronized.change browser_info (K empty_browser_info); session_info := NONE)
   169   else
   170     let
   171       val doc_output =
   172         if document_output = "" then NONE else SOME (Path.explode document_output);
   173 
   174       val documents = if doc = "" orelse null doc_files then [] else doc_variants;
   175       val readme = if File.exists readme_html_path then SOME readme_html_path else NONE;
   176 
   177       val docs =
   178         (case readme of NONE => [] | SOME p => [(Url.File p, "README")]) @
   179           map (fn (name, _) => (Url.File (Path.ext doc (Path.basic name)), name)) documents;
   180     in
   181       session_info :=
   182         SOME (make_session_info (symbols, name, chapter, info_path, info, doc,
   183           doc_output, doc_files, graph_file, documents, verbose, readme));
   184       Synchronized.change browser_info (K empty_browser_info);
   185       add_html_index (0, HTML.begin_session_index symbols name (Url.File session_graph_path) docs)
   186     end;
   187 
   188 
   189 (* isabelle tool wrappers *)
   190 
   191 fun isabelle_document {verbose, purge} format name tags dir =
   192   let
   193     val s = "isabelle document -o '" ^ format ^ "' \
   194       \-n '" ^ name ^ "' -t '" ^ tags ^ "' " ^ File.bash_path dir ^ " 2>&1";
   195     val doc_path = Path.appends [dir, Path.parent, Path.basic name |> Path.ext format];
   196     val _ = if verbose then writeln s else ();
   197     val (out, rc) = Isabelle_System.bash_output s;
   198     val _ =
   199       if not (File.exists doc_path) orelse rc <> 0 then
   200         cat_error out ("Failed to build document " ^ quote (show_path doc_path))
   201       else if verbose then writeln out
   202       else ();
   203     val _ = if purge andalso rc = 0 then Isabelle_System.rm_tree dir else ();
   204   in doc_path end;
   205 
   206 
   207 (* finish session -- output all generated text *)
   208 
   209 fun sorted_index index = map snd (sort (int_ord o apply2 fst) (rev index));
   210 fun index_buffer index = Buffer.add (implode (sorted_index index)) Buffer.empty;
   211 
   212 fun write_tex src name path =
   213   File.write_buffer (Path.append path (tex_path name)) src;
   214 
   215 fun write_tex_index tex_index path =
   216   write_tex (index_buffer tex_index |> Buffer.add Latex.tex_trailer) doc_indexN path;
   217 
   218 fun finish () =
   219   with_session_info () (fn {name, chapter, info, info_path, doc_format,
   220     doc_output, doc_files, graph_file, documents, verbose, readme, ...} =>
   221   let
   222     val {theories, tex_index, html_index} = Synchronized.value browser_info;
   223     val thys = Symtab.dest theories;
   224 
   225     val session_prefix =
   226       Path.append (Path.append info_path (Path.basic chapter)) (Path.basic name);
   227 
   228     fun finish_html (a, {html_source, ...}: theory_info) =
   229       File.write (Path.append session_prefix (html_path a)) html_source;
   230 
   231     val _ =
   232       if info then
   233        (Isabelle_System.mkdirs session_prefix;
   234         File.write_buffer (Path.append session_prefix index_path)
   235           (index_buffer html_index |> Buffer.add HTML.end_document);
   236         (case readme of NONE => () | SOME path => Isabelle_System.copy_file path session_prefix);
   237         List.app finish_html thys;
   238         if verbose
   239         then Output.physical_stderr ("Browser info at " ^ show_path session_prefix ^ "\n")
   240         else ())
   241       else ();
   242 
   243     fun document_job doc_prefix backdrop (doc_name, tags) =
   244       let
   245         val doc_dir = Path.append doc_prefix (Path.basic doc_name);
   246         val _ = Isabelle_System.mkdirs doc_dir;
   247         val _ =
   248           Isabelle_System.bash ("isabelle latex -o sty " ^
   249             File.bash_path (Path.append doc_dir (Path.basic "root.tex")));
   250         val _ = List.app (fn file => Isabelle_System.copy_file_base file doc_dir) doc_files;
   251         val _ = Isabelle_System.copy_file graph_file (Path.append doc_dir session_graph_path);
   252         val _ = write_tex_index tex_index doc_dir;
   253         val _ =
   254           List.app (fn (a, {tex_source, ...}) =>
   255             write_tex (Buffer.add tex_source Buffer.empty) a doc_dir) thys;
   256       in
   257         fn () =>
   258           (isabelle_document {verbose = true, purge = backdrop} doc_format doc_name tags doc_dir,
   259             fn doc =>
   260               if verbose orelse not backdrop then
   261                 Output.physical_stderr ("Document at " ^ show_path doc ^ "\n")
   262               else ())
   263       end;
   264 
   265     val jobs =
   266       (if info orelse is_none doc_output then
   267         map (document_job session_prefix true) documents
   268        else []) @
   269       (case doc_output of
   270         NONE => []
   271       | SOME path => map (document_job path false) documents);
   272 
   273     val _ = jobs |> Par_List.map (fn job => job ()) |> List.app (op |>);
   274   in
   275     Synchronized.change browser_info (K empty_browser_info);
   276     session_info := NONE
   277   end);
   278 
   279 
   280 (* theory elements *)
   281 
   282 fun theory_output thy tex =
   283   with_session_info () (fn _ =>
   284     if is_session_theory thy then
   285       let val name = Context.theory_name thy;
   286       in change_theory_info name (fn (_, html) => (Latex.isabelle_theory name tex, html)) end
   287     else ());
   288 
   289 fun theory_link (curr_chapter, curr_session) thy =
   290   let
   291     val {chapter, name = session} = Browser_Info.get thy;
   292     val link = html_path (Context.theory_name thy);
   293   in
   294     if curr_session = session then SOME link
   295     else if curr_chapter = chapter then
   296       SOME (Path.appends [Path.parent, Path.basic session, link])
   297     else if chapter = Context.PureN then NONE
   298     else SOME (Path.appends [Path.parent, Path.parent, Path.basic chapter, Path.basic session, link])
   299   end;
   300 
   301 fun begin_theory update_time mk_text thy =
   302   with_session_info thy (fn {symbols, name = session_name, chapter, ...} =>
   303     let
   304       val name = Context.theory_name thy;
   305 
   306       val parent_specs =
   307         Theory.parents_of thy |> map (fn parent =>
   308           (Option.map Url.File (theory_link (chapter, session_name) parent),
   309             (Context.theory_name parent)));
   310       val html_source = HTML.theory symbols name parent_specs (mk_text ());
   311       val _ = init_theory_info name (make_theory_info ("", html_source));
   312 
   313       val _ =
   314         if is_session_theory thy then
   315           (add_html_index (update_time, HTML.theory_entry symbols (Url.File (html_path name), name));
   316            add_tex_index (update_time, Latex.theory_entry name))
   317         else ();
   318     in Browser_Info.put {chapter = chapter, name = session_name} thy end);
   319 
   320 
   321 
   322 (** draft document output **)
   323 
   324 fun display_drafts src_paths = Isabelle_System.with_tmp_dir "drafts" (fn dir =>
   325   let
   326     fun prep_draft path i =
   327       let
   328         val base = Path.base path;
   329         val name =
   330           (case Path.implode (#1 (Path.split_ext base)) of
   331             "" => "DUMMY"
   332           | s => s)  ^ serial_string ();
   333       in
   334         if File.exists path then
   335           (((name, base, File.read path), (i, Latex.theory_entry name)), i + 1)
   336         else error ("Bad file: " ^ Path.print path)
   337       end;
   338     val (srcs, tex_index) = split_list (fst (fold_map prep_draft src_paths 0));
   339 
   340     val doc_path = Path.append dir document_path;
   341     val _ = Isabelle_System.mkdirs doc_path;
   342     val root_path = Path.append doc_path (Path.basic "root.tex");
   343     val _ = Isabelle_System.copy_file (Path.explode "~~/lib/texinputs/draft.tex") root_path;
   344     val _ = Isabelle_System.bash ("isabelle latex -o sty " ^ File.bash_path root_path);
   345     val _ = Isabelle_System.bash ("isabelle latex -o syms " ^ File.bash_path root_path);
   346 
   347     fun known name =
   348       let val ss = split_lines (File.read (Path.append doc_path (Path.basic name)))
   349       in member (op =) ss end;
   350     val known_syms = known "syms.lst";
   351     val known_ctrls = known "ctrls.lst";
   352 
   353     val _ = srcs |> List.app (fn (name, base, txt) =>
   354       Symbol.explode txt
   355       |> Latex.symbol_source (known_syms, known_ctrls) (Path.implode base)
   356       |> File.write (Path.append doc_path (tex_path name)));
   357     val _ = write_tex_index tex_index doc_path;
   358 
   359     val result =
   360       isabelle_document {verbose = false, purge = true} "pdf" documentN "" doc_path;
   361 
   362     val target_dir = Path.explode "$ISABELLE_HOME_USER/tmp";
   363     val target = Path.explode "$ISABELLE_HOME_USER/tmp/drafts.pdf"
   364     val _ = Isabelle_System.mkdirs target_dir;
   365     val _ = Isabelle_System.copy_file result target;
   366   in Isabelle_System.bash ("isabelle display " ^ File.bash_path target ^ " &") end);
   367 
   368 end;