src/HOL/Algebra/Group.thy
author ballarin
Wed Nov 04 08:13:49 2015 +0100 (2015-11-04)
changeset 61565 352c73a689da
parent 61384 9f5145281888
child 61628 8dd2bd4fe30b
permissions -rw-r--r--
Qualifiers in locale expressions default to mandatory regardless of the command.
     1 (*  Title:      HOL/Algebra/Group.thy
     2     Author:     Clemens Ballarin, started 4 February 2003
     3 
     4 Based on work by Florian Kammueller, L C Paulson and Markus Wenzel.
     5 *)
     6 
     7 theory Group
     8 imports Lattice "~~/src/HOL/Library/FuncSet"
     9 begin
    10 
    11 section \<open>Monoids and Groups\<close>
    12 
    13 subsection \<open>Definitions\<close>
    14 
    15 text \<open>
    16   Definitions follow @{cite "Jacobson:1985"}.
    17 \<close>
    18 
    19 record 'a monoid =  "'a partial_object" +
    20   mult    :: "['a, 'a] \<Rightarrow> 'a" (infixl "\<otimes>\<index>" 70)
    21   one     :: 'a ("\<one>\<index>")
    22 
    23 definition
    24   m_inv :: "('a, 'b) monoid_scheme => 'a => 'a" ("inv\<index> _" [81] 80)
    25   where "inv\<^bsub>G\<^esub> x = (THE y. y \<in> carrier G & x \<otimes>\<^bsub>G\<^esub> y = \<one>\<^bsub>G\<^esub> & y \<otimes>\<^bsub>G\<^esub> x = \<one>\<^bsub>G\<^esub>)"
    26 
    27 definition
    28   Units :: "_ => 'a set"
    29   --\<open>The set of invertible elements\<close>
    30   where "Units G = {y. y \<in> carrier G & (\<exists>x \<in> carrier G. x \<otimes>\<^bsub>G\<^esub> y = \<one>\<^bsub>G\<^esub> & y \<otimes>\<^bsub>G\<^esub> x = \<one>\<^bsub>G\<^esub>)}"
    31 
    32 consts
    33   pow :: "[('a, 'm) monoid_scheme, 'a, 'b::semiring_1] => 'a"  (infixr "'(^')\<index>" 75)
    34 
    35 overloading nat_pow == "pow :: [_, 'a, nat] => 'a"
    36 begin
    37   definition "nat_pow G a n = rec_nat \<one>\<^bsub>G\<^esub> (%u b. b \<otimes>\<^bsub>G\<^esub> a) n"
    38 end
    39 
    40 overloading int_pow == "pow :: [_, 'a, int] => 'a"
    41 begin
    42   definition "int_pow G a z =
    43    (let p = rec_nat \<one>\<^bsub>G\<^esub> (%u b. b \<otimes>\<^bsub>G\<^esub> a)
    44     in if z < 0 then inv\<^bsub>G\<^esub> (p (nat (-z))) else p (nat z))"
    45 end
    46 
    47 locale monoid =
    48   fixes G (structure)
    49   assumes m_closed [intro, simp]:
    50          "\<lbrakk>x \<in> carrier G; y \<in> carrier G\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> carrier G"
    51       and m_assoc:
    52          "\<lbrakk>x \<in> carrier G; y \<in> carrier G; z \<in> carrier G\<rbrakk> 
    53           \<Longrightarrow> (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
    54       and one_closed [intro, simp]: "\<one> \<in> carrier G"
    55       and l_one [simp]: "x \<in> carrier G \<Longrightarrow> \<one> \<otimes> x = x"
    56       and r_one [simp]: "x \<in> carrier G \<Longrightarrow> x \<otimes> \<one> = x"
    57 
    58 lemma monoidI:
    59   fixes G (structure)
    60   assumes m_closed:
    61       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
    62     and one_closed: "\<one> \<in> carrier G"
    63     and m_assoc:
    64       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
    65       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
    66     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
    67     and r_one: "!!x. x \<in> carrier G ==> x \<otimes> \<one> = x"
    68   shows "monoid G"
    69   by (fast intro!: monoid.intro intro: assms)
    70 
    71 lemma (in monoid) Units_closed [dest]:
    72   "x \<in> Units G ==> x \<in> carrier G"
    73   by (unfold Units_def) fast
    74 
    75 lemma (in monoid) inv_unique:
    76   assumes eq: "y \<otimes> x = \<one>"  "x \<otimes> y' = \<one>"
    77     and G: "x \<in> carrier G"  "y \<in> carrier G"  "y' \<in> carrier G"
    78   shows "y = y'"
    79 proof -
    80   from G eq have "y = y \<otimes> (x \<otimes> y')" by simp
    81   also from G have "... = (y \<otimes> x) \<otimes> y'" by (simp add: m_assoc)
    82   also from G eq have "... = y'" by simp
    83   finally show ?thesis .
    84 qed
    85 
    86 lemma (in monoid) Units_m_closed [intro, simp]:
    87   assumes x: "x \<in> Units G" and y: "y \<in> Units G"
    88   shows "x \<otimes> y \<in> Units G"
    89 proof -
    90   from x obtain x' where x: "x \<in> carrier G" "x' \<in> carrier G" and xinv: "x \<otimes> x' = \<one>" "x' \<otimes> x = \<one>"
    91     unfolding Units_def by fast
    92   from y obtain y' where y: "y \<in> carrier G" "y' \<in> carrier G" and yinv: "y \<otimes> y' = \<one>" "y' \<otimes> y = \<one>"
    93     unfolding Units_def by fast
    94   from x y xinv yinv have "y' \<otimes> (x' \<otimes> x) \<otimes> y = \<one>" by simp
    95   moreover from x y xinv yinv have "x \<otimes> (y \<otimes> y') \<otimes> x' = \<one>" by simp
    96   moreover note x y
    97   ultimately show ?thesis unfolding Units_def
    98     -- "Must avoid premature use of @{text hyp_subst_tac}."
    99     apply (rule_tac CollectI)
   100     apply (rule)
   101     apply (fast)
   102     apply (rule bexI [where x = "y' \<otimes> x'"])
   103     apply (auto simp: m_assoc)
   104     done
   105 qed
   106 
   107 lemma (in monoid) Units_one_closed [intro, simp]:
   108   "\<one> \<in> Units G"
   109   by (unfold Units_def) auto
   110 
   111 lemma (in monoid) Units_inv_closed [intro, simp]:
   112   "x \<in> Units G ==> inv x \<in> carrier G"
   113   apply (unfold Units_def m_inv_def, auto)
   114   apply (rule theI2, fast)
   115    apply (fast intro: inv_unique, fast)
   116   done
   117 
   118 lemma (in monoid) Units_l_inv_ex:
   119   "x \<in> Units G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   120   by (unfold Units_def) auto
   121 
   122 lemma (in monoid) Units_r_inv_ex:
   123   "x \<in> Units G ==> \<exists>y \<in> carrier G. x \<otimes> y = \<one>"
   124   by (unfold Units_def) auto
   125 
   126 lemma (in monoid) Units_l_inv [simp]:
   127   "x \<in> Units G ==> inv x \<otimes> x = \<one>"
   128   apply (unfold Units_def m_inv_def, auto)
   129   apply (rule theI2, fast)
   130    apply (fast intro: inv_unique, fast)
   131   done
   132 
   133 lemma (in monoid) Units_r_inv [simp]:
   134   "x \<in> Units G ==> x \<otimes> inv x = \<one>"
   135   apply (unfold Units_def m_inv_def, auto)
   136   apply (rule theI2, fast)
   137    apply (fast intro: inv_unique, fast)
   138   done
   139 
   140 lemma (in monoid) Units_inv_Units [intro, simp]:
   141   "x \<in> Units G ==> inv x \<in> Units G"
   142 proof -
   143   assume x: "x \<in> Units G"
   144   show "inv x \<in> Units G"
   145     by (auto simp add: Units_def
   146       intro: Units_l_inv Units_r_inv x Units_closed [OF x])
   147 qed
   148 
   149 lemma (in monoid) Units_l_cancel [simp]:
   150   "[| x \<in> Units G; y \<in> carrier G; z \<in> carrier G |] ==>
   151    (x \<otimes> y = x \<otimes> z) = (y = z)"
   152 proof
   153   assume eq: "x \<otimes> y = x \<otimes> z"
   154     and G: "x \<in> Units G"  "y \<in> carrier G"  "z \<in> carrier G"
   155   then have "(inv x \<otimes> x) \<otimes> y = (inv x \<otimes> x) \<otimes> z"
   156     by (simp add: m_assoc Units_closed del: Units_l_inv)
   157   with G show "y = z" by simp
   158 next
   159   assume eq: "y = z"
   160     and G: "x \<in> Units G"  "y \<in> carrier G"  "z \<in> carrier G"
   161   then show "x \<otimes> y = x \<otimes> z" by simp
   162 qed
   163 
   164 lemma (in monoid) Units_inv_inv [simp]:
   165   "x \<in> Units G ==> inv (inv x) = x"
   166 proof -
   167   assume x: "x \<in> Units G"
   168   then have "inv x \<otimes> inv (inv x) = inv x \<otimes> x" by simp
   169   with x show ?thesis by (simp add: Units_closed del: Units_l_inv Units_r_inv)
   170 qed
   171 
   172 lemma (in monoid) inv_inj_on_Units:
   173   "inj_on (m_inv G) (Units G)"
   174 proof (rule inj_onI)
   175   fix x y
   176   assume G: "x \<in> Units G"  "y \<in> Units G" and eq: "inv x = inv y"
   177   then have "inv (inv x) = inv (inv y)" by simp
   178   with G show "x = y" by simp
   179 qed
   180 
   181 lemma (in monoid) Units_inv_comm:
   182   assumes inv: "x \<otimes> y = \<one>"
   183     and G: "x \<in> Units G"  "y \<in> Units G"
   184   shows "y \<otimes> x = \<one>"
   185 proof -
   186   from G have "x \<otimes> y \<otimes> x = x \<otimes> \<one>" by (auto simp add: inv Units_closed)
   187   with G show ?thesis by (simp del: r_one add: m_assoc Units_closed)
   188 qed
   189 
   190 text \<open>Power\<close>
   191 
   192 lemma (in monoid) nat_pow_closed [intro, simp]:
   193   "x \<in> carrier G ==> x (^) (n::nat) \<in> carrier G"
   194   by (induct n) (simp_all add: nat_pow_def)
   195 
   196 lemma (in monoid) nat_pow_0 [simp]:
   197   "x (^) (0::nat) = \<one>"
   198   by (simp add: nat_pow_def)
   199 
   200 lemma (in monoid) nat_pow_Suc [simp]:
   201   "x (^) (Suc n) = x (^) n \<otimes> x"
   202   by (simp add: nat_pow_def)
   203 
   204 lemma (in monoid) nat_pow_one [simp]:
   205   "\<one> (^) (n::nat) = \<one>"
   206   by (induct n) simp_all
   207 
   208 lemma (in monoid) nat_pow_mult:
   209   "x \<in> carrier G ==> x (^) (n::nat) \<otimes> x (^) m = x (^) (n + m)"
   210   by (induct m) (simp_all add: m_assoc [THEN sym])
   211 
   212 lemma (in monoid) nat_pow_pow:
   213   "x \<in> carrier G ==> (x (^) n) (^) m = x (^) (n * m::nat)"
   214   by (induct m) (simp, simp add: nat_pow_mult add.commute)
   215 
   216 
   217 (* Jacobson defines submonoid here. *)
   218 (* Jacobson defines the order of a monoid here. *)
   219 
   220 
   221 subsection \<open>Groups\<close>
   222 
   223 text \<open>
   224   A group is a monoid all of whose elements are invertible.
   225 \<close>
   226 
   227 locale group = monoid +
   228   assumes Units: "carrier G <= Units G"
   229 
   230 lemma (in group) is_group: "group G" by (rule group_axioms)
   231 
   232 theorem groupI:
   233   fixes G (structure)
   234   assumes m_closed [simp]:
   235       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
   236     and one_closed [simp]: "\<one> \<in> carrier G"
   237     and m_assoc:
   238       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   239       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
   240     and l_one [simp]: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
   241     and l_inv_ex: "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   242   shows "group G"
   243 proof -
   244   have l_cancel [simp]:
   245     "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   246     (x \<otimes> y = x \<otimes> z) = (y = z)"
   247   proof
   248     fix x y z
   249     assume eq: "x \<otimes> y = x \<otimes> z"
   250       and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   251     with l_inv_ex obtain x_inv where xG: "x_inv \<in> carrier G"
   252       and l_inv: "x_inv \<otimes> x = \<one>" by fast
   253     from G eq xG have "(x_inv \<otimes> x) \<otimes> y = (x_inv \<otimes> x) \<otimes> z"
   254       by (simp add: m_assoc)
   255     with G show "y = z" by (simp add: l_inv)
   256   next
   257     fix x y z
   258     assume eq: "y = z"
   259       and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   260     then show "x \<otimes> y = x \<otimes> z" by simp
   261   qed
   262   have r_one:
   263     "!!x. x \<in> carrier G ==> x \<otimes> \<one> = x"
   264   proof -
   265     fix x
   266     assume x: "x \<in> carrier G"
   267     with l_inv_ex obtain x_inv where xG: "x_inv \<in> carrier G"
   268       and l_inv: "x_inv \<otimes> x = \<one>" by fast
   269     from x xG have "x_inv \<otimes> (x \<otimes> \<one>) = x_inv \<otimes> x"
   270       by (simp add: m_assoc [symmetric] l_inv)
   271     with x xG show "x \<otimes> \<one> = x" by simp
   272   qed
   273   have inv_ex:
   274     "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one> & x \<otimes> y = \<one>"
   275   proof -
   276     fix x
   277     assume x: "x \<in> carrier G"
   278     with l_inv_ex obtain y where y: "y \<in> carrier G"
   279       and l_inv: "y \<otimes> x = \<one>" by fast
   280     from x y have "y \<otimes> (x \<otimes> y) = y \<otimes> \<one>"
   281       by (simp add: m_assoc [symmetric] l_inv r_one)
   282     with x y have r_inv: "x \<otimes> y = \<one>"
   283       by simp
   284     from x y show "\<exists>y \<in> carrier G. y \<otimes> x = \<one> & x \<otimes> y = \<one>"
   285       by (fast intro: l_inv r_inv)
   286   qed
   287   then have carrier_subset_Units: "carrier G <= Units G"
   288     by (unfold Units_def) fast
   289   show ?thesis
   290     by standard (auto simp: r_one m_assoc carrier_subset_Units)
   291 qed
   292 
   293 lemma (in monoid) group_l_invI:
   294   assumes l_inv_ex:
   295     "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   296   shows "group G"
   297   by (rule groupI) (auto intro: m_assoc l_inv_ex)
   298 
   299 lemma (in group) Units_eq [simp]:
   300   "Units G = carrier G"
   301 proof
   302   show "Units G <= carrier G" by fast
   303 next
   304   show "carrier G <= Units G" by (rule Units)
   305 qed
   306 
   307 lemma (in group) inv_closed [intro, simp]:
   308   "x \<in> carrier G ==> inv x \<in> carrier G"
   309   using Units_inv_closed by simp
   310 
   311 lemma (in group) l_inv_ex [simp]:
   312   "x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   313   using Units_l_inv_ex by simp
   314 
   315 lemma (in group) r_inv_ex [simp]:
   316   "x \<in> carrier G ==> \<exists>y \<in> carrier G. x \<otimes> y = \<one>"
   317   using Units_r_inv_ex by simp
   318 
   319 lemma (in group) l_inv [simp]:
   320   "x \<in> carrier G ==> inv x \<otimes> x = \<one>"
   321   using Units_l_inv by simp
   322 
   323 
   324 subsection \<open>Cancellation Laws and Basic Properties\<close>
   325 
   326 lemma (in group) l_cancel [simp]:
   327   "[| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   328    (x \<otimes> y = x \<otimes> z) = (y = z)"
   329   using Units_l_inv by simp
   330 
   331 lemma (in group) r_inv [simp]:
   332   "x \<in> carrier G ==> x \<otimes> inv x = \<one>"
   333 proof -
   334   assume x: "x \<in> carrier G"
   335   then have "inv x \<otimes> (x \<otimes> inv x) = inv x \<otimes> \<one>"
   336     by (simp add: m_assoc [symmetric])
   337   with x show ?thesis by (simp del: r_one)
   338 qed
   339 
   340 lemma (in group) r_cancel [simp]:
   341   "[| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   342    (y \<otimes> x = z \<otimes> x) = (y = z)"
   343 proof
   344   assume eq: "y \<otimes> x = z \<otimes> x"
   345     and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   346   then have "y \<otimes> (x \<otimes> inv x) = z \<otimes> (x \<otimes> inv x)"
   347     by (simp add: m_assoc [symmetric] del: r_inv Units_r_inv)
   348   with G show "y = z" by simp
   349 next
   350   assume eq: "y = z"
   351     and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   352   then show "y \<otimes> x = z \<otimes> x" by simp
   353 qed
   354 
   355 lemma (in group) inv_one [simp]:
   356   "inv \<one> = \<one>"
   357 proof -
   358   have "inv \<one> = \<one> \<otimes> (inv \<one>)" by (simp del: r_inv Units_r_inv)
   359   moreover have "... = \<one>" by simp
   360   finally show ?thesis .
   361 qed
   362 
   363 lemma (in group) inv_inv [simp]:
   364   "x \<in> carrier G ==> inv (inv x) = x"
   365   using Units_inv_inv by simp
   366 
   367 lemma (in group) inv_inj:
   368   "inj_on (m_inv G) (carrier G)"
   369   using inv_inj_on_Units by simp
   370 
   371 lemma (in group) inv_mult_group:
   372   "[| x \<in> carrier G; y \<in> carrier G |] ==> inv (x \<otimes> y) = inv y \<otimes> inv x"
   373 proof -
   374   assume G: "x \<in> carrier G"  "y \<in> carrier G"
   375   then have "inv (x \<otimes> y) \<otimes> (x \<otimes> y) = (inv y \<otimes> inv x) \<otimes> (x \<otimes> y)"
   376     by (simp add: m_assoc) (simp add: m_assoc [symmetric])
   377   with G show ?thesis by (simp del: l_inv Units_l_inv)
   378 qed
   379 
   380 lemma (in group) inv_comm:
   381   "[| x \<otimes> y = \<one>; x \<in> carrier G; y \<in> carrier G |] ==> y \<otimes> x = \<one>"
   382   by (rule Units_inv_comm) auto
   383 
   384 lemma (in group) inv_equality:
   385      "[|y \<otimes> x = \<one>; x \<in> carrier G; y \<in> carrier G|] ==> inv x = y"
   386 apply (simp add: m_inv_def)
   387 apply (rule the_equality)
   388  apply (simp add: inv_comm [of y x])
   389 apply (rule r_cancel [THEN iffD1], auto)
   390 done
   391 
   392 (* Contributed by Joachim Breitner *)
   393 lemma (in group) inv_solve_left:
   394   "\<lbrakk> a \<in> carrier G; b \<in> carrier G; c \<in> carrier G \<rbrakk> \<Longrightarrow> a = inv b \<otimes> c \<longleftrightarrow> c = b \<otimes> a"
   395   by (metis inv_equality l_inv_ex l_one m_assoc r_inv)
   396 lemma (in group) inv_solve_right:
   397   "\<lbrakk> a \<in> carrier G; b \<in> carrier G; c \<in> carrier G \<rbrakk> \<Longrightarrow> a = b \<otimes> inv c \<longleftrightarrow> b = a \<otimes> c"
   398   by (metis inv_equality l_inv_ex l_one m_assoc r_inv)
   399 
   400 text \<open>Power\<close>
   401 
   402 lemma (in group) int_pow_def2:
   403   "a (^) (z::int) = (if z < 0 then inv (a (^) (nat (-z))) else a (^) (nat z))"
   404   by (simp add: int_pow_def nat_pow_def Let_def)
   405 
   406 lemma (in group) int_pow_0 [simp]:
   407   "x (^) (0::int) = \<one>"
   408   by (simp add: int_pow_def2)
   409 
   410 lemma (in group) int_pow_one [simp]:
   411   "\<one> (^) (z::int) = \<one>"
   412   by (simp add: int_pow_def2)
   413 
   414 (* The following are contributed by Joachim Breitner *)
   415 
   416 lemma (in group) int_pow_closed [intro, simp]:
   417   "x \<in> carrier G ==> x (^) (i::int) \<in> carrier G"
   418   by (simp add: int_pow_def2)
   419 
   420 lemma (in group) int_pow_1 [simp]:
   421   "x \<in> carrier G \<Longrightarrow> x (^) (1::int) = x"
   422   by (simp add: int_pow_def2)
   423 
   424 lemma (in group) int_pow_neg:
   425   "x \<in> carrier G \<Longrightarrow> x (^) (-i::int) = inv (x (^) i)"
   426   by (simp add: int_pow_def2)
   427 
   428 lemma (in group) int_pow_mult:
   429   "x \<in> carrier G \<Longrightarrow> x (^) (i + j::int) = x (^) i \<otimes> x (^) j"
   430 proof -
   431   have [simp]: "-i - j = -j - i" by simp
   432   assume "x : carrier G" then
   433   show ?thesis
   434     by (auto simp add: int_pow_def2 inv_solve_left inv_solve_right nat_add_distrib [symmetric] nat_pow_mult )
   435 qed
   436 
   437  
   438 subsection \<open>Subgroups\<close>
   439 
   440 locale subgroup =
   441   fixes H and G (structure)
   442   assumes subset: "H \<subseteq> carrier G"
   443     and m_closed [intro, simp]: "\<lbrakk>x \<in> H; y \<in> H\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> H"
   444     and one_closed [simp]: "\<one> \<in> H"
   445     and m_inv_closed [intro,simp]: "x \<in> H \<Longrightarrow> inv x \<in> H"
   446 
   447 lemma (in subgroup) is_subgroup:
   448   "subgroup H G" by (rule subgroup_axioms)
   449 
   450 declare (in subgroup) group.intro [intro]
   451 
   452 lemma (in subgroup) mem_carrier [simp]:
   453   "x \<in> H \<Longrightarrow> x \<in> carrier G"
   454   using subset by blast
   455 
   456 lemma subgroup_imp_subset:
   457   "subgroup H G \<Longrightarrow> H \<subseteq> carrier G"
   458   by (rule subgroup.subset)
   459 
   460 lemma (in subgroup) subgroup_is_group [intro]:
   461   assumes "group G"
   462   shows "group (G\<lparr>carrier := H\<rparr>)"
   463 proof -
   464   interpret group G by fact
   465   show ?thesis
   466     apply (rule monoid.group_l_invI)
   467     apply (unfold_locales) [1]
   468     apply (auto intro: m_assoc l_inv mem_carrier)
   469     done
   470 qed
   471 
   472 text \<open>
   473   Since @{term H} is nonempty, it contains some element @{term x}.  Since
   474   it is closed under inverse, it contains @{text "inv x"}.  Since
   475   it is closed under product, it contains @{text "x \<otimes> inv x = \<one>"}.
   476 \<close>
   477 
   478 lemma (in group) one_in_subset:
   479   "[| H \<subseteq> carrier G; H \<noteq> {}; \<forall>a \<in> H. inv a \<in> H; \<forall>a\<in>H. \<forall>b\<in>H. a \<otimes> b \<in> H |]
   480    ==> \<one> \<in> H"
   481 by force
   482 
   483 text \<open>A characterization of subgroups: closed, non-empty subset.\<close>
   484 
   485 lemma (in group) subgroupI:
   486   assumes subset: "H \<subseteq> carrier G" and non_empty: "H \<noteq> {}"
   487     and inv: "!!a. a \<in> H \<Longrightarrow> inv a \<in> H"
   488     and mult: "!!a b. \<lbrakk>a \<in> H; b \<in> H\<rbrakk> \<Longrightarrow> a \<otimes> b \<in> H"
   489   shows "subgroup H G"
   490 proof (simp add: subgroup_def assms)
   491   show "\<one> \<in> H" by (rule one_in_subset) (auto simp only: assms)
   492 qed
   493 
   494 declare monoid.one_closed [iff] group.inv_closed [simp]
   495   monoid.l_one [simp] monoid.r_one [simp] group.inv_inv [simp]
   496 
   497 lemma subgroup_nonempty:
   498   "~ subgroup {} G"
   499   by (blast dest: subgroup.one_closed)
   500 
   501 lemma (in subgroup) finite_imp_card_positive:
   502   "finite (carrier G) ==> 0 < card H"
   503 proof (rule classical)
   504   assume "finite (carrier G)" and a: "~ 0 < card H"
   505   then have "finite H" by (blast intro: finite_subset [OF subset])
   506   with is_subgroup a have "subgroup {} G" by simp
   507   with subgroup_nonempty show ?thesis by contradiction
   508 qed
   509 
   510 (*
   511 lemma (in monoid) Units_subgroup:
   512   "subgroup (Units G) G"
   513 *)
   514 
   515 
   516 subsection \<open>Direct Products\<close>
   517 
   518 definition
   519   DirProd :: "_ \<Rightarrow> _ \<Rightarrow> ('a \<times> 'b) monoid" (infixr "\<times>\<times>" 80) where
   520   "G \<times>\<times> H =
   521     \<lparr>carrier = carrier G \<times> carrier H,
   522      mult = (\<lambda>(g, h) (g', h'). (g \<otimes>\<^bsub>G\<^esub> g', h \<otimes>\<^bsub>H\<^esub> h')),
   523      one = (\<one>\<^bsub>G\<^esub>, \<one>\<^bsub>H\<^esub>)\<rparr>"
   524 
   525 lemma DirProd_monoid:
   526   assumes "monoid G" and "monoid H"
   527   shows "monoid (G \<times>\<times> H)"
   528 proof -
   529   interpret G: monoid G by fact
   530   interpret H: monoid H by fact
   531   from assms
   532   show ?thesis by (unfold monoid_def DirProd_def, auto) 
   533 qed
   534 
   535 
   536 text\<open>Does not use the previous result because it's easier just to use auto.\<close>
   537 lemma DirProd_group:
   538   assumes "group G" and "group H"
   539   shows "group (G \<times>\<times> H)"
   540 proof -
   541   interpret G: group G by fact
   542   interpret H: group H by fact
   543   show ?thesis by (rule groupI)
   544      (auto intro: G.m_assoc H.m_assoc G.l_inv H.l_inv
   545            simp add: DirProd_def)
   546 qed
   547 
   548 lemma carrier_DirProd [simp]:
   549      "carrier (G \<times>\<times> H) = carrier G \<times> carrier H"
   550   by (simp add: DirProd_def)
   551 
   552 lemma one_DirProd [simp]:
   553      "\<one>\<^bsub>G \<times>\<times> H\<^esub> = (\<one>\<^bsub>G\<^esub>, \<one>\<^bsub>H\<^esub>)"
   554   by (simp add: DirProd_def)
   555 
   556 lemma mult_DirProd [simp]:
   557      "(g, h) \<otimes>\<^bsub>(G \<times>\<times> H)\<^esub> (g', h') = (g \<otimes>\<^bsub>G\<^esub> g', h \<otimes>\<^bsub>H\<^esub> h')"
   558   by (simp add: DirProd_def)
   559 
   560 lemma inv_DirProd [simp]:
   561   assumes "group G" and "group H"
   562   assumes g: "g \<in> carrier G"
   563       and h: "h \<in> carrier H"
   564   shows "m_inv (G \<times>\<times> H) (g, h) = (inv\<^bsub>G\<^esub> g, inv\<^bsub>H\<^esub> h)"
   565 proof -
   566   interpret G: group G by fact
   567   interpret H: group H by fact
   568   interpret Prod: group "G \<times>\<times> H"
   569     by (auto intro: DirProd_group group.intro group.axioms assms)
   570   show ?thesis by (simp add: Prod.inv_equality g h)
   571 qed
   572 
   573 
   574 subsection \<open>Homomorphisms and Isomorphisms\<close>
   575 
   576 definition
   577   hom :: "_ => _ => ('a => 'b) set" where
   578   "hom G H =
   579     {h. h \<in> carrier G \<rightarrow> carrier H &
   580       (\<forall>x \<in> carrier G. \<forall>y \<in> carrier G. h (x \<otimes>\<^bsub>G\<^esub> y) = h x \<otimes>\<^bsub>H\<^esub> h y)}"
   581 
   582 lemma (in group) hom_compose:
   583   "[|h \<in> hom G H; i \<in> hom H I|] ==> compose (carrier G) i h \<in> hom G I"
   584 by (fastforce simp add: hom_def compose_def)
   585 
   586 definition
   587   iso :: "_ => _ => ('a => 'b) set" (infixr "\<cong>" 60)
   588   where "G \<cong> H = {h. h \<in> hom G H & bij_betw h (carrier G) (carrier H)}"
   589 
   590 lemma iso_refl: "(%x. x) \<in> G \<cong> G"
   591 by (simp add: iso_def hom_def inj_on_def bij_betw_def Pi_def)
   592 
   593 lemma (in group) iso_sym:
   594      "h \<in> G \<cong> H \<Longrightarrow> inv_into (carrier G) h \<in> H \<cong> G"
   595 apply (simp add: iso_def bij_betw_inv_into) 
   596 apply (subgoal_tac "inv_into (carrier G) h \<in> carrier H \<rightarrow> carrier G") 
   597  prefer 2 apply (simp add: bij_betw_imp_funcset [OF bij_betw_inv_into]) 
   598 apply (simp add: hom_def bij_betw_def inv_into_f_eq f_inv_into_f Pi_def)
   599 done
   600 
   601 lemma (in group) iso_trans: 
   602      "[|h \<in> G \<cong> H; i \<in> H \<cong> I|] ==> (compose (carrier G) i h) \<in> G \<cong> I"
   603 by (auto simp add: iso_def hom_compose bij_betw_compose)
   604 
   605 lemma DirProd_commute_iso:
   606   shows "(\<lambda>(x,y). (y,x)) \<in> (G \<times>\<times> H) \<cong> (H \<times>\<times> G)"
   607 by (auto simp add: iso_def hom_def inj_on_def bij_betw_def)
   608 
   609 lemma DirProd_assoc_iso:
   610   shows "(\<lambda>(x,y,z). (x,(y,z))) \<in> (G \<times>\<times> H \<times>\<times> I) \<cong> (G \<times>\<times> (H \<times>\<times> I))"
   611 by (auto simp add: iso_def hom_def inj_on_def bij_betw_def)
   612 
   613 
   614 text\<open>Basis for homomorphism proofs: we assume two groups @{term G} and
   615   @{term H}, with a homomorphism @{term h} between them\<close>
   616 locale group_hom = G?: group G + H?: group H for G (structure) and H (structure) +
   617   fixes h
   618   assumes homh: "h \<in> hom G H"
   619 
   620 lemma (in group_hom) hom_mult [simp]:
   621   "[| x \<in> carrier G; y \<in> carrier G |] ==> h (x \<otimes>\<^bsub>G\<^esub> y) = h x \<otimes>\<^bsub>H\<^esub> h y"
   622 proof -
   623   assume "x \<in> carrier G" "y \<in> carrier G"
   624   with homh [unfolded hom_def] show ?thesis by simp
   625 qed
   626 
   627 lemma (in group_hom) hom_closed [simp]:
   628   "x \<in> carrier G ==> h x \<in> carrier H"
   629 proof -
   630   assume "x \<in> carrier G"
   631   with homh [unfolded hom_def] show ?thesis by auto
   632 qed
   633 
   634 lemma (in group_hom) one_closed [simp]:
   635   "h \<one> \<in> carrier H"
   636   by simp
   637 
   638 lemma (in group_hom) hom_one [simp]:
   639   "h \<one> = \<one>\<^bsub>H\<^esub>"
   640 proof -
   641   have "h \<one> \<otimes>\<^bsub>H\<^esub> \<one>\<^bsub>H\<^esub> = h \<one> \<otimes>\<^bsub>H\<^esub> h \<one>"
   642     by (simp add: hom_mult [symmetric] del: hom_mult)
   643   then show ?thesis by (simp del: r_one)
   644 qed
   645 
   646 lemma (in group_hom) inv_closed [simp]:
   647   "x \<in> carrier G ==> h (inv x) \<in> carrier H"
   648   by simp
   649 
   650 lemma (in group_hom) hom_inv [simp]:
   651   "x \<in> carrier G ==> h (inv x) = inv\<^bsub>H\<^esub> (h x)"
   652 proof -
   653   assume x: "x \<in> carrier G"
   654   then have "h x \<otimes>\<^bsub>H\<^esub> h (inv x) = \<one>\<^bsub>H\<^esub>"
   655     by (simp add: hom_mult [symmetric] del: hom_mult)
   656   also from x have "... = h x \<otimes>\<^bsub>H\<^esub> inv\<^bsub>H\<^esub> (h x)"
   657     by (simp add: hom_mult [symmetric] del: hom_mult)
   658   finally have "h x \<otimes>\<^bsub>H\<^esub> h (inv x) = h x \<otimes>\<^bsub>H\<^esub> inv\<^bsub>H\<^esub> (h x)" .
   659   with x show ?thesis by (simp del: H.r_inv H.Units_r_inv)
   660 qed
   661 
   662 (* Contributed by Joachim Breitner *)
   663 lemma (in group) int_pow_is_hom:
   664   "x \<in> carrier G \<Longrightarrow> (op(^) x) \<in> hom \<lparr> carrier = UNIV, mult = op +, one = 0::int \<rparr> G "
   665   unfolding hom_def by (simp add: int_pow_mult)
   666 
   667 
   668 subsection \<open>Commutative Structures\<close>
   669 
   670 text \<open>
   671   Naming convention: multiplicative structures that are commutative
   672   are called \emph{commutative}, additive structures are called
   673   \emph{Abelian}.
   674 \<close>
   675 
   676 locale comm_monoid = monoid +
   677   assumes m_comm: "\<lbrakk>x \<in> carrier G; y \<in> carrier G\<rbrakk> \<Longrightarrow> x \<otimes> y = y \<otimes> x"
   678 
   679 lemma (in comm_monoid) m_lcomm:
   680   "\<lbrakk>x \<in> carrier G; y \<in> carrier G; z \<in> carrier G\<rbrakk> \<Longrightarrow>
   681    x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
   682 proof -
   683   assume xyz: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
   684   from xyz have "x \<otimes> (y \<otimes> z) = (x \<otimes> y) \<otimes> z" by (simp add: m_assoc)
   685   also from xyz have "... = (y \<otimes> x) \<otimes> z" by (simp add: m_comm)
   686   also from xyz have "... = y \<otimes> (x \<otimes> z)" by (simp add: m_assoc)
   687   finally show ?thesis .
   688 qed
   689 
   690 lemmas (in comm_monoid) m_ac = m_assoc m_comm m_lcomm
   691 
   692 lemma comm_monoidI:
   693   fixes G (structure)
   694   assumes m_closed:
   695       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
   696     and one_closed: "\<one> \<in> carrier G"
   697     and m_assoc:
   698       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   699       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
   700     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
   701     and m_comm:
   702       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
   703   shows "comm_monoid G"
   704   using l_one
   705     by (auto intro!: comm_monoid.intro comm_monoid_axioms.intro monoid.intro 
   706              intro: assms simp: m_closed one_closed m_comm)
   707 
   708 lemma (in monoid) monoid_comm_monoidI:
   709   assumes m_comm:
   710       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
   711   shows "comm_monoid G"
   712   by (rule comm_monoidI) (auto intro: m_assoc m_comm)
   713 
   714 (*lemma (in comm_monoid) r_one [simp]:
   715   "x \<in> carrier G ==> x \<otimes> \<one> = x"
   716 proof -
   717   assume G: "x \<in> carrier G"
   718   then have "x \<otimes> \<one> = \<one> \<otimes> x" by (simp add: m_comm)
   719   also from G have "... = x" by simp
   720   finally show ?thesis .
   721 qed*)
   722 
   723 lemma (in comm_monoid) nat_pow_distr:
   724   "[| x \<in> carrier G; y \<in> carrier G |] ==>
   725   (x \<otimes> y) (^) (n::nat) = x (^) n \<otimes> y (^) n"
   726   by (induct n) (simp, simp add: m_ac)
   727 
   728 locale comm_group = comm_monoid + group
   729 
   730 lemma (in group) group_comm_groupI:
   731   assumes m_comm: "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==>
   732       x \<otimes> y = y \<otimes> x"
   733   shows "comm_group G"
   734   by standard (simp_all add: m_comm)
   735 
   736 lemma comm_groupI:
   737   fixes G (structure)
   738   assumes m_closed:
   739       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
   740     and one_closed: "\<one> \<in> carrier G"
   741     and m_assoc:
   742       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
   743       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
   744     and m_comm:
   745       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
   746     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
   747     and l_inv_ex: "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
   748   shows "comm_group G"
   749   by (fast intro: group.group_comm_groupI groupI assms)
   750 
   751 lemma (in comm_group) inv_mult:
   752   "[| x \<in> carrier G; y \<in> carrier G |] ==> inv (x \<otimes> y) = inv x \<otimes> inv y"
   753   by (simp add: m_ac inv_mult_group)
   754 
   755 
   756 subsection \<open>The Lattice of Subgroups of a Group\<close>
   757 
   758 text_raw \<open>\label{sec:subgroup-lattice}\<close>
   759 
   760 theorem (in group) subgroups_partial_order:
   761   "partial_order \<lparr>carrier = {H. subgroup H G}, eq = op =, le = op \<subseteq>\<rparr>"
   762   by standard simp_all
   763 
   764 lemma (in group) subgroup_self:
   765   "subgroup (carrier G) G"
   766   by (rule subgroupI) auto
   767 
   768 lemma (in group) subgroup_imp_group:
   769   "subgroup H G ==> group (G\<lparr>carrier := H\<rparr>)"
   770   by (erule subgroup.subgroup_is_group) (rule group_axioms)
   771 
   772 lemma (in group) is_monoid [intro, simp]:
   773   "monoid G"
   774   by (auto intro: monoid.intro m_assoc) 
   775 
   776 lemma (in group) subgroup_inv_equality:
   777   "[| subgroup H G; x \<in> H |] ==> m_inv (G \<lparr>carrier := H\<rparr>) x = inv x"
   778 apply (rule_tac inv_equality [THEN sym])
   779   apply (rule group.l_inv [OF subgroup_imp_group, simplified], assumption+)
   780  apply (rule subsetD [OF subgroup.subset], assumption+)
   781 apply (rule subsetD [OF subgroup.subset], assumption)
   782 apply (rule_tac group.inv_closed [OF subgroup_imp_group, simplified], assumption+)
   783 done
   784 
   785 theorem (in group) subgroups_Inter:
   786   assumes subgr: "(!!H. H \<in> A ==> subgroup H G)"
   787     and not_empty: "A ~= {}"
   788   shows "subgroup (\<Inter>A) G"
   789 proof (rule subgroupI)
   790   from subgr [THEN subgroup.subset] and not_empty
   791   show "\<Inter>A \<subseteq> carrier G" by blast
   792 next
   793   from subgr [THEN subgroup.one_closed]
   794   show "\<Inter>A ~= {}" by blast
   795 next
   796   fix x assume "x \<in> \<Inter>A"
   797   with subgr [THEN subgroup.m_inv_closed]
   798   show "inv x \<in> \<Inter>A" by blast
   799 next
   800   fix x y assume "x \<in> \<Inter>A" "y \<in> \<Inter>A"
   801   with subgr [THEN subgroup.m_closed]
   802   show "x \<otimes> y \<in> \<Inter>A" by blast
   803 qed
   804 
   805 theorem (in group) subgroups_complete_lattice:
   806   "complete_lattice \<lparr>carrier = {H. subgroup H G}, eq = op =, le = op \<subseteq>\<rparr>"
   807     (is "complete_lattice ?L")
   808 proof (rule partial_order.complete_lattice_criterion1)
   809   show "partial_order ?L" by (rule subgroups_partial_order)
   810 next
   811   have "greatest ?L (carrier G) (carrier ?L)"
   812     by (unfold greatest_def) (simp add: subgroup.subset subgroup_self)
   813   then show "\<exists>G. greatest ?L G (carrier ?L)" ..
   814 next
   815   fix A
   816   assume L: "A \<subseteq> carrier ?L" and non_empty: "A ~= {}"
   817   then have Int_subgroup: "subgroup (\<Inter>A) G"
   818     by (fastforce intro: subgroups_Inter)
   819   have "greatest ?L (\<Inter>A) (Lower ?L A)" (is "greatest _ ?Int _")
   820   proof (rule greatest_LowerI)
   821     fix H
   822     assume H: "H \<in> A"
   823     with L have subgroupH: "subgroup H G" by auto
   824     from subgroupH have groupH: "group (G \<lparr>carrier := H\<rparr>)" (is "group ?H")
   825       by (rule subgroup_imp_group)
   826     from groupH have monoidH: "monoid ?H"
   827       by (rule group.is_monoid)
   828     from H have Int_subset: "?Int \<subseteq> H" by fastforce
   829     then show "le ?L ?Int H" by simp
   830   next
   831     fix H
   832     assume H: "H \<in> Lower ?L A"
   833     with L Int_subgroup show "le ?L H ?Int"
   834       by (fastforce simp: Lower_def intro: Inter_greatest)
   835   next
   836     show "A \<subseteq> carrier ?L" by (rule L)
   837   next
   838     show "?Int \<in> carrier ?L" by simp (rule Int_subgroup)
   839   qed
   840   then show "\<exists>I. greatest ?L I (Lower ?L A)" ..
   841 qed
   842 
   843 end