src/HOL/Product_Type.thy
author haftmann
Tue Nov 10 16:11:39 2009 +0100 (2009-11-10)
changeset 33594 357f74e0090c
parent 33275 b497b2574bf6
child 33638 548a34929e98
permissions -rw-r--r--
lemmas about apfst and apsnd
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Inductive
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_set.ML")
    13   ("Tools/inductive_realizer.ML")
    14   ("Tools/Datatype/datatype_realizer.ML")
    15 begin
    16 
    17 subsection {* @{typ bool} is a datatype *}
    18 
    19 rep_datatype True False by (auto intro: bool_induct)
    20 
    21 declare case_split [cases type: bool]
    22   -- "prefer plain propositional version"
    23 
    24 lemma
    25   shows [code]: "eq_class.eq False P \<longleftrightarrow> \<not> P"
    26     and [code]: "eq_class.eq True P \<longleftrightarrow> P" 
    27     and [code]: "eq_class.eq P False \<longleftrightarrow> \<not> P" 
    28     and [code]: "eq_class.eq P True \<longleftrightarrow> P"
    29     and [code nbe]: "eq_class.eq P P \<longleftrightarrow> True"
    30   by (simp_all add: eq)
    31 
    32 code_const "eq_class.eq \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    33   (Haskell infixl 4 "==")
    34 
    35 code_instance bool :: eq
    36   (Haskell -)
    37 
    38 
    39 subsection {* Unit *}
    40 
    41 typedef unit = "{True}"
    42 proof
    43   show "True : ?unit" ..
    44 qed
    45 
    46 definition
    47   Unity :: unit    ("'(')")
    48 where
    49   "() = Abs_unit True"
    50 
    51 lemma unit_eq [noatp]: "u = ()"
    52   by (induct u) (simp add: unit_def Unity_def)
    53 
    54 text {*
    55   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    56   this rule directly --- it loops!
    57 *}
    58 
    59 ML {*
    60   val unit_eq_proc =
    61     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    62       Simplifier.simproc @{theory} "unit_eq" ["x::unit"]
    63       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    64     end;
    65 
    66   Addsimprocs [unit_eq_proc];
    67 *}
    68 
    69 rep_datatype "()" by simp
    70 
    71 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    72   by simp
    73 
    74 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    75   by (rule triv_forall_equality)
    76 
    77 text {*
    78   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    79   [source] "%u::unit. f u"}, replacing it by @{term [source]
    80   f} rather than by @{term [source] "%u. f ()"}.
    81 *}
    82 
    83 lemma unit_abs_eta_conv [simp,noatp]: "(%u::unit. f ()) = f"
    84   by (rule ext) simp
    85 
    86 instantiation unit :: default
    87 begin
    88 
    89 definition "default = ()"
    90 
    91 instance ..
    92 
    93 end
    94 
    95 text {* code generator setup *}
    96 
    97 lemma [code]:
    98   "eq_class.eq (u\<Colon>unit) v \<longleftrightarrow> True" unfolding eq unit_eq [of u] unit_eq [of v] by rule+
    99 
   100 code_type unit
   101   (SML "unit")
   102   (OCaml "unit")
   103   (Haskell "()")
   104 
   105 code_instance unit :: eq
   106   (Haskell -)
   107 
   108 code_const "eq_class.eq \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   109   (Haskell infixl 4 "==")
   110 
   111 code_const Unity
   112   (SML "()")
   113   (OCaml "()")
   114   (Haskell "()")
   115 
   116 code_reserved SML
   117   unit
   118 
   119 code_reserved OCaml
   120   unit
   121 
   122 
   123 subsection {* Pairs *}
   124 
   125 subsubsection {* Product type, basic operations and concrete syntax *}
   126 
   127 definition
   128   Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
   129 where
   130   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   131 
   132 global
   133 
   134 typedef (Prod)
   135   ('a, 'b) "*"    (infixr "*" 20)
   136     = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   137 proof
   138   fix a b show "Pair_Rep a b \<in> ?Prod"
   139     by rule+
   140 qed
   141 
   142 syntax (xsymbols)
   143   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   144 syntax (HTML output)
   145   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   146 
   147 consts
   148   Pair     :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b"
   149   fst      :: "'a \<times> 'b \<Rightarrow> 'a"
   150   snd      :: "'a \<times> 'b \<Rightarrow> 'b"
   151   split    :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   152   curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c"
   153 
   154 local
   155 
   156 defs
   157   Pair_def:     "Pair a b == Abs_Prod (Pair_Rep a b)"
   158   fst_def:      "fst p == THE a. EX b. p = Pair a b"
   159   snd_def:      "snd p == THE b. EX a. p = Pair a b"
   160   split_def:    "split == (%c p. c (fst p) (snd p))"
   161   curry_def:    "curry == (%c x y. c (Pair x y))"
   162 
   163 text {*
   164   Patterns -- extends pre-defined type @{typ pttrn} used in
   165   abstractions.
   166 *}
   167 
   168 nonterminals
   169   tuple_args patterns
   170 
   171 syntax
   172   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   173   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   174   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   175   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   176   ""            :: "pttrn => patterns"                  ("_")
   177   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   178 
   179 translations
   180   "(x, y)"       == "Pair x y"
   181   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   182   "%(x,y,zs).b"  == "split(%x (y,zs).b)"
   183   "%(x,y).b"     == "split(%x y. b)"
   184   "_abs (Pair x y) t" => "%(x,y).t"
   185   (* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   186      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *)
   187 
   188 (* reconstructs pattern from (nested) splits, avoiding eta-contraction of body*)
   189 (* works best with enclosing "let", if "let" does not avoid eta-contraction   *)
   190 print_translation {*
   191 let fun split_tr' [Abs (x,T,t as (Abs abs))] =
   192       (* split (%x y. t) => %(x,y) t *)
   193       let val (y,t') = atomic_abs_tr' abs;
   194           val (x',t'') = atomic_abs_tr' (x,T,t');
   195     
   196       in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end
   197     | split_tr' [Abs (x,T,(s as Const ("split",_)$t))] =
   198        (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   199        let val (Const ("_abs",_)$(Const ("_pattern",_)$y$z)$t') = split_tr' [t];
   200            val (x',t'') = atomic_abs_tr' (x,T,t');
   201        in Syntax.const "_abs"$ 
   202            (Syntax.const "_pattern"$x'$(Syntax.const "_patterns"$y$z))$t'' end
   203     | split_tr' [Const ("split",_)$t] =
   204        (* split (split (%x y z. t)) => %((x,y),z). t *)   
   205        split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   206     | split_tr' [Const ("_abs",_)$x_y$(Abs abs)] =
   207        (* split (%pttrn z. t) => %(pttrn,z). t *)
   208        let val (z,t) = atomic_abs_tr' abs;
   209        in Syntax.const "_abs" $ (Syntax.const "_pattern" $x_y$z) $ t end
   210     | split_tr' _ =  raise Match;
   211 in [("split", split_tr')]
   212 end
   213 *}
   214 
   215 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   216 typed_print_translation {*
   217 let
   218   fun split_guess_names_tr' _ T [Abs (x,_,Abs _)] = raise Match
   219     | split_guess_names_tr' _ T  [Abs (x,xT,t)] =
   220         (case (head_of t) of
   221            Const ("split",_) => raise Match
   222          | _ => let 
   223                   val (_::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   224                   val (y,t') = atomic_abs_tr' ("y",yT,(incr_boundvars 1 t)$Bound 0); 
   225                   val (x',t'') = atomic_abs_tr' (x,xT,t');
   226                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   227     | split_guess_names_tr' _ T [t] =
   228        (case (head_of t) of
   229            Const ("split",_) => raise Match 
   230          | _ => let 
   231                   val (xT::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   232                   val (y,t') = 
   233                         atomic_abs_tr' ("y",yT,(incr_boundvars 2 t)$Bound 1$Bound 0); 
   234                   val (x',t'') = atomic_abs_tr' ("x",xT,t');
   235                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   236     | split_guess_names_tr' _ _ _ = raise Match;
   237 in [("split", split_guess_names_tr')]
   238 end 
   239 *}
   240 
   241 
   242 text {* Towards a datatype declaration *}
   243 
   244 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   245   apply (unfold Pair_def)
   246   apply (rule Rep_Prod [unfolded Prod_def, THEN CollectE])
   247   apply (erule exE, erule exE, rule exI, rule exI)
   248   apply (rule Rep_Prod_inverse [symmetric, THEN trans])
   249   apply (erule arg_cong)
   250   done
   251 
   252 lemma PairE [cases type: *]:
   253   obtains x y where "p = (x, y)"
   254   using surj_pair [of p] by blast
   255 
   256 lemma ProdI: "Pair_Rep a b \<in> Prod"
   257   unfolding Prod_def by rule+
   258 
   259 lemma Pair_Rep_inject: "Pair_Rep a b = Pair_Rep a' b' \<Longrightarrow> a = a' \<and> b = b'"
   260   unfolding Pair_Rep_def by (drule fun_cong, drule fun_cong) blast
   261 
   262 lemma inj_on_Abs_Prod: "inj_on Abs_Prod Prod"
   263   apply (rule inj_on_inverseI)
   264   apply (erule Abs_Prod_inverse)
   265   done
   266 
   267 lemma Pair_inject:
   268   assumes "(a, b) = (a', b')"
   269     and "a = a' ==> b = b' ==> R"
   270   shows R
   271   apply (insert prems [unfolded Pair_def])
   272   apply (rule inj_on_Abs_Prod [THEN inj_onD, THEN Pair_Rep_inject, THEN conjE])
   273   apply (assumption | rule ProdI)+
   274   done
   275 
   276 rep_datatype (prod) Pair
   277 proof -
   278   fix P p
   279   assume "\<And>x y. P (x, y)"
   280   then show "P p" by (cases p) simp
   281 qed (auto elim: Pair_inject)
   282 
   283 lemmas Pair_eq = prod.inject
   284 
   285 lemma fst_conv [simp, code]: "fst (a, b) = a"
   286   unfolding fst_def by blast
   287 
   288 lemma snd_conv [simp, code]: "snd (a, b) = b"
   289   unfolding snd_def by blast
   290 
   291 
   292 subsubsection {* Basic rules and proof tools *}
   293 
   294 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   295   by simp
   296 
   297 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   298   by simp
   299 
   300 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   301   by (cases p) simp
   302 
   303 lemmas surjective_pairing = pair_collapse [symmetric]
   304 
   305 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   306 proof
   307   fix a b
   308   assume "!!x. PROP P x"
   309   then show "PROP P (a, b)" .
   310 next
   311   fix x
   312   assume "!!a b. PROP P (a, b)"
   313   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   314 qed
   315 
   316 text {*
   317   The rule @{thm [source] split_paired_all} does not work with the
   318   Simplifier because it also affects premises in congrence rules,
   319   where this can lead to premises of the form @{text "!!a b. ... =
   320   ?P(a, b)"} which cannot be solved by reflexivity.
   321 *}
   322 
   323 lemmas split_tupled_all = split_paired_all unit_all_eq2
   324 
   325 ML {*
   326   (* replace parameters of product type by individual component parameters *)
   327   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   328   local (* filtering with exists_paired_all is an essential optimization *)
   329     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   330           can HOLogic.dest_prodT T orelse exists_paired_all t
   331       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   332       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   333       | exists_paired_all _ = false;
   334     val ss = HOL_basic_ss
   335       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   336       addsimprocs [unit_eq_proc];
   337   in
   338     val split_all_tac = SUBGOAL (fn (t, i) =>
   339       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   340     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   341       if exists_paired_all t then full_simp_tac ss i else no_tac);
   342     fun split_all th =
   343    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   344   end;
   345 *}
   346 
   347 declaration {* fn _ =>
   348   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   349 *}
   350 
   351 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   352   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   353   by fast
   354 
   355 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   356   by fast
   357 
   358 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   359   by (cases s, cases t) simp
   360 
   361 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   362   by (simp add: Pair_fst_snd_eq)
   363 
   364 
   365 subsubsection {* @{text split} and @{text curry} *}
   366 
   367 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   368   by (simp add: split_def)
   369 
   370 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   371   by (simp add: curry_def)
   372 
   373 lemmas split = split_conv  -- {* for backwards compatibility *}
   374 
   375 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   376   by (rule split_conv [THEN iffD2])
   377 
   378 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   379   by (rule split_conv [THEN iffD1])
   380 
   381 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   382   by (simp add: curry_def)
   383 
   384 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   385   by (simp add: curry_def)
   386 
   387 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   388   by (simp add: curry_def)
   389 
   390 lemma curry_split [simp]: "curry (split f) = f"
   391   by (simp add: curry_def split_def)
   392 
   393 lemma split_curry [simp]: "split (curry f) = f"
   394   by (simp add: curry_def split_def)
   395 
   396 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   397   by (simp add: split_def id_def)
   398 
   399 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   400   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity Datatype. *}
   401   by (rule ext) auto
   402 
   403 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   404   by (cases x) simp
   405 
   406 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   407   unfolding split_def ..
   408 
   409 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   410   -- {* Can't be added to simpset: loops! *}
   411   by (simp add: split_eta)
   412 
   413 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   414   by (simp add: split_def)
   415 
   416 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   417   -- {* Prevents simplification of @{term c}: much faster *}
   418   by (erule arg_cong)
   419 
   420 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   421   by (simp add: split_eta)
   422 
   423 text {*
   424   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   425   @{thm [source] split_eta} as a rewrite rule is not general enough,
   426   and using @{thm [source] cond_split_eta} directly would render some
   427   existing proofs very inefficient; similarly for @{text
   428   split_beta}.
   429 *}
   430 
   431 ML {*
   432 
   433 local
   434   val cond_split_eta_ss = HOL_basic_ss addsimps [thm "cond_split_eta"]
   435   fun  Pair_pat k 0 (Bound m) = (m = k)
   436   |    Pair_pat k i (Const ("Pair",  _) $ Bound m $ t) = i > 0 andalso
   437                         m = k+i andalso Pair_pat k (i-1) t
   438   |    Pair_pat _ _ _ = false;
   439   fun no_args k i (Abs (_, _, t)) = no_args (k+1) i t
   440   |   no_args k i (t $ u) = no_args k i t andalso no_args k i u
   441   |   no_args k i (Bound m) = m < k orelse m > k+i
   442   |   no_args _ _ _ = true;
   443   fun split_pat tp i (Abs  (_,_,t)) = if tp 0 i t then SOME (i,t) else NONE
   444   |   split_pat tp i (Const ("split", _) $ Abs (_, _, t)) = split_pat tp (i+1) t
   445   |   split_pat tp i _ = NONE;
   446   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   447         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs,rhs)))
   448         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   449 
   450   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k+1) i t
   451   |   beta_term_pat k i (t $ u) = Pair_pat k i (t $ u) orelse
   452                         (beta_term_pat k i t andalso beta_term_pat k i u)
   453   |   beta_term_pat k i t = no_args k i t;
   454   fun  eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   455   |    eta_term_pat _ _ _ = false;
   456   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   457   |   subst arg k i (t $ u) = if Pair_pat k i (t $ u) then incr_boundvars k arg
   458                               else (subst arg k i t $ subst arg k i u)
   459   |   subst arg k i t = t;
   460   fun beta_proc ss (s as Const ("split", _) $ Abs (_, _, t) $ arg) =
   461         (case split_pat beta_term_pat 1 t of
   462         SOME (i,f) => SOME (metaeq ss s (subst arg 0 i f))
   463         | NONE => NONE)
   464   |   beta_proc _ _ = NONE;
   465   fun eta_proc ss (s as Const ("split", _) $ Abs (_, _, t)) =
   466         (case split_pat eta_term_pat 1 t of
   467           SOME (_,ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   468         | NONE => NONE)
   469   |   eta_proc _ _ = NONE;
   470 in
   471   val split_beta_proc = Simplifier.simproc @{theory} "split_beta" ["split f z"] (K beta_proc);
   472   val split_eta_proc = Simplifier.simproc @{theory} "split_eta" ["split f"] (K eta_proc);
   473 end;
   474 
   475 Addsimprocs [split_beta_proc, split_eta_proc];
   476 *}
   477 
   478 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   479   by (subst surjective_pairing, rule split_conv)
   480 
   481 lemma split_split [noatp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   482   -- {* For use with @{text split} and the Simplifier. *}
   483   by (insert surj_pair [of p], clarify, simp)
   484 
   485 text {*
   486   @{thm [source] split_split} could be declared as @{text "[split]"}
   487   done after the Splitter has been speeded up significantly;
   488   precompute the constants involved and don't do anything unless the
   489   current goal contains one of those constants.
   490 *}
   491 
   492 lemma split_split_asm [noatp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   493 by (subst split_split, simp)
   494 
   495 
   496 text {*
   497   \medskip @{term split} used as a logical connective or set former.
   498 
   499   \medskip These rules are for use with @{text blast}; could instead
   500   call @{text simp} using @{thm [source] split} as rewrite. *}
   501 
   502 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   503   apply (simp only: split_tupled_all)
   504   apply (simp (no_asm_simp))
   505   done
   506 
   507 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   508   apply (simp only: split_tupled_all)
   509   apply (simp (no_asm_simp))
   510   done
   511 
   512 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   513   by (induct p) (auto simp add: split_def)
   514 
   515 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   516   by (induct p) (auto simp add: split_def)
   517 
   518 lemma splitE2:
   519   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   520 proof -
   521   assume q: "Q (split P z)"
   522   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   523   show R
   524     apply (rule r surjective_pairing)+
   525     apply (rule split_beta [THEN subst], rule q)
   526     done
   527 qed
   528 
   529 lemma splitD': "split R (a,b) c ==> R a b c"
   530   by simp
   531 
   532 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   533   by simp
   534 
   535 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   536 by (simp only: split_tupled_all, simp)
   537 
   538 lemma mem_splitE:
   539   assumes major: "z: split c p"
   540     and cases: "!!x y. [| p = (x,y); z: c x y |] ==> Q"
   541   shows Q
   542   by (rule major [unfolded split_def] cases surjective_pairing)+
   543 
   544 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   545 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   546 
   547 ML {*
   548 local (* filtering with exists_p_split is an essential optimization *)
   549   fun exists_p_split (Const ("split",_) $ _ $ (Const ("Pair",_)$_$_)) = true
   550     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   551     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   552     | exists_p_split _ = false;
   553   val ss = HOL_basic_ss addsimps [thm "split_conv"];
   554 in
   555 val split_conv_tac = SUBGOAL (fn (t, i) =>
   556     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   557 end;
   558 *}
   559 
   560 (* This prevents applications of splitE for already splitted arguments leading
   561    to quite time-consuming computations (in particular for nested tuples) *)
   562 declaration {* fn _ =>
   563   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   564 *}
   565 
   566 lemma split_eta_SetCompr [simp,noatp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   567   by (rule ext) fast
   568 
   569 lemma split_eta_SetCompr2 [simp,noatp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   570   by (rule ext) fast
   571 
   572 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   573   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   574   by (rule ext) blast
   575 
   576 (* Do NOT make this a simp rule as it
   577    a) only helps in special situations
   578    b) can lead to nontermination in the presence of split_def
   579 *)
   580 lemma split_comp_eq: 
   581   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   582   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   583   by (rule ext) auto
   584 
   585 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   586   apply (rule_tac x = "(a, b)" in image_eqI)
   587    apply auto
   588   done
   589 
   590 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   591   by blast
   592 
   593 (*
   594 the following  would be slightly more general,
   595 but cannot be used as rewrite rule:
   596 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   597 ### ?y = .x
   598 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   599 by (rtac some_equality 1)
   600 by ( Simp_tac 1)
   601 by (split_all_tac 1)
   602 by (Asm_full_simp_tac 1)
   603 qed "The_split_eq";
   604 *)
   605 
   606 text {*
   607   Setup of internal @{text split_rule}.
   608 *}
   609 
   610 definition
   611   internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   612 where
   613   "internal_split == split"
   614 
   615 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   616   by (simp only: internal_split_def split_conv)
   617 
   618 hide const internal_split
   619 
   620 use "Tools/split_rule.ML"
   621 setup SplitRule.setup
   622 
   623 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   624 
   625 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   626   by auto
   627 
   628 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   629   by (auto simp: split_tupled_all)
   630 
   631 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   632   by (induct p) auto
   633 
   634 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   635   by (induct p) auto
   636 
   637 lemma prod_case_unfold: "prod_case = (%c p. c (fst p) (snd p))"
   638   by (simp add: expand_fun_eq)
   639 
   640 declare prod_caseI2' [intro!] prod_caseI2 [intro!] prod_caseI [intro!]
   641 declare prod_caseE' [elim!] prod_caseE [elim!]
   642 
   643 lemma prod_case_split:
   644   "prod_case = split"
   645   by (auto simp add: expand_fun_eq)
   646 
   647 lemma prod_case_beta:
   648   "prod_case f p = f (fst p) (snd p)"
   649   unfolding prod_case_split split_beta ..
   650 
   651 
   652 subsection {* Further cases/induct rules for tuples *}
   653 
   654 lemma prod_cases3 [cases type]:
   655   obtains (fields) a b c where "y = (a, b, c)"
   656   by (cases y, case_tac b) blast
   657 
   658 lemma prod_induct3 [case_names fields, induct type]:
   659     "(!!a b c. P (a, b, c)) ==> P x"
   660   by (cases x) blast
   661 
   662 lemma prod_cases4 [cases type]:
   663   obtains (fields) a b c d where "y = (a, b, c, d)"
   664   by (cases y, case_tac c) blast
   665 
   666 lemma prod_induct4 [case_names fields, induct type]:
   667     "(!!a b c d. P (a, b, c, d)) ==> P x"
   668   by (cases x) blast
   669 
   670 lemma prod_cases5 [cases type]:
   671   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   672   by (cases y, case_tac d) blast
   673 
   674 lemma prod_induct5 [case_names fields, induct type]:
   675     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   676   by (cases x) blast
   677 
   678 lemma prod_cases6 [cases type]:
   679   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   680   by (cases y, case_tac e) blast
   681 
   682 lemma prod_induct6 [case_names fields, induct type]:
   683     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   684   by (cases x) blast
   685 
   686 lemma prod_cases7 [cases type]:
   687   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   688   by (cases y, case_tac f) blast
   689 
   690 lemma prod_induct7 [case_names fields, induct type]:
   691     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   692   by (cases x) blast
   693 
   694 
   695 subsubsection {* Derived operations *}
   696 
   697 text {*
   698   The composition-uncurry combinator.
   699 *}
   700 
   701 notation fcomp (infixl "o>" 60)
   702 
   703 definition
   704   scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "o\<rightarrow>" 60)
   705 where
   706   "f o\<rightarrow> g = (\<lambda>x. split g (f x))"
   707 
   708 lemma scomp_apply:  "(f o\<rightarrow> g) x = split g (f x)"
   709   by (simp add: scomp_def)
   710 
   711 lemma Pair_scomp: "Pair x o\<rightarrow> f = f x"
   712   by (simp add: expand_fun_eq scomp_apply)
   713 
   714 lemma scomp_Pair: "x o\<rightarrow> Pair = x"
   715   by (simp add: expand_fun_eq scomp_apply)
   716 
   717 lemma scomp_scomp: "(f o\<rightarrow> g) o\<rightarrow> h = f o\<rightarrow> (\<lambda>x. g x o\<rightarrow> h)"
   718   by (simp add: expand_fun_eq split_twice scomp_def)
   719 
   720 lemma scomp_fcomp: "(f o\<rightarrow> g) o> h = f o\<rightarrow> (\<lambda>x. g x o> h)"
   721   by (simp add: expand_fun_eq scomp_apply fcomp_def split_def)
   722 
   723 lemma fcomp_scomp: "(f o> g) o\<rightarrow> h = f o> (g o\<rightarrow> h)"
   724   by (simp add: expand_fun_eq scomp_apply fcomp_apply)
   725 
   726 code_const scomp
   727   (Eval infixl 3 "#->")
   728 
   729 no_notation fcomp (infixl "o>" 60)
   730 no_notation scomp (infixl "o\<rightarrow>" 60)
   731 
   732 
   733 text {*
   734   @{term prod_fun} --- action of the product functor upon
   735   Datatypes.
   736 *}
   737 
   738 definition prod_fun :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   739   [code del]: "prod_fun f g = (\<lambda>(x, y). (f x, g y))"
   740 
   741 lemma prod_fun [simp, code]: "prod_fun f g (a, b) = (f a, g b)"
   742   by (simp add: prod_fun_def)
   743 
   744 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   745   by (rule ext) auto
   746 
   747 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   748   by (rule ext) auto
   749 
   750 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   751   apply (rule image_eqI)
   752   apply (rule prod_fun [symmetric], assumption)
   753   done
   754 
   755 lemma prod_fun_imageE [elim!]:
   756   assumes major: "c: (prod_fun f g)`r"
   757     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   758   shows P
   759   apply (rule major [THEN imageE])
   760   apply (rule_tac p = x in PairE)
   761   apply (rule cases)
   762    apply (blast intro: prod_fun)
   763   apply blast
   764   done
   765 
   766 definition
   767   apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b"
   768 where
   769   [code del]: "apfst f = prod_fun f id"
   770 
   771 definition
   772   apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c"
   773 where
   774   [code del]: "apsnd f = prod_fun id f"
   775 
   776 lemma apfst_conv [simp, code]:
   777   "apfst f (x, y) = (f x, y)" 
   778   by (simp add: apfst_def)
   779 
   780 lemma upd_snd_conv [simp, code]:
   781   "apsnd f (x, y) = (x, f y)" 
   782   by (simp add: apsnd_def)
   783 
   784 lemma fst_apfst [simp]:
   785   "fst (apfst f x) = f (fst x)"
   786   by (cases x) simp
   787 
   788 lemma fst_apsnd [simp]:
   789   "fst (apsnd f x) = fst x"
   790   by (cases x) simp
   791 
   792 lemma snd_apfst [simp]:
   793   "snd (apfst f x) = snd x"
   794   by (cases x) simp
   795 
   796 lemma snd_apsnd [simp]:
   797   "snd (apsnd f x) = f (snd x)"
   798   by (cases x) simp
   799 
   800 lemma apfst_compose:
   801   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   802   by (cases x) simp
   803 
   804 lemma apsnd_compose:
   805   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   806   by (cases x) simp
   807 
   808 lemma apfst_apsnd [simp]:
   809   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   810   by (cases x) simp
   811 
   812 lemma apsnd_apfst [simp]:
   813   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   814   by (cases x) simp
   815 
   816 lemma apfst_id [simp] :
   817   "apfst id = id"
   818   by (simp add: expand_fun_eq)
   819 
   820 lemma apsnd_id [simp] :
   821   "apsnd id = id"
   822   by (simp add: expand_fun_eq)
   823 
   824 lemma apfst_eq_conv [simp]:
   825   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   826   by (cases x) simp
   827 
   828 lemma apsnd_eq_conv [simp]:
   829   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   830   by (cases x) simp
   831 
   832 
   833 text {*
   834   Disjoint union of a family of sets -- Sigma.
   835 *}
   836 
   837 definition  Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   838   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   839 
   840 abbreviation
   841   Times :: "['a set, 'b set] => ('a * 'b) set"
   842     (infixr "<*>" 80) where
   843   "A <*> B == Sigma A (%_. B)"
   844 
   845 notation (xsymbols)
   846   Times  (infixr "\<times>" 80)
   847 
   848 notation (HTML output)
   849   Times  (infixr "\<times>" 80)
   850 
   851 syntax
   852   "@Sigma" ::"[pttrn, 'a set, 'b set] => ('a * 'b) set" ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   853 
   854 translations
   855   "SIGMA x:A. B" == "Product_Type.Sigma A (%x. B)"
   856 
   857 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   858   by (unfold Sigma_def) blast
   859 
   860 lemma SigmaE [elim!]:
   861     "[| c: Sigma A B;
   862         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   863      |] ==> P"
   864   -- {* The general elimination rule. *}
   865   by (unfold Sigma_def) blast
   866 
   867 text {*
   868   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   869   eigenvariables.
   870 *}
   871 
   872 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   873   by blast
   874 
   875 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   876   by blast
   877 
   878 lemma SigmaE2:
   879     "[| (a, b) : Sigma A B;
   880         [| a:A;  b:B(a) |] ==> P
   881      |] ==> P"
   882   by blast
   883 
   884 lemma Sigma_cong:
   885      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   886       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   887   by auto
   888 
   889 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   890   by blast
   891 
   892 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   893   by blast
   894 
   895 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   896   by blast
   897 
   898 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   899   by auto
   900 
   901 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   902   by auto
   903 
   904 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   905   by auto
   906 
   907 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   908   by blast
   909 
   910 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   911   by blast
   912 
   913 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   914   by (blast elim: equalityE)
   915 
   916 lemma SetCompr_Sigma_eq:
   917     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   918   by blast
   919 
   920 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   921   by blast
   922 
   923 lemma UN_Times_distrib:
   924   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   925   -- {* Suggested by Pierre Chartier *}
   926   by blast
   927 
   928 lemma split_paired_Ball_Sigma [simp,noatp]:
   929     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   930   by blast
   931 
   932 lemma split_paired_Bex_Sigma [simp,noatp]:
   933     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   934   by blast
   935 
   936 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   937   by blast
   938 
   939 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   940   by blast
   941 
   942 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   943   by blast
   944 
   945 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   946   by blast
   947 
   948 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   949   by blast
   950 
   951 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   952   by blast
   953 
   954 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   955   by blast
   956 
   957 text {*
   958   Non-dependent versions are needed to avoid the need for higher-order
   959   matching, especially when the rules are re-oriented.
   960 *}
   961 
   962 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
   963 by blast
   964 
   965 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
   966 by blast
   967 
   968 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
   969 by blast
   970 
   971 lemma insert_times_insert[simp]:
   972   "insert a A \<times> insert b B =
   973    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
   974 by blast
   975 
   976 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
   977   by (auto, rule_tac p = "f x" in PairE, auto)
   978 
   979 subsubsection {* Code generator setup *}
   980 
   981 lemma [code]:
   982   "eq_class.eq (x1\<Colon>'a\<Colon>eq, y1\<Colon>'b\<Colon>eq) (x2, y2) \<longleftrightarrow> x1 = x2 \<and> y1 = y2" by (simp add: eq)
   983 
   984 lemma split_case_cert:
   985   assumes "CASE \<equiv> split f"
   986   shows "CASE (a, b) \<equiv> f a b"
   987   using assms by simp
   988 
   989 setup {*
   990   Code.add_case @{thm split_case_cert}
   991 *}
   992 
   993 code_type *
   994   (SML infix 2 "*")
   995   (OCaml infix 2 "*")
   996   (Haskell "!((_),/ (_))")
   997 
   998 code_instance * :: eq
   999   (Haskell -)
  1000 
  1001 code_const "eq_class.eq \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
  1002   (Haskell infixl 4 "==")
  1003 
  1004 code_const Pair
  1005   (SML "!((_),/ (_))")
  1006   (OCaml "!((_),/ (_))")
  1007   (Haskell "!((_),/ (_))")
  1008 
  1009 code_const fst and snd
  1010   (Haskell "fst" and "snd")
  1011 
  1012 types_code
  1013   "*"     ("(_ */ _)")
  1014 attach (term_of) {*
  1015 fun term_of_id_42 aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
  1016 *}
  1017 attach (test) {*
  1018 fun gen_id_42 aG aT bG bT i =
  1019   let
  1020     val (x, t) = aG i;
  1021     val (y, u) = bG i
  1022   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
  1023 *}
  1024 
  1025 consts_code
  1026   "Pair"    ("(_,/ _)")
  1027 
  1028 setup {*
  1029 
  1030 let
  1031 
  1032 fun strip_abs_split 0 t = ([], t)
  1033   | strip_abs_split i (Abs (s, T, t)) =
  1034       let
  1035         val s' = Codegen.new_name t s;
  1036         val v = Free (s', T)
  1037       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
  1038   | strip_abs_split i (u as Const ("split", _) $ t) = (case strip_abs_split (i+1) t of
  1039         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
  1040       | _ => ([], u))
  1041   | strip_abs_split i t =
  1042       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
  1043 
  1044 fun let_codegen thy defs dep thyname brack t gr = (case strip_comb t of
  1045     (t1 as Const ("Let", _), t2 :: t3 :: ts) =>
  1046     let
  1047       fun dest_let (l as Const ("Let", _) $ t $ u) =
  1048           (case strip_abs_split 1 u of
  1049              ([p], u') => apfst (cons (p, t)) (dest_let u')
  1050            | _ => ([], l))
  1051         | dest_let t = ([], t);
  1052       fun mk_code (l, r) gr =
  1053         let
  1054           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
  1055           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
  1056         in ((pl, pr), gr2) end
  1057     in case dest_let (t1 $ t2 $ t3) of
  1058         ([], _) => NONE
  1059       | (ps, u) =>
  1060           let
  1061             val (qs, gr1) = fold_map mk_code ps gr;
  1062             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
  1063             val (pargs, gr3) = fold_map
  1064               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
  1065           in
  1066             SOME (Codegen.mk_app brack
  1067               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
  1068                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
  1069                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
  1070                        Pretty.brk 1, pr]]) qs))),
  1071                 Pretty.brk 1, Codegen.str "in ", pu,
  1072                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
  1073           end
  1074     end
  1075   | _ => NONE);
  1076 
  1077 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
  1078     (t1 as Const ("split", _), t2 :: ts) =>
  1079       let
  1080         val ([p], u) = strip_abs_split 1 (t1 $ t2);
  1081         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
  1082         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
  1083         val (pargs, gr3) = fold_map
  1084           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
  1085       in
  1086         SOME (Codegen.mk_app brack
  1087           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
  1088             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
  1089       end
  1090   | _ => NONE);
  1091 
  1092 in
  1093 
  1094   Codegen.add_codegen "let_codegen" let_codegen
  1095   #> Codegen.add_codegen "split_codegen" split_codegen
  1096 
  1097 end
  1098 *}
  1099 
  1100 
  1101 subsection {* Legacy bindings *}
  1102 
  1103 ML {*
  1104 val Collect_split = thm "Collect_split";
  1105 val Compl_Times_UNIV1 = thm "Compl_Times_UNIV1";
  1106 val Compl_Times_UNIV2 = thm "Compl_Times_UNIV2";
  1107 val PairE = thm "PairE";
  1108 val Pair_Rep_inject = thm "Pair_Rep_inject";
  1109 val Pair_def = thm "Pair_def";
  1110 val Pair_eq = @{thm "prod.inject"};
  1111 val Pair_fst_snd_eq = thm "Pair_fst_snd_eq";
  1112 val ProdI = thm "ProdI";
  1113 val SetCompr_Sigma_eq = thm "SetCompr_Sigma_eq";
  1114 val SigmaD1 = thm "SigmaD1";
  1115 val SigmaD2 = thm "SigmaD2";
  1116 val SigmaE = thm "SigmaE";
  1117 val SigmaE2 = thm "SigmaE2";
  1118 val SigmaI = thm "SigmaI";
  1119 val Sigma_Diff_distrib1 = thm "Sigma_Diff_distrib1";
  1120 val Sigma_Diff_distrib2 = thm "Sigma_Diff_distrib2";
  1121 val Sigma_Int_distrib1 = thm "Sigma_Int_distrib1";
  1122 val Sigma_Int_distrib2 = thm "Sigma_Int_distrib2";
  1123 val Sigma_Un_distrib1 = thm "Sigma_Un_distrib1";
  1124 val Sigma_Un_distrib2 = thm "Sigma_Un_distrib2";
  1125 val Sigma_Union = thm "Sigma_Union";
  1126 val Sigma_def = thm "Sigma_def";
  1127 val Sigma_empty1 = thm "Sigma_empty1";
  1128 val Sigma_empty2 = thm "Sigma_empty2";
  1129 val Sigma_mono = thm "Sigma_mono";
  1130 val The_split = thm "The_split";
  1131 val The_split_eq = thm "The_split_eq";
  1132 val The_split_eq = thm "The_split_eq";
  1133 val Times_Diff_distrib1 = thm "Times_Diff_distrib1";
  1134 val Times_Int_distrib1 = thm "Times_Int_distrib1";
  1135 val Times_Un_distrib1 = thm "Times_Un_distrib1";
  1136 val Times_eq_cancel2 = thm "Times_eq_cancel2";
  1137 val Times_subset_cancel2 = thm "Times_subset_cancel2";
  1138 val UNIV_Times_UNIV = thm "UNIV_Times_UNIV";
  1139 val UN_Times_distrib = thm "UN_Times_distrib";
  1140 val Unity_def = thm "Unity_def";
  1141 val cond_split_eta = thm "cond_split_eta";
  1142 val fst_conv = thm "fst_conv";
  1143 val fst_def = thm "fst_def";
  1144 val fst_eqD = thm "fst_eqD";
  1145 val inj_on_Abs_Prod = thm "inj_on_Abs_Prod";
  1146 val mem_Sigma_iff = thm "mem_Sigma_iff";
  1147 val mem_splitE = thm "mem_splitE";
  1148 val mem_splitI = thm "mem_splitI";
  1149 val mem_splitI2 = thm "mem_splitI2";
  1150 val prod_eqI = thm "prod_eqI";
  1151 val prod_fun = thm "prod_fun";
  1152 val prod_fun_compose = thm "prod_fun_compose";
  1153 val prod_fun_def = thm "prod_fun_def";
  1154 val prod_fun_ident = thm "prod_fun_ident";
  1155 val prod_fun_imageE = thm "prod_fun_imageE";
  1156 val prod_fun_imageI = thm "prod_fun_imageI";
  1157 val prod_induct = thm "prod.induct";
  1158 val snd_conv = thm "snd_conv";
  1159 val snd_def = thm "snd_def";
  1160 val snd_eqD = thm "snd_eqD";
  1161 val split = thm "split";
  1162 val splitD = thm "splitD";
  1163 val splitD' = thm "splitD'";
  1164 val splitE = thm "splitE";
  1165 val splitE' = thm "splitE'";
  1166 val splitE2 = thm "splitE2";
  1167 val splitI = thm "splitI";
  1168 val splitI2 = thm "splitI2";
  1169 val splitI2' = thm "splitI2'";
  1170 val split_beta = thm "split_beta";
  1171 val split_conv = thm "split_conv";
  1172 val split_def = thm "split_def";
  1173 val split_eta = thm "split_eta";
  1174 val split_eta_SetCompr = thm "split_eta_SetCompr";
  1175 val split_eta_SetCompr2 = thm "split_eta_SetCompr2";
  1176 val split_paired_All = thm "split_paired_All";
  1177 val split_paired_Ball_Sigma = thm "split_paired_Ball_Sigma";
  1178 val split_paired_Bex_Sigma = thm "split_paired_Bex_Sigma";
  1179 val split_paired_Ex = thm "split_paired_Ex";
  1180 val split_paired_The = thm "split_paired_The";
  1181 val split_paired_all = thm "split_paired_all";
  1182 val split_part = thm "split_part";
  1183 val split_split = thm "split_split";
  1184 val split_split_asm = thm "split_split_asm";
  1185 val split_tupled_all = thms "split_tupled_all";
  1186 val split_weak_cong = thm "split_weak_cong";
  1187 val surj_pair = thm "surj_pair";
  1188 val surjective_pairing = thm "surjective_pairing";
  1189 val unit_abs_eta_conv = thm "unit_abs_eta_conv";
  1190 val unit_all_eq1 = thm "unit_all_eq1";
  1191 val unit_all_eq2 = thm "unit_all_eq2";
  1192 val unit_eq = thm "unit_eq";
  1193 *}
  1194 
  1195 
  1196 subsection {* Further inductive packages *}
  1197 
  1198 use "Tools/inductive_realizer.ML"
  1199 setup InductiveRealizer.setup
  1200 
  1201 use "Tools/inductive_set.ML"
  1202 setup Inductive_Set.setup
  1203 
  1204 use "Tools/Datatype/datatype_realizer.ML"
  1205 setup DatatypeRealizer.setup
  1206 
  1207 end