src/HOL/Num.thy
author wenzelm
Sat May 25 15:37:53 2013 +0200 (2013-05-25)
changeset 52143 36ffe23b25f8
parent 51143 0a2371e7ced3
child 52187 1f7b3aadec69
permissions -rw-r--r--
syntax translations always depend on context;
     1 (*  Title:      HOL/Num.thy
     2     Author:     Florian Haftmann
     3     Author:     Brian Huffman
     4 *)
     5 
     6 header {* Binary Numerals *}
     7 
     8 theory Num
     9 imports Datatype
    10 begin
    11 
    12 subsection {* The @{text num} type *}
    13 
    14 datatype num = One | Bit0 num | Bit1 num
    15 
    16 text {* Increment function for type @{typ num} *}
    17 
    18 primrec inc :: "num \<Rightarrow> num" where
    19   "inc One = Bit0 One" |
    20   "inc (Bit0 x) = Bit1 x" |
    21   "inc (Bit1 x) = Bit0 (inc x)"
    22 
    23 text {* Converting between type @{typ num} and type @{typ nat} *}
    24 
    25 primrec nat_of_num :: "num \<Rightarrow> nat" where
    26   "nat_of_num One = Suc 0" |
    27   "nat_of_num (Bit0 x) = nat_of_num x + nat_of_num x" |
    28   "nat_of_num (Bit1 x) = Suc (nat_of_num x + nat_of_num x)"
    29 
    30 primrec num_of_nat :: "nat \<Rightarrow> num" where
    31   "num_of_nat 0 = One" |
    32   "num_of_nat (Suc n) = (if 0 < n then inc (num_of_nat n) else One)"
    33 
    34 lemma nat_of_num_pos: "0 < nat_of_num x"
    35   by (induct x) simp_all
    36 
    37 lemma nat_of_num_neq_0: " nat_of_num x \<noteq> 0"
    38   by (induct x) simp_all
    39 
    40 lemma nat_of_num_inc: "nat_of_num (inc x) = Suc (nat_of_num x)"
    41   by (induct x) simp_all
    42 
    43 lemma num_of_nat_double:
    44   "0 < n \<Longrightarrow> num_of_nat (n + n) = Bit0 (num_of_nat n)"
    45   by (induct n) simp_all
    46 
    47 text {*
    48   Type @{typ num} is isomorphic to the strictly positive
    49   natural numbers.
    50 *}
    51 
    52 lemma nat_of_num_inverse: "num_of_nat (nat_of_num x) = x"
    53   by (induct x) (simp_all add: num_of_nat_double nat_of_num_pos)
    54 
    55 lemma num_of_nat_inverse: "0 < n \<Longrightarrow> nat_of_num (num_of_nat n) = n"
    56   by (induct n) (simp_all add: nat_of_num_inc)
    57 
    58 lemma num_eq_iff: "x = y \<longleftrightarrow> nat_of_num x = nat_of_num y"
    59   apply safe
    60   apply (drule arg_cong [where f=num_of_nat])
    61   apply (simp add: nat_of_num_inverse)
    62   done
    63 
    64 lemma num_induct [case_names One inc]:
    65   fixes P :: "num \<Rightarrow> bool"
    66   assumes One: "P One"
    67     and inc: "\<And>x. P x \<Longrightarrow> P (inc x)"
    68   shows "P x"
    69 proof -
    70   obtain n where n: "Suc n = nat_of_num x"
    71     by (cases "nat_of_num x", simp_all add: nat_of_num_neq_0)
    72   have "P (num_of_nat (Suc n))"
    73   proof (induct n)
    74     case 0 show ?case using One by simp
    75   next
    76     case (Suc n)
    77     then have "P (inc (num_of_nat (Suc n)))" by (rule inc)
    78     then show "P (num_of_nat (Suc (Suc n)))" by simp
    79   qed
    80   with n show "P x"
    81     by (simp add: nat_of_num_inverse)
    82 qed
    83 
    84 text {*
    85   From now on, there are two possible models for @{typ num}:
    86   as positive naturals (rule @{text "num_induct"})
    87   and as digit representation (rules @{text "num.induct"}, @{text "num.cases"}).
    88 *}
    89 
    90 
    91 subsection {* Numeral operations *}
    92 
    93 instantiation num :: "{plus,times,linorder}"
    94 begin
    95 
    96 definition [code del]:
    97   "m + n = num_of_nat (nat_of_num m + nat_of_num n)"
    98 
    99 definition [code del]:
   100   "m * n = num_of_nat (nat_of_num m * nat_of_num n)"
   101 
   102 definition [code del]:
   103   "m \<le> n \<longleftrightarrow> nat_of_num m \<le> nat_of_num n"
   104 
   105 definition [code del]:
   106   "m < n \<longleftrightarrow> nat_of_num m < nat_of_num n"
   107 
   108 instance
   109   by (default, auto simp add: less_num_def less_eq_num_def num_eq_iff)
   110 
   111 end
   112 
   113 lemma nat_of_num_add: "nat_of_num (x + y) = nat_of_num x + nat_of_num y"
   114   unfolding plus_num_def
   115   by (intro num_of_nat_inverse add_pos_pos nat_of_num_pos)
   116 
   117 lemma nat_of_num_mult: "nat_of_num (x * y) = nat_of_num x * nat_of_num y"
   118   unfolding times_num_def
   119   by (intro num_of_nat_inverse mult_pos_pos nat_of_num_pos)
   120 
   121 lemma add_num_simps [simp, code]:
   122   "One + One = Bit0 One"
   123   "One + Bit0 n = Bit1 n"
   124   "One + Bit1 n = Bit0 (n + One)"
   125   "Bit0 m + One = Bit1 m"
   126   "Bit0 m + Bit0 n = Bit0 (m + n)"
   127   "Bit0 m + Bit1 n = Bit1 (m + n)"
   128   "Bit1 m + One = Bit0 (m + One)"
   129   "Bit1 m + Bit0 n = Bit1 (m + n)"
   130   "Bit1 m + Bit1 n = Bit0 (m + n + One)"
   131   by (simp_all add: num_eq_iff nat_of_num_add)
   132 
   133 lemma mult_num_simps [simp, code]:
   134   "m * One = m"
   135   "One * n = n"
   136   "Bit0 m * Bit0 n = Bit0 (Bit0 (m * n))"
   137   "Bit0 m * Bit1 n = Bit0 (m * Bit1 n)"
   138   "Bit1 m * Bit0 n = Bit0 (Bit1 m * n)"
   139   "Bit1 m * Bit1 n = Bit1 (m + n + Bit0 (m * n))"
   140   by (simp_all add: num_eq_iff nat_of_num_add
   141     nat_of_num_mult distrib_right distrib_left)
   142 
   143 lemma eq_num_simps:
   144   "One = One \<longleftrightarrow> True"
   145   "One = Bit0 n \<longleftrightarrow> False"
   146   "One = Bit1 n \<longleftrightarrow> False"
   147   "Bit0 m = One \<longleftrightarrow> False"
   148   "Bit1 m = One \<longleftrightarrow> False"
   149   "Bit0 m = Bit0 n \<longleftrightarrow> m = n"
   150   "Bit0 m = Bit1 n \<longleftrightarrow> False"
   151   "Bit1 m = Bit0 n \<longleftrightarrow> False"
   152   "Bit1 m = Bit1 n \<longleftrightarrow> m = n"
   153   by simp_all
   154 
   155 lemma le_num_simps [simp, code]:
   156   "One \<le> n \<longleftrightarrow> True"
   157   "Bit0 m \<le> One \<longleftrightarrow> False"
   158   "Bit1 m \<le> One \<longleftrightarrow> False"
   159   "Bit0 m \<le> Bit0 n \<longleftrightarrow> m \<le> n"
   160   "Bit0 m \<le> Bit1 n \<longleftrightarrow> m \<le> n"
   161   "Bit1 m \<le> Bit1 n \<longleftrightarrow> m \<le> n"
   162   "Bit1 m \<le> Bit0 n \<longleftrightarrow> m < n"
   163   using nat_of_num_pos [of n] nat_of_num_pos [of m]
   164   by (auto simp add: less_eq_num_def less_num_def)
   165 
   166 lemma less_num_simps [simp, code]:
   167   "m < One \<longleftrightarrow> False"
   168   "One < Bit0 n \<longleftrightarrow> True"
   169   "One < Bit1 n \<longleftrightarrow> True"
   170   "Bit0 m < Bit0 n \<longleftrightarrow> m < n"
   171   "Bit0 m < Bit1 n \<longleftrightarrow> m \<le> n"
   172   "Bit1 m < Bit1 n \<longleftrightarrow> m < n"
   173   "Bit1 m < Bit0 n \<longleftrightarrow> m < n"
   174   using nat_of_num_pos [of n] nat_of_num_pos [of m]
   175   by (auto simp add: less_eq_num_def less_num_def)
   176 
   177 text {* Rules using @{text One} and @{text inc} as constructors *}
   178 
   179 lemma add_One: "x + One = inc x"
   180   by (simp add: num_eq_iff nat_of_num_add nat_of_num_inc)
   181 
   182 lemma add_One_commute: "One + n = n + One"
   183   by (induct n) simp_all
   184 
   185 lemma add_inc: "x + inc y = inc (x + y)"
   186   by (simp add: num_eq_iff nat_of_num_add nat_of_num_inc)
   187 
   188 lemma mult_inc: "x * inc y = x * y + x"
   189   by (simp add: num_eq_iff nat_of_num_mult nat_of_num_add nat_of_num_inc)
   190 
   191 text {* The @{const num_of_nat} conversion *}
   192 
   193 lemma num_of_nat_One:
   194   "n \<le> 1 \<Longrightarrow> num_of_nat n = One"
   195   by (cases n) simp_all
   196 
   197 lemma num_of_nat_plus_distrib:
   198   "0 < m \<Longrightarrow> 0 < n \<Longrightarrow> num_of_nat (m + n) = num_of_nat m + num_of_nat n"
   199   by (induct n) (auto simp add: add_One add_One_commute add_inc)
   200 
   201 text {* A double-and-decrement function *}
   202 
   203 primrec BitM :: "num \<Rightarrow> num" where
   204   "BitM One = One" |
   205   "BitM (Bit0 n) = Bit1 (BitM n)" |
   206   "BitM (Bit1 n) = Bit1 (Bit0 n)"
   207 
   208 lemma BitM_plus_one: "BitM n + One = Bit0 n"
   209   by (induct n) simp_all
   210 
   211 lemma one_plus_BitM: "One + BitM n = Bit0 n"
   212   unfolding add_One_commute BitM_plus_one ..
   213 
   214 text {* Squaring and exponentiation *}
   215 
   216 primrec sqr :: "num \<Rightarrow> num" where
   217   "sqr One = One" |
   218   "sqr (Bit0 n) = Bit0 (Bit0 (sqr n))" |
   219   "sqr (Bit1 n) = Bit1 (Bit0 (sqr n + n))"
   220 
   221 primrec pow :: "num \<Rightarrow> num \<Rightarrow> num" where
   222   "pow x One = x" |
   223   "pow x (Bit0 y) = sqr (pow x y)" |
   224   "pow x (Bit1 y) = sqr (pow x y) * x"
   225 
   226 lemma nat_of_num_sqr: "nat_of_num (sqr x) = nat_of_num x * nat_of_num x"
   227   by (induct x, simp_all add: algebra_simps nat_of_num_add)
   228 
   229 lemma sqr_conv_mult: "sqr x = x * x"
   230   by (simp add: num_eq_iff nat_of_num_sqr nat_of_num_mult)
   231 
   232 
   233 subsection {* Binary numerals *}
   234 
   235 text {*
   236   We embed binary representations into a generic algebraic
   237   structure using @{text numeral}.
   238 *}
   239 
   240 class numeral = one + semigroup_add
   241 begin
   242 
   243 primrec numeral :: "num \<Rightarrow> 'a" where
   244   numeral_One: "numeral One = 1" |
   245   numeral_Bit0: "numeral (Bit0 n) = numeral n + numeral n" |
   246   numeral_Bit1: "numeral (Bit1 n) = numeral n + numeral n + 1"
   247 
   248 lemma numeral_code [code]:
   249   "numeral One = 1"
   250   "numeral (Bit0 n) = (let m = numeral n in m + m)"
   251   "numeral (Bit1 n) = (let m = numeral n in m + m + 1)"
   252   by (simp_all add: Let_def)
   253   
   254 lemma one_plus_numeral_commute: "1 + numeral x = numeral x + 1"
   255   apply (induct x)
   256   apply simp
   257   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   258   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   259   done
   260 
   261 lemma numeral_inc: "numeral (inc x) = numeral x + 1"
   262 proof (induct x)
   263   case (Bit1 x)
   264   have "numeral x + (1 + numeral x) + 1 = numeral x + (numeral x + 1) + 1"
   265     by (simp only: one_plus_numeral_commute)
   266   with Bit1 show ?case
   267     by (simp add: add_assoc)
   268 qed simp_all
   269 
   270 declare numeral.simps [simp del]
   271 
   272 abbreviation "Numeral1 \<equiv> numeral One"
   273 
   274 declare numeral_One [code_post]
   275 
   276 end
   277 
   278 text {* Negative numerals. *}
   279 
   280 class neg_numeral = numeral + group_add
   281 begin
   282 
   283 definition neg_numeral :: "num \<Rightarrow> 'a" where
   284   "neg_numeral k = - numeral k"
   285 
   286 end
   287 
   288 text {* Numeral syntax. *}
   289 
   290 syntax
   291   "_Numeral" :: "num_const \<Rightarrow> 'a"    ("_")
   292 
   293 parse_translation {*
   294   let
   295     fun num_of_int n =
   296       if n > 0 then
   297         (case IntInf.quotRem (n, 2) of
   298           (0, 1) => Syntax.const @{const_name One}
   299         | (n, 0) => Syntax.const @{const_name Bit0} $ num_of_int n
   300         | (n, 1) => Syntax.const @{const_name Bit1} $ num_of_int n)
   301       else raise Match
   302     val pos = Syntax.const @{const_name numeral}
   303     val neg = Syntax.const @{const_name neg_numeral}
   304     val one = Syntax.const @{const_name Groups.one}
   305     val zero = Syntax.const @{const_name Groups.zero}
   306     fun numeral_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] =
   307           c $ numeral_tr [t] $ u
   308       | numeral_tr [Const (num, _)] =
   309           let
   310             val {value, ...} = Lexicon.read_xnum num;
   311           in
   312             if value = 0 then zero else
   313             if value > 0
   314             then pos $ num_of_int value
   315             else neg $ num_of_int (~value)
   316           end
   317       | numeral_tr ts = raise TERM ("numeral_tr", ts);
   318   in [("_Numeral", K numeral_tr)] end
   319 *}
   320 
   321 typed_print_translation {*
   322   let
   323     fun dest_num (Const (@{const_syntax Bit0}, _) $ n) = 2 * dest_num n
   324       | dest_num (Const (@{const_syntax Bit1}, _) $ n) = 2 * dest_num n + 1
   325       | dest_num (Const (@{const_syntax One}, _)) = 1;
   326     fun num_tr' sign ctxt T [n] =
   327       let
   328         val k = dest_num n;
   329         val t' = Syntax.const @{syntax_const "_Numeral"} $
   330           Syntax.free (sign ^ string_of_int k);
   331       in
   332         (case T of
   333           Type (@{type_name fun}, [_, T']) =>
   334             if not (Printer.show_type_constraint ctxt) andalso can Term.dest_Type T' then t'
   335             else Syntax.const @{syntax_const "_constrain"} $ t' $ Syntax_Phases.term_of_typ ctxt T'
   336         | T' => if T' = dummyT then t' else raise Match)
   337       end;
   338   in
   339    [(@{const_syntax numeral}, num_tr' ""),
   340     (@{const_syntax neg_numeral}, num_tr' "-")]
   341   end
   342 *}
   343 
   344 ML_file "Tools/numeral.ML"
   345 
   346 
   347 subsection {* Class-specific numeral rules *}
   348 
   349 text {*
   350   @{const numeral} is a morphism.
   351 *}
   352 
   353 subsubsection {* Structures with addition: class @{text numeral} *}
   354 
   355 context numeral
   356 begin
   357 
   358 lemma numeral_add: "numeral (m + n) = numeral m + numeral n"
   359   by (induct n rule: num_induct)
   360      (simp_all only: numeral_One add_One add_inc numeral_inc add_assoc)
   361 
   362 lemma numeral_plus_numeral: "numeral m + numeral n = numeral (m + n)"
   363   by (rule numeral_add [symmetric])
   364 
   365 lemma numeral_plus_one: "numeral n + 1 = numeral (n + One)"
   366   using numeral_add [of n One] by (simp add: numeral_One)
   367 
   368 lemma one_plus_numeral: "1 + numeral n = numeral (One + n)"
   369   using numeral_add [of One n] by (simp add: numeral_One)
   370 
   371 lemma one_add_one: "1 + 1 = 2"
   372   using numeral_add [of One One] by (simp add: numeral_One)
   373 
   374 lemmas add_numeral_special =
   375   numeral_plus_one one_plus_numeral one_add_one
   376 
   377 end
   378 
   379 subsubsection {*
   380   Structures with negation: class @{text neg_numeral}
   381 *}
   382 
   383 context neg_numeral
   384 begin
   385 
   386 text {* Numerals form an abelian subgroup. *}
   387 
   388 inductive is_num :: "'a \<Rightarrow> bool" where
   389   "is_num 1" |
   390   "is_num x \<Longrightarrow> is_num (- x)" |
   391   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> is_num (x + y)"
   392 
   393 lemma is_num_numeral: "is_num (numeral k)"
   394   by (induct k, simp_all add: numeral.simps is_num.intros)
   395 
   396 lemma is_num_add_commute:
   397   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> x + y = y + x"
   398   apply (induct x rule: is_num.induct)
   399   apply (induct y rule: is_num.induct)
   400   apply simp
   401   apply (rule_tac a=x in add_left_imp_eq)
   402   apply (rule_tac a=x in add_right_imp_eq)
   403   apply (simp add: add_assoc minus_add_cancel)
   404   apply (simp add: add_assoc [symmetric], simp add: add_assoc)
   405   apply (rule_tac a=x in add_left_imp_eq)
   406   apply (rule_tac a=x in add_right_imp_eq)
   407   apply (simp add: add_assoc minus_add_cancel add_minus_cancel)
   408   apply (simp add: add_assoc, simp add: add_assoc [symmetric])
   409   done
   410 
   411 lemma is_num_add_left_commute:
   412   "\<lbrakk>is_num x; is_num y\<rbrakk> \<Longrightarrow> x + (y + z) = y + (x + z)"
   413   by (simp only: add_assoc [symmetric] is_num_add_commute)
   414 
   415 lemmas is_num_normalize =
   416   add_assoc is_num_add_commute is_num_add_left_commute
   417   is_num.intros is_num_numeral
   418   diff_minus minus_add add_minus_cancel minus_add_cancel
   419 
   420 definition dbl :: "'a \<Rightarrow> 'a" where "dbl x = x + x"
   421 definition dbl_inc :: "'a \<Rightarrow> 'a" where "dbl_inc x = x + x + 1"
   422 definition dbl_dec :: "'a \<Rightarrow> 'a" where "dbl_dec x = x + x - 1"
   423 
   424 definition sub :: "num \<Rightarrow> num \<Rightarrow> 'a" where
   425   "sub k l = numeral k - numeral l"
   426 
   427 lemma numeral_BitM: "numeral (BitM n) = numeral (Bit0 n) - 1"
   428   by (simp only: BitM_plus_one [symmetric] numeral_add numeral_One eq_diff_eq)
   429 
   430 lemma dbl_simps [simp]:
   431   "dbl (neg_numeral k) = neg_numeral (Bit0 k)"
   432   "dbl 0 = 0"
   433   "dbl 1 = 2"
   434   "dbl (numeral k) = numeral (Bit0 k)"
   435   unfolding dbl_def neg_numeral_def numeral.simps
   436   by (simp_all add: minus_add)
   437 
   438 lemma dbl_inc_simps [simp]:
   439   "dbl_inc (neg_numeral k) = neg_numeral (BitM k)"
   440   "dbl_inc 0 = 1"
   441   "dbl_inc 1 = 3"
   442   "dbl_inc (numeral k) = numeral (Bit1 k)"
   443   unfolding dbl_inc_def neg_numeral_def numeral.simps numeral_BitM
   444   by (simp_all add: is_num_normalize)
   445 
   446 lemma dbl_dec_simps [simp]:
   447   "dbl_dec (neg_numeral k) = neg_numeral (Bit1 k)"
   448   "dbl_dec 0 = -1"
   449   "dbl_dec 1 = 1"
   450   "dbl_dec (numeral k) = numeral (BitM k)"
   451   unfolding dbl_dec_def neg_numeral_def numeral.simps numeral_BitM
   452   by (simp_all add: is_num_normalize)
   453 
   454 lemma sub_num_simps [simp]:
   455   "sub One One = 0"
   456   "sub One (Bit0 l) = neg_numeral (BitM l)"
   457   "sub One (Bit1 l) = neg_numeral (Bit0 l)"
   458   "sub (Bit0 k) One = numeral (BitM k)"
   459   "sub (Bit1 k) One = numeral (Bit0 k)"
   460   "sub (Bit0 k) (Bit0 l) = dbl (sub k l)"
   461   "sub (Bit0 k) (Bit1 l) = dbl_dec (sub k l)"
   462   "sub (Bit1 k) (Bit0 l) = dbl_inc (sub k l)"
   463   "sub (Bit1 k) (Bit1 l) = dbl (sub k l)"
   464   unfolding dbl_def dbl_dec_def dbl_inc_def sub_def
   465   unfolding neg_numeral_def numeral.simps numeral_BitM
   466   by (simp_all add: is_num_normalize)
   467 
   468 lemma add_neg_numeral_simps:
   469   "numeral m + neg_numeral n = sub m n"
   470   "neg_numeral m + numeral n = sub n m"
   471   "neg_numeral m + neg_numeral n = neg_numeral (m + n)"
   472   unfolding sub_def diff_minus neg_numeral_def numeral_add numeral.simps
   473   by (simp_all add: is_num_normalize)
   474 
   475 lemma add_neg_numeral_special:
   476   "1 + neg_numeral m = sub One m"
   477   "neg_numeral m + 1 = sub One m"
   478   unfolding sub_def diff_minus neg_numeral_def numeral_add numeral.simps
   479   by (simp_all add: is_num_normalize)
   480 
   481 lemma diff_numeral_simps:
   482   "numeral m - numeral n = sub m n"
   483   "numeral m - neg_numeral n = numeral (m + n)"
   484   "neg_numeral m - numeral n = neg_numeral (m + n)"
   485   "neg_numeral m - neg_numeral n = sub n m"
   486   unfolding neg_numeral_def sub_def diff_minus numeral_add numeral.simps
   487   by (simp_all add: is_num_normalize)
   488 
   489 lemma diff_numeral_special:
   490   "1 - numeral n = sub One n"
   491   "1 - neg_numeral n = numeral (One + n)"
   492   "numeral m - 1 = sub m One"
   493   "neg_numeral m - 1 = neg_numeral (m + One)"
   494   unfolding neg_numeral_def sub_def diff_minus numeral_add numeral.simps
   495   by (simp_all add: is_num_normalize)
   496 
   497 lemma minus_one: "- 1 = -1"
   498   unfolding neg_numeral_def numeral.simps ..
   499 
   500 lemma minus_numeral: "- numeral n = neg_numeral n"
   501   unfolding neg_numeral_def ..
   502 
   503 lemma minus_neg_numeral: "- neg_numeral n = numeral n"
   504   unfolding neg_numeral_def by simp
   505 
   506 lemmas minus_numeral_simps [simp] =
   507   minus_one minus_numeral minus_neg_numeral
   508 
   509 end
   510 
   511 subsubsection {*
   512   Structures with multiplication: class @{text semiring_numeral}
   513 *}
   514 
   515 class semiring_numeral = semiring + monoid_mult
   516 begin
   517 
   518 subclass numeral ..
   519 
   520 lemma numeral_mult: "numeral (m * n) = numeral m * numeral n"
   521   apply (induct n rule: num_induct)
   522   apply (simp add: numeral_One)
   523   apply (simp add: mult_inc numeral_inc numeral_add distrib_left)
   524   done
   525 
   526 lemma numeral_times_numeral: "numeral m * numeral n = numeral (m * n)"
   527   by (rule numeral_mult [symmetric])
   528 
   529 end
   530 
   531 subsubsection {*
   532   Structures with a zero: class @{text semiring_1}
   533 *}
   534 
   535 context semiring_1
   536 begin
   537 
   538 subclass semiring_numeral ..
   539 
   540 lemma of_nat_numeral [simp]: "of_nat (numeral n) = numeral n"
   541   by (induct n,
   542     simp_all only: numeral.simps numeral_class.numeral.simps of_nat_add of_nat_1)
   543 
   544 lemma mult_2: "2 * z = z + z"
   545   unfolding one_add_one [symmetric] distrib_right by simp
   546 
   547 lemma mult_2_right: "z * 2 = z + z"
   548   unfolding one_add_one [symmetric] distrib_left by simp
   549 
   550 end
   551 
   552 lemma nat_of_num_numeral [code_abbrev]:
   553   "nat_of_num = numeral"
   554 proof
   555   fix n
   556   have "numeral n = nat_of_num n"
   557     by (induct n) (simp_all add: numeral.simps)
   558   then show "nat_of_num n = numeral n" by simp
   559 qed
   560 
   561 lemma nat_of_num_code [code]:
   562   "nat_of_num One = 1"
   563   "nat_of_num (Bit0 n) = (let m = nat_of_num n in m + m)"
   564   "nat_of_num (Bit1 n) = (let m = nat_of_num n in Suc (m + m))"
   565   by (simp_all add: Let_def)
   566 
   567 subsubsection {*
   568   Equality: class @{text semiring_char_0}
   569 *}
   570 
   571 context semiring_char_0
   572 begin
   573 
   574 lemma numeral_eq_iff: "numeral m = numeral n \<longleftrightarrow> m = n"
   575   unfolding of_nat_numeral [symmetric] nat_of_num_numeral [symmetric]
   576     of_nat_eq_iff num_eq_iff ..
   577 
   578 lemma numeral_eq_one_iff: "numeral n = 1 \<longleftrightarrow> n = One"
   579   by (rule numeral_eq_iff [of n One, unfolded numeral_One])
   580 
   581 lemma one_eq_numeral_iff: "1 = numeral n \<longleftrightarrow> One = n"
   582   by (rule numeral_eq_iff [of One n, unfolded numeral_One])
   583 
   584 lemma numeral_neq_zero: "numeral n \<noteq> 0"
   585   unfolding of_nat_numeral [symmetric] nat_of_num_numeral [symmetric]
   586   by (simp add: nat_of_num_pos)
   587 
   588 lemma zero_neq_numeral: "0 \<noteq> numeral n"
   589   unfolding eq_commute [of 0] by (rule numeral_neq_zero)
   590 
   591 lemmas eq_numeral_simps [simp] =
   592   numeral_eq_iff
   593   numeral_eq_one_iff
   594   one_eq_numeral_iff
   595   numeral_neq_zero
   596   zero_neq_numeral
   597 
   598 end
   599 
   600 subsubsection {*
   601   Comparisons: class @{text linordered_semidom}
   602 *}
   603 
   604 text {*  Could be perhaps more general than here. *}
   605 
   606 context linordered_semidom
   607 begin
   608 
   609 lemma numeral_le_iff: "numeral m \<le> numeral n \<longleftrightarrow> m \<le> n"
   610 proof -
   611   have "of_nat (numeral m) \<le> of_nat (numeral n) \<longleftrightarrow> m \<le> n"
   612     unfolding less_eq_num_def nat_of_num_numeral of_nat_le_iff ..
   613   then show ?thesis by simp
   614 qed
   615 
   616 lemma one_le_numeral: "1 \<le> numeral n"
   617 using numeral_le_iff [of One n] by (simp add: numeral_One)
   618 
   619 lemma numeral_le_one_iff: "numeral n \<le> 1 \<longleftrightarrow> n \<le> One"
   620 using numeral_le_iff [of n One] by (simp add: numeral_One)
   621 
   622 lemma numeral_less_iff: "numeral m < numeral n \<longleftrightarrow> m < n"
   623 proof -
   624   have "of_nat (numeral m) < of_nat (numeral n) \<longleftrightarrow> m < n"
   625     unfolding less_num_def nat_of_num_numeral of_nat_less_iff ..
   626   then show ?thesis by simp
   627 qed
   628 
   629 lemma not_numeral_less_one: "\<not> numeral n < 1"
   630   using numeral_less_iff [of n One] by (simp add: numeral_One)
   631 
   632 lemma one_less_numeral_iff: "1 < numeral n \<longleftrightarrow> One < n"
   633   using numeral_less_iff [of One n] by (simp add: numeral_One)
   634 
   635 lemma zero_le_numeral: "0 \<le> numeral n"
   636   by (induct n) (simp_all add: numeral.simps)
   637 
   638 lemma zero_less_numeral: "0 < numeral n"
   639   by (induct n) (simp_all add: numeral.simps add_pos_pos)
   640 
   641 lemma not_numeral_le_zero: "\<not> numeral n \<le> 0"
   642   by (simp add: not_le zero_less_numeral)
   643 
   644 lemma not_numeral_less_zero: "\<not> numeral n < 0"
   645   by (simp add: not_less zero_le_numeral)
   646 
   647 lemmas le_numeral_extra =
   648   zero_le_one not_one_le_zero
   649   order_refl [of 0] order_refl [of 1]
   650 
   651 lemmas less_numeral_extra =
   652   zero_less_one not_one_less_zero
   653   less_irrefl [of 0] less_irrefl [of 1]
   654 
   655 lemmas le_numeral_simps [simp] =
   656   numeral_le_iff
   657   one_le_numeral
   658   numeral_le_one_iff
   659   zero_le_numeral
   660   not_numeral_le_zero
   661 
   662 lemmas less_numeral_simps [simp] =
   663   numeral_less_iff
   664   one_less_numeral_iff
   665   not_numeral_less_one
   666   zero_less_numeral
   667   not_numeral_less_zero
   668 
   669 end
   670 
   671 subsubsection {*
   672   Multiplication and negation: class @{text ring_1}
   673 *}
   674 
   675 context ring_1
   676 begin
   677 
   678 subclass neg_numeral ..
   679 
   680 lemma mult_neg_numeral_simps:
   681   "neg_numeral m * neg_numeral n = numeral (m * n)"
   682   "neg_numeral m * numeral n = neg_numeral (m * n)"
   683   "numeral m * neg_numeral n = neg_numeral (m * n)"
   684   unfolding neg_numeral_def mult_minus_left mult_minus_right
   685   by (simp_all only: minus_minus numeral_mult)
   686 
   687 lemma mult_minus1 [simp]: "-1 * z = - z"
   688   unfolding neg_numeral_def numeral.simps mult_minus_left by simp
   689 
   690 lemma mult_minus1_right [simp]: "z * -1 = - z"
   691   unfolding neg_numeral_def numeral.simps mult_minus_right by simp
   692 
   693 end
   694 
   695 subsubsection {*
   696   Equality using @{text iszero} for rings with non-zero characteristic
   697 *}
   698 
   699 context ring_1
   700 begin
   701 
   702 definition iszero :: "'a \<Rightarrow> bool"
   703   where "iszero z \<longleftrightarrow> z = 0"
   704 
   705 lemma iszero_0 [simp]: "iszero 0"
   706   by (simp add: iszero_def)
   707 
   708 lemma not_iszero_1 [simp]: "\<not> iszero 1"
   709   by (simp add: iszero_def)
   710 
   711 lemma not_iszero_Numeral1: "\<not> iszero Numeral1"
   712   by (simp add: numeral_One)
   713 
   714 lemma iszero_neg_numeral [simp]:
   715   "iszero (neg_numeral w) \<longleftrightarrow> iszero (numeral w)"
   716   unfolding iszero_def neg_numeral_def
   717   by (rule neg_equal_0_iff_equal)
   718 
   719 lemma eq_iff_iszero_diff: "x = y \<longleftrightarrow> iszero (x - y)"
   720   unfolding iszero_def by (rule eq_iff_diff_eq_0)
   721 
   722 text {* The @{text "eq_numeral_iff_iszero"} lemmas are not declared
   723 @{text "[simp]"} by default, because for rings of characteristic zero,
   724 better simp rules are possible. For a type like integers mod @{text
   725 "n"}, type-instantiated versions of these rules should be added to the
   726 simplifier, along with a type-specific rule for deciding propositions
   727 of the form @{text "iszero (numeral w)"}.
   728 
   729 bh: Maybe it would not be so bad to just declare these as simp
   730 rules anyway? I should test whether these rules take precedence over
   731 the @{text "ring_char_0"} rules in the simplifier.
   732 *}
   733 
   734 lemma eq_numeral_iff_iszero:
   735   "numeral x = numeral y \<longleftrightarrow> iszero (sub x y)"
   736   "numeral x = neg_numeral y \<longleftrightarrow> iszero (numeral (x + y))"
   737   "neg_numeral x = numeral y \<longleftrightarrow> iszero (numeral (x + y))"
   738   "neg_numeral x = neg_numeral y \<longleftrightarrow> iszero (sub y x)"
   739   "numeral x = 1 \<longleftrightarrow> iszero (sub x One)"
   740   "1 = numeral y \<longleftrightarrow> iszero (sub One y)"
   741   "neg_numeral x = 1 \<longleftrightarrow> iszero (numeral (x + One))"
   742   "1 = neg_numeral y \<longleftrightarrow> iszero (numeral (One + y))"
   743   "numeral x = 0 \<longleftrightarrow> iszero (numeral x)"
   744   "0 = numeral y \<longleftrightarrow> iszero (numeral y)"
   745   "neg_numeral x = 0 \<longleftrightarrow> iszero (numeral x)"
   746   "0 = neg_numeral y \<longleftrightarrow> iszero (numeral y)"
   747   unfolding eq_iff_iszero_diff diff_numeral_simps diff_numeral_special
   748   by simp_all
   749 
   750 end
   751 
   752 subsubsection {*
   753   Equality and negation: class @{text ring_char_0}
   754 *}
   755 
   756 class ring_char_0 = ring_1 + semiring_char_0
   757 begin
   758 
   759 lemma not_iszero_numeral [simp]: "\<not> iszero (numeral w)"
   760   by (simp add: iszero_def)
   761 
   762 lemma neg_numeral_eq_iff: "neg_numeral m = neg_numeral n \<longleftrightarrow> m = n"
   763   by (simp only: neg_numeral_def neg_equal_iff_equal numeral_eq_iff)
   764 
   765 lemma numeral_neq_neg_numeral: "numeral m \<noteq> neg_numeral n"
   766   unfolding neg_numeral_def eq_neg_iff_add_eq_0
   767   by (simp add: numeral_plus_numeral)
   768 
   769 lemma neg_numeral_neq_numeral: "neg_numeral m \<noteq> numeral n"
   770   by (rule numeral_neq_neg_numeral [symmetric])
   771 
   772 lemma zero_neq_neg_numeral: "0 \<noteq> neg_numeral n"
   773   unfolding neg_numeral_def neg_0_equal_iff_equal by simp
   774 
   775 lemma neg_numeral_neq_zero: "neg_numeral n \<noteq> 0"
   776   unfolding neg_numeral_def neg_equal_0_iff_equal by simp
   777 
   778 lemma one_neq_neg_numeral: "1 \<noteq> neg_numeral n"
   779   using numeral_neq_neg_numeral [of One n] by (simp add: numeral_One)
   780 
   781 lemma neg_numeral_neq_one: "neg_numeral n \<noteq> 1"
   782   using neg_numeral_neq_numeral [of n One] by (simp add: numeral_One)
   783 
   784 lemmas eq_neg_numeral_simps [simp] =
   785   neg_numeral_eq_iff
   786   numeral_neq_neg_numeral neg_numeral_neq_numeral
   787   one_neq_neg_numeral neg_numeral_neq_one
   788   zero_neq_neg_numeral neg_numeral_neq_zero
   789 
   790 end
   791 
   792 subsubsection {*
   793   Structures with negation and order: class @{text linordered_idom}
   794 *}
   795 
   796 context linordered_idom
   797 begin
   798 
   799 subclass ring_char_0 ..
   800 
   801 lemma neg_numeral_le_iff: "neg_numeral m \<le> neg_numeral n \<longleftrightarrow> n \<le> m"
   802   by (simp only: neg_numeral_def neg_le_iff_le numeral_le_iff)
   803 
   804 lemma neg_numeral_less_iff: "neg_numeral m < neg_numeral n \<longleftrightarrow> n < m"
   805   by (simp only: neg_numeral_def neg_less_iff_less numeral_less_iff)
   806 
   807 lemma neg_numeral_less_zero: "neg_numeral n < 0"
   808   by (simp only: neg_numeral_def neg_less_0_iff_less zero_less_numeral)
   809 
   810 lemma neg_numeral_le_zero: "neg_numeral n \<le> 0"
   811   by (simp only: neg_numeral_def neg_le_0_iff_le zero_le_numeral)
   812 
   813 lemma not_zero_less_neg_numeral: "\<not> 0 < neg_numeral n"
   814   by (simp only: not_less neg_numeral_le_zero)
   815 
   816 lemma not_zero_le_neg_numeral: "\<not> 0 \<le> neg_numeral n"
   817   by (simp only: not_le neg_numeral_less_zero)
   818 
   819 lemma neg_numeral_less_numeral: "neg_numeral m < numeral n"
   820   using neg_numeral_less_zero zero_less_numeral by (rule less_trans)
   821 
   822 lemma neg_numeral_le_numeral: "neg_numeral m \<le> numeral n"
   823   by (simp only: less_imp_le neg_numeral_less_numeral)
   824 
   825 lemma not_numeral_less_neg_numeral: "\<not> numeral m < neg_numeral n"
   826   by (simp only: not_less neg_numeral_le_numeral)
   827 
   828 lemma not_numeral_le_neg_numeral: "\<not> numeral m \<le> neg_numeral n"
   829   by (simp only: not_le neg_numeral_less_numeral)
   830   
   831 lemma neg_numeral_less_one: "neg_numeral m < 1"
   832   by (rule neg_numeral_less_numeral [of m One, unfolded numeral_One])
   833 
   834 lemma neg_numeral_le_one: "neg_numeral m \<le> 1"
   835   by (rule neg_numeral_le_numeral [of m One, unfolded numeral_One])
   836 
   837 lemma not_one_less_neg_numeral: "\<not> 1 < neg_numeral m"
   838   by (simp only: not_less neg_numeral_le_one)
   839 
   840 lemma not_one_le_neg_numeral: "\<not> 1 \<le> neg_numeral m"
   841   by (simp only: not_le neg_numeral_less_one)
   842 
   843 lemma sub_non_negative:
   844   "sub n m \<ge> 0 \<longleftrightarrow> n \<ge> m"
   845   by (simp only: sub_def le_diff_eq) simp
   846 
   847 lemma sub_positive:
   848   "sub n m > 0 \<longleftrightarrow> n > m"
   849   by (simp only: sub_def less_diff_eq) simp
   850 
   851 lemma sub_non_positive:
   852   "sub n m \<le> 0 \<longleftrightarrow> n \<le> m"
   853   by (simp only: sub_def diff_le_eq) simp
   854 
   855 lemma sub_negative:
   856   "sub n m < 0 \<longleftrightarrow> n < m"
   857   by (simp only: sub_def diff_less_eq) simp
   858 
   859 lemmas le_neg_numeral_simps [simp] =
   860   neg_numeral_le_iff
   861   neg_numeral_le_numeral not_numeral_le_neg_numeral
   862   neg_numeral_le_zero not_zero_le_neg_numeral
   863   neg_numeral_le_one not_one_le_neg_numeral
   864 
   865 lemmas less_neg_numeral_simps [simp] =
   866   neg_numeral_less_iff
   867   neg_numeral_less_numeral not_numeral_less_neg_numeral
   868   neg_numeral_less_zero not_zero_less_neg_numeral
   869   neg_numeral_less_one not_one_less_neg_numeral
   870 
   871 lemma abs_numeral [simp]: "abs (numeral n) = numeral n"
   872   by simp
   873 
   874 lemma abs_neg_numeral [simp]: "abs (neg_numeral n) = numeral n"
   875   by (simp only: neg_numeral_def abs_minus_cancel abs_numeral)
   876 
   877 end
   878 
   879 subsubsection {*
   880   Natural numbers
   881 *}
   882 
   883 lemma Suc_1 [simp]: "Suc 1 = 2"
   884   unfolding Suc_eq_plus1 by (rule one_add_one)
   885 
   886 lemma Suc_numeral [simp]: "Suc (numeral n) = numeral (n + One)"
   887   unfolding Suc_eq_plus1 by (rule numeral_plus_one)
   888 
   889 definition pred_numeral :: "num \<Rightarrow> nat"
   890   where [code del]: "pred_numeral k = numeral k - 1"
   891 
   892 lemma numeral_eq_Suc: "numeral k = Suc (pred_numeral k)"
   893   unfolding pred_numeral_def by simp
   894 
   895 lemma eval_nat_numeral:
   896   "numeral One = Suc 0"
   897   "numeral (Bit0 n) = Suc (numeral (BitM n))"
   898   "numeral (Bit1 n) = Suc (numeral (Bit0 n))"
   899   by (simp_all add: numeral.simps BitM_plus_one)
   900 
   901 lemma pred_numeral_simps [simp]:
   902   "pred_numeral One = 0"
   903   "pred_numeral (Bit0 k) = numeral (BitM k)"
   904   "pred_numeral (Bit1 k) = numeral (Bit0 k)"
   905   unfolding pred_numeral_def eval_nat_numeral
   906   by (simp_all only: diff_Suc_Suc diff_0)
   907 
   908 lemma numeral_2_eq_2: "2 = Suc (Suc 0)"
   909   by (simp add: eval_nat_numeral)
   910 
   911 lemma numeral_3_eq_3: "3 = Suc (Suc (Suc 0))"
   912   by (simp add: eval_nat_numeral)
   913 
   914 lemma numeral_1_eq_Suc_0: "Numeral1 = Suc 0"
   915   by (simp only: numeral_One One_nat_def)
   916 
   917 lemma Suc_nat_number_of_add:
   918   "Suc (numeral v + n) = numeral (v + One) + n"
   919   by simp
   920 
   921 (*Maps #n to n for n = 1, 2*)
   922 lemmas numerals = numeral_One [where 'a=nat] numeral_2_eq_2
   923 
   924 text {* Comparisons involving @{term Suc}. *}
   925 
   926 lemma eq_numeral_Suc [simp]: "numeral k = Suc n \<longleftrightarrow> pred_numeral k = n"
   927   by (simp add: numeral_eq_Suc)
   928 
   929 lemma Suc_eq_numeral [simp]: "Suc n = numeral k \<longleftrightarrow> n = pred_numeral k"
   930   by (simp add: numeral_eq_Suc)
   931 
   932 lemma less_numeral_Suc [simp]: "numeral k < Suc n \<longleftrightarrow> pred_numeral k < n"
   933   by (simp add: numeral_eq_Suc)
   934 
   935 lemma less_Suc_numeral [simp]: "Suc n < numeral k \<longleftrightarrow> n < pred_numeral k"
   936   by (simp add: numeral_eq_Suc)
   937 
   938 lemma le_numeral_Suc [simp]: "numeral k \<le> Suc n \<longleftrightarrow> pred_numeral k \<le> n"
   939   by (simp add: numeral_eq_Suc)
   940 
   941 lemma le_Suc_numeral [simp]: "Suc n \<le> numeral k \<longleftrightarrow> n \<le> pred_numeral k"
   942   by (simp add: numeral_eq_Suc)
   943 
   944 lemma diff_Suc_numeral [simp]: "Suc n - numeral k = n - pred_numeral k"
   945   by (simp add: numeral_eq_Suc)
   946 
   947 lemma diff_numeral_Suc [simp]: "numeral k - Suc n = pred_numeral k - n"
   948   by (simp add: numeral_eq_Suc)
   949 
   950 lemma max_Suc_numeral [simp]:
   951   "max (Suc n) (numeral k) = Suc (max n (pred_numeral k))"
   952   by (simp add: numeral_eq_Suc)
   953 
   954 lemma max_numeral_Suc [simp]:
   955   "max (numeral k) (Suc n) = Suc (max (pred_numeral k) n)"
   956   by (simp add: numeral_eq_Suc)
   957 
   958 lemma min_Suc_numeral [simp]:
   959   "min (Suc n) (numeral k) = Suc (min n (pred_numeral k))"
   960   by (simp add: numeral_eq_Suc)
   961 
   962 lemma min_numeral_Suc [simp]:
   963   "min (numeral k) (Suc n) = Suc (min (pred_numeral k) n)"
   964   by (simp add: numeral_eq_Suc)
   965 
   966 text {* For @{term nat_case} and @{term nat_rec}. *}
   967 
   968 lemma nat_case_numeral [simp]:
   969   "nat_case a f (numeral v) = (let pv = pred_numeral v in f pv)"
   970   by (simp add: numeral_eq_Suc)
   971 
   972 lemma nat_case_add_eq_if [simp]:
   973   "nat_case a f ((numeral v) + n) = (let pv = pred_numeral v in f (pv + n))"
   974   by (simp add: numeral_eq_Suc)
   975 
   976 lemma nat_rec_numeral [simp]:
   977   "nat_rec a f (numeral v) =
   978     (let pv = pred_numeral v in f pv (nat_rec a f pv))"
   979   by (simp add: numeral_eq_Suc Let_def)
   980 
   981 lemma nat_rec_add_eq_if [simp]:
   982   "nat_rec a f (numeral v + n) =
   983     (let pv = pred_numeral v in f (pv + n) (nat_rec a f (pv + n)))"
   984   by (simp add: numeral_eq_Suc Let_def)
   985 
   986 text {* Case analysis on @{term "n < 2"} *}
   987 
   988 lemma less_2_cases: "n < 2 \<Longrightarrow> n = 0 \<or> n = Suc 0"
   989   by (auto simp add: numeral_2_eq_2)
   990 
   991 text {* Removal of Small Numerals: 0, 1 and (in additive positions) 2 *}
   992 text {* bh: Are these rules really a good idea? *}
   993 
   994 lemma add_2_eq_Suc [simp]: "2 + n = Suc (Suc n)"
   995   by simp
   996 
   997 lemma add_2_eq_Suc' [simp]: "n + 2 = Suc (Suc n)"
   998   by simp
   999 
  1000 text {* Can be used to eliminate long strings of Sucs, but not by default. *}
  1001 
  1002 lemma Suc3_eq_add_3: "Suc (Suc (Suc n)) = 3 + n"
  1003   by simp
  1004 
  1005 lemmas nat_1_add_1 = one_add_one [where 'a=nat] (* legacy *)
  1006 
  1007 
  1008 subsection {* Numeral equations as default simplification rules *}
  1009 
  1010 declare (in numeral) numeral_One [simp]
  1011 declare (in numeral) numeral_plus_numeral [simp]
  1012 declare (in numeral) add_numeral_special [simp]
  1013 declare (in neg_numeral) add_neg_numeral_simps [simp]
  1014 declare (in neg_numeral) add_neg_numeral_special [simp]
  1015 declare (in neg_numeral) diff_numeral_simps [simp]
  1016 declare (in neg_numeral) diff_numeral_special [simp]
  1017 declare (in semiring_numeral) numeral_times_numeral [simp]
  1018 declare (in ring_1) mult_neg_numeral_simps [simp]
  1019 
  1020 subsection {* Setting up simprocs *}
  1021 
  1022 lemma mult_numeral_1: "Numeral1 * a = (a::'a::semiring_numeral)"
  1023   by simp
  1024 
  1025 lemma mult_numeral_1_right: "a * Numeral1 = (a::'a::semiring_numeral)"
  1026   by simp
  1027 
  1028 lemma divide_numeral_1: "a / Numeral1 = (a::'a::field)"
  1029   by simp
  1030 
  1031 lemma inverse_numeral_1:
  1032   "inverse Numeral1 = (Numeral1::'a::division_ring)"
  1033   by simp
  1034 
  1035 text{*Theorem lists for the cancellation simprocs. The use of a binary
  1036 numeral for 1 reduces the number of special cases.*}
  1037 
  1038 lemmas mult_1s =
  1039   mult_numeral_1 mult_numeral_1_right 
  1040   mult_minus1 mult_minus1_right
  1041 
  1042 setup {*
  1043   Reorient_Proc.add
  1044     (fn Const (@{const_name numeral}, _) $ _ => true
  1045     | Const (@{const_name neg_numeral}, _) $ _ => true
  1046     | _ => false)
  1047 *}
  1048 
  1049 simproc_setup reorient_numeral
  1050   ("numeral w = x" | "neg_numeral w = y") = Reorient_Proc.proc
  1051 
  1052 
  1053 subsubsection {* Simplification of arithmetic operations on integer constants. *}
  1054 
  1055 lemmas arith_special = (* already declared simp above *)
  1056   add_numeral_special add_neg_numeral_special
  1057   diff_numeral_special minus_one
  1058 
  1059 (* rules already in simpset *)
  1060 lemmas arith_extra_simps =
  1061   numeral_plus_numeral add_neg_numeral_simps add_0_left add_0_right
  1062   minus_numeral minus_neg_numeral minus_zero minus_one
  1063   diff_numeral_simps diff_0 diff_0_right
  1064   numeral_times_numeral mult_neg_numeral_simps
  1065   mult_zero_left mult_zero_right
  1066   abs_numeral abs_neg_numeral
  1067 
  1068 text {*
  1069   For making a minimal simpset, one must include these default simprules.
  1070   Also include @{text simp_thms}.
  1071 *}
  1072 
  1073 lemmas arith_simps =
  1074   add_num_simps mult_num_simps sub_num_simps
  1075   BitM.simps dbl_simps dbl_inc_simps dbl_dec_simps
  1076   abs_zero abs_one arith_extra_simps
  1077 
  1078 text {* Simplification of relational operations *}
  1079 
  1080 lemmas eq_numeral_extra =
  1081   zero_neq_one one_neq_zero
  1082 
  1083 lemmas rel_simps =
  1084   le_num_simps less_num_simps eq_num_simps
  1085   le_numeral_simps le_neg_numeral_simps le_numeral_extra
  1086   less_numeral_simps less_neg_numeral_simps less_numeral_extra
  1087   eq_numeral_simps eq_neg_numeral_simps eq_numeral_extra
  1088 
  1089 
  1090 subsubsection {* Simplification of arithmetic when nested to the right. *}
  1091 
  1092 lemma add_numeral_left [simp]:
  1093   "numeral v + (numeral w + z) = (numeral(v + w) + z)"
  1094   by (simp_all add: add_assoc [symmetric])
  1095 
  1096 lemma add_neg_numeral_left [simp]:
  1097   "numeral v + (neg_numeral w + y) = (sub v w + y)"
  1098   "neg_numeral v + (numeral w + y) = (sub w v + y)"
  1099   "neg_numeral v + (neg_numeral w + y) = (neg_numeral(v + w) + y)"
  1100   by (simp_all add: add_assoc [symmetric])
  1101 
  1102 lemma mult_numeral_left [simp]:
  1103   "numeral v * (numeral w * z) = (numeral(v * w) * z :: 'a::semiring_numeral)"
  1104   "neg_numeral v * (numeral w * y) = (neg_numeral(v * w) * y :: 'b::ring_1)"
  1105   "numeral v * (neg_numeral w * y) = (neg_numeral(v * w) * y :: 'b::ring_1)"
  1106   "neg_numeral v * (neg_numeral w * y) = (numeral(v * w) * y :: 'b::ring_1)"
  1107   by (simp_all add: mult_assoc [symmetric])
  1108 
  1109 hide_const (open) One Bit0 Bit1 BitM inc pow sqr sub dbl dbl_inc dbl_dec
  1110 
  1111 
  1112 subsection {* code module namespace *}
  1113 
  1114 code_modulename SML
  1115   Num Arith
  1116 
  1117 code_modulename OCaml
  1118   Num Arith
  1119 
  1120 code_modulename Haskell
  1121   Num Arith
  1122 
  1123 end
  1124 
  1125