src/HOL/IntDef.thy
author haftmann
Thu Jul 19 21:47:37 2007 +0200 (2007-07-19)
changeset 23852 3736cdf9398b
parent 23705 315c638d5856
child 23879 4776af8be741
permissions -rw-r--r--
moved set Nats to Nat.thy
     1 (*  Title:      IntDef.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 
     6 *)
     7 
     8 header{*The Integers as Equivalence Classes over Pairs of Natural Numbers*} 
     9 
    10 theory IntDef
    11 imports Equiv_Relations Nat
    12 begin
    13 
    14 
    15 text {* the equivalence relation underlying the integers *}
    16 
    17 definition
    18   intrel :: "((nat \<times> nat) \<times> (nat \<times> nat)) set"
    19 where
    20   "intrel = {((x, y), (u, v)) | x y u v. x + v = u +y }"
    21 
    22 typedef (Integ)
    23   int = "UNIV//intrel"
    24   by (auto simp add: quotient_def)
    25 
    26 instance int :: zero
    27   Zero_int_def: "0 \<equiv> Abs_Integ (intrel `` {(0, 0)})" ..
    28 
    29 instance int :: one
    30   One_int_def: "1 \<equiv> Abs_Integ (intrel `` {(1, 0)})" ..
    31 
    32 instance int :: plus
    33   add_int_def: "z + w \<equiv> Abs_Integ
    34     (\<Union>(x, y) \<in> Rep_Integ z. \<Union>(u, v) \<in> Rep_Integ w.
    35       intrel `` {(x + u, y + v)})" ..
    36 
    37 instance int :: minus
    38   minus_int_def:
    39     "- z \<equiv> Abs_Integ (\<Union>(x, y) \<in> Rep_Integ z. intrel `` {(y, x)})"
    40   diff_int_def:  "z - w \<equiv> z + (-w)" ..
    41 
    42 instance int :: times
    43   mult_int_def: "z * w \<equiv>  Abs_Integ
    44     (\<Union>(x, y) \<in> Rep_Integ z. \<Union>(u,v ) \<in> Rep_Integ w.
    45       intrel `` {(x*u + y*v, x*v + y*u)})" ..
    46 
    47 instance int :: ord
    48   le_int_def:
    49    "z \<le> w \<equiv> \<exists>x y u v. x+v \<le> u+y \<and> (x, y) \<in> Rep_Integ z \<and> (u, v) \<in> Rep_Integ w"
    50   less_int_def: "z < w \<equiv> z \<le> w \<and> z \<noteq> w" ..
    51 
    52 lemmas [code func del] = Zero_int_def One_int_def add_int_def
    53   minus_int_def mult_int_def le_int_def less_int_def
    54 
    55 
    56 subsection{*Construction of the Integers*}
    57 
    58 lemma intrel_iff [simp]: "(((x,y),(u,v)) \<in> intrel) = (x+v = u+y)"
    59 by (simp add: intrel_def)
    60 
    61 lemma equiv_intrel: "equiv UNIV intrel"
    62 by (simp add: intrel_def equiv_def refl_def sym_def trans_def)
    63 
    64 text{*Reduces equality of equivalence classes to the @{term intrel} relation:
    65   @{term "(intrel `` {x} = intrel `` {y}) = ((x,y) \<in> intrel)"} *}
    66 lemmas equiv_intrel_iff [simp] = eq_equiv_class_iff [OF equiv_intrel UNIV_I UNIV_I]
    67 
    68 text{*All equivalence classes belong to set of representatives*}
    69 lemma [simp]: "intrel``{(x,y)} \<in> Integ"
    70 by (auto simp add: Integ_def intrel_def quotient_def)
    71 
    72 text{*Reduces equality on abstractions to equality on representatives:
    73   @{prop "\<lbrakk>x \<in> Integ; y \<in> Integ\<rbrakk> \<Longrightarrow> (Abs_Integ x = Abs_Integ y) = (x=y)"} *}
    74 declare Abs_Integ_inject [simp]  Abs_Integ_inverse [simp]
    75 
    76 text{*Case analysis on the representation of an integer as an equivalence
    77       class of pairs of naturals.*}
    78 lemma eq_Abs_Integ [case_names Abs_Integ, cases type: int]:
    79      "(!!x y. z = Abs_Integ(intrel``{(x,y)}) ==> P) ==> P"
    80 apply (rule Abs_Integ_cases [of z]) 
    81 apply (auto simp add: Integ_def quotient_def) 
    82 done
    83 
    84 
    85 subsection{*Arithmetic Operations*}
    86 
    87 lemma minus: "- Abs_Integ(intrel``{(x,y)}) = Abs_Integ(intrel `` {(y,x)})"
    88 proof -
    89   have "(\<lambda>(x,y). intrel``{(y,x)}) respects intrel"
    90     by (simp add: congruent_def) 
    91   thus ?thesis
    92     by (simp add: minus_int_def UN_equiv_class [OF equiv_intrel])
    93 qed
    94 
    95 lemma add:
    96      "Abs_Integ (intrel``{(x,y)}) + Abs_Integ (intrel``{(u,v)}) =
    97       Abs_Integ (intrel``{(x+u, y+v)})"
    98 proof -
    99   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). intrel `` {(x+u, y+v)}) w) z) 
   100         respects2 intrel"
   101     by (simp add: congruent2_def)
   102   thus ?thesis
   103     by (simp add: add_int_def UN_UN_split_split_eq
   104                   UN_equiv_class2 [OF equiv_intrel equiv_intrel])
   105 qed
   106 
   107 text{*Congruence property for multiplication*}
   108 lemma mult_congruent2:
   109      "(%p1 p2. (%(x,y). (%(u,v). intrel``{(x*u + y*v, x*v + y*u)}) p2) p1)
   110       respects2 intrel"
   111 apply (rule equiv_intrel [THEN congruent2_commuteI])
   112  apply (force simp add: mult_ac, clarify) 
   113 apply (simp add: congruent_def mult_ac)  
   114 apply (rename_tac u v w x y z)
   115 apply (subgoal_tac "u*y + x*y = w*y + v*y  &  u*z + x*z = w*z + v*z")
   116 apply (simp add: mult_ac)
   117 apply (simp add: add_mult_distrib [symmetric])
   118 done
   119 
   120 lemma mult:
   121      "Abs_Integ((intrel``{(x,y)})) * Abs_Integ((intrel``{(u,v)})) =
   122       Abs_Integ(intrel `` {(x*u + y*v, x*v + y*u)})"
   123 by (simp add: mult_int_def UN_UN_split_split_eq mult_congruent2
   124               UN_equiv_class2 [OF equiv_intrel equiv_intrel])
   125 
   126 text{*The integers form a @{text comm_ring_1}*}
   127 instance int :: comm_ring_1
   128 proof
   129   fix i j k :: int
   130   show "(i + j) + k = i + (j + k)"
   131     by (cases i, cases j, cases k) (simp add: add add_assoc)
   132   show "i + j = j + i" 
   133     by (cases i, cases j) (simp add: add_ac add)
   134   show "0 + i = i"
   135     by (cases i) (simp add: Zero_int_def add)
   136   show "- i + i = 0"
   137     by (cases i) (simp add: Zero_int_def minus add)
   138   show "i - j = i + - j"
   139     by (simp add: diff_int_def)
   140   show "(i * j) * k = i * (j * k)"
   141     by (cases i, cases j, cases k) (simp add: mult ring_simps)
   142   show "i * j = j * i"
   143     by (cases i, cases j) (simp add: mult ring_simps)
   144   show "1 * i = i"
   145     by (cases i) (simp add: One_int_def mult)
   146   show "(i + j) * k = i * k + j * k"
   147     by (cases i, cases j, cases k) (simp add: add mult ring_simps)
   148   show "0 \<noteq> (1::int)"
   149     by (simp add: Zero_int_def One_int_def)
   150 qed
   151 
   152 abbreviation
   153   int :: "nat \<Rightarrow> int"
   154 where
   155   "int \<equiv> of_nat"
   156 
   157 lemma int_def: "int m = Abs_Integ (intrel `` {(m, 0)})"
   158 by (induct m, simp_all add: Zero_int_def One_int_def add)
   159 
   160 
   161 subsection{*The @{text "\<le>"} Ordering*}
   162 
   163 lemma le:
   164   "(Abs_Integ(intrel``{(x,y)}) \<le> Abs_Integ(intrel``{(u,v)})) = (x+v \<le> u+y)"
   165 by (force simp add: le_int_def)
   166 
   167 lemma less:
   168   "(Abs_Integ(intrel``{(x,y)}) < Abs_Integ(intrel``{(u,v)})) = (x+v < u+y)"
   169 by (simp add: less_int_def le order_less_le)
   170 
   171 instance int :: linorder
   172 proof
   173   fix i j k :: int
   174   show "(i < j) = (i \<le> j \<and> i \<noteq> j)"
   175     by (simp add: less_int_def)
   176   show "i \<le> i"
   177     by (cases i) (simp add: le)
   178   show "i \<le> j \<Longrightarrow> j \<le> k \<Longrightarrow> i \<le> k"
   179     by (cases i, cases j, cases k) (simp add: le)
   180   show "i \<le> j \<Longrightarrow> j \<le> i \<Longrightarrow> i = j"
   181     by (cases i, cases j) (simp add: le)
   182   show "i \<le> j \<or> j \<le> i"
   183     by (cases i, cases j) (simp add: le linorder_linear)
   184 qed
   185 
   186 instance int :: pordered_cancel_ab_semigroup_add
   187 proof
   188   fix i j k :: int
   189   show "i \<le> j \<Longrightarrow> k + i \<le> k + j"
   190     by (cases i, cases j, cases k) (simp add: le add)
   191 qed
   192 
   193 text{*Strict Monotonicity of Multiplication*}
   194 
   195 text{*strict, in 1st argument; proof is by induction on k>0*}
   196 lemma zmult_zless_mono2_lemma:
   197      "(i::int)<j ==> 0<k ==> int k * i < int k * j"
   198 apply (induct "k", simp)
   199 apply (simp add: left_distrib)
   200 apply (case_tac "k=0")
   201 apply (simp_all add: add_strict_mono)
   202 done
   203 
   204 lemma zero_le_imp_eq_int: "(0::int) \<le> k ==> \<exists>n. k = int n"
   205 apply (cases k)
   206 apply (auto simp add: le add int_def Zero_int_def)
   207 apply (rule_tac x="x-y" in exI, simp)
   208 done
   209 
   210 lemma zero_less_imp_eq_int: "(0::int) < k ==> \<exists>n>0. k = int n"
   211 apply (cases k)
   212 apply (simp add: less int_def Zero_int_def)
   213 apply (rule_tac x="x-y" in exI, simp)
   214 done
   215 
   216 lemma zmult_zless_mono2: "[| i<j;  (0::int) < k |] ==> k*i < k*j"
   217 apply (drule zero_less_imp_eq_int)
   218 apply (auto simp add: zmult_zless_mono2_lemma)
   219 done
   220 
   221 instance int :: minus
   222   zabs_def: "\<bar>i\<Colon>int\<bar> \<equiv> if i < 0 then - i else i" ..
   223 
   224 instance int :: distrib_lattice
   225   "inf \<equiv> min"
   226   "sup \<equiv> max"
   227   by intro_classes
   228     (auto simp add: inf_int_def sup_int_def min_max.sup_inf_distrib1)
   229 
   230 text{*The integers form an ordered integral domain*}
   231 instance int :: ordered_idom
   232 proof
   233   fix i j k :: int
   234   show "i < j \<Longrightarrow> 0 < k \<Longrightarrow> k * i < k * j"
   235     by (rule zmult_zless_mono2)
   236   show "\<bar>i\<bar> = (if i < 0 then -i else i)"
   237     by (simp only: zabs_def)
   238 qed
   239 
   240 lemma zless_imp_add1_zle: "w<z ==> w + (1::int) \<le> z"
   241 apply (cases w, cases z) 
   242 apply (simp add: less le add One_int_def)
   243 done
   244 
   245 
   246 subsection{*Magnitude of an Integer, as a Natural Number: @{term nat}*}
   247 
   248 definition
   249   nat :: "int \<Rightarrow> nat"
   250 where
   251   [code func del]: "nat z = contents (\<Union>(x, y) \<in> Rep_Integ z. {x-y})"
   252 
   253 lemma nat: "nat (Abs_Integ (intrel``{(x,y)})) = x-y"
   254 proof -
   255   have "(\<lambda>(x,y). {x-y}) respects intrel"
   256     by (simp add: congruent_def) arith
   257   thus ?thesis
   258     by (simp add: nat_def UN_equiv_class [OF equiv_intrel])
   259 qed
   260 
   261 lemma nat_int [simp]: "nat (int n) = n"
   262 by (simp add: nat int_def)
   263 
   264 lemma nat_zero [simp]: "nat 0 = 0"
   265 by (simp add: Zero_int_def nat)
   266 
   267 lemma int_nat_eq [simp]: "int (nat z) = (if 0 \<le> z then z else 0)"
   268 by (cases z, simp add: nat le int_def Zero_int_def)
   269 
   270 corollary nat_0_le: "0 \<le> z ==> int (nat z) = z"
   271 by simp
   272 
   273 lemma nat_le_0 [simp]: "z \<le> 0 ==> nat z = 0"
   274 by (cases z, simp add: nat le Zero_int_def)
   275 
   276 lemma nat_le_eq_zle: "0 < w | 0 \<le> z ==> (nat w \<le> nat z) = (w\<le>z)"
   277 apply (cases w, cases z) 
   278 apply (simp add: nat le linorder_not_le [symmetric] Zero_int_def, arith)
   279 done
   280 
   281 text{*An alternative condition is @{term "0 \<le> w"} *}
   282 corollary nat_mono_iff: "0 < z ==> (nat w < nat z) = (w < z)"
   283 by (simp add: nat_le_eq_zle linorder_not_le [symmetric]) 
   284 
   285 corollary nat_less_eq_zless: "0 \<le> w ==> (nat w < nat z) = (w<z)"
   286 by (simp add: nat_le_eq_zle linorder_not_le [symmetric]) 
   287 
   288 lemma zless_nat_conj [simp]: "(nat w < nat z) = (0 < z & w < z)"
   289 apply (cases w, cases z) 
   290 apply (simp add: nat le Zero_int_def linorder_not_le [symmetric], arith)
   291 done
   292 
   293 lemma nonneg_eq_int: "[| 0 \<le> z;  !!m. z = int m ==> P |] ==> P"
   294 by (blast dest: nat_0_le sym)
   295 
   296 lemma nat_eq_iff: "(nat w = m) = (if 0 \<le> w then w = int m else m=0)"
   297 by (cases w, simp add: nat le int_def Zero_int_def, arith)
   298 
   299 corollary nat_eq_iff2: "(m = nat w) = (if 0 \<le> w then w = int m else m=0)"
   300 by (simp only: eq_commute [of m] nat_eq_iff)
   301 
   302 lemma nat_less_iff: "0 \<le> w ==> (nat w < m) = (w < int m)"
   303 apply (cases w)
   304 apply (simp add: nat le int_def Zero_int_def linorder_not_le [symmetric], arith)
   305 done
   306 
   307 lemma int_eq_iff: "(int m = z) = (m = nat z & 0 \<le> z)"
   308 by (auto simp add: nat_eq_iff2)
   309 
   310 lemma zero_less_nat_eq [simp]: "(0 < nat z) = (0 < z)"
   311 by (insert zless_nat_conj [of 0], auto)
   312 
   313 lemma nat_add_distrib:
   314      "[| (0::int) \<le> z;  0 \<le> z' |] ==> nat (z+z') = nat z + nat z'"
   315 by (cases z, cases z', simp add: nat add le Zero_int_def)
   316 
   317 lemma nat_diff_distrib:
   318      "[| (0::int) \<le> z';  z' \<le> z |] ==> nat (z-z') = nat z - nat z'"
   319 by (cases z, cases z', 
   320     simp add: nat add minus diff_minus le Zero_int_def)
   321 
   322 lemma nat_zminus_int [simp]: "nat (- (int n)) = 0"
   323 by (simp add: int_def minus nat Zero_int_def) 
   324 
   325 lemma zless_nat_eq_int_zless: "(m < nat z) = (int m < z)"
   326 by (cases z, simp add: nat less int_def, arith)
   327 
   328 
   329 subsection{*Lemmas about the Function @{term int} and Orderings*}
   330 
   331 lemma negative_zless_0: "- (int (Suc n)) < 0"
   332 by (simp add: order_less_le del: of_nat_Suc)
   333 
   334 lemma negative_zless [iff]: "- (int (Suc n)) < int m"
   335 by (rule negative_zless_0 [THEN order_less_le_trans], simp)
   336 
   337 lemma negative_zle_0: "- int n \<le> 0"
   338 by (simp add: minus_le_iff)
   339 
   340 lemma negative_zle [iff]: "- int n \<le> int m"
   341 by (rule order_trans [OF negative_zle_0 of_nat_0_le_iff])
   342 
   343 lemma not_zle_0_negative [simp]: "~ (0 \<le> - (int (Suc n)))"
   344 by (subst le_minus_iff, simp del: of_nat_Suc)
   345 
   346 lemma int_zle_neg: "(int n \<le> - int m) = (n = 0 & m = 0)"
   347 by (simp add: int_def le minus Zero_int_def)
   348 
   349 lemma not_int_zless_negative [simp]: "~ (int n < - int m)"
   350 by (simp add: linorder_not_less)
   351 
   352 lemma negative_eq_positive [simp]: "(- int n = int m) = (n = 0 & m = 0)"
   353 by (force simp add: order_eq_iff [of "- int n"] int_zle_neg)
   354 
   355 lemma zle_iff_zadd: "(w \<le> z) = (\<exists>n. z = w + int n)"
   356 proof -
   357   have "(w \<le> z) = (0 \<le> z - w)"
   358     by (simp only: le_diff_eq add_0_left)
   359   also have "\<dots> = (\<exists>n. z - w = int n)"
   360     by (auto elim: zero_le_imp_eq_int)
   361   also have "\<dots> = (\<exists>n. z = w + int n)"
   362     by (simp only: group_simps)
   363   finally show ?thesis .
   364 qed
   365 
   366 lemma zadd_int_left: "(int m) + (int n + z) = int (m + n) + z"
   367 by simp
   368 
   369 lemma int_Suc0_eq_1: "int (Suc 0) = 1"
   370 by simp
   371 
   372 lemma abs_of_nat [simp]: "\<bar>of_nat n::'a::ordered_idom\<bar> = of_nat n"
   373 by (rule  of_nat_0_le_iff [THEN abs_of_nonneg]) (* belongs in Nat.thy *)
   374 
   375 text{*This version is proved for all ordered rings, not just integers!
   376       It is proved here because attribute @{text arith_split} is not available
   377       in theory @{text Ring_and_Field}.
   378       But is it really better than just rewriting with @{text abs_if}?*}
   379 lemma abs_split [arith_split]:
   380      "P(abs(a::'a::ordered_idom)) = ((0 \<le> a --> P a) & (a < 0 --> P(-a)))"
   381 by (force dest: order_less_le_trans simp add: abs_if linorder_not_less)
   382 
   383 
   384 subsection {* Constants @{term neg} and @{term iszero} *}
   385 
   386 definition
   387   neg  :: "'a\<Colon>ordered_idom \<Rightarrow> bool"
   388 where
   389   [code inline]: "neg Z \<longleftrightarrow> Z < 0"
   390 
   391 definition (*for simplifying equalities*)
   392   iszero :: "'a\<Colon>semiring_1 \<Rightarrow> bool"
   393 where
   394   "iszero z \<longleftrightarrow> z = 0"
   395 
   396 lemma not_neg_int [simp]: "~ neg (int n)"
   397 by (simp add: neg_def)
   398 
   399 lemma neg_zminus_int [simp]: "neg (- (int (Suc n)))"
   400 by (simp add: neg_def neg_less_0_iff_less del: of_nat_Suc)
   401 
   402 lemmas neg_eq_less_0 = neg_def
   403 
   404 lemma not_neg_eq_ge_0: "(~neg x) = (0 \<le> x)"
   405 by (simp add: neg_def linorder_not_less)
   406 
   407 
   408 text{*To simplify inequalities when Numeral1 can get simplified to 1*}
   409 
   410 lemma not_neg_0: "~ neg 0"
   411 by (simp add: One_int_def neg_def)
   412 
   413 lemma not_neg_1: "~ neg 1"
   414 by (simp add: neg_def linorder_not_less zero_le_one)
   415 
   416 lemma iszero_0: "iszero 0"
   417 by (simp add: iszero_def)
   418 
   419 lemma not_iszero_1: "~ iszero 1"
   420 by (simp add: iszero_def eq_commute)
   421 
   422 lemma neg_nat: "neg z ==> nat z = 0"
   423 by (simp add: neg_def order_less_imp_le) 
   424 
   425 lemma not_neg_nat: "~ neg z ==> int (nat z) = z"
   426 by (simp add: linorder_not_less neg_def)
   427 
   428 
   429 subsection{*Embedding of the Integers into any @{text ring_1}: @{term of_int}*}
   430 
   431 constdefs
   432   of_int :: "int => 'a::ring_1"
   433   "of_int z == contents (\<Union>(i,j) \<in> Rep_Integ z. { of_nat i - of_nat j })"
   434 lemmas [code func del] = of_int_def
   435 
   436 lemma of_int: "of_int (Abs_Integ (intrel `` {(i,j)})) = of_nat i - of_nat j"
   437 proof -
   438   have "(\<lambda>(i,j). { of_nat i - (of_nat j :: 'a) }) respects intrel"
   439     by (simp add: congruent_def compare_rls of_nat_add [symmetric]
   440             del: of_nat_add) 
   441   thus ?thesis
   442     by (simp add: of_int_def UN_equiv_class [OF equiv_intrel])
   443 qed
   444 
   445 lemma of_int_0 [simp]: "of_int 0 = 0"
   446 by (simp add: of_int Zero_int_def)
   447 
   448 lemma of_int_1 [simp]: "of_int 1 = 1"
   449 by (simp add: of_int One_int_def)
   450 
   451 lemma of_int_add [simp]: "of_int (w+z) = of_int w + of_int z"
   452 by (cases w, cases z, simp add: compare_rls of_int add)
   453 
   454 lemma of_int_minus [simp]: "of_int (-z) = - (of_int z)"
   455 by (cases z, simp add: compare_rls of_int minus)
   456 
   457 lemma of_int_diff [simp]: "of_int (w-z) = of_int w - of_int z"
   458 by (simp add: diff_minus)
   459 
   460 lemma of_int_mult [simp]: "of_int (w*z) = of_int w * of_int z"
   461 apply (cases w, cases z)
   462 apply (simp add: compare_rls of_int left_diff_distrib right_diff_distrib
   463                  mult add_ac of_nat_mult)
   464 done
   465 
   466 lemma of_int_le_iff [simp]:
   467      "(of_int w \<le> (of_int z::'a::ordered_idom)) = (w \<le> z)"
   468 apply (cases w)
   469 apply (cases z)
   470 apply (simp add: compare_rls of_int le diff_int_def add minus
   471                  of_nat_add [symmetric]   del: of_nat_add)
   472 done
   473 
   474 text{*Special cases where either operand is zero*}
   475 lemmas of_int_0_le_iff [simp] = of_int_le_iff [of 0, simplified]
   476 lemmas of_int_le_0_iff [simp] = of_int_le_iff [of _ 0, simplified]
   477 
   478 
   479 lemma of_int_less_iff [simp]:
   480      "(of_int w < (of_int z::'a::ordered_idom)) = (w < z)"
   481 by (simp add: linorder_not_le [symmetric])
   482 
   483 text{*Special cases where either operand is zero*}
   484 lemmas of_int_0_less_iff [simp] = of_int_less_iff [of 0, simplified]
   485 lemmas of_int_less_0_iff [simp] = of_int_less_iff [of _ 0, simplified]
   486 
   487 text{*Class for unital rings with characteristic zero.
   488  Includes non-ordered rings like the complex numbers.*}
   489 axclass ring_char_0 < ring_1, semiring_char_0
   490 
   491 lemma of_int_eq_iff [simp]:
   492      "(of_int w = (of_int z::'a::ring_char_0)) = (w = z)"
   493 apply (cases w, cases z, simp add: of_int)
   494 apply (simp only: diff_eq_eq diff_add_eq eq_diff_eq)
   495 apply (simp only: of_nat_add [symmetric] of_nat_eq_iff)
   496 done
   497 
   498 text{*Every @{text ordered_idom} has characteristic zero.*}
   499 instance ordered_idom < ring_char_0 ..
   500 
   501 text{*Special cases where either operand is zero*}
   502 lemmas of_int_0_eq_iff [simp] = of_int_eq_iff [of 0, simplified]
   503 lemmas of_int_eq_0_iff [simp] = of_int_eq_iff [of _ 0, simplified]
   504 
   505 lemma of_int_eq_id [simp]: "of_int = (id :: int => int)"
   506 proof
   507   fix z
   508   show "of_int z = id z"
   509     by (cases z)
   510       (simp add: of_int add minus int_def diff_minus)
   511 qed
   512 
   513 lemma of_nat_nat: "0 \<le> z ==> of_nat (nat z) = of_int z"
   514 by (cases z rule: eq_Abs_Integ)
   515    (simp add: nat le of_int Zero_int_def of_nat_diff)
   516 
   517 
   518 subsection{*The Set of Integers*}
   519 
   520 constdefs
   521   Ints  :: "'a::ring_1 set"
   522   "Ints == range of_int"
   523 
   524 notation (xsymbols)
   525   Ints  ("\<int>")
   526 
   527 lemma Ints_0 [simp]: "0 \<in> Ints"
   528 apply (simp add: Ints_def)
   529 apply (rule range_eqI)
   530 apply (rule of_int_0 [symmetric])
   531 done
   532 
   533 lemma Ints_1 [simp]: "1 \<in> Ints"
   534 apply (simp add: Ints_def)
   535 apply (rule range_eqI)
   536 apply (rule of_int_1 [symmetric])
   537 done
   538 
   539 lemma Ints_add [simp]: "[|a \<in> Ints; b \<in> Ints|] ==> a+b \<in> Ints"
   540 apply (auto simp add: Ints_def)
   541 apply (rule range_eqI)
   542 apply (rule of_int_add [symmetric])
   543 done
   544 
   545 lemma Ints_minus [simp]: "a \<in> Ints ==> -a \<in> Ints"
   546 apply (auto simp add: Ints_def)
   547 apply (rule range_eqI)
   548 apply (rule of_int_minus [symmetric])
   549 done
   550 
   551 lemma Ints_diff [simp]: "[|a \<in> Ints; b \<in> Ints|] ==> a-b \<in> Ints"
   552 apply (auto simp add: Ints_def)
   553 apply (rule range_eqI)
   554 apply (rule of_int_diff [symmetric])
   555 done
   556 
   557 lemma Ints_mult [simp]: "[|a \<in> Ints; b \<in> Ints|] ==> a*b \<in> Ints"
   558 apply (auto simp add: Ints_def)
   559 apply (rule range_eqI)
   560 apply (rule of_int_mult [symmetric])
   561 done
   562 
   563 text{*Collapse nested embeddings*}
   564 lemma of_int_of_nat_eq [simp]: "of_int (of_nat n) = of_nat n"
   565 by (induct n, auto)
   566 
   567 lemma Ints_cases [cases set: Ints]:
   568   assumes "q \<in> \<int>"
   569   obtains (of_int) z where "q = of_int z"
   570   unfolding Ints_def
   571 proof -
   572   from `q \<in> \<int>` have "q \<in> range of_int" unfolding Ints_def .
   573   then obtain z where "q = of_int z" ..
   574   then show thesis ..
   575 qed
   576 
   577 lemma Ints_induct [case_names of_int, induct set: Ints]:
   578   "q \<in> \<int> ==> (!!z. P (of_int z)) ==> P q"
   579   by (rule Ints_cases) auto
   580 
   581 
   582 subsection {* Further properties *}
   583 
   584 text{*Now we replace the case analysis rule by a more conventional one:
   585 whether an integer is negative or not.*}
   586 
   587 lemma zless_iff_Suc_zadd:
   588     "(w < z) = (\<exists>n. z = w + int (Suc n))"
   589 apply (cases z, cases w)
   590 apply (auto simp add: less add int_def)
   591 apply (rename_tac a b c d) 
   592 apply (rule_tac x="a+d - Suc(c+b)" in exI) 
   593 apply arith
   594 done
   595 
   596 lemma negD: "x<0 ==> \<exists>n. x = - (int (Suc n))"
   597 apply (cases x)
   598 apply (auto simp add: le minus Zero_int_def int_def order_less_le)
   599 apply (rule_tac x="y - Suc x" in exI, arith)
   600 done
   601 
   602 theorem int_cases [cases type: int, case_names nonneg neg]:
   603      "[|!! n. z = int n ==> P;  !! n. z =  - (int (Suc n)) ==> P |] ==> P"
   604 apply (cases "z < 0", blast dest!: negD)
   605 apply (simp add: linorder_not_less del: of_nat_Suc)
   606 apply (blast dest: nat_0_le [THEN sym])
   607 done
   608 
   609 theorem int_induct [induct type: int, case_names nonneg neg]:
   610      "[|!! n. P (int n);  !!n. P (- (int (Suc n))) |] ==> P z"
   611   by (cases z rule: int_cases) auto
   612 
   613 text{*Contributed by Brian Huffman*}
   614 theorem int_diff_cases [case_names diff]:
   615 assumes prem: "!!m n. z = int m - int n ==> P" shows "P"
   616 apply (cases z rule: eq_Abs_Integ)
   617 apply (rule_tac m=x and n=y in prem)
   618 apply (simp add: int_def diff_def minus add)
   619 done
   620 
   621 
   622 subsection {* Legacy theorems *}
   623 
   624 lemmas zminus_zminus = minus_minus [of "?z::int"]
   625 lemmas zminus_0 = minus_zero [where 'a=int]
   626 lemmas zminus_zadd_distrib = minus_add_distrib [of "?z::int" "?w"]
   627 lemmas zadd_commute = add_commute [of "?z::int" "?w"]
   628 lemmas zadd_assoc = add_assoc [of "?z1.0::int" "?z2.0" "?z3.0"]
   629 lemmas zadd_left_commute = add_left_commute [of "?x::int" "?y" "?z"]
   630 lemmas zadd_ac = zadd_assoc zadd_commute zadd_left_commute
   631 lemmas zmult_ac = OrderedGroup.mult_ac
   632 lemmas zadd_0 = OrderedGroup.add_0_left [of "?z::int"]
   633 lemmas zadd_0_right = OrderedGroup.add_0_left [of "?z::int"]
   634 lemmas zadd_zminus_inverse2 = left_minus [of "?z::int"]
   635 lemmas zmult_zminus = mult_minus_left [of "?z::int" "?w"]
   636 lemmas zmult_commute = mult_commute [of "?z::int" "?w"]
   637 lemmas zmult_assoc = mult_assoc [of "?z1.0::int" "?z2.0" "?z3.0"]
   638 lemmas zadd_zmult_distrib = left_distrib [of "?z1.0::int" "?z2.0" "?w"]
   639 lemmas zadd_zmult_distrib2 = right_distrib [of "?w::int" "?z1.0" "?z2.0"]
   640 lemmas zdiff_zmult_distrib = left_diff_distrib [of "?z1.0::int" "?z2.0" "?w"]
   641 lemmas zdiff_zmult_distrib2 = right_diff_distrib [of "?w::int" "?z1.0" "?z2.0"]
   642 
   643 lemmas int_distrib =
   644   zadd_zmult_distrib zadd_zmult_distrib2
   645   zdiff_zmult_distrib zdiff_zmult_distrib2
   646 
   647 lemmas zmult_1 = mult_1_left [of "?z::int"]
   648 lemmas zmult_1_right = mult_1_right [of "?z::int"]
   649 
   650 lemmas zle_refl = order_refl [of "?w::int"]
   651 lemmas zle_trans = order_trans [where 'a=int and x="?i" and y="?j" and z="?k"]
   652 lemmas zle_anti_sym = order_antisym [of "?z::int" "?w"]
   653 lemmas zle_linear = linorder_linear [of "?z::int" "?w"]
   654 lemmas zless_linear = linorder_less_linear [where 'a = int]
   655 
   656 lemmas zadd_left_mono = add_left_mono [of "?i::int" "?j" "?k"]
   657 lemmas zadd_strict_right_mono = add_strict_right_mono [of "?i::int" "?j" "?k"]
   658 lemmas zadd_zless_mono = add_less_le_mono [of "?w'::int" "?w" "?z'" "?z"]
   659 
   660 lemmas int_0_less_1 = zero_less_one [where 'a=int]
   661 lemmas int_0_neq_1 = zero_neq_one [where 'a=int]
   662 
   663 lemmas inj_int = inj_of_nat [where 'a=int]
   664 lemmas int_int_eq = of_nat_eq_iff [where 'a=int]
   665 lemmas zadd_int = of_nat_add [where 'a=int, symmetric]
   666 lemmas int_mult = of_nat_mult [where 'a=int]
   667 lemmas zmult_int = of_nat_mult [where 'a=int, symmetric]
   668 lemmas int_eq_0_conv = of_nat_eq_0_iff [where 'a=int and m="?n"]
   669 lemmas zless_int = of_nat_less_iff [where 'a=int]
   670 lemmas int_less_0_conv = of_nat_less_0_iff [where 'a=int and m="?k"]
   671 lemmas zero_less_int_conv = of_nat_0_less_iff [where 'a=int]
   672 lemmas zle_int = of_nat_le_iff [where 'a=int]
   673 lemmas zero_zle_int = of_nat_0_le_iff [where 'a=int]
   674 lemmas int_le_0_conv = of_nat_le_0_iff [where 'a=int and m="?n"]
   675 lemmas int_0 = of_nat_0 [where ?'a_1.0=int]
   676 lemmas int_1 = of_nat_1 [where 'a=int]
   677 lemmas int_Suc = of_nat_Suc [where ?'a_1.0=int]
   678 lemmas abs_int_eq = abs_of_nat [where 'a=int and n="?m"]
   679 lemmas of_int_int_eq = of_int_of_nat_eq [where 'a=int]
   680 lemmas zdiff_int = of_nat_diff [where 'a=int, symmetric]
   681 lemmas zless_le = less_int_def [THEN meta_eq_to_obj_eq]
   682 lemmas int_eq_of_nat = TrueI
   683 
   684 abbreviation
   685   int_of_nat :: "nat \<Rightarrow> int"
   686 where
   687   "int_of_nat \<equiv> of_nat"
   688 
   689 end