src/Pure/sign.ML
author wenzelm
Sat May 25 15:37:53 2013 +0200 (2013-05-25)
changeset 52143 36ffe23b25f8
parent 47008 8b13ebf3eda4
child 56025 d74fed45fa8b
permissions -rw-r--r--
syntax translations always depend on context;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val syn_of: theory -> Syntax.syntax
    11   val tsig_of: theory -> Type.tsig
    12   val classes_of: theory -> Sorts.algebra
    13   val all_classes: theory -> class list
    14   val super_classes: theory -> class -> class list
    15   val minimize_sort: theory -> sort -> sort
    16   val complete_sort: theory -> sort -> sort
    17   val set_defsort: sort -> theory -> theory
    18   val defaultS: theory -> sort
    19   val subsort: theory -> sort * sort -> bool
    20   val of_sort: theory -> typ * sort -> bool
    21   val inter_sort: theory -> sort * sort -> sort
    22   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    23   val is_logtype: theory -> string -> bool
    24   val typ_instance: theory -> typ * typ -> bool
    25   val typ_equiv: theory -> typ * typ -> bool
    26   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    27   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    28   val consts_of: theory -> Consts.T
    29   val the_const_constraint: theory -> string -> typ
    30   val const_type: theory -> string -> typ option
    31   val the_const_type: theory -> string -> typ
    32   val declared_tyname: theory -> string -> bool
    33   val declared_const: theory -> string -> bool
    34   val naming_of: theory -> Name_Space.naming
    35   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    36   val restore_naming: theory -> theory -> theory
    37   val inherit_naming: theory -> Proof.context -> Context.generic
    38   val full_name: theory -> binding -> string
    39   val full_name_path: theory -> string -> binding -> string
    40   val full_bname: theory -> bstring -> string
    41   val full_bname_path: theory -> string -> bstring -> string
    42   val const_monomorphic: theory -> string -> bool
    43   val const_typargs: theory -> string * typ -> typ list
    44   val const_instance: theory -> string * typ list -> typ
    45   val mk_const: theory -> string * typ list -> term
    46   val class_space: theory -> Name_Space.T
    47   val type_space: theory -> Name_Space.T
    48   val const_space: theory -> Name_Space.T
    49   val intern_class: theory -> xstring -> string
    50   val intern_type: theory -> xstring -> string
    51   val intern_const: theory -> xstring -> string
    52   val class_alias: binding -> class -> theory -> theory
    53   val type_alias: binding -> string -> theory -> theory
    54   val const_alias: binding -> string -> theory -> theory
    55   val arity_number: theory -> string -> int
    56   val arity_sorts: theory -> string -> sort -> sort list
    57   val certify_class: theory -> class -> class
    58   val certify_sort: theory -> sort -> sort
    59   val certify_typ: theory -> typ -> typ
    60   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    61   val certify': bool -> Context.pretty -> bool -> Consts.T -> theory -> term -> term * typ * int
    62   val certify_term: theory -> term -> term * typ * int
    63   val cert_term: theory -> term -> term
    64   val cert_prop: theory -> term -> term
    65   val no_frees: Proof.context -> term -> term
    66   val no_vars: Proof.context -> term -> term
    67   val add_type: Proof.context -> binding * int * mixfix -> theory -> theory
    68   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    69   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    70   val add_nonterminals_global: binding list -> theory -> theory
    71   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    72   val add_syntax: (string * string * mixfix) list -> theory -> theory
    73   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    74   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    75   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    76   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    77   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    78   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    79   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    80   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    81   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    82   val add_consts: (binding * string * mixfix) list -> theory -> theory
    83   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    84   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    85   val revert_abbrev: string -> string -> theory -> theory
    86   val add_const_constraint: string * typ option -> theory -> theory
    87   val primitive_class: binding * class list -> theory -> theory
    88   val primitive_classrel: class * class -> theory -> theory
    89   val primitive_arity: arity -> theory -> theory
    90   val parse_ast_translation:
    91     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
    92   val parse_translation:
    93     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    94   val print_translation:
    95     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    96   val typed_print_translation:
    97     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
    98   val print_ast_translation:
    99     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   100   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   101   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   102   val new_group: theory -> theory
   103   val reset_group: theory -> theory
   104   val add_path: string -> theory -> theory
   105   val root_path: theory -> theory
   106   val parent_path: theory -> theory
   107   val mandatory_path: string -> theory -> theory
   108   val qualified_path: bool -> binding -> theory -> theory
   109   val local_path: theory -> theory
   110   val hide_class: bool -> string -> theory -> theory
   111   val hide_type: bool -> string -> theory -> theory
   112   val hide_const: bool -> string -> theory -> theory
   113 end
   114 
   115 structure Sign: SIGN =
   116 struct
   117 
   118 (** datatype sign **)
   119 
   120 datatype sign = Sign of
   121  {syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   122   tsig: Type.tsig,              (*order-sorted signature of types*)
   123   consts: Consts.T};            (*polymorphic constants*)
   124 
   125 fun make_sign (syn, tsig, consts) = Sign {syn = syn, tsig = tsig, consts = consts};
   126 
   127 structure Data = Theory_Data_PP
   128 (
   129   type T = sign;
   130   fun extend (Sign {syn, tsig, consts, ...}) = make_sign (syn, tsig, consts);
   131 
   132   val empty = make_sign (Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   133 
   134   fun merge pp (sign1, sign2) =
   135     let
   136       val Sign {syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   137       val Sign {syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   138 
   139       val syn = Syntax.merge_syntax (syn1, syn2);
   140       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   141       val consts = Consts.merge (consts1, consts2);
   142     in make_sign (syn, tsig, consts) end;
   143 );
   144 
   145 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   146 
   147 fun map_sign f = Data.map (fn Sign {syn, tsig, consts} => make_sign (f (syn, tsig, consts)));
   148 
   149 fun map_syn f = map_sign (fn (syn, tsig, consts) => (f syn, tsig, consts));
   150 fun map_tsig f = map_sign (fn (syn, tsig, consts) => (syn, f tsig, consts));
   151 fun map_consts f = map_sign (fn (syn, tsig, consts) => (syn, tsig, f consts));
   152 
   153 
   154 (* syntax *)
   155 
   156 val syn_of = #syn o rep_sg;
   157 
   158 
   159 (* type signature *)
   160 
   161 val tsig_of = #tsig o rep_sg;
   162 
   163 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   164 val all_classes = Sorts.all_classes o classes_of;
   165 val super_classes = Sorts.super_classes o classes_of;
   166 val minimize_sort = Sorts.minimize_sort o classes_of;
   167 val complete_sort = Sorts.complete_sort o classes_of;
   168 
   169 val set_defsort = map_tsig o Type.set_defsort;
   170 val defaultS = Type.defaultS o tsig_of;
   171 val subsort = Type.subsort o tsig_of;
   172 val of_sort = Type.of_sort o tsig_of;
   173 val inter_sort = Type.inter_sort o tsig_of;
   174 val witness_sorts = Type.witness_sorts o tsig_of;
   175 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   176 
   177 val typ_instance = Type.typ_instance o tsig_of;
   178 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   179 val typ_match = Type.typ_match o tsig_of;
   180 val typ_unify = Type.unify o tsig_of;
   181 
   182 
   183 (* polymorphic constants *)
   184 
   185 val consts_of = #consts o rep_sg;
   186 val the_const_constraint = Consts.the_constraint o consts_of;
   187 val the_const_type = #2 oo (Consts.the_const o consts_of);
   188 val const_type = try o the_const_type;
   189 val const_monomorphic = Consts.is_monomorphic o consts_of;
   190 val const_typargs = Consts.typargs o consts_of;
   191 val const_instance = Consts.instance o consts_of;
   192 
   193 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   194 
   195 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   196 val declared_const = can o the_const_constraint;
   197 
   198 
   199 (* naming *)
   200 
   201 val naming_of = Name_Space.naming_of o Context.Theory;
   202 val map_naming = Context.theory_map o Name_Space.map_naming;
   203 val restore_naming = map_naming o K o naming_of;
   204 fun inherit_naming thy = Name_Space.map_naming (K (naming_of thy)) o Context.Proof;
   205 
   206 val full_name = Name_Space.full_name o naming_of;
   207 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   208 
   209 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   210 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   211 
   212 
   213 
   214 (** name spaces **)
   215 
   216 val class_space = Type.class_space o tsig_of;
   217 val type_space = Type.type_space o tsig_of;
   218 val const_space = Consts.space_of o consts_of;
   219 
   220 val intern_class = Name_Space.intern o class_space;
   221 val intern_type = Name_Space.intern o type_space;
   222 val intern_const = Name_Space.intern o const_space;
   223 
   224 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   225 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   226 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   227 
   228 
   229 
   230 (** certify entities **)    (*exception TYPE*)
   231 
   232 (* certify wrt. type signature *)
   233 
   234 val arity_number = Type.arity_number o tsig_of;
   235 fun arity_sorts thy = Type.arity_sorts (Context.pretty_global thy) (tsig_of thy);
   236 
   237 val certify_class = Type.cert_class o tsig_of;
   238 val certify_sort = Type.cert_sort o tsig_of;
   239 val certify_typ = Type.cert_typ o tsig_of;
   240 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   241 
   242 
   243 (* certify term/prop *)
   244 
   245 local
   246 
   247 fun type_check pp tm =
   248   let
   249     fun err_appl bs t T u U =
   250       let
   251         val xs = map Free bs;           (*we do not rename here*)
   252         val t' = subst_bounds (xs, t);
   253         val u' = subst_bounds (xs, u);
   254         val msg = Type.appl_error (Syntax.init_pretty pp) t' T u' U;
   255       in raise TYPE (msg, [T, U], [t', u']) end;
   256 
   257     fun typ_of (_, Const (_, T)) = T
   258       | typ_of (_, Free  (_, T)) = T
   259       | typ_of (_, Var (_, T)) = T
   260       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   261           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   262       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   263       | typ_of (bs, t $ u) =
   264           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   265             (case T of
   266               Type ("fun", [T1, T2]) =>
   267                 if T1 = U then T2 else err_appl bs t T u U
   268             | _ => err_appl bs t T u U)
   269           end;
   270   in typ_of ([], tm) end;
   271 
   272 fun err msg = raise TYPE (msg, [], []);
   273 
   274 fun check_vars (t $ u) = (check_vars t; check_vars u)
   275   | check_vars (Abs (_, _, t)) = check_vars t
   276   | check_vars (Free (x, _)) =
   277       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   278   | check_vars (Var (xi as (_, i), _)) =
   279       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   280   | check_vars _ = ();
   281 
   282 in
   283 
   284 fun certify' prop pp do_expand consts thy tm =
   285   let
   286     val _ = check_vars tm;
   287     val tm' = Term.map_types (certify_typ thy) tm;
   288     val T = type_check pp tm';
   289     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   290     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   291   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   292 
   293 fun certify_term thy = certify' false (Context.pretty_global thy) true (consts_of thy) thy;
   294 fun cert_term_abbrev thy =
   295   #1 o certify' false (Context.pretty_global thy) false (consts_of thy) thy;
   296 val cert_term = #1 oo certify_term;
   297 fun cert_prop thy = #1 o certify' true (Context.pretty_global thy) true (consts_of thy) thy;
   298 
   299 end;
   300 
   301 
   302 (* specifications *)
   303 
   304 fun no_variables kind add addT mk mkT ctxt tm =
   305   (case (add tm [], addT tm []) of
   306     ([], []) => tm
   307   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   308       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   309        Pretty.commas
   310         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   311 
   312 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   313 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   314 
   315 
   316 
   317 (** signature extension functions **)  (*exception ERROR/TYPE*)
   318 
   319 (* add type constructors *)
   320 
   321 fun add_type ctxt (b, n, mx) thy = thy |> map_sign (fn (syn, tsig, consts) =>
   322   let
   323     val type_syntax = (Lexicon.mark_type (full_name thy b), Mixfix.make_type n, mx);
   324     val syn' = Syntax.update_type_gram true Syntax.mode_default [type_syntax] syn;
   325     val tsig' = Type.add_type (inherit_naming thy ctxt) (b, n) tsig;
   326   in (syn', tsig', consts) end);
   327 
   328 fun add_types_global types thy =
   329   fold (add_type (Syntax.init_pretty_global thy)) types thy;
   330 
   331 
   332 (* add nonterminals *)
   333 
   334 fun add_nonterminals ctxt ns thy = thy |> map_sign (fn (syn, tsig, consts) =>
   335   (syn, fold (Type.add_nonterminal (inherit_naming thy ctxt)) ns tsig, consts));
   336 
   337 fun add_nonterminals_global ns thy =
   338   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   339 
   340 
   341 (* add type abbreviations *)
   342 
   343 fun add_type_abbrev ctxt abbr thy = thy |> map_sign (fn (syn, tsig, consts) =>
   344   (syn, Type.add_abbrev (inherit_naming thy ctxt) abbr tsig, consts));
   345 
   346 
   347 (* modify syntax *)
   348 
   349 fun gen_syntax change_gram parse_typ mode args thy =
   350   let
   351     val ctxt = Type.set_mode Type.mode_syntax (Proof_Context.init_global thy);
   352     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   353       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   354   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   355 
   356 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   357 
   358 val add_modesyntax = gen_add_syntax Syntax.read_typ;
   359 val add_modesyntax_i = gen_add_syntax (K I);
   360 val add_syntax = add_modesyntax Syntax.mode_default;
   361 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   362 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.read_typ;
   363 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   364 
   365 fun type_notation add mode args =
   366   let
   367     fun type_syntax (Type (c, args), mx) =
   368           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   369       | type_syntax _ = NONE;
   370   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   371 
   372 fun notation add mode args thy =
   373   let
   374     fun const_syntax (Const (c, _), mx) =
   375           (case try (Consts.type_scheme (consts_of thy)) c of
   376             SOME T => SOME (Lexicon.mark_const c, T, mx)
   377           | NONE => NONE)
   378       | const_syntax _ = NONE;
   379   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   380 
   381 
   382 (* add constants *)
   383 
   384 local
   385 
   386 fun gen_add_consts prep_typ ctxt raw_args thy =
   387   let
   388     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o prep_typ ctxt;
   389     fun prep (b, raw_T, mx) =
   390       let
   391         val c = full_name thy b;
   392         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   393           cat_error msg ("in declaration of constant " ^ Binding.print b);
   394         val T' = Logic.varifyT_global T;
   395       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   396     val args = map prep raw_args;
   397   in
   398     thy
   399     |> map_consts (fold (Consts.declare (inherit_naming thy ctxt) o #1) args)
   400     |> add_syntax_i (map #2 args)
   401     |> pair (map #3 args)
   402   end;
   403 
   404 in
   405 
   406 fun add_consts args thy =
   407   #2 (gen_add_consts Syntax.read_typ (Proof_Context.init_global thy) args thy);
   408 
   409 fun add_consts_i args thy =
   410   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   411 
   412 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   413 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   414 
   415 end;
   416 
   417 
   418 (* abbreviations *)
   419 
   420 fun add_abbrev mode (b, raw_t) thy =  (* FIXME proper ctxt (?) *)
   421   let
   422     val ctxt = Syntax.init_pretty_global thy;
   423     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   424     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   425       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   426     val (res, consts') = consts_of thy
   427       |> Consts.abbreviate (inherit_naming thy ctxt) (tsig_of thy) mode (b, t);
   428   in (res, thy |> map_consts (K consts')) end;
   429 
   430 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   431 
   432 
   433 (* add constraints *)
   434 
   435 fun add_const_constraint (c, opt_T) thy =
   436   let
   437     fun prepT raw_T =
   438       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   439       in cert_term thy (Const (c, T)); T end
   440       handle TYPE (msg, _, _) => error msg;
   441   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   442 
   443 
   444 (* primitive classes and arities *)
   445 
   446 fun primitive_class (bclass, classes) thy =
   447   thy
   448   |> map_sign (fn (syn, tsig, consts) =>
   449       let val tsig' = Type.add_class (Context.Theory thy) (bclass, classes) tsig;
   450       in (syn, tsig', consts) end)
   451   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   452 
   453 fun primitive_classrel arg thy =
   454   thy |> map_tsig (Type.add_classrel (Context.pretty_global thy) arg);
   455 
   456 fun primitive_arity arg thy =
   457   thy |> map_tsig (Type.add_arity (Context.pretty_global thy) arg);
   458 
   459 
   460 (* add translation functions *)
   461 
   462 local
   463 
   464 fun mk trs = map Syntax_Ext.mk_trfun trs;
   465 
   466 in
   467 
   468 fun parse_ast_translation atrs = map_syn (Syntax.update_trfuns (mk atrs, [], [], []));
   469 fun parse_translation trs = map_syn (Syntax.update_trfuns ([], mk trs, [], []));
   470 fun print_translation tr's =
   471   map_syn (Syntax.update_trfuns ([], [], mk (map (apsnd Syntax_Trans.non_typed_tr') tr's), []));
   472 fun typed_print_translation tr's = map_syn (Syntax.update_trfuns ([], [], mk tr's, []));
   473 fun print_ast_translation atr's = map_syn (Syntax.update_trfuns ([], [], [], mk atr's));
   474 
   475 end;
   476 
   477 
   478 (* translation rules *)
   479 
   480 val add_trrules = map_syn o Syntax.update_trrules;
   481 val del_trrules = map_syn o Syntax.remove_trrules;
   482 
   483 
   484 (* naming *)
   485 
   486 val new_group = map_naming Name_Space.new_group;
   487 val reset_group = map_naming Name_Space.reset_group;
   488 
   489 val add_path = map_naming o Name_Space.add_path;
   490 val root_path = map_naming Name_Space.root_path;
   491 val parent_path = map_naming Name_Space.parent_path;
   492 val mandatory_path = map_naming o Name_Space.mandatory_path;
   493 val qualified_path = map_naming oo Name_Space.qualified_path;
   494 
   495 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   496 
   497 
   498 (* hide names *)
   499 
   500 val hide_class = map_tsig oo Type.hide_class;
   501 val hide_type = map_tsig oo Type.hide_type;
   502 val hide_const = map_consts oo Consts.hide;
   503 
   504 end;