src/HOL/MicroJava/J/TypeRel.thy
author kleing
Sun Dec 16 00:18:17 2001 +0100 (2001-12-16)
changeset 12517 360e3215f029
parent 12443 e56ab6134b41
child 12911 704713ca07ea
permissions -rw-r--r--
exception merge, cleanup, tuned
     1 (*  Title:      HOL/MicroJava/J/TypeRel.thy
     2     ID:         $Id$
     3     Author:     David von Oheimb
     4     Copyright   1999 Technische Universitaet Muenchen
     5 *)
     6 
     7 header "Relations between Java Types"
     8 
     9 theory TypeRel = Decl:
    10 
    11 consts
    12   subcls1 :: "'c prog => (cname \<times> cname) set"  -- "subclass"
    13   widen   :: "'c prog => (ty    \<times> ty   ) set"  -- "widening"
    14   cast    :: "'c prog => (cname \<times> cname) set"  -- "casting"
    15 
    16 syntax (xsymbols)
    17   subcls1 :: "'c prog => [cname, cname] => bool" ("_ \<turnstile> _ \<prec>C1 _" [71,71,71] 70)
    18   subcls  :: "'c prog => [cname, cname] => bool" ("_ \<turnstile> _ \<preceq>C _"  [71,71,71] 70)
    19   widen   :: "'c prog => [ty   , ty   ] => bool" ("_ \<turnstile> _ \<preceq> _"   [71,71,71] 70)
    20   cast    :: "'c prog => [cname, cname] => bool" ("_ \<turnstile> _ \<preceq>? _"  [71,71,71] 70)
    21 
    22 syntax
    23   subcls1 :: "'c prog => [cname, cname] => bool" ("_ |- _ <=C1 _" [71,71,71] 70)
    24   subcls  :: "'c prog => [cname, cname] => bool" ("_ |- _ <=C _"  [71,71,71] 70)
    25   widen   :: "'c prog => [ty   , ty   ] => bool" ("_ |- _ <= _"   [71,71,71] 70)
    26   cast    :: "'c prog => [cname, cname] => bool" ("_ |- _ <=? _"  [71,71,71] 70)
    27 
    28 translations
    29   "G\<turnstile>C \<prec>C1 D" == "(C,D) \<in> subcls1 G"
    30   "G\<turnstile>C \<preceq>C  D" == "(C,D) \<in> (subcls1 G)^*"
    31   "G\<turnstile>S \<preceq>   T" == "(S,T) \<in> widen   G"
    32   "G\<turnstile>C \<preceq>?  D" == "(C,D) \<in> cast    G"
    33 
    34 -- "direct subclass, cf. 8.1.3"
    35 inductive "subcls1 G" intros
    36   subcls1I: "\<lbrakk>class G C = Some (D,rest); C \<noteq> Object\<rbrakk> \<Longrightarrow> G\<turnstile>C\<prec>C1D"
    37   
    38 lemma subcls1D: 
    39   "G\<turnstile>C\<prec>C1D \<Longrightarrow> C \<noteq> Object \<and> (\<exists>fs ms. class G C = Some (D,fs,ms))"
    40 apply (erule subcls1.elims)
    41 apply auto
    42 done
    43 
    44 lemma subcls1_def2: 
    45 "subcls1 G = (\<Sigma>C\<in>{C. is_class G C} . {D. C\<noteq>Object \<and> fst (the (class G C))=D})"
    46   by (auto simp add: is_class_def dest: subcls1D intro: subcls1I)
    47 
    48 lemma finite_subcls1: "finite (subcls1 G)"
    49 apply(subst subcls1_def2)
    50 apply(rule finite_SigmaI [OF finite_is_class])
    51 apply(rule_tac B = "{fst (the (class G C))}" in finite_subset)
    52 apply  auto
    53 done
    54 
    55 lemma subcls_is_class: "(C,D) \<in> (subcls1 G)^+ ==> is_class G C"
    56 apply (unfold is_class_def)
    57 apply(erule trancl_trans_induct)
    58 apply (auto dest!: subcls1D)
    59 done
    60 
    61 lemma subcls_is_class2 [rule_format (no_asm)]: 
    62   "G\<turnstile>C\<preceq>C D \<Longrightarrow> is_class G D \<longrightarrow> is_class G C"
    63 apply (unfold is_class_def)
    64 apply (erule rtrancl_induct)
    65 apply  (drule_tac [2] subcls1D)
    66 apply  auto
    67 done
    68 
    69 consts class_rec ::"'c prog \<times> cname \<Rightarrow> 
    70         'a \<Rightarrow> (cname \<Rightarrow> fdecl list \<Rightarrow> 'c mdecl list \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> 'a"
    71 
    72 recdef class_rec "same_fst (\<lambda>G. wf ((subcls1 G)^-1)) (\<lambda>G. (subcls1 G)^-1)"
    73       "class_rec (G,C) = (\<lambda>t f. case class G C of None \<Rightarrow> arbitrary 
    74                          | Some (D,fs,ms) \<Rightarrow> if wf ((subcls1 G)^-1) then 
    75       f C fs ms (if C = Object then t else class_rec (G,D) t f) else arbitrary)"
    76 (hints intro: subcls1I)
    77 
    78 declare class_rec.simps [simp del]
    79 
    80 
    81 lemma class_rec_lemma: "\<lbrakk> wf ((subcls1 G)^-1); class G C = Some (D,fs,ms)\<rbrakk> \<Longrightarrow>
    82  class_rec (G,C) t f = f C fs ms (if C=Object then t else class_rec (G,D) t f)";
    83   apply (rule class_rec.simps [THEN trans [THEN fun_cong [THEN fun_cong]]])
    84   apply simp
    85   done
    86 
    87 consts
    88 
    89   method :: "'c prog \<times> cname => ( sig   \<leadsto> cname \<times> ty \<times> 'c)" (* ###curry *)
    90   field  :: "'c prog \<times> cname => ( vname \<leadsto> cname \<times> ty     )" (* ###curry *)
    91   fields :: "'c prog \<times> cname => ((vname \<times> cname) \<times> ty) list" (* ###curry *)
    92 
    93 -- "methods of a class, with inheritance, overriding and hiding, cf. 8.4.6"
    94 defs method_def: "method \<equiv> \<lambda>(G,C). class_rec (G,C) empty (\<lambda>C fs ms ts.
    95                            ts ++ map_of (map (\<lambda>(s,m). (s,(C,m))) ms))"
    96 
    97 lemma method_rec_lemma: "[|class G C = Some (D,fs,ms); wf ((subcls1 G)^-1)|] ==>
    98   method (G,C) = (if C = Object then empty else method (G,D)) ++  
    99   map_of (map (\<lambda>(s,m). (s,(C,m))) ms)"
   100 apply (unfold method_def)
   101 apply (simp split del: split_if)
   102 apply (erule (1) class_rec_lemma [THEN trans]);
   103 apply auto
   104 done
   105 
   106 
   107 -- "list of fields of a class, including inherited and hidden ones"
   108 defs fields_def: "fields \<equiv> \<lambda>(G,C). class_rec (G,C) []    (\<lambda>C fs ms ts.
   109                            map (\<lambda>(fn,ft). ((fn,C),ft)) fs @ ts)"
   110 
   111 lemma fields_rec_lemma: "[|class G C = Some (D,fs,ms); wf ((subcls1 G)^-1)|] ==>
   112  fields (G,C) = 
   113   map (\<lambda>(fn,ft). ((fn,C),ft)) fs @ (if C = Object then [] else fields (G,D))"
   114 apply (unfold fields_def)
   115 apply (simp split del: split_if)
   116 apply (erule (1) class_rec_lemma [THEN trans]);
   117 apply auto
   118 done
   119 
   120 
   121 defs field_def: "field == map_of o (map (\<lambda>((fn,fd),ft). (fn,(fd,ft)))) o fields"
   122 
   123 lemma field_fields: 
   124 "field (G,C) fn = Some (fd, fT) \<Longrightarrow> map_of (fields (G,C)) (fn, fd) = Some fT"
   125 apply (unfold field_def)
   126 apply (rule table_of_remap_SomeD)
   127 apply simp
   128 done
   129 
   130 
   131 -- "widening, viz. method invocation conversion,cf. 5.3 i.e. sort of syntactic subtyping"
   132 inductive "widen G" intros 
   133   refl   [intro!, simp]:       "G\<turnstile>      T \<preceq> T"   -- "identity conv., cf. 5.1.1"
   134   subcls         : "G\<turnstile>C\<preceq>C D ==> G\<turnstile>Class C \<preceq> Class D"
   135   null   [intro!]:             "G\<turnstile>     NT \<preceq> RefT R"
   136 
   137 -- "casting conversion, cf. 5.5 / 5.1.5"
   138 -- "left out casts on primitve types"
   139 inductive "cast G" intros
   140   widen:  "G\<turnstile>C\<preceq>C D ==> G\<turnstile>C \<preceq>? D"
   141   subcls: "G\<turnstile>D\<preceq>C C ==> G\<turnstile>C \<preceq>? D"
   142 
   143 lemma widen_PrimT_RefT [iff]: "(G\<turnstile>PrimT pT\<preceq>RefT rT) = False"
   144 apply (rule iffI)
   145 apply (erule widen.elims)
   146 apply auto
   147 done
   148 
   149 lemma widen_RefT: "G\<turnstile>RefT R\<preceq>T ==> \<exists>t. T=RefT t"
   150 apply (ind_cases "G\<turnstile>S\<preceq>T")
   151 apply auto
   152 done
   153 
   154 lemma widen_RefT2: "G\<turnstile>S\<preceq>RefT R ==> \<exists>t. S=RefT t"
   155 apply (ind_cases "G\<turnstile>S\<preceq>T")
   156 apply auto
   157 done
   158 
   159 lemma widen_Class: "G\<turnstile>Class C\<preceq>T ==> \<exists>D. T=Class D"
   160 apply (ind_cases "G\<turnstile>S\<preceq>T")
   161 apply auto
   162 done
   163 
   164 lemma widen_Class_NullT [iff]: "(G\<turnstile>Class C\<preceq>NT) = False"
   165 apply (rule iffI)
   166 apply (ind_cases "G\<turnstile>S\<preceq>T")
   167 apply auto
   168 done
   169 
   170 lemma widen_Class_Class [iff]: "(G\<turnstile>Class C\<preceq> Class D) = (G\<turnstile>C\<preceq>C D)"
   171 apply (rule iffI)
   172 apply (ind_cases "G\<turnstile>S\<preceq>T")
   173 apply (auto elim: widen.subcls)
   174 done
   175 
   176 theorem widen_trans[trans]: "\<lbrakk>G\<turnstile>S\<preceq>U; G\<turnstile>U\<preceq>T\<rbrakk> \<Longrightarrow> G\<turnstile>S\<preceq>T"
   177 proof -
   178   assume "G\<turnstile>S\<preceq>U" thus "\<And>T. G\<turnstile>U\<preceq>T \<Longrightarrow> G\<turnstile>S\<preceq>T"
   179   proof induct
   180     case (refl T T') thus "G\<turnstile>T\<preceq>T'" .
   181   next
   182     case (subcls C D T)
   183     then obtain E where "T = Class E" by (blast dest: widen_Class)
   184     with subcls show "G\<turnstile>Class C\<preceq>T" by (auto elim: rtrancl_trans)
   185   next
   186     case (null R RT)
   187     then obtain rt where "RT = RefT rt" by (blast dest: widen_RefT)
   188     thus "G\<turnstile>NT\<preceq>RT" by auto
   189   qed
   190 qed
   191 
   192 end