src/HOL/Analysis/Linear_Algebra.thy
 author paulson Wed May 02 23:32:47 2018 +0100 (12 months ago) changeset 68069 36209dfb981e parent 68062 ee88c0fccbae child 68073 fad29d2a17a5 permissions -rw-r--r--
tidying up and using real induction methods
```     1 (*  Title:      HOL/Analysis/Linear_Algebra.thy
```
```     2     Author:     Amine Chaieb, University of Cambridge
```
```     3 *)
```
```     4
```
```     5 section \<open>Elementary linear algebra on Euclidean spaces\<close>
```
```     6
```
```     7 theory Linear_Algebra
```
```     8 imports
```
```     9   Euclidean_Space
```
```    10   "HOL-Library.Infinite_Set"
```
```    11 begin
```
```    12
```
```    13 lemma linear_simps:
```
```    14   assumes "bounded_linear f"
```
```    15   shows
```
```    16     "f (a + b) = f a + f b"
```
```    17     "f (a - b) = f a - f b"
```
```    18     "f 0 = 0"
```
```    19     "f (- a) = - f a"
```
```    20     "f (s *\<^sub>R v) = s *\<^sub>R (f v)"
```
```    21 proof -
```
```    22   interpret f: bounded_linear f by fact
```
```    23   show "f (a + b) = f a + f b" by (rule f.add)
```
```    24   show "f (a - b) = f a - f b" by (rule f.diff)
```
```    25   show "f 0 = 0" by (rule f.zero)
```
```    26   show "f (- a) = - f a" by (rule f.minus)
```
```    27   show "f (s *\<^sub>R v) = s *\<^sub>R (f v)" by (rule f.scaleR)
```
```    28 qed
```
```    29
```
```    30 subsection \<open>A generic notion of "hull" (convex, affine, conic hull and closure).\<close>
```
```    31
```
```    32 definition%important hull :: "('a set \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'a set"  (infixl "hull" 75)
```
```    33   where "S hull s = \<Inter>{t. S t \<and> s \<subseteq> t}"
```
```    34
```
```    35 lemma hull_same: "S s \<Longrightarrow> S hull s = s"
```
```    36   unfolding hull_def by auto
```
```    37
```
```    38 lemma hull_in: "(\<And>T. Ball T S \<Longrightarrow> S (\<Inter>T)) \<Longrightarrow> S (S hull s)"
```
```    39   unfolding hull_def Ball_def by auto
```
```    40
```
```    41 lemma hull_eq: "(\<And>T. Ball T S \<Longrightarrow> S (\<Inter>T)) \<Longrightarrow> (S hull s) = s \<longleftrightarrow> S s"
```
```    42   using hull_same[of S s] hull_in[of S s] by metis
```
```    43
```
```    44 lemma hull_hull [simp]: "S hull (S hull s) = S hull s"
```
```    45   unfolding hull_def by blast
```
```    46
```
```    47 lemma hull_subset[intro]: "s \<subseteq> (S hull s)"
```
```    48   unfolding hull_def by blast
```
```    49
```
```    50 lemma hull_mono: "s \<subseteq> t \<Longrightarrow> (S hull s) \<subseteq> (S hull t)"
```
```    51   unfolding hull_def by blast
```
```    52
```
```    53 lemma hull_antimono: "\<forall>x. S x \<longrightarrow> T x \<Longrightarrow> (T hull s) \<subseteq> (S hull s)"
```
```    54   unfolding hull_def by blast
```
```    55
```
```    56 lemma hull_minimal: "s \<subseteq> t \<Longrightarrow> S t \<Longrightarrow> (S hull s) \<subseteq> t"
```
```    57   unfolding hull_def by blast
```
```    58
```
```    59 lemma subset_hull: "S t \<Longrightarrow> S hull s \<subseteq> t \<longleftrightarrow> s \<subseteq> t"
```
```    60   unfolding hull_def by blast
```
```    61
```
```    62 lemma hull_UNIV [simp]: "S hull UNIV = UNIV"
```
```    63   unfolding hull_def by auto
```
```    64
```
```    65 lemma hull_unique: "s \<subseteq> t \<Longrightarrow> S t \<Longrightarrow> (\<And>t'. s \<subseteq> t' \<Longrightarrow> S t' \<Longrightarrow> t \<subseteq> t') \<Longrightarrow> (S hull s = t)"
```
```    66   unfolding hull_def by auto
```
```    67
```
```    68 lemma hull_induct: "\<lbrakk>a \<in> Q hull S; \<And>x. x\<in> S \<Longrightarrow> P x; Q {x. P x}\<rbrakk> \<Longrightarrow> P a"
```
```    69   using hull_minimal[of S "{x. P x}" Q]
```
```    70   by (auto simp add: subset_eq)
```
```    71
```
```    72 lemma hull_inc: "x \<in> S \<Longrightarrow> x \<in> P hull S"
```
```    73   by (metis hull_subset subset_eq)
```
```    74
```
```    75 lemma hull_Un_subset: "(S hull s) \<union> (S hull t) \<subseteq> (S hull (s \<union> t))"
```
```    76   unfolding Un_subset_iff by (metis hull_mono Un_upper1 Un_upper2)
```
```    77
```
```    78 lemma hull_Un:
```
```    79   assumes T: "\<And>T. Ball T S \<Longrightarrow> S (\<Inter>T)"
```
```    80   shows "S hull (s \<union> t) = S hull (S hull s \<union> S hull t)"
```
```    81   apply (rule equalityI)
```
```    82   apply (meson hull_mono hull_subset sup.mono)
```
```    83   by (metis hull_Un_subset hull_hull hull_mono)
```
```    84
```
```    85 lemma hull_Un_left: "P hull (S \<union> T) = P hull (P hull S \<union> T)"
```
```    86   apply (rule equalityI)
```
```    87    apply (simp add: Un_commute hull_mono hull_subset sup.coboundedI2)
```
```    88   by (metis Un_subset_iff hull_hull hull_mono hull_subset)
```
```    89
```
```    90 lemma hull_Un_right: "P hull (S \<union> T) = P hull (S \<union> P hull T)"
```
```    91   by (metis hull_Un_left sup.commute)
```
```    92
```
```    93 lemma hull_insert:
```
```    94    "P hull (insert a S) = P hull (insert a (P hull S))"
```
```    95   by (metis hull_Un_right insert_is_Un)
```
```    96
```
```    97 lemma hull_redundant_eq: "a \<in> (S hull s) \<longleftrightarrow> S hull (insert a s) = S hull s"
```
```    98   unfolding hull_def by blast
```
```    99
```
```   100 lemma hull_redundant: "a \<in> (S hull s) \<Longrightarrow> S hull (insert a s) = S hull s"
```
```   101   by (metis hull_redundant_eq)
```
```   102
```
```   103 subsection \<open>Linear functions.\<close>
```
```   104
```
```   105 lemma%important linear_iff:
```
```   106   "linear f \<longleftrightarrow> (\<forall>x y. f (x + y) = f x + f y) \<and> (\<forall>c x. f (c *\<^sub>R x) = c *\<^sub>R f x)"
```
```   107   (is "linear f \<longleftrightarrow> ?rhs")
```
```   108 proof%unimportant
```
```   109   assume "linear f"
```
```   110   then interpret f: linear f .
```
```   111   show "?rhs" by (simp add: f.add f.scaleR)
```
```   112 next
```
```   113   assume "?rhs"
```
```   114   then show "linear f" by unfold_locales simp_all
```
```   115 qed
```
```   116
```
```   117 lemma linear_compose_cmul: "linear f \<Longrightarrow> linear (\<lambda>x. c *\<^sub>R f x)"
```
```   118   by (simp add: linear_iff algebra_simps)
```
```   119
```
```   120 lemma linear_compose_scaleR: "linear f \<Longrightarrow> linear (\<lambda>x. f x *\<^sub>R c)"
```
```   121   by (simp add: linear_iff scaleR_add_left)
```
```   122
```
```   123 lemma linear_compose_neg: "linear f \<Longrightarrow> linear (\<lambda>x. - f x)"
```
```   124   by (simp add: linear_iff)
```
```   125
```
```   126 lemma linear_compose_add: "linear f \<Longrightarrow> linear g \<Longrightarrow> linear (\<lambda>x. f x + g x)"
```
```   127   by (simp add: linear_iff algebra_simps)
```
```   128
```
```   129 lemma linear_compose_sub: "linear f \<Longrightarrow> linear g \<Longrightarrow> linear (\<lambda>x. f x - g x)"
```
```   130   by (simp add: linear_iff algebra_simps)
```
```   131
```
```   132 lemma linear_compose: "linear f \<Longrightarrow> linear g \<Longrightarrow> linear (g \<circ> f)"
```
```   133   by (simp add: linear_iff)
```
```   134
```
```   135 lemma linear_id: "linear id"
```
```   136   by (simp add: linear_iff id_def)
```
```   137
```
```   138 lemma linear_zero: "linear (\<lambda>x. 0)"
```
```   139   by (simp add: linear_iff)
```
```   140
```
```   141 lemma linear_uminus: "linear uminus"
```
```   142 by (simp add: linear_iff)
```
```   143
```
```   144 lemma linear_compose_sum:
```
```   145   assumes lS: "\<forall>a \<in> S. linear (f a)"
```
```   146   shows "linear (\<lambda>x. sum (\<lambda>a. f a x) S)"
```
```   147 proof (cases "finite S")
```
```   148   case True
```
```   149   then show ?thesis
```
```   150     using lS by induct (simp_all add: linear_zero linear_compose_add)
```
```   151 next
```
```   152   case False
```
```   153   then show ?thesis
```
```   154     by (simp add: linear_zero)
```
```   155 qed
```
```   156
```
```   157 lemma linear_0: "linear f \<Longrightarrow> f 0 = 0"
```
```   158   unfolding linear_iff  by (metis real_vector.scale_zero_left)
```
```   159
```
```   160 lemma linear_cmul: "linear f \<Longrightarrow> f (c *\<^sub>R x) = c *\<^sub>R f x"
```
```   161   by (rule linear.scaleR)
```
```   162
```
```   163 lemma linear_neg: "linear f \<Longrightarrow> f (- x) = - f x"
```
```   164   using linear_cmul [where c="-1"] by simp
```
```   165
```
```   166 lemma linear_add: "linear f \<Longrightarrow> f (x + y) = f x + f y"
```
```   167   by (metis linear_iff)
```
```   168
```
```   169 lemma linear_diff: "linear f \<Longrightarrow> f (x - y) = f x - f y"
```
```   170   using linear_add [of f x "- y"] by (simp add: linear_neg)
```
```   171
```
```   172 lemma linear_sum:
```
```   173   assumes f: "linear f"
```
```   174   shows "f (sum g S) = sum (f \<circ> g) S"
```
```   175 proof (cases "finite S")
```
```   176   case True
```
```   177   then show ?thesis
```
```   178     by induct (simp_all add: linear_0 [OF f] linear_add [OF f])
```
```   179 next
```
```   180   case False
```
```   181   then show ?thesis
```
```   182     by (simp add: linear_0 [OF f])
```
```   183 qed
```
```   184
```
```   185 lemma linear_sum_mul:
```
```   186   assumes lin: "linear f"
```
```   187   shows "f (sum (\<lambda>i. c i *\<^sub>R v i) S) = sum (\<lambda>i. c i *\<^sub>R f (v i)) S"
```
```   188   using linear_sum[OF lin, of "\<lambda>i. c i *\<^sub>R v i" , unfolded o_def] linear_cmul[OF lin]
```
```   189   by simp
```
```   190
```
```   191 lemma linear_injective_0:
```
```   192   assumes lin: "linear f"
```
```   193   shows "inj f \<longleftrightarrow> (\<forall>x. f x = 0 \<longrightarrow> x = 0)"
```
```   194 proof -
```
```   195   have "inj f \<longleftrightarrow> (\<forall> x y. f x = f y \<longrightarrow> x = y)"
```
```   196     by (simp add: inj_on_def)
```
```   197   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f x - f y = 0 \<longrightarrow> x - y = 0)"
```
```   198     by simp
```
```   199   also have "\<dots> \<longleftrightarrow> (\<forall> x y. f (x - y) = 0 \<longrightarrow> x - y = 0)"
```
```   200     by (simp add: linear_diff[OF lin])
```
```   201   also have "\<dots> \<longleftrightarrow> (\<forall> x. f x = 0 \<longrightarrow> x = 0)"
```
```   202     by auto
```
```   203   finally show ?thesis .
```
```   204 qed
```
```   205
```
```   206 lemma linear_scaleR  [simp]: "linear (\<lambda>x. scaleR c x)"
```
```   207   by (simp add: linear_iff scaleR_add_right)
```
```   208
```
```   209 lemma linear_scaleR_left [simp]: "linear (\<lambda>r. scaleR r x)"
```
```   210   by (simp add: linear_iff scaleR_add_left)
```
```   211
```
```   212 lemma injective_scaleR: "c \<noteq> 0 \<Longrightarrow> inj (\<lambda>x::'a::real_vector. scaleR c x)"
```
```   213   by (simp add: inj_on_def)
```
```   214
```
```   215 lemma linear_add_cmul:
```
```   216   assumes "linear f"
```
```   217   shows "f (a *\<^sub>R x + b *\<^sub>R y) = a *\<^sub>R f x +  b *\<^sub>R f y"
```
```   218   using linear_add[of f] linear_cmul[of f] assms by simp
```
```   219
```
```   220 subsection \<open>Subspaces of vector spaces\<close>
```
```   221
```
```   222 definition%important (in real_vector) subspace :: "'a set \<Rightarrow> bool"
```
```   223   where "subspace S \<longleftrightarrow> 0 \<in> S \<and> (\<forall>x \<in> S. \<forall>y \<in> S. x + y \<in> S) \<and> (\<forall>c. \<forall>x \<in> S. c *\<^sub>R x \<in> S)"
```
```   224
```
```   225 definition%important (in real_vector) "span S = (subspace hull S)"
```
```   226 definition%important (in real_vector) "dependent S \<longleftrightarrow> (\<exists>a \<in> S. a \<in> span (S - {a}))"
```
```   227 abbreviation (in real_vector) "independent s \<equiv> \<not> dependent s"
```
```   228
```
```   229 text \<open>Closure properties of subspaces.\<close>
```
```   230
```
```   231 lemma subspace_UNIV[simp]: "subspace UNIV"
```
```   232   by (simp add: subspace_def)
```
```   233
```
```   234 lemma (in real_vector) subspace_0: "subspace S \<Longrightarrow> 0 \<in> S"
```
```   235   by (metis subspace_def)
```
```   236
```
```   237 lemma (in real_vector) subspace_add: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> x + y \<in> S"
```
```   238   by (metis subspace_def)
```
```   239
```
```   240 lemma (in real_vector) subspace_mul: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> c *\<^sub>R x \<in> S"
```
```   241   by (metis subspace_def)
```
```   242
```
```   243 lemma subspace_neg: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> - x \<in> S"
```
```   244   by (metis scaleR_minus1_left subspace_mul)
```
```   245
```
```   246 lemma subspace_diff: "subspace S \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S \<Longrightarrow> x - y \<in> S"
```
```   247   using subspace_add [of S x "- y"] by (simp add: subspace_neg)
```
```   248
```
```   249 lemma (in real_vector) subspace_sum:
```
```   250   assumes sA: "subspace A"
```
```   251     and f: "\<And>x. x \<in> B \<Longrightarrow> f x \<in> A"
```
```   252   shows "sum f B \<in> A"
```
```   253 proof (cases "finite B")
```
```   254   case True
```
```   255   then show ?thesis
```
```   256     using f by induct (simp_all add: subspace_0 [OF sA] subspace_add [OF sA])
```
```   257 qed (simp add: subspace_0 [OF sA])
```
```   258
```
```   259 lemma subspace_trivial [iff]: "subspace {0}"
```
```   260   by (simp add: subspace_def)
```
```   261
```
```   262 lemma (in real_vector) subspace_inter: "subspace A \<Longrightarrow> subspace B \<Longrightarrow> subspace (A \<inter> B)"
```
```   263   by (simp add: subspace_def)
```
```   264
```
```   265 lemma subspace_Times: "subspace A \<Longrightarrow> subspace B \<Longrightarrow> subspace (A \<times> B)"
```
```   266   unfolding subspace_def zero_prod_def by simp
```
```   267
```
```   268 lemma subspace_sums: "\<lbrakk>subspace S; subspace T\<rbrakk> \<Longrightarrow> subspace {x + y|x y. x \<in> S \<and> y \<in> T}"
```
```   269 apply (simp add: subspace_def)
```
```   270 apply (intro conjI impI allI)
```
```   271   using add.right_neutral apply blast
```
```   272  apply clarify
```
```   273  apply (metis add.assoc add.left_commute)
```
```   274 using scaleR_add_right by blast
```
```   275
```
```   276 subsection%unimportant \<open>Properties of span\<close>
```
```   277
```
```   278 lemma (in real_vector) span_mono: "A \<subseteq> B \<Longrightarrow> span A \<subseteq> span B"
```
```   279   by (metis span_def hull_mono)
```
```   280
```
```   281 lemma (in real_vector) subspace_span [iff]: "subspace (span S)"
```
```   282   unfolding span_def
```
```   283   by (rule hull_in) (auto simp: subspace_def)
```
```   284
```
```   285 lemma (in real_vector) span_superset: "a \<in> S \<Longrightarrow> a \<in> span S"
```
```   286         and span_0 [simp]: "0 \<in> span S"
```
```   287         and span_add: "x \<in> span S \<Longrightarrow> y \<in> span S \<Longrightarrow> x + y \<in> span S"
```
```   288         and span_mul: "x \<in> span S \<Longrightarrow> c *\<^sub>R x \<in> span S"
```
```   289   by (metis span_def hull_subset subset_eq) (metis subspace_span subspace_def)+
```
```   290
```
```   291 lemmas (in real_vector) span_clauses = span_superset span_0 span_add span_mul
```
```   292
```
```   293 lemma span_neg: "x \<in> span S \<Longrightarrow> - x \<in> span S"
```
```   294   by (metis subspace_neg subspace_span)
```
```   295
```
```   296 lemma span_diff: "x \<in> span S \<Longrightarrow> y \<in> span S \<Longrightarrow> x - y \<in> span S"
```
```   297   by (metis subspace_span subspace_diff)
```
```   298
```
```   299 lemma (in real_vector) span_sum: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> span S) \<Longrightarrow> sum f A \<in> span S"
```
```   300   by (rule subspace_sum [OF subspace_span])
```
```   301
```
```   302 lemma span_add_eq: "x \<in> span S \<Longrightarrow> x + y \<in> span S \<longleftrightarrow> y \<in> span S"
```
```   303   by (metis add_minus_cancel scaleR_minus1_left subspace_def subspace_span)
```
```   304
```
```   305 lemma span_unique:
```
```   306   "S \<subseteq> T \<Longrightarrow> subspace T \<Longrightarrow> (\<And>T'. S \<subseteq> T' \<Longrightarrow> subspace T' \<Longrightarrow> T \<subseteq> T') \<Longrightarrow> span S = T"
```
```   307   unfolding span_def by (rule hull_unique)
```
```   308
```
```   309 lemma span_minimal: "S \<subseteq> T \<Longrightarrow> subspace T \<Longrightarrow> span S \<subseteq> T"
```
```   310   unfolding span_def by (rule hull_minimal)
```
```   311
```
```   312 lemma span_UNIV [simp]: "span UNIV = UNIV"
```
```   313   by (intro span_unique) auto
```
```   314
```
```   315 lemma (in real_vector) span_induct [consumes 1, case_names base step, induct set: span]:
```
```   316   assumes x: "x \<in> span S"
```
```   317     and P: "subspace (Collect P)"
```
```   318     and SP: "\<And>x. x \<in> S \<Longrightarrow> P x"
```
```   319   shows "P x"
```
```   320 proof -
```
```   321   from SP have SP': "S \<subseteq> Collect P"
```
```   322     by (simp add: subset_eq)
```
```   323   from x hull_minimal[where S=subspace, OF SP' P, unfolded span_def[symmetric]]
```
```   324   show ?thesis
```
```   325     using subset_eq by force
```
```   326 qed
```
```   327
```
```   328 lemma span_empty[simp]: "span {} = {0}"
```
```   329   unfolding span_def
```
```   330   by (rule hull_unique) (auto simp add: subspace_def)
```
```   331
```
```   332 lemma (in real_vector) independent_empty [iff]: "independent {}"
```
```   333   by (simp add: dependent_def)
```
```   334
```
```   335 lemma dependent_single[simp]: "dependent {x} \<longleftrightarrow> x = 0"
```
```   336   unfolding dependent_def by auto
```
```   337
```
```   338 lemma (in real_vector) independent_mono: "independent A \<Longrightarrow> B \<subseteq> A \<Longrightarrow> independent B"
```
```   339   unfolding dependent_def span_mono
```
```   340   by (metis insert_Diff local.span_mono subsetCE subset_insert_iff)
```
```   341
```
```   342 lemma (in real_vector) span_subspace: "A \<subseteq> B \<Longrightarrow> B \<le> span A \<Longrightarrow>  subspace B \<Longrightarrow> span A = B"
```
```   343   by (metis order_antisym span_def hull_minimal)
```
```   344
```
```   345 inductive_set (in real_vector) span_induct_alt_help for S :: "'a set"
```
```   346 where
```
```   347   span_induct_alt_help_0: "0 \<in> span_induct_alt_help S"
```
```   348 | span_induct_alt_help_S:
```
```   349     "x \<in> S \<Longrightarrow> z \<in> span_induct_alt_help S \<Longrightarrow>
```
```   350       (c *\<^sub>R x + z) \<in> span_induct_alt_help S"
```
```   351
```
```   352 lemma span_induct_alt [consumes 1, case_names base step, induct set: span]:
```
```   353   assumes x: "x \<in> span S"
```
```   354     and h0: "h 0"
```
```   355     and hS: "\<And>c x y. x \<in> S \<Longrightarrow> h y \<Longrightarrow> h (c *\<^sub>R x + y)"
```
```   356   shows "h x"
```
```   357 proof -
```
```   358   have th0: "h x" if "x \<in> span_induct_alt_help S" for x
```
```   359     by (metis span_induct_alt_help.induct[OF that] h0 hS)
```
```   360   have "x \<in> span_induct_alt_help S" if "x \<in> span S" for x
```
```   361     using that
```
```   362   proof (induction x rule: span_induct)
```
```   363     case base
```
```   364     have 0: "0 \<in> span_induct_alt_help S"
```
```   365       by (rule span_induct_alt_help_0)
```
```   366     moreover
```
```   367     have "(x + y) \<in> span_induct_alt_help S"
```
```   368       if "x \<in> span_induct_alt_help S" "y \<in> span_induct_alt_help S" for x y
```
```   369       using that
```
```   370       by induct (auto simp: add.assoc span_induct_alt_help.span_induct_alt_help_S)
```
```   371     moreover
```
```   372     have "(c *\<^sub>R x) \<in> span_induct_alt_help S" if "x \<in> span_induct_alt_help S" for c x
```
```   373       using that
```
```   374       proof (induction rule: span_induct_alt_help.induct)
```
```   375         case span_induct_alt_help_0
```
```   376         then show ?case
```
```   377           by (simp add: 0)
```
```   378       next
```
```   379         case (span_induct_alt_help_S x z c)
```
```   380         then show ?case
```
```   381           by (simp add: scaleR_add_right span_induct_alt_help.span_induct_alt_help_S)
```
```   382       qed
```
```   383     ultimately show ?case
```
```   384       unfolding subspace_def Ball_def by blast
```
```   385   next
```
```   386     case (step x)
```
```   387     then show ?case
```
```   388       using span_induct_alt_help_S[OF step span_induct_alt_help_0, of 1]
```
```   389       by simp
```
```   390   qed
```
```   391   with th0 x show ?thesis by blast
```
```   392 qed
```
```   393
```
```   394 text \<open>Individual closure properties.\<close>
```
```   395
```
```   396 lemma span_span: "span (span A) = span A"
```
```   397   unfolding span_def hull_hull ..
```
```   398
```
```   399 lemma span_inc: "S \<subseteq> span S"
```
```   400   by (metis subset_eq span_superset)
```
```   401
```
```   402 lemma span_eq: "span S = span T \<longleftrightarrow> S \<subseteq> span T \<and> T \<subseteq> span S"
```
```   403   using span_inc[unfolded subset_eq] using span_mono[of T "span S"] span_mono[of S "span T"]
```
```   404   by (auto simp add: span_span)
```
```   405
```
```   406 lemma (in real_vector) dependent_0:
```
```   407   assumes "0 \<in> A"
```
```   408   shows "dependent A"
```
```   409   unfolding dependent_def
```
```   410   using assms span_0 by blast
```
```   411
```
```   412 text \<open>The key breakdown property.\<close>
```
```   413
```
```   414 lemma span_singleton: "span {x} = range (\<lambda>k. k *\<^sub>R x)"
```
```   415 proof (rule span_unique)
```
```   416   show "{x} \<subseteq> range (\<lambda>k. k *\<^sub>R x)"
```
```   417     by (fast intro: scaleR_one [symmetric])
```
```   418   show "subspace (range (\<lambda>k. k *\<^sub>R x))"
```
```   419     unfolding subspace_def
```
```   420     by (auto intro: scaleR_add_left [symmetric])
```
```   421 next
```
```   422   fix T
```
```   423   assume "{x} \<subseteq> T" and "subspace T"
```
```   424   then show "range (\<lambda>k. k *\<^sub>R x) \<subseteq> T"
```
```   425     unfolding subspace_def by auto
```
```   426 qed
```
```   427
```
```   428 text \<open>Mapping under linear image.\<close>
```
```   429
```
```   430 lemma subspace_linear_image:
```
```   431   assumes lf: "linear f"
```
```   432     and sS: "subspace S"
```
```   433   shows "subspace (f ` S)"
```
```   434   using lf sS linear_0[OF lf]
```
```   435   unfolding linear_iff subspace_def
```
```   436   apply (auto simp add: image_iff)
```
```   437   apply (rule_tac x="x + y" in bexI)
```
```   438   apply auto
```
```   439   apply (rule_tac x="c *\<^sub>R x" in bexI)
```
```   440   apply auto
```
```   441   done
```
```   442
```
```   443 lemma subspace_linear_vimage: "linear f \<Longrightarrow> subspace S \<Longrightarrow> subspace (f -` S)"
```
```   444   by (auto simp add: subspace_def linear_iff linear_0[of f])
```
```   445
```
```   446 lemma subspace_linear_preimage: "linear f \<Longrightarrow> subspace S \<Longrightarrow> subspace {x. f x \<in> S}"
```
```   447   by (auto simp add: subspace_def linear_iff linear_0[of f])
```
```   448
```
```   449 lemma span_linear_image:
```
```   450   assumes lf: "linear f"
```
```   451   shows "span (f ` S) = f ` span S"
```
```   452 proof (rule span_unique)
```
```   453   show "f ` S \<subseteq> f ` span S"
```
```   454     by (intro image_mono span_inc)
```
```   455   show "subspace (f ` span S)"
```
```   456     using lf subspace_span by (rule subspace_linear_image)
```
```   457 next
```
```   458   fix T
```
```   459   assume "f ` S \<subseteq> T" and "subspace T"
```
```   460   then show "f ` span S \<subseteq> T"
```
```   461     unfolding image_subset_iff_subset_vimage
```
```   462     by (intro span_minimal subspace_linear_vimage lf)
```
```   463 qed
```
```   464
```
```   465 lemma spans_image:
```
```   466   assumes lf: "linear f"
```
```   467     and VB: "V \<subseteq> span B"
```
```   468   shows "f ` V \<subseteq> span (f ` B)"
```
```   469   unfolding span_linear_image[OF lf] by (metis VB image_mono)
```
```   470
```
```   471 lemma span_Un: "span (A \<union> B) = (\<lambda>(a, b). a + b) ` (span A \<times> span B)"
```
```   472 proof (rule span_unique)
```
```   473   show "A \<union> B \<subseteq> (\<lambda>(a, b). a + b) ` (span A \<times> span B)"
```
```   474     by safe (force intro: span_clauses)+
```
```   475 next
```
```   476   have "linear (\<lambda>(a, b). a + b)"
```
```   477     by (simp add: linear_iff scaleR_add_right)
```
```   478   moreover have "subspace (span A \<times> span B)"
```
```   479     by (intro subspace_Times subspace_span)
```
```   480   ultimately show "subspace ((\<lambda>(a, b). a + b) ` (span A \<times> span B))"
```
```   481     by (rule subspace_linear_image)
```
```   482 next
```
```   483   fix T
```
```   484   assume "A \<union> B \<subseteq> T" and "subspace T"
```
```   485   then show "(\<lambda>(a, b). a + b) ` (span A \<times> span B) \<subseteq> T"
```
```   486     by (auto intro!: subspace_add elim: span_induct)
```
```   487 qed
```
```   488
```
```   489 lemma span_insert: "span (insert a S) = {x. \<exists>k. (x - k *\<^sub>R a) \<in> span S}"
```
```   490 proof -
```
```   491   have "span ({a} \<union> S) = {x. \<exists>k. (x - k *\<^sub>R a) \<in> span S}"
```
```   492     unfolding span_Un span_singleton
```
```   493     apply (auto simp: image_iff)
```
```   494     apply (metis add_diff_cancel_left')
```
```   495     by force
```
```   496   then show ?thesis by simp
```
```   497 qed
```
```   498
```
```   499 lemma span_breakdown:
```
```   500   assumes bS: "b \<in> S"
```
```   501     and aS: "a \<in> span S"
```
```   502   shows "\<exists>k. a - k *\<^sub>R b \<in> span (S - {b})"
```
```   503   using assms span_insert [of b "S - {b}"]
```
```   504   by (simp add: insert_absorb)
```
```   505
```
```   506 lemma span_breakdown_eq: "x \<in> span (insert a S) \<longleftrightarrow> (\<exists>k. x - k *\<^sub>R a \<in> span S)"
```
```   507   by (simp add: span_insert)
```
```   508
```
```   509 text \<open>Hence some "reversal" results.\<close>
```
```   510
```
```   511 lemma in_span_insert:
```
```   512   assumes a: "a \<in> span (insert b S)"
```
```   513     and na: "a \<notin> span S"
```
```   514   shows "b \<in> span (insert a S)"
```
```   515 proof -
```
```   516   from a obtain k where k: "a - k *\<^sub>R b \<in> span S"
```
```   517     unfolding span_insert by fast
```
```   518   show ?thesis
```
```   519   proof (cases "k = 0")
```
```   520     case True
```
```   521     with k have "a \<in> span S" by simp
```
```   522     with na show ?thesis by simp
```
```   523   next
```
```   524     case False
```
```   525     from k have "(- inverse k) *\<^sub>R (a - k *\<^sub>R b) \<in> span S"
```
```   526       by (rule span_mul)
```
```   527     then have "b - inverse k *\<^sub>R a \<in> span S"
```
```   528       using \<open>k \<noteq> 0\<close> by (simp add: scaleR_diff_right)
```
```   529     then show ?thesis
```
```   530       unfolding span_insert by fast
```
```   531   qed
```
```   532 qed
```
```   533
```
```   534 lemma in_span_delete:
```
```   535   assumes a: "a \<in> span S"
```
```   536     and na: "a \<notin> span (S - {b})"
```
```   537   shows "b \<in> span (insert a (S - {b}))"
```
```   538   apply (rule in_span_insert)
```
```   539   apply (rule set_rev_mp)
```
```   540   apply (rule a)
```
```   541   apply (rule span_mono)
```
```   542   apply blast
```
```   543   apply (rule na)
```
```   544   done
```
```   545
```
```   546 text \<open>Transitivity property.\<close>
```
```   547
```
```   548 lemma span_redundant: "x \<in> span S \<Longrightarrow> span (insert x S) = span S"
```
```   549   unfolding span_def by (rule hull_redundant)
```
```   550
```
```   551 lemma span_trans:
```
```   552   assumes x: "x \<in> span S"
```
```   553     and y: "y \<in> span (insert x S)"
```
```   554   shows "y \<in> span S"
```
```   555   using assms by (simp only: span_redundant)
```
```   556
```
```   557 lemma span_insert_0[simp]: "span (insert 0 S) = span S"
```
```   558   by (simp only: span_redundant span_0)
```
```   559
```
```   560 text \<open>An explicit expansion is sometimes needed.\<close>
```
```   561
```
```   562 lemma span_explicit:
```
```   563   "span P = {y. \<exists>S u. finite S \<and> S \<subseteq> P \<and> sum (\<lambda>v. u v *\<^sub>R v) S = y}"
```
```   564   (is "_ = {y. ?h y}" is "_ = {y. \<exists>S u. ?Q S u y}")
```
```   565 proof -
```
```   566   have "x \<in> span P" if "?h x" for x
```
```   567   proof -
```
```   568     from that
```
```   569     obtain S u where "finite S" and "S \<subseteq> P" and "sum (\<lambda>v. u v *\<^sub>R v) S = x"
```
```   570       by blast
```
```   571     then show ?thesis
```
```   572       by (auto intro: span_sum span_mul span_superset)
```
```   573   qed
```
```   574   moreover
```
```   575   have "?h x" if "x \<in> span P" for x
```
```   576     using that
```
```   577   proof (induction rule: span_induct_alt)
```
```   578     case base
```
```   579     then show ?case
```
```   580       by force
```
```   581   next
```
```   582     case (step c x y)
```
```   583     then obtain S u where fS: "finite S" and SP: "S\<subseteq>P"
```
```   584       and u: "sum (\<lambda>v. u v *\<^sub>R v) S = y" by blast
```
```   585     let ?S = "insert x S"
```
```   586     let ?u = "\<lambda>y. if y = x then (if x \<in> S then u y + c else c) else u y"
```
```   587     from fS SP step have th0: "finite (insert x S)" "insert x S \<subseteq> P"
```
```   588       by blast+
```
```   589     have "?Q ?S ?u (c*\<^sub>R x + y)"
```
```   590     proof cases
```
```   591       assume xS: "x \<in> S"
```
```   592       have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = (\<Sum>v\<in>S - {x}. u v *\<^sub>R v) + (u x + c) *\<^sub>R x"
```
```   593         using xS by (simp add: sum.remove [OF fS xS] insert_absorb)
```
```   594       also have "\<dots> = (\<Sum>v\<in>S. u v *\<^sub>R v) + c *\<^sub>R x"
```
```   595         by (simp add: sum.remove [OF fS xS] algebra_simps)
```
```   596       also have "\<dots> = c*\<^sub>R x + y"
```
```   597         by (simp add: add.commute u)
```
```   598       finally have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = c*\<^sub>R x + y" .
```
```   599       then show ?thesis using th0 by blast
```
```   600     next
```
```   601       assume xS: "x \<notin> S"
```
```   602       have "(\<Sum>v\<in>S. (if v = x then c else u v) *\<^sub>R v) = y"
```
```   603         unfolding u[symmetric]
```
```   604         by (rule sum.cong) (use xS in auto)
```
```   605       then show ?thesis using fS xS th0
```
```   606         by (simp add: add.commute cong del: if_weak_cong)
```
```   607     qed
```
```   608     then show ?case
```
```   609       by fast
```
```   610   qed
```
```   611   ultimately show ?thesis by blast
```
```   612 qed
```
```   613
```
```   614 lemma dependent_explicit:
```
```   615   "dependent P \<longleftrightarrow> (\<exists>S u. finite S \<and> S \<subseteq> P \<and> (\<exists>v\<in>S. u v \<noteq> 0 \<and> sum (\<lambda>v. u v *\<^sub>R v) S = 0))"
```
```   616   (is "?lhs = ?rhs")
```
```   617 proof -
```
```   618   {
```
```   619     assume dP: "dependent P"
```
```   620     then obtain a S u where aP: "a \<in> P" and fS: "finite S"
```
```   621       and SP: "S \<subseteq> P - {a}" and ua: "sum (\<lambda>v. u v *\<^sub>R v) S = a"
```
```   622       unfolding dependent_def span_explicit by blast
```
```   623     let ?S = "insert a S"
```
```   624     let ?u = "\<lambda>y. if y = a then - 1 else u y"
```
```   625     let ?v = a
```
```   626     from aP SP have aS: "a \<notin> S"
```
```   627       by blast
```
```   628     have "(\<Sum>v\<in>S. (if v = a then - 1 else u v) *\<^sub>R v) = (\<Sum>v\<in>S. u v *\<^sub>R v)"
```
```   629       using aS by (auto intro: sum.cong)
```
```   630     then have s0: "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = 0"
```
```   631       using fS aS by (simp add: ua)
```
```   632     moreover from fS SP aP have "finite ?S" "?S \<subseteq> P" "?v \<in> ?S" "?u ?v \<noteq> 0"
```
```   633       by auto
```
```   634     ultimately have ?rhs by fast
```
```   635   }
```
```   636   moreover
```
```   637   {
```
```   638     fix S u v
```
```   639     assume fS: "finite S"
```
```   640       and SP: "S \<subseteq> P"
```
```   641       and vS: "v \<in> S"
```
```   642       and uv: "u v \<noteq> 0"
```
```   643       and u: "sum (\<lambda>v. u v *\<^sub>R v) S = 0"
```
```   644     let ?a = v
```
```   645     let ?S = "S - {v}"
```
```   646     let ?u = "\<lambda>i. (- u i) / u v"
```
```   647     have th0: "?a \<in> P" "finite ?S" "?S \<subseteq> P"
```
```   648       using fS SP vS by auto
```
```   649     have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S =
```
```   650       sum (\<lambda>v. (- (inverse (u ?a))) *\<^sub>R (u v *\<^sub>R v)) S - ?u v *\<^sub>R v"
```
```   651       using fS vS uv by (simp add: sum_diff1 field_simps)
```
```   652     also have "\<dots> = ?a"
```
```   653       unfolding scaleR_right.sum [symmetric] u using uv by simp
```
```   654     finally have "sum (\<lambda>v. ?u v *\<^sub>R v) ?S = ?a" .
```
```   655     with th0 have ?lhs
```
```   656       unfolding dependent_def span_explicit
```
```   657       apply -
```
```   658       apply (rule bexI[where x= "?a"])
```
```   659       apply (simp_all del: scaleR_minus_left)
```
```   660       apply (rule exI[where x= "?S"])
```
```   661       apply (auto simp del: scaleR_minus_left)
```
```   662       done
```
```   663   }
```
```   664   ultimately show ?thesis by blast
```
```   665 qed
```
```   666
```
```   667 lemma dependent_finite:
```
```   668   assumes "finite S"
```
```   669     shows "dependent S \<longleftrightarrow> (\<exists>u. (\<exists>v \<in> S. u v \<noteq> 0) \<and> (\<Sum>v\<in>S. u v *\<^sub>R v) = 0)"
```
```   670            (is "?lhs = ?rhs")
```
```   671 proof
```
```   672   assume ?lhs
```
```   673   then obtain T u v
```
```   674          where "finite T" "T \<subseteq> S" "v\<in>T" "u v \<noteq> 0" "(\<Sum>v\<in>T. u v *\<^sub>R v) = 0"
```
```   675     by (force simp: dependent_explicit)
```
```   676   with assms show ?rhs
```
```   677     apply (rule_tac x="\<lambda>v. if v \<in> T then u v else 0" in exI)
```
```   678     apply (auto simp: sum.mono_neutral_right)
```
```   679     done
```
```   680 next
```
```   681   assume ?rhs  with assms show ?lhs
```
```   682     by (fastforce simp add: dependent_explicit)
```
```   683 qed
```
```   684
```
```   685 lemma span_alt:
```
```   686   "span B = {(\<Sum>x | f x \<noteq> 0. f x *\<^sub>R x) | f. {x. f x \<noteq> 0} \<subseteq> B \<and> finite {x. f x \<noteq> 0}}"
```
```   687   unfolding span_explicit
```
```   688   apply safe
```
```   689   subgoal for x S u
```
```   690     by (intro exI[of _ "\<lambda>x. if x \<in> S then u x else 0"])
```
```   691         (auto intro!: sum.mono_neutral_cong_right)
```
```   692   apply auto
```
```   693   done
```
```   694
```
```   695 lemma dependent_alt:
```
```   696   "dependent B \<longleftrightarrow>
```
```   697     (\<exists>X. finite {x. X x \<noteq> 0} \<and> {x. X x \<noteq> 0} \<subseteq> B \<and> (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x) = 0 \<and> (\<exists>x. X x \<noteq> 0))"
```
```   698   unfolding dependent_explicit
```
```   699   apply safe
```
```   700   subgoal for S u v
```
```   701     apply (intro exI[of _ "\<lambda>x. if x \<in> S then u x else 0"])
```
```   702     apply (subst sum.mono_neutral_cong_left[where T=S])
```
```   703     apply (auto intro!: sum.mono_neutral_cong_right cong: rev_conj_cong)
```
```   704     done
```
```   705   apply auto
```
```   706   done
```
```   707
```
```   708 lemma independent_alt:
```
```   709   "independent B \<longleftrightarrow>
```
```   710     (\<forall>X. finite {x. X x \<noteq> 0} \<longrightarrow> {x. X x \<noteq> 0} \<subseteq> B \<longrightarrow> (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x) = 0 \<longrightarrow> (\<forall>x. X x = 0))"
```
```   711   unfolding dependent_alt by auto
```
```   712
```
```   713 lemma independentD_alt:
```
```   714   "independent B \<Longrightarrow> finite {x. X x \<noteq> 0} \<Longrightarrow> {x. X x \<noteq> 0} \<subseteq> B \<Longrightarrow> (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x) = 0 \<Longrightarrow> X x = 0"
```
```   715   unfolding independent_alt by blast
```
```   716
```
```   717 lemma independentD_unique:
```
```   718   assumes B: "independent B"
```
```   719     and X: "finite {x. X x \<noteq> 0}" "{x. X x \<noteq> 0} \<subseteq> B"
```
```   720     and Y: "finite {x. Y x \<noteq> 0}" "{x. Y x \<noteq> 0} \<subseteq> B"
```
```   721     and "(\<Sum>x | X x \<noteq> 0. X x *\<^sub>R x) = (\<Sum>x| Y x \<noteq> 0. Y x *\<^sub>R x)"
```
```   722   shows "X = Y"
```
```   723 proof -
```
```   724   have "X x - Y x = 0" for x
```
```   725     using B
```
```   726   proof (rule independentD_alt)
```
```   727     have "{x. X x - Y x \<noteq> 0} \<subseteq> {x. X x \<noteq> 0} \<union> {x. Y x \<noteq> 0}"
```
```   728       by auto
```
```   729     then show "finite {x. X x - Y x \<noteq> 0}" "{x. X x - Y x \<noteq> 0} \<subseteq> B"
```
```   730       using X Y by (auto dest: finite_subset)
```
```   731     then have "(\<Sum>x | X x - Y x \<noteq> 0. (X x - Y x) *\<^sub>R x) = (\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. (X v - Y v) *\<^sub>R v)"
```
```   732       using X Y by (intro sum.mono_neutral_cong_left) auto
```
```   733     also have "\<dots> = (\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. X v *\<^sub>R v) - (\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. Y v *\<^sub>R v)"
```
```   734       by (simp add: scaleR_diff_left sum_subtractf assms)
```
```   735     also have "(\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. X v *\<^sub>R v) = (\<Sum>v\<in>{S. X S \<noteq> 0}. X v *\<^sub>R v)"
```
```   736       using X Y by (intro sum.mono_neutral_cong_right) auto
```
```   737     also have "(\<Sum>v\<in>{S. X S \<noteq> 0} \<union> {S. Y S \<noteq> 0}. Y v *\<^sub>R v) = (\<Sum>v\<in>{S. Y S \<noteq> 0}. Y v *\<^sub>R v)"
```
```   738       using X Y by (intro sum.mono_neutral_cong_right) auto
```
```   739     finally show "(\<Sum>x | X x - Y x \<noteq> 0. (X x - Y x) *\<^sub>R x) = 0"
```
```   740       using assms by simp
```
```   741   qed
```
```   742   then show ?thesis
```
```   743     by auto
```
```   744 qed
```
```   745
```
```   746 text \<open>This is useful for building a basis step-by-step.\<close>
```
```   747
```
```   748 lemma independent_insert:
```
```   749   "independent (insert a S) \<longleftrightarrow>
```
```   750     (if a \<in> S then independent S else independent S \<and> a \<notin> span S)"
```
```   751   (is "?lhs \<longleftrightarrow> ?rhs")
```
```   752 proof (cases "a \<in> S")
```
```   753   case True
```
```   754   then show ?thesis
```
```   755     using insert_absorb[OF True] by simp
```
```   756 next
```
```   757   case False
```
```   758   show ?thesis
```
```   759   proof
```
```   760     assume i: ?lhs
```
```   761     then show ?rhs
```
```   762       using False
```
```   763       using dependent_def independent_mono by fastforce
```
```   764   next
```
```   765     assume i: ?rhs
```
```   766     show ?lhs
```
```   767       using i False
```
```   768       apply (auto simp add: dependent_def)
```
```   769       by (metis in_span_insert insert_Diff_if insert_Diff_single insert_absorb)
```
```   770   qed
```
```   771 qed
```
```   772
```
```   773 lemma independent_Union_directed:
```
```   774   assumes directed: "\<And>c d. c \<in> C \<Longrightarrow> d \<in> C \<Longrightarrow> c \<subseteq> d \<or> d \<subseteq> c"
```
```   775   assumes indep: "\<And>c. c \<in> C \<Longrightarrow> independent c"
```
```   776   shows "independent (\<Union>C)"
```
```   777 proof
```
```   778   assume "dependent (\<Union>C)"
```
```   779   then obtain u v S where S: "finite S" "S \<subseteq> \<Union>C" "v \<in> S" "u v \<noteq> 0" "(\<Sum>v\<in>S. u v *\<^sub>R v) = 0"
```
```   780     by (auto simp: dependent_explicit)
```
```   781
```
```   782   have "S \<noteq> {}"
```
```   783     using \<open>v \<in> S\<close> by auto
```
```   784   have "\<exists>c\<in>C. S \<subseteq> c"
```
```   785     using \<open>finite S\<close> \<open>S \<noteq> {}\<close> \<open>S \<subseteq> \<Union>C\<close>
```
```   786   proof (induction rule: finite_ne_induct)
```
```   787     case (insert i I)
```
```   788     then obtain c d where cd: "c \<in> C" "d \<in> C" and iI: "I \<subseteq> c" "i \<in> d"
```
```   789       by blast
```
```   790     from directed[OF cd] cd have "c \<union> d \<in> C"
```
```   791       by (auto simp: sup.absorb1 sup.absorb2)
```
```   792     with iI show ?case
```
```   793       by (intro bexI[of _ "c \<union> d"]) auto
```
```   794   qed auto
```
```   795   then obtain c where "c \<in> C" "S \<subseteq> c"
```
```   796     by auto
```
```   797   have "dependent c"
```
```   798     unfolding dependent_explicit
```
```   799     by (intro exI[of _ S] exI[of _ u] bexI[of _ v] conjI) fact+
```
```   800   with indep[OF \<open>c \<in> C\<close>] show False
```
```   801     by auto
```
```   802 qed
```
```   803
```
```   804 text \<open>Hence we can create a maximal independent subset.\<close>
```
```   805
```
```   806 lemma maximal_independent_subset_extend:
```
```   807   assumes "S \<subseteq> V" "independent S"
```
```   808   obtains B where "S \<subseteq> B" "B \<subseteq> V" "independent B" "V \<subseteq> span B"
```
```   809 proof -
```
```   810   let ?C = "{B. S \<subseteq> B \<and> independent B \<and> B \<subseteq> V}"
```
```   811   have "\<exists>M\<in>?C. \<forall>X\<in>?C. M \<subseteq> X \<longrightarrow> X = M"
```
```   812   proof (rule subset_Zorn)
```
```   813     fix C :: "'a set set" assume "subset.chain ?C C"
```
```   814     then have C: "\<And>c. c \<in> C \<Longrightarrow> c \<subseteq> V" "\<And>c. c \<in> C \<Longrightarrow> S \<subseteq> c" "\<And>c. c \<in> C \<Longrightarrow> independent c"
```
```   815       "\<And>c d. c \<in> C \<Longrightarrow> d \<in> C \<Longrightarrow> c \<subseteq> d \<or> d \<subseteq> c"
```
```   816       unfolding subset.chain_def by blast+
```
```   817
```
```   818     show "\<exists>U\<in>?C. \<forall>X\<in>C. X \<subseteq> U"
```
```   819     proof cases
```
```   820       assume "C = {}" with assms show ?thesis
```
```   821         by (auto intro!: exI[of _ S])
```
```   822     next
```
```   823       assume "C \<noteq> {}"
```
```   824       with C(2) have "S \<subseteq> \<Union>C"
```
```   825         by auto
```
```   826       moreover have "independent (\<Union>C)"
```
```   827         by (intro independent_Union_directed C)
```
```   828       moreover have "\<Union>C \<subseteq> V"
```
```   829         using C by auto
```
```   830       ultimately show ?thesis
```
```   831         by auto
```
```   832     qed
```
```   833   qed
```
```   834   then obtain B where B: "independent B" "B \<subseteq> V" "S \<subseteq> B"
```
```   835     and max: "\<And>S. independent S \<Longrightarrow> S \<subseteq> V \<Longrightarrow> B \<subseteq> S \<Longrightarrow> S = B"
```
```   836     by auto
```
```   837   moreover
```
```   838   { assume "\<not> V \<subseteq> span B"
```
```   839     then obtain v where "v \<in> V" "v \<notin> span B"
```
```   840       by auto
```
```   841     with B have "independent (insert v B)"
```
```   842       unfolding independent_insert by auto
```
```   843     from max[OF this] \<open>v \<in> V\<close> \<open>B \<subseteq> V\<close>
```
```   844     have "v \<in> B"
```
```   845       by auto
```
```   846     with \<open>v \<notin> span B\<close> have False
```
```   847       by (auto intro: span_superset) }
```
```   848   ultimately show ?thesis
```
```   849     by (meson that)
```
```   850 qed
```
```   851
```
```   852
```
```   853 lemma maximal_independent_subset:
```
```   854   obtains B where "B \<subseteq> V" "independent B" "V \<subseteq> span B"
```
```   855   by (metis maximal_independent_subset_extend[of "{}"] empty_subsetI independent_empty)
```
```   856
```
```   857 lemma span_finite:
```
```   858   assumes fS: "finite S"
```
```   859   shows "span S = {y. \<exists>u. sum (\<lambda>v. u v *\<^sub>R v) S = y}"
```
```   860   (is "_ = ?rhs")
```
```   861 proof -
```
```   862   {
```
```   863     fix y
```
```   864     assume y: "y \<in> span S"
```
```   865     from y obtain S' u where fS': "finite S'"
```
```   866       and SS': "S' \<subseteq> S"
```
```   867       and u: "sum (\<lambda>v. u v *\<^sub>R v) S' = y"
```
```   868       unfolding span_explicit by blast
```
```   869     let ?u = "\<lambda>x. if x \<in> S' then u x else 0"
```
```   870     have "sum (\<lambda>v. ?u v *\<^sub>R v) S = sum (\<lambda>v. u v *\<^sub>R v) S'"
```
```   871       using SS' fS by (auto intro!: sum.mono_neutral_cong_right)
```
```   872     then have "sum (\<lambda>v. ?u v *\<^sub>R v) S = y" by (metis u)
```
```   873     then have "y \<in> ?rhs" by auto
```
```   874   }
```
```   875   moreover
```
```   876   {
```
```   877     fix y u
```
```   878     assume u: "sum (\<lambda>v. u v *\<^sub>R v) S = y"
```
```   879     then have "y \<in> span S" using fS unfolding span_explicit by auto
```
```   880   }
```
```   881   ultimately show ?thesis by blast
```
```   882 qed
```
```   883
```
```   884 lemma linear_independent_extend_subspace:
```
```   885   assumes "independent B"
```
```   886   shows "\<exists>g. linear g \<and> (\<forall>x\<in>B. g x = f x) \<and> range g = span (f`B)"
```
```   887 proof -
```
```   888   from maximal_independent_subset_extend[OF _ \<open>independent B\<close>, of UNIV]
```
```   889   obtain B' where "B \<subseteq> B'" "independent B'" "span B' = UNIV"
```
```   890     by (auto simp: top_unique)
```
```   891   have "\<forall>y. \<exists>X. {x. X x \<noteq> 0} \<subseteq> B' \<and> finite {x. X x \<noteq> 0} \<and> y = (\<Sum>x|X x \<noteq> 0. X x *\<^sub>R x)"
```
```   892     using \<open>span B' = UNIV\<close> unfolding span_alt by auto
```
```   893   then obtain X where X: "\<And>y. {x. X y x \<noteq> 0} \<subseteq> B'" "\<And>y. finite {x. X y x \<noteq> 0}"
```
```   894     "\<And>y. y = (\<Sum>x|X y x \<noteq> 0. X y x *\<^sub>R x)"
```
```   895     unfolding choice_iff by auto
```
```   896
```
```   897   have X_add: "X (x + y) = (\<lambda>z. X x z + X y z)" for x y
```
```   898     using \<open>independent B'\<close>
```
```   899   proof (rule independentD_unique)
```
```   900     have "(\<Sum>z | X x z + X y z \<noteq> 0. (X x z + X y z) *\<^sub>R z)
```
```   901       = (\<Sum>z\<in>{z. X x z \<noteq> 0} \<union> {z. X y z \<noteq> 0}. (X x z + X y z) *\<^sub>R z)"
```
```   902       by (intro sum.mono_neutral_cong_left) (auto intro: X)
```
```   903     also have "\<dots> = (\<Sum>z\<in>{z. X x z \<noteq> 0}. X x z *\<^sub>R z) + (\<Sum>z\<in>{z. X y z \<noteq> 0}. X y z *\<^sub>R z)"
```
```   904       by (auto simp add: scaleR_add_left sum.distrib
```
```   905                intro!: arg_cong2[where f="(+)"]  sum.mono_neutral_cong_right X)
```
```   906     also have "\<dots> = x + y"
```
```   907       by (simp add: X(3)[symmetric])
```
```   908     also have "\<dots> = (\<Sum>z | X (x + y) z \<noteq> 0. X (x + y) z *\<^sub>R z)"
```
```   909       by (rule X(3))
```
```   910     finally show "(\<Sum>z | X (x + y) z \<noteq> 0. X (x + y) z *\<^sub>R z) = (\<Sum>z | X x z + X y z \<noteq> 0. (X x z + X y z) *\<^sub>R z)"
```
```   911       ..
```
```   912     have "{z. X x z + X y z \<noteq> 0} \<subseteq> {z. X x z \<noteq> 0} \<union> {z. X y z \<noteq> 0}"
```
```   913       by auto
```
```   914     then show "finite {z. X x z + X y z \<noteq> 0}" "{xa. X x xa + X y xa \<noteq> 0} \<subseteq> B'"
```
```   915         "finite {xa. X (x + y) xa \<noteq> 0}" "{xa. X (x + y) xa \<noteq> 0} \<subseteq> B'"
```
```   916       using X(1) by (auto dest: finite_subset intro: X)
```
```   917   qed
```
```   918
```
```   919   have X_cmult: "X (c *\<^sub>R x) = (\<lambda>z. c * X x z)" for x c
```
```   920     using \<open>independent B'\<close>
```
```   921   proof (rule independentD_unique)
```
```   922     show "finite {z. X (c *\<^sub>R x) z \<noteq> 0}" "{z. X (c *\<^sub>R x) z \<noteq> 0} \<subseteq> B'"
```
```   923       "finite {z. c * X x z \<noteq> 0}" "{z. c * X x z \<noteq> 0} \<subseteq> B' "
```
```   924       using X(1,2) by auto
```
```   925     show "(\<Sum>z | X (c *\<^sub>R x) z \<noteq> 0. X (c *\<^sub>R x) z *\<^sub>R z) = (\<Sum>z | c * X x z \<noteq> 0. (c * X x z) *\<^sub>R z)"
```
```   926       unfolding scaleR_scaleR[symmetric] scaleR_sum_right[symmetric]
```
```   927       by (cases "c = 0") (auto simp: X(3)[symmetric])
```
```   928   qed
```
```   929
```
```   930   have X_B': "x \<in> B' \<Longrightarrow> X x = (\<lambda>z. if z = x then 1 else 0)" for x
```
```   931     using \<open>independent B'\<close>
```
```   932     by (rule independentD_unique[OF _ X(2) X(1)]) (auto intro: X simp: X(3)[symmetric])
```
```   933
```
```   934   define f' where "f' y = (if y \<in> B then f y else 0)" for y
```
```   935   define g where "g y = (\<Sum>x|X y x \<noteq> 0. X y x *\<^sub>R f' x)" for y
```
```   936
```
```   937   have g_f': "x \<in> B' \<Longrightarrow> g x = f' x" for x
```
```   938     by (auto simp: g_def X_B')
```
```   939
```
```   940   have "linear g"
```
```   941   proof
```
```   942     fix x y
```
```   943     have *: "(\<Sum>z | X x z + X y z \<noteq> 0. (X x z + X y z) *\<^sub>R f' z)
```
```   944       = (\<Sum>z\<in>{z. X x z \<noteq> 0} \<union> {z. X y z \<noteq> 0}. (X x z + X y z) *\<^sub>R f' z)"
```
```   945       by (intro sum.mono_neutral_cong_left) (auto intro: X)
```
```   946     show "g (x + y) = g x + g y"
```
```   947       unfolding g_def X_add *
```
```   948       by (auto simp add: scaleR_add_left sum.distrib
```
```   949                intro!: arg_cong2[where f="(+)"]  sum.mono_neutral_cong_right X)
```
```   950   next
```
```   951     show "g (r *\<^sub>R x) = r *\<^sub>R g x" for r x
```
```   952       by (auto simp add: g_def X_cmult scaleR_sum_right intro!: sum.mono_neutral_cong_left X)
```
```   953   qed
```
```   954   moreover have "\<forall>x\<in>B. g x = f x"
```
```   955     using \<open>B \<subseteq> B'\<close> by (auto simp: g_f' f'_def)
```
```   956   moreover have "range g = span (f`B)"
```
```   957     unfolding \<open>span B' = UNIV\<close>[symmetric] span_linear_image[OF \<open>linear g\<close>, symmetric]
```
```   958   proof (rule span_subspace)
```
```   959     have "g ` B' \<subseteq> f`B \<union> {0}"
```
```   960       by (auto simp: g_f' f'_def)
```
```   961     also have "\<dots> \<subseteq> span (f`B)"
```
```   962       by (auto intro: span_superset span_0)
```
```   963     finally show "g ` B' \<subseteq> span (f`B)"
```
```   964       by auto
```
```   965     have "x \<in> B \<Longrightarrow> f x = g x" for x
```
```   966       using \<open>B \<subseteq> B'\<close> by (auto simp add: g_f' f'_def)
```
```   967     then show "span (f ` B) \<subseteq> span (g ` B')"
```
```   968       using \<open>B \<subseteq> B'\<close> by (intro span_mono) auto
```
```   969   qed (rule subspace_span)
```
```   970   ultimately show ?thesis
```
```   971     by auto
```
```   972 qed
```
```   973
```
```   974 lemma linear_independent_extend:
```
```   975   "independent B \<Longrightarrow> \<exists>g. linear g \<and> (\<forall>x\<in>B. g x = f x)"
```
```   976   using linear_independent_extend_subspace[of B f] by auto
```
```   977
```
```   978 text \<open>Linear functions are equal on a subspace if they are on a spanning set.\<close>
```
```   979
```
```   980 lemma subspace_kernel:
```
```   981   assumes lf: "linear f"
```
```   982   shows "subspace {x. f x = 0}"
```
```   983   unfolding subspace_def
```
```   984   by (simp add: linear_add[OF lf] linear_cmul[OF lf] linear_0[OF lf])
```
```   985
```
```   986 lemma linear_eq_0_span:
```
```   987   assumes x: "x \<in> span B" and lf: "linear f" and f0: "\<And>x. x\<in>B \<Longrightarrow> f x = 0"
```
```   988   shows "f x = 0"
```
```   989   using x f0 subspace_kernel[OF lf] span_induct
```
```   990   by blast
```
```   991
```
```   992 lemma linear_eq_0: "\<lbrakk>x \<in> S; linear f; S \<subseteq> span B; \<And>x. x\<in>B \<Longrightarrow> f x = 0\<rbrakk> \<Longrightarrow> f x = 0"
```
```   993   using linear_eq_0_span[of x B f] by auto
```
```   994
```
```   995 lemma linear_eq_span: "\<lbrakk>x \<in> span B; linear f; linear g; \<And>x. x\<in>B \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> f x = g x"
```
```   996   using linear_eq_0_span[of x B "\<lambda>x. f x - g x"]  by (auto simp: linear_compose_sub)
```
```   997
```
```   998 lemma linear_eq: "\<lbrakk>x \<in> S; linear f; linear g; S \<subseteq> span B; \<And>x. x\<in>B \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> f x = g x"
```
```   999   using linear_eq_span[of _ B f g] by auto
```
```  1000
```
```  1001 text \<open>The degenerate case of the Exchange Lemma.\<close>
```
```  1002
```
```  1003 lemma spanning_subset_independent:
```
```  1004   assumes BA: "B \<subseteq> A"
```
```  1005     and iA: "independent A"
```
```  1006     and AsB: "A \<subseteq> span B"
```
```  1007   shows "A = B"
```
```  1008 proof
```
```  1009   show "B \<subseteq> A" by (rule BA)
```
```  1010
```
```  1011   from span_mono[OF BA] span_mono[OF AsB]
```
```  1012   have sAB: "span A = span B" unfolding span_span by blast
```
```  1013
```
```  1014   show "A \<subseteq> B"
```
```  1015   proof
```
```  1016     fix x
```
```  1017     assume x: "x \<in> A"
```
```  1018     from iA have th0: "x \<notin> span (A - {x})"
```
```  1019       unfolding dependent_def using x by blast
```
```  1020     from x have xsA: "x \<in> span A"
```
```  1021       by (blast intro: span_superset)
```
```  1022     have "A - {x} \<subseteq> A" by blast
```
```  1023     then have th1: "span (A - {x}) \<subseteq> span A"
```
```  1024       by (metis span_mono)
```
```  1025     show "x \<in> B"
```
```  1026     proof (rule ccontr)
```
```  1027       assume xB: "x \<notin> B"
```
```  1028       from xB BA have "B \<subseteq> A - {x}"
```
```  1029         by blast
```
```  1030       then have "span B \<subseteq> span (A - {x})"
```
```  1031         by (metis span_mono)
```
```  1032       with th1 th0 sAB have "x \<notin> span A"
```
```  1033         by blast
```
```  1034       with x show False
```
```  1035         by (metis span_superset)
```
```  1036     qed
```
```  1037   qed
```
```  1038 qed
```
```  1039
```
```  1040 text \<open>Relation between bases and injectivity/surjectivity of map.\<close>
```
```  1041
```
```  1042 lemma spanning_surjective_image:
```
```  1043   assumes us: "UNIV \<subseteq> span S"
```
```  1044     and lf: "linear f"
```
```  1045     and sf: "surj f"
```
```  1046   shows "UNIV \<subseteq> span (f ` S)"
```
```  1047 proof -
```
```  1048   have "UNIV \<subseteq> f ` UNIV"
```
```  1049     using sf by (auto simp add: surj_def)
```
```  1050   also have " \<dots> \<subseteq> span (f ` S)"
```
```  1051     using spans_image[OF lf us] .
```
```  1052   finally show ?thesis .
```
```  1053 qed
```
```  1054
```
```  1055 lemma independent_inj_on_image:
```
```  1056   assumes iS: "independent S"
```
```  1057     and lf: "linear f"
```
```  1058     and fi: "inj_on f (span S)"
```
```  1059   shows "independent (f ` S)"
```
```  1060   unfolding dependent_def
```
```  1061 proof clarsimp
```
```  1062   fix a
```
```  1063   assume a: "a \<in> S" "f a \<in> span (f ` S - {f a})"
```
```  1064   have eq: "f ` S - {f a} = f ` (S - {a})"
```
```  1065     using fi \<open>a\<in>S\<close> by (auto simp add: inj_on_def span_superset)
```
```  1066   from a have "f a \<in> f ` span (S - {a})"
```
```  1067     unfolding eq span_linear_image[OF lf, of "S - {a}"] by blast
```
```  1068   then have "a \<in> span (S - {a})"
```
```  1069     by (rule inj_on_image_mem_iff_alt[OF fi, rotated])
```
```  1070       (insert span_mono[of "S - {a}" S], auto intro: span_superset \<open>a\<in>S\<close>)
```
```  1071   with a(1) iS have False
```
```  1072     by (simp add: dependent_def)
```
```  1073   then show False
```
```  1074     unfolding dependent_def by blast
```
```  1075 qed
```
```  1076
```
```  1077 lemma independent_injective_image:
```
```  1078   "independent S \<Longrightarrow> linear f \<Longrightarrow> inj f \<Longrightarrow> independent (f ` S)"
```
```  1079   using independent_inj_on_image[of S f] by (auto simp: subset_inj_on)
```
```  1080
```
```  1081 text \<open>Detailed theorems about left and right invertibility in general case.\<close>
```
```  1082
```
```  1083 lemma linear_inj_on_left_inverse:
```
```  1084   assumes lf: "linear f" and fi: "inj_on f (span S)"
```
```  1085   shows "\<exists>g. range g \<subseteq> span S \<and> linear g \<and> (\<forall>x\<in>span S. g (f x) = x)"
```
```  1086 proof -
```
```  1087   obtain B where "independent B" "B \<subseteq> S" "S \<subseteq> span B"
```
```  1088     using maximal_independent_subset[of S] .
```
```  1089   then have "span S = span B"
```
```  1090     unfolding span_eq by (auto simp: span_superset)
```
```  1091   with linear_independent_extend_subspace[OF independent_inj_on_image, OF \<open>independent B\<close> lf] fi
```
```  1092   obtain g where g: "linear g" "\<forall>x\<in>f ` B. g x = inv_into B f x" "range g = span (inv_into B f ` f ` B)"
```
```  1093     by fastforce
```
```  1094   have fB: "inj_on f B"
```
```  1095     using fi by (auto simp: \<open>span S = span B\<close> intro: subset_inj_on span_superset)
```
```  1096
```
```  1097   have "g (f x) = x" if "x \<in> span B" for x
```
```  1098   proof (rule linear_eq_span)
```
```  1099     show "linear (\<lambda>x. x)" "linear (\<lambda>x. g (f x))"
```
```  1100       using linear_id linear_compose[OF \<open>linear f\<close> \<open>linear g\<close>] by (auto simp: id_def comp_def)
```
```  1101     show "g (f x) = x" if "x \<in> B" for x
```
```  1102       using g fi \<open>span S = span B\<close>   by (simp add: fB that)
```
```  1103   qed (rule that)
```
```  1104   moreover
```
```  1105   have "inv_into B f ` f ` B \<subseteq> B"
```
```  1106     by (auto simp: fB)
```
```  1107   then have "range g \<subseteq> span S"
```
```  1108     unfolding g \<open>span S = span B\<close> by (intro span_mono)
```
```  1109   ultimately show ?thesis
```
```  1110     using \<open>span S = span B\<close> \<open>linear g\<close> by auto
```
```  1111 qed
```
```  1112
```
```  1113 lemma linear_injective_left_inverse: "linear f \<Longrightarrow> inj f \<Longrightarrow> \<exists>g. linear g \<and> g \<circ> f = id"
```
```  1114   using linear_inj_on_left_inverse[of f UNIV] by (auto simp: fun_eq_iff)
```
```  1115
```
```  1116 lemma linear_surj_right_inverse:
```
```  1117   assumes lf: "linear f" and sf: "span T \<subseteq> f`span S"
```
```  1118   shows "\<exists>g. range g \<subseteq> span S \<and> linear g \<and> (\<forall>x\<in>span T. f (g x) = x)"
```
```  1119 proof -
```
```  1120   obtain B where "independent B" "B \<subseteq> T" "T \<subseteq> span B"
```
```  1121     using maximal_independent_subset[of T] .
```
```  1122   then have "span T = span B"
```
```  1123     unfolding span_eq by (auto simp: span_superset)
```
```  1124
```
```  1125   from linear_independent_extend_subspace[OF \<open>independent B\<close>, of "inv_into (span S) f"]
```
```  1126   obtain g where g: "linear g" "\<forall>x\<in>B. g x = inv_into (span S) f x" "range g = span (inv_into (span S) f`B)"
```
```  1127     by auto
```
```  1128   moreover have "x \<in> B \<Longrightarrow> f (inv_into (span S) f x) = x" for x
```
```  1129     using \<open>B \<subseteq> T\<close> \<open>span T \<subseteq> f`span S\<close> by (intro f_inv_into_f) (auto intro: span_superset)
```
```  1130   ultimately have "\<forall>x\<in>B. f (g x) = x"
```
```  1131     by auto
```
```  1132   then have "\<forall>x\<in>span B. f (g x) = x"
```
```  1133     using linear_id linear_compose[OF \<open>linear g\<close> \<open>linear f\<close>] linear_eq_span by fastforce
```
```  1134   moreover have "inv_into (span S) f ` B \<subseteq> span S"
```
```  1135     using \<open>B \<subseteq> T\<close> \<open>span T \<subseteq> f`span S\<close> by (auto intro: inv_into_into span_superset)
```
```  1136   then have "range g \<subseteq> span S"
```
```  1137     unfolding g by (intro span_minimal subspace_span) auto
```
```  1138   ultimately show ?thesis
```
```  1139     using \<open>linear g\<close> \<open>span T = span B\<close> by auto
```
```  1140 qed
```
```  1141
```
```  1142 lemma linear_surjective_right_inverse: "linear f \<Longrightarrow> surj f \<Longrightarrow> \<exists>g. linear g \<and> f \<circ> g = id"
```
```  1143   using linear_surj_right_inverse[of f UNIV UNIV]
```
```  1144   by (auto simp: fun_eq_iff)
```
```  1145
```
```  1146 text \<open>The general case of the Exchange Lemma, the key to what follows.\<close>
```
```  1147
```
```  1148 lemma exchange_lemma:
```
```  1149   assumes f: "finite T"
```
```  1150     and i: "independent S"
```
```  1151     and sp: "S \<subseteq> span T"
```
```  1152   shows "\<exists>t'. card t' = card T \<and> finite t' \<and> S \<subseteq> t' \<and> t' \<subseteq> S \<union> T \<and> S \<subseteq> span t'"
```
```  1153   using f i sp
```
```  1154 proof (induct "card (T - S)" arbitrary: S T rule: less_induct)
```
```  1155   case less
```
```  1156   note ft = \<open>finite T\<close> and S = \<open>independent S\<close> and sp = \<open>S \<subseteq> span T\<close>
```
```  1157   let ?P = "\<lambda>t'. card t' = card T \<and> finite t' \<and> S \<subseteq> t' \<and> t' \<subseteq> S \<union> T \<and> S \<subseteq> span t'"
```
```  1158   show ?case
```
```  1159   proof (cases "S \<subseteq> T \<or> T \<subseteq> S")
```
```  1160     case True
```
```  1161     then show ?thesis
```
```  1162     proof
```
```  1163       assume "S \<subseteq> T" then show ?thesis
```
```  1164         by (metis ft Un_commute sp sup_ge1)
```
```  1165     next
```
```  1166       assume "T \<subseteq> S" then show ?thesis
```
```  1167         by (metis Un_absorb sp spanning_subset_independent[OF _ S sp] ft)
```
```  1168     qed
```
```  1169   next
```
```  1170     case False
```
```  1171     then have st: "\<not> S \<subseteq> T" "\<not> T \<subseteq> S"
```
```  1172       by auto
```
```  1173     from st(2) obtain b where b: "b \<in> T" "b \<notin> S"
```
```  1174       by blast
```
```  1175     from b have "T - {b} - S \<subset> T - S"
```
```  1176       by blast
```
```  1177     then have cardlt: "card (T - {b} - S) < card (T - S)"
```
```  1178       using ft by (auto intro: psubset_card_mono)
```
```  1179     from b ft have ct0: "card T \<noteq> 0"
```
```  1180       by auto
```
```  1181     show ?thesis
```
```  1182     proof (cases "S \<subseteq> span (T - {b})")
```
```  1183       case True
```
```  1184       from ft have ftb: "finite (T - {b})"
```
```  1185         by auto
```
```  1186       from less(1)[OF cardlt ftb S True]
```
```  1187       obtain U where U: "card U = card (T - {b})" "S \<subseteq> U" "U \<subseteq> S \<union> (T - {b})" "S \<subseteq> span U"
```
```  1188         and fu: "finite U" by blast
```
```  1189       let ?w = "insert b U"
```
```  1190       have th0: "S \<subseteq> insert b U"
```
```  1191         using U by blast
```
```  1192       have th1: "insert b U \<subseteq> S \<union> T"
```
```  1193         using U b by blast
```
```  1194       have bu: "b \<notin> U"
```
```  1195         using b U by blast
```
```  1196       from U(1) ft b have "card U = (card T - 1)"
```
```  1197         by auto
```
```  1198       then have th2: "card (insert b U) = card T"
```
```  1199         using card_insert_disjoint[OF fu bu] ct0 by auto
```
```  1200       from U(4) have "S \<subseteq> span U" .
```
```  1201       also have "\<dots> \<subseteq> span (insert b U)"
```
```  1202         by (rule span_mono) blast
```
```  1203       finally have th3: "S \<subseteq> span (insert b U)" .
```
```  1204       from th0 th1 th2 th3 fu have th: "?P ?w"
```
```  1205         by blast
```
```  1206       from th show ?thesis by blast
```
```  1207     next
```
```  1208       case False
```
```  1209       then obtain a where a: "a \<in> S" "a \<notin> span (T - {b})"
```
```  1210         by blast
```
```  1211       have ab: "a \<noteq> b"
```
```  1212         using a b by blast
```
```  1213       have at: "a \<notin> T"
```
```  1214         using a ab span_superset[of a "T- {b}"] by auto
```
```  1215       have mlt: "card ((insert a (T - {b})) - S) < card (T - S)"
```
```  1216         using cardlt ft a b by auto
```
```  1217       have ft': "finite (insert a (T - {b}))"
```
```  1218         using ft by auto
```
```  1219       have sp': "S \<subseteq> span (insert a (T - {b}))"
```
```  1220       proof
```
```  1221         fix x
```
```  1222         assume xs: "x \<in> S"
```
```  1223         have T: "T \<subseteq> insert b (insert a (T - {b}))"
```
```  1224           using b by auto
```
```  1225         have bs: "b \<in> span (insert a (T - {b}))"
```
```  1226           by (rule in_span_delete) (use a sp in auto)
```
```  1227         from xs sp have "x \<in> span T"
```
```  1228           by blast
```
```  1229         with span_mono[OF T] have x: "x \<in> span (insert b (insert a (T - {b})))" ..
```
```  1230         from span_trans[OF bs x] show "x \<in> span (insert a (T - {b}))" .
```
```  1231       qed
```
```  1232       from less(1)[OF mlt ft' S sp'] obtain U where U:
```
```  1233         "card U = card (insert a (T - {b}))"
```
```  1234         "finite U" "S \<subseteq> U" "U \<subseteq> S \<union> insert a (T - {b})"
```
```  1235         "S \<subseteq> span U" by blast
```
```  1236       from U a b ft at ct0 have "?P U"
```
```  1237         by auto
```
```  1238       then show ?thesis by blast
```
```  1239     qed
```
```  1240   qed
```
```  1241 qed
```
```  1242
```
```  1243 text \<open>This implies corresponding size bounds.\<close>
```
```  1244
```
```  1245 lemma independent_span_bound:
```
```  1246   assumes f: "finite T"
```
```  1247     and i: "independent S"
```
```  1248     and sp: "S \<subseteq> span T"
```
```  1249   shows "finite S \<and> card S \<le> card T"
```
```  1250   by (metis exchange_lemma[OF f i sp] finite_subset card_mono)
```
```  1251
```
```  1252 lemma finite_Atleast_Atmost_nat[simp]: "finite {f x |x. x \<in> (UNIV::'a::finite set)}"
```
```  1253   using finite finite_image_set by blast
```
```  1254
```
```  1255
```
```  1256 subsection%unimportant \<open>More interesting properties of the norm.\<close>
```
```  1257
```
```  1258 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
```
```  1259   by auto
```
```  1260
```
```  1261 notation inner (infix "\<bullet>" 70)
```
```  1262
```
```  1263 lemma square_bound_lemma:
```
```  1264   fixes x :: real
```
```  1265   shows "x < (1 + x) * (1 + x)"
```
```  1266 proof -
```
```  1267   have "(x + 1/2)\<^sup>2 + 3/4 > 0"
```
```  1268     using zero_le_power2[of "x+1/2"] by arith
```
```  1269   then show ?thesis
```
```  1270     by (simp add: field_simps power2_eq_square)
```
```  1271 qed
```
```  1272
```
```  1273 lemma square_continuous:
```
```  1274   fixes e :: real
```
```  1275   shows "e > 0 \<Longrightarrow> \<exists>d. 0 < d \<and> (\<forall>y. \<bar>y - x\<bar> < d \<longrightarrow> \<bar>y * y - x * x\<bar> < e)"
```
```  1276   using isCont_power[OF continuous_ident, of x, unfolded isCont_def LIM_eq, rule_format, of e 2]
```
```  1277   by (force simp add: power2_eq_square)
```
```  1278
```
```  1279 lemma norm_triangle_sub:
```
```  1280   fixes x y :: "'a::real_normed_vector"
```
```  1281   shows "norm x \<le> norm y + norm (x - y)"
```
```  1282   using norm_triangle_ineq[of "y" "x - y"] by (simp add: field_simps)
```
```  1283
```
```  1284 lemma norm_le: "norm x \<le> norm y \<longleftrightarrow> x \<bullet> x \<le> y \<bullet> y"
```
```  1285   by (simp add: norm_eq_sqrt_inner)
```
```  1286
```
```  1287 lemma norm_lt: "norm x < norm y \<longleftrightarrow> x \<bullet> x < y \<bullet> y"
```
```  1288   by (simp add: norm_eq_sqrt_inner)
```
```  1289
```
```  1290 lemma norm_eq: "norm x = norm y \<longleftrightarrow> x \<bullet> x = y \<bullet> y"
```
```  1291   apply (subst order_eq_iff)
```
```  1292   apply (auto simp: norm_le)
```
```  1293   done
```
```  1294
```
```  1295 lemma norm_eq_1: "norm x = 1 \<longleftrightarrow> x \<bullet> x = 1"
```
```  1296   by (simp add: norm_eq_sqrt_inner)
```
```  1297
```
```  1298
```
```  1299 text\<open>Equality of vectors in terms of @{term "(\<bullet>)"} products.\<close>
```
```  1300
```
```  1301 lemma linear_componentwise:
```
```  1302   fixes f:: "'a::euclidean_space \<Rightarrow> 'b::real_inner"
```
```  1303   assumes lf: "linear f"
```
```  1304   shows "(f x) \<bullet> j = (\<Sum>i\<in>Basis. (x\<bullet>i) * (f i\<bullet>j))" (is "?lhs = ?rhs")
```
```  1305 proof -
```
```  1306   have "?rhs = (\<Sum>i\<in>Basis. (x\<bullet>i) *\<^sub>R (f i))\<bullet>j"
```
```  1307     by (simp add: inner_sum_left)
```
```  1308   then show ?thesis
```
```  1309     unfolding linear_sum_mul[OF lf, symmetric]
```
```  1310     unfolding euclidean_representation ..
```
```  1311 qed
```
```  1312
```
```  1313 lemma vector_eq: "x = y \<longleftrightarrow> x \<bullet> x = x \<bullet> y \<and> y \<bullet> y = x \<bullet> x"
```
```  1314   (is "?lhs \<longleftrightarrow> ?rhs")
```
```  1315 proof
```
```  1316   assume ?lhs
```
```  1317   then show ?rhs by simp
```
```  1318 next
```
```  1319   assume ?rhs
```
```  1320   then have "x \<bullet> x - x \<bullet> y = 0 \<and> x \<bullet> y - y \<bullet> y = 0"
```
```  1321     by simp
```
```  1322   then have "x \<bullet> (x - y) = 0 \<and> y \<bullet> (x - y) = 0"
```
```  1323     by (simp add: inner_diff inner_commute)
```
```  1324   then have "(x - y) \<bullet> (x - y) = 0"
```
```  1325     by (simp add: field_simps inner_diff inner_commute)
```
```  1326   then show "x = y" by simp
```
```  1327 qed
```
```  1328
```
```  1329 lemma norm_triangle_half_r:
```
```  1330   "norm (y - x1) < e / 2 \<Longrightarrow> norm (y - x2) < e / 2 \<Longrightarrow> norm (x1 - x2) < e"
```
```  1331   using dist_triangle_half_r unfolding dist_norm[symmetric] by auto
```
```  1332
```
```  1333 lemma norm_triangle_half_l:
```
```  1334   assumes "norm (x - y) < e / 2"
```
```  1335     and "norm (x' - y) < e / 2"
```
```  1336   shows "norm (x - x') < e"
```
```  1337   using dist_triangle_half_l[OF assms[unfolded dist_norm[symmetric]]]
```
```  1338   unfolding dist_norm[symmetric] .
```
```  1339
```
```  1340 lemma norm_triangle_le: "norm x + norm y \<le> e \<Longrightarrow> norm (x + y) \<le> e"
```
```  1341   by (rule norm_triangle_ineq [THEN order_trans])
```
```  1342
```
```  1343 lemma norm_triangle_lt: "norm x + norm y < e \<Longrightarrow> norm (x + y) < e"
```
```  1344   by (rule norm_triangle_ineq [THEN le_less_trans])
```
```  1345
```
```  1346 lemma abs_triangle_half_r:
```
```  1347   fixes y :: "'a::linordered_field"
```
```  1348   shows "abs (y - x1) < e / 2 \<Longrightarrow> abs (y - x2) < e / 2 \<Longrightarrow> abs (x1 - x2) < e"
```
```  1349   by linarith
```
```  1350
```
```  1351 lemma abs_triangle_half_l:
```
```  1352   fixes y :: "'a::linordered_field"
```
```  1353   assumes "abs (x - y) < e / 2"
```
```  1354     and "abs (x' - y) < e / 2"
```
```  1355   shows "abs (x - x') < e"
```
```  1356   using assms by linarith
```
```  1357
```
```  1358 lemma sum_clauses:
```
```  1359   shows "sum f {} = 0"
```
```  1360     and "finite S \<Longrightarrow> sum f (insert x S) = (if x \<in> S then sum f S else f x + sum f S)"
```
```  1361   by (auto simp add: insert_absorb)
```
```  1362
```
```  1363 lemma sum_norm_bound:
```
```  1364   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
```
```  1365   assumes K: "\<And>x. x \<in> S \<Longrightarrow> norm (f x) \<le> K"
```
```  1366   shows "norm (sum f S) \<le> of_nat (card S)*K"
```
```  1367   using sum_norm_le[OF K] sum_constant[symmetric]
```
```  1368   by simp
```
```  1369
```
```  1370 lemma sum_group:
```
```  1371   assumes fS: "finite S" and fT: "finite T" and fST: "f ` S \<subseteq> T"
```
```  1372   shows "sum (\<lambda>y. sum g {x. x \<in> S \<and> f x = y}) T = sum g S"
```
```  1373   unfolding sum_image_gen[OF fS, of g f]
```
```  1374   by (auto intro: sum.neutral sum.mono_neutral_right[OF fT fST])
```
```  1375
```
```  1376 lemma vector_eq_ldot: "(\<forall>x. x \<bullet> y = x \<bullet> z) \<longleftrightarrow> y = z"
```
```  1377 proof
```
```  1378   assume "\<forall>x. x \<bullet> y = x \<bullet> z"
```
```  1379   then have "\<forall>x. x \<bullet> (y - z) = 0"
```
```  1380     by (simp add: inner_diff)
```
```  1381   then have "(y - z) \<bullet> (y - z) = 0" ..
```
```  1382   then show "y = z" by simp
```
```  1383 qed simp
```
```  1384
```
```  1385 lemma vector_eq_rdot: "(\<forall>z. x \<bullet> z = y \<bullet> z) \<longleftrightarrow> x = y"
```
```  1386 proof
```
```  1387   assume "\<forall>z. x \<bullet> z = y \<bullet> z"
```
```  1388   then have "\<forall>z. (x - y) \<bullet> z = 0"
```
```  1389     by (simp add: inner_diff)
```
```  1390   then have "(x - y) \<bullet> (x - y) = 0" ..
```
```  1391   then show "x = y" by simp
```
```  1392 qed simp
```
```  1393
```
```  1394
```
```  1395 subsection \<open>Orthogonality.\<close>
```
```  1396
```
```  1397 definition%important (in real_inner) "orthogonal x y \<longleftrightarrow> x \<bullet> y = 0"
```
```  1398
```
```  1399 context real_inner
```
```  1400 begin
```
```  1401
```
```  1402 lemma orthogonal_self: "orthogonal x x \<longleftrightarrow> x = 0"
```
```  1403   by (simp add: orthogonal_def)
```
```  1404
```
```  1405 lemma orthogonal_clauses:
```
```  1406   "orthogonal a 0"
```
```  1407   "orthogonal a x \<Longrightarrow> orthogonal a (c *\<^sub>R x)"
```
```  1408   "orthogonal a x \<Longrightarrow> orthogonal a (- x)"
```
```  1409   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x + y)"
```
```  1410   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x - y)"
```
```  1411   "orthogonal 0 a"
```
```  1412   "orthogonal x a \<Longrightarrow> orthogonal (c *\<^sub>R x) a"
```
```  1413   "orthogonal x a \<Longrightarrow> orthogonal (- x) a"
```
```  1414   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x + y) a"
```
```  1415   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x - y) a"
```
```  1416   unfolding orthogonal_def inner_add inner_diff by auto
```
```  1417
```
```  1418 end
```
```  1419
```
```  1420 lemma orthogonal_commute: "orthogonal x y \<longleftrightarrow> orthogonal y x"
```
```  1421   by (simp add: orthogonal_def inner_commute)
```
```  1422
```
```  1423 lemma orthogonal_scaleR [simp]: "c \<noteq> 0 \<Longrightarrow> orthogonal (c *\<^sub>R x) = orthogonal x"
```
```  1424   by (rule ext) (simp add: orthogonal_def)
```
```  1425
```
```  1426 lemma pairwise_ortho_scaleR:
```
```  1427     "pairwise (\<lambda>i j. orthogonal (f i) (g j)) B
```
```  1428     \<Longrightarrow> pairwise (\<lambda>i j. orthogonal (a i *\<^sub>R f i) (a j *\<^sub>R g j)) B"
```
```  1429   by (auto simp: pairwise_def orthogonal_clauses)
```
```  1430
```
```  1431 lemma orthogonal_rvsum:
```
```  1432     "\<lbrakk>finite s; \<And>y. y \<in> s \<Longrightarrow> orthogonal x (f y)\<rbrakk> \<Longrightarrow> orthogonal x (sum f s)"
```
```  1433   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
```
```  1434
```
```  1435 lemma orthogonal_lvsum:
```
```  1436     "\<lbrakk>finite s; \<And>x. x \<in> s \<Longrightarrow> orthogonal (f x) y\<rbrakk> \<Longrightarrow> orthogonal (sum f s) y"
```
```  1437   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
```
```  1438
```
```  1439 lemma norm_add_Pythagorean:
```
```  1440   assumes "orthogonal a b"
```
```  1441     shows "norm(a + b) ^ 2 = norm a ^ 2 + norm b ^ 2"
```
```  1442 proof -
```
```  1443   from assms have "(a - (0 - b)) \<bullet> (a - (0 - b)) = a \<bullet> a - (0 - b \<bullet> b)"
```
```  1444     by (simp add: algebra_simps orthogonal_def inner_commute)
```
```  1445   then show ?thesis
```
```  1446     by (simp add: power2_norm_eq_inner)
```
```  1447 qed
```
```  1448
```
```  1449 lemma norm_sum_Pythagorean:
```
```  1450   assumes "finite I" "pairwise (\<lambda>i j. orthogonal (f i) (f j)) I"
```
```  1451     shows "(norm (sum f I))\<^sup>2 = (\<Sum>i\<in>I. (norm (f i))\<^sup>2)"
```
```  1452 using assms
```
```  1453 proof (induction I rule: finite_induct)
```
```  1454   case empty then show ?case by simp
```
```  1455 next
```
```  1456   case (insert x I)
```
```  1457   then have "orthogonal (f x) (sum f I)"
```
```  1458     by (metis pairwise_insert orthogonal_rvsum)
```
```  1459   with insert show ?case
```
```  1460     by (simp add: pairwise_insert norm_add_Pythagorean)
```
```  1461 qed
```
```  1462
```
```  1463
```
```  1464 subsection \<open>Bilinear functions.\<close>
```
```  1465
```
```  1466 definition%important "bilinear f \<longleftrightarrow> (\<forall>x. linear (\<lambda>y. f x y)) \<and> (\<forall>y. linear (\<lambda>x. f x y))"
```
```  1467
```
```  1468 lemma bilinear_ladd: "bilinear h \<Longrightarrow> h (x + y) z = h x z + h y z"
```
```  1469   by (simp add: bilinear_def linear_iff)
```
```  1470
```
```  1471 lemma bilinear_radd: "bilinear h \<Longrightarrow> h x (y + z) = h x y + h x z"
```
```  1472   by (simp add: bilinear_def linear_iff)
```
```  1473
```
```  1474 lemma bilinear_lmul: "bilinear h \<Longrightarrow> h (c *\<^sub>R x) y = c *\<^sub>R h x y"
```
```  1475   by (simp add: bilinear_def linear_iff)
```
```  1476
```
```  1477 lemma bilinear_rmul: "bilinear h \<Longrightarrow> h x (c *\<^sub>R y) = c *\<^sub>R h x y"
```
```  1478   by (simp add: bilinear_def linear_iff)
```
```  1479
```
```  1480 lemma bilinear_lneg: "bilinear h \<Longrightarrow> h (- x) y = - h x y"
```
```  1481   by (drule bilinear_lmul [of _ "- 1"]) simp
```
```  1482
```
```  1483 lemma bilinear_rneg: "bilinear h \<Longrightarrow> h x (- y) = - h x y"
```
```  1484   by (drule bilinear_rmul [of _ _ "- 1"]) simp
```
```  1485
```
```  1486 lemma (in ab_group_add) eq_add_iff: "x = x + y \<longleftrightarrow> y = 0"
```
```  1487   using add_left_imp_eq[of x y 0] by auto
```
```  1488
```
```  1489 lemma bilinear_lzero:
```
```  1490   assumes "bilinear h"
```
```  1491   shows "h 0 x = 0"
```
```  1492   using bilinear_ladd [OF assms, of 0 0 x] by (simp add: eq_add_iff field_simps)
```
```  1493
```
```  1494 lemma bilinear_rzero:
```
```  1495   assumes "bilinear h"
```
```  1496   shows "h x 0 = 0"
```
```  1497   using bilinear_radd [OF assms, of x 0 0 ] by (simp add: eq_add_iff field_simps)
```
```  1498
```
```  1499 lemma bilinear_lsub: "bilinear h \<Longrightarrow> h (x - y) z = h x z - h y z"
```
```  1500   using bilinear_ladd [of h x "- y"] by (simp add: bilinear_lneg)
```
```  1501
```
```  1502 lemma bilinear_rsub: "bilinear h \<Longrightarrow> h z (x - y) = h z x - h z y"
```
```  1503   using bilinear_radd [of h _ x "- y"] by (simp add: bilinear_rneg)
```
```  1504
```
```  1505 lemma bilinear_sum:
```
```  1506   assumes bh: "bilinear h"
```
```  1507     and fS: "finite S"
```
```  1508     and fT: "finite T"
```
```  1509   shows "h (sum f S) (sum g T) = sum (\<lambda>(i,j). h (f i) (g j)) (S \<times> T) "
```
```  1510 proof -
```
```  1511   have "h (sum f S) (sum g T) = sum (\<lambda>x. h (f x) (sum g T)) S"
```
```  1512     apply (rule linear_sum[unfolded o_def])
```
```  1513     using bh fS
```
```  1514     apply (auto simp add: bilinear_def)
```
```  1515     done
```
```  1516   also have "\<dots> = sum (\<lambda>x. sum (\<lambda>y. h (f x) (g y)) T) S"
```
```  1517     apply (rule sum.cong, simp)
```
```  1518     apply (rule linear_sum[unfolded o_def])
```
```  1519     using bh fT
```
```  1520     apply (auto simp add: bilinear_def)
```
```  1521     done
```
```  1522   finally show ?thesis
```
```  1523     unfolding sum.cartesian_product .
```
```  1524 qed
```
```  1525
```
```  1526
```
```  1527 subsection \<open>Adjoints.\<close>
```
```  1528
```
```  1529 definition%important "adjoint f = (SOME f'. \<forall>x y. f x \<bullet> y = x \<bullet> f' y)"
```
```  1530
```
```  1531 lemma adjoint_unique:
```
```  1532   assumes "\<forall>x y. inner (f x) y = inner x (g y)"
```
```  1533   shows "adjoint f = g"
```
```  1534   unfolding adjoint_def
```
```  1535 proof (rule some_equality)
```
```  1536   show "\<forall>x y. inner (f x) y = inner x (g y)"
```
```  1537     by (rule assms)
```
```  1538 next
```
```  1539   fix h
```
```  1540   assume "\<forall>x y. inner (f x) y = inner x (h y)"
```
```  1541   then have "\<forall>x y. inner x (g y) = inner x (h y)"
```
```  1542     using assms by simp
```
```  1543   then have "\<forall>x y. inner x (g y - h y) = 0"
```
```  1544     by (simp add: inner_diff_right)
```
```  1545   then have "\<forall>y. inner (g y - h y) (g y - h y) = 0"
```
```  1546     by simp
```
```  1547   then have "\<forall>y. h y = g y"
```
```  1548     by simp
```
```  1549   then show "h = g" by (simp add: ext)
```
```  1550 qed
```
```  1551
```
```  1552 text \<open>TODO: The following lemmas about adjoints should hold for any
```
```  1553   Hilbert space (i.e. complete inner product space).
```
```  1554   (see \<^url>\<open>http://en.wikipedia.org/wiki/Hermitian_adjoint\<close>)
```
```  1555 \<close>
```
```  1556
```
```  1557 lemma adjoint_works:
```
```  1558   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
```
```  1559   assumes lf: "linear f"
```
```  1560   shows "x \<bullet> adjoint f y = f x \<bullet> y"
```
```  1561 proof -
```
```  1562   have "\<forall>y. \<exists>w. \<forall>x. f x \<bullet> y = x \<bullet> w"
```
```  1563   proof (intro allI exI)
```
```  1564     fix y :: "'m" and x
```
```  1565     let ?w = "(\<Sum>i\<in>Basis. (f i \<bullet> y) *\<^sub>R i) :: 'n"
```
```  1566     have "f x \<bullet> y = f (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R i) \<bullet> y"
```
```  1567       by (simp add: euclidean_representation)
```
```  1568     also have "\<dots> = (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R f i) \<bullet> y"
```
```  1569       unfolding linear_sum[OF lf]
```
```  1570       by (simp add: linear_cmul[OF lf])
```
```  1571     finally show "f x \<bullet> y = x \<bullet> ?w"
```
```  1572       by (simp add: inner_sum_left inner_sum_right mult.commute)
```
```  1573   qed
```
```  1574   then show ?thesis
```
```  1575     unfolding adjoint_def choice_iff
```
```  1576     by (intro someI2_ex[where Q="\<lambda>f'. x \<bullet> f' y = f x \<bullet> y"]) auto
```
```  1577 qed
```
```  1578
```
```  1579 lemma adjoint_clauses:
```
```  1580   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
```
```  1581   assumes lf: "linear f"
```
```  1582   shows "x \<bullet> adjoint f y = f x \<bullet> y"
```
```  1583     and "adjoint f y \<bullet> x = y \<bullet> f x"
```
```  1584   by (simp_all add: adjoint_works[OF lf] inner_commute)
```
```  1585
```
```  1586 lemma adjoint_linear:
```
```  1587   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
```
```  1588   assumes lf: "linear f"
```
```  1589   shows "linear (adjoint f)"
```
```  1590   by (simp add: lf linear_iff euclidean_eq_iff[where 'a='n] euclidean_eq_iff[where 'a='m]
```
```  1591     adjoint_clauses[OF lf] inner_distrib)
```
```  1592
```
```  1593 lemma adjoint_adjoint:
```
```  1594   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
```
```  1595   assumes lf: "linear f"
```
```  1596   shows "adjoint (adjoint f) = f"
```
```  1597   by (rule adjoint_unique, simp add: adjoint_clauses [OF lf])
```
```  1598
```
```  1599
```
```  1600 subsection%unimportant \<open>Interlude: Some properties of real sets\<close>
```
```  1601
```
```  1602 lemma seq_mono_lemma:
```
```  1603   assumes "\<forall>(n::nat) \<ge> m. (d n :: real) < e n"
```
```  1604     and "\<forall>n \<ge> m. e n \<le> e m"
```
```  1605   shows "\<forall>n \<ge> m. d n < e m"
```
```  1606   using assms by force
```
```  1607
```
```  1608 lemma infinite_enumerate:
```
```  1609   assumes fS: "infinite S"
```
```  1610   shows "\<exists>r::nat\<Rightarrow>nat. strict_mono r \<and> (\<forall>n. r n \<in> S)"
```
```  1611   unfolding strict_mono_def
```
```  1612   using enumerate_in_set[OF fS] enumerate_mono[of _ _ S] fS by auto
```
```  1613
```
```  1614 lemma approachable_lt_le: "(\<exists>(d::real) > 0. \<forall>x. f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> P x)"
```
```  1615   apply auto
```
```  1616   apply (rule_tac x="d/2" in exI)
```
```  1617   apply auto
```
```  1618   done
```
```  1619
```
```  1620 lemma approachable_lt_le2:  \<comment> \<open>like the above, but pushes aside an extra formula\<close>
```
```  1621     "(\<exists>(d::real) > 0. \<forall>x. Q x \<longrightarrow> f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> Q x \<longrightarrow> P x)"
```
```  1622   apply auto
```
```  1623   apply (rule_tac x="d/2" in exI, auto)
```
```  1624   done
```
```  1625
```
```  1626 lemma triangle_lemma:
```
```  1627   fixes x y z :: real
```
```  1628   assumes x: "0 \<le> x"
```
```  1629     and y: "0 \<le> y"
```
```  1630     and z: "0 \<le> z"
```
```  1631     and xy: "x\<^sup>2 \<le> y\<^sup>2 + z\<^sup>2"
```
```  1632   shows "x \<le> y + z"
```
```  1633 proof -
```
```  1634   have "y\<^sup>2 + z\<^sup>2 \<le> y\<^sup>2 + 2 * y * z + z\<^sup>2"
```
```  1635     using z y by simp
```
```  1636   with xy have th: "x\<^sup>2 \<le> (y + z)\<^sup>2"
```
```  1637     by (simp add: power2_eq_square field_simps)
```
```  1638   from y z have yz: "y + z \<ge> 0"
```
```  1639     by arith
```
```  1640   from power2_le_imp_le[OF th yz] show ?thesis .
```
```  1641 qed
```
```  1642
```
```  1643
```
```  1644
```
```  1645 subsection \<open>Archimedean properties and useful consequences\<close>
```
```  1646
```
```  1647 text\<open>Bernoulli's inequality\<close>
```
```  1648 proposition%important Bernoulli_inequality:
```
```  1649   fixes x :: real
```
```  1650   assumes "-1 \<le> x"
```
```  1651     shows "1 + n * x \<le> (1 + x) ^ n"
```
```  1652 proof%unimportant (induct n)
```
```  1653   case 0
```
```  1654   then show ?case by simp
```
```  1655 next
```
```  1656   case (Suc n)
```
```  1657   have "1 + Suc n * x \<le> 1 + (Suc n)*x + n * x^2"
```
```  1658     by (simp add: algebra_simps)
```
```  1659   also have "... = (1 + x) * (1 + n*x)"
```
```  1660     by (auto simp: power2_eq_square algebra_simps  of_nat_Suc)
```
```  1661   also have "... \<le> (1 + x) ^ Suc n"
```
```  1662     using Suc.hyps assms mult_left_mono by fastforce
```
```  1663   finally show ?case .
```
```  1664 qed
```
```  1665
```
```  1666 corollary Bernoulli_inequality_even:
```
```  1667   fixes x :: real
```
```  1668   assumes "even n"
```
```  1669     shows "1 + n * x \<le> (1 + x) ^ n"
```
```  1670 proof (cases "-1 \<le> x \<or> n=0")
```
```  1671   case True
```
```  1672   then show ?thesis
```
```  1673     by (auto simp: Bernoulli_inequality)
```
```  1674 next
```
```  1675   case False
```
```  1676   then have "real n \<ge> 1"
```
```  1677     by simp
```
```  1678   with False have "n * x \<le> -1"
```
```  1679     by (metis linear minus_zero mult.commute mult.left_neutral mult_left_mono_neg neg_le_iff_le order_trans zero_le_one)
```
```  1680   then have "1 + n * x \<le> 0"
```
```  1681     by auto
```
```  1682   also have "... \<le> (1 + x) ^ n"
```
```  1683     using assms
```
```  1684     using zero_le_even_power by blast
```
```  1685   finally show ?thesis .
```
```  1686 qed
```
```  1687
```
```  1688 corollary real_arch_pow:
```
```  1689   fixes x :: real
```
```  1690   assumes x: "1 < x"
```
```  1691   shows "\<exists>n. y < x^n"
```
```  1692 proof -
```
```  1693   from x have x0: "x - 1 > 0"
```
```  1694     by arith
```
```  1695   from reals_Archimedean3[OF x0, rule_format, of y]
```
```  1696   obtain n :: nat where n: "y < real n * (x - 1)" by metis
```
```  1697   from x0 have x00: "x- 1 \<ge> -1" by arith
```
```  1698   from Bernoulli_inequality[OF x00, of n] n
```
```  1699   have "y < x^n" by auto
```
```  1700   then show ?thesis by metis
```
```  1701 qed
```
```  1702
```
```  1703 corollary real_arch_pow_inv:
```
```  1704   fixes x y :: real
```
```  1705   assumes y: "y > 0"
```
```  1706     and x1: "x < 1"
```
```  1707   shows "\<exists>n. x^n < y"
```
```  1708 proof (cases "x > 0")
```
```  1709   case True
```
```  1710   with x1 have ix: "1 < 1/x" by (simp add: field_simps)
```
```  1711   from real_arch_pow[OF ix, of "1/y"]
```
```  1712   obtain n where n: "1/y < (1/x)^n" by blast
```
```  1713   then show ?thesis using y \<open>x > 0\<close>
```
```  1714     by (auto simp add: field_simps)
```
```  1715 next
```
```  1716   case False
```
```  1717   with y x1 show ?thesis
```
```  1718     by (metis less_le_trans not_less power_one_right)
```
```  1719 qed
```
```  1720
```
```  1721 lemma forall_pos_mono:
```
```  1722   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
```
```  1723     (\<And>n::nat. n \<noteq> 0 \<Longrightarrow> P (inverse (real n))) \<Longrightarrow> (\<And>e. 0 < e \<Longrightarrow> P e)"
```
```  1724   by (metis real_arch_inverse)
```
```  1725
```
```  1726 lemma forall_pos_mono_1:
```
```  1727   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
```
```  1728     (\<And>n. P (inverse (real (Suc n)))) \<Longrightarrow> 0 < e \<Longrightarrow> P e"
```
```  1729   apply (rule forall_pos_mono)
```
```  1730   apply auto
```
```  1731   apply (metis Suc_pred of_nat_Suc)
```
```  1732   done
```
```  1733
```
```  1734
```
```  1735 subsection%unimportant \<open>Euclidean Spaces as Typeclass\<close>
```
```  1736
```
```  1737 lemma independent_Basis: "independent Basis"
```
```  1738   unfolding dependent_def
```
```  1739   apply (subst span_finite)
```
```  1740   apply simp
```
```  1741   apply clarify
```
```  1742   apply (drule_tac f="inner a" in arg_cong)
```
```  1743   apply (simp add: inner_Basis inner_sum_right eq_commute)
```
```  1744   done
```
```  1745
```
```  1746 lemma span_Basis [simp]: "span Basis = UNIV"
```
```  1747   unfolding span_finite [OF finite_Basis]
```
```  1748   by (fast intro: euclidean_representation)
```
```  1749
```
```  1750 lemma in_span_Basis: "x \<in> span Basis"
```
```  1751   unfolding span_Basis ..
```
```  1752
```
```  1753 lemma Basis_le_norm: "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> norm x"
```
```  1754   by (rule order_trans [OF Cauchy_Schwarz_ineq2]) simp
```
```  1755
```
```  1756 lemma norm_bound_Basis_le: "b \<in> Basis \<Longrightarrow> norm x \<le> e \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> e"
```
```  1757   by (metis Basis_le_norm order_trans)
```
```  1758
```
```  1759 lemma norm_bound_Basis_lt: "b \<in> Basis \<Longrightarrow> norm x < e \<Longrightarrow> \<bar>x \<bullet> b\<bar> < e"
```
```  1760   by (metis Basis_le_norm le_less_trans)
```
```  1761
```
```  1762 lemma norm_le_l1: "norm x \<le> (\<Sum>b\<in>Basis. \<bar>x \<bullet> b\<bar>)"
```
```  1763   apply (subst euclidean_representation[of x, symmetric])
```
```  1764   apply (rule order_trans[OF norm_sum])
```
```  1765   apply (auto intro!: sum_mono)
```
```  1766   done
```
```  1767
```
```  1768 lemma sum_norm_allsubsets_bound:
```
```  1769   fixes f :: "'a \<Rightarrow> 'n::euclidean_space"
```
```  1770   assumes fP: "finite P"
```
```  1771     and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (sum f Q) \<le> e"
```
```  1772   shows "(\<Sum>x\<in>P. norm (f x)) \<le> 2 * real DIM('n) * e"
```
```  1773 proof -
```
```  1774   have "(\<Sum>x\<in>P. norm (f x)) \<le> (\<Sum>x\<in>P. \<Sum>b\<in>Basis. \<bar>f x \<bullet> b\<bar>)"
```
```  1775     by (rule sum_mono) (rule norm_le_l1)
```
```  1776   also have "(\<Sum>x\<in>P. \<Sum>b\<in>Basis. \<bar>f x \<bullet> b\<bar>) = (\<Sum>b\<in>Basis. \<Sum>x\<in>P. \<bar>f x \<bullet> b\<bar>)"
```
```  1777     by (rule sum.swap)
```
```  1778   also have "\<dots> \<le> of_nat (card (Basis :: 'n set)) * (2 * e)"
```
```  1779   proof (rule sum_bounded_above)
```
```  1780     fix i :: 'n
```
```  1781     assume i: "i \<in> Basis"
```
```  1782     have "norm (\<Sum>x\<in>P. \<bar>f x \<bullet> i\<bar>) \<le>
```
```  1783       norm ((\<Sum>x\<in>P \<inter> - {x. f x \<bullet> i < 0}. f x) \<bullet> i) + norm ((\<Sum>x\<in>P \<inter> {x. f x \<bullet> i < 0}. f x) \<bullet> i)"
```
```  1784       by (simp add: abs_real_def sum.If_cases[OF fP] sum_negf norm_triangle_ineq4 inner_sum_left
```
```  1785         del: real_norm_def)
```
```  1786     also have "\<dots> \<le> e + e"
```
```  1787       unfolding real_norm_def
```
```  1788       by (intro add_mono norm_bound_Basis_le i fPs) auto
```
```  1789     finally show "(\<Sum>x\<in>P. \<bar>f x \<bullet> i\<bar>) \<le> 2*e" by simp
```
```  1790   qed
```
```  1791   also have "\<dots> = 2 * real DIM('n) * e" by simp
```
```  1792   finally show ?thesis .
```
```  1793 qed
```
```  1794
```
```  1795
```
```  1796 subsection%unimportant \<open>Linearity and Bilinearity continued\<close>
```
```  1797
```
```  1798 lemma linear_bounded:
```
```  1799   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
```
```  1800   assumes lf: "linear f"
```
```  1801   shows "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
```
```  1802 proof
```
```  1803   let ?B = "\<Sum>b\<in>Basis. norm (f b)"
```
```  1804   show "\<forall>x. norm (f x) \<le> ?B * norm x"
```
```  1805   proof
```
```  1806     fix x :: 'a
```
```  1807     let ?g = "\<lambda>b. (x \<bullet> b) *\<^sub>R f b"
```
```  1808     have "norm (f x) = norm (f (\<Sum>b\<in>Basis. (x \<bullet> b) *\<^sub>R b))"
```
```  1809       unfolding euclidean_representation ..
```
```  1810     also have "\<dots> = norm (sum ?g Basis)"
```
```  1811       by (simp add: linear_sum [OF lf] linear_cmul [OF lf])
```
```  1812     finally have th0: "norm (f x) = norm (sum ?g Basis)" .
```
```  1813     have th: "norm (?g i) \<le> norm (f i) * norm x" if "i \<in> Basis" for i
```
```  1814     proof -
```
```  1815       from Basis_le_norm[OF that, of x]
```
```  1816       show "norm (?g i) \<le> norm (f i) * norm x"
```
```  1817         unfolding norm_scaleR  by (metis mult.commute mult_left_mono norm_ge_zero)
```
```  1818     qed
```
```  1819     from sum_norm_le[of _ ?g, OF th]
```
```  1820     show "norm (f x) \<le> ?B * norm x"
```
```  1821       unfolding th0 sum_distrib_right by metis
```
```  1822   qed
```
```  1823 qed
```
```  1824
```
```  1825 lemma linear_conv_bounded_linear:
```
```  1826   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
```
```  1827   shows "linear f \<longleftrightarrow> bounded_linear f"
```
```  1828 proof
```
```  1829   assume "linear f"
```
```  1830   then interpret f: linear f .
```
```  1831   show "bounded_linear f"
```
```  1832   proof
```
```  1833     have "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
```
```  1834       using \<open>linear f\<close> by (rule linear_bounded)
```
```  1835     then show "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
```
```  1836       by (simp add: mult.commute)
```
```  1837   qed
```
```  1838 next
```
```  1839   assume "bounded_linear f"
```
```  1840   then interpret f: bounded_linear f .
```
```  1841   show "linear f" ..
```
```  1842 qed
```
```  1843
```
```  1844 lemmas linear_linear = linear_conv_bounded_linear[symmetric]
```
```  1845
```
```  1846 lemma linear_bounded_pos:
```
```  1847   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
```
```  1848   assumes lf: "linear f"
```
```  1849  obtains B where "B > 0" "\<And>x. norm (f x) \<le> B * norm x"
```
```  1850 proof -
```
```  1851   have "\<exists>B > 0. \<forall>x. norm (f x) \<le> norm x * B"
```
```  1852     using lf unfolding linear_conv_bounded_linear
```
```  1853     by (rule bounded_linear.pos_bounded)
```
```  1854   with that show ?thesis
```
```  1855     by (auto simp: mult.commute)
```
```  1856 qed
```
```  1857
```
```  1858 lemma linear_invertible_bounded_below_pos:
```
```  1859   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::euclidean_space"
```
```  1860   assumes "linear f" "linear g" "g \<circ> f = id"
```
```  1861   obtains B where "B > 0" "\<And>x. B * norm x \<le> norm(f x)"
```
```  1862 proof -
```
```  1863   obtain B where "B > 0" and B: "\<And>x. norm (g x) \<le> B * norm x"
```
```  1864     using linear_bounded_pos [OF \<open>linear g\<close>] by blast
```
```  1865   show thesis
```
```  1866   proof
```
```  1867     show "0 < 1/B"
```
```  1868       by (simp add: \<open>B > 0\<close>)
```
```  1869     show "1/B * norm x \<le> norm (f x)" for x
```
```  1870     proof -
```
```  1871       have "1/B * norm x = 1/B * norm (g (f x))"
```
```  1872         using assms by (simp add: pointfree_idE)
```
```  1873       also have "\<dots> \<le> norm (f x)"
```
```  1874         using B [of "f x"] by (simp add: \<open>B > 0\<close> mult.commute pos_divide_le_eq)
```
```  1875       finally show ?thesis .
```
```  1876     qed
```
```  1877   qed
```
```  1878 qed
```
```  1879
```
```  1880 lemma linear_inj_bounded_below_pos:
```
```  1881   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::euclidean_space"
```
```  1882   assumes "linear f" "inj f"
```
```  1883   obtains B where "B > 0" "\<And>x. B * norm x \<le> norm(f x)"
```
```  1884   using linear_injective_left_inverse [OF assms] linear_invertible_bounded_below_pos assms by blast
```
```  1885
```
```  1886 lemma bounded_linearI':
```
```  1887   fixes f ::"'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
```
```  1888   assumes "\<And>x y. f (x + y) = f x + f y"
```
```  1889     and "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
```
```  1890   shows "bounded_linear f"
```
```  1891   unfolding linear_conv_bounded_linear[symmetric]
```
```  1892   by (rule linearI[OF assms])
```
```  1893
```
```  1894 lemma bilinear_bounded:
```
```  1895   fixes h :: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'k::real_normed_vector"
```
```  1896   assumes bh: "bilinear h"
```
```  1897   shows "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
```
```  1898 proof (clarify intro!: exI[of _ "\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)"])
```
```  1899   fix x :: 'm
```
```  1900   fix y :: 'n
```
```  1901   have "norm (h x y) = norm (h (sum (\<lambda>i. (x \<bullet> i) *\<^sub>R i) Basis) (sum (\<lambda>i. (y \<bullet> i) *\<^sub>R i) Basis))"
```
```  1902     by (simp add: euclidean_representation)
```
```  1903   also have "\<dots> = norm (sum (\<lambda> (i,j). h ((x \<bullet> i) *\<^sub>R i) ((y \<bullet> j) *\<^sub>R j)) (Basis \<times> Basis))"
```
```  1904     unfolding bilinear_sum[OF bh finite_Basis finite_Basis] ..
```
```  1905   finally have th: "norm (h x y) = \<dots>" .
```
```  1906   have "\<And>i j. \<lbrakk>i \<in> Basis; j \<in> Basis\<rbrakk>
```
```  1907            \<Longrightarrow> \<bar>x \<bullet> i\<bar> * (\<bar>y \<bullet> j\<bar> * norm (h i j)) \<le> norm x * (norm y * norm (h i j))"
```
```  1908     by (auto simp add: zero_le_mult_iff Basis_le_norm mult_mono)
```
```  1909   then show "norm (h x y) \<le> (\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)) * norm x * norm y"
```
```  1910     unfolding sum_distrib_right th sum.cartesian_product
```
```  1911     by (clarsimp simp add: bilinear_rmul[OF bh] bilinear_lmul[OF bh]
```
```  1912       field_simps simp del: scaleR_scaleR intro!: sum_norm_le)
```
```  1913 qed
```
```  1914
```
```  1915 lemma bilinear_conv_bounded_bilinear:
```
```  1916   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
```
```  1917   shows "bilinear h \<longleftrightarrow> bounded_bilinear h"
```
```  1918 proof
```
```  1919   assume "bilinear h"
```
```  1920   show "bounded_bilinear h"
```
```  1921   proof
```
```  1922     fix x y z
```
```  1923     show "h (x + y) z = h x z + h y z"
```
```  1924       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
```
```  1925   next
```
```  1926     fix x y z
```
```  1927     show "h x (y + z) = h x y + h x z"
```
```  1928       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
```
```  1929   next
```
```  1930     show "h (scaleR r x) y = scaleR r (h x y)" "h x (scaleR r y) = scaleR r (h x y)" for r x y
```
```  1931       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff
```
```  1932       by simp_all
```
```  1933   next
```
```  1934     have "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
```
```  1935       using \<open>bilinear h\<close> by (rule bilinear_bounded)
```
```  1936     then show "\<exists>K. \<forall>x y. norm (h x y) \<le> norm x * norm y * K"
```
```  1937       by (simp add: ac_simps)
```
```  1938   qed
```
```  1939 next
```
```  1940   assume "bounded_bilinear h"
```
```  1941   then interpret h: bounded_bilinear h .
```
```  1942   show "bilinear h"
```
```  1943     unfolding bilinear_def linear_conv_bounded_linear
```
```  1944     using h.bounded_linear_left h.bounded_linear_right by simp
```
```  1945 qed
```
```  1946
```
```  1947 lemma bilinear_bounded_pos:
```
```  1948   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
```
```  1949   assumes bh: "bilinear h"
```
```  1950   shows "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
```
```  1951 proof -
```
```  1952   have "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> norm x * norm y * B"
```
```  1953     using bh [unfolded bilinear_conv_bounded_bilinear]
```
```  1954     by (rule bounded_bilinear.pos_bounded)
```
```  1955   then show ?thesis
```
```  1956     by (simp only: ac_simps)
```
```  1957 qed
```
```  1958
```
```  1959 lemma bounded_linear_imp_has_derivative:
```
```  1960      "bounded_linear f \<Longrightarrow> (f has_derivative f) net"
```
```  1961   by (simp add: has_derivative_def bounded_linear.linear linear_diff)
```
```  1962
```
```  1963 lemma linear_imp_has_derivative:
```
```  1964   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
```
```  1965   shows "linear f \<Longrightarrow> (f has_derivative f) net"
```
```  1966 by (simp add: has_derivative_def linear_conv_bounded_linear linear_diff)
```
```  1967
```
```  1968 lemma bounded_linear_imp_differentiable: "bounded_linear f \<Longrightarrow> f differentiable net"
```
```  1969   using bounded_linear_imp_has_derivative differentiable_def by blast
```
```  1970
```
```  1971 lemma linear_imp_differentiable:
```
```  1972   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
```
```  1973   shows "linear f \<Longrightarrow> f differentiable net"
```
```  1974 by (metis linear_imp_has_derivative differentiable_def)
```
```  1975
```
```  1976
```
```  1977 subsection%unimportant \<open>We continue.\<close>
```
```  1978
```
```  1979 lemma independent_bound:
```
```  1980   fixes S :: "'a::euclidean_space set"
```
```  1981   shows "independent S \<Longrightarrow> finite S \<and> card S \<le> DIM('a)"
```
```  1982   using independent_span_bound[OF finite_Basis, of S] by auto
```
```  1983
```
```  1984 corollary
```
```  1985   fixes S :: "'a::euclidean_space set"
```
```  1986   assumes "independent S"
```
```  1987   shows independent_imp_finite: "finite S" and independent_card_le:"card S \<le> DIM('a)"
```
```  1988 using assms independent_bound by auto
```
```  1989
```
```  1990 lemma independent_explicit:
```
```  1991   fixes B :: "'a::euclidean_space set"
```
```  1992   shows "independent B \<longleftrightarrow>
```
```  1993          finite B \<and> (\<forall>c. (\<Sum>v\<in>B. c v *\<^sub>R v) = 0 \<longrightarrow> (\<forall>v \<in> B. c v = 0))"
```
```  1994 apply (cases "finite B")
```
```  1995  apply (force simp: dependent_finite)
```
```  1996 using independent_bound
```
```  1997 apply auto
```
```  1998 done
```
```  1999
```
```  2000 lemma dependent_biggerset:
```
```  2001   fixes S :: "'a::euclidean_space set"
```
```  2002   shows "(finite S \<Longrightarrow> card S > DIM('a)) \<Longrightarrow> dependent S"
```
```  2003   by (metis independent_bound not_less)
```
```  2004
```
```  2005 text \<open>Notion of dimension.\<close>
```
```  2006
```
```  2007 definition "dim V = (SOME n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> card B = n)"
```
```  2008
```
```  2009 lemma basis_exists:
```
```  2010   obtains B :: "'a::euclidean_space set"
```
```  2011   where "B \<subseteq> V" "independent B" "V \<subseteq> span B" "card B = dim V"
```
```  2012 proof -
```
```  2013   obtain B :: "'a set" where "B \<subseteq> V" "independent B" "V \<subseteq> span B"
```
```  2014     by (meson maximal_independent_subset[of V])
```
```  2015   then show ?thesis
```
```  2016     using that some_eq_ex[of "\<lambda>n. \<exists>B. B \<subseteq> V \<and> independent B \<and> V \<subseteq> span B \<and> (card B = n)"]
```
```  2017     unfolding dim_def by blast
```
```  2018 qed
```
```  2019
```
```  2020 corollary dim_le_card:
```
```  2021   fixes s :: "'a::euclidean_space set"
```
```  2022   shows "finite s \<Longrightarrow> dim s \<le> card s"
```
```  2023 by (metis basis_exists card_mono)
```
```  2024
```
```  2025 text \<open>Consequences of independence or spanning for cardinality.\<close>
```
```  2026
```
```  2027 lemma independent_card_le_dim:
```
```  2028   fixes B :: "'a::euclidean_space set"
```
```  2029   assumes "B \<subseteq> V"
```
```  2030     and "independent B"
```
```  2031   shows "card B \<le> dim V"
```
```  2032 proof -
```
```  2033   from basis_exists[of V] \<open>B \<subseteq> V\<close>
```
```  2034   obtain B' where "independent B'" "B \<subseteq> span B'" "card B' = dim V"
```
```  2035     by force
```
```  2036   with independent_span_bound[OF _ \<open>independent B\<close> \<open>B \<subseteq> span B'\<close>] independent_bound[of B']
```
```  2037   show ?thesis by auto
```
```  2038 qed
```
```  2039
```
```  2040 lemma span_card_ge_dim:
```
```  2041   fixes B :: "'a::euclidean_space set"
```
```  2042   shows "B \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> finite B \<Longrightarrow> dim V \<le> card B"
```
```  2043   by (metis basis_exists[of V] independent_span_bound subset_trans)
```
```  2044
```
```  2045 lemma basis_card_eq_dim:
```
```  2046   fixes V :: "'a::euclidean_space set"
```
```  2047   shows "B \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> independent B \<Longrightarrow> finite B \<and> card B = dim V"
```
```  2048   by (metis order_eq_iff independent_card_le_dim span_card_ge_dim independent_bound)
```
```  2049
```
```  2050 lemma dim_unique:
```
```  2051   fixes B :: "'a::euclidean_space set"
```
```  2052   shows "B \<subseteq> V \<Longrightarrow> V \<subseteq> span B \<Longrightarrow> independent B \<Longrightarrow> card B = n \<Longrightarrow> dim V = n"
```
```  2053   by (metis basis_card_eq_dim)
```
```  2054
```
```  2055 text \<open>More lemmas about dimension.\<close>
```
```  2056
```
```  2057 lemma dim_UNIV [simp]: "dim (UNIV :: 'a::euclidean_space set) = DIM('a)"
```
```  2058   using independent_Basis
```
```  2059   by (intro dim_unique[of Basis]) auto
```
```  2060
```
```  2061 lemma dim_subset:
```
```  2062   fixes S :: "'a::euclidean_space set"
```
```  2063   shows "S \<subseteq> T \<Longrightarrow> dim S \<le> dim T"
```
```  2064   using basis_exists[of T] basis_exists[of S]
```
```  2065   by (metis independent_card_le_dim subset_trans)
```
```  2066
```
```  2067 lemma dim_subset_UNIV:
```
```  2068   fixes S :: "'a::euclidean_space set"
```
```  2069   shows "dim S \<le> DIM('a)"
```
```  2070   by (metis dim_subset subset_UNIV dim_UNIV)
```
```  2071
```
```  2072 text \<open>Converses to those.\<close>
```
```  2073
```
```  2074 lemma card_ge_dim_independent:
```
```  2075   fixes B :: "'a::euclidean_space set"
```
```  2076   assumes BV: "B \<subseteq> V"
```
```  2077     and iB: "independent B"
```
```  2078     and dVB: "dim V \<le> card B"
```
```  2079   shows "V \<subseteq> span B"
```
```  2080 proof
```
```  2081   fix a
```
```  2082   assume aV: "a \<in> V"
```
```  2083   {
```
```  2084     assume aB: "a \<notin> span B"
```
```  2085     then have iaB: "independent (insert a B)"
```
```  2086       using iB aV BV by (simp add: independent_insert)
```
```  2087     from aV BV have th0: "insert a B \<subseteq> V"
```
```  2088       by blast
```
```  2089     from aB have "a \<notin>B"
```
```  2090       by (auto simp add: span_superset)
```
```  2091     with independent_card_le_dim[OF th0 iaB] dVB independent_bound[OF iB]
```
```  2092     have False by auto
```
```  2093   }
```
```  2094   then show "a \<in> span B" by blast
```
```  2095 qed
```
```  2096
```
```  2097 lemma card_le_dim_spanning:
```
```  2098   assumes BV: "(B:: ('a::euclidean_space) set) \<subseteq> V"
```
```  2099     and VB: "V \<subseteq> span B"
```
```  2100     and fB: "finite B"
```
```  2101     and dVB: "dim V \<ge> card B"
```
```  2102   shows "independent B"
```
```  2103 proof -
```
```  2104   {
```
```  2105     fix a
```
```  2106     assume a: "a \<in> B" "a \<in> span (B - {a})"
```
```  2107     from a fB have c0: "card B \<noteq> 0"
```
```  2108       by auto
```
```  2109     from a fB have cb: "card (B - {a}) = card B - 1"
```
```  2110       by auto
```
```  2111     from BV a have th0: "B - {a} \<subseteq> V"
```
```  2112       by blast
```
```  2113     {
```
```  2114       fix x
```
```  2115       assume x: "x \<in> V"
```
```  2116       from a have eq: "insert a (B - {a}) = B"
```
```  2117         by blast
```
```  2118       from x VB have x': "x \<in> span B"
```
```  2119         by blast
```
```  2120       from span_trans[OF a(2), unfolded eq, OF x']
```
```  2121       have "x \<in> span (B - {a})" .
```
```  2122     }
```
```  2123     then have th1: "V \<subseteq> span (B - {a})"
```
```  2124       by blast
```
```  2125     have th2: "finite (B - {a})"
```
```  2126       using fB by auto
```
```  2127     from span_card_ge_dim[OF th0 th1 th2]
```
```  2128     have c: "dim V \<le> card (B - {a})" .
```
```  2129     from c c0 dVB cb have False by simp
```
```  2130   }
```
```  2131   then show ?thesis
```
```  2132     unfolding dependent_def by blast
```
```  2133 qed
```
```  2134
```
```  2135 lemma card_eq_dim:
```
```  2136   fixes B :: "'a::euclidean_space set"
```
```  2137   shows "B \<subseteq> V \<Longrightarrow> card B = dim V \<Longrightarrow> finite B \<Longrightarrow> independent B \<longleftrightarrow> V \<subseteq> span B"
```
```  2138   by (metis order_eq_iff card_le_dim_spanning card_ge_dim_independent)
```
```  2139
```
```  2140 text \<open>More general size bound lemmas.\<close>
```
```  2141
```
```  2142 lemma independent_bound_general:
```
```  2143   fixes S :: "'a::euclidean_space set"
```
```  2144   shows "independent S \<Longrightarrow> finite S \<and> card S \<le> dim S"
```
```  2145   by (metis independent_card_le_dim independent_bound subset_refl)
```
```  2146
```
```  2147 lemma dependent_biggerset_general:
```
```  2148   fixes S :: "'a::euclidean_space set"
```
```  2149   shows "(finite S \<Longrightarrow> card S > dim S) \<Longrightarrow> dependent S"
```
```  2150   using independent_bound_general[of S] by (metis linorder_not_le)
```
```  2151
```
```  2152 lemma dim_span [simp]:
```
```  2153   fixes S :: "'a::euclidean_space set"
```
```  2154   shows "dim (span S) = dim S"
```
```  2155 proof -
```
```  2156   have th0: "dim S \<le> dim (span S)"
```
```  2157     by (auto simp add: subset_eq intro: dim_subset span_superset)
```
```  2158   from basis_exists[of S]
```
```  2159   obtain B where B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S"
```
```  2160     by blast
```
```  2161   from B have fB: "finite B" "card B = dim S"
```
```  2162     using independent_bound by blast+
```
```  2163   have bSS: "B \<subseteq> span S"
```
```  2164     using B(1) by (metis subset_eq span_inc)
```
```  2165   have sssB: "span S \<subseteq> span B"
```
```  2166     using span_mono[OF B(3)] by (simp add: span_span)
```
```  2167   from span_card_ge_dim[OF bSS sssB fB(1)] th0 show ?thesis
```
```  2168     using fB(2) by arith
```
```  2169 qed
```
```  2170
```
```  2171 lemma subset_le_dim:
```
```  2172   fixes S :: "'a::euclidean_space set"
```
```  2173   shows "S \<subseteq> span T \<Longrightarrow> dim S \<le> dim T"
```
```  2174   by (metis dim_span dim_subset)
```
```  2175
```
```  2176 lemma span_eq_dim:
```
```  2177   fixes S :: "'a::euclidean_space set"
```
```  2178   shows "span S = span T \<Longrightarrow> dim S = dim T"
```
```  2179   by (metis dim_span)
```
```  2180
```
```  2181 lemma dim_image_le:
```
```  2182   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
```
```  2183   assumes lf: "linear f"
```
```  2184   shows "dim (f ` S) \<le> dim (S)"
```
```  2185 proof -
```
```  2186   from basis_exists[of S] obtain B where
```
```  2187     B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S" by blast
```
```  2188   from B have fB: "finite B" "card B = dim S"
```
```  2189     using independent_bound by blast+
```
```  2190   have "dim (f ` S) \<le> card (f ` B)"
```
```  2191     apply (rule span_card_ge_dim)
```
```  2192     using lf B fB
```
```  2193     apply (auto simp add: span_linear_image spans_image subset_image_iff)
```
```  2194     done
```
```  2195   also have "\<dots> \<le> dim S"
```
```  2196     using card_image_le[OF fB(1)] fB by simp
```
```  2197   finally show ?thesis .
```
```  2198 qed
```
```  2199
```
```  2200 text \<open>Picking an orthogonal replacement for a spanning set.\<close>
```
```  2201
```
```  2202 lemma vector_sub_project_orthogonal:
```
```  2203   fixes b x :: "'a::euclidean_space"
```
```  2204   shows "b \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *\<^sub>R b) = 0"
```
```  2205   unfolding inner_simps by auto
```
```  2206
```
```  2207 lemma pairwise_orthogonal_insert:
```
```  2208   assumes "pairwise orthogonal S"
```
```  2209     and "\<And>y. y \<in> S \<Longrightarrow> orthogonal x y"
```
```  2210   shows "pairwise orthogonal (insert x S)"
```
```  2211   using assms unfolding pairwise_def
```
```  2212   by (auto simp add: orthogonal_commute)
```
```  2213
```
```  2214 lemma basis_orthogonal:
```
```  2215   fixes B :: "'a::real_inner set"
```
```  2216   assumes fB: "finite B"
```
```  2217   shows "\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C"
```
```  2218   (is " \<exists>C. ?P B C")
```
```  2219   using fB
```
```  2220 proof (induct rule: finite_induct)
```
```  2221   case empty
```
```  2222   then show ?case
```
```  2223     apply (rule exI[where x="{}"])
```
```  2224     apply (auto simp add: pairwise_def)
```
```  2225     done
```
```  2226 next
```
```  2227   case (insert a B)
```
```  2228   note fB = \<open>finite B\<close> and aB = \<open>a \<notin> B\<close>
```
```  2229   from \<open>\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C\<close>
```
```  2230   obtain C where C: "finite C" "card C \<le> card B"
```
```  2231     "span C = span B" "pairwise orthogonal C" by blast
```
```  2232   let ?a = "a - sum (\<lambda>x. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x) C"
```
```  2233   let ?C = "insert ?a C"
```
```  2234   from C(1) have fC: "finite ?C"
```
```  2235     by simp
```
```  2236   from fB aB C(1,2) have cC: "card ?C \<le> card (insert a B)"
```
```  2237     by (simp add: card_insert_if)
```
```  2238   {
```
```  2239     fix x k
```
```  2240     have th0: "\<And>(a::'a) b c. a - (b - c) = c + (a - b)"
```
```  2241       by (simp add: field_simps)
```
```  2242     have "x - k *\<^sub>R (a - (\<Sum>x\<in>C. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x)) \<in> span C \<longleftrightarrow> x - k *\<^sub>R a \<in> span C"
```
```  2243       apply (simp only: scaleR_right_diff_distrib th0)
```
```  2244       apply (rule span_add_eq)
```
```  2245       apply (rule span_mul)
```
```  2246       apply (rule span_sum)
```
```  2247       apply (rule span_mul)
```
```  2248       apply (rule span_superset)
```
```  2249       apply assumption
```
```  2250       done
```
```  2251   }
```
```  2252   then have SC: "span ?C = span (insert a B)"
```
```  2253     unfolding set_eq_iff span_breakdown_eq C(3)[symmetric] by auto
```
```  2254   {
```
```  2255     fix y
```
```  2256     assume yC: "y \<in> C"
```
```  2257     then have Cy: "C = insert y (C - {y})"
```
```  2258       by blast
```
```  2259     have fth: "finite (C - {y})"
```
```  2260       using C by simp
```
```  2261     have "orthogonal ?a y"
```
```  2262       unfolding orthogonal_def
```
```  2263       unfolding inner_diff inner_sum_left right_minus_eq
```
```  2264       unfolding sum.remove [OF \<open>finite C\<close> \<open>y \<in> C\<close>]
```
```  2265       apply (clarsimp simp add: inner_commute[of y a])
```
```  2266       apply (rule sum.neutral)
```
```  2267       apply clarsimp
```
```  2268       apply (rule C(4)[unfolded pairwise_def orthogonal_def, rule_format])
```
```  2269       using \<open>y \<in> C\<close> by auto
```
```  2270   }
```
```  2271   with \<open>pairwise orthogonal C\<close> have CPO: "pairwise orthogonal ?C"
```
```  2272     by (rule pairwise_orthogonal_insert)
```
```  2273   from fC cC SC CPO have "?P (insert a B) ?C"
```
```  2274     by blast
```
```  2275   then show ?case by blast
```
```  2276 qed
```
```  2277
```
```  2278 lemma orthogonal_basis_exists:
```
```  2279   fixes V :: "('a::euclidean_space) set"
```
```  2280   shows "\<exists>B. independent B \<and> B \<subseteq> span V \<and> V \<subseteq> span B \<and> (card B = dim V) \<and> pairwise orthogonal B"
```
```  2281 proof -
```
```  2282   from basis_exists[of V] obtain B where
```
```  2283     B: "B \<subseteq> V" "independent B" "V \<subseteq> span B" "card B = dim V"
```
```  2284     by blast
```
```  2285   from B have fB: "finite B" "card B = dim V"
```
```  2286     using independent_bound by auto
```
```  2287   from basis_orthogonal[OF fB(1)] obtain C where
```
```  2288     C: "finite C" "card C \<le> card B" "span C = span B" "pairwise orthogonal C"
```
```  2289     by blast
```
```  2290   from C B have CSV: "C \<subseteq> span V"
```
```  2291     by (metis span_inc span_mono subset_trans)
```
```  2292   from span_mono[OF B(3)] C have SVC: "span V \<subseteq> span C"
```
```  2293     by (simp add: span_span)
```
```  2294   from card_le_dim_spanning[OF CSV SVC C(1)] C(2,3) fB
```
```  2295   have iC: "independent C"
```
```  2296     by (simp add: dim_span)
```
```  2297   from C fB have "card C \<le> dim V"
```
```  2298     by simp
```
```  2299   moreover have "dim V \<le> card C"
```
```  2300     using span_card_ge_dim[OF CSV SVC C(1)]
```
```  2301     by (simp add: dim_span)
```
```  2302   ultimately have CdV: "card C = dim V"
```
```  2303     using C(1) by simp
```
```  2304   from C B CSV CdV iC show ?thesis
```
```  2305     by auto
```
```  2306 qed
```
```  2307
```
```  2308 text \<open>Low-dimensional subset is in a hyperplane (weak orthogonal complement).\<close>
```
```  2309
```
```  2310 lemma span_not_univ_orthogonal:
```
```  2311   fixes S :: "'a::euclidean_space set"
```
```  2312   assumes sU: "span S \<noteq> UNIV"
```
```  2313   shows "\<exists>a::'a. a \<noteq> 0 \<and> (\<forall>x \<in> span S. a \<bullet> x = 0)"
```
```  2314 proof -
```
```  2315   from sU obtain a where a: "a \<notin> span S"
```
```  2316     by blast
```
```  2317   from orthogonal_basis_exists obtain B where
```
```  2318     B: "independent B" "B \<subseteq> span S" "S \<subseteq> span B" "card B = dim S" "pairwise orthogonal B"
```
```  2319     by blast
```
```  2320   from B have fB: "finite B" "card B = dim S"
```
```  2321     using independent_bound by auto
```
```  2322   from span_mono[OF B(2)] span_mono[OF B(3)]
```
```  2323   have sSB: "span S = span B"
```
```  2324     by (simp add: span_span)
```
```  2325   let ?a = "a - sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B"
```
```  2326   have "sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B \<in> span S"
```
```  2327     unfolding sSB
```
```  2328     apply (rule span_sum)
```
```  2329     apply (rule span_mul)
```
```  2330     apply (rule span_superset)
```
```  2331     apply assumption
```
```  2332     done
```
```  2333   with a have a0:"?a  \<noteq> 0"
```
```  2334     by auto
```
```  2335   have "?a \<bullet> x = 0" if "x\<in>span B" for x
```
```  2336   proof (rule span_induct [OF that])
```
```  2337     show "subspace {x. ?a \<bullet> x = 0}"
```
```  2338       by (auto simp add: subspace_def inner_add)
```
```  2339   next
```
```  2340     {
```
```  2341       fix x
```
```  2342       assume x: "x \<in> B"
```
```  2343       from x have B': "B = insert x (B - {x})"
```
```  2344         by blast
```
```  2345       have fth: "finite (B - {x})"
```
```  2346         using fB by simp
```
```  2347       have "?a \<bullet> x = 0"
```
```  2348         apply (subst B')
```
```  2349         using fB fth
```
```  2350         unfolding sum_clauses(2)[OF fth]
```
```  2351         apply simp unfolding inner_simps
```
```  2352         apply (clarsimp simp add: inner_add inner_sum_left)
```
```  2353         apply (rule sum.neutral, rule ballI)
```
```  2354         apply (simp only: inner_commute)
```
```  2355         apply (auto simp add: x field_simps
```
```  2356           intro: B(5)[unfolded pairwise_def orthogonal_def, rule_format])
```
```  2357         done
```
```  2358     }
```
```  2359     then show "?a \<bullet> x = 0" if "x \<in> B" for x
```
```  2360       using that by blast
```
```  2361     qed
```
```  2362   with a0 show ?thesis
```
```  2363     unfolding sSB by (auto intro: exI[where x="?a"])
```
```  2364 qed
```
```  2365
```
```  2366 lemma span_not_univ_subset_hyperplane:
```
```  2367   fixes S :: "'a::euclidean_space set"
```
```  2368   assumes SU: "span S \<noteq> UNIV"
```
```  2369   shows "\<exists> a. a \<noteq>0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
```
```  2370   using span_not_univ_orthogonal[OF SU] by auto
```
```  2371
```
```  2372 lemma lowdim_subset_hyperplane:
```
```  2373   fixes S :: "'a::euclidean_space set"
```
```  2374   assumes d: "dim S < DIM('a)"
```
```  2375   shows "\<exists>a::'a. a \<noteq> 0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
```
```  2376 proof -
```
```  2377   {
```
```  2378     assume "span S = UNIV"
```
```  2379     then have "dim (span S) = dim (UNIV :: ('a) set)"
```
```  2380       by simp
```
```  2381     then have "dim S = DIM('a)"
```
```  2382       by (simp add: dim_span dim_UNIV)
```
```  2383     with d have False by arith
```
```  2384   }
```
```  2385   then have th: "span S \<noteq> UNIV"
```
```  2386     by blast
```
```  2387   from span_not_univ_subset_hyperplane[OF th] show ?thesis .
```
```  2388 qed
```
```  2389
```
```  2390 text \<open>We can extend a linear basis-basis injection to the whole set.\<close>
```
```  2391
```
```  2392 lemma linear_indep_image_lemma:
```
```  2393   assumes lf: "linear f"
```
```  2394     and fB: "finite B"
```
```  2395     and ifB: "independent (f ` B)"
```
```  2396     and fi: "inj_on f B"
```
```  2397     and xsB: "x \<in> span B"
```
```  2398     and fx: "f x = 0"
```
```  2399   shows "x = 0"
```
```  2400   using fB ifB fi xsB fx
```
```  2401 proof (induction B arbitrary: x rule: finite_induct)
```
```  2402   case empty
```
```  2403   then show ?case by auto
```
```  2404 next
```
```  2405   case (insert a b x)
```
```  2406   have th0: "f ` b \<subseteq> f ` (insert a b)"
```
```  2407     by (simp add: subset_insertI)
```
```  2408   have ifb: "independent (f ` b)"
```
```  2409     using independent_mono insert.prems(1) th0 by blast
```
```  2410   have fib: "inj_on f b"
```
```  2411     using insert.prems(2) by blast
```
```  2412   from span_breakdown[of a "insert a b", simplified, OF insert.prems(3)]
```
```  2413   obtain k where k: "x - k*\<^sub>R a \<in> span (b - {a})"
```
```  2414     by blast
```
```  2415   have "f (x - k*\<^sub>R a) \<in> span (f ` b)"
```
```  2416     unfolding span_linear_image[OF lf]
```
```  2417     using "insert.hyps"(2) k by auto
```
```  2418   then have "f x - k*\<^sub>R f a \<in> span (f ` b)"
```
```  2419     by (simp add: linear_diff[OF lf] linear_cmul[OF lf])
```
```  2420   then have th: "-k *\<^sub>R f a \<in> span (f ` b)"
```
```  2421     using insert.prems(4) by simp
```
```  2422   have xsb: "x \<in> span b"
```
```  2423   proof (cases "k = 0")
```
```  2424     case True
```
```  2425     with k have "x \<in> span (b - {a})" by simp
```
```  2426     then show ?thesis using span_mono[of "b - {a}" b]
```
```  2427       by blast
```
```  2428   next
```
```  2429     case False
```
```  2430     from inj_on_image_set_diff[OF insert.prems(2), of "insert a b " "{a}", symmetric]
```
```  2431     have "f ` insert a b - f ` {a} = f ` (insert a b - {a})" by blast
```
```  2432     then have "f a \<notin> span (f ` b)"
```
```  2433       using dependent_def insert.hyps(2) insert.prems(1) by fastforce
```
```  2434     moreover have "f a \<in> span (f ` b)"
```
```  2435       using False span_mul[OF th, of "- 1/ k"] by auto
```
```  2436     ultimately have False
```
```  2437       by blast
```
```  2438     then show ?thesis by blast
```
```  2439   qed
```
```  2440   show "x = 0"
```
```  2441     using ifb fib xsb insert.IH insert.prems(4) by blast
```
```  2442 qed
```
```  2443
```
```  2444 text \<open>Can construct an isomorphism between spaces of same dimension.\<close>
```
```  2445
```
```  2446 lemma subspace_isomorphism:
```
```  2447   fixes S :: "'a::euclidean_space set"
```
```  2448     and T :: "'b::euclidean_space set"
```
```  2449   assumes s: "subspace S"
```
```  2450     and t: "subspace T"
```
```  2451     and d: "dim S = dim T"
```
```  2452   shows "\<exists>f. linear f \<and> f ` S = T \<and> inj_on f S"
```
```  2453 proof -
```
```  2454   from basis_exists[of S] independent_bound
```
```  2455   obtain B where B: "B \<subseteq> S" "independent B" "S \<subseteq> span B" "card B = dim S" and fB: "finite B"
```
```  2456     by metis
```
```  2457   from basis_exists[of T] independent_bound
```
```  2458   obtain C where C: "C \<subseteq> T" "independent C" "T \<subseteq> span C" "card C = dim T" and fC: "finite C"
```
```  2459     by metis
```
```  2460   from B(4) C(4) card_le_inj[of B C] d
```
```  2461   obtain f where f: "f ` B \<subseteq> C" "inj_on f B" using \<open>finite B\<close> \<open>finite C\<close>
```
```  2462     by auto
```
```  2463   from linear_independent_extend[OF B(2)]
```
```  2464   obtain g where g: "linear g" "\<forall>x\<in> B. g x = f x"
```
```  2465     by blast
```
```  2466   from inj_on_iff_eq_card[OF fB, of f] f(2) have "card (f ` B) = card B"
```
```  2467     by simp
```
```  2468   with B(4) C(4) have ceq: "card (f ` B) = card C"
```
```  2469     using d by simp
```
```  2470   have "g ` B = f ` B"
```
```  2471     using g(2) by (auto simp add: image_iff)
```
```  2472   also have "\<dots> = C" using card_subset_eq[OF fC f(1) ceq] .
```
```  2473   finally have gBC: "g ` B = C" .
```
```  2474   have gi: "inj_on g B"
```
```  2475     using f(2) g(2) by (auto simp add: inj_on_def)
```
```  2476   note g0 = linear_indep_image_lemma[OF g(1) fB, unfolded gBC, OF C(2) gi]
```
```  2477   {
```
```  2478     fix x y
```
```  2479     assume x: "x \<in> S" and y: "y \<in> S" and gxy: "g x = g y"
```
```  2480     from B(3) x y have x': "x \<in> span B" and y': "y \<in> span B"
```
```  2481       by blast+
```
```  2482     from gxy have th0: "g (x - y) = 0"
```
```  2483       by (simp add: linear_diff[OF g(1)])
```
```  2484     have th1: "x - y \<in> span B"
```
```  2485       using x' y' by (metis span_diff)
```
```  2486     have "x = y"
```
```  2487       using g0[OF th1 th0] by simp
```
```  2488   }
```
```  2489   then have giS: "inj_on g S"
```
```  2490     unfolding inj_on_def by blast
```
```  2491   from span_subspace[OF B(1,3) s] have "g ` S = span (g ` B)"
```
```  2492     by (simp add: span_linear_image[OF g(1)])
```
```  2493   also have "\<dots> = span C" unfolding gBC ..
```
```  2494   also have "\<dots> = T" using span_subspace[OF C(1,3) t] .
```
```  2495   finally have gS: "g ` S = T" .
```
```  2496   from g(1) gS giS show ?thesis
```
```  2497     by blast
```
```  2498 qed
```
```  2499
```
```  2500 lemma linear_eq_stdbasis:
```
```  2501   fixes f :: "'a::euclidean_space \<Rightarrow> _"
```
```  2502   assumes lf: "linear f"
```
```  2503     and lg: "linear g"
```
```  2504     and fg: "\<And>b. b \<in> Basis \<Longrightarrow> f b = g b"
```
```  2505   shows "f = g"
```
```  2506   using linear_eq[OF _ lf lg, of _ _ Basis] fg by auto
```
```  2507
```
```  2508 text \<open>Similar results for bilinear functions.\<close>
```
```  2509
```
```  2510 lemma bilinear_eq:
```
```  2511   assumes bf: "bilinear f"
```
```  2512     and bg: "bilinear g"
```
```  2513     and SB: "S \<subseteq> span B"
```
```  2514     and TC: "T \<subseteq> span C"
```
```  2515     and "x\<in>S" "y\<in>T"
```
```  2516     and fg: "\<And>x y. \<lbrakk>x \<in> B; y\<in> C\<rbrakk> \<Longrightarrow> f x y = g x y"
```
```  2517   shows "f x y = g x y"
```
```  2518 proof -
```
```  2519   let ?P = "{x. \<forall>y\<in> span C. f x y = g x y}"
```
```  2520   from bf bg have sp: "subspace ?P"
```
```  2521     unfolding bilinear_def linear_iff subspace_def bf bg
```
```  2522     by (auto simp add: bilinear_lzero[OF bf] bilinear_lzero[OF bg] span_add
```
```  2523       intro: bilinear_ladd[OF bf])
```
```  2524   have sfg: "\<And>x. x \<in> B \<Longrightarrow> subspace {a. f x a = g x a}"
```
```  2525     apply (auto simp add: subspace_def)
```
```  2526     using bf bg unfolding bilinear_def linear_iff
```
```  2527     apply (auto simp add: bilinear_rzero[OF bf] bilinear_rzero[OF bg] span_add
```
```  2528       intro: bilinear_ladd[OF bf])
```
```  2529     done
```
```  2530   have "\<forall>y\<in> span C. f x y = g x y" if "x \<in> span B" for x
```
```  2531     apply (rule span_induct [OF that sp])
```
```  2532     using fg sfg span_induct by blast
```
```  2533   then show ?thesis
```
```  2534     using SB TC assms by auto
```
```  2535 qed
```
```  2536
```
```  2537 lemma bilinear_eq_stdbasis:
```
```  2538   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> _"
```
```  2539   assumes bf: "bilinear f"
```
```  2540     and bg: "bilinear g"
```
```  2541     and fg: "\<And>i j. i \<in> Basis \<Longrightarrow> j \<in> Basis \<Longrightarrow> f i j = g i j"
```
```  2542   shows "f = g"
```
```  2543   using bilinear_eq[OF bf bg equalityD2[OF span_Basis] equalityD2[OF span_Basis]] fg
```
```  2544   by blast
```
```  2545
```
```  2546 text \<open>An injective map @{typ "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"} is also surjective.\<close>
```
```  2547
```
```  2548 lemma linear_injective_imp_surjective:
```
```  2549   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
```
```  2550   assumes lf: "linear f"
```
```  2551     and fi: "inj f"
```
```  2552   shows "surj f"
```
```  2553 proof -
```
```  2554   let ?U = "UNIV :: 'a set"
```
```  2555   from basis_exists[of ?U] obtain B
```
```  2556     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" "card B = dim ?U"
```
```  2557     by blast
```
```  2558   from B(4) have d: "dim ?U = card B"
```
```  2559     by simp
```
```  2560   have th: "?U \<subseteq> span (f ` B)"
```
```  2561     apply (rule card_ge_dim_independent)
```
```  2562     apply blast
```
```  2563     apply (rule independent_injective_image[OF B(2) lf fi])
```
```  2564     by (metis card_image d fi inj_on_subset order_refl top_greatest)
```
```  2565   from th show ?thesis
```
```  2566     unfolding span_linear_image[OF lf] surj_def
```
```  2567     using B(3) by blast
```
```  2568 qed
```
```  2569
```
```  2570 text \<open>And vice versa.\<close>
```
```  2571
```
```  2572 lemma surjective_iff_injective_gen:
```
```  2573   assumes fS: "finite S"
```
```  2574     and fT: "finite T"
```
```  2575     and c: "card S = card T"
```
```  2576     and ST: "f ` S \<subseteq> T"
```
```  2577   shows "(\<forall>y \<in> T. \<exists>x \<in> S. f x = y) \<longleftrightarrow> inj_on f S"
```
```  2578   (is "?lhs \<longleftrightarrow> ?rhs")
```
```  2579 proof
```
```  2580   assume h: "?lhs"
```
```  2581   { fix x y
```
```  2582     assume x: "x \<in> S" and y: "y \<in> S" and f: "f x = f y"
```
```  2583     from x fS have S0: "card S \<noteq> 0"
```
```  2584       by auto
```
```  2585     have "x = y"
```
```  2586     proof (rule ccontr)
```
```  2587       assume xy: "\<not> ?thesis"
```
```  2588       have th: "card S \<le> card (f ` (S - {y}))"
```
```  2589         unfolding c
```
```  2590       proof (rule card_mono)
```
```  2591         show "finite (f ` (S - {y}))"
```
```  2592           by (simp add: fS)
```
```  2593         show "T \<subseteq> f ` (S - {y})"
```
```  2594           using h xy x y f unfolding subset_eq image_iff
```
```  2595           by (metis member_remove remove_def)
```
```  2596       qed
```
```  2597       also have " \<dots> \<le> card (S - {y})"
```
```  2598         apply (rule card_image_le)
```
```  2599         using fS by simp
```
```  2600       also have "\<dots> \<le> card S - 1" using y fS by simp
```
```  2601       finally show False using S0 by arith
```
```  2602     qed
```
```  2603   }
```
```  2604   then show ?rhs
```
```  2605     unfolding inj_on_def by blast
```
```  2606 next
```
```  2607   assume h: ?rhs
```
```  2608   have "f ` S = T"
```
```  2609     by (simp add: ST c card_image card_subset_eq fT h)
```
```  2610   then show ?lhs by blast
```
```  2611 qed
```
```  2612
```
```  2613 lemma linear_surjective_imp_injective:
```
```  2614   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
```
```  2615   assumes lf: "linear f" and sf: "surj f"
```
```  2616   shows "inj f"
```
```  2617 proof -
```
```  2618   let ?U = "UNIV :: 'a set"
```
```  2619   from basis_exists[of ?U] obtain B
```
```  2620     where B: "B \<subseteq> ?U" "independent B" "?U \<subseteq> span B" and d: "card B = dim ?U"
```
```  2621     by blast
```
```  2622   {
```
```  2623     fix x
```
```  2624     assume x: "x \<in> span B" and fx: "f x = 0"
```
```  2625     from B(2) have fB: "finite B"
```
```  2626       using independent_bound by auto
```
```  2627     have Uspan: "UNIV \<subseteq> span (f ` B)"
```
```  2628       by (simp add: B(3) lf sf spanning_surjective_image)
```
```  2629     have fBi: "independent (f ` B)"
```
```  2630     proof (rule card_le_dim_spanning)
```
```  2631       show "card (f ` B) \<le> dim ?U"
```
```  2632         using card_image_le d fB by fastforce
```
```  2633     qed (use fB Uspan in auto)
```
```  2634     have th0: "dim ?U \<le> card (f ` B)"
```
```  2635       by (rule span_card_ge_dim) (use Uspan fB in auto)
```
```  2636     moreover have "card (f ` B) \<le> card B"
```
```  2637       by (rule card_image_le, rule fB)
```
```  2638     ultimately have th1: "card B = card (f ` B)"
```
```  2639       unfolding d by arith
```
```  2640     have fiB: "inj_on f B"
```
```  2641       by (simp add: eq_card_imp_inj_on fB th1)
```
```  2642     from linear_indep_image_lemma[OF lf fB fBi fiB x] fx
```
```  2643     have "x = 0" by blast
```
```  2644   }
```
```  2645   then show ?thesis
```
```  2646     unfolding linear_injective_0[OF lf] using B(3) by blast
```
```  2647 qed
```
```  2648
```
```  2649 text \<open>Hence either is enough for isomorphism.\<close>
```
```  2650
```
```  2651 lemma left_right_inverse_eq:
```
```  2652   assumes fg: "f \<circ> g = id"
```
```  2653     and gh: "g \<circ> h = id"
```
```  2654   shows "f = h"
```
```  2655 proof -
```
```  2656   have "f = f \<circ> (g \<circ> h)"
```
```  2657     unfolding gh by simp
```
```  2658   also have "\<dots> = (f \<circ> g) \<circ> h"
```
```  2659     by (simp add: o_assoc)
```
```  2660   finally show "f = h"
```
```  2661     unfolding fg by simp
```
```  2662 qed
```
```  2663
```
```  2664 lemma isomorphism_expand:
```
```  2665   "f \<circ> g = id \<and> g \<circ> f = id \<longleftrightarrow> (\<forall>x. f (g x) = x) \<and> (\<forall>x. g (f x) = x)"
```
```  2666   by (simp add: fun_eq_iff o_def id_def)
```
```  2667
```
```  2668 lemma linear_injective_isomorphism:
```
```  2669   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
```
```  2670   assumes lf: "linear f"
```
```  2671     and fi: "inj f"
```
```  2672   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
```
```  2673   unfolding isomorphism_expand[symmetric]
```
```  2674   using linear_surjective_right_inverse[OF lf linear_injective_imp_surjective[OF lf fi]]
```
```  2675     linear_injective_left_inverse[OF lf fi]
```
```  2676   by (metis left_right_inverse_eq)
```
```  2677
```
```  2678 lemma linear_surjective_isomorphism:
```
```  2679   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
```
```  2680   assumes lf: "linear f"
```
```  2681     and sf: "surj f"
```
```  2682   shows "\<exists>f'. linear f' \<and> (\<forall>x. f' (f x) = x) \<and> (\<forall>x. f (f' x) = x)"
```
```  2683   unfolding isomorphism_expand[symmetric]
```
```  2684   using linear_surjective_right_inverse[OF lf sf]
```
```  2685     linear_injective_left_inverse[OF lf linear_surjective_imp_injective[OF lf sf]]
```
```  2686   by (metis left_right_inverse_eq)
```
```  2687
```
```  2688 text \<open>Left and right inverses are the same for
```
```  2689   @{typ "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"}.\<close>
```
```  2690
```
```  2691 lemma linear_inverse_left:
```
```  2692   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
```
```  2693   assumes lf: "linear f"
```
```  2694     and lf': "linear f'"
```
```  2695   shows "f \<circ> f' = id \<longleftrightarrow> f' \<circ> f = id"
```
```  2696 proof -
```
```  2697   {
```
```  2698     fix f f':: "'a \<Rightarrow> 'a"
```
```  2699     assume lf: "linear f" "linear f'"
```
```  2700     assume f: "f \<circ> f' = id"
```
```  2701     from f have sf: "surj f"
```
```  2702       by (auto simp add: o_def id_def surj_def) metis
```
```  2703     from linear_surjective_isomorphism[OF lf(1) sf] lf f
```
```  2704     have "f' \<circ> f = id"
```
```  2705       unfolding fun_eq_iff o_def id_def by metis
```
```  2706   }
```
```  2707   then show ?thesis
```
```  2708     using lf lf' by metis
```
```  2709 qed
```
```  2710
```
```  2711 text \<open>Moreover, a one-sided inverse is automatically linear.\<close>
```
```  2712
```
```  2713 lemma left_inverse_linear:
```
```  2714   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
```
```  2715   assumes lf: "linear f"
```
```  2716     and gf: "g \<circ> f = id"
```
```  2717   shows "linear g"
```
```  2718 proof -
```
```  2719   from gf have fi: "inj f"
```
```  2720     by (auto simp add: inj_on_def o_def id_def fun_eq_iff) metis
```
```  2721   from linear_injective_isomorphism[OF lf fi]
```
```  2722   obtain h :: "'a \<Rightarrow> 'a" where "linear h" and h: "\<forall>x. h (f x) = x" "\<forall>x. f (h x) = x"
```
```  2723     by blast
```
```  2724   have "h = g"
```
```  2725     by (metis gf h isomorphism_expand left_right_inverse_eq)
```
```  2726   with \<open>linear h\<close> show ?thesis by blast
```
```  2727 qed
```
```  2728
```
```  2729 lemma inj_linear_imp_inv_linear:
```
```  2730   fixes f :: "'a::euclidean_space \<Rightarrow> 'a::euclidean_space"
```
```  2731   assumes "linear f" "inj f" shows "linear (inv f)"
```
```  2732 using assms inj_iff left_inverse_linear by blast
```
```  2733
```
```  2734
```
```  2735 subsection \<open>Infinity norm\<close>
```
```  2736
```
```  2737 definition%important "infnorm (x::'a::euclidean_space) = Sup {\<bar>x \<bullet> b\<bar> |b. b \<in> Basis}"
```
```  2738
```
```  2739 lemma infnorm_set_image:
```
```  2740   fixes x :: "'a::euclidean_space"
```
```  2741   shows "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} = (\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
```
```  2742   by blast
```
```  2743
```
```  2744 lemma infnorm_Max:
```
```  2745   fixes x :: "'a::euclidean_space"
```
```  2746   shows "infnorm x = Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis)"
```
```  2747   by (simp add: infnorm_def infnorm_set_image cSup_eq_Max)
```
```  2748
```
```  2749 lemma infnorm_set_lemma:
```
```  2750   fixes x :: "'a::euclidean_space"
```
```  2751   shows "finite {\<bar>x \<bullet> i\<bar> |i. i \<in> Basis}"
```
```  2752     and "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} \<noteq> {}"
```
```  2753   unfolding infnorm_set_image
```
```  2754   by auto
```
```  2755
```
```  2756 lemma infnorm_pos_le:
```
```  2757   fixes x :: "'a::euclidean_space"
```
```  2758   shows "0 \<le> infnorm x"
```
```  2759   by (simp add: infnorm_Max Max_ge_iff ex_in_conv)
```
```  2760
```
```  2761 lemma infnorm_triangle:
```
```  2762   fixes x :: "'a::euclidean_space"
```
```  2763   shows "infnorm (x + y) \<le> infnorm x + infnorm y"
```
```  2764 proof -
```
```  2765   have *: "\<And>a b c d :: real. \<bar>a\<bar> \<le> c \<Longrightarrow> \<bar>b\<bar> \<le> d \<Longrightarrow> \<bar>a + b\<bar> \<le> c + d"
```
```  2766     by simp
```
```  2767   show ?thesis
```
```  2768     by (auto simp: infnorm_Max inner_add_left intro!: *)
```
```  2769 qed
```
```  2770
```
```  2771 lemma infnorm_eq_0:
```
```  2772   fixes x :: "'a::euclidean_space"
```
```  2773   shows "infnorm x = 0 \<longleftrightarrow> x = 0"
```
```  2774 proof -
```
```  2775   have "infnorm x \<le> 0 \<longleftrightarrow> x = 0"
```
```  2776     unfolding infnorm_Max by (simp add: euclidean_all_zero_iff)
```
```  2777   then show ?thesis
```
```  2778     using infnorm_pos_le[of x] by simp
```
```  2779 qed
```
```  2780
```
```  2781 lemma infnorm_0: "infnorm 0 = 0"
```
```  2782   by (simp add: infnorm_eq_0)
```
```  2783
```
```  2784 lemma infnorm_neg: "infnorm (- x) = infnorm x"
```
```  2785   unfolding infnorm_def by simp
```
```  2786
```
```  2787 lemma infnorm_sub: "infnorm (x - y) = infnorm (y - x)"
```
```  2788   by (metis infnorm_neg minus_diff_eq)
```
```  2789
```
```  2790 lemma absdiff_infnorm: "\<bar>infnorm x - infnorm y\<bar> \<le> infnorm (x - y)"
```
```  2791 proof -
```
```  2792   have *: "\<And>(nx::real) n ny. nx \<le> n + ny \<Longrightarrow> ny \<le> n + nx \<Longrightarrow> \<bar>nx - ny\<bar> \<le> n"
```
```  2793     by arith
```
```  2794   show ?thesis
```
```  2795   proof (rule *)
```
```  2796     from infnorm_triangle[of "x - y" " y"] infnorm_triangle[of "x - y" "-x"]
```
```  2797     show "infnorm x \<le> infnorm (x - y) + infnorm y" "infnorm y \<le> infnorm (x - y) + infnorm x"
```
```  2798       by (simp_all add: field_simps infnorm_neg)
```
```  2799   qed
```
```  2800 qed
```
```  2801
```
```  2802 lemma real_abs_infnorm: "\<bar>infnorm x\<bar> = infnorm x"
```
```  2803   using infnorm_pos_le[of x] by arith
```
```  2804
```
```  2805 lemma Basis_le_infnorm:
```
```  2806   fixes x :: "'a::euclidean_space"
```
```  2807   shows "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> infnorm x"
```
```  2808   by (simp add: infnorm_Max)
```
```  2809
```
```  2810 lemma infnorm_mul: "infnorm (a *\<^sub>R x) = \<bar>a\<bar> * infnorm x"
```
```  2811   unfolding infnorm_Max
```
```  2812 proof (safe intro!: Max_eqI)
```
```  2813   let ?B = "(\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
```
```  2814   { fix b :: 'a
```
```  2815     assume "b \<in> Basis"
```
```  2816     then show "\<bar>a *\<^sub>R x \<bullet> b\<bar> \<le> \<bar>a\<bar> * Max ?B"
```
```  2817       by (simp add: abs_mult mult_left_mono)
```
```  2818   next
```
```  2819     from Max_in[of ?B] obtain b where "b \<in> Basis" "Max ?B = \<bar>x \<bullet> b\<bar>"
```
```  2820       by (auto simp del: Max_in)
```
```  2821     then show "\<bar>a\<bar> * Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis) \<in> (\<lambda>i. \<bar>a *\<^sub>R x \<bullet> i\<bar>) ` Basis"
```
```  2822       by (intro image_eqI[where x=b]) (auto simp: abs_mult)
```
```  2823   }
```
```  2824 qed simp
```
```  2825
```
```  2826 lemma infnorm_mul_lemma: "infnorm (a *\<^sub>R x) \<le> \<bar>a\<bar> * infnorm x"
```
```  2827   unfolding infnorm_mul ..
```
```  2828
```
```  2829 lemma infnorm_pos_lt: "infnorm x > 0 \<longleftrightarrow> x \<noteq> 0"
```
```  2830   using infnorm_pos_le[of x] infnorm_eq_0[of x] by arith
```
```  2831
```
```  2832 text \<open>Prove that it differs only up to a bound from Euclidean norm.\<close>
```
```  2833
```
```  2834 lemma infnorm_le_norm: "infnorm x \<le> norm x"
```
```  2835   by (simp add: Basis_le_norm infnorm_Max)
```
```  2836
```
```  2837 lemma norm_le_infnorm:
```
```  2838   fixes x :: "'a::euclidean_space"
```
```  2839   shows "norm x \<le> sqrt DIM('a) * infnorm x"
```
```  2840   unfolding norm_eq_sqrt_inner id_def
```
```  2841 proof (rule real_le_lsqrt[OF inner_ge_zero])
```
```  2842   show "sqrt DIM('a) * infnorm x \<ge> 0"
```
```  2843     by (simp add: zero_le_mult_iff infnorm_pos_le)
```
```  2844   have "x \<bullet> x \<le> (\<Sum>b\<in>Basis. x \<bullet> b * (x \<bullet> b))"
```
```  2845     by (metis euclidean_inner order_refl)
```
```  2846   also have "... \<le> DIM('a) * \<bar>infnorm x\<bar>\<^sup>2"
```
```  2847     by (rule sum_bounded_above) (metis Basis_le_infnorm abs_le_square_iff power2_eq_square real_abs_infnorm)
```
```  2848   also have "... \<le> (sqrt DIM('a) * infnorm x)\<^sup>2"
```
```  2849     by (simp add: power_mult_distrib)
```
```  2850   finally show "x \<bullet> x \<le> (sqrt DIM('a) * infnorm x)\<^sup>2" .
```
```  2851 qed
```
```  2852
```
```  2853 lemma tendsto_infnorm [tendsto_intros]:
```
```  2854   assumes "(f \<longlongrightarrow> a) F"
```
```  2855   shows "((\<lambda>x. infnorm (f x)) \<longlongrightarrow> infnorm a) F"
```
```  2856 proof (rule tendsto_compose [OF LIM_I assms])
```
```  2857   fix r :: real
```
```  2858   assume "r > 0"
```
```  2859   then show "\<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (infnorm x - infnorm a) < r"
```
```  2860     by (metis real_norm_def le_less_trans absdiff_infnorm infnorm_le_norm)
```
```  2861 qed
```
```  2862
```
```  2863 text \<open>Equality in Cauchy-Schwarz and triangle inequalities.\<close>
```
```  2864
```
```  2865 lemma norm_cauchy_schwarz_eq: "x \<bullet> y = norm x * norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
```
```  2866   (is "?lhs \<longleftrightarrow> ?rhs")
```
```  2867 proof (cases "x=0")
```
```  2868   case True
```
```  2869   then show ?thesis
```
```  2870     by auto
```
```  2871 next
```
```  2872   case False
```
```  2873   from inner_eq_zero_iff[of "norm y *\<^sub>R x - norm x *\<^sub>R y"]
```
```  2874   have "?rhs \<longleftrightarrow>
```
```  2875       (norm y * (norm y * norm x * norm x - norm x * (x \<bullet> y)) -
```
```  2876         norm x * (norm y * (y \<bullet> x) - norm x * norm y * norm y) =  0)"
```
```  2877     using False unfolding inner_simps
```
```  2878     by (auto simp add: power2_norm_eq_inner[symmetric] power2_eq_square inner_commute field_simps)
```
```  2879   also have "\<dots> \<longleftrightarrow> (2 * norm x * norm y * (norm x * norm y - x \<bullet> y) = 0)"
```
```  2880     using False  by (simp add: field_simps inner_commute)
```
```  2881   also have "\<dots> \<longleftrightarrow> ?lhs"
```
```  2882     using False by auto
```
```  2883   finally show ?thesis by metis
```
```  2884 qed
```
```  2885
```
```  2886 lemma norm_cauchy_schwarz_abs_eq:
```
```  2887   "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow>
```
```  2888     norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm x *\<^sub>R y = - norm y *\<^sub>R x"
```
```  2889   (is "?lhs \<longleftrightarrow> ?rhs")
```
```  2890 proof -
```
```  2891   have th: "\<And>(x::real) a. a \<ge> 0 \<Longrightarrow> \<bar>x\<bar> = a \<longleftrightarrow> x = a \<or> x = - a"
```
```  2892     by arith
```
```  2893   have "?rhs \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm (- x) *\<^sub>R y = norm y *\<^sub>R (- x)"
```
```  2894     by simp
```
```  2895   also have "\<dots> \<longleftrightarrow> (x \<bullet> y = norm x * norm y \<or> (- x) \<bullet> y = norm x * norm y)"
```
```  2896     unfolding norm_cauchy_schwarz_eq[symmetric]
```
```  2897     unfolding norm_minus_cancel norm_scaleR ..
```
```  2898   also have "\<dots> \<longleftrightarrow> ?lhs"
```
```  2899     unfolding th[OF mult_nonneg_nonneg, OF norm_ge_zero[of x] norm_ge_zero[of y]] inner_simps
```
```  2900     by auto
```
```  2901   finally show ?thesis ..
```
```  2902 qed
```
```  2903
```
```  2904 lemma norm_triangle_eq:
```
```  2905   fixes x y :: "'a::real_inner"
```
```  2906   shows "norm (x + y) = norm x + norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
```
```  2907 proof (cases "x = 0 \<or> y = 0")
```
```  2908   case True
```
```  2909   then show ?thesis
```
```  2910     by force
```
```  2911 next
```
```  2912   case False
```
```  2913   then have n: "norm x > 0" "norm y > 0"
```
```  2914     by auto
```
```  2915   have "norm (x + y) = norm x + norm y \<longleftrightarrow> (norm (x + y))\<^sup>2 = (norm x + norm y)\<^sup>2"
```
```  2916     by simp
```
```  2917   also have "\<dots> \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
```
```  2918     unfolding norm_cauchy_schwarz_eq[symmetric]
```
```  2919     unfolding power2_norm_eq_inner inner_simps
```
```  2920     by (simp add: power2_norm_eq_inner[symmetric] power2_eq_square inner_commute field_simps)
```
```  2921   finally show ?thesis .
```
```  2922 qed
```
```  2923
```
```  2924
```
```  2925 subsection \<open>Collinearity\<close>
```
```  2926
```
```  2927 definition%important collinear :: "'a::real_vector set \<Rightarrow> bool"
```
```  2928   where "collinear S \<longleftrightarrow> (\<exists>u. \<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u)"
```
```  2929
```
```  2930 lemma collinear_alt:
```
```  2931      "collinear S \<longleftrightarrow> (\<exists>u v. \<forall>x \<in> S. \<exists>c. x = u + c *\<^sub>R v)" (is "?lhs = ?rhs")
```
```  2932 proof
```
```  2933   assume ?lhs
```
```  2934   then show ?rhs
```
```  2935     unfolding collinear_def by (metis Groups.add_ac(2) diff_add_cancel)
```
```  2936 next
```
```  2937   assume ?rhs
```
```  2938   then obtain u v where *: "\<And>x. x \<in> S \<Longrightarrow> \<exists>c. x = u + c *\<^sub>R v"
```
```  2939     by (auto simp: )
```
```  2940   have "\<exists>c. x - y = c *\<^sub>R v" if "x \<in> S" "y \<in> S" for x y
```
```  2941         by (metis *[OF \<open>x \<in> S\<close>] *[OF \<open>y \<in> S\<close>] scaleR_left.diff add_diff_cancel_left)
```
```  2942   then show ?lhs
```
```  2943     using collinear_def by blast
```
```  2944 qed
```
```  2945
```
```  2946 lemma collinear:
```
```  2947   fixes S :: "'a::{perfect_space,real_vector} set"
```
```  2948   shows "collinear S \<longleftrightarrow> (\<exists>u. u \<noteq> 0 \<and> (\<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u))"
```
```  2949 proof -
```
```  2950   have "\<exists>v. v \<noteq> 0 \<and> (\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v)"
```
```  2951     if "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R u" "u=0" for u
```
```  2952   proof -
```
```  2953     have "\<forall>x\<in>S. \<forall>y\<in>S. x = y"
```
```  2954       using that by auto
```
```  2955     moreover
```
```  2956     obtain v::'a where "v \<noteq> 0"
```
```  2957       using UNIV_not_singleton [of 0] by auto
```
```  2958     ultimately have "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v"
```
```  2959       by auto
```
```  2960     then show ?thesis
```
```  2961       using \<open>v \<noteq> 0\<close> by blast
```
```  2962   qed
```
```  2963   then show ?thesis
```
```  2964     apply (clarsimp simp: collinear_def)
```
```  2965     by (metis real_vector.scale_zero_right vector_fraction_eq_iff)
```
```  2966 qed
```
```  2967
```
```  2968 lemma collinear_subset: "\<lbrakk>collinear T; S \<subseteq> T\<rbrakk> \<Longrightarrow> collinear S"
```
```  2969   by (meson collinear_def subsetCE)
```
```  2970
```
```  2971 lemma collinear_empty [iff]: "collinear {}"
```
```  2972   by (simp add: collinear_def)
```
```  2973
```
```  2974 lemma collinear_sing [iff]: "collinear {x}"
```
```  2975   by (simp add: collinear_def)
```
```  2976
```
```  2977 lemma collinear_2 [iff]: "collinear {x, y}"
```
```  2978   apply (simp add: collinear_def)
```
```  2979   apply (rule exI[where x="x - y"])
```
```  2980   by (metis minus_diff_eq scaleR_left.minus scaleR_one)
```
```  2981
```
```  2982 lemma collinear_lemma: "collinear {0, x, y} \<longleftrightarrow> x = 0 \<or> y = 0 \<or> (\<exists>c. y = c *\<^sub>R x)"
```
```  2983   (is "?lhs \<longleftrightarrow> ?rhs")
```
```  2984 proof (cases "x = 0 \<or> y = 0")
```
```  2985   case True
```
```  2986   then show ?thesis
```
```  2987     by (auto simp: insert_commute)
```
```  2988 next
```
```  2989   case False
```
```  2990   show ?thesis
```
```  2991   proof
```
```  2992     assume h: "?lhs"
```
```  2993     then obtain u where u: "\<forall> x\<in> {0,x,y}. \<forall>y\<in> {0,x,y}. \<exists>c. x - y = c *\<^sub>R u"
```
```  2994       unfolding collinear_def by blast
```
```  2995     from u[rule_format, of x 0] u[rule_format, of y 0]
```
```  2996     obtain cx and cy where
```
```  2997       cx: "x = cx *\<^sub>R u" and cy: "y = cy *\<^sub>R u"
```
```  2998       by auto
```
```  2999     from cx cy False have cx0: "cx \<noteq> 0" and cy0: "cy \<noteq> 0" by auto
```
```  3000     let ?d = "cy / cx"
```
```  3001     from cx cy cx0 have "y = ?d *\<^sub>R x"
```
```  3002       by simp
```
```  3003     then show ?rhs using False by blast
```
```  3004   next
```
```  3005     assume h: "?rhs"
```
```  3006     then obtain c where c: "y = c *\<^sub>R x"
```
```  3007       using False by blast
```
```  3008     show ?lhs
```
```  3009       unfolding collinear_def c
```
```  3010       apply (rule exI[where x=x])
```
```  3011       apply auto
```
```  3012           apply (rule exI[where x="- 1"], simp)
```
```  3013          apply (rule exI[where x= "-c"], simp)
```
```  3014         apply (rule exI[where x=1], simp)
```
```  3015        apply (rule exI[where x="1 - c"], simp add: scaleR_left_diff_distrib)
```
```  3016       apply (rule exI[where x="c - 1"], simp add: scaleR_left_diff_distrib)
```
```  3017       done
```
```  3018   qed
```
```  3019 qed
```
```  3020
```
```  3021 lemma norm_cauchy_schwarz_equal: "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow> collinear {0, x, y}"
```
```  3022 proof (cases "x=0")
```
```  3023   case True
```
```  3024   then show ?thesis
```
```  3025     by (auto simp: insert_commute)
```
```  3026 next
```
```  3027   case False
```
```  3028   then have nnz: "norm x \<noteq> 0"
```
```  3029     by auto
```
```  3030   show ?thesis
```
```  3031   proof
```
```  3032     assume "\<bar>x \<bullet> y\<bar> = norm x * norm y"
```
```  3033     then show "collinear {0, x, y}"
```
```  3034       unfolding norm_cauchy_schwarz_abs_eq collinear_lemma
```
```  3035       by (meson eq_vector_fraction_iff nnz)
```
```  3036   next
```
```  3037     assume "collinear {0, x, y}"
```
```  3038     with False show "\<bar>x \<bullet> y\<bar> = norm x * norm y"
```
```  3039       unfolding norm_cauchy_schwarz_abs_eq collinear_lemma  by (auto simp: abs_if)
```
```  3040   qed
```
```  3041 qed
```
```  3042
```
```  3043 end
```