src/HOL/BNF_Def.thy
author blanchet
Tue Sep 16 19:23:37 2014 +0200 (2014-09-16)
changeset 58352 37745650a3f4
parent 58106 c8cba801c483
child 58446 e89f57d1e46c
permissions -rw-r--r--
register 'prod' and 'sum' as datatypes, to allow N2M through them
     1 (*  Title:      HOL/BNF_Def.thy
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Author:     Jasmin Blanchette, TU Muenchen
     4     Copyright   2012, 2013, 2014
     5 
     6 Definition of bounded natural functors.
     7 *)
     8 
     9 header {* Definition of Bounded Natural Functors *}
    10 
    11 theory BNF_Def
    12 imports BNF_Cardinal_Arithmetic Fun_Def_Base
    13 keywords
    14   "print_bnfs" :: diag and
    15   "bnf" :: thy_goal
    16 begin
    17 
    18 lemma Collect_splitD: "x \<in> Collect (split A) \<Longrightarrow> A (fst x) (snd x)"
    19   by auto
    20 
    21 definition
    22   rel_fun :: "('a \<Rightarrow> 'c \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> 'd \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('c \<Rightarrow> 'd) \<Rightarrow> bool"
    23 where
    24   "rel_fun A B = (\<lambda>f g. \<forall>x y. A x y \<longrightarrow> B (f x) (g y))"
    25 
    26 lemma rel_funI [intro]:
    27   assumes "\<And>x y. A x y \<Longrightarrow> B (f x) (g y)"
    28   shows "rel_fun A B f g"
    29   using assms by (simp add: rel_fun_def)
    30 
    31 lemma rel_funD:
    32   assumes "rel_fun A B f g" and "A x y"
    33   shows "B (f x) (g y)"
    34   using assms by (simp add: rel_fun_def)
    35 
    36 definition rel_set :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool"
    37   where "rel_set R = (\<lambda>A B. (\<forall>x\<in>A. \<exists>y\<in>B. R x y) \<and> (\<forall>y\<in>B. \<exists>x\<in>A. R x y))"
    38 
    39 lemma rel_setI:
    40   assumes "\<And>x. x \<in> A \<Longrightarrow> \<exists>y\<in>B. R x y"
    41   assumes "\<And>y. y \<in> B \<Longrightarrow> \<exists>x\<in>A. R x y"
    42   shows "rel_set R A B"
    43   using assms unfolding rel_set_def by simp
    44 
    45 lemma predicate2_transferD:
    46    "\<lbrakk>rel_fun R1 (rel_fun R2 (op =)) P Q; a \<in> A; b \<in> B; A \<subseteq> {(x, y). R1 x y}; B \<subseteq> {(x, y). R2 x y}\<rbrakk> \<Longrightarrow>
    47    P (fst a) (fst b) \<longleftrightarrow> Q (snd a) (snd b)"
    48   unfolding rel_fun_def by (blast dest!: Collect_splitD)
    49 
    50 definition collect where
    51   "collect F x = (\<Union>f \<in> F. f x)"
    52 
    53 lemma fstI: "x = (y, z) \<Longrightarrow> fst x = y"
    54   by simp
    55 
    56 lemma sndI: "x = (y, z) \<Longrightarrow> snd x = z"
    57   by simp
    58 
    59 lemma bijI': "\<lbrakk>\<And>x y. (f x = f y) = (x = y); \<And>y. \<exists>x. y = f x\<rbrakk> \<Longrightarrow> bij f"
    60   unfolding bij_def inj_on_def by auto blast
    61 
    62 (* Operator: *)
    63 definition "Gr A f = {(a, f a) | a. a \<in> A}"
    64 
    65 definition "Grp A f = (\<lambda>a b. b = f a \<and> a \<in> A)"
    66 
    67 definition vimage2p where
    68   "vimage2p f g R = (\<lambda>x y. R (f x) (g y))"
    69 
    70 lemma collect_comp: "collect F \<circ> g = collect ((\<lambda>f. f \<circ> g) ` F)"
    71   by (rule ext) (auto simp only: comp_apply collect_def)
    72 
    73 definition convol ("\<langle>(_,/ _)\<rangle>") where
    74   "\<langle>f, g\<rangle> \<equiv> \<lambda>a. (f a, g a)"
    75 
    76 lemma fst_convol: "fst \<circ> \<langle>f, g\<rangle> = f"
    77   apply(rule ext)
    78   unfolding convol_def by simp
    79 
    80 lemma snd_convol: "snd \<circ> \<langle>f, g\<rangle> = g"
    81   apply(rule ext)
    82   unfolding convol_def by simp
    83 
    84 lemma convol_mem_GrpI:
    85   "x \<in> A \<Longrightarrow> \<langle>id, g\<rangle> x \<in> (Collect (split (Grp A g)))"
    86   unfolding convol_def Grp_def by auto
    87 
    88 definition csquare where
    89   "csquare A f1 f2 p1 p2 \<longleftrightarrow> (\<forall> a \<in> A. f1 (p1 a) = f2 (p2 a))"
    90 
    91 lemma eq_alt: "op = = Grp UNIV id"
    92   unfolding Grp_def by auto
    93 
    94 lemma leq_conversepI: "R = op = \<Longrightarrow> R \<le> R^--1"
    95   by auto
    96 
    97 lemma leq_OOI: "R = op = \<Longrightarrow> R \<le> R OO R"
    98   by auto
    99 
   100 lemma OO_Grp_alt: "(Grp A f)^--1 OO Grp A g = (\<lambda>x y. \<exists>z. z \<in> A \<and> f z = x \<and> g z = y)"
   101   unfolding Grp_def by auto
   102 
   103 lemma Grp_UNIV_id: "f = id \<Longrightarrow> (Grp UNIV f)^--1 OO Grp UNIV f = Grp UNIV f"
   104   unfolding Grp_def by auto
   105 
   106 lemma Grp_UNIV_idI: "x = y \<Longrightarrow> Grp UNIV id x y"
   107   unfolding Grp_def by auto
   108 
   109 lemma Grp_mono: "A \<le> B \<Longrightarrow> Grp A f \<le> Grp B f"
   110   unfolding Grp_def by auto
   111 
   112 lemma GrpI: "\<lbrakk>f x = y; x \<in> A\<rbrakk> \<Longrightarrow> Grp A f x y"
   113   unfolding Grp_def by auto
   114 
   115 lemma GrpE: "Grp A f x y \<Longrightarrow> (\<lbrakk>f x = y; x \<in> A\<rbrakk> \<Longrightarrow> R) \<Longrightarrow> R"
   116   unfolding Grp_def by auto
   117 
   118 lemma Collect_split_Grp_eqD: "z \<in> Collect (split (Grp A f)) \<Longrightarrow> (f \<circ> fst) z = snd z"
   119   unfolding Grp_def comp_def by auto
   120 
   121 lemma Collect_split_Grp_inD: "z \<in> Collect (split (Grp A f)) \<Longrightarrow> fst z \<in> A"
   122   unfolding Grp_def comp_def by auto
   123 
   124 definition "pick_middlep P Q a c = (SOME b. P a b \<and> Q b c)"
   125 
   126 lemma pick_middlep:
   127   "(P OO Q) a c \<Longrightarrow> P a (pick_middlep P Q a c) \<and> Q (pick_middlep P Q a c) c"
   128   unfolding pick_middlep_def apply(rule someI_ex) by auto
   129 
   130 definition fstOp where
   131   "fstOp P Q ac = (fst ac, pick_middlep P Q (fst ac) (snd ac))"
   132 
   133 definition sndOp where
   134   "sndOp P Q ac = (pick_middlep P Q (fst ac) (snd ac), (snd ac))"
   135 
   136 lemma fstOp_in: "ac \<in> Collect (split (P OO Q)) \<Longrightarrow> fstOp P Q ac \<in> Collect (split P)"
   137   unfolding fstOp_def mem_Collect_eq
   138   by (subst (asm) surjective_pairing, unfold prod.case) (erule pick_middlep[THEN conjunct1])
   139 
   140 lemma fst_fstOp: "fst bc = (fst \<circ> fstOp P Q) bc"
   141   unfolding comp_def fstOp_def by simp
   142 
   143 lemma snd_sndOp: "snd bc = (snd \<circ> sndOp P Q) bc"
   144   unfolding comp_def sndOp_def by simp
   145 
   146 lemma sndOp_in: "ac \<in> Collect (split (P OO Q)) \<Longrightarrow> sndOp P Q ac \<in> Collect (split Q)"
   147   unfolding sndOp_def mem_Collect_eq
   148   by (subst (asm) surjective_pairing, unfold prod.case) (erule pick_middlep[THEN conjunct2])
   149 
   150 lemma csquare_fstOp_sndOp:
   151   "csquare (Collect (split (P OO Q))) snd fst (fstOp P Q) (sndOp P Q)"
   152   unfolding csquare_def fstOp_def sndOp_def using pick_middlep by simp
   153 
   154 lemma snd_fst_flip: "snd xy = (fst \<circ> (%(x, y). (y, x))) xy"
   155   by (simp split: prod.split)
   156 
   157 lemma fst_snd_flip: "fst xy = (snd \<circ> (%(x, y). (y, x))) xy"
   158   by (simp split: prod.split)
   159 
   160 lemma flip_pred: "A \<subseteq> Collect (split (R ^--1)) \<Longrightarrow> (%(x, y). (y, x)) ` A \<subseteq> Collect (split R)"
   161   by auto
   162 
   163 lemma Collect_split_mono: "A \<le> B \<Longrightarrow> Collect (split A) \<subseteq> Collect (split B)"
   164   by auto
   165 
   166 lemma Collect_split_mono_strong: 
   167   "\<lbrakk>X = fst ` A; Y = snd ` A; \<forall>a\<in>X. \<forall>b \<in> Y. P a b \<longrightarrow> Q a b; A \<subseteq> Collect (split P)\<rbrakk> \<Longrightarrow>
   168    A \<subseteq> Collect (split Q)"
   169   by fastforce
   170 
   171 
   172 lemma predicate2_eqD: "A = B \<Longrightarrow> A a b \<longleftrightarrow> B a b"
   173   by simp
   174 
   175 lemma case_sum_o_inj: "case_sum f g \<circ> Inl = f" "case_sum f g \<circ> Inr = g"
   176   by auto
   177 
   178 lemma map_sum_o_inj: "map_sum f g o Inl = Inl o f" "map_sum f g o Inr = Inr o g"
   179   by auto
   180 
   181 lemma card_order_csum_cone_cexp_def:
   182   "card_order r \<Longrightarrow> ( |A1| +c cone) ^c r = |Func UNIV (Inl ` A1 \<union> {Inr ()})|"
   183   unfolding cexp_def cone_def Field_csum Field_card_of by (auto dest: Field_card_order)
   184 
   185 lemma If_the_inv_into_in_Func:
   186   "\<lbrakk>inj_on g C; C \<subseteq> B \<union> {x}\<rbrakk> \<Longrightarrow>
   187    (\<lambda>i. if i \<in> g ` C then the_inv_into C g i else x) \<in> Func UNIV (B \<union> {x})"
   188   unfolding Func_def by (auto dest: the_inv_into_into)
   189 
   190 lemma If_the_inv_into_f_f:
   191   "\<lbrakk>i \<in> C; inj_on g C\<rbrakk> \<Longrightarrow> ((\<lambda>i. if i \<in> g ` C then the_inv_into C g i else x) \<circ> g) i = id i"
   192   unfolding Func_def by (auto elim: the_inv_into_f_f)
   193 
   194 lemma the_inv_f_o_f_id: "inj f \<Longrightarrow> (the_inv f \<circ> f) z = id z"
   195   by (simp add: the_inv_f_f)
   196 
   197 lemma vimage2pI: "R (f x) (g y) \<Longrightarrow> vimage2p f g R x y"
   198   unfolding vimage2p_def by -
   199 
   200 lemma rel_fun_iff_leq_vimage2p: "(rel_fun R S) f g = (R \<le> vimage2p f g S)"
   201   unfolding rel_fun_def vimage2p_def by auto
   202 
   203 lemma convol_image_vimage2p: "\<langle>f \<circ> fst, g \<circ> snd\<rangle> ` Collect (split (vimage2p f g R)) \<subseteq> Collect (split R)"
   204   unfolding vimage2p_def convol_def by auto
   205 
   206 lemma vimage2p_Grp: "vimage2p f g P = Grp UNIV f OO P OO (Grp UNIV g)\<inverse>\<inverse>"
   207   unfolding vimage2p_def Grp_def by auto
   208 
   209 lemma subst_Pair: "P x y \<Longrightarrow> a = (x, y) \<Longrightarrow> P (fst a) (snd a)"
   210   by simp
   211 
   212 lemma comp_apply_eq: "f (g x) = h (k x) \<Longrightarrow> (f \<circ> g) x = (h \<circ> k) x"
   213   unfolding comp_apply by assumption
   214 
   215 ML_file "Tools/BNF/bnf_util.ML"
   216 ML_file "Tools/BNF/bnf_tactics.ML"
   217 ML_file "Tools/BNF/bnf_def_tactics.ML"
   218 ML_file "Tools/BNF/bnf_def.ML"
   219 
   220 end