src/HOL/Topological_Spaces.thy
author wenzelm
Tue Sep 03 22:04:23 2013 +0200 (2013-09-03)
changeset 53381 355a4cac5440
parent 53374 a14d2a854c02
child 53859 e6cb01686f7b
permissions -rw-r--r--
tuned proofs -- less guessing;
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 subsection {* Topological space *}
    13 
    14 class "open" =
    15   fixes "open" :: "'a set \<Rightarrow> bool"
    16 
    17 class topological_space = "open" +
    18   assumes open_UNIV [simp, intro]: "open UNIV"
    19   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    20   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    21 begin
    22 
    23 definition
    24   closed :: "'a set \<Rightarrow> bool" where
    25   "closed S \<longleftrightarrow> open (- S)"
    26 
    27 lemma open_empty [intro, simp]: "open {}"
    28   using open_Union [of "{}"] by simp
    29 
    30 lemma open_Un [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    31   using open_Union [of "{S, T}"] by simp
    32 
    33 lemma open_UN [intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    34   unfolding SUP_def by (rule open_Union) auto
    35 
    36 lemma open_Inter [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    37   by (induct set: finite) auto
    38 
    39 lemma open_INT [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    40   unfolding INF_def by (rule open_Inter) auto
    41 
    42 lemma openI:
    43   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    44   shows "open S"
    45 proof -
    46   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    47   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    48   ultimately show "open S" by simp
    49 qed
    50 
    51 lemma closed_empty [intro, simp]:  "closed {}"
    52   unfolding closed_def by simp
    53 
    54 lemma closed_Un [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    55   unfolding closed_def by auto
    56 
    57 lemma closed_UNIV [intro, simp]: "closed UNIV"
    58   unfolding closed_def by simp
    59 
    60 lemma closed_Int [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    61   unfolding closed_def by auto
    62 
    63 lemma closed_INT [intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    64   unfolding closed_def by auto
    65 
    66 lemma closed_Inter [intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    67   unfolding closed_def uminus_Inf by auto
    68 
    69 lemma closed_Union [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    70   by (induct set: finite) auto
    71 
    72 lemma closed_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    73   unfolding SUP_def by (rule closed_Union) auto
    74 
    75 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    76   unfolding closed_def by simp
    77 
    78 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    79   unfolding closed_def by simp
    80 
    81 lemma open_Diff [intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    82   unfolding closed_open Diff_eq by (rule open_Int)
    83 
    84 lemma closed_Diff [intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    85   unfolding open_closed Diff_eq by (rule closed_Int)
    86 
    87 lemma open_Compl [intro]: "closed S \<Longrightarrow> open (- S)"
    88   unfolding closed_open .
    89 
    90 lemma closed_Compl [intro]: "open S \<Longrightarrow> closed (- S)"
    91   unfolding open_closed .
    92 
    93 end
    94 
    95 subsection{* Hausdorff and other separation properties *}
    96 
    97 class t0_space = topological_space +
    98   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
    99 
   100 class t1_space = topological_space +
   101   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   102 
   103 instance t1_space \<subseteq> t0_space
   104 proof qed (fast dest: t1_space)
   105 
   106 lemma separation_t1:
   107   fixes x y :: "'a::t1_space"
   108   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   109   using t1_space[of x y] by blast
   110 
   111 lemma closed_singleton:
   112   fixes a :: "'a::t1_space"
   113   shows "closed {a}"
   114 proof -
   115   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   116   have "open ?T" by (simp add: open_Union)
   117   also have "?T = - {a}"
   118     by (simp add: set_eq_iff separation_t1, auto)
   119   finally show "closed {a}" unfolding closed_def .
   120 qed
   121 
   122 lemma closed_insert [simp]:
   123   fixes a :: "'a::t1_space"
   124   assumes "closed S" shows "closed (insert a S)"
   125 proof -
   126   from closed_singleton assms
   127   have "closed ({a} \<union> S)" by (rule closed_Un)
   128   thus "closed (insert a S)" by simp
   129 qed
   130 
   131 lemma finite_imp_closed:
   132   fixes S :: "'a::t1_space set"
   133   shows "finite S \<Longrightarrow> closed S"
   134 by (induct set: finite, simp_all)
   135 
   136 text {* T2 spaces are also known as Hausdorff spaces. *}
   137 
   138 class t2_space = topological_space +
   139   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   140 
   141 instance t2_space \<subseteq> t1_space
   142 proof qed (fast dest: hausdorff)
   143 
   144 lemma separation_t2:
   145   fixes x y :: "'a::t2_space"
   146   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   147   using hausdorff[of x y] by blast
   148 
   149 lemma separation_t0:
   150   fixes x y :: "'a::t0_space"
   151   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   152   using t0_space[of x y] by blast
   153 
   154 text {* A perfect space is a topological space with no isolated points. *}
   155 
   156 class perfect_space = topological_space +
   157   assumes not_open_singleton: "\<not> open {x}"
   158 
   159 
   160 subsection {* Generators for toplogies *}
   161 
   162 inductive generate_topology for S where
   163   UNIV: "generate_topology S UNIV"
   164 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   165 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   166 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   167 
   168 hide_fact (open) UNIV Int UN Basis 
   169 
   170 lemma generate_topology_Union: 
   171   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   172   unfolding SUP_def by (intro generate_topology.UN) auto
   173 
   174 lemma topological_space_generate_topology:
   175   "class.topological_space (generate_topology S)"
   176   by default (auto intro: generate_topology.intros)
   177 
   178 subsection {* Order topologies *}
   179 
   180 class order_topology = order + "open" +
   181   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   182 begin
   183 
   184 subclass topological_space
   185   unfolding open_generated_order
   186   by (rule topological_space_generate_topology)
   187 
   188 lemma open_greaterThan [simp]: "open {a <..}"
   189   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   190 
   191 lemma open_lessThan [simp]: "open {..< a}"
   192   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   193 
   194 lemma open_greaterThanLessThan [simp]: "open {a <..< b}"
   195    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   196 
   197 end
   198 
   199 class linorder_topology = linorder + order_topology
   200 
   201 lemma closed_atMost [simp]: "closed {.. a::'a::linorder_topology}"
   202   by (simp add: closed_open)
   203 
   204 lemma closed_atLeast [simp]: "closed {a::'a::linorder_topology ..}"
   205   by (simp add: closed_open)
   206 
   207 lemma closed_atLeastAtMost [simp]: "closed {a::'a::linorder_topology .. b}"
   208 proof -
   209   have "{a .. b} = {a ..} \<inter> {.. b}"
   210     by auto
   211   then show ?thesis
   212     by (simp add: closed_Int)
   213 qed
   214 
   215 lemma (in linorder) less_separate:
   216   assumes "x < y"
   217   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   218 proof (cases "\<exists>z. x < z \<and> z < y")
   219   case True
   220   then obtain z where "x < z \<and> z < y" ..
   221   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   222     by auto
   223   then show ?thesis by blast
   224 next
   225   case False
   226   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   227     by auto
   228   then show ?thesis by blast
   229 qed
   230 
   231 instance linorder_topology \<subseteq> t2_space
   232 proof
   233   fix x y :: 'a
   234   from less_separate[of x y] less_separate[of y x]
   235   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   236     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   237 qed
   238 
   239 lemma (in linorder_topology) open_right:
   240   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   241   using assms unfolding open_generated_order
   242 proof induction
   243   case (Int A B)
   244   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   245   then show ?case by (auto intro!: exI[of _ "min a b"])
   246 next
   247   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   248 qed blast+
   249 
   250 lemma (in linorder_topology) open_left:
   251   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   252   using assms unfolding open_generated_order
   253 proof induction
   254   case (Int A B)
   255   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   256   then show ?case by (auto intro!: exI[of _ "max a b"])
   257 next
   258   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   259 qed blast+
   260 
   261 subsection {* Filters *}
   262 
   263 text {*
   264   This definition also allows non-proper filters.
   265 *}
   266 
   267 locale is_filter =
   268   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   269   assumes True: "F (\<lambda>x. True)"
   270   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   271   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   272 
   273 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   274 proof
   275   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   276 qed
   277 
   278 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   279   using Rep_filter [of F] by simp
   280 
   281 lemma Abs_filter_inverse':
   282   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   283   using assms by (simp add: Abs_filter_inverse)
   284 
   285 
   286 subsubsection {* Eventually *}
   287 
   288 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   289   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   290 
   291 lemma eventually_Abs_filter:
   292   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   293   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   294 
   295 lemma filter_eq_iff:
   296   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   297   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   298 
   299 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   300   unfolding eventually_def
   301   by (rule is_filter.True [OF is_filter_Rep_filter])
   302 
   303 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   304 proof -
   305   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   306   thus "eventually P F" by simp
   307 qed
   308 
   309 lemma eventually_mono:
   310   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   311   unfolding eventually_def
   312   by (rule is_filter.mono [OF is_filter_Rep_filter])
   313 
   314 lemma eventually_conj:
   315   assumes P: "eventually (\<lambda>x. P x) F"
   316   assumes Q: "eventually (\<lambda>x. Q x) F"
   317   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   318   using assms unfolding eventually_def
   319   by (rule is_filter.conj [OF is_filter_Rep_filter])
   320 
   321 lemma eventually_Ball_finite:
   322   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   323   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   324 using assms by (induct set: finite, simp, simp add: eventually_conj)
   325 
   326 lemma eventually_all_finite:
   327   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   328   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   329   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   330 using eventually_Ball_finite [of UNIV P] assms by simp
   331 
   332 lemma eventually_mp:
   333   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   334   assumes "eventually (\<lambda>x. P x) F"
   335   shows "eventually (\<lambda>x. Q x) F"
   336 proof (rule eventually_mono)
   337   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   338   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   339     using assms by (rule eventually_conj)
   340 qed
   341 
   342 lemma eventually_rev_mp:
   343   assumes "eventually (\<lambda>x. P x) F"
   344   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   345   shows "eventually (\<lambda>x. Q x) F"
   346 using assms(2) assms(1) by (rule eventually_mp)
   347 
   348 lemma eventually_conj_iff:
   349   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   350   by (auto intro: eventually_conj elim: eventually_rev_mp)
   351 
   352 lemma eventually_elim1:
   353   assumes "eventually (\<lambda>i. P i) F"
   354   assumes "\<And>i. P i \<Longrightarrow> Q i"
   355   shows "eventually (\<lambda>i. Q i) F"
   356   using assms by (auto elim!: eventually_rev_mp)
   357 
   358 lemma eventually_elim2:
   359   assumes "eventually (\<lambda>i. P i) F"
   360   assumes "eventually (\<lambda>i. Q i) F"
   361   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   362   shows "eventually (\<lambda>i. R i) F"
   363   using assms by (auto elim!: eventually_rev_mp)
   364 
   365 lemma eventually_subst:
   366   assumes "eventually (\<lambda>n. P n = Q n) F"
   367   shows "eventually P F = eventually Q F" (is "?L = ?R")
   368 proof -
   369   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   370       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   371     by (auto elim: eventually_elim1)
   372   then show ?thesis by (auto elim: eventually_elim2)
   373 qed
   374 
   375 ML {*
   376   fun eventually_elim_tac ctxt thms thm =
   377     let
   378       val thy = Proof_Context.theory_of ctxt
   379       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   380       val raw_elim_thm =
   381         (@{thm allI} RS @{thm always_eventually})
   382         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   383         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   384       val cases_prop = prop_of (raw_elim_thm RS thm)
   385       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   386     in
   387       CASES cases (rtac raw_elim_thm 1) thm
   388     end
   389 *}
   390 
   391 method_setup eventually_elim = {*
   392   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   393 *} "elimination of eventually quantifiers"
   394 
   395 
   396 subsubsection {* Finer-than relation *}
   397 
   398 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   399 filter @{term F'}. *}
   400 
   401 instantiation filter :: (type) complete_lattice
   402 begin
   403 
   404 definition le_filter_def:
   405   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   406 
   407 definition
   408   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   409 
   410 definition
   411   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   412 
   413 definition
   414   "bot = Abs_filter (\<lambda>P. True)"
   415 
   416 definition
   417   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   418 
   419 definition
   420   "inf F F' = Abs_filter
   421       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   422 
   423 definition
   424   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   425 
   426 definition
   427   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   428 
   429 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   430   unfolding top_filter_def
   431   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   432 
   433 lemma eventually_bot [simp]: "eventually P bot"
   434   unfolding bot_filter_def
   435   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   436 
   437 lemma eventually_sup:
   438   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   439   unfolding sup_filter_def
   440   by (rule eventually_Abs_filter, rule is_filter.intro)
   441      (auto elim!: eventually_rev_mp)
   442 
   443 lemma eventually_inf:
   444   "eventually P (inf F F') \<longleftrightarrow>
   445    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   446   unfolding inf_filter_def
   447   apply (rule eventually_Abs_filter, rule is_filter.intro)
   448   apply (fast intro: eventually_True)
   449   apply clarify
   450   apply (intro exI conjI)
   451   apply (erule (1) eventually_conj)
   452   apply (erule (1) eventually_conj)
   453   apply simp
   454   apply auto
   455   done
   456 
   457 lemma eventually_Sup:
   458   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   459   unfolding Sup_filter_def
   460   apply (rule eventually_Abs_filter, rule is_filter.intro)
   461   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   462   done
   463 
   464 instance proof
   465   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   466   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   467     by (rule less_filter_def) }
   468   { show "F \<le> F"
   469     unfolding le_filter_def by simp }
   470   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   471     unfolding le_filter_def by simp }
   472   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   473     unfolding le_filter_def filter_eq_iff by fast }
   474   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   475     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   476   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   477     unfolding le_filter_def eventually_inf
   478     by (auto elim!: eventually_mono intro: eventually_conj) }
   479   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   480     unfolding le_filter_def eventually_sup by simp_all }
   481   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   482     unfolding le_filter_def eventually_sup by simp }
   483   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   484     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   485   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   486     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   487   { assume "F \<in> S" thus "F \<le> Sup S"
   488     unfolding le_filter_def eventually_Sup by simp }
   489   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   490     unfolding le_filter_def eventually_Sup by simp }
   491   { show "Inf {} = (top::'a filter)"
   492     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   493       (metis (full_types) Topological_Spaces.top_filter_def always_eventually eventually_top) }
   494   { show "Sup {} = (bot::'a filter)"
   495     by (auto simp: bot_filter_def Sup_filter_def) }
   496 qed
   497 
   498 end
   499 
   500 lemma filter_leD:
   501   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   502   unfolding le_filter_def by simp
   503 
   504 lemma filter_leI:
   505   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   506   unfolding le_filter_def by simp
   507 
   508 lemma eventually_False:
   509   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   510   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   511 
   512 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   513   where "trivial_limit F \<equiv> F = bot"
   514 
   515 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   516   by (rule eventually_False [symmetric])
   517 
   518 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   519   by (cases P) (simp_all add: eventually_False)
   520 
   521 
   522 subsubsection {* Map function for filters *}
   523 
   524 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   525   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   526 
   527 lemma eventually_filtermap:
   528   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   529   unfolding filtermap_def
   530   apply (rule eventually_Abs_filter)
   531   apply (rule is_filter.intro)
   532   apply (auto elim!: eventually_rev_mp)
   533   done
   534 
   535 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   536   by (simp add: filter_eq_iff eventually_filtermap)
   537 
   538 lemma filtermap_filtermap:
   539   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   540   by (simp add: filter_eq_iff eventually_filtermap)
   541 
   542 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   543   unfolding le_filter_def eventually_filtermap by simp
   544 
   545 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   546   by (simp add: filter_eq_iff eventually_filtermap)
   547 
   548 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   549   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   550 
   551 subsubsection {* Order filters *}
   552 
   553 definition at_top :: "('a::order) filter"
   554   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   555 
   556 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   557   unfolding at_top_def
   558 proof (rule eventually_Abs_filter, rule is_filter.intro)
   559   fix P Q :: "'a \<Rightarrow> bool"
   560   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   561   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   562   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   563   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   564 qed auto
   565 
   566 lemma eventually_ge_at_top:
   567   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   568   unfolding eventually_at_top_linorder by auto
   569 
   570 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::unbounded_dense_linorder. \<forall>n>N. P n)"
   571   unfolding eventually_at_top_linorder
   572 proof safe
   573   fix N assume "\<forall>n\<ge>N. P n"
   574   then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   575 next
   576   fix N assume "\<forall>n>N. P n"
   577   moreover obtain y where "N < y" using gt_ex[of N] ..
   578   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   579 qed
   580 
   581 lemma eventually_gt_at_top:
   582   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   583   unfolding eventually_at_top_dense by auto
   584 
   585 definition at_bot :: "('a::order) filter"
   586   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   587 
   588 lemma eventually_at_bot_linorder:
   589   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   590   unfolding at_bot_def
   591 proof (rule eventually_Abs_filter, rule is_filter.intro)
   592   fix P Q :: "'a \<Rightarrow> bool"
   593   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   594   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   595   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   596   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   597 qed auto
   598 
   599 lemma eventually_le_at_bot:
   600   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   601   unfolding eventually_at_bot_linorder by auto
   602 
   603 lemma eventually_at_bot_dense:
   604   fixes P :: "'a::unbounded_dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   605   unfolding eventually_at_bot_linorder
   606 proof safe
   607   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   608 next
   609   fix N assume "\<forall>n<N. P n" 
   610   moreover obtain y where "y < N" using lt_ex[of N] ..
   611   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   612 qed
   613 
   614 lemma eventually_gt_at_bot:
   615   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   616   unfolding eventually_at_bot_dense by auto
   617 
   618 subsection {* Sequentially *}
   619 
   620 abbreviation sequentially :: "nat filter"
   621   where "sequentially == at_top"
   622 
   623 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   624   unfolding at_top_def by simp
   625 
   626 lemma eventually_sequentially:
   627   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   628   by (rule eventually_at_top_linorder)
   629 
   630 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   631   unfolding filter_eq_iff eventually_sequentially by auto
   632 
   633 lemmas trivial_limit_sequentially = sequentially_bot
   634 
   635 lemma eventually_False_sequentially [simp]:
   636   "\<not> eventually (\<lambda>n. False) sequentially"
   637   by (simp add: eventually_False)
   638 
   639 lemma le_sequentially:
   640   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   641   unfolding le_filter_def eventually_sequentially
   642   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   643 
   644 lemma eventually_sequentiallyI:
   645   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   646   shows "eventually P sequentially"
   647 using assms by (auto simp: eventually_sequentially)
   648 
   649 lemma eventually_sequentially_seg:
   650   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   651   unfolding eventually_sequentially
   652   apply safe
   653    apply (rule_tac x="N + k" in exI)
   654    apply rule
   655    apply (erule_tac x="n - k" in allE)
   656    apply auto []
   657   apply (rule_tac x=N in exI)
   658   apply auto []
   659   done
   660 
   661 subsubsection {* Standard filters *}
   662 
   663 definition principal :: "'a set \<Rightarrow> 'a filter" where
   664   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   665 
   666 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   667   unfolding principal_def
   668   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   669 
   670 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   671   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   672 
   673 lemma principal_UNIV[simp]: "principal UNIV = top"
   674   by (auto simp: filter_eq_iff eventually_principal)
   675 
   676 lemma principal_empty[simp]: "principal {} = bot"
   677   by (auto simp: filter_eq_iff eventually_principal)
   678 
   679 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   680   by (auto simp: le_filter_def eventually_principal)
   681 
   682 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   683   unfolding le_filter_def eventually_principal
   684   apply safe
   685   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   686   apply (auto elim: eventually_elim1)
   687   done
   688 
   689 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   690   unfolding eq_iff by simp
   691 
   692 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   693   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   694 
   695 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   696   unfolding filter_eq_iff eventually_inf eventually_principal
   697   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   698 
   699 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   700   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   701 
   702 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   703   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   704 
   705 subsubsection {* Topological filters *}
   706 
   707 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   708   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   709 
   710 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   711   where "at a within s = inf (nhds a) (principal (s - {a}))"
   712 
   713 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   714   "at x \<equiv> at x within (CONST UNIV)"
   715 
   716 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   717   "at_right x \<equiv> at x within {x <..}"
   718 
   719 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   720   "at_left x \<equiv> at x within {..< x}"
   721 
   722 lemma (in topological_space) eventually_nhds:
   723   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   724   unfolding nhds_def
   725 proof (rule eventually_Abs_filter, rule is_filter.intro)
   726   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   727   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" ..
   728 next
   729   fix P Q
   730   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   731      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   732   then obtain S T where
   733     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   734     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   735   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   736     by (simp add: open_Int)
   737   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" ..
   738 qed auto
   739 
   740 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   741   unfolding trivial_limit_def eventually_nhds by simp
   742 
   743 lemma eventually_at_filter:
   744   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   745   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   746 
   747 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   748   unfolding at_within_def by (intro inf_mono) auto
   749 
   750 lemma eventually_at_topological:
   751   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   752   unfolding eventually_nhds eventually_at_filter by simp
   753 
   754 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   755   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   756 
   757 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   758   unfolding trivial_limit_def eventually_at_topological
   759   by (safe, case_tac "S = {a}", simp, fast, fast)
   760 
   761 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   762   by (simp add: at_eq_bot_iff not_open_singleton)
   763 
   764 lemma eventually_at_right:
   765   fixes x :: "'a :: {no_top, linorder_topology}"
   766   shows "eventually P (at_right x) \<longleftrightarrow> (\<exists>b. x < b \<and> (\<forall>z. x < z \<and> z < b \<longrightarrow> P z))"
   767   unfolding eventually_at_topological
   768 proof safe
   769   obtain y where "x < y" using gt_ex[of x] ..
   770   moreover fix S assume "open S" "x \<in> S" note open_right[OF this, of y]
   771   moreover note gt_ex[of x]
   772   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {x<..} \<longrightarrow> P s"
   773   ultimately show "\<exists>b>x. \<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   774     by (auto simp: subset_eq Ball_def)
   775 next
   776   fix b assume "x < b" "\<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   777   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>xa\<in>S. xa \<noteq> x \<longrightarrow> xa \<in> {x<..} \<longrightarrow> P xa)"
   778     by (intro exI[of _ "{..< b}"]) auto
   779 qed
   780 
   781 lemma eventually_at_left:
   782   fixes x :: "'a :: {no_bot, linorder_topology}"
   783   shows "eventually P (at_left x) \<longleftrightarrow> (\<exists>b. x > b \<and> (\<forall>z. b < z \<and> z < x \<longrightarrow> P z))"
   784   unfolding eventually_at_topological
   785 proof safe
   786   obtain y where "y < x" using lt_ex[of x] ..
   787   moreover fix S assume "open S" "x \<in> S" note open_left[OF this, of y]
   788   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s"
   789   ultimately show "\<exists>b<x. \<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   790     by (auto simp: subset_eq Ball_def)
   791 next
   792   fix b assume "b < x" "\<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   793   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s)"
   794     by (intro exI[of _ "{b <..}"]) auto
   795 qed
   796 
   797 lemma trivial_limit_at_left_real [simp]:
   798   "\<not> trivial_limit (at_left (x::'a::{no_bot, unbounded_dense_linorder, linorder_topology}))"
   799   unfolding trivial_limit_def eventually_at_left by (auto dest: dense)
   800 
   801 lemma trivial_limit_at_right_real [simp]:
   802   "\<not> trivial_limit (at_right (x::'a::{no_top, unbounded_dense_linorder, linorder_topology}))"
   803   unfolding trivial_limit_def eventually_at_right by (auto dest: dense)
   804 
   805 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   806   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   807            elim: eventually_elim2 eventually_elim1)
   808 
   809 lemma eventually_at_split:
   810   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   811   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   812 
   813 subsection {* Limits *}
   814 
   815 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   816   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   817 
   818 syntax
   819   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   820 
   821 translations
   822   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   823 
   824 lemma filterlim_iff:
   825   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   826   unfolding filterlim_def le_filter_def eventually_filtermap ..
   827 
   828 lemma filterlim_compose:
   829   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   830   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   831 
   832 lemma filterlim_mono:
   833   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   834   unfolding filterlim_def by (metis filtermap_mono order_trans)
   835 
   836 lemma filterlim_ident: "LIM x F. x :> F"
   837   by (simp add: filterlim_def filtermap_ident)
   838 
   839 lemma filterlim_cong:
   840   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   841   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   842 
   843 lemma filterlim_principal:
   844   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   845   unfolding filterlim_def eventually_filtermap le_principal ..
   846 
   847 lemma filterlim_inf:
   848   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   849   unfolding filterlim_def by simp
   850 
   851 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   852   unfolding filterlim_def filtermap_filtermap ..
   853 
   854 lemma filterlim_sup:
   855   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   856   unfolding filterlim_def filtermap_sup by auto
   857 
   858 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   859   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   860 
   861 subsubsection {* Tendsto *}
   862 
   863 abbreviation (in topological_space)
   864   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   865   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   866 
   867 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   868   "Lim A f = (THE l. (f ---> l) A)"
   869 
   870 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
   871   by simp
   872 
   873 ML {*
   874 
   875 structure Tendsto_Intros = Named_Thms
   876 (
   877   val name = @{binding tendsto_intros}
   878   val description = "introduction rules for tendsto"
   879 )
   880 
   881 *}
   882 
   883 setup {*
   884   Tendsto_Intros.setup #>
   885   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   886     map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])) o Tendsto_Intros.get o Context.proof_of);
   887 *}
   888 
   889 lemma (in topological_space) tendsto_def:
   890    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   891   unfolding filterlim_def
   892 proof safe
   893   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   894   then show "eventually (\<lambda>x. f x \<in> S) F"
   895     unfolding eventually_nhds eventually_filtermap le_filter_def
   896     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   897 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   898 
   899 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   900   unfolding tendsto_def le_filter_def by fast
   901 
   902 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
   903   by (blast intro: tendsto_mono at_le)
   904 
   905 lemma filterlim_at:
   906   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
   907   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   908 
   909 lemma (in topological_space) topological_tendstoI:
   910   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
   911   unfolding tendsto_def by auto
   912 
   913 lemma (in topological_space) topological_tendstoD:
   914   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   915   unfolding tendsto_def by auto
   916 
   917 lemma order_tendstoI:
   918   fixes y :: "_ :: order_topology"
   919   assumes "\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   920   assumes "\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   921   shows "(f ---> y) F"
   922 proof (rule topological_tendstoI)
   923   fix S assume "open S" "y \<in> S"
   924   then show "eventually (\<lambda>x. f x \<in> S) F"
   925     unfolding open_generated_order
   926   proof induct
   927     case (UN K)
   928     then obtain k where "y \<in> k" "k \<in> K" by auto
   929     with UN(2)[of k] show ?case
   930       by (auto elim: eventually_elim1)
   931   qed (insert assms, auto elim: eventually_elim2)
   932 qed
   933 
   934 lemma order_tendstoD:
   935   fixes y :: "_ :: order_topology"
   936   assumes y: "(f ---> y) F"
   937   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   938     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   939   using topological_tendstoD[OF y, of "{..< a}"] topological_tendstoD[OF y, of "{a <..}"] by auto
   940 
   941 lemma order_tendsto_iff: 
   942   fixes f :: "_ \<Rightarrow> 'a :: order_topology"
   943   shows "(f ---> x) F \<longleftrightarrow>(\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   944   by (metis order_tendstoI order_tendstoD)
   945 
   946 lemma tendsto_bot [simp]: "(f ---> a) bot"
   947   unfolding tendsto_def by simp
   948 
   949 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
   950   unfolding tendsto_def eventually_at_topological by auto
   951 
   952 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   953   by (simp add: tendsto_def)
   954 
   955 lemma (in t2_space) tendsto_unique:
   956   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   957   shows "a = b"
   958 proof (rule ccontr)
   959   assume "a \<noteq> b"
   960   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   961     using hausdorff [OF `a \<noteq> b`] by fast
   962   have "eventually (\<lambda>x. f x \<in> U) F"
   963     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   964   moreover
   965   have "eventually (\<lambda>x. f x \<in> V) F"
   966     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   967   ultimately
   968   have "eventually (\<lambda>x. False) F"
   969   proof eventually_elim
   970     case (elim x)
   971     hence "f x \<in> U \<inter> V" by simp
   972     with `U \<inter> V = {}` show ?case by simp
   973   qed
   974   with `\<not> trivial_limit F` show "False"
   975     by (simp add: trivial_limit_def)
   976 qed
   977 
   978 lemma (in t2_space) tendsto_const_iff:
   979   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
   980   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   981 
   982 lemma increasing_tendsto:
   983   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   984   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   985       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   986   shows "(f ---> l) F"
   987   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
   988 
   989 lemma decreasing_tendsto:
   990   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   991   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   992       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   993   shows "(f ---> l) F"
   994   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
   995 
   996 lemma tendsto_sandwich:
   997   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
   998   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   999   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1000   shows "(g ---> c) net"
  1001 proof (rule order_tendstoI)
  1002   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1003     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1004 next
  1005   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1006     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1007 qed
  1008 
  1009 lemma tendsto_le:
  1010   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1011   assumes F: "\<not> trivial_limit F"
  1012   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1013   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1014   shows "y \<le> x"
  1015 proof (rule ccontr)
  1016   assume "\<not> y \<le> x"
  1017   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1018     by (auto simp: not_le)
  1019   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1020     using x y by (auto intro: order_tendstoD)
  1021   with ev have "eventually (\<lambda>x. False) F"
  1022     by eventually_elim (insert xy, fastforce)
  1023   with F show False
  1024     by (simp add: eventually_False)
  1025 qed
  1026 
  1027 lemma tendsto_le_const:
  1028   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1029   assumes F: "\<not> trivial_limit F"
  1030   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>x. a \<le> f x) F"
  1031   shows "a \<le> x"
  1032   using F x tendsto_const a by (rule tendsto_le)
  1033 
  1034 subsubsection {* Rules about @{const Lim} *}
  1035 
  1036 lemma (in t2_space) tendsto_Lim:
  1037   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1038   unfolding Lim_def using tendsto_unique[of net f] by auto
  1039 
  1040 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1041   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1042 
  1043 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1044 
  1045 lemma filterlim_at_top:
  1046   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1047   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1048   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1049 
  1050 lemma filterlim_at_top_dense:
  1051   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1052   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1053   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1054             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1055 
  1056 lemma filterlim_at_top_ge:
  1057   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1058   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1059   unfolding filterlim_at_top
  1060 proof safe
  1061   fix Z assume *: "\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F"
  1062   with *[THEN spec, of "max Z c"] show "eventually (\<lambda>x. Z \<le> f x) F"
  1063     by (auto elim!: eventually_elim1)
  1064 qed simp
  1065 
  1066 lemma filterlim_at_top_at_top:
  1067   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1068   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1069   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1070   assumes Q: "eventually Q at_top"
  1071   assumes P: "eventually P at_top"
  1072   shows "filterlim f at_top at_top"
  1073 proof -
  1074   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1075     unfolding eventually_at_top_linorder by auto
  1076   show ?thesis
  1077   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1078     fix z assume "x \<le> z"
  1079     with x have "P z" by auto
  1080     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1081       by (rule eventually_ge_at_top)
  1082     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1083       by eventually_elim (metis mono bij `P z`)
  1084   qed
  1085 qed
  1086 
  1087 lemma filterlim_at_top_gt:
  1088   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1089   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1090   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1091 
  1092 lemma filterlim_at_bot: 
  1093   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1094   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1095   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1096 
  1097 lemma filterlim_at_bot_le:
  1098   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1099   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1100   unfolding filterlim_at_bot
  1101 proof safe
  1102   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1103   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1104     by (auto elim!: eventually_elim1)
  1105 qed simp
  1106 
  1107 lemma filterlim_at_bot_lt:
  1108   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1109   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1110   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1111 
  1112 lemma filterlim_at_bot_at_right:
  1113   fixes f :: "'a::{no_top, linorder_topology} \<Rightarrow> 'b::linorder"
  1114   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1115   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1116   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1117   assumes P: "eventually P at_bot"
  1118   shows "filterlim f at_bot (at_right a)"
  1119 proof -
  1120   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1121     unfolding eventually_at_bot_linorder by auto
  1122   show ?thesis
  1123   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1124     fix z assume "z \<le> x"
  1125     with x have "P z" by auto
  1126     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1127       using bound[OF bij(2)[OF `P z`]]
  1128       unfolding eventually_at_right by (auto intro!: exI[of _ "g z"])
  1129     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1130       by eventually_elim (metis bij `P z` mono)
  1131   qed
  1132 qed
  1133 
  1134 lemma filterlim_at_top_at_left:
  1135   fixes f :: "'a::{no_bot, linorder_topology} \<Rightarrow> 'b::linorder"
  1136   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1137   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1138   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1139   assumes P: "eventually P at_top"
  1140   shows "filterlim f at_top (at_left a)"
  1141 proof -
  1142   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1143     unfolding eventually_at_top_linorder by auto
  1144   show ?thesis
  1145   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1146     fix z assume "x \<le> z"
  1147     with x have "P z" by auto
  1148     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1149       using bound[OF bij(2)[OF `P z`]]
  1150       unfolding eventually_at_left by (auto intro!: exI[of _ "g z"])
  1151     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1152       by eventually_elim (metis bij `P z` mono)
  1153   qed
  1154 qed
  1155 
  1156 lemma filterlim_split_at:
  1157   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1158   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1159 
  1160 lemma filterlim_at_split:
  1161   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1162   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1163 
  1164 
  1165 subsection {* Limits on sequences *}
  1166 
  1167 abbreviation (in topological_space)
  1168   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1169     ("((_)/ ----> (_))" [60, 60] 60) where
  1170   "X ----> L \<equiv> (X ---> L) sequentially"
  1171 
  1172 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1173   "lim X \<equiv> Lim sequentially X"
  1174 
  1175 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1176   "convergent X = (\<exists>L. X ----> L)"
  1177 
  1178 lemma lim_def: "lim X = (THE L. X ----> L)"
  1179   unfolding Lim_def ..
  1180 
  1181 subsubsection {* Monotone sequences and subsequences *}
  1182 
  1183 definition
  1184   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1185     --{*Definition of monotonicity.
  1186         The use of disjunction here complicates proofs considerably.
  1187         One alternative is to add a Boolean argument to indicate the direction.
  1188         Another is to develop the notions of increasing and decreasing first.*}
  1189   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1190 
  1191 definition
  1192   incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1193     --{*Increasing sequence*}
  1194   "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
  1195 
  1196 definition
  1197   decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1198     --{*Decreasing sequence*}
  1199   "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1200 
  1201 definition
  1202   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1203     --{*Definition of subsequence*}
  1204   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1205 
  1206 lemma incseq_mono: "mono f \<longleftrightarrow> incseq f"
  1207   unfolding mono_def incseq_def by auto
  1208 
  1209 lemma incseq_SucI:
  1210   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1211   using lift_Suc_mono_le[of X]
  1212   by (auto simp: incseq_def)
  1213 
  1214 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1215   by (auto simp: incseq_def)
  1216 
  1217 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1218   using incseqD[of A i "Suc i"] by auto
  1219 
  1220 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1221   by (auto intro: incseq_SucI dest: incseq_SucD)
  1222 
  1223 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1224   unfolding incseq_def by auto
  1225 
  1226 lemma decseq_SucI:
  1227   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1228   using order.lift_Suc_mono_le[OF dual_order, of X]
  1229   by (auto simp: decseq_def)
  1230 
  1231 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1232   by (auto simp: decseq_def)
  1233 
  1234 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1235   using decseqD[of A i "Suc i"] by auto
  1236 
  1237 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1238   by (auto intro: decseq_SucI dest: decseq_SucD)
  1239 
  1240 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1241   unfolding decseq_def by auto
  1242 
  1243 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1244   unfolding monoseq_def incseq_def decseq_def ..
  1245 
  1246 lemma monoseq_Suc:
  1247   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1248   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1249 
  1250 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1251 by (simp add: monoseq_def)
  1252 
  1253 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1254 by (simp add: monoseq_def)
  1255 
  1256 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1257 by (simp add: monoseq_Suc)
  1258 
  1259 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1260 by (simp add: monoseq_Suc)
  1261 
  1262 lemma monoseq_minus:
  1263   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1264   assumes "monoseq a"
  1265   shows "monoseq (\<lambda> n. - a n)"
  1266 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1267   case True
  1268   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1269   thus ?thesis by (rule monoI2)
  1270 next
  1271   case False
  1272   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1273   thus ?thesis by (rule monoI1)
  1274 qed
  1275 
  1276 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1277 
  1278 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1279 apply (simp add: subseq_def)
  1280 apply (auto dest!: less_imp_Suc_add)
  1281 apply (induct_tac k)
  1282 apply (auto intro: less_trans)
  1283 done
  1284 
  1285 text{* for any sequence, there is a monotonic subsequence *}
  1286 lemma seq_monosub:
  1287   fixes s :: "nat => 'a::linorder"
  1288   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
  1289 proof cases
  1290   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
  1291   assume *: "\<forall>n. \<exists>p. ?P p n"
  1292   def f \<equiv> "nat_rec (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
  1293   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
  1294   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
  1295   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
  1296   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
  1297   then have "subseq f" unfolding subseq_Suc_iff by auto
  1298   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
  1299   proof (intro disjI2 allI)
  1300     fix n show "s (f (Suc n)) \<le> s (f n)"
  1301     proof (cases n)
  1302       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
  1303     next
  1304       case (Suc m)
  1305       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
  1306       with P_Suc Suc show ?thesis by simp
  1307     qed
  1308   qed
  1309   ultimately show ?thesis by auto
  1310 next
  1311   let "?P p m" = "m < p \<and> s m < s p"
  1312   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1313   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1314   def f \<equiv> "nat_rec (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
  1315   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
  1316   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
  1317   have P_0: "?P (f 0) (Suc N)"
  1318     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
  1319   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
  1320       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
  1321   note P' = this
  1322   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
  1323       by (induct i) (insert P_0 P', auto) }
  1324   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
  1325     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
  1326   then show ?thesis by auto
  1327 qed
  1328 
  1329 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1330 proof(induct n)
  1331   case 0 thus ?case by simp
  1332 next
  1333   case (Suc n)
  1334   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1335   have "n < f (Suc n)" by arith
  1336   thus ?case by arith
  1337 qed
  1338 
  1339 lemma eventually_subseq:
  1340   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1341   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1342 
  1343 lemma not_eventually_sequentiallyD:
  1344   assumes P: "\<not> eventually P sequentially"
  1345   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1346 proof -
  1347   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1348     unfolding eventually_sequentially by (simp add: not_less)
  1349   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1350     by (auto simp: choice_iff)
  1351   then show ?thesis
  1352     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1353              simp: less_eq_Suc_le subseq_Suc_iff)
  1354 qed
  1355 
  1356 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1357   unfolding filterlim_iff by (metis eventually_subseq)
  1358 
  1359 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1360   unfolding subseq_def by simp
  1361 
  1362 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1363   using assms by (auto simp: subseq_def)
  1364 
  1365 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1366   by (simp add: incseq_def monoseq_def)
  1367 
  1368 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1369   by (simp add: decseq_def monoseq_def)
  1370 
  1371 lemma decseq_eq_incseq:
  1372   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1373   by (simp add: decseq_def incseq_def)
  1374 
  1375 lemma INT_decseq_offset:
  1376   assumes "decseq F"
  1377   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1378 proof safe
  1379   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1380   show "x \<in> F i"
  1381   proof cases
  1382     from x have "x \<in> F n" by auto
  1383     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1384       unfolding decseq_def by simp
  1385     finally show ?thesis .
  1386   qed (insert x, simp)
  1387 qed auto
  1388 
  1389 lemma LIMSEQ_const_iff:
  1390   fixes k l :: "'a::t2_space"
  1391   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1392   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1393 
  1394 lemma LIMSEQ_SUP:
  1395   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1396   by (intro increasing_tendsto)
  1397      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1398 
  1399 lemma LIMSEQ_INF:
  1400   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1401   by (intro decreasing_tendsto)
  1402      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1403 
  1404 lemma LIMSEQ_ignore_initial_segment:
  1405   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1406   unfolding tendsto_def
  1407   by (subst eventually_sequentially_seg[where k=k])
  1408 
  1409 lemma LIMSEQ_offset:
  1410   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1411   unfolding tendsto_def
  1412   by (subst (asm) eventually_sequentially_seg[where k=k])
  1413 
  1414 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1415 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1416 
  1417 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1418 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1419 
  1420 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1421 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1422 
  1423 lemma LIMSEQ_unique:
  1424   fixes a b :: "'a::t2_space"
  1425   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1426   using trivial_limit_sequentially by (rule tendsto_unique)
  1427 
  1428 lemma LIMSEQ_le_const:
  1429   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1430   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1431 
  1432 lemma LIMSEQ_le:
  1433   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1434   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1435 
  1436 lemma LIMSEQ_le_const2:
  1437   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1438   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1439 
  1440 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1441 by (simp add: convergent_def)
  1442 
  1443 lemma convergentI: "(X ----> L) ==> convergent X"
  1444 by (auto simp add: convergent_def)
  1445 
  1446 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1447 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1448 
  1449 lemma convergent_const: "convergent (\<lambda>n. c)"
  1450   by (rule convergentI, rule tendsto_const)
  1451 
  1452 lemma monoseq_le:
  1453   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1454     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1455   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1456 
  1457 lemma LIMSEQ_subseq_LIMSEQ:
  1458   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1459   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1460 
  1461 lemma convergent_subseq_convergent:
  1462   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1463   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1464 
  1465 lemma limI: "X ----> L ==> lim X = L"
  1466 apply (simp add: lim_def)
  1467 apply (blast intro: LIMSEQ_unique)
  1468 done
  1469 
  1470 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1471   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1472 
  1473 subsubsection{*Increasing and Decreasing Series*}
  1474 
  1475 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1476   by (metis incseq_def LIMSEQ_le_const)
  1477 
  1478 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1479   by (metis decseq_def LIMSEQ_le_const2)
  1480 
  1481 subsection {* First countable topologies *}
  1482 
  1483 class first_countable_topology = topological_space +
  1484   assumes first_countable_basis:
  1485     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1486 
  1487 lemma (in first_countable_topology) countable_basis_at_decseq:
  1488   obtains A :: "nat \<Rightarrow> 'a set" where
  1489     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1490     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1491 proof atomize_elim
  1492   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1493     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1494     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1495   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1496   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1497       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1498   proof (safe intro!: exI[of _ F])
  1499     fix i
  1500     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1501     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1502   next
  1503     fix S assume "open S" "x \<in> S"
  1504     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1505     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1506       by (auto simp: F_def)
  1507     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1508       by (auto simp: eventually_sequentially)
  1509   qed
  1510 qed
  1511 
  1512 lemma (in first_countable_topology) countable_basis:
  1513   obtains A :: "nat \<Rightarrow> 'a set" where
  1514     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1515     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1516 proof atomize_elim
  1517   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1518     "\<And>i. open (A i)"
  1519     "\<And>i. x \<in> A i"
  1520     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1521     by (rule countable_basis_at_decseq) blast
  1522   {
  1523     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1524     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1525       by (auto elim: eventually_elim1 simp: subset_eq)
  1526   }
  1527   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1528     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1529 qed
  1530 
  1531 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1532   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1533   shows "eventually P (inf (nhds a) (principal s))"
  1534 proof (rule ccontr)
  1535   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1536     "\<And>i. open (A i)"
  1537     "\<And>i. a \<in> A i"
  1538     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F ----> a"
  1539     by (rule countable_basis) blast
  1540   assume "\<not> ?thesis"
  1541   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1542     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1543   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1544     by blast
  1545   with A have "F ----> a" by auto
  1546   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1547     using assms F0 by simp
  1548   thus "False" by (simp add: F3)
  1549 qed
  1550 
  1551 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1552   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1553     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1554 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1555   assume "eventually P (inf (nhds a) (principal s))" 
  1556   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1557     by (auto simp: eventually_inf_principal eventually_nhds)
  1558   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1559   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1560     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1561 qed
  1562 
  1563 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1564   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1565   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1566 
  1567 subsection {* Function limit at a point *}
  1568 
  1569 abbreviation
  1570   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1571         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1572   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1573 
  1574 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1575   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1576 
  1577 lemma LIM_const_not_eq[tendsto_intros]:
  1578   fixes a :: "'a::perfect_space"
  1579   fixes k L :: "'b::t2_space"
  1580   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1581   by (simp add: tendsto_const_iff)
  1582 
  1583 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1584 
  1585 lemma LIM_const_eq:
  1586   fixes a :: "'a::perfect_space"
  1587   fixes k L :: "'b::t2_space"
  1588   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1589   by (simp add: tendsto_const_iff)
  1590 
  1591 lemma LIM_unique:
  1592   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1593   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1594   using at_neq_bot by (rule tendsto_unique)
  1595 
  1596 text {* Limits are equal for functions equal except at limit point *}
  1597 
  1598 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1599   unfolding tendsto_def eventually_at_topological by simp
  1600 
  1601 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1602   by (simp add: LIM_equal)
  1603 
  1604 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1605   by simp
  1606 
  1607 lemma tendsto_at_iff_tendsto_nhds:
  1608   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1609   unfolding tendsto_def eventually_at_filter
  1610   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1611 
  1612 lemma tendsto_compose:
  1613   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1614   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1615 
  1616 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1617   unfolding o_def by (rule tendsto_compose)
  1618 
  1619 lemma tendsto_compose_eventually:
  1620   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1621   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1622 
  1623 lemma LIM_compose_eventually:
  1624   assumes f: "f -- a --> b"
  1625   assumes g: "g -- b --> c"
  1626   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1627   shows "(\<lambda>x. g (f x)) -- a --> c"
  1628   using g f inj by (rule tendsto_compose_eventually)
  1629 
  1630 subsubsection {* Relation of LIM and LIMSEQ *}
  1631 
  1632 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1633   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1634     eventually P (at a within s)"
  1635   unfolding at_within_def
  1636   by (intro sequentially_imp_eventually_nhds_within) auto
  1637 
  1638 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1639   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1640   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1641 
  1642 lemma LIMSEQ_SEQ_conv1:
  1643   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1644   assumes f: "f -- a --> l"
  1645   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1646   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1647 
  1648 lemma LIMSEQ_SEQ_conv2:
  1649   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1650   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1651   shows "f -- a --> l"
  1652   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1653 
  1654 lemma LIMSEQ_SEQ_conv:
  1655   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1656    (X -- a --> (L::'b::topological_space))"
  1657   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1658 
  1659 subsection {* Continuity *}
  1660 
  1661 subsubsection {* Continuity on a set *}
  1662 
  1663 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1664   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  1665 
  1666 lemma continuous_on_cong [cong]:
  1667   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1668   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1669 
  1670 lemma continuous_on_topological:
  1671   "continuous_on s f \<longleftrightarrow>
  1672     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1673   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1674 
  1675 lemma continuous_on_open_invariant:
  1676   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1677 proof safe
  1678   fix B :: "'b set" assume "continuous_on s f" "open B"
  1679   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1680     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1681   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1682     unfolding bchoice_iff ..
  1683   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1684     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1685 next
  1686   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1687   show "continuous_on s f"
  1688     unfolding continuous_on_topological
  1689   proof safe
  1690     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1691     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1692     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1693       by (intro exI[of _ A]) auto
  1694   qed
  1695 qed
  1696 
  1697 lemma continuous_on_open_vimage:
  1698   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1699   unfolding continuous_on_open_invariant
  1700   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1701 
  1702 lemma continuous_on_closed_invariant:
  1703   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1704 proof -
  1705   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1706     by (metis double_compl)
  1707   show ?thesis
  1708     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1709 qed
  1710 
  1711 lemma continuous_on_closed_vimage:
  1712   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1713   unfolding continuous_on_closed_invariant
  1714   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1715 
  1716 lemma continuous_on_open_Union:
  1717   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1718   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1719 
  1720 lemma continuous_on_open_UN:
  1721   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1722   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  1723 
  1724 lemma continuous_on_closed_Un:
  1725   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1726   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1727 
  1728 lemma continuous_on_If:
  1729   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1730     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1731   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1732 proof-
  1733   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1734     by auto
  1735   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1736     by simp_all
  1737   with closed show ?thesis
  1738     by (rule continuous_on_closed_Un)
  1739 qed
  1740 
  1741 ML {*
  1742 
  1743 structure Continuous_On_Intros = Named_Thms
  1744 (
  1745   val name = @{binding continuous_on_intros}
  1746   val description = "Structural introduction rules for setwise continuity"
  1747 )
  1748 
  1749 *}
  1750 
  1751 setup Continuous_On_Intros.setup
  1752 
  1753 lemma continuous_on_id[continuous_on_intros]: "continuous_on s (\<lambda>x. x)"
  1754   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  1755 
  1756 lemma continuous_on_const[continuous_on_intros]: "continuous_on s (\<lambda>x. c)"
  1757   unfolding continuous_on_def by (auto intro: tendsto_const)
  1758 
  1759 lemma continuous_on_compose[continuous_on_intros]:
  1760   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1761   unfolding continuous_on_topological by simp metis
  1762 
  1763 lemma continuous_on_compose2:
  1764   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1765   using continuous_on_compose[of s f g] by (simp add: comp_def)
  1766 
  1767 subsubsection {* Continuity at a point *}
  1768 
  1769 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1770   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  1771 
  1772 ML {*
  1773 
  1774 structure Continuous_Intros = Named_Thms
  1775 (
  1776   val name = @{binding continuous_intros}
  1777   val description = "Structural introduction rules for pointwise continuity"
  1778 )
  1779 
  1780 *}
  1781 
  1782 setup Continuous_Intros.setup
  1783 
  1784 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1785   unfolding continuous_def by auto
  1786 
  1787 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1788   by simp
  1789 
  1790 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  1791   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1792 
  1793 lemma continuous_within_topological:
  1794   "continuous (at x within s) f \<longleftrightarrow>
  1795     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1796   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1797 
  1798 lemma continuous_within_compose[continuous_intros]:
  1799   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1800   continuous (at x within s) (g o f)"
  1801   by (simp add: continuous_within_topological) metis
  1802 
  1803 lemma continuous_within_compose2:
  1804   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1805   continuous (at x within s) (\<lambda>x. g (f x))"
  1806   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1807 
  1808 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  1809   using continuous_within[of x UNIV f] by simp
  1810 
  1811 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1812   unfolding continuous_within by (rule tendsto_ident_at)
  1813 
  1814 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1815   unfolding continuous_def by (rule tendsto_const)
  1816 
  1817 lemma continuous_on_eq_continuous_within:
  1818   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1819   unfolding continuous_on_def continuous_within ..
  1820 
  1821 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  1822   "isCont f a \<equiv> continuous (at a) f"
  1823 
  1824 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  1825   by (rule continuous_at)
  1826 
  1827 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1828   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1829 
  1830 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1831   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1832 
  1833 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1834   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1835 
  1836 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1837   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  1838 
  1839 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  1840   by simp
  1841 
  1842 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  1843   using continuous_ident by (rule isContI_continuous)
  1844 
  1845 lemmas isCont_const = continuous_const
  1846 
  1847 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1848   unfolding isCont_def by (rule tendsto_compose)
  1849 
  1850 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1851   unfolding o_def by (rule isCont_o2)
  1852 
  1853 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1854   unfolding isCont_def by (rule tendsto_compose)
  1855 
  1856 lemma continuous_within_compose3:
  1857   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1858   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  1859 
  1860 subsubsection{* Open-cover compactness *}
  1861 
  1862 context topological_space
  1863 begin
  1864 
  1865 definition compact :: "'a set \<Rightarrow> bool" where
  1866   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  1867     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  1868 
  1869 lemma compactI:
  1870   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  1871   shows "compact s"
  1872   unfolding compact_eq_heine_borel using assms by metis
  1873 
  1874 lemma compact_empty[simp]: "compact {}"
  1875   by (auto intro!: compactI)
  1876 
  1877 lemma compactE:
  1878   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  1879   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  1880   using assms unfolding compact_eq_heine_borel by metis
  1881 
  1882 lemma compactE_image:
  1883   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  1884   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  1885   using assms unfolding ball_simps[symmetric] SUP_def
  1886   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  1887 
  1888 lemma compact_inter_closed [intro]:
  1889   assumes "compact s" and "closed t"
  1890   shows "compact (s \<inter> t)"
  1891 proof (rule compactI)
  1892   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  1893   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  1894   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  1895   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  1896     using `compact s` unfolding compact_eq_heine_borel by auto
  1897   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  1898   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  1899     by (intro exI[of _ "D - {-t}"]) auto
  1900 qed
  1901 
  1902 end
  1903 
  1904 lemma (in t2_space) compact_imp_closed:
  1905   assumes "compact s" shows "closed s"
  1906 unfolding closed_def
  1907 proof (rule openI)
  1908   fix y assume "y \<in> - s"
  1909   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  1910   note `compact s`
  1911   moreover have "\<forall>u\<in>?C. open u" by simp
  1912   moreover have "s \<subseteq> \<Union>?C"
  1913   proof
  1914     fix x assume "x \<in> s"
  1915     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  1916     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  1917       by (rule hausdorff)
  1918     with `x \<in> s` show "x \<in> \<Union>?C"
  1919       unfolding eventually_nhds by auto
  1920   qed
  1921   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  1922     by (rule compactE)
  1923   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  1924   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  1925     by (simp add: eventually_Ball_finite)
  1926   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  1927     by (auto elim!: eventually_mono [rotated])
  1928   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  1929     by (simp add: eventually_nhds subset_eq)
  1930 qed
  1931 
  1932 lemma compact_continuous_image:
  1933   assumes f: "continuous_on s f" and s: "compact s"
  1934   shows "compact (f ` s)"
  1935 proof (rule compactI)
  1936   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  1937   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  1938     unfolding continuous_on_open_invariant by blast
  1939   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  1940     unfolding bchoice_iff ..
  1941   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  1942     by (fastforce simp add: subset_eq set_eq_iff)+
  1943   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  1944   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  1945     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  1946 qed
  1947 
  1948 lemma continuous_on_inv:
  1949   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1950   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  1951   shows "continuous_on (f ` s) g"
  1952 unfolding continuous_on_topological
  1953 proof (clarsimp simp add: assms(3))
  1954   fix x :: 'a and B :: "'a set"
  1955   assume "x \<in> s" and "open B" and "x \<in> B"
  1956   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  1957     using assms(3) by (auto, metis)
  1958   have "continuous_on (s - B) f"
  1959     using `continuous_on s f` Diff_subset
  1960     by (rule continuous_on_subset)
  1961   moreover have "compact (s - B)"
  1962     using `open B` and `compact s`
  1963     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  1964   ultimately have "compact (f ` (s - B))"
  1965     by (rule compact_continuous_image)
  1966   hence "closed (f ` (s - B))"
  1967     by (rule compact_imp_closed)
  1968   hence "open (- f ` (s - B))"
  1969     by (rule open_Compl)
  1970   moreover have "f x \<in> - f ` (s - B)"
  1971     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  1972   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  1973     by (simp add: 1)
  1974   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  1975     by fast
  1976 qed
  1977 
  1978 lemma continuous_on_inv_into:
  1979   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1980   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  1981   shows "continuous_on (f ` s) (the_inv_into s f)"
  1982   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  1983 
  1984 lemma (in linorder_topology) compact_attains_sup:
  1985   assumes "compact S" "S \<noteq> {}"
  1986   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  1987 proof (rule classical)
  1988   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  1989   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  1990     by (metis not_le)
  1991   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  1992     by auto
  1993   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  1994     by (erule compactE_image)
  1995   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  1996     by (auto intro!: Max_in)
  1997   with C have "S \<subseteq> {..< Max (t`C)}"
  1998     by (auto intro: less_le_trans simp: subset_eq)
  1999   with t Max `C \<subseteq> S` show ?thesis
  2000     by fastforce
  2001 qed
  2002 
  2003 lemma (in linorder_topology) compact_attains_inf:
  2004   assumes "compact S" "S \<noteq> {}"
  2005   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2006 proof (rule classical)
  2007   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2008   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2009     by (metis not_le)
  2010   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2011     by auto
  2012   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2013     by (erule compactE_image)
  2014   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2015     by (auto intro!: Min_in)
  2016   with C have "S \<subseteq> {Min (t`C) <..}"
  2017     by (auto intro: le_less_trans simp: subset_eq)
  2018   with t Min `C \<subseteq> S` show ?thesis
  2019     by fastforce
  2020 qed
  2021 
  2022 lemma continuous_attains_sup:
  2023   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2024   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2025   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2026 
  2027 lemma continuous_attains_inf:
  2028   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2029   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2030   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2031 
  2032 
  2033 subsection {* Connectedness *}
  2034 
  2035 context topological_space
  2036 begin
  2037 
  2038 definition "connected S \<longleftrightarrow>
  2039   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2040 
  2041 lemma connectedI:
  2042   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2043   \<Longrightarrow> connected U"
  2044   by (auto simp: connected_def)
  2045 
  2046 lemma connected_empty[simp]: "connected {}"
  2047   by (auto intro!: connectedI)
  2048 
  2049 end
  2050 
  2051 lemma (in linorder_topology) connectedD_interval:
  2052   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2053   shows "z \<in> U"
  2054 proof -
  2055   have eq: "{..<z} \<union> {z<..} = - {z}"
  2056     by auto
  2057   { assume "z \<notin> U" "x < z" "z < y"
  2058     with xy have "\<not> connected U"
  2059       unfolding connected_def simp_thms
  2060       apply (rule_tac exI[of _ "{..< z}"])
  2061       apply (rule_tac exI[of _ "{z <..}"])
  2062       apply (auto simp add: eq)
  2063       done }
  2064   with assms show "z \<in> U"
  2065     by (metis less_le)
  2066 qed
  2067 
  2068 lemma connected_continuous_image:
  2069   assumes *: "continuous_on s f"
  2070   assumes "connected s"
  2071   shows "connected (f ` s)"
  2072 proof (rule connectedI)
  2073   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2074     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2075   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2076     using * `open A` unfolding continuous_on_open_invariant by metis
  2077   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2078     using * `open B` unfolding continuous_on_open_invariant by metis
  2079 
  2080   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2081   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2082     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2083     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2084   next
  2085     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2086     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2087   qed (insert A' B' A B, auto)
  2088   with `connected s` show False
  2089     unfolding connected_def by blast
  2090 qed
  2091 
  2092 
  2093 section {* Connectedness *}
  2094 
  2095 class linear_continuum_topology = linorder_topology + linear_continuum
  2096 begin
  2097 
  2098 lemma Inf_notin_open:
  2099   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2100   shows "Inf A \<notin> A"
  2101 proof
  2102   assume "Inf A \<in> A"
  2103   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2104     using open_left[of A "Inf A" x] assms by auto
  2105   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2106     by (auto simp: subset_eq)
  2107   then show False
  2108     using cInf_lower[OF `c \<in> A`, of x] bnd by (metis less_imp_le not_le)
  2109 qed
  2110 
  2111 lemma Sup_notin_open:
  2112   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2113   shows "Sup A \<notin> A"
  2114 proof
  2115   assume "Sup A \<in> A"
  2116   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2117     using open_right[of A "Sup A" x] assms by auto
  2118   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2119     by (auto simp: subset_eq)
  2120   then show False
  2121     using cSup_upper[OF `c \<in> A`, of x] bnd by (metis less_imp_le not_le)
  2122 qed
  2123 
  2124 end
  2125 
  2126 instance linear_continuum_topology \<subseteq> perfect_space
  2127 proof
  2128   fix x :: 'a
  2129   obtain y where "x < y \<or> y < x"
  2130     using ex_gt_or_lt [of x] ..
  2131   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2132   show "\<not> open {x}"
  2133     by auto
  2134 qed
  2135 
  2136 lemma connectedI_interval:
  2137   fixes U :: "'a :: linear_continuum_topology set"
  2138   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2139   shows "connected U"
  2140 proof (rule connectedI)
  2141   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2142     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2143 
  2144     let ?z = "Inf (B \<inter> {x <..})"
  2145 
  2146     have "x \<le> ?z" "?z \<le> y"
  2147       using `y \<in> B` `x < y` by (auto intro: cInf_lower[where z=x] cInf_greatest)
  2148     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2149       by (rule *)
  2150     moreover have "?z \<notin> B \<inter> {x <..}"
  2151       using `open B` by (intro Inf_notin_open) auto
  2152     ultimately have "?z \<in> A"
  2153       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2154 
  2155     { assume "?z < y"
  2156       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2157         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2158       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2159         using cInf_less_iff[of "B \<inter> {x <..}" x "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2160         by (auto intro: less_imp_le)
  2161       moreover have "?z \<le> b"
  2162         using `b \<in> B` `x < b`
  2163         by (intro cInf_lower[where z=x]) auto
  2164       moreover have "b \<in> U"
  2165         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2166         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2167       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2168         by (intro bexI[of _ b]) auto }
  2169     then have False
  2170       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2171   note not_disjoint = this
  2172 
  2173   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2174   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2175   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2176   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2177   ultimately show False by (cases x y rule: linorder_cases) auto
  2178 qed
  2179 
  2180 lemma connected_iff_interval:
  2181   fixes U :: "'a :: linear_continuum_topology set"
  2182   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2183   by (auto intro: connectedI_interval dest: connectedD_interval)
  2184 
  2185 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2186   unfolding connected_iff_interval by auto
  2187 
  2188 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2189   unfolding connected_iff_interval by auto
  2190 
  2191 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2192   unfolding connected_iff_interval by auto
  2193 
  2194 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2195   unfolding connected_iff_interval by auto
  2196 
  2197 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2198   unfolding connected_iff_interval by auto
  2199 
  2200 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2201   unfolding connected_iff_interval by auto
  2202 
  2203 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2204   unfolding connected_iff_interval by auto
  2205 
  2206 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2207   unfolding connected_iff_interval by auto
  2208 
  2209 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2210   unfolding connected_iff_interval by auto
  2211 
  2212 lemma connected_contains_Ioo: 
  2213   fixes A :: "'a :: linorder_topology set"
  2214   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2215   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2216 
  2217 subsection {* Intermediate Value Theorem *}
  2218 
  2219 lemma IVT':
  2220   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2221   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2222   assumes *: "continuous_on {a .. b} f"
  2223   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2224 proof -
  2225   have "connected {a..b}"
  2226     unfolding connected_iff_interval by auto
  2227   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2228   show ?thesis
  2229     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2230 qed
  2231 
  2232 lemma IVT2':
  2233   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2234   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2235   assumes *: "continuous_on {a .. b} f"
  2236   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2237 proof -
  2238   have "connected {a..b}"
  2239     unfolding connected_iff_interval by auto
  2240   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2241   show ?thesis
  2242     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2243 qed
  2244 
  2245 lemma IVT:
  2246   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2247   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2248   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2249 
  2250 lemma IVT2:
  2251   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2252   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2253   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2254 
  2255 lemma continuous_inj_imp_mono:
  2256   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2257   assumes x: "a < x" "x < b"
  2258   assumes cont: "continuous_on {a..b} f"
  2259   assumes inj: "inj_on f {a..b}"
  2260   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2261 proof -
  2262   note I = inj_on_iff[OF inj]
  2263   { assume "f x < f a" "f x < f b"
  2264     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2265       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2266       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2267     with x I have False by auto }
  2268   moreover
  2269   { assume "f a < f x" "f b < f x"
  2270     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2271       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2272       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2273     with x I have False by auto }
  2274   ultimately show ?thesis
  2275     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2276 qed
  2277 
  2278 end
  2279