src/HOL/Limits.thy
author hoelzl
Mon Dec 03 18:19:01 2012 +0100 (2012-12-03)
changeset 50323 3764d4620fb3
parent 50322 b06b95a5fda2
child 50324 0a1242d5e7d4
permissions -rw-r--r--
add filterlim rules for unary minus and inverse
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Filters *}
    12 
    13 text {*
    14   This definition also allows non-proper filters.
    15 *}
    16 
    17 locale is_filter =
    18   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    19   assumes True: "F (\<lambda>x. True)"
    20   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    21   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    22 
    23 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    24 proof
    25   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    26 qed
    27 
    28 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    29   using Rep_filter [of F] by simp
    30 
    31 lemma Abs_filter_inverse':
    32   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    33   using assms by (simp add: Abs_filter_inverse)
    34 
    35 
    36 subsection {* Eventually *}
    37 
    38 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    39   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    40 
    41 lemma eventually_Abs_filter:
    42   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    43   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    44 
    45 lemma filter_eq_iff:
    46   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    47   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    48 
    49 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    50   unfolding eventually_def
    51   by (rule is_filter.True [OF is_filter_Rep_filter])
    52 
    53 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    54 proof -
    55   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    56   thus "eventually P F" by simp
    57 qed
    58 
    59 lemma eventually_mono:
    60   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    61   unfolding eventually_def
    62   by (rule is_filter.mono [OF is_filter_Rep_filter])
    63 
    64 lemma eventually_conj:
    65   assumes P: "eventually (\<lambda>x. P x) F"
    66   assumes Q: "eventually (\<lambda>x. Q x) F"
    67   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    68   using assms unfolding eventually_def
    69   by (rule is_filter.conj [OF is_filter_Rep_filter])
    70 
    71 lemma eventually_mp:
    72   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    73   assumes "eventually (\<lambda>x. P x) F"
    74   shows "eventually (\<lambda>x. Q x) F"
    75 proof (rule eventually_mono)
    76   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    77   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    78     using assms by (rule eventually_conj)
    79 qed
    80 
    81 lemma eventually_rev_mp:
    82   assumes "eventually (\<lambda>x. P x) F"
    83   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 using assms(2) assms(1) by (rule eventually_mp)
    86 
    87 lemma eventually_conj_iff:
    88   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    89   by (auto intro: eventually_conj elim: eventually_rev_mp)
    90 
    91 lemma eventually_elim1:
    92   assumes "eventually (\<lambda>i. P i) F"
    93   assumes "\<And>i. P i \<Longrightarrow> Q i"
    94   shows "eventually (\<lambda>i. Q i) F"
    95   using assms by (auto elim!: eventually_rev_mp)
    96 
    97 lemma eventually_elim2:
    98   assumes "eventually (\<lambda>i. P i) F"
    99   assumes "eventually (\<lambda>i. Q i) F"
   100   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   101   shows "eventually (\<lambda>i. R i) F"
   102   using assms by (auto elim!: eventually_rev_mp)
   103 
   104 lemma eventually_subst:
   105   assumes "eventually (\<lambda>n. P n = Q n) F"
   106   shows "eventually P F = eventually Q F" (is "?L = ?R")
   107 proof -
   108   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   109       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   110     by (auto elim: eventually_elim1)
   111   then show ?thesis by (auto elim: eventually_elim2)
   112 qed
   113 
   114 ML {*
   115   fun eventually_elim_tac ctxt thms thm =
   116     let
   117       val thy = Proof_Context.theory_of ctxt
   118       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   119       val raw_elim_thm =
   120         (@{thm allI} RS @{thm always_eventually})
   121         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   122         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   123       val cases_prop = prop_of (raw_elim_thm RS thm)
   124       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   125     in
   126       CASES cases (rtac raw_elim_thm 1) thm
   127     end
   128 *}
   129 
   130 method_setup eventually_elim = {*
   131   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   132 *} "elimination of eventually quantifiers"
   133 
   134 
   135 subsection {* Finer-than relation *}
   136 
   137 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   138 filter @{term F'}. *}
   139 
   140 instantiation filter :: (type) complete_lattice
   141 begin
   142 
   143 definition le_filter_def:
   144   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   145 
   146 definition
   147   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   148 
   149 definition
   150   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   151 
   152 definition
   153   "bot = Abs_filter (\<lambda>P. True)"
   154 
   155 definition
   156   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   157 
   158 definition
   159   "inf F F' = Abs_filter
   160       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   161 
   162 definition
   163   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   164 
   165 definition
   166   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   167 
   168 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   169   unfolding top_filter_def
   170   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   171 
   172 lemma eventually_bot [simp]: "eventually P bot"
   173   unfolding bot_filter_def
   174   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   175 
   176 lemma eventually_sup:
   177   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   178   unfolding sup_filter_def
   179   by (rule eventually_Abs_filter, rule is_filter.intro)
   180      (auto elim!: eventually_rev_mp)
   181 
   182 lemma eventually_inf:
   183   "eventually P (inf F F') \<longleftrightarrow>
   184    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   185   unfolding inf_filter_def
   186   apply (rule eventually_Abs_filter, rule is_filter.intro)
   187   apply (fast intro: eventually_True)
   188   apply clarify
   189   apply (intro exI conjI)
   190   apply (erule (1) eventually_conj)
   191   apply (erule (1) eventually_conj)
   192   apply simp
   193   apply auto
   194   done
   195 
   196 lemma eventually_Sup:
   197   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   198   unfolding Sup_filter_def
   199   apply (rule eventually_Abs_filter, rule is_filter.intro)
   200   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   201   done
   202 
   203 instance proof
   204   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   205   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   206     by (rule less_filter_def) }
   207   { show "F \<le> F"
   208     unfolding le_filter_def by simp }
   209   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   210     unfolding le_filter_def by simp }
   211   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   212     unfolding le_filter_def filter_eq_iff by fast }
   213   { show "F \<le> top"
   214     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
   215   { show "bot \<le> F"
   216     unfolding le_filter_def by simp }
   217   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   218     unfolding le_filter_def eventually_sup by simp_all }
   219   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   220     unfolding le_filter_def eventually_sup by simp }
   221   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   222     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   223   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   224     unfolding le_filter_def eventually_inf
   225     by (auto elim!: eventually_mono intro: eventually_conj) }
   226   { assume "F \<in> S" thus "F \<le> Sup S"
   227     unfolding le_filter_def eventually_Sup by simp }
   228   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   229     unfolding le_filter_def eventually_Sup by simp }
   230   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   231     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   232   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   233     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   234 qed
   235 
   236 end
   237 
   238 lemma filter_leD:
   239   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   240   unfolding le_filter_def by simp
   241 
   242 lemma filter_leI:
   243   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   244   unfolding le_filter_def by simp
   245 
   246 lemma eventually_False:
   247   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   248   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   249 
   250 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   251   where "trivial_limit F \<equiv> F = bot"
   252 
   253 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   254   by (rule eventually_False [symmetric])
   255 
   256 
   257 subsection {* Map function for filters *}
   258 
   259 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   260   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   261 
   262 lemma eventually_filtermap:
   263   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   264   unfolding filtermap_def
   265   apply (rule eventually_Abs_filter)
   266   apply (rule is_filter.intro)
   267   apply (auto elim!: eventually_rev_mp)
   268   done
   269 
   270 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   271   by (simp add: filter_eq_iff eventually_filtermap)
   272 
   273 lemma filtermap_filtermap:
   274   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   275   by (simp add: filter_eq_iff eventually_filtermap)
   276 
   277 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   278   unfolding le_filter_def eventually_filtermap by simp
   279 
   280 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   281   by (simp add: filter_eq_iff eventually_filtermap)
   282 
   283 subsection {* Order filters *}
   284 
   285 definition at_top :: "('a::order) filter"
   286   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   287 
   288 lemma eventually_at_top_linorder:
   289   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_top \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   290   unfolding at_top_def
   291 proof (rule eventually_Abs_filter, rule is_filter.intro)
   292   fix P Q :: "'a \<Rightarrow> bool"
   293   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   294   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   295   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   296   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   297 qed auto
   298 
   299 lemma eventually_at_top_dense:
   300   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_top \<longleftrightarrow> (\<exists>N. \<forall>n>N. P n)"
   301   unfolding eventually_at_top_linorder
   302 proof safe
   303   fix N assume "\<forall>n\<ge>N. P n" then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   304 next
   305   fix N assume "\<forall>n>N. P n" 
   306   moreover from gt_ex[of N] guess y ..
   307   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   308 qed
   309 
   310 definition at_bot :: "('a::order) filter"
   311   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   312 
   313 lemma eventually_at_bot_linorder:
   314   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   315   unfolding at_bot_def
   316 proof (rule eventually_Abs_filter, rule is_filter.intro)
   317   fix P Q :: "'a \<Rightarrow> bool"
   318   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   319   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   320   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   321   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   322 qed auto
   323 
   324 lemma eventually_at_bot_dense:
   325   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   326   unfolding eventually_at_bot_linorder
   327 proof safe
   328   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   329 next
   330   fix N assume "\<forall>n<N. P n" 
   331   moreover from lt_ex[of N] guess y ..
   332   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   333 qed
   334 
   335 subsection {* Sequentially *}
   336 
   337 abbreviation sequentially :: "nat filter"
   338   where "sequentially == at_top"
   339 
   340 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   341   unfolding at_top_def by simp
   342 
   343 lemma eventually_sequentially:
   344   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   345   by (rule eventually_at_top_linorder)
   346 
   347 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   348   unfolding filter_eq_iff eventually_sequentially by auto
   349 
   350 lemmas trivial_limit_sequentially = sequentially_bot
   351 
   352 lemma eventually_False_sequentially [simp]:
   353   "\<not> eventually (\<lambda>n. False) sequentially"
   354   by (simp add: eventually_False)
   355 
   356 lemma le_sequentially:
   357   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   358   unfolding le_filter_def eventually_sequentially
   359   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   360 
   361 lemma eventually_sequentiallyI:
   362   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   363   shows "eventually P sequentially"
   364 using assms by (auto simp: eventually_sequentially)
   365 
   366 
   367 subsection {* Standard filters *}
   368 
   369 definition within :: "'a filter \<Rightarrow> 'a set \<Rightarrow> 'a filter" (infixr "within" 70)
   370   where "F within S = Abs_filter (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F)"
   371 
   372 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   373   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   374 
   375 definition (in topological_space) at :: "'a \<Rightarrow> 'a filter"
   376   where "at a = nhds a within - {a}"
   377 
   378 lemma eventually_within:
   379   "eventually P (F within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F"
   380   unfolding within_def
   381   by (rule eventually_Abs_filter, rule is_filter.intro)
   382      (auto elim!: eventually_rev_mp)
   383 
   384 lemma within_UNIV [simp]: "F within UNIV = F"
   385   unfolding filter_eq_iff eventually_within by simp
   386 
   387 lemma within_empty [simp]: "F within {} = bot"
   388   unfolding filter_eq_iff eventually_within by simp
   389 
   390 lemma within_le: "F within S \<le> F"
   391   unfolding le_filter_def eventually_within by (auto elim: eventually_elim1)
   392 
   393 lemma le_withinI: "F \<le> F' \<Longrightarrow> eventually (\<lambda>x. x \<in> S) F \<Longrightarrow> F \<le> F' within S"
   394   unfolding le_filter_def eventually_within by (auto elim: eventually_elim2)
   395 
   396 lemma le_within_iff: "eventually (\<lambda>x. x \<in> S) F \<Longrightarrow> F \<le> F' within S \<longleftrightarrow> F \<le> F'"
   397   by (blast intro: within_le le_withinI order_trans)
   398 
   399 lemma eventually_nhds:
   400   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   401 unfolding nhds_def
   402 proof (rule eventually_Abs_filter, rule is_filter.intro)
   403   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   404   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
   405 next
   406   fix P Q
   407   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   408      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   409   then obtain S T where
   410     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   411     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   412   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   413     by (simp add: open_Int)
   414   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
   415 qed auto
   416 
   417 lemma eventually_nhds_metric:
   418   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   419 unfolding eventually_nhds open_dist
   420 apply safe
   421 apply fast
   422 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   423 apply clarsimp
   424 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   425 apply (simp only: less_diff_eq)
   426 apply (erule le_less_trans [OF dist_triangle])
   427 done
   428 
   429 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   430   unfolding trivial_limit_def eventually_nhds by simp
   431 
   432 lemma eventually_at_topological:
   433   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   434 unfolding at_def eventually_within eventually_nhds by simp
   435 
   436 lemma eventually_at:
   437   fixes a :: "'a::metric_space"
   438   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   439 unfolding at_def eventually_within eventually_nhds_metric by auto
   440 
   441 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   442   unfolding trivial_limit_def eventually_at_topological
   443   by (safe, case_tac "S = {a}", simp, fast, fast)
   444 
   445 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   446   by (simp add: at_eq_bot_iff not_open_singleton)
   447 
   448 
   449 subsection {* Boundedness *}
   450 
   451 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   452   where "Bfun f F = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
   453 
   454 lemma BfunI:
   455   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
   456 unfolding Bfun_def
   457 proof (intro exI conjI allI)
   458   show "0 < max K 1" by simp
   459 next
   460   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
   461     using K by (rule eventually_elim1, simp)
   462 qed
   463 
   464 lemma BfunE:
   465   assumes "Bfun f F"
   466   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   467 using assms unfolding Bfun_def by fast
   468 
   469 
   470 subsection {* Convergence to Zero *}
   471 
   472 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   473   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   474 
   475 lemma ZfunI:
   476   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   477   unfolding Zfun_def by simp
   478 
   479 lemma ZfunD:
   480   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   481   unfolding Zfun_def by simp
   482 
   483 lemma Zfun_ssubst:
   484   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   485   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   486 
   487 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   488   unfolding Zfun_def by simp
   489 
   490 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   491   unfolding Zfun_def by simp
   492 
   493 lemma Zfun_imp_Zfun:
   494   assumes f: "Zfun f F"
   495   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   496   shows "Zfun (\<lambda>x. g x) F"
   497 proof (cases)
   498   assume K: "0 < K"
   499   show ?thesis
   500   proof (rule ZfunI)
   501     fix r::real assume "0 < r"
   502     hence "0 < r / K"
   503       using K by (rule divide_pos_pos)
   504     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   505       using ZfunD [OF f] by fast
   506     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   507     proof eventually_elim
   508       case (elim x)
   509       hence "norm (f x) * K < r"
   510         by (simp add: pos_less_divide_eq K)
   511       thus ?case
   512         by (simp add: order_le_less_trans [OF elim(1)])
   513     qed
   514   qed
   515 next
   516   assume "\<not> 0 < K"
   517   hence K: "K \<le> 0" by (simp only: not_less)
   518   show ?thesis
   519   proof (rule ZfunI)
   520     fix r :: real
   521     assume "0 < r"
   522     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   523     proof eventually_elim
   524       case (elim x)
   525       also have "norm (f x) * K \<le> norm (f x) * 0"
   526         using K norm_ge_zero by (rule mult_left_mono)
   527       finally show ?case
   528         using `0 < r` by simp
   529     qed
   530   qed
   531 qed
   532 
   533 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   534   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   535 
   536 lemma Zfun_add:
   537   assumes f: "Zfun f F" and g: "Zfun g F"
   538   shows "Zfun (\<lambda>x. f x + g x) F"
   539 proof (rule ZfunI)
   540   fix r::real assume "0 < r"
   541   hence r: "0 < r / 2" by simp
   542   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   543     using f r by (rule ZfunD)
   544   moreover
   545   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   546     using g r by (rule ZfunD)
   547   ultimately
   548   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   549   proof eventually_elim
   550     case (elim x)
   551     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   552       by (rule norm_triangle_ineq)
   553     also have "\<dots> < r/2 + r/2"
   554       using elim by (rule add_strict_mono)
   555     finally show ?case
   556       by simp
   557   qed
   558 qed
   559 
   560 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   561   unfolding Zfun_def by simp
   562 
   563 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   564   by (simp only: diff_minus Zfun_add Zfun_minus)
   565 
   566 lemma (in bounded_linear) Zfun:
   567   assumes g: "Zfun g F"
   568   shows "Zfun (\<lambda>x. f (g x)) F"
   569 proof -
   570   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   571     using bounded by fast
   572   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   573     by simp
   574   with g show ?thesis
   575     by (rule Zfun_imp_Zfun)
   576 qed
   577 
   578 lemma (in bounded_bilinear) Zfun:
   579   assumes f: "Zfun f F"
   580   assumes g: "Zfun g F"
   581   shows "Zfun (\<lambda>x. f x ** g x) F"
   582 proof (rule ZfunI)
   583   fix r::real assume r: "0 < r"
   584   obtain K where K: "0 < K"
   585     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   586     using pos_bounded by fast
   587   from K have K': "0 < inverse K"
   588     by (rule positive_imp_inverse_positive)
   589   have "eventually (\<lambda>x. norm (f x) < r) F"
   590     using f r by (rule ZfunD)
   591   moreover
   592   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   593     using g K' by (rule ZfunD)
   594   ultimately
   595   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   596   proof eventually_elim
   597     case (elim x)
   598     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   599       by (rule norm_le)
   600     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   601       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   602     also from K have "r * inverse K * K = r"
   603       by simp
   604     finally show ?case .
   605   qed
   606 qed
   607 
   608 lemma (in bounded_bilinear) Zfun_left:
   609   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   610   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   611 
   612 lemma (in bounded_bilinear) Zfun_right:
   613   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   614   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   615 
   616 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   617 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   618 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   619 
   620 
   621 subsection {* Limits *}
   622 
   623 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   624   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   625 
   626 syntax
   627   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   628 
   629 translations
   630   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   631 
   632 lemma filterlimE: "(LIM x F1. f x :> F2) \<Longrightarrow> eventually P F2 \<Longrightarrow> eventually (\<lambda>x. P (f x)) F1"
   633   by (auto simp: filterlim_def eventually_filtermap le_filter_def)
   634 
   635 lemma filterlimI: "(\<And>P. eventually P F2 \<Longrightarrow> eventually (\<lambda>x. P (f x)) F1) \<Longrightarrow> (LIM x F1. f x :> F2)"
   636   by (auto simp: filterlim_def eventually_filtermap le_filter_def)
   637 
   638 lemma filterlim_compose: 
   639   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   640   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   641 
   642 lemma filterlim_mono: 
   643   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   644   unfolding filterlim_def by (metis filtermap_mono order_trans)
   645 
   646 abbreviation (in topological_space)
   647   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   648   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   649 
   650 ML {*
   651 structure Tendsto_Intros = Named_Thms
   652 (
   653   val name = @{binding tendsto_intros}
   654   val description = "introduction rules for tendsto"
   655 )
   656 *}
   657 
   658 setup Tendsto_Intros.setup
   659 
   660 lemma tendsto_def: "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   661   unfolding filterlim_def
   662 proof safe
   663   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   664   then show "eventually (\<lambda>x. f x \<in> S) F"
   665     unfolding eventually_nhds eventually_filtermap le_filter_def
   666     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   667 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   668 
   669 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   670   unfolding tendsto_def le_filter_def by fast
   671 
   672 lemma topological_tendstoI:
   673   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F)
   674     \<Longrightarrow> (f ---> l) F"
   675   unfolding tendsto_def by auto
   676 
   677 lemma topological_tendstoD:
   678   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   679   unfolding tendsto_def by auto
   680 
   681 lemma tendstoI:
   682   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   683   shows "(f ---> l) F"
   684   apply (rule topological_tendstoI)
   685   apply (simp add: open_dist)
   686   apply (drule (1) bspec, clarify)
   687   apply (drule assms)
   688   apply (erule eventually_elim1, simp)
   689   done
   690 
   691 lemma tendstoD:
   692   "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   693   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   694   apply (clarsimp simp add: open_dist)
   695   apply (rule_tac x="e - dist x l" in exI, clarsimp)
   696   apply (simp only: less_diff_eq)
   697   apply (erule le_less_trans [OF dist_triangle])
   698   apply simp
   699   apply simp
   700   done
   701 
   702 lemma tendsto_iff:
   703   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
   704   using tendstoI tendstoD by fast
   705 
   706 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   707   by (simp only: tendsto_iff Zfun_def dist_norm)
   708 
   709 lemma tendsto_bot [simp]: "(f ---> a) bot"
   710   unfolding tendsto_def by simp
   711 
   712 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   713   unfolding tendsto_def eventually_at_topological by auto
   714 
   715 lemma tendsto_ident_at_within [tendsto_intros]:
   716   "((\<lambda>x. x) ---> a) (at a within S)"
   717   unfolding tendsto_def eventually_within eventually_at_topological by auto
   718 
   719 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   720   by (simp add: tendsto_def)
   721 
   722 lemma tendsto_unique:
   723   fixes f :: "'a \<Rightarrow> 'b::t2_space"
   724   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   725   shows "a = b"
   726 proof (rule ccontr)
   727   assume "a \<noteq> b"
   728   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   729     using hausdorff [OF `a \<noteq> b`] by fast
   730   have "eventually (\<lambda>x. f x \<in> U) F"
   731     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   732   moreover
   733   have "eventually (\<lambda>x. f x \<in> V) F"
   734     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   735   ultimately
   736   have "eventually (\<lambda>x. False) F"
   737   proof eventually_elim
   738     case (elim x)
   739     hence "f x \<in> U \<inter> V" by simp
   740     with `U \<inter> V = {}` show ?case by simp
   741   qed
   742   with `\<not> trivial_limit F` show "False"
   743     by (simp add: trivial_limit_def)
   744 qed
   745 
   746 lemma tendsto_const_iff:
   747   fixes a b :: "'a::t2_space"
   748   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a) ---> b) F \<longleftrightarrow> a = b"
   749   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   750 
   751 lemma tendsto_at_iff_tendsto_nhds:
   752   "(g ---> g l) (at l) \<longleftrightarrow> (g ---> g l) (nhds l)"
   753   unfolding tendsto_def at_def eventually_within
   754   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
   755 
   756 lemma tendsto_compose:
   757   "(g ---> g l) (at l) \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
   758   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
   759 
   760 lemma tendsto_compose_eventually:
   761   assumes g: "(g ---> m) (at l)"
   762   assumes f: "(f ---> l) F"
   763   assumes inj: "eventually (\<lambda>x. f x \<noteq> l) F"
   764   shows "((\<lambda>x. g (f x)) ---> m) F"
   765 proof -
   766   from f inj have "LIM x F. f x :> at l"
   767     unfolding filterlim_def at_def by (simp add: le_within_iff eventually_filtermap)
   768   from filterlim_compose[OF g this] show ?thesis .
   769 qed
   770 
   771 lemma metric_tendsto_imp_tendsto:
   772   assumes f: "(f ---> a) F"
   773   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
   774   shows "(g ---> b) F"
   775 proof (rule tendstoI)
   776   fix e :: real assume "0 < e"
   777   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
   778   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
   779     using le_less_trans by (rule eventually_elim2)
   780 qed
   781 
   782 subsubsection {* Distance and norms *}
   783 
   784 lemma tendsto_dist [tendsto_intros]:
   785   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   786   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   787 proof (rule tendstoI)
   788   fix e :: real assume "0 < e"
   789   hence e2: "0 < e/2" by simp
   790   from tendstoD [OF f e2] tendstoD [OF g e2]
   791   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   792   proof (eventually_elim)
   793     case (elim x)
   794     then show "dist (dist (f x) (g x)) (dist l m) < e"
   795       unfolding dist_real_def
   796       using dist_triangle2 [of "f x" "g x" "l"]
   797       using dist_triangle2 [of "g x" "l" "m"]
   798       using dist_triangle3 [of "l" "m" "f x"]
   799       using dist_triangle [of "f x" "m" "g x"]
   800       by arith
   801   qed
   802 qed
   803 
   804 lemma norm_conv_dist: "norm x = dist x 0"
   805   unfolding dist_norm by simp
   806 
   807 lemma tendsto_norm [tendsto_intros]:
   808   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   809   unfolding norm_conv_dist by (intro tendsto_intros)
   810 
   811 lemma tendsto_norm_zero:
   812   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   813   by (drule tendsto_norm, simp)
   814 
   815 lemma tendsto_norm_zero_cancel:
   816   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   817   unfolding tendsto_iff dist_norm by simp
   818 
   819 lemma tendsto_norm_zero_iff:
   820   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   821   unfolding tendsto_iff dist_norm by simp
   822 
   823 lemma tendsto_rabs [tendsto_intros]:
   824   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   825   by (fold real_norm_def, rule tendsto_norm)
   826 
   827 lemma tendsto_rabs_zero:
   828   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   829   by (fold real_norm_def, rule tendsto_norm_zero)
   830 
   831 lemma tendsto_rabs_zero_cancel:
   832   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   833   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   834 
   835 lemma tendsto_rabs_zero_iff:
   836   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   837   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   838 
   839 subsubsection {* Addition and subtraction *}
   840 
   841 lemma tendsto_add [tendsto_intros]:
   842   fixes a b :: "'a::real_normed_vector"
   843   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   844   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   845 
   846 lemma tendsto_add_zero:
   847   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
   848   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   849   by (drule (1) tendsto_add, simp)
   850 
   851 lemma tendsto_minus [tendsto_intros]:
   852   fixes a :: "'a::real_normed_vector"
   853   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   854   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   855 
   856 lemma tendsto_minus_cancel:
   857   fixes a :: "'a::real_normed_vector"
   858   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   859   by (drule tendsto_minus, simp)
   860 
   861 lemma tendsto_diff [tendsto_intros]:
   862   fixes a b :: "'a::real_normed_vector"
   863   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   864   by (simp add: diff_minus tendsto_add tendsto_minus)
   865 
   866 lemma tendsto_setsum [tendsto_intros]:
   867   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   868   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   869   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   870 proof (cases "finite S")
   871   assume "finite S" thus ?thesis using assms
   872     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   873 next
   874   assume "\<not> finite S" thus ?thesis
   875     by (simp add: tendsto_const)
   876 qed
   877 
   878 lemma real_tendsto_sandwich:
   879   fixes f g h :: "'a \<Rightarrow> real"
   880   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   881   assumes lim: "(f ---> c) net" "(h ---> c) net"
   882   shows "(g ---> c) net"
   883 proof -
   884   have "((\<lambda>n. g n - f n) ---> 0) net"
   885   proof (rule metric_tendsto_imp_tendsto)
   886     show "eventually (\<lambda>n. dist (g n - f n) 0 \<le> dist (h n - f n) 0) net"
   887       using ev by (rule eventually_elim2) (simp add: dist_real_def)
   888     show "((\<lambda>n. h n - f n) ---> 0) net"
   889       using tendsto_diff[OF lim(2,1)] by simp
   890   qed
   891   from tendsto_add[OF this lim(1)] show ?thesis by simp
   892 qed
   893 
   894 subsubsection {* Linear operators and multiplication *}
   895 
   896 lemma (in bounded_linear) tendsto:
   897   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   898   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   899 
   900 lemma (in bounded_linear) tendsto_zero:
   901   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   902   by (drule tendsto, simp only: zero)
   903 
   904 lemma (in bounded_bilinear) tendsto:
   905   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   906   by (simp only: tendsto_Zfun_iff prod_diff_prod
   907                  Zfun_add Zfun Zfun_left Zfun_right)
   908 
   909 lemma (in bounded_bilinear) tendsto_zero:
   910   assumes f: "(f ---> 0) F"
   911   assumes g: "(g ---> 0) F"
   912   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   913   using tendsto [OF f g] by (simp add: zero_left)
   914 
   915 lemma (in bounded_bilinear) tendsto_left_zero:
   916   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   917   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   918 
   919 lemma (in bounded_bilinear) tendsto_right_zero:
   920   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   921   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   922 
   923 lemmas tendsto_of_real [tendsto_intros] =
   924   bounded_linear.tendsto [OF bounded_linear_of_real]
   925 
   926 lemmas tendsto_scaleR [tendsto_intros] =
   927   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   928 
   929 lemmas tendsto_mult [tendsto_intros] =
   930   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   931 
   932 lemmas tendsto_mult_zero =
   933   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   934 
   935 lemmas tendsto_mult_left_zero =
   936   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   937 
   938 lemmas tendsto_mult_right_zero =
   939   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   940 
   941 lemma tendsto_power [tendsto_intros]:
   942   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   943   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   944   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   945 
   946 lemma tendsto_setprod [tendsto_intros]:
   947   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   948   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   949   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   950 proof (cases "finite S")
   951   assume "finite S" thus ?thesis using assms
   952     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   953 next
   954   assume "\<not> finite S" thus ?thesis
   955     by (simp add: tendsto_const)
   956 qed
   957 
   958 subsubsection {* Inverse and division *}
   959 
   960 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   961   assumes f: "Zfun f F"
   962   assumes g: "Bfun g F"
   963   shows "Zfun (\<lambda>x. f x ** g x) F"
   964 proof -
   965   obtain K where K: "0 \<le> K"
   966     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   967     using nonneg_bounded by fast
   968   obtain B where B: "0 < B"
   969     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   970     using g by (rule BfunE)
   971   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   972   using norm_g proof eventually_elim
   973     case (elim x)
   974     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   975       by (rule norm_le)
   976     also have "\<dots> \<le> norm (f x) * B * K"
   977       by (intro mult_mono' order_refl norm_g norm_ge_zero
   978                 mult_nonneg_nonneg K elim)
   979     also have "\<dots> = norm (f x) * (B * K)"
   980       by (rule mult_assoc)
   981     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   982   qed
   983   with f show ?thesis
   984     by (rule Zfun_imp_Zfun)
   985 qed
   986 
   987 lemma (in bounded_bilinear) flip:
   988   "bounded_bilinear (\<lambda>x y. y ** x)"
   989   apply default
   990   apply (rule add_right)
   991   apply (rule add_left)
   992   apply (rule scaleR_right)
   993   apply (rule scaleR_left)
   994   apply (subst mult_commute)
   995   using bounded by fast
   996 
   997 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   998   assumes f: "Bfun f F"
   999   assumes g: "Zfun g F"
  1000   shows "Zfun (\<lambda>x. f x ** g x) F"
  1001   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
  1002 
  1003 lemma Bfun_inverse_lemma:
  1004   fixes x :: "'a::real_normed_div_algebra"
  1005   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1006   apply (subst nonzero_norm_inverse, clarsimp)
  1007   apply (erule (1) le_imp_inverse_le)
  1008   done
  1009 
  1010 lemma Bfun_inverse:
  1011   fixes a :: "'a::real_normed_div_algebra"
  1012   assumes f: "(f ---> a) F"
  1013   assumes a: "a \<noteq> 0"
  1014   shows "Bfun (\<lambda>x. inverse (f x)) F"
  1015 proof -
  1016   from a have "0 < norm a" by simp
  1017   hence "\<exists>r>0. r < norm a" by (rule dense)
  1018   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
  1019   have "eventually (\<lambda>x. dist (f x) a < r) F"
  1020     using tendstoD [OF f r1] by fast
  1021   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
  1022   proof eventually_elim
  1023     case (elim x)
  1024     hence 1: "norm (f x - a) < r"
  1025       by (simp add: dist_norm)
  1026     hence 2: "f x \<noteq> 0" using r2 by auto
  1027     hence "norm (inverse (f x)) = inverse (norm (f x))"
  1028       by (rule nonzero_norm_inverse)
  1029     also have "\<dots> \<le> inverse (norm a - r)"
  1030     proof (rule le_imp_inverse_le)
  1031       show "0 < norm a - r" using r2 by simp
  1032     next
  1033       have "norm a - norm (f x) \<le> norm (a - f x)"
  1034         by (rule norm_triangle_ineq2)
  1035       also have "\<dots> = norm (f x - a)"
  1036         by (rule norm_minus_commute)
  1037       also have "\<dots> < r" using 1 .
  1038       finally show "norm a - r \<le> norm (f x)" by simp
  1039     qed
  1040     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
  1041   qed
  1042   thus ?thesis by (rule BfunI)
  1043 qed
  1044 
  1045 lemma tendsto_inverse [tendsto_intros]:
  1046   fixes a :: "'a::real_normed_div_algebra"
  1047   assumes f: "(f ---> a) F"
  1048   assumes a: "a \<noteq> 0"
  1049   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
  1050 proof -
  1051   from a have "0 < norm a" by simp
  1052   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
  1053     by (rule tendstoD)
  1054   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
  1055     unfolding dist_norm by (auto elim!: eventually_elim1)
  1056   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
  1057     - (inverse (f x) * (f x - a) * inverse a)) F"
  1058     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
  1059   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
  1060     by (intro Zfun_minus Zfun_mult_left
  1061       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
  1062       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
  1063   ultimately show ?thesis
  1064     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
  1065 qed
  1066 
  1067 lemma tendsto_divide [tendsto_intros]:
  1068   fixes a b :: "'a::real_normed_field"
  1069   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
  1070     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
  1071   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
  1072 
  1073 lemma tendsto_sgn [tendsto_intros]:
  1074   fixes l :: "'a::real_normed_vector"
  1075   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
  1076   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1077 
  1078 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1079 
  1080 lemma filterlim_at_top:
  1081   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1082   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1083   by (safe elim!: filterlimE intro!: filterlimI)
  1084      (auto simp: eventually_at_top_dense elim!: eventually_elim1)
  1085 
  1086 lemma filterlim_at_top_gt:
  1087   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1088   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z < f x) F)"
  1089   unfolding filterlim_at_top
  1090 proof safe
  1091   fix Z assume *: "\<forall>Z>c. eventually (\<lambda>x. Z < f x) F"
  1092   from gt_ex[of "max Z c"] guess x ..
  1093   with *[THEN spec, of x] show "eventually (\<lambda>x. Z < f x) F"
  1094     by (auto elim!: eventually_elim1)
  1095 qed simp
  1096 
  1097 lemma filterlim_at_bot: 
  1098   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1099   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1100   by (safe elim!: filterlimE intro!: filterlimI)
  1101      (auto simp: eventually_at_bot_dense elim!: eventually_elim1)
  1102 
  1103 lemma filterlim_at_bot_lt:
  1104   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1105   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z > f x) F)"
  1106   unfolding filterlim_at_bot
  1107 proof safe
  1108   fix Z assume *: "\<forall>Z<c. eventually (\<lambda>x. Z > f x) F"
  1109   from lt_ex[of "min Z c"] guess x ..
  1110   with *[THEN spec, of x] show "eventually (\<lambda>x. Z > f x) F"
  1111     by (auto elim!: eventually_elim1)
  1112 qed simp
  1113 
  1114 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1115   unfolding filterlim_at_top
  1116   apply (intro allI)
  1117   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1118   apply (auto simp: natceiling_le_eq)
  1119   done
  1120 
  1121 lemma filterlim_inverse_at_top_pos:
  1122   "LIM x (nhds 0 within {0::real <..}). inverse x :> at_top"
  1123   unfolding filterlim_at_top_gt[where c=0] eventually_within
  1124 proof safe
  1125   fix Z :: real assume [arith]: "0 < Z"
  1126   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1127     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1128   then show "eventually (\<lambda>x. x \<in> {0<..} \<longrightarrow> Z < inverse x) (nhds 0)"
  1129     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1130 qed
  1131 
  1132 lemma filterlim_inverse_at_top:
  1133   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1134   by (intro filterlim_compose[OF filterlim_inverse_at_top_pos])
  1135      (simp add: filterlim_def eventually_filtermap le_within_iff)
  1136 
  1137 lemma filterlim_inverse_at_bot_neg:
  1138   "LIM x (nhds 0 within {..< 0::real}). inverse x :> at_bot"
  1139   unfolding filterlim_at_bot_lt[where c=0] eventually_within
  1140 proof safe
  1141   fix Z :: real assume [arith]: "Z < 0"
  1142   have "eventually (\<lambda>x. inverse Z < x) (nhds 0)"
  1143     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1144   then show "eventually (\<lambda>x. x \<in> {..< 0} \<longrightarrow> inverse x < Z) (nhds 0)"
  1145     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1146 qed
  1147 
  1148 lemma filterlim_inverse_at_bot:
  1149   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1150   by (intro filterlim_compose[OF filterlim_inverse_at_bot_neg])
  1151      (simp add: filterlim_def eventually_filtermap le_within_iff)
  1152 
  1153 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1154   unfolding filterlim_at_top eventually_at_bot_dense
  1155   by (blast intro: less_minus_iff[THEN iffD1])
  1156 
  1157 lemma filterlim_uminus_at_top: "LIM x F. f x :> at_bot \<Longrightarrow> LIM x F. - (f x) :: real :> at_top"
  1158   by (rule filterlim_compose[OF filterlim_uminus_at_top_at_bot])
  1159 
  1160 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1161   unfolding filterlim_at_bot eventually_at_top_dense
  1162   by (blast intro: minus_less_iff[THEN iffD1])
  1163 
  1164 lemma filterlim_uminus_at_bot: "LIM x F. f x :> at_top \<Longrightarrow> LIM x F. - (f x) :: real :> at_bot"
  1165   by (rule filterlim_compose[OF filterlim_uminus_at_bot_at_top])
  1166 
  1167 end