src/HOL/Lattices.thy
 author haftmann Sat Jul 11 21:33:01 2009 +0200 (2009-07-11) changeset 31991 37390299214a parent 30729 461ee3e49ad3 child 32063 2aab4f2af536 permissions -rw-r--r--
added boolean_algebra type class; tuned lattice duals
```     1 (*  Title:      HOL/Lattices.thy
```
```     2     Author:     Tobias Nipkow
```
```     3 *)
```
```     4
```
```     5 header {* Abstract lattices *}
```
```     6
```
```     7 theory Lattices
```
```     8 imports Orderings
```
```     9 begin
```
```    10
```
```    11 subsection {* Lattices *}
```
```    12
```
```    13 notation
```
```    14   less_eq  (infix "\<sqsubseteq>" 50) and
```
```    15   less  (infix "\<sqsubset>" 50)
```
```    16
```
```    17 class lower_semilattice = order +
```
```    18   fixes inf :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<sqinter>" 70)
```
```    19   assumes inf_le1 [simp]: "x \<sqinter> y \<sqsubseteq> x"
```
```    20   and inf_le2 [simp]: "x \<sqinter> y \<sqsubseteq> y"
```
```    21   and inf_greatest: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> y \<sqinter> z"
```
```    22
```
```    23 class upper_semilattice = order +
```
```    24   fixes sup :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<squnion>" 65)
```
```    25   assumes sup_ge1 [simp]: "x \<sqsubseteq> x \<squnion> y"
```
```    26   and sup_ge2 [simp]: "y \<sqsubseteq> x \<squnion> y"
```
```    27   and sup_least: "y \<sqsubseteq> x \<Longrightarrow> z \<sqsubseteq> x \<Longrightarrow> y \<squnion> z \<sqsubseteq> x"
```
```    28 begin
```
```    29
```
```    30 text {* Dual lattice *}
```
```    31
```
```    32 lemma dual_semilattice:
```
```    33   "lower_semilattice (op \<ge>) (op >) sup"
```
```    34 by (rule lower_semilattice.intro, rule dual_order)
```
```    35   (unfold_locales, simp_all add: sup_least)
```
```    36
```
```    37 end
```
```    38
```
```    39 class lattice = lower_semilattice + upper_semilattice
```
```    40
```
```    41
```
```    42 subsubsection {* Intro and elim rules*}
```
```    43
```
```    44 context lower_semilattice
```
```    45 begin
```
```    46
```
```    47 lemma le_infI1[intro]:
```
```    48   assumes "a \<sqsubseteq> x"
```
```    49   shows "a \<sqinter> b \<sqsubseteq> x"
```
```    50 proof (rule order_trans)
```
```    51   from assms show "a \<sqsubseteq> x" .
```
```    52   show "a \<sqinter> b \<sqsubseteq> a" by simp
```
```    53 qed
```
```    54 lemmas (in -) [rule del] = le_infI1
```
```    55
```
```    56 lemma le_infI2[intro]:
```
```    57   assumes "b \<sqsubseteq> x"
```
```    58   shows "a \<sqinter> b \<sqsubseteq> x"
```
```    59 proof (rule order_trans)
```
```    60   from assms show "b \<sqsubseteq> x" .
```
```    61   show "a \<sqinter> b \<sqsubseteq> b" by simp
```
```    62 qed
```
```    63 lemmas (in -) [rule del] = le_infI2
```
```    64
```
```    65 lemma le_infI[intro!]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<sqinter> b"
```
```    66 by(blast intro: inf_greatest)
```
```    67 lemmas (in -) [rule del] = le_infI
```
```    68
```
```    69 lemma le_infE [elim!]: "x \<sqsubseteq> a \<sqinter> b \<Longrightarrow> (x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> P) \<Longrightarrow> P"
```
```    70   by (blast intro: order_trans)
```
```    71 lemmas (in -) [rule del] = le_infE
```
```    72
```
```    73 lemma le_inf_iff [simp]:
```
```    74   "x \<sqsubseteq> y \<sqinter> z = (x \<sqsubseteq> y \<and> x \<sqsubseteq> z)"
```
```    75 by blast
```
```    76
```
```    77 lemma le_iff_inf: "(x \<sqsubseteq> y) = (x \<sqinter> y = x)"
```
```    78   by (blast intro: antisym dest: eq_iff [THEN iffD1])
```
```    79
```
```    80 lemma mono_inf:
```
```    81   fixes f :: "'a \<Rightarrow> 'b\<Colon>lower_semilattice"
```
```    82   shows "mono f \<Longrightarrow> f (A \<sqinter> B) \<le> f A \<sqinter> f B"
```
```    83   by (auto simp add: mono_def intro: Lattices.inf_greatest)
```
```    84
```
```    85 end
```
```    86
```
```    87 context upper_semilattice
```
```    88 begin
```
```    89
```
```    90 lemma le_supI1[intro]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
```
```    91   by (rule order_trans) auto
```
```    92 lemmas (in -) [rule del] = le_supI1
```
```    93
```
```    94 lemma le_supI2[intro]: "x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
```
```    95   by (rule order_trans) auto
```
```    96 lemmas (in -) [rule del] = le_supI2
```
```    97
```
```    98 lemma le_supI[intro!]: "a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> a \<squnion> b \<sqsubseteq> x"
```
```    99   by (blast intro: sup_least)
```
```   100 lemmas (in -) [rule del] = le_supI
```
```   101
```
```   102 lemma le_supE[elim!]: "a \<squnion> b \<sqsubseteq> x \<Longrightarrow> (a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> P) \<Longrightarrow> P"
```
```   103   by (blast intro: order_trans)
```
```   104 lemmas (in -) [rule del] = le_supE
```
```   105
```
```   106 lemma ge_sup_conv[simp]:
```
```   107   "x \<squnion> y \<sqsubseteq> z = (x \<sqsubseteq> z \<and> y \<sqsubseteq> z)"
```
```   108 by blast
```
```   109
```
```   110 lemma le_iff_sup: "(x \<sqsubseteq> y) = (x \<squnion> y = y)"
```
```   111   by (blast intro: antisym dest: eq_iff [THEN iffD1])
```
```   112
```
```   113 lemma mono_sup:
```
```   114   fixes f :: "'a \<Rightarrow> 'b\<Colon>upper_semilattice"
```
```   115   shows "mono f \<Longrightarrow> f A \<squnion> f B \<le> f (A \<squnion> B)"
```
```   116   by (auto simp add: mono_def intro: Lattices.sup_least)
```
```   117
```
```   118 end
```
```   119
```
```   120
```
```   121 subsubsection{* Equational laws *}
```
```   122
```
```   123 context lower_semilattice
```
```   124 begin
```
```   125
```
```   126 lemma inf_commute: "(x \<sqinter> y) = (y \<sqinter> x)"
```
```   127   by (blast intro: antisym)
```
```   128
```
```   129 lemma inf_assoc: "(x \<sqinter> y) \<sqinter> z = x \<sqinter> (y \<sqinter> z)"
```
```   130   by (blast intro: antisym)
```
```   131
```
```   132 lemma inf_idem[simp]: "x \<sqinter> x = x"
```
```   133   by (blast intro: antisym)
```
```   134
```
```   135 lemma inf_left_idem[simp]: "x \<sqinter> (x \<sqinter> y) = x \<sqinter> y"
```
```   136   by (blast intro: antisym)
```
```   137
```
```   138 lemma inf_absorb1: "x \<sqsubseteq> y \<Longrightarrow> x \<sqinter> y = x"
```
```   139   by (blast intro: antisym)
```
```   140
```
```   141 lemma inf_absorb2: "y \<sqsubseteq> x \<Longrightarrow> x \<sqinter> y = y"
```
```   142   by (blast intro: antisym)
```
```   143
```
```   144 lemma inf_left_commute: "x \<sqinter> (y \<sqinter> z) = y \<sqinter> (x \<sqinter> z)"
```
```   145   by (blast intro: antisym)
```
```   146
```
```   147 lemmas inf_ACI = inf_commute inf_assoc inf_left_commute inf_left_idem
```
```   148
```
```   149 end
```
```   150
```
```   151
```
```   152 context upper_semilattice
```
```   153 begin
```
```   154
```
```   155 lemma sup_commute: "(x \<squnion> y) = (y \<squnion> x)"
```
```   156   by (blast intro: antisym)
```
```   157
```
```   158 lemma sup_assoc: "(x \<squnion> y) \<squnion> z = x \<squnion> (y \<squnion> z)"
```
```   159   by (blast intro: antisym)
```
```   160
```
```   161 lemma sup_idem[simp]: "x \<squnion> x = x"
```
```   162   by (blast intro: antisym)
```
```   163
```
```   164 lemma sup_left_idem[simp]: "x \<squnion> (x \<squnion> y) = x \<squnion> y"
```
```   165   by (blast intro: antisym)
```
```   166
```
```   167 lemma sup_absorb1: "y \<sqsubseteq> x \<Longrightarrow> x \<squnion> y = x"
```
```   168   by (blast intro: antisym)
```
```   169
```
```   170 lemma sup_absorb2: "x \<sqsubseteq> y \<Longrightarrow> x \<squnion> y = y"
```
```   171   by (blast intro: antisym)
```
```   172
```
```   173 lemma sup_left_commute: "x \<squnion> (y \<squnion> z) = y \<squnion> (x \<squnion> z)"
```
```   174   by (blast intro: antisym)
```
```   175
```
```   176 lemmas sup_ACI = sup_commute sup_assoc sup_left_commute sup_left_idem
```
```   177
```
```   178 end
```
```   179
```
```   180 context lattice
```
```   181 begin
```
```   182
```
```   183 lemma dual_lattice:
```
```   184   "lattice (op \<ge>) (op >) sup inf"
```
```   185   by (rule lattice.intro, rule dual_semilattice, rule upper_semilattice.intro, rule dual_order)
```
```   186     (unfold_locales, auto)
```
```   187
```
```   188 lemma inf_sup_absorb: "x \<sqinter> (x \<squnion> y) = x"
```
```   189   by (blast intro: antisym inf_le1 inf_greatest sup_ge1)
```
```   190
```
```   191 lemma sup_inf_absorb: "x \<squnion> (x \<sqinter> y) = x"
```
```   192   by (blast intro: antisym sup_ge1 sup_least inf_le1)
```
```   193
```
```   194 lemmas ACI = inf_ACI sup_ACI
```
```   195
```
```   196 lemmas inf_sup_ord = inf_le1 inf_le2 sup_ge1 sup_ge2
```
```   197
```
```   198 text{* Towards distributivity *}
```
```   199
```
```   200 lemma distrib_sup_le: "x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> (x \<squnion> z)"
```
```   201   by blast
```
```   202
```
```   203 lemma distrib_inf_le: "(x \<sqinter> y) \<squnion> (x \<sqinter> z) \<sqsubseteq> x \<sqinter> (y \<squnion> z)"
```
```   204   by blast
```
```   205
```
```   206
```
```   207 text{* If you have one of them, you have them all. *}
```
```   208
```
```   209 lemma distrib_imp1:
```
```   210 assumes D: "!!x y z. x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
```
```   211 shows "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
```
```   212 proof-
```
```   213   have "x \<squnion> (y \<sqinter> z) = (x \<squnion> (x \<sqinter> z)) \<squnion> (y \<sqinter> z)" by(simp add:sup_inf_absorb)
```
```   214   also have "\<dots> = x \<squnion> (z \<sqinter> (x \<squnion> y))" by(simp add:D inf_commute sup_assoc)
```
```   215   also have "\<dots> = ((x \<squnion> y) \<sqinter> x) \<squnion> ((x \<squnion> y) \<sqinter> z)"
```
```   216     by(simp add:inf_sup_absorb inf_commute)
```
```   217   also have "\<dots> = (x \<squnion> y) \<sqinter> (x \<squnion> z)" by(simp add:D)
```
```   218   finally show ?thesis .
```
```   219 qed
```
```   220
```
```   221 lemma distrib_imp2:
```
```   222 assumes D: "!!x y z. x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
```
```   223 shows "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
```
```   224 proof-
```
```   225   have "x \<sqinter> (y \<squnion> z) = (x \<sqinter> (x \<squnion> z)) \<sqinter> (y \<squnion> z)" by(simp add:inf_sup_absorb)
```
```   226   also have "\<dots> = x \<sqinter> (z \<squnion> (x \<sqinter> y))" by(simp add:D sup_commute inf_assoc)
```
```   227   also have "\<dots> = ((x \<sqinter> y) \<squnion> x) \<sqinter> ((x \<sqinter> y) \<squnion> z)"
```
```   228     by(simp add:sup_inf_absorb sup_commute)
```
```   229   also have "\<dots> = (x \<sqinter> y) \<squnion> (x \<sqinter> z)" by(simp add:D)
```
```   230   finally show ?thesis .
```
```   231 qed
```
```   232
```
```   233 (* seems unused *)
```
```   234 lemma modular_le: "x \<sqsubseteq> z \<Longrightarrow> x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> z"
```
```   235 by blast
```
```   236
```
```   237 end
```
```   238
```
```   239
```
```   240 subsection {* Distributive lattices *}
```
```   241
```
```   242 class distrib_lattice = lattice +
```
```   243   assumes sup_inf_distrib1: "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
```
```   244
```
```   245 context distrib_lattice
```
```   246 begin
```
```   247
```
```   248 lemma sup_inf_distrib2:
```
```   249  "(y \<sqinter> z) \<squnion> x = (y \<squnion> x) \<sqinter> (z \<squnion> x)"
```
```   250 by(simp add:ACI sup_inf_distrib1)
```
```   251
```
```   252 lemma inf_sup_distrib1:
```
```   253  "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
```
```   254 by(rule distrib_imp2[OF sup_inf_distrib1])
```
```   255
```
```   256 lemma inf_sup_distrib2:
```
```   257  "(y \<squnion> z) \<sqinter> x = (y \<sqinter> x) \<squnion> (z \<sqinter> x)"
```
```   258 by(simp add:ACI inf_sup_distrib1)
```
```   259
```
```   260 lemma dual_distrib_lattice:
```
```   261   "distrib_lattice (op \<ge>) (op >) sup inf"
```
```   262   by (rule distrib_lattice.intro, rule dual_lattice)
```
```   263     (unfold_locales, fact inf_sup_distrib1)
```
```   264
```
```   265 lemmas distrib =
```
```   266   sup_inf_distrib1 sup_inf_distrib2 inf_sup_distrib1 inf_sup_distrib2
```
```   267
```
```   268 end
```
```   269
```
```   270
```
```   271 subsection {* Boolean algebras *}
```
```   272
```
```   273 class boolean_algebra = distrib_lattice + top + bot + minus + uminus +
```
```   274   assumes inf_compl_bot: "x \<sqinter> - x = bot"
```
```   275     and sup_compl_top: "x \<squnion> - x = top"
```
```   276   assumes diff_eq: "x - y = x \<sqinter> - y"
```
```   277 begin
```
```   278
```
```   279 lemma dual_boolean_algebra:
```
```   280   "boolean_algebra (\<lambda>x y. x \<squnion> - y) uminus (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) top bot"
```
```   281   by (rule boolean_algebra.intro, rule dual_distrib_lattice)
```
```   282     (unfold_locales,
```
```   283       auto simp add: inf_compl_bot sup_compl_top diff_eq less_le_not_le)
```
```   284
```
```   285 lemma compl_inf_bot:
```
```   286   "- x \<sqinter> x = bot"
```
```   287   by (simp add: inf_commute inf_compl_bot)
```
```   288
```
```   289 lemma compl_sup_top:
```
```   290   "- x \<squnion> x = top"
```
```   291   by (simp add: sup_commute sup_compl_top)
```
```   292
```
```   293 lemma inf_bot_left [simp]:
```
```   294   "bot \<sqinter> x = bot"
```
```   295   by (rule inf_absorb1) simp
```
```   296
```
```   297 lemma inf_bot_right [simp]:
```
```   298   "x \<sqinter> bot = bot"
```
```   299   by (rule inf_absorb2) simp
```
```   300
```
```   301 lemma sup_top_left [simp]:
```
```   302   "top \<squnion> x = top"
```
```   303   by (rule sup_absorb1) simp
```
```   304
```
```   305 lemma sup_top_right [simp]:
```
```   306   "x \<squnion> top = top"
```
```   307   by (rule sup_absorb2) simp
```
```   308
```
```   309 lemma inf_top_left [simp]:
```
```   310   "top \<sqinter> x = x"
```
```   311   by (rule inf_absorb2) simp
```
```   312
```
```   313 lemma inf_top_right [simp]:
```
```   314   "x \<sqinter> top = x"
```
```   315   by (rule inf_absorb1) simp
```
```   316
```
```   317 lemma sup_bot_left [simp]:
```
```   318   "bot \<squnion> x = x"
```
```   319   by (rule sup_absorb2) simp
```
```   320
```
```   321 lemma sup_bot_right [simp]:
```
```   322   "x \<squnion> bot = x"
```
```   323   by (rule sup_absorb1) simp
```
```   324
```
```   325 lemma compl_unique:
```
```   326   assumes "x \<sqinter> y = bot"
```
```   327     and "x \<squnion> y = top"
```
```   328   shows "- x = y"
```
```   329 proof -
```
```   330   have "(x \<sqinter> - x) \<squnion> (- x \<sqinter> y) = (x \<sqinter> y) \<squnion> (- x \<sqinter> y)"
```
```   331     using inf_compl_bot assms(1) by simp
```
```   332   then have "(- x \<sqinter> x) \<squnion> (- x \<sqinter> y) = (y \<sqinter> x) \<squnion> (y \<sqinter> - x)"
```
```   333     by (simp add: inf_commute)
```
```   334   then have "- x \<sqinter> (x \<squnion> y) = y \<sqinter> (x \<squnion> - x)"
```
```   335     by (simp add: inf_sup_distrib1)
```
```   336   then have "- x \<sqinter> top = y \<sqinter> top"
```
```   337     using sup_compl_top assms(2) by simp
```
```   338   then show "- x = y" by (simp add: inf_top_right)
```
```   339 qed
```
```   340
```
```   341 lemma double_compl [simp]:
```
```   342   "- (- x) = x"
```
```   343   using compl_inf_bot compl_sup_top by (rule compl_unique)
```
```   344
```
```   345 lemma compl_eq_compl_iff [simp]:
```
```   346   "- x = - y \<longleftrightarrow> x = y"
```
```   347 proof
```
```   348   assume "- x = - y"
```
```   349   then have "- x \<sqinter> y = bot"
```
```   350     and "- x \<squnion> y = top"
```
```   351     by (simp_all add: compl_inf_bot compl_sup_top)
```
```   352   then have "- (- x) = y" by (rule compl_unique)
```
```   353   then show "x = y" by simp
```
```   354 next
```
```   355   assume "x = y"
```
```   356   then show "- x = - y" by simp
```
```   357 qed
```
```   358
```
```   359 lemma compl_bot_eq [simp]:
```
```   360   "- bot = top"
```
```   361 proof -
```
```   362   from sup_compl_top have "bot \<squnion> - bot = top" .
```
```   363   then show ?thesis by simp
```
```   364 qed
```
```   365
```
```   366 lemma compl_top_eq [simp]:
```
```   367   "- top = bot"
```
```   368 proof -
```
```   369   from inf_compl_bot have "top \<sqinter> - top = bot" .
```
```   370   then show ?thesis by simp
```
```   371 qed
```
```   372
```
```   373 lemma compl_inf [simp]:
```
```   374   "- (x \<sqinter> y) = - x \<squnion> - y"
```
```   375 proof (rule compl_unique)
```
```   376   have "(x \<sqinter> y) \<sqinter> (- x \<squnion> - y) = ((x \<sqinter> y) \<sqinter> - x) \<squnion> ((x \<sqinter> y) \<sqinter> - y)"
```
```   377     by (rule inf_sup_distrib1)
```
```   378   also have "... = (y \<sqinter> (x \<sqinter> - x)) \<squnion> (x \<sqinter> (y \<sqinter> - y))"
```
```   379     by (simp only: inf_commute inf_assoc inf_left_commute)
```
```   380   finally show "(x \<sqinter> y) \<sqinter> (- x \<squnion> - y) = bot"
```
```   381     by (simp add: inf_compl_bot)
```
```   382 next
```
```   383   have "(x \<sqinter> y) \<squnion> (- x \<squnion> - y) = (x \<squnion> (- x \<squnion> - y)) \<sqinter> (y \<squnion> (- x \<squnion> - y))"
```
```   384     by (rule sup_inf_distrib2)
```
```   385   also have "... = (- y \<squnion> (x \<squnion> - x)) \<sqinter> (- x \<squnion> (y \<squnion> - y))"
```
```   386     by (simp only: sup_commute sup_assoc sup_left_commute)
```
```   387   finally show "(x \<sqinter> y) \<squnion> (- x \<squnion> - y) = top"
```
```   388     by (simp add: sup_compl_top)
```
```   389 qed
```
```   390
```
```   391 lemma compl_sup [simp]:
```
```   392   "- (x \<squnion> y) = - x \<sqinter> - y"
```
```   393 proof -
```
```   394   interpret boolean_algebra "\<lambda>x y. x \<squnion> - y" uminus "op \<ge>" "op >" "op \<squnion>" "op \<sqinter>" top bot
```
```   395     by (rule dual_boolean_algebra)
```
```   396   then show ?thesis by simp
```
```   397 qed
```
```   398
```
```   399 end
```
```   400
```
```   401
```
```   402 subsection {* Uniqueness of inf and sup *}
```
```   403
```
```   404 lemma (in lower_semilattice) inf_unique:
```
```   405   fixes f (infixl "\<triangle>" 70)
```
```   406   assumes le1: "\<And>x y. x \<triangle> y \<le> x" and le2: "\<And>x y. x \<triangle> y \<le> y"
```
```   407   and greatest: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z"
```
```   408   shows "x \<sqinter> y = x \<triangle> y"
```
```   409 proof (rule antisym)
```
```   410   show "x \<triangle> y \<le> x \<sqinter> y" by (rule le_infI) (rule le1, rule le2)
```
```   411 next
```
```   412   have leI: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z" by (blast intro: greatest)
```
```   413   show "x \<sqinter> y \<le> x \<triangle> y" by (rule leI) simp_all
```
```   414 qed
```
```   415
```
```   416 lemma (in upper_semilattice) sup_unique:
```
```   417   fixes f (infixl "\<nabla>" 70)
```
```   418   assumes ge1 [simp]: "\<And>x y. x \<le> x \<nabla> y" and ge2: "\<And>x y. y \<le> x \<nabla> y"
```
```   419   and least: "\<And>x y z. y \<le> x \<Longrightarrow> z \<le> x \<Longrightarrow> y \<nabla> z \<le> x"
```
```   420   shows "x \<squnion> y = x \<nabla> y"
```
```   421 proof (rule antisym)
```
```   422   show "x \<squnion> y \<le> x \<nabla> y" by (rule le_supI) (rule ge1, rule ge2)
```
```   423 next
```
```   424   have leI: "\<And>x y z. x \<le> z \<Longrightarrow> y \<le> z \<Longrightarrow> x \<nabla> y \<le> z" by (blast intro: least)
```
```   425   show "x \<nabla> y \<le> x \<squnion> y" by (rule leI) simp_all
```
```   426 qed
```
```   427
```
```   428
```
```   429 subsection {* @{const min}/@{const max} on linear orders as
```
```   430   special case of @{const inf}/@{const sup} *}
```
```   431
```
```   432 lemma (in linorder) distrib_lattice_min_max:
```
```   433   "distrib_lattice (op \<le>) (op <) min max"
```
```   434 proof
```
```   435   have aux: "\<And>x y \<Colon> 'a. x < y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
```
```   436     by (auto simp add: less_le antisym)
```
```   437   fix x y z
```
```   438   show "max x (min y z) = min (max x y) (max x z)"
```
```   439   unfolding min_def max_def
```
```   440   by auto
```
```   441 qed (auto simp add: min_def max_def not_le less_imp_le)
```
```   442
```
```   443 interpretation min_max: distrib_lattice "op \<le> :: 'a::linorder \<Rightarrow> 'a \<Rightarrow> bool" "op <" min max
```
```   444   by (rule distrib_lattice_min_max)
```
```   445
```
```   446 lemma inf_min: "inf = (min \<Colon> 'a\<Colon>{lower_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
```
```   447   by (rule ext)+ (auto intro: antisym)
```
```   448
```
```   449 lemma sup_max: "sup = (max \<Colon> 'a\<Colon>{upper_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
```
```   450   by (rule ext)+ (auto intro: antisym)
```
```   451
```
```   452 lemmas le_maxI1 = min_max.sup_ge1
```
```   453 lemmas le_maxI2 = min_max.sup_ge2
```
```   454
```
```   455 lemmas max_ac = min_max.sup_assoc min_max.sup_commute
```
```   456   mk_left_commute [of max, OF min_max.sup_assoc min_max.sup_commute]
```
```   457
```
```   458 lemmas min_ac = min_max.inf_assoc min_max.inf_commute
```
```   459   mk_left_commute [of min, OF min_max.inf_assoc min_max.inf_commute]
```
```   460
```
```   461 text {*
```
```   462   Now we have inherited antisymmetry as an intro-rule on all
```
```   463   linear orders. This is a problem because it applies to bool, which is
```
```   464   undesirable.
```
```   465 *}
```
```   466
```
```   467 lemmas [rule del] = min_max.le_infI min_max.le_supI
```
```   468   min_max.le_supE min_max.le_infE min_max.le_supI1 min_max.le_supI2
```
```   469   min_max.le_infI1 min_max.le_infI2
```
```   470
```
```   471
```
```   472 subsection {* Bool as lattice *}
```
```   473
```
```   474 instantiation bool :: boolean_algebra
```
```   475 begin
```
```   476
```
```   477 definition
```
```   478   bool_Compl_def: "uminus = Not"
```
```   479
```
```   480 definition
```
```   481   bool_diff_def: "A - B \<longleftrightarrow> A \<and> \<not> B"
```
```   482
```
```   483 definition
```
```   484   inf_bool_eq: "P \<sqinter> Q \<longleftrightarrow> P \<and> Q"
```
```   485
```
```   486 definition
```
```   487   sup_bool_eq: "P \<squnion> Q \<longleftrightarrow> P \<or> Q"
```
```   488
```
```   489 instance proof
```
```   490 qed (simp_all add: inf_bool_eq sup_bool_eq le_bool_def
```
```   491   bot_bool_eq top_bool_eq bool_Compl_def bool_diff_def, auto)
```
```   492
```
```   493 end
```
```   494
```
```   495
```
```   496 subsection {* Fun as lattice *}
```
```   497
```
```   498 instantiation "fun" :: (type, lattice) lattice
```
```   499 begin
```
```   500
```
```   501 definition
```
```   502   inf_fun_eq [code del]: "f \<sqinter> g = (\<lambda>x. f x \<sqinter> g x)"
```
```   503
```
```   504 definition
```
```   505   sup_fun_eq [code del]: "f \<squnion> g = (\<lambda>x. f x \<squnion> g x)"
```
```   506
```
```   507 instance
```
```   508 apply intro_classes
```
```   509 unfolding inf_fun_eq sup_fun_eq
```
```   510 apply (auto intro: le_funI)
```
```   511 apply (rule le_funI)
```
```   512 apply (auto dest: le_funD)
```
```   513 apply (rule le_funI)
```
```   514 apply (auto dest: le_funD)
```
```   515 done
```
```   516
```
```   517 end
```
```   518
```
```   519 instance "fun" :: (type, distrib_lattice) distrib_lattice
```
```   520 proof
```
```   521 qed (auto simp add: inf_fun_eq sup_fun_eq sup_inf_distrib1)
```
```   522
```
```   523 instantiation "fun" :: (type, uminus) uminus
```
```   524 begin
```
```   525
```
```   526 definition
```
```   527   fun_Compl_def: "- A = (\<lambda>x. - A x)"
```
```   528
```
```   529 instance ..
```
```   530
```
```   531 end
```
```   532
```
```   533 instantiation "fun" :: (type, minus) minus
```
```   534 begin
```
```   535
```
```   536 definition
```
```   537   fun_diff_def: "A - B = (\<lambda>x. A x - B x)"
```
```   538
```
```   539 instance ..
```
```   540
```
```   541 end
```
```   542
```
```   543 instance "fun" :: (type, boolean_algebra) boolean_algebra
```
```   544 proof
```
```   545 qed (simp_all add: inf_fun_eq sup_fun_eq bot_fun_eq top_fun_eq fun_Compl_def fun_diff_def
```
```   546   inf_compl_bot sup_compl_top diff_eq)
```
```   547
```
```   548
```
```   549 text {* redundant bindings *}
```
```   550
```
```   551 lemmas inf_aci = inf_ACI
```
```   552 lemmas sup_aci = sup_ACI
```
```   553
```
```   554 no_notation
```
```   555   less_eq  (infix "\<sqsubseteq>" 50) and
```
```   556   less (infix "\<sqsubset>" 50) and
```
```   557   inf  (infixl "\<sqinter>" 70) and
```
```   558   sup  (infixl "\<squnion>" 65)
```
```   559
```
```   560 end
```