src/Pure/library.ML
author wenzelm
Tue Jan 01 16:09:26 2008 +0100 (2008-01-01)
changeset 25752 374446e93558
parent 25702 a61554b1e7a9
child 25797 b293e3ed3cad
permissions -rw-r--r--
removed separate exists/forall code;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    67   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68 
    69   (*lists*)
    70   exception UnequalLengths
    71   val single: 'a -> 'a list
    72   val the_single: 'a list -> 'a
    73   val singleton: ('a list -> 'b list) -> 'a -> 'b
    74   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    75   val apply: ('a -> 'a) list -> 'a -> 'a
    76   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    77   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    78   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    79   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    80   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    81   val flat: 'a list list -> 'a list
    82   val unflat: 'a list list -> 'b list -> 'b list list
    83   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    84   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    85   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    86   val maps: ('a -> 'b list) -> 'a list -> 'b list
    87   val filter: ('a -> bool) -> 'a list -> 'a list
    88   val filter_out: ('a -> bool) -> 'a list -> 'a list
    89   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    90   val chop: int -> 'a list -> 'a list * 'a list
    91   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    92   val nth: 'a list -> int -> 'a
    93   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    94   val nth_drop: int -> 'a list -> 'a list
    95   val nth_list: 'a list list -> int -> 'a list
    96   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    97   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val split_last: 'a list -> 'a list * 'a
    99   val find_index: ('a -> bool) -> 'a list -> int
   100   val find_index_eq: ''a -> ''a list -> int
   101   val find_first: ('a -> bool) -> 'a list -> 'a option
   102   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   103   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   104   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   105   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   108   val ~~ : 'a list * 'b list -> ('a * 'b) list
   109   val split_list: ('a * 'b) list -> 'a list * 'b list
   110   val separate: 'a -> 'a list -> 'a list
   111   val replicate: int -> 'a -> 'a list
   112   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   113   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val prefixes: 'a list -> 'a list list
   118   val suffixes1: 'a list -> 'a list list
   119   val suffixes: 'a list -> 'a list list
   120 
   121   (*integers*)
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val radixpand: int * int -> int list
   127   val radixstring: int * string * int -> string
   128   val string_of_int: int -> string
   129   val signed_string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131   val read_radix_int: int -> string list -> int * string list
   132   val read_int: string list -> int * string list
   133   val oct_char: string -> string
   134 
   135   (*strings*)
   136   val nth_string: string -> int -> string
   137   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   138   val exists_string: (string -> bool) -> string -> bool
   139   val forall_string: (string -> bool) -> string -> bool
   140   val enclose: string -> string -> string -> string
   141   val unenclose: string -> string
   142   val quote: string -> string
   143   val space_implode: string -> string list -> string
   144   val commas: string list -> string
   145   val commas_quote: string list -> string
   146   val cat_lines: string list -> string
   147   val space_explode: string -> string -> string list
   148   val split_lines: string -> string list
   149   val prefix_lines: string -> string -> string
   150   val untabify: string list -> string list
   151   val prefix: string -> string -> string
   152   val suffix: string -> string -> string
   153   val unprefix: string -> string -> string
   154   val unsuffix: string -> string -> string
   155   val replicate_string: int -> string -> string
   156   val translate_string: (string -> string) -> string -> string
   157   val multiply: 'a list -> 'a list list -> 'a list list
   158   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   159   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   160 
   161   (*lists as sets -- see also Pure/General/ord_list.ML*)
   162   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   163   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   164   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   165   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   166   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   167   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   168   val mem: ''a * ''a list -> bool
   169   val mem_int: int * int list -> bool
   170   val mem_string: string * string list -> bool
   171   val union: ''a list * ''a list -> ''a list
   172   val union_int: int list * int list -> int list
   173   val union_string: string list * string list -> string list
   174   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   175   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   176   val inter: ''a list * ''a list -> ''a list
   177   val inter_int: int list * int list -> int list
   178   val inter_string: string list * string list -> string list
   179   val subset: ''a list * ''a list -> bool
   180   val subset_int: int list * int list -> bool
   181   val subset_string: string list * string list -> bool
   182   val eq_set: ''a list * ''a list -> bool
   183   val eq_set_string: string list * string list -> bool
   184   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   185   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   186   val \ : ''a list * ''a -> ''a list
   187   val \\ : ''a list * ''a list -> ''a list
   188   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   189   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   190   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   191 
   192   (*lists as multisets*)
   193   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   194   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   195 
   196   (*orders*)
   197   val is_equal: order -> bool
   198   val rev_order: order -> order
   199   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   200   val bool_ord: bool * bool -> order
   201   val int_ord: int * int -> order
   202   val string_ord: string * string -> order
   203   val fast_string_ord: string * string -> order
   204   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   205   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   206   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   207   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   208   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   209   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   210   val sort_strings: string list -> string list
   211   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   212 
   213   (*random numbers*)
   214   exception RANDOM
   215   val random: unit -> real
   216   val random_range: int -> int -> int
   217   val one_of: 'a list -> 'a
   218   val frequency: (int * 'a) list -> 'a
   219 
   220   (*misc*)
   221   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   222   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   223   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   224   val gensym: string -> string
   225   type stamp
   226   val stamp: unit -> stamp
   227   type serial
   228   val serial: unit -> serial
   229   val serial_string: unit -> string
   230   structure Object: sig type T end
   231 end;
   232 
   233 signature LIBRARY =
   234 sig
   235   include BASIC_LIBRARY
   236   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   237   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   238   val take: int * 'a list -> 'a list
   239   val drop: int * 'a list -> 'a list
   240   val last_elem: 'a list -> 'a
   241 end;
   242 
   243 structure Library: LIBRARY =
   244 struct
   245 
   246 (* functions *)
   247 
   248 fun undefined _ = raise Match;
   249 
   250 fun I x = x;
   251 fun K x = fn _ => x;
   252 fun curry f x y = f (x, y);
   253 fun uncurry f (x, y) = f x y;
   254 
   255 (*application and structured results -- old version*)
   256 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   257 
   258 (*conditional application*)
   259 fun b ? f = fn x => if b then f x else x;
   260 
   261 (*composition with multiple args*)
   262 fun (f oo g) x y = f (g x y);
   263 fun (f ooo g) x y z = f (g x y z);
   264 fun (f oooo g) x y z w = f (g x y z w);
   265 
   266 (*function exponentiation: f(...(f x)...) with n applications of f*)
   267 fun funpow (0: int) _ x = x
   268   | funpow n f x = funpow (n - 1) f (f x);
   269 
   270 
   271 (* errors *)
   272 
   273 exception SYS_ERROR of string;
   274 fun sys_error msg = raise SYS_ERROR msg;
   275 
   276 exception ERROR of string;
   277 fun error msg = raise ERROR msg;
   278 
   279 fun cat_error "" msg = error msg
   280   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   281 
   282 fun assert_all pred list msg =
   283   let
   284     fun ass [] = ()
   285       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   286   in ass list end;
   287 
   288 
   289 (* pairs *)
   290 
   291 fun pair x y = (x, y);
   292 fun rpair x y = (y, x);
   293 
   294 fun fst (x, y) = x;
   295 fun snd (x, y) = y;
   296 
   297 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   298 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   299 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   300 
   301 fun swap (x, y) = (y, x);
   302 
   303 fun apfst f (x, y) = (f x, y);
   304 fun apsnd f (x, y) = (x, f y);
   305 fun pairself f (x, y) = (f x, f y);
   306 
   307 
   308 (* booleans *)
   309 
   310 (*polymorphic equality*)
   311 fun equal x y = x = y;
   312 fun not_equal x y = x <> y;
   313 
   314 (*combining predicates*)
   315 fun p orf q = fn x => p x orelse q x;
   316 fun p andf q = fn x => p x andalso q x;
   317 
   318 val exists = List.exists;
   319 val forall = List.all;
   320 
   321 
   322 (* flags *)
   323 
   324 fun set flag = (flag := true; true);
   325 fun reset flag = (flag := false; false);
   326 fun toggle flag = (flag := not (! flag); ! flag);
   327 
   328 fun change r f = r := f (! r);
   329 
   330 (*temporarily set flag during execution*)
   331 fun setmp_noncritical flag value f x =
   332   let
   333     val orig_value = ! flag;
   334     val _ = flag := value;
   335     val result = Exn.capture f x;
   336     val _ = flag := orig_value;
   337   in Exn.release result end;
   338 
   339 fun setmp flag value f x = NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   340 
   341 
   342 
   343 (** lists **)
   344 
   345 exception UnequalLengths;
   346 
   347 fun single x = [x];
   348 
   349 fun the_single [x] = x
   350   | the_single _ = raise Empty;
   351 
   352 fun singleton f x = the_single (f [x]);
   353 
   354 fun yield_singleton f x = f [x] #>> the_single;
   355 
   356 fun apply [] x = x
   357   | apply (f :: fs) x = apply fs (f x);
   358 
   359 fun perhaps_apply funs arg =
   360   let
   361     fun app [] res = res
   362       | app (f :: fs) (changed, x) =
   363           (case f x of
   364             NONE => app fs (changed, x)
   365           | SOME x' => app fs (true, x'));
   366   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   367 
   368 fun perhaps_loop f arg =
   369   let
   370     fun loop (changed, x) =
   371       (case f x of
   372         NONE => (changed, x)
   373       | SOME x' => loop (true, x'));
   374   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   375 
   376 
   377 (* fold -- old versions *)
   378 
   379 (*the following versions of fold are designed to fit nicely with infixes*)
   380 
   381 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   382     for operators that associate to the left (TAIL RECURSIVE)*)
   383 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   384   let fun itl (e, [])  = e
   385         | itl (e, a::l) = itl (f(e, a), l)
   386   in  itl end;
   387 
   388 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   389     for operators that associate to the right (not tail recursive)*)
   390 fun foldr f (l, e) =
   391   let fun itr [] = e
   392         | itr (a::l) = f(a, itr l)
   393   in  itr l  end;
   394 
   395 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   396     for operators that associate to the left (TAIL RECURSIVE)*)
   397 fun foldl1 f [] = raise Empty
   398   | foldl1 f (x :: xs) = foldl f (x, xs);
   399 
   400 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   401     for n > 0, operators that associate to the right (not tail recursive)*)
   402 fun foldr1 f [] = raise Empty
   403   | foldr1 f l =
   404       let fun itr [x] = x
   405             | itr (x::l) = f(x, itr l)
   406       in  itr l  end;
   407 
   408 fun foldl_map f =
   409   let
   410     fun fold_aux (x, []) = (x, [])
   411       | fold_aux (x, y :: ys) =
   412           let
   413             val (x', y') = f (x, y);
   414             val (x'', ys') = fold_aux (x', ys);
   415           in (x'', y' :: ys') end;
   416   in fold_aux end;
   417 
   418 
   419 (* basic list functions *)
   420 
   421 fun eq_list eq (list1, list2) =
   422   let
   423     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   424       | eq_lst _ = true;
   425   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   426 
   427 fun maps f [] = []
   428   | maps f (x :: xs) = f x @ maps f xs;
   429 
   430 val filter = List.filter;
   431 fun filter_out f = filter (not o f);
   432 val map_filter = List.mapPartial;
   433 
   434 fun chop (0: int) xs = ([], xs)
   435   | chop _ [] = ([], [])
   436   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   437 
   438 (*take the first n elements from a list*)
   439 fun take (n: int, []) = []
   440   | take (n, x :: xs) =
   441       if n > 0 then x :: take (n - 1, xs) else [];
   442 
   443 (*drop the first n elements from a list*)
   444 fun drop (n: int, []) = []
   445   | drop (n, x :: xs) =
   446       if n > 0 then drop (n - 1, xs) else x :: xs;
   447 
   448 fun dropwhile P [] = []
   449   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   450 
   451 (*return nth element of a list, where 0 designates the first element;
   452   raise Subscript if list too short*)
   453 fun nth xs i = List.nth (xs, i);
   454 
   455 fun nth_list xss i = nth xss i handle Subscript => [];
   456 
   457 fun nth_map 0 f (x :: xs) = f x :: xs
   458   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   459   | nth_map (_: int) _ [] = raise Subscript;
   460 
   461 fun nth_drop n xs =
   462   List.take (xs, n) @ List.drop (xs, n + 1);
   463 
   464 fun map_index f =
   465   let
   466     fun mapp (_: int) [] = []
   467       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   468   in mapp 0 end;
   469 
   470 fun fold_index f =
   471   let
   472     fun fold_aux (_: int) [] y = y
   473       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   474   in fold_aux 0 end;
   475 
   476 val last_elem = List.last;
   477 
   478 (*rear decomposition*)
   479 fun split_last [] = raise Empty
   480   | split_last [x] = ([], x)
   481   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   482 
   483 (*find the position of an element in a list*)
   484 fun find_index pred =
   485   let fun find (_: int) [] = ~1
   486         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   487   in find 0 end;
   488 
   489 fun find_index_eq x = find_index (equal x);
   490 
   491 (*find first element satisfying predicate*)
   492 val find_first = List.find;
   493 
   494 (*get first element by lookup function*)
   495 fun get_first _ [] = NONE
   496   | get_first f (x :: xs) =
   497       (case f x of
   498         NONE => get_first f xs
   499       | some => some);
   500 
   501 fun get_index f =
   502   let
   503     fun get (_: int) [] = NONE
   504       | get i (x :: xs) =
   505           case f x
   506            of NONE => get (i + 1) xs
   507             | SOME y => SOME (i, y)
   508   in get 0 end;
   509 
   510 val flat = List.concat;
   511 
   512 fun unflat (xs :: xss) ys =
   513       let val (ps, qs) = chop (length xs) ys
   514       in ps :: unflat xss qs end
   515   | unflat [] [] = []
   516   | unflat _ _ = raise UnequalLengths;
   517 
   518 fun burrow f xss = unflat xss (f (flat xss));
   519 
   520 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   521 
   522 fun fold_burrow f xss s =
   523   apfst (unflat xss) (f (flat xss) s);
   524 
   525 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   526 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   527   | separate _ xs = xs;
   528 
   529 (*make the list [x, x, ..., x] of length n*)
   530 fun replicate (n: int) x =
   531   let fun rep (0, xs) = xs
   532         | rep (n, xs) = rep (n - 1, x :: xs)
   533   in
   534     if n < 0 then raise Subscript
   535     else rep (n, [])
   536   end;
   537 
   538 fun translate_string f = String.translate (f o String.str);
   539 
   540 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   541 fun multiply [] _ = []
   542   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   543 
   544 
   545 (* direct product *)
   546 
   547 fun map_product f _ [] = []
   548   | map_product f [] _ = []
   549   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   550 
   551 fun fold_product f _ [] z = z
   552   | fold_product f [] _ z = z
   553   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   554 
   555 
   556 (* lists of pairs *)
   557 
   558 exception UnequalLengths;
   559 
   560 fun map2 _ [] [] = []
   561   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   562   | map2 _ _ _ = raise UnequalLengths;
   563 
   564 fun fold2 f [] [] z = z
   565   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   566   | fold2 f _ _ _ = raise UnequalLengths;
   567 
   568 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   569   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   570   | zip_options _ [] = []
   571   | zip_options [] _ = raise UnequalLengths;
   572 
   573 (*combine two lists forming a list of pairs:
   574   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   575 fun [] ~~ [] = []
   576   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   577   | _ ~~ _ = raise UnequalLengths;
   578 
   579 (*inverse of ~~; the old 'split':
   580   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   581 val split_list = ListPair.unzip;
   582 
   583 
   584 (* prefixes, suffixes *)
   585 
   586 fun is_prefix _ [] _ = true
   587   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   588   | is_prefix eq _ _ = false;
   589 
   590 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   591    where xi is the first element that does not satisfy the predicate*)
   592 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   593   let fun take (rxs, []) = (rev rxs, [])
   594         | take (rxs, x :: xs) =
   595             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   596   in  take([], xs)  end;
   597 
   598 fun chop_prefix eq ([], ys) = ([], ([], ys))
   599   | chop_prefix eq (xs, []) = ([], (xs, []))
   600   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   601       if eq (x, y) then
   602         let val (ps', xys'') = chop_prefix eq (xs', ys')
   603         in (x :: ps', xys'') end
   604       else ([], (xs, ys));
   605 
   606 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   607    where xi is the last element that does not satisfy the predicate*)
   608 fun take_suffix _ [] = ([], [])
   609   | take_suffix pred (x :: xs) =
   610       (case take_suffix pred xs of
   611         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   612       | (prfx, sffx) => (x :: prfx, sffx));
   613 
   614 fun prefixes1 [] = []
   615   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   616 
   617 fun prefixes xs = [] :: prefixes1 xs;
   618 
   619 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   620 fun suffixes xs = [] :: suffixes1 xs;
   621 
   622 
   623 
   624 (** integers **)
   625 
   626 fun inc i = (i := ! i + (1: int); ! i);
   627 fun dec i = (i := ! i - (1: int); ! i);
   628 
   629 
   630 (* lists of integers *)
   631 
   632 (*make the list [from, from + 1, ..., to]*)
   633 fun ((i: int) upto j) =
   634   if i > j then [] else i :: (i + 1 upto j);
   635 
   636 (*make the list [from, from - 1, ..., to]*)
   637 fun ((i: int) downto j) =
   638   if i < j then [] else i :: (i - 1 downto j);
   639 
   640 
   641 (* convert integers to strings *)
   642 
   643 (*expand the number in the given base;
   644   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   645 fun radixpand (base, num) : int list =
   646   let
   647     fun radix (n, tail) =
   648       if n < base then n :: tail
   649       else radix (n div base, (n mod base) :: tail)
   650   in radix (num, []) end;
   651 
   652 (*expands a number into a string of characters starting from "zerochar";
   653   example: radixstring (2, "0", 8) gives "1000"*)
   654 fun radixstring (base, zerochar, num) =
   655   let val offset = ord zerochar;
   656       fun chrof n = chr (offset + n)
   657   in implode (map chrof (radixpand (base, num))) end;
   658 
   659 
   660 val string_of_int = Int.toString;
   661 
   662 fun signed_string_of_int i =
   663   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   664 
   665 fun string_of_indexname (a, 0) = a
   666   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   667 
   668 
   669 (* read integers *)
   670 
   671 fun read_radix_int radix cs =
   672   let
   673     val zero = ord "0";
   674     val limit = zero + radix;
   675     fun scan (num, []) = (num, [])
   676       | scan (num, c :: cs) =
   677         if zero <= ord c andalso ord c < limit then
   678           scan (radix * num + (ord c - zero), cs)
   679         else (num, c :: cs);
   680   in scan (0, cs) end;
   681 
   682 val read_int = read_radix_int 10;
   683 
   684 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   685 
   686 
   687 
   688 (** strings **)
   689 
   690 (* functions tuned for strings, avoiding explode *)
   691 
   692 fun nth_string str i =
   693   (case try String.substring (str, i, 1) of
   694     SOME s => s
   695   | NONE => raise Subscript);
   696 
   697 fun fold_string f str x0 =
   698   let
   699     val n = size str;
   700     fun iter (x, i) =
   701       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   702   in iter (x0, 0) end;
   703 
   704 fun exists_string pred str =
   705   let
   706     val n = size str;
   707     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   708   in ex 0 end;
   709 
   710 fun forall_string pred = not o exists_string (not o pred);
   711 
   712 (*enclose in brackets*)
   713 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   714 fun unenclose str = String.substring (str, 1, size str - 2);
   715 
   716 (*simple quoting (does not escape special chars)*)
   717 val quote = enclose "\"" "\"";
   718 
   719 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   720 fun space_implode a bs = implode (separate a bs);
   721 
   722 val commas = space_implode ", ";
   723 val commas_quote = commas o map quote;
   724 
   725 (*concatenate messages, one per line, into a string*)
   726 val cat_lines = space_implode "\n";
   727 
   728 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   729 fun space_explode _ "" = []
   730   | space_explode sep s = String.fields (fn c => str c = sep) s;
   731 
   732 val split_lines = space_explode "\n";
   733 
   734 fun prefix_lines "" txt = txt
   735   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   736 
   737 fun untabify chs =
   738   let
   739     val tab_width = 8;
   740 
   741     fun untab pos [] ys = rev ys
   742       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   743       | untab pos ("\t" :: xs) ys =
   744           let val d = tab_width - (pos mod tab_width)
   745           in untab (pos + d) xs (funpow d (cons " ") ys) end
   746       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   747   in
   748     if not (exists (fn c => c = "\t") chs) then chs
   749     else untab 0 chs []
   750   end;
   751 
   752 fun prefix prfx s = prfx ^ s;
   753 fun suffix sffx s = s ^ sffx;
   754 
   755 fun unprefix prfx s =
   756   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   757   else raise Fail "unprefix";
   758 
   759 fun unsuffix sffx s =
   760   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   761   else raise Fail "unsuffix";
   762 
   763 fun replicate_string (0: int) _ = ""
   764   | replicate_string 1 a = a
   765   | replicate_string k a =
   766       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   767       else replicate_string (k div 2) (a ^ a) ^ a;
   768 
   769 
   770 
   771 (** lists as sets -- see also Pure/General/ord_list.ML **)
   772 
   773 (*canonical member, insert, remove*)
   774 fun member eq list x =
   775   let
   776     fun memb [] = false
   777       | memb (y :: ys) = eq (x, y) orelse memb ys;
   778   in memb list end;
   779 
   780 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   781 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   782 fun update eq x xs = cons x (remove eq x xs);
   783 
   784 fun subtract eq = fold (remove eq);
   785 
   786 fun merge _ ([], ys) = ys
   787   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   788 
   789 (*old-style infixes*)
   790 fun x mem xs = member (op =) xs x;
   791 fun (x: int) mem_int xs = member (op =) xs x;
   792 fun (x: string) mem_string xs = member (op =) xs x;
   793 
   794 
   795 (*union of sets represented as lists: no repetitions*)
   796 fun xs union [] = xs
   797   | [] union ys = ys
   798   | (x :: xs) union ys = xs union (insert (op =) x ys);
   799 
   800 (*union of sets, optimized version for ints*)
   801 fun (xs:int list) union_int [] = xs
   802   | [] union_int ys = ys
   803   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   804 
   805 (*union of sets, optimized version for strings*)
   806 fun (xs:string list) union_string [] = xs
   807   | [] union_string ys = ys
   808   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   809 
   810 (*generalized union*)
   811 fun gen_union eq (xs, []) = xs
   812   | gen_union eq ([], ys) = ys
   813   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   814 
   815 
   816 (*intersection*)
   817 fun [] inter ys = []
   818   | (x :: xs) inter ys =
   819       if x mem ys then x :: (xs inter ys) else xs inter ys;
   820 
   821 (*intersection, optimized version for ints*)
   822 fun ([]:int list) inter_int ys = []
   823   | (x :: xs) inter_int ys =
   824       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   825 
   826 (*intersection, optimized version for strings *)
   827 fun ([]:string list) inter_string ys = []
   828   | (x :: xs) inter_string ys =
   829       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   830 
   831 (*generalized intersection*)
   832 fun gen_inter eq ([], ys) = []
   833   | gen_inter eq (x::xs, ys) =
   834       if member eq ys x then x :: gen_inter eq (xs, ys)
   835       else gen_inter eq (xs, ys);
   836 
   837 
   838 (*subset*)
   839 fun [] subset ys = true
   840   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   841 
   842 (*subset, optimized version for ints*)
   843 fun ([]: int list) subset_int ys = true
   844   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   845 
   846 (*subset, optimized version for strings*)
   847 fun ([]: string list) subset_string ys = true
   848   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   849 
   850 (*set equality*)
   851 fun eq_set (xs, ys) =
   852   xs = ys orelse (xs subset ys andalso ys subset xs);
   853 
   854 (*set equality for strings*)
   855 fun eq_set_string ((xs: string list), ys) =
   856   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   857 
   858 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   859 
   860 fun gen_eq_set eq (xs, ys) =
   861   eq_list eq (xs, ys) orelse
   862     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   863 
   864 
   865 (*removing an element from a list WITHOUT duplicates*)
   866 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   867   | [] \ x = [];
   868 fun ys \\ xs = foldl (op \) (ys,xs);
   869 
   870 
   871 (*makes a list of the distinct members of the input; preserves order, takes
   872   first of equal elements*)
   873 fun distinct eq lst =
   874   let
   875     fun dist (rev_seen, []) = rev rev_seen
   876       | dist (rev_seen, x :: xs) =
   877           if member eq rev_seen x then dist (rev_seen, xs)
   878           else dist (x :: rev_seen, xs);
   879   in dist ([], lst) end;
   880 
   881 (*returns a list containing all repeated elements exactly once; preserves
   882   order, takes first of equal elements*)
   883 fun duplicates eq lst =
   884   let
   885     fun dups (rev_dups, []) = rev rev_dups
   886       | dups (rev_dups, x :: xs) =
   887           if member eq rev_dups x orelse not (member eq xs x) then
   888             dups (rev_dups, xs)
   889           else dups (x :: rev_dups, xs);
   890   in dups ([], lst) end;
   891 
   892 fun has_duplicates eq =
   893   let
   894     fun dups [] = false
   895       | dups (x :: xs) = member eq xs x orelse dups xs;
   896   in dups end;
   897 
   898 
   899 
   900 (** lists as multisets **)
   901 
   902 fun remove1 _ _ [] = raise Empty
   903   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   904 
   905 fun submultiset _ ([], _)  = true
   906   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   907 
   908 
   909 
   910 (** orders **)
   911 
   912 fun is_equal EQUAL = true
   913   | is_equal _ = false;
   914 
   915 fun rev_order LESS = GREATER
   916   | rev_order EQUAL = EQUAL
   917   | rev_order GREATER = LESS;
   918 
   919 (*assume rel is a linear strict order*)
   920 fun make_ord rel (x, y) =
   921   if rel (x, y) then LESS
   922   else if rel (y, x) then GREATER
   923   else EQUAL;
   924 
   925 fun bool_ord (false, true) = LESS
   926   | bool_ord (true, false) = GREATER
   927   | bool_ord _ = EQUAL;
   928 
   929 val int_ord = Int.compare;
   930 val string_ord = String.compare;
   931 
   932 fun fast_string_ord (s1, s2) =
   933   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   934 
   935 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   936   | option_ord _ (NONE, NONE) = EQUAL
   937   | option_ord _ (NONE, SOME _) = LESS
   938   | option_ord _ (SOME _, NONE) = GREATER;
   939 
   940 (*lexicographic product*)
   941 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   942   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   943 
   944 (*dictionary order -- in general NOT well-founded!*)
   945 fun dict_ord elem_ord (x :: xs, y :: ys) =
   946       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   947   | dict_ord _ ([], []) = EQUAL
   948   | dict_ord _ ([], _ :: _) = LESS
   949   | dict_ord _ (_ :: _, []) = GREATER;
   950 
   951 (*lexicographic product of lists*)
   952 fun list_ord elem_ord (xs, ys) =
   953   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   954 
   955 
   956 (* sorting *)
   957 
   958 (*quicksort -- stable, i.e. does not reorder equal elements*)
   959 fun quicksort unique ord =
   960   let
   961     fun qsort [] = []
   962       | qsort (xs as [_]) = xs
   963       | qsort (xs as [x, y]) =
   964           (case ord (x, y) of
   965             LESS => xs
   966           | EQUAL => if unique then [x] else xs
   967           | GREATER => [y, x])
   968       | qsort xs =
   969           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   970           in qsort lts @ eqs @ qsort gts end
   971     and part _ [] = ([], [], [])
   972       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   973     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   974       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   975       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   976       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   977   in qsort end;
   978 
   979 fun sort ord = quicksort false ord;
   980 fun sort_distinct ord = quicksort true ord;
   981 
   982 val sort_strings = sort string_ord;
   983 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   984 
   985 
   986 
   987 (** random numbers **)
   988 
   989 exception RANDOM;
   990 
   991 fun rmod x y = x - y * Real.realFloor (x / y);
   992 
   993 local
   994   val a = 16807.0;
   995   val m = 2147483647.0;
   996   val random_seed = ref 1.0;
   997 in
   998 
   999 fun random () = CRITICAL (fn () =>
  1000   let val r = rmod (a * ! random_seed) m
  1001   in (random_seed := r; r) end);
  1002 
  1003 end;
  1004 
  1005 fun random_range l h =
  1006   if h < l orelse l < 0 then raise RANDOM
  1007   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1008 
  1009 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1010 
  1011 fun frequency xs =
  1012   let
  1013     val sum = foldl op + (0, map fst xs);
  1014     fun pick n ((k: int, x) :: xs) =
  1015       if n <= k then x else pick (n - k) xs
  1016   in pick (random_range 1 sum) xs end;
  1017 
  1018 
  1019 
  1020 (** misc **)
  1021 
  1022 fun divide_and_conquer decomp x =
  1023   let val (ys, recomb) = decomp x
  1024   in recomb (map (divide_and_conquer decomp) ys) end;
  1025 
  1026 
  1027 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1028    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1029 fun partition_list p i j =
  1030   let fun part k xs =
  1031             if k>j then
  1032               (case xs of [] => []
  1033                          | _ => raise Fail "partition_list")
  1034             else
  1035             let val (ns, rest) = List.partition (p k) xs;
  1036             in  ns :: part(k+1)rest  end
  1037   in  part (i: int) end;
  1038 
  1039 fun partition_eq (eq:'a * 'a -> bool) =
  1040   let
  1041     fun part [] = []
  1042       | part (x :: ys) =
  1043           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1044           in (x::xs)::(part xs') end
  1045   in part end;
  1046 
  1047 
  1048 
  1049 (* generating identifiers *)
  1050 
  1051 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1052 local
  1053 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1054 fun gensym_char i =
  1055   if i<26 then chr (ord "A" + i)
  1056   else if i<52 then chr (ord "a" + i - 26)
  1057   else chr (ord "0" + i - 52);
  1058 
  1059 val char_vec = Vector.tabulate (62, gensym_char);
  1060 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1061 
  1062 val gensym_seed = ref (0: int);
  1063 
  1064 in
  1065   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1066 end;
  1067 
  1068 
  1069 (* stamps and serial numbers *)
  1070 
  1071 type stamp = unit ref;
  1072 val stamp: unit -> stamp = ref;
  1073 
  1074 type serial = int;
  1075 val serial = Multithreading.serial;
  1076 val serial_string = string_of_int o serial;
  1077 
  1078 
  1079 (* generic objects *)
  1080 
  1081 (*note that the builtin exception datatype may be extended by new
  1082   constructors at any time*)
  1083 structure Object = struct type T = exn end;
  1084 
  1085 end;
  1086 
  1087 structure BasicLibrary: BASIC_LIBRARY = Library;
  1088 open BasicLibrary;