src/HOL/Rat.thy
author kuncar
Mon May 21 16:37:28 2012 +0200 (2012-05-21)
changeset 47952 36a8c477dae8
parent 47907 54e3847f1669
child 48891 c0eafbd55de3
permissions -rw-r--r--
use quot_del instead of ML code in Rat.thy
     1 (*  Title:  HOL/Rat.thy
     2     Author: Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 header {* Rational numbers *}
     6 
     7 theory Rat
     8 imports GCD Archimedean_Field
     9 uses ("Tools/float_syntax.ML")
    10 begin
    11 
    12 subsection {* Rational numbers as quotient *}
    13 
    14 subsubsection {* Construction of the type of rational numbers *}
    15 
    16 definition
    17   ratrel :: "(int \<times> int) \<Rightarrow> (int \<times> int) \<Rightarrow> bool" where
    18   "ratrel = (\<lambda>x y. snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x)"
    19 
    20 lemma ratrel_iff [simp]:
    21   "ratrel x y \<longleftrightarrow> snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x"
    22   by (simp add: ratrel_def)
    23 
    24 lemma exists_ratrel_refl: "\<exists>x. ratrel x x"
    25   by (auto intro!: one_neq_zero)
    26 
    27 lemma symp_ratrel: "symp ratrel"
    28   by (simp add: ratrel_def symp_def)
    29 
    30 lemma transp_ratrel: "transp ratrel"
    31 proof (rule transpI, unfold split_paired_all)
    32   fix a b a' b' a'' b'' :: int
    33   assume A: "ratrel (a, b) (a', b')"
    34   assume B: "ratrel (a', b') (a'', b'')"
    35   have "b' * (a * b'') = b'' * (a * b')" by simp
    36   also from A have "a * b' = a' * b" by auto
    37   also have "b'' * (a' * b) = b * (a' * b'')" by simp
    38   also from B have "a' * b'' = a'' * b'" by auto
    39   also have "b * (a'' * b') = b' * (a'' * b)" by simp
    40   finally have "b' * (a * b'') = b' * (a'' * b)" .
    41   moreover from B have "b' \<noteq> 0" by auto
    42   ultimately have "a * b'' = a'' * b" by simp
    43   with A B show "ratrel (a, b) (a'', b'')" by auto
    44 qed
    45 
    46 lemma part_equivp_ratrel: "part_equivp ratrel"
    47   by (rule part_equivpI [OF exists_ratrel_refl symp_ratrel transp_ratrel])
    48 
    49 quotient_type rat = "int \<times> int" / partial: "ratrel"
    50   morphisms Rep_Rat Abs_Rat
    51   by (rule part_equivp_ratrel)
    52 
    53 declare rat.forall_transfer [transfer_rule del]
    54 
    55 lemma forall_rat_transfer [transfer_rule]: (* TODO: generate automatically *)
    56   "(fun_rel (fun_rel cr_rat op =) op =)
    57     (transfer_bforall (\<lambda>x. snd x \<noteq> 0)) transfer_forall"
    58   using rat.forall_transfer by simp
    59 
    60 
    61 subsubsection {* Representation and basic operations *}
    62 
    63 lift_definition Fract :: "int \<Rightarrow> int \<Rightarrow> rat"
    64   is "\<lambda>a b. if b = 0 then (0, 1) else (a, b)"
    65   by simp
    66 
    67 lemma eq_rat:
    68   shows "\<And>a b c d. b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b = Fract c d \<longleftrightarrow> a * d = c * b"
    69   and "\<And>a. Fract a 0 = Fract 0 1"
    70   and "\<And>a c. Fract 0 a = Fract 0 c"
    71   by (transfer, simp)+
    72 
    73 lemma Rat_cases [case_names Fract, cases type: rat]:
    74   assumes "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
    75   shows C
    76 proof -
    77   obtain a b :: int where "q = Fract a b" and "b \<noteq> 0"
    78     by transfer simp
    79   let ?a = "a div gcd a b"
    80   let ?b = "b div gcd a b"
    81   from `b \<noteq> 0` have "?b * gcd a b = b"
    82     by (simp add: dvd_div_mult_self)
    83   with `b \<noteq> 0` have "?b \<noteq> 0" by auto
    84   from `q = Fract a b` `b \<noteq> 0` `?b \<noteq> 0` have q: "q = Fract ?a ?b"
    85     by (simp add: eq_rat dvd_div_mult mult_commute [of a])
    86   from `b \<noteq> 0` have coprime: "coprime ?a ?b"
    87     by (auto intro: div_gcd_coprime_int)
    88   show C proof (cases "b > 0")
    89     case True
    90     note assms
    91     moreover note q
    92     moreover from True have "?b > 0" by (simp add: nonneg1_imp_zdiv_pos_iff)
    93     moreover note coprime
    94     ultimately show C .
    95   next
    96     case False
    97     note assms
    98     moreover have "q = Fract (- ?a) (- ?b)" unfolding q by transfer simp
    99     moreover from False `b \<noteq> 0` have "- ?b > 0" by (simp add: pos_imp_zdiv_neg_iff)
   100     moreover from coprime have "coprime (- ?a) (- ?b)" by simp
   101     ultimately show C .
   102   qed
   103 qed
   104 
   105 lemma Rat_induct [case_names Fract, induct type: rat]:
   106   assumes "\<And>a b. b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> P (Fract a b)"
   107   shows "P q"
   108   using assms by (cases q) simp
   109 
   110 instantiation rat :: field_inverse_zero
   111 begin
   112 
   113 lift_definition zero_rat :: "rat" is "(0, 1)"
   114   by simp
   115 
   116 lift_definition one_rat :: "rat" is "(1, 1)"
   117   by simp
   118 
   119 lemma Zero_rat_def: "0 = Fract 0 1"
   120   by transfer simp
   121 
   122 lemma One_rat_def: "1 = Fract 1 1"
   123   by transfer simp
   124 
   125 lift_definition plus_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   126   is "\<lambda>x y. (fst x * snd y + fst y * snd x, snd x * snd y)"
   127   by (clarsimp, simp add: left_distrib, simp add: mult_ac)
   128 
   129 lemma add_rat [simp]:
   130   assumes "b \<noteq> 0" and "d \<noteq> 0"
   131   shows "Fract a b + Fract c d = Fract (a * d + c * b) (b * d)"
   132   using assms by transfer simp
   133 
   134 lift_definition uminus_rat :: "rat \<Rightarrow> rat" is "\<lambda>x. (- fst x, snd x)"
   135   by simp
   136 
   137 lemma minus_rat [simp]: "- Fract a b = Fract (- a) b"
   138   by transfer simp
   139 
   140 lemma minus_rat_cancel [simp]: "Fract (- a) (- b) = Fract a b"
   141   by (cases "b = 0") (simp_all add: eq_rat)
   142 
   143 definition
   144   diff_rat_def: "q - r = q + - (r::rat)"
   145 
   146 lemma diff_rat [simp]:
   147   assumes "b \<noteq> 0" and "d \<noteq> 0"
   148   shows "Fract a b - Fract c d = Fract (a * d - c * b) (b * d)"
   149   using assms by (simp add: diff_rat_def)
   150 
   151 lift_definition times_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   152   is "\<lambda>x y. (fst x * fst y, snd x * snd y)"
   153   by (simp add: mult_ac)
   154 
   155 lemma mult_rat [simp]: "Fract a b * Fract c d = Fract (a * c) (b * d)"
   156   by transfer simp
   157 
   158 lemma mult_rat_cancel:
   159   assumes "c \<noteq> 0"
   160   shows "Fract (c * a) (c * b) = Fract a b"
   161   using assms by transfer simp
   162 
   163 lift_definition inverse_rat :: "rat \<Rightarrow> rat"
   164   is "\<lambda>x. if fst x = 0 then (0, 1) else (snd x, fst x)"
   165   by (auto simp add: mult_commute)
   166 
   167 lemma inverse_rat [simp]: "inverse (Fract a b) = Fract b a"
   168   by transfer simp
   169 
   170 definition
   171   divide_rat_def: "q / r = q * inverse (r::rat)"
   172 
   173 lemma divide_rat [simp]: "Fract a b / Fract c d = Fract (a * d) (b * c)"
   174   by (simp add: divide_rat_def)
   175 
   176 instance proof
   177   fix q r s :: rat
   178   show "(q * r) * s = q * (r * s)"
   179     by transfer simp
   180   show "q * r = r * q"
   181     by transfer simp
   182   show "1 * q = q"
   183     by transfer simp
   184   show "(q + r) + s = q + (r + s)"
   185     by transfer (simp add: algebra_simps)
   186   show "q + r = r + q"
   187     by transfer simp
   188   show "0 + q = q"
   189     by transfer simp
   190   show "- q + q = 0"
   191     by transfer simp
   192   show "q - r = q + - r"
   193     by (fact diff_rat_def)
   194   show "(q + r) * s = q * s + r * s"
   195     by transfer (simp add: algebra_simps)
   196   show "(0::rat) \<noteq> 1"
   197     by transfer simp
   198   { assume "q \<noteq> 0" thus "inverse q * q = 1"
   199     by transfer simp }
   200   show "q / r = q * inverse r"
   201     by (fact divide_rat_def)
   202   show "inverse 0 = (0::rat)"
   203     by transfer simp
   204 qed
   205 
   206 end
   207 
   208 lemma of_nat_rat: "of_nat k = Fract (of_nat k) 1"
   209   by (induct k) (simp_all add: Zero_rat_def One_rat_def)
   210 
   211 lemma of_int_rat: "of_int k = Fract k 1"
   212   by (cases k rule: int_diff_cases) (simp add: of_nat_rat)
   213 
   214 lemma Fract_of_nat_eq: "Fract (of_nat k) 1 = of_nat k"
   215   by (rule of_nat_rat [symmetric])
   216 
   217 lemma Fract_of_int_eq: "Fract k 1 = of_int k"
   218   by (rule of_int_rat [symmetric])
   219 
   220 lemma rat_number_collapse:
   221   "Fract 0 k = 0"
   222   "Fract 1 1 = 1"
   223   "Fract (numeral w) 1 = numeral w"
   224   "Fract (neg_numeral w) 1 = neg_numeral w"
   225   "Fract k 0 = 0"
   226   using Fract_of_int_eq [of "numeral w"]
   227   using Fract_of_int_eq [of "neg_numeral w"]
   228   by (simp_all add: Zero_rat_def One_rat_def eq_rat)
   229 
   230 lemma rat_number_expand:
   231   "0 = Fract 0 1"
   232   "1 = Fract 1 1"
   233   "numeral k = Fract (numeral k) 1"
   234   "neg_numeral k = Fract (neg_numeral k) 1"
   235   by (simp_all add: rat_number_collapse)
   236 
   237 lemma Rat_cases_nonzero [case_names Fract 0]:
   238   assumes Fract: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
   239   assumes 0: "q = 0 \<Longrightarrow> C"
   240   shows C
   241 proof (cases "q = 0")
   242   case True then show C using 0 by auto
   243 next
   244   case False
   245   then obtain a b where "q = Fract a b" and "b > 0" and "coprime a b" by (cases q) auto
   246   moreover with False have "0 \<noteq> Fract a b" by simp
   247   with `b > 0` have "a \<noteq> 0" by (simp add: Zero_rat_def eq_rat)
   248   with Fract `q = Fract a b` `b > 0` `coprime a b` show C by blast
   249 qed
   250 
   251 subsubsection {* Function @{text normalize} *}
   252 
   253 lemma Fract_coprime: "Fract (a div gcd a b) (b div gcd a b) = Fract a b"
   254 proof (cases "b = 0")
   255   case True then show ?thesis by (simp add: eq_rat)
   256 next
   257   case False
   258   moreover have "b div gcd a b * gcd a b = b"
   259     by (rule dvd_div_mult_self) simp
   260   ultimately have "b div gcd a b \<noteq> 0" by auto
   261   with False show ?thesis by (simp add: eq_rat dvd_div_mult mult_commute [of a])
   262 qed
   263 
   264 definition normalize :: "int \<times> int \<Rightarrow> int \<times> int" where
   265   "normalize p = (if snd p > 0 then (let a = gcd (fst p) (snd p) in (fst p div a, snd p div a))
   266     else if snd p = 0 then (0, 1)
   267     else (let a = - gcd (fst p) (snd p) in (fst p div a, snd p div a)))"
   268 
   269 lemma normalize_crossproduct:
   270   assumes "q \<noteq> 0" "s \<noteq> 0"
   271   assumes "normalize (p, q) = normalize (r, s)"
   272   shows "p * s = r * q"
   273 proof -
   274   have aux: "p * gcd r s = sgn (q * s) * r * gcd p q \<Longrightarrow> q * gcd r s = sgn (q * s) * s * gcd p q \<Longrightarrow> p * s = q * r"
   275   proof -
   276     assume "p * gcd r s = sgn (q * s) * r * gcd p q" and "q * gcd r s = sgn (q * s) * s * gcd p q"
   277     then have "(p * gcd r s) * (sgn (q * s) * s * gcd p q) = (q * gcd r s) * (sgn (q * s) * r * gcd p q)" by simp
   278     with assms show "p * s = q * r" by (auto simp add: mult_ac sgn_times sgn_0_0)
   279   qed
   280   from assms show ?thesis
   281     by (auto simp add: normalize_def Let_def dvd_div_div_eq_mult mult_commute sgn_times split: if_splits intro: aux)
   282 qed
   283 
   284 lemma normalize_eq: "normalize (a, b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   285   by (auto simp add: normalize_def Let_def Fract_coprime dvd_div_neg rat_number_collapse
   286     split:split_if_asm)
   287 
   288 lemma normalize_denom_pos: "normalize r = (p, q) \<Longrightarrow> q > 0"
   289   by (auto simp add: normalize_def Let_def dvd_div_neg pos_imp_zdiv_neg_iff nonneg1_imp_zdiv_pos_iff
   290     split:split_if_asm)
   291 
   292 lemma normalize_coprime: "normalize r = (p, q) \<Longrightarrow> coprime p q"
   293   by (auto simp add: normalize_def Let_def dvd_div_neg div_gcd_coprime_int
   294     split:split_if_asm)
   295 
   296 lemma normalize_stable [simp]:
   297   "q > 0 \<Longrightarrow> coprime p q \<Longrightarrow> normalize (p, q) = (p, q)"
   298   by (simp add: normalize_def)
   299 
   300 lemma normalize_denom_zero [simp]:
   301   "normalize (p, 0) = (0, 1)"
   302   by (simp add: normalize_def)
   303 
   304 lemma normalize_negative [simp]:
   305   "q < 0 \<Longrightarrow> normalize (p, q) = normalize (- p, - q)"
   306   by (simp add: normalize_def Let_def dvd_div_neg dvd_neg_div)
   307 
   308 text{*
   309   Decompose a fraction into normalized, i.e. coprime numerator and denominator:
   310 *}
   311 
   312 definition quotient_of :: "rat \<Rightarrow> int \<times> int" where
   313   "quotient_of x = (THE pair. x = Fract (fst pair) (snd pair) &
   314                    snd pair > 0 & coprime (fst pair) (snd pair))"
   315 
   316 lemma quotient_of_unique:
   317   "\<exists>!p. r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   318 proof (cases r)
   319   case (Fract a b)
   320   then have "r = Fract (fst (a, b)) (snd (a, b)) \<and> snd (a, b) > 0 \<and> coprime (fst (a, b)) (snd (a, b))" by auto
   321   then show ?thesis proof (rule ex1I)
   322     fix p
   323     obtain c d :: int where p: "p = (c, d)" by (cases p)
   324     assume "r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   325     with p have Fract': "r = Fract c d" "d > 0" "coprime c d" by simp_all
   326     have "c = a \<and> d = b"
   327     proof (cases "a = 0")
   328       case True with Fract Fract' show ?thesis by (simp add: eq_rat)
   329     next
   330       case False
   331       with Fract Fract' have *: "c * b = a * d" and "c \<noteq> 0" by (auto simp add: eq_rat)
   332       then have "c * b > 0 \<longleftrightarrow> a * d > 0" by auto
   333       with `b > 0` `d > 0` have "a > 0 \<longleftrightarrow> c > 0" by (simp add: zero_less_mult_iff)
   334       with `a \<noteq> 0` `c \<noteq> 0` have sgn: "sgn a = sgn c" by (auto simp add: not_less)
   335       from `coprime a b` `coprime c d` have "\<bar>a\<bar> * \<bar>d\<bar> = \<bar>c\<bar> * \<bar>b\<bar> \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> \<bar>d\<bar> = \<bar>b\<bar>"
   336         by (simp add: coprime_crossproduct_int)
   337       with `b > 0` `d > 0` have "\<bar>a\<bar> * d = \<bar>c\<bar> * b \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> d = b" by simp
   338       then have "a * sgn a * d = c * sgn c * b \<longleftrightarrow> a * sgn a = c * sgn c \<and> d = b" by (simp add: abs_sgn)
   339       with sgn * show ?thesis by (auto simp add: sgn_0_0)
   340     qed
   341     with p show "p = (a, b)" by simp
   342   qed
   343 qed
   344 
   345 lemma quotient_of_Fract [code]:
   346   "quotient_of (Fract a b) = normalize (a, b)"
   347 proof -
   348   have "Fract a b = Fract (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?Fract)
   349     by (rule sym) (auto intro: normalize_eq)
   350   moreover have "0 < snd (normalize (a, b))" (is ?denom_pos) 
   351     by (cases "normalize (a, b)") (rule normalize_denom_pos, simp)
   352   moreover have "coprime (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?coprime)
   353     by (rule normalize_coprime) simp
   354   ultimately have "?Fract \<and> ?denom_pos \<and> ?coprime" by blast
   355   with quotient_of_unique have
   356     "(THE p. Fract a b = Fract (fst p) (snd p) \<and> 0 < snd p \<and> coprime (fst p) (snd p)) = normalize (a, b)"
   357     by (rule the1_equality)
   358   then show ?thesis by (simp add: quotient_of_def)
   359 qed
   360 
   361 lemma quotient_of_number [simp]:
   362   "quotient_of 0 = (0, 1)"
   363   "quotient_of 1 = (1, 1)"
   364   "quotient_of (numeral k) = (numeral k, 1)"
   365   "quotient_of (neg_numeral k) = (neg_numeral k, 1)"
   366   by (simp_all add: rat_number_expand quotient_of_Fract)
   367 
   368 lemma quotient_of_eq: "quotient_of (Fract a b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   369   by (simp add: quotient_of_Fract normalize_eq)
   370 
   371 lemma quotient_of_denom_pos: "quotient_of r = (p, q) \<Longrightarrow> q > 0"
   372   by (cases r) (simp add: quotient_of_Fract normalize_denom_pos)
   373 
   374 lemma quotient_of_coprime: "quotient_of r = (p, q) \<Longrightarrow> coprime p q"
   375   by (cases r) (simp add: quotient_of_Fract normalize_coprime)
   376 
   377 lemma quotient_of_inject:
   378   assumes "quotient_of a = quotient_of b"
   379   shows "a = b"
   380 proof -
   381   obtain p q r s where a: "a = Fract p q"
   382     and b: "b = Fract r s"
   383     and "q > 0" and "s > 0" by (cases a, cases b)
   384   with assms show ?thesis by (simp add: eq_rat quotient_of_Fract normalize_crossproduct)
   385 qed
   386 
   387 lemma quotient_of_inject_eq:
   388   "quotient_of a = quotient_of b \<longleftrightarrow> a = b"
   389   by (auto simp add: quotient_of_inject)
   390 
   391 
   392 subsubsection {* Various *}
   393 
   394 lemma Fract_of_int_quotient: "Fract k l = of_int k / of_int l"
   395   by (simp add: Fract_of_int_eq [symmetric])
   396 
   397 lemma Fract_add_one: "n \<noteq> 0 ==> Fract (m + n) n = Fract m n + 1"
   398   by (simp add: rat_number_expand)
   399 
   400 
   401 subsubsection {* The ordered field of rational numbers *}
   402 
   403 lift_definition positive :: "rat \<Rightarrow> bool"
   404   is "\<lambda>x. 0 < fst x * snd x"
   405 proof (clarsimp)
   406   fix a b c d :: int
   407   assume "b \<noteq> 0" and "d \<noteq> 0" and "a * d = c * b"
   408   hence "a * d * b * d = c * b * b * d"
   409     by simp
   410   hence "a * b * d\<twosuperior> = c * d * b\<twosuperior>"
   411     unfolding power2_eq_square by (simp add: mult_ac)
   412   hence "0 < a * b * d\<twosuperior> \<longleftrightarrow> 0 < c * d * b\<twosuperior>"
   413     by simp
   414   thus "0 < a * b \<longleftrightarrow> 0 < c * d"
   415     using `b \<noteq> 0` and `d \<noteq> 0`
   416     by (simp add: zero_less_mult_iff)
   417 qed
   418 
   419 lemma positive_zero: "\<not> positive 0"
   420   by transfer simp
   421 
   422 lemma positive_add:
   423   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   424 apply transfer
   425 apply (simp add: zero_less_mult_iff)
   426 apply (elim disjE, simp_all add: add_pos_pos add_neg_neg
   427   mult_pos_pos mult_pos_neg mult_neg_pos mult_neg_neg)
   428 done
   429 
   430 lemma positive_mult:
   431   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   432 by transfer (drule (1) mult_pos_pos, simp add: mult_ac)
   433 
   434 lemma positive_minus:
   435   "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   436 by transfer (force simp: neq_iff zero_less_mult_iff mult_less_0_iff)
   437 
   438 instantiation rat :: linordered_field_inverse_zero
   439 begin
   440 
   441 definition
   442   "x < y \<longleftrightarrow> positive (y - x)"
   443 
   444 definition
   445   "x \<le> (y::rat) \<longleftrightarrow> x < y \<or> x = y"
   446 
   447 definition
   448   "abs (a::rat) = (if a < 0 then - a else a)"
   449 
   450 definition
   451   "sgn (a::rat) = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   452 
   453 instance proof
   454   fix a b c :: rat
   455   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   456     by (rule abs_rat_def)
   457   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   458     unfolding less_eq_rat_def less_rat_def
   459     by (auto, drule (1) positive_add, simp_all add: positive_zero)
   460   show "a \<le> a"
   461     unfolding less_eq_rat_def by simp
   462   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   463     unfolding less_eq_rat_def less_rat_def
   464     by (auto, drule (1) positive_add, simp add: algebra_simps)
   465   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   466     unfolding less_eq_rat_def less_rat_def
   467     by (auto, drule (1) positive_add, simp add: positive_zero)
   468   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   469     unfolding less_eq_rat_def less_rat_def by (auto simp: diff_minus)
   470   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   471     by (rule sgn_rat_def)
   472   show "a \<le> b \<or> b \<le> a"
   473     unfolding less_eq_rat_def less_rat_def
   474     by (auto dest!: positive_minus)
   475   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   476     unfolding less_rat_def
   477     by (drule (1) positive_mult, simp add: algebra_simps)
   478 qed
   479 
   480 end
   481 
   482 instantiation rat :: distrib_lattice
   483 begin
   484 
   485 definition
   486   "(inf :: rat \<Rightarrow> rat \<Rightarrow> rat) = min"
   487 
   488 definition
   489   "(sup :: rat \<Rightarrow> rat \<Rightarrow> rat) = max"
   490 
   491 instance proof
   492 qed (auto simp add: inf_rat_def sup_rat_def min_max.sup_inf_distrib1)
   493 
   494 end
   495 
   496 lemma positive_rat: "positive (Fract a b) \<longleftrightarrow> 0 < a * b"
   497   by transfer simp
   498 
   499 lemma less_rat [simp]:
   500   assumes "b \<noteq> 0" and "d \<noteq> 0"
   501   shows "Fract a b < Fract c d \<longleftrightarrow> (a * d) * (b * d) < (c * b) * (b * d)"
   502   using assms unfolding less_rat_def
   503   by (simp add: positive_rat algebra_simps)
   504 
   505 lemma le_rat [simp]:
   506   assumes "b \<noteq> 0" and "d \<noteq> 0"
   507   shows "Fract a b \<le> Fract c d \<longleftrightarrow> (a * d) * (b * d) \<le> (c * b) * (b * d)"
   508   using assms unfolding le_less by (simp add: eq_rat)
   509 
   510 lemma abs_rat [simp, code]: "\<bar>Fract a b\<bar> = Fract \<bar>a\<bar> \<bar>b\<bar>"
   511   by (auto simp add: abs_rat_def zabs_def Zero_rat_def not_less le_less eq_rat zero_less_mult_iff)
   512 
   513 lemma sgn_rat [simp, code]: "sgn (Fract a b) = of_int (sgn a * sgn b)"
   514   unfolding Fract_of_int_eq
   515   by (auto simp: zsgn_def sgn_rat_def Zero_rat_def eq_rat)
   516     (auto simp: rat_number_collapse not_less le_less zero_less_mult_iff)
   517 
   518 lemma Rat_induct_pos [case_names Fract, induct type: rat]:
   519   assumes step: "\<And>a b. 0 < b \<Longrightarrow> P (Fract a b)"
   520   shows "P q"
   521 proof (cases q)
   522   have step': "\<And>a b. b < 0 \<Longrightarrow> P (Fract a b)"
   523   proof -
   524     fix a::int and b::int
   525     assume b: "b < 0"
   526     hence "0 < -b" by simp
   527     hence "P (Fract (-a) (-b))" by (rule step)
   528     thus "P (Fract a b)" by (simp add: order_less_imp_not_eq [OF b])
   529   qed
   530   case (Fract a b)
   531   thus "P q" by (force simp add: linorder_neq_iff step step')
   532 qed
   533 
   534 lemma zero_less_Fract_iff:
   535   "0 < b \<Longrightarrow> 0 < Fract a b \<longleftrightarrow> 0 < a"
   536   by (simp add: Zero_rat_def zero_less_mult_iff)
   537 
   538 lemma Fract_less_zero_iff:
   539   "0 < b \<Longrightarrow> Fract a b < 0 \<longleftrightarrow> a < 0"
   540   by (simp add: Zero_rat_def mult_less_0_iff)
   541 
   542 lemma zero_le_Fract_iff:
   543   "0 < b \<Longrightarrow> 0 \<le> Fract a b \<longleftrightarrow> 0 \<le> a"
   544   by (simp add: Zero_rat_def zero_le_mult_iff)
   545 
   546 lemma Fract_le_zero_iff:
   547   "0 < b \<Longrightarrow> Fract a b \<le> 0 \<longleftrightarrow> a \<le> 0"
   548   by (simp add: Zero_rat_def mult_le_0_iff)
   549 
   550 lemma one_less_Fract_iff:
   551   "0 < b \<Longrightarrow> 1 < Fract a b \<longleftrightarrow> b < a"
   552   by (simp add: One_rat_def mult_less_cancel_right_disj)
   553 
   554 lemma Fract_less_one_iff:
   555   "0 < b \<Longrightarrow> Fract a b < 1 \<longleftrightarrow> a < b"
   556   by (simp add: One_rat_def mult_less_cancel_right_disj)
   557 
   558 lemma one_le_Fract_iff:
   559   "0 < b \<Longrightarrow> 1 \<le> Fract a b \<longleftrightarrow> b \<le> a"
   560   by (simp add: One_rat_def mult_le_cancel_right)
   561 
   562 lemma Fract_le_one_iff:
   563   "0 < b \<Longrightarrow> Fract a b \<le> 1 \<longleftrightarrow> a \<le> b"
   564   by (simp add: One_rat_def mult_le_cancel_right)
   565 
   566 
   567 subsubsection {* Rationals are an Archimedean field *}
   568 
   569 lemma rat_floor_lemma:
   570   shows "of_int (a div b) \<le> Fract a b \<and> Fract a b < of_int (a div b + 1)"
   571 proof -
   572   have "Fract a b = of_int (a div b) + Fract (a mod b) b"
   573     by (cases "b = 0", simp, simp add: of_int_rat)
   574   moreover have "0 \<le> Fract (a mod b) b \<and> Fract (a mod b) b < 1"
   575     unfolding Fract_of_int_quotient
   576     by (rule linorder_cases [of b 0]) (simp add: divide_nonpos_neg, simp, simp add: divide_nonneg_pos)
   577   ultimately show ?thesis by simp
   578 qed
   579 
   580 instance rat :: archimedean_field
   581 proof
   582   fix r :: rat
   583   show "\<exists>z. r \<le> of_int z"
   584   proof (induct r)
   585     case (Fract a b)
   586     have "Fract a b \<le> of_int (a div b + 1)"
   587       using rat_floor_lemma [of a b] by simp
   588     then show "\<exists>z. Fract a b \<le> of_int z" ..
   589   qed
   590 qed
   591 
   592 instantiation rat :: floor_ceiling
   593 begin
   594 
   595 definition [code del]:
   596   "floor (x::rat) = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   597 
   598 instance proof
   599   fix x :: rat
   600   show "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   601     unfolding floor_rat_def using floor_exists1 by (rule theI')
   602 qed
   603 
   604 end
   605 
   606 lemma floor_Fract: "floor (Fract a b) = a div b"
   607   using rat_floor_lemma [of a b]
   608   by (simp add: floor_unique)
   609 
   610 
   611 subsection {* Linear arithmetic setup *}
   612 
   613 declaration {*
   614   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
   615     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
   616   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_int_eq_iff} RS iffD2]
   617     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
   618   #> Lin_Arith.add_simps [@{thm neg_less_iff_less},
   619       @{thm True_implies_equals},
   620       read_instantiate @{context} [(("a", 0), "(numeral ?v)")] @{thm right_distrib},
   621       read_instantiate @{context} [(("a", 0), "(neg_numeral ?v)")] @{thm right_distrib},
   622       @{thm divide_1}, @{thm divide_zero_left},
   623       @{thm times_divide_eq_right}, @{thm times_divide_eq_left},
   624       @{thm minus_divide_left} RS sym, @{thm minus_divide_right} RS sym,
   625       @{thm of_int_minus}, @{thm of_int_diff},
   626       @{thm of_int_of_nat_eq}]
   627   #> Lin_Arith.add_simprocs Numeral_Simprocs.field_cancel_numeral_factors
   628   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat => rat"})
   629   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int => rat"}))
   630 *}
   631 
   632 
   633 subsection {* Embedding from Rationals to other Fields *}
   634 
   635 class field_char_0 = field + ring_char_0
   636 
   637 subclass (in linordered_field) field_char_0 ..
   638 
   639 context field_char_0
   640 begin
   641 
   642 lift_definition of_rat :: "rat \<Rightarrow> 'a"
   643   is "\<lambda>x. of_int (fst x) / of_int (snd x)"
   644 apply (clarsimp simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   645 apply (simp only: of_int_mult [symmetric])
   646 done
   647 
   648 end
   649 
   650 lemma of_rat_rat: "b \<noteq> 0 \<Longrightarrow> of_rat (Fract a b) = of_int a / of_int b"
   651   by transfer simp
   652 
   653 lemma of_rat_0 [simp]: "of_rat 0 = 0"
   654   by transfer simp
   655 
   656 lemma of_rat_1 [simp]: "of_rat 1 = 1"
   657   by transfer simp
   658 
   659 lemma of_rat_add: "of_rat (a + b) = of_rat a + of_rat b"
   660   by transfer (simp add: add_frac_eq)
   661 
   662 lemma of_rat_minus: "of_rat (- a) = - of_rat a"
   663   by transfer simp
   664 
   665 lemma of_rat_diff: "of_rat (a - b) = of_rat a - of_rat b"
   666 by (simp only: diff_minus of_rat_add of_rat_minus)
   667 
   668 lemma of_rat_mult: "of_rat (a * b) = of_rat a * of_rat b"
   669 apply transfer
   670 apply (simp add: divide_inverse nonzero_inverse_mult_distrib mult_ac)
   671 done
   672 
   673 lemma nonzero_of_rat_inverse:
   674   "a \<noteq> 0 \<Longrightarrow> of_rat (inverse a) = inverse (of_rat a)"
   675 apply (rule inverse_unique [symmetric])
   676 apply (simp add: of_rat_mult [symmetric])
   677 done
   678 
   679 lemma of_rat_inverse:
   680   "(of_rat (inverse a)::'a::{field_char_0, field_inverse_zero}) =
   681    inverse (of_rat a)"
   682 by (cases "a = 0", simp_all add: nonzero_of_rat_inverse)
   683 
   684 lemma nonzero_of_rat_divide:
   685   "b \<noteq> 0 \<Longrightarrow> of_rat (a / b) = of_rat a / of_rat b"
   686 by (simp add: divide_inverse of_rat_mult nonzero_of_rat_inverse)
   687 
   688 lemma of_rat_divide:
   689   "(of_rat (a / b)::'a::{field_char_0, field_inverse_zero})
   690    = of_rat a / of_rat b"
   691 by (cases "b = 0") (simp_all add: nonzero_of_rat_divide)
   692 
   693 lemma of_rat_power:
   694   "(of_rat (a ^ n)::'a::field_char_0) = of_rat a ^ n"
   695 by (induct n) (simp_all add: of_rat_mult)
   696 
   697 lemma of_rat_eq_iff [simp]: "(of_rat a = of_rat b) = (a = b)"
   698 apply transfer
   699 apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   700 apply (simp only: of_int_mult [symmetric] of_int_eq_iff)
   701 done
   702 
   703 lemma of_rat_less:
   704   "(of_rat r :: 'a::linordered_field) < of_rat s \<longleftrightarrow> r < s"
   705 proof (induct r, induct s)
   706   fix a b c d :: int
   707   assume not_zero: "b > 0" "d > 0"
   708   then have "b * d > 0" by (rule mult_pos_pos)
   709   have of_int_divide_less_eq:
   710     "(of_int a :: 'a) / of_int b < of_int c / of_int d
   711       \<longleftrightarrow> (of_int a :: 'a) * of_int d < of_int c * of_int b"
   712     using not_zero by (simp add: pos_less_divide_eq pos_divide_less_eq)
   713   show "(of_rat (Fract a b) :: 'a::linordered_field) < of_rat (Fract c d)
   714     \<longleftrightarrow> Fract a b < Fract c d"
   715     using not_zero `b * d > 0`
   716     by (simp add: of_rat_rat of_int_divide_less_eq of_int_mult [symmetric] del: of_int_mult)
   717 qed
   718 
   719 lemma of_rat_less_eq:
   720   "(of_rat r :: 'a::linordered_field) \<le> of_rat s \<longleftrightarrow> r \<le> s"
   721   unfolding le_less by (auto simp add: of_rat_less)
   722 
   723 lemmas of_rat_eq_0_iff [simp] = of_rat_eq_iff [of _ 0, simplified]
   724 
   725 lemma of_rat_eq_id [simp]: "of_rat = id"
   726 proof
   727   fix a
   728   show "of_rat a = id a"
   729   by (induct a)
   730      (simp add: of_rat_rat Fract_of_int_eq [symmetric])
   731 qed
   732 
   733 text{*Collapse nested embeddings*}
   734 lemma of_rat_of_nat_eq [simp]: "of_rat (of_nat n) = of_nat n"
   735 by (induct n) (simp_all add: of_rat_add)
   736 
   737 lemma of_rat_of_int_eq [simp]: "of_rat (of_int z) = of_int z"
   738 by (cases z rule: int_diff_cases) (simp add: of_rat_diff)
   739 
   740 lemma of_rat_numeral_eq [simp]:
   741   "of_rat (numeral w) = numeral w"
   742 using of_rat_of_int_eq [of "numeral w"] by simp
   743 
   744 lemma of_rat_neg_numeral_eq [simp]:
   745   "of_rat (neg_numeral w) = neg_numeral w"
   746 using of_rat_of_int_eq [of "neg_numeral w"] by simp
   747 
   748 lemmas zero_rat = Zero_rat_def
   749 lemmas one_rat = One_rat_def
   750 
   751 abbreviation
   752   rat_of_nat :: "nat \<Rightarrow> rat"
   753 where
   754   "rat_of_nat \<equiv> of_nat"
   755 
   756 abbreviation
   757   rat_of_int :: "int \<Rightarrow> rat"
   758 where
   759   "rat_of_int \<equiv> of_int"
   760 
   761 subsection {* The Set of Rational Numbers *}
   762 
   763 context field_char_0
   764 begin
   765 
   766 definition
   767   Rats  :: "'a set" where
   768   "Rats = range of_rat"
   769 
   770 notation (xsymbols)
   771   Rats  ("\<rat>")
   772 
   773 end
   774 
   775 lemma Rats_of_rat [simp]: "of_rat r \<in> Rats"
   776 by (simp add: Rats_def)
   777 
   778 lemma Rats_of_int [simp]: "of_int z \<in> Rats"
   779 by (subst of_rat_of_int_eq [symmetric], rule Rats_of_rat)
   780 
   781 lemma Rats_of_nat [simp]: "of_nat n \<in> Rats"
   782 by (subst of_rat_of_nat_eq [symmetric], rule Rats_of_rat)
   783 
   784 lemma Rats_number_of [simp]: "numeral w \<in> Rats"
   785 by (subst of_rat_numeral_eq [symmetric], rule Rats_of_rat)
   786 
   787 lemma Rats_neg_number_of [simp]: "neg_numeral w \<in> Rats"
   788 by (subst of_rat_neg_numeral_eq [symmetric], rule Rats_of_rat)
   789 
   790 lemma Rats_0 [simp]: "0 \<in> Rats"
   791 apply (unfold Rats_def)
   792 apply (rule range_eqI)
   793 apply (rule of_rat_0 [symmetric])
   794 done
   795 
   796 lemma Rats_1 [simp]: "1 \<in> Rats"
   797 apply (unfold Rats_def)
   798 apply (rule range_eqI)
   799 apply (rule of_rat_1 [symmetric])
   800 done
   801 
   802 lemma Rats_add [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a + b \<in> Rats"
   803 apply (auto simp add: Rats_def)
   804 apply (rule range_eqI)
   805 apply (rule of_rat_add [symmetric])
   806 done
   807 
   808 lemma Rats_minus [simp]: "a \<in> Rats \<Longrightarrow> - a \<in> Rats"
   809 apply (auto simp add: Rats_def)
   810 apply (rule range_eqI)
   811 apply (rule of_rat_minus [symmetric])
   812 done
   813 
   814 lemma Rats_diff [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a - b \<in> Rats"
   815 apply (auto simp add: Rats_def)
   816 apply (rule range_eqI)
   817 apply (rule of_rat_diff [symmetric])
   818 done
   819 
   820 lemma Rats_mult [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a * b \<in> Rats"
   821 apply (auto simp add: Rats_def)
   822 apply (rule range_eqI)
   823 apply (rule of_rat_mult [symmetric])
   824 done
   825 
   826 lemma nonzero_Rats_inverse:
   827   fixes a :: "'a::field_char_0"
   828   shows "\<lbrakk>a \<in> Rats; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Rats"
   829 apply (auto simp add: Rats_def)
   830 apply (rule range_eqI)
   831 apply (erule nonzero_of_rat_inverse [symmetric])
   832 done
   833 
   834 lemma Rats_inverse [simp]:
   835   fixes a :: "'a::{field_char_0, field_inverse_zero}"
   836   shows "a \<in> Rats \<Longrightarrow> inverse a \<in> Rats"
   837 apply (auto simp add: Rats_def)
   838 apply (rule range_eqI)
   839 apply (rule of_rat_inverse [symmetric])
   840 done
   841 
   842 lemma nonzero_Rats_divide:
   843   fixes a b :: "'a::field_char_0"
   844   shows "\<lbrakk>a \<in> Rats; b \<in> Rats; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   845 apply (auto simp add: Rats_def)
   846 apply (rule range_eqI)
   847 apply (erule nonzero_of_rat_divide [symmetric])
   848 done
   849 
   850 lemma Rats_divide [simp]:
   851   fixes a b :: "'a::{field_char_0, field_inverse_zero}"
   852   shows "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   853 apply (auto simp add: Rats_def)
   854 apply (rule range_eqI)
   855 apply (rule of_rat_divide [symmetric])
   856 done
   857 
   858 lemma Rats_power [simp]:
   859   fixes a :: "'a::field_char_0"
   860   shows "a \<in> Rats \<Longrightarrow> a ^ n \<in> Rats"
   861 apply (auto simp add: Rats_def)
   862 apply (rule range_eqI)
   863 apply (rule of_rat_power [symmetric])
   864 done
   865 
   866 lemma Rats_cases [cases set: Rats]:
   867   assumes "q \<in> \<rat>"
   868   obtains (of_rat) r where "q = of_rat r"
   869 proof -
   870   from `q \<in> \<rat>` have "q \<in> range of_rat" unfolding Rats_def .
   871   then obtain r where "q = of_rat r" ..
   872   then show thesis ..
   873 qed
   874 
   875 lemma Rats_induct [case_names of_rat, induct set: Rats]:
   876   "q \<in> \<rat> \<Longrightarrow> (\<And>r. P (of_rat r)) \<Longrightarrow> P q"
   877   by (rule Rats_cases) auto
   878 
   879 
   880 subsection {* Implementation of rational numbers as pairs of integers *}
   881 
   882 text {* Formal constructor *}
   883 
   884 definition Frct :: "int \<times> int \<Rightarrow> rat" where
   885   [simp]: "Frct p = Fract (fst p) (snd p)"
   886 
   887 lemma [code abstype]:
   888   "Frct (quotient_of q) = q"
   889   by (cases q) (auto intro: quotient_of_eq)
   890 
   891 
   892 text {* Numerals *}
   893 
   894 declare quotient_of_Fract [code abstract]
   895 
   896 definition of_int :: "int \<Rightarrow> rat"
   897 where
   898   [code_abbrev]: "of_int = Int.of_int"
   899 hide_const (open) of_int
   900 
   901 lemma quotient_of_int [code abstract]:
   902   "quotient_of (Rat.of_int a) = (a, 1)"
   903   by (simp add: of_int_def of_int_rat quotient_of_Fract)
   904 
   905 lemma [code_unfold]:
   906   "numeral k = Rat.of_int (numeral k)"
   907   by (simp add: Rat.of_int_def)
   908 
   909 lemma [code_unfold]:
   910   "neg_numeral k = Rat.of_int (neg_numeral k)"
   911   by (simp add: Rat.of_int_def)
   912 
   913 lemma Frct_code_post [code_post]:
   914   "Frct (0, a) = 0"
   915   "Frct (a, 0) = 0"
   916   "Frct (1, 1) = 1"
   917   "Frct (numeral k, 1) = numeral k"
   918   "Frct (neg_numeral k, 1) = neg_numeral k"
   919   "Frct (1, numeral k) = 1 / numeral k"
   920   "Frct (1, neg_numeral k) = 1 / neg_numeral k"
   921   "Frct (numeral k, numeral l) = numeral k / numeral l"
   922   "Frct (numeral k, neg_numeral l) = numeral k / neg_numeral l"
   923   "Frct (neg_numeral k, numeral l) = neg_numeral k / numeral l"
   924   "Frct (neg_numeral k, neg_numeral l) = neg_numeral k / neg_numeral l"
   925   by (simp_all add: Fract_of_int_quotient)
   926 
   927 
   928 text {* Operations *}
   929 
   930 lemma rat_zero_code [code abstract]:
   931   "quotient_of 0 = (0, 1)"
   932   by (simp add: Zero_rat_def quotient_of_Fract normalize_def)
   933 
   934 lemma rat_one_code [code abstract]:
   935   "quotient_of 1 = (1, 1)"
   936   by (simp add: One_rat_def quotient_of_Fract normalize_def)
   937 
   938 lemma rat_plus_code [code abstract]:
   939   "quotient_of (p + q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   940      in normalize (a * d + b * c, c * d))"
   941   by (cases p, cases q) (simp add: quotient_of_Fract)
   942 
   943 lemma rat_uminus_code [code abstract]:
   944   "quotient_of (- p) = (let (a, b) = quotient_of p in (- a, b))"
   945   by (cases p) (simp add: quotient_of_Fract)
   946 
   947 lemma rat_minus_code [code abstract]:
   948   "quotient_of (p - q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   949      in normalize (a * d - b * c, c * d))"
   950   by (cases p, cases q) (simp add: quotient_of_Fract)
   951 
   952 lemma rat_times_code [code abstract]:
   953   "quotient_of (p * q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   954      in normalize (a * b, c * d))"
   955   by (cases p, cases q) (simp add: quotient_of_Fract)
   956 
   957 lemma rat_inverse_code [code abstract]:
   958   "quotient_of (inverse p) = (let (a, b) = quotient_of p
   959     in if a = 0 then (0, 1) else (sgn a * b, \<bar>a\<bar>))"
   960 proof (cases p)
   961   case (Fract a b) then show ?thesis
   962     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract gcd_int.commute)
   963 qed
   964 
   965 lemma rat_divide_code [code abstract]:
   966   "quotient_of (p / q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   967      in normalize (a * d, c * b))"
   968   by (cases p, cases q) (simp add: quotient_of_Fract)
   969 
   970 lemma rat_abs_code [code abstract]:
   971   "quotient_of \<bar>p\<bar> = (let (a, b) = quotient_of p in (\<bar>a\<bar>, b))"
   972   by (cases p) (simp add: quotient_of_Fract)
   973 
   974 lemma rat_sgn_code [code abstract]:
   975   "quotient_of (sgn p) = (sgn (fst (quotient_of p)), 1)"
   976 proof (cases p)
   977   case (Fract a b) then show ?thesis
   978   by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract)
   979 qed
   980 
   981 lemma rat_floor_code [code]:
   982   "floor p = (let (a, b) = quotient_of p in a div b)"
   983 by (cases p) (simp add: quotient_of_Fract floor_Fract)
   984 
   985 instantiation rat :: equal
   986 begin
   987 
   988 definition [code]:
   989   "HOL.equal a b \<longleftrightarrow> quotient_of a = quotient_of b"
   990 
   991 instance proof
   992 qed (simp add: equal_rat_def quotient_of_inject_eq)
   993 
   994 lemma rat_eq_refl [code nbe]:
   995   "HOL.equal (r::rat) r \<longleftrightarrow> True"
   996   by (rule equal_refl)
   997 
   998 end
   999 
  1000 lemma rat_less_eq_code [code]:
  1001   "p \<le> q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d \<le> c * b)"
  1002   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1003 
  1004 lemma rat_less_code [code]:
  1005   "p < q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d < c * b)"
  1006   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1007 
  1008 lemma [code]:
  1009   "of_rat p = (let (a, b) = quotient_of p in of_int a / of_int b)"
  1010   by (cases p) (simp add: quotient_of_Fract of_rat_rat)
  1011 
  1012 
  1013 text {* Quickcheck *}
  1014 
  1015 definition (in term_syntax)
  1016   valterm_fract :: "int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> rat \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  1017   [code_unfold]: "valterm_fract k l = Code_Evaluation.valtermify Fract {\<cdot>} k {\<cdot>} l"
  1018 
  1019 notation fcomp (infixl "\<circ>>" 60)
  1020 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1021 
  1022 instantiation rat :: random
  1023 begin
  1024 
  1025 definition
  1026   "Quickcheck.random i = Quickcheck.random i \<circ>\<rightarrow> (\<lambda>num. Random.range i \<circ>\<rightarrow> (\<lambda>denom. Pair (
  1027      let j = Code_Numeral.int_of (denom + 1)
  1028      in valterm_fract num (j, \<lambda>u. Code_Evaluation.term_of j))))"
  1029 
  1030 instance ..
  1031 
  1032 end
  1033 
  1034 no_notation fcomp (infixl "\<circ>>" 60)
  1035 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1036 
  1037 instantiation rat :: exhaustive
  1038 begin
  1039 
  1040 definition
  1041   "exhaustive_rat f d = Quickcheck_Exhaustive.exhaustive (%l. Quickcheck_Exhaustive.exhaustive (%k. f (Fract k (Code_Numeral.int_of l + 1))) d) d"
  1042 
  1043 instance ..
  1044 
  1045 end
  1046 
  1047 instantiation rat :: full_exhaustive
  1048 begin
  1049 
  1050 definition
  1051   "full_exhaustive_rat f d = Quickcheck_Exhaustive.full_exhaustive (%(l, _). Quickcheck_Exhaustive.full_exhaustive (%k.
  1052      f (let j = Code_Numeral.int_of l + 1
  1053         in valterm_fract k (j, %_. Code_Evaluation.term_of j))) d) d"
  1054 
  1055 instance ..
  1056 
  1057 end
  1058 
  1059 instantiation rat :: partial_term_of
  1060 begin
  1061 
  1062 instance ..
  1063 
  1064 end
  1065 
  1066 lemma [code]:
  1067   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_variable p tt) == Code_Evaluation.Free (STR ''_'') (Typerep.Typerep (STR ''Rat.rat'') [])"
  1068   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_constructor 0 [l, k]) ==
  1069      Code_Evaluation.App (Code_Evaluation.Const (STR ''Rat.Frct'')
  1070      (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []],
  1071         Typerep.Typerep (STR ''Rat.rat'') []])) (Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.Const (STR ''Product_Type.Pair'') (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []]]])) (partial_term_of (TYPE(int)) l)) (partial_term_of (TYPE(int)) k))"
  1072 by (rule partial_term_of_anything)+
  1073 
  1074 instantiation rat :: narrowing
  1075 begin
  1076 
  1077 definition
  1078   "narrowing = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.apply
  1079     (Quickcheck_Narrowing.cons (%nom denom. Fract nom denom)) narrowing) narrowing"
  1080 
  1081 instance ..
  1082 
  1083 end
  1084 
  1085 
  1086 subsection {* Setup for Nitpick *}
  1087 
  1088 declaration {*
  1089   Nitpick_HOL.register_frac_type @{type_name rat}
  1090    [(@{const_name zero_rat_inst.zero_rat}, @{const_name Nitpick.zero_frac}),
  1091     (@{const_name one_rat_inst.one_rat}, @{const_name Nitpick.one_frac}),
  1092     (@{const_name plus_rat_inst.plus_rat}, @{const_name Nitpick.plus_frac}),
  1093     (@{const_name times_rat_inst.times_rat}, @{const_name Nitpick.times_frac}),
  1094     (@{const_name uminus_rat_inst.uminus_rat}, @{const_name Nitpick.uminus_frac}),
  1095     (@{const_name inverse_rat_inst.inverse_rat}, @{const_name Nitpick.inverse_frac}),
  1096     (@{const_name ord_rat_inst.less_rat}, @{const_name Nitpick.less_frac}),
  1097     (@{const_name ord_rat_inst.less_eq_rat}, @{const_name Nitpick.less_eq_frac}),
  1098     (@{const_name field_char_0_class.of_rat}, @{const_name Nitpick.of_frac})]
  1099 *}
  1100 
  1101 lemmas [nitpick_unfold] = inverse_rat_inst.inverse_rat
  1102   one_rat_inst.one_rat ord_rat_inst.less_rat
  1103   ord_rat_inst.less_eq_rat plus_rat_inst.plus_rat times_rat_inst.times_rat
  1104   uminus_rat_inst.uminus_rat zero_rat_inst.zero_rat
  1105 
  1106 subsection{* Float syntax *}
  1107 
  1108 syntax "_Float" :: "float_const \<Rightarrow> 'a"    ("_")
  1109 
  1110 use "Tools/float_syntax.ML"
  1111 setup Float_Syntax.setup
  1112 
  1113 text{* Test: *}
  1114 lemma "123.456 = -111.111 + 200 + 30 + 4 + 5/10 + 6/100 + (7/1000::rat)"
  1115 by simp
  1116 
  1117 
  1118 hide_const (open) normalize positive
  1119 
  1120 lemmas [transfer_rule del] =
  1121   rat.All_transfer rat.Ex_transfer rat.rel_eq_transfer forall_rat_transfer
  1122   Fract.transfer zero_rat.transfer one_rat.transfer plus_rat.transfer
  1123   uminus_rat.transfer times_rat.transfer inverse_rat.transfer
  1124   positive.transfer of_rat.transfer
  1125 
  1126 text {* De-register @{text "rat"} as a quotient type: *}
  1127 
  1128 declare Quotient_rat[quot_del]
  1129 
  1130 end