src/HOL/HOL.thy
author wenzelm
Tue Aug 17 22:13:23 1999 +0200 (1999-08-17)
changeset 7238 36e58620ffc8
parent 7220 da6f387ca482
child 7357 d0e16da40ea2
permissions -rw-r--r--
replaced HOL_quantifiers flag by "HOL" print mode;
simplified HOL basic syntax (more orthogonal);
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4     Copyright   1993  University of Cambridge
     5 
     6 Higher-Order Logic.
     7 *)
     8 
     9 HOL = CPure +
    10 
    11 
    12 (** Core syntax **)
    13 
    14 global
    15 
    16 classes
    17   term < logic
    18 
    19 default
    20   term
    21 
    22 types
    23   bool
    24 
    25 arities
    26   fun :: (term, term) term
    27   bool :: term
    28 
    29 
    30 consts
    31 
    32   (* Constants *)
    33 
    34   Trueprop      :: bool => prop                     ("(_)" 5)
    35   Not           :: bool => bool                     ("~ _" [40] 40)
    36   True, False   :: bool
    37   If            :: [bool, 'a, 'a] => 'a   ("(if (_)/ then (_)/ else (_))" 10)
    38   arbitrary     :: 'a
    39 
    40   (* Binders *)
    41 
    42   Eps           :: ('a => bool) => 'a
    43   All           :: ('a => bool) => bool             (binder "ALL " 10)
    44   Ex            :: ('a => bool) => bool             (binder "EX " 10)
    45   Ex1           :: ('a => bool) => bool             (binder "EX! " 10)
    46   Let           :: ['a, 'a => 'b] => 'b
    47 
    48   (* Infixes *)
    49 
    50   "="           :: ['a, 'a] => bool                 (infixl 50)
    51   "&"           :: [bool, bool] => bool             (infixr 35)
    52   "|"           :: [bool, bool] => bool             (infixr 30)
    53   "-->"         :: [bool, bool] => bool             (infixr 25)
    54 
    55 
    56 (* Overloaded Constants *)
    57 
    58 axclass
    59   plus < term
    60 
    61 axclass
    62   minus < term
    63 
    64 axclass
    65   times < term
    66 
    67 axclass
    68   power < term
    69 
    70 consts
    71   "+"           :: ['a::plus, 'a]  => 'a            (infixl 65)
    72   "-"           :: ['a::minus, 'a] => 'a            (infixl 65)
    73   uminus        :: ['a::minus] => 'a                ("- _" [81] 80)
    74   "*"           :: ['a::times, 'a] => 'a            (infixl 70)
    75   (*See Nat.thy for "^"*)
    76 
    77 
    78 
    79 (** Additional concrete syntax **)
    80 
    81 nonterminals
    82   letbinds  letbind
    83   case_syn  cases_syn
    84 
    85 syntax
    86   "~="          :: ['a, 'a] => bool                 (infixl 50)
    87   "_Eps"        :: [pttrn, bool] => 'a              ("(3SOME _./ _)" [0, 10] 10)
    88 
    89   (* Let expressions *)
    90 
    91   "_bind"       :: [pttrn, 'a] => letbind           ("(2_ =/ _)" 10)
    92   ""            :: letbind => letbinds              ("_")
    93   "_binds"      :: [letbind, letbinds] => letbinds  ("_;/ _")
    94   "_Let"        :: [letbinds, 'a] => 'a             ("(let (_)/ in (_))" 10)
    95 
    96   (* Case expressions *)
    97 
    98   "@case"       :: ['a, cases_syn] => 'b            ("(case _ of/ _)" 10)
    99   "@case1"      :: ['a, 'b] => case_syn             ("(2_ =>/ _)" 10)
   100   ""            :: case_syn => cases_syn            ("_")
   101   "@case2"      :: [case_syn, cases_syn] => cases_syn   ("_/ | _")
   102 
   103 translations
   104   "x ~= y"                == "~ (x = y)"
   105   "SOME x. P"             == "Eps (%x. P)"
   106   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   107   "let x = a in e"        == "Let a (%x. e)"
   108 
   109 syntax ("" output)
   110   "op ="        :: ['a, 'a] => bool                 ("(_ =/ _)" [51, 51] 50)
   111   "op ~="       :: ['a, 'a] => bool                 ("(_ ~=/ _)" [51, 51] 50)
   112 
   113 syntax (symbols)
   114   Not           :: bool => bool                     ("\\<not> _" [40] 40)
   115   "op &"        :: [bool, bool] => bool             (infixr "\\<and>" 35)
   116   "op |"        :: [bool, bool] => bool             (infixr "\\<or>" 30)
   117   "op -->"      :: [bool, bool] => bool             (infixr "\\<midarrow>\\<rightarrow>" 25)
   118   "op o"        :: ['b => 'c, 'a => 'b, 'a] => 'c   (infixl "\\<circ>" 55)
   119   "op ~="       :: ['a, 'a] => bool                 (infixl "\\<noteq>" 50)
   120   "_Eps"        :: [pttrn, bool] => 'a              ("(3\\<epsilon>_./ _)" [0, 10] 10)
   121   "ALL "        :: [idts, bool] => bool             ("(3\\<forall>_./ _)" [0, 10] 10)
   122   "EX "         :: [idts, bool] => bool             ("(3\\<exists>_./ _)" [0, 10] 10)
   123   "EX! "        :: [idts, bool] => bool             ("(3\\<exists>!_./ _)" [0, 10] 10)
   124   "@case1"      :: ['a, 'b] => case_syn             ("(2_ \\<Rightarrow>/ _)" 10)
   125 (*"@case2"      :: [case_syn, cases_syn] => cases_syn   ("_/ \\<orelse> _")*)
   126 
   127 syntax (symbols output)
   128   "op ~="       :: ['a, 'a] => bool                 ("(_ \\<noteq>/ _)" [51, 51] 50)
   129 
   130 syntax (xsymbols)
   131   "op -->"      :: [bool, bool] => bool             (infixr "\\<longrightarrow>" 25)
   132 
   133 syntax (HTML output)
   134   Not           :: bool => bool                     ("\\<not> _" [40] 40)
   135 
   136 syntax (HOL)
   137   "_Eps"        :: [pttrn, bool] => 'a              ("(3@ _./ _)" [0, 10] 10)
   138   "ALL "        :: [idts, bool] => bool             ("(3! _./ _)" [0, 10] 10)
   139   "EX "         :: [idts, bool] => bool             ("(3? _./ _)" [0, 10] 10)
   140   "EX! "        :: [idts, bool] => bool             ("(3?! _./ _)" [0, 10] 10)
   141 
   142 
   143 
   144 (** Rules and definitions **)
   145 
   146 local
   147 
   148 rules
   149 
   150   eq_reflection "(x=y) ==> (x==y)"
   151 
   152   (* Basic Rules *)
   153 
   154   refl          "t = (t::'a)"
   155   subst         "[| s = t; P(s) |] ==> P(t::'a)"
   156 
   157   (*Extensionality is built into the meta-logic, and this rule expresses
   158     a related property.  It is an eta-expanded version of the traditional
   159     rule, and similar to the ABS rule of HOL.*)
   160   ext           "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   161 
   162   selectI       "P (x::'a) ==> P (@x. P x)"
   163 
   164   impI          "(P ==> Q) ==> P-->Q"
   165   mp            "[| P-->Q;  P |] ==> Q"
   166 
   167 defs
   168 
   169   True_def      "True      == ((%x::bool. x) = (%x. x))"
   170   All_def       "All(P)    == (P = (%x. True))"
   171   Ex_def        "Ex(P)     == P(@x. P(x))"
   172   False_def     "False     == (!P. P)"
   173   not_def       "~ P       == P-->False"
   174   and_def       "P & Q     == !R. (P-->Q-->R) --> R"
   175   or_def        "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   176   Ex1_def       "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   177 
   178 rules
   179   (* Axioms *)
   180 
   181   iff           "(P-->Q) --> (Q-->P) --> (P=Q)"
   182   True_or_False "(P=True) | (P=False)"
   183 
   184 defs
   185   (*misc definitions*)
   186   Let_def       "Let s f == f(s)"
   187   if_def        "If P x y == @z::'a. (P=True --> z=x) & (P=False --> z=y)"
   188 
   189   (*arbitrary is completely unspecified, but is made to appear as a
   190     definition syntactically*)
   191   arbitrary_def "False ==> arbitrary == (@x. False)"
   192 
   193 
   194 
   195 (** initial HOL theory setup **)
   196 
   197 setup Simplifier.setup
   198 setup ClasetThyData.setup
   199 
   200 
   201 end