src/HOL/Map.thy
author krauss
Fri Nov 24 13:44:51 2006 +0100 (2006-11-24)
changeset 21512 3786eb1b69d6
parent 21404 eb85850d3eb7
child 22230 bdec4a82f385
permissions -rw-r--r--
Lemma "fundef_default_value" uses predicate instead of set.
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) "~=>" = "'a => 'b option"  (infixr 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 syntax (xsymbols)
    19   "~=>" :: "[type, type] => type"  (infixr "\<rightharpoonup>" 0)
    20 
    21 abbreviation
    22   empty :: "'a ~=> 'b" where
    23   "empty == %x. None"
    24 
    25 definition
    26   map_comp :: "('b ~=> 'c)  => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    27   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    28 
    29 notation (xsymbols)
    30   map_comp  (infixl "\<circ>\<^sub>m" 55)
    31 
    32 definition
    33   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    34   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    35 
    36 definition
    37   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    38   "m|`A = (\<lambda>x. if x : A then m x else None)"
    39 
    40 notation (latex output)
    41   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    42 
    43 definition
    44   dom :: "('a ~=> 'b) => 'a set" where
    45   "dom m = {a. m a ~= None}"
    46 
    47 definition
    48   ran :: "('a ~=> 'b) => 'b set" where
    49   "ran m = {b. EX a. m a = Some b}"
    50 
    51 definition
    52   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    53   "(m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2) = (\<forall>a \<in> dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a)"
    54 
    55 consts
    56   map_of :: "('a * 'b) list => 'a ~=> 'b"
    57   map_upds :: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    58 
    59 nonterminals
    60   maplets maplet
    61 
    62 syntax
    63   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    64   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    65   ""         :: "maplet => maplets"             ("_")
    66   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    67   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    68   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    69 
    70 syntax (xsymbols)
    71   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    72   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    73 
    74 translations
    75   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    76   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    77   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    78   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    79   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    80   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    81 
    82 primrec
    83   "map_of [] = empty"
    84   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    85 
    86 defs
    87   map_upds_def: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    88 
    89 (* special purpose constants that should be defined somewhere else and
    90 whose syntax is a bit odd as well:
    91 
    92  "@chg_map" :: "('a ~=> 'b) => 'a => ('b => 'b) => ('a ~=> 'b)"
    93                                           ("_/'(_/\<mapsto>\<lambda>_. _')"  [900,0,0,0] 900)
    94   "m(x\<mapsto>\<lambda>y. f)" == "chg_map (\<lambda>y. f) x m"
    95 
    96 map_upd_s::"('a ~=> 'b) => 'a set => 'b =>
    97             ('a ~=> 'b)"                         ("_/'(_{|->}_/')" [900,0,0]900)
    98 map_subst::"('a ~=> 'b) => 'b => 'b =>
    99             ('a ~=> 'b)"                         ("_/'(_~>_/')"    [900,0,0]900)
   100 
   101 map_upd_s_def: "m(as{|->}b) == %x. if x : as then Some b else m x"
   102 map_subst_def: "m(a~>b)     == %x. if m x = Some a then Some b else m x"
   103 
   104   map_upd_s  :: "('a ~=> 'b) => 'a set => 'b => ('a ~=> 'b)"
   105                                                  ("_/'(_/{\<mapsto>}/_')" [900,0,0]900)
   106   map_subst :: "('a ~=> 'b) => 'b => 'b =>
   107                 ('a ~=> 'b)"                     ("_/'(_\<leadsto>_/')"    [900,0,0]900)
   108 
   109 
   110 subsection {* @{term [source] map_upd_s} *}
   111 
   112 lemma map_upd_s_apply [simp]:
   113   "(m(as{|->}b)) x = (if x : as then Some b else m x)"
   114 by (simp add: map_upd_s_def)
   115 
   116 lemma map_subst_apply [simp]:
   117   "(m(a~>b)) x = (if m x = Some a then Some b else m x)"
   118 by (simp add: map_subst_def)
   119 
   120 *)
   121 
   122 
   123 subsection {* @{term [source] empty} *}
   124 
   125 lemma empty_upd_none [simp]: "empty(x := None) = empty"
   126   by (rule ext) simp
   127 
   128 (* FIXME: what is this sum_case nonsense?? *)
   129 lemma sum_case_empty_empty[simp]: "sum_case empty empty = empty"
   130   by (rule ext) (simp split: sum.split)
   131 
   132 
   133 subsection {* @{term [source] map_upd} *}
   134 
   135 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   136   by (rule ext) simp
   137 
   138 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   139 proof
   140   assume "t(k \<mapsto> x) = empty"
   141   then have "(t(k \<mapsto> x)) k = None" by simp
   142   then show False by simp
   143 qed
   144 
   145 lemma map_upd_eqD1:
   146   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   147   shows "x = y"
   148 proof -
   149   from prems have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   150   then show ?thesis by simp
   151 qed
   152 
   153 lemma map_upd_Some_unfold:
   154     "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   155   by auto
   156 
   157 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   158   by auto
   159 
   160 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   161   unfolding image_def
   162   apply (simp (no_asm_use) add: full_SetCompr_eq)
   163   apply (rule finite_subset)
   164    prefer 2 apply assumption
   165   apply auto
   166   done
   167 
   168 
   169 (* FIXME: what is this sum_case nonsense?? *)
   170 subsection {* @{term [source] sum_case} and @{term [source] empty}/@{term [source] map_upd} *}
   171 
   172 lemma sum_case_map_upd_empty [simp]:
   173     "sum_case (m(k|->y)) empty = (sum_case m empty)(Inl k|->y)"
   174   by (rule ext) (simp split: sum.split)
   175 
   176 lemma sum_case_empty_map_upd [simp]:
   177     "sum_case empty (m(k|->y)) = (sum_case empty m)(Inr k|->y)"
   178   by (rule ext) (simp split: sum.split)
   179 
   180 lemma sum_case_map_upd_map_upd [simp]:
   181     "sum_case (m1(k1|->y1)) (m2(k2|->y2)) = (sum_case (m1(k1|->y1)) m2)(Inr k2|->y2)"
   182   by (rule ext) (simp split: sum.split)
   183 
   184 
   185 subsection {* @{term [source] map_of} *}
   186 
   187 lemma map_of_eq_None_iff:
   188     "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   189   by (induct xys) simp_all
   190 
   191 lemma map_of_is_SomeD:
   192     "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   193   apply (induct xys)
   194    apply simp
   195   apply (clarsimp split: if_splits)
   196   done
   197 
   198 lemma map_of_eq_Some_iff [simp]:
   199     "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   200   apply (induct xys)
   201    apply simp
   202   apply (auto simp: map_of_eq_None_iff [symmetric])
   203   done
   204 
   205 lemma Some_eq_map_of_iff [simp]:
   206     "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   207   by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   208 
   209 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   210     \<Longrightarrow> map_of xys x = Some y"
   211   apply (induct xys)
   212    apply simp
   213   apply force
   214   done
   215 
   216 lemma map_of_zip_is_None [simp]:
   217     "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   218   by (induct rule: list_induct2) simp_all
   219 
   220 lemma finite_range_map_of: "finite (range (map_of xys))"
   221   apply (induct xys)
   222    apply (simp_all add: image_constant)
   223   apply (rule finite_subset)
   224    prefer 2 apply assumption
   225   apply auto
   226   done
   227 
   228 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   229   by (induct xs) (simp, atomize (full), auto)
   230 
   231 lemma map_of_mapk_SomeI:
   232   assumes "inj f"
   233   shows "map_of t k = Some x ==>
   234     map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   235   by (induct t) (auto simp add: `inj f` inj_eq)
   236 
   237 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   238   by (induct l) auto
   239 
   240 lemma map_of_filter_in:
   241   assumes 1: "map_of xs k = Some z"
   242     and 2: "P k z"
   243   shows "map_of (filter (split P) xs) k = Some z"
   244   using 1 by (induct xs) (insert 2, auto)
   245 
   246 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   247   by (induct xs) auto
   248 
   249 
   250 subsection {* @{term [source] option_map} related *}
   251 
   252 lemma option_map_o_empty [simp]: "option_map f o empty = empty"
   253   by (rule ext) simp
   254 
   255 lemma option_map_o_map_upd [simp]:
   256     "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   257   by (rule ext) simp
   258 
   259 
   260 subsection {* @{term [source] map_comp} related *}
   261 
   262 lemma map_comp_empty [simp]:
   263     "m \<circ>\<^sub>m empty = empty"
   264     "empty \<circ>\<^sub>m m = empty"
   265   by (auto simp add: map_comp_def intro: ext split: option.splits)
   266 
   267 lemma map_comp_simps [simp]:
   268     "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   269     "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   270   by (auto simp add: map_comp_def)
   271 
   272 lemma map_comp_Some_iff:
   273     "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   274   by (auto simp add: map_comp_def split: option.splits)
   275 
   276 lemma map_comp_None_iff:
   277     "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   278   by (auto simp add: map_comp_def split: option.splits)
   279 
   280 
   281 subsection {* @{text "++"} *}
   282 
   283 lemma map_add_empty[simp]: "m ++ empty = m"
   284   unfolding map_add_def by simp
   285 
   286 lemma empty_map_add[simp]: "empty ++ m = m"
   287   unfolding map_add_def by (rule ext) (simp split: option.split)
   288 
   289 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   290   unfolding map_add_def by (rule ext) (simp add: map_add_def split: option.split)
   291 
   292 lemma map_add_Some_iff:
   293     "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   294   unfolding map_add_def by (simp split: option.split)
   295 
   296 lemma map_add_SomeD [dest!]:
   297     "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   298   by (rule map_add_Some_iff [THEN iffD1])
   299 
   300 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   301   by (subst map_add_Some_iff) fast
   302 
   303 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   304   unfolding map_add_def by (simp split: option.split)
   305 
   306 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   307   unfolding map_add_def by (rule ext) simp
   308 
   309 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   310   by (simp add: map_upds_def)
   311 
   312 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   313   unfolding map_add_def
   314   apply (induct xs)
   315    apply simp
   316   apply (rule ext)
   317   apply (simp split add: option.split)
   318   done
   319 
   320 lemma finite_range_map_of_map_add:
   321   "finite (range f) ==> finite (range (f ++ map_of l))"
   322   apply (induct l)
   323    apply (auto simp del: fun_upd_apply)
   324   apply (erule finite_range_updI)
   325   done
   326 
   327 lemma inj_on_map_add_dom [iff]:
   328     "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   329   unfolding map_add_def dom_def inj_on_def
   330   by (fastsimp split: option.splits)
   331 
   332 
   333 subsection {* @{term [source] restrict_map} *}
   334 
   335 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   336   by (simp add: restrict_map_def)
   337 
   338 lemma restrict_map_empty [simp]: "empty|`D = empty"
   339   by (simp add: restrict_map_def)
   340 
   341 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   342   by (simp add: restrict_map_def)
   343 
   344 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   345   by (simp add: restrict_map_def)
   346 
   347 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   348   by (auto simp: restrict_map_def ran_def split: split_if_asm)
   349 
   350 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   351   by (auto simp: restrict_map_def dom_def split: split_if_asm)
   352 
   353 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   354   by (rule ext) (auto simp: restrict_map_def)
   355 
   356 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   357   by (rule ext) (auto simp: restrict_map_def)
   358 
   359 lemma restrict_fun_upd [simp]:
   360     "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   361   by (simp add: restrict_map_def expand_fun_eq)
   362 
   363 lemma fun_upd_None_restrict [simp]:
   364     "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   365   by (simp add: restrict_map_def expand_fun_eq)
   366 
   367 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   368   by (simp add: restrict_map_def expand_fun_eq)
   369 
   370 lemma fun_upd_restrict_conv [simp]:
   371     "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   372   by (simp add: restrict_map_def expand_fun_eq)
   373 
   374 
   375 subsection {* @{term [source] map_upds} *}
   376 
   377 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   378   by (simp add: map_upds_def)
   379 
   380 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   381   by (simp add:map_upds_def)
   382 
   383 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   384   by (simp add:map_upds_def)
   385 
   386 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   387     m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   388   apply(induct xs)
   389    apply (clarsimp simp add: neq_Nil_conv)
   390   apply (case_tac ys)
   391    apply simp
   392   apply simp
   393   done
   394 
   395 lemma map_upds_list_update2_drop [simp]:
   396   "\<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   397     \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   398   apply (induct xs arbitrary: m ys i)
   399    apply simp
   400   apply (case_tac ys)
   401    apply simp
   402   apply (simp split: nat.split)
   403   done
   404 
   405 lemma map_upd_upds_conv_if:
   406   "(f(x|->y))(xs [|->] ys) =
   407    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   408                                     else (f(xs [|->] ys))(x|->y))"
   409   apply (induct xs arbitrary: x y ys f)
   410    apply simp
   411   apply (case_tac ys)
   412    apply (auto split: split_if simp: fun_upd_twist)
   413   done
   414 
   415 lemma map_upds_twist [simp]:
   416     "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   417   using set_take_subset by (fastsimp simp add: map_upd_upds_conv_if)
   418 
   419 lemma map_upds_apply_nontin [simp]:
   420     "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   421   apply (induct xs arbitrary: ys)
   422    apply simp
   423   apply (case_tac ys)
   424    apply (auto simp: map_upd_upds_conv_if)
   425   done
   426 
   427 lemma fun_upds_append_drop [simp]:
   428     "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   429   apply (induct xs arbitrary: m ys)
   430    apply simp
   431   apply (case_tac ys)
   432    apply simp_all
   433   done
   434 
   435 lemma fun_upds_append2_drop [simp]:
   436     "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   437   apply (induct xs arbitrary: m ys)
   438    apply simp
   439   apply (case_tac ys)
   440    apply simp_all
   441   done
   442 
   443 
   444 lemma restrict_map_upds[simp]:
   445   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   446     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   447   apply (induct xs arbitrary: m ys)
   448    apply simp
   449   apply (case_tac ys)
   450    apply simp
   451   apply (simp add: Diff_insert [symmetric] insert_absorb)
   452   apply (simp add: map_upd_upds_conv_if)
   453   done
   454 
   455 
   456 subsection {* @{term [source] dom} *}
   457 
   458 lemma domI: "m a = Some b ==> a : dom m"
   459   unfolding dom_def by simp
   460 (* declare domI [intro]? *)
   461 
   462 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   463   by (cases "m a") (auto simp add: dom_def)
   464 
   465 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   466   unfolding dom_def by simp
   467 
   468 lemma dom_empty [simp]: "dom empty = {}"
   469   unfolding dom_def by simp
   470 
   471 lemma dom_fun_upd [simp]:
   472     "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   473   unfolding dom_def by auto
   474 
   475 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   476   by (induct xys) (auto simp del: fun_upd_apply)
   477 
   478 lemma dom_map_of_conv_image_fst:
   479     "dom(map_of xys) = fst ` (set xys)"
   480   unfolding dom_map_of by force
   481 
   482 lemma dom_map_of_zip [simp]: "[| length xs = length ys; distinct xs |] ==>
   483     dom(map_of(zip xs ys)) = set xs"
   484   by (induct rule: list_induct2) simp_all
   485 
   486 lemma finite_dom_map_of: "finite (dom (map_of l))"
   487   unfolding dom_def
   488   by (induct l) (auto simp add: insert_Collect [symmetric])
   489 
   490 lemma dom_map_upds [simp]:
   491     "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   492   apply (induct xs arbitrary: m ys)
   493    apply simp
   494   apply (case_tac ys)
   495    apply auto
   496   done
   497 
   498 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   499   unfolding dom_def by auto
   500 
   501 lemma dom_override_on [simp]:
   502   "dom(override_on f g A) =
   503     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   504   unfolding dom_def override_on_def by auto
   505 
   506 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   507   by (rule ext) (force simp: map_add_def dom_def split: option.split)
   508 
   509 
   510 subsection {* @{term [source] ran} *}
   511 
   512 lemma ranI: "m a = Some b ==> b : ran m"
   513   unfolding ran_def by auto
   514 (* declare ranI [intro]? *)
   515 
   516 lemma ran_empty [simp]: "ran empty = {}"
   517   unfolding ran_def by simp
   518 
   519 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   520   unfolding ran_def
   521   apply auto
   522   apply (subgoal_tac "aa ~= a")
   523    apply auto
   524   done
   525 
   526 
   527 subsection {* @{text "map_le"} *}
   528 
   529 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   530   by (simp add: map_le_def)
   531 
   532 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   533   by (force simp add: map_le_def)
   534 
   535 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   536   by (fastsimp simp add: map_le_def)
   537 
   538 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   539   by (force simp add: map_le_def)
   540 
   541 lemma map_le_upds [simp]:
   542     "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   543   apply (induct as arbitrary: f g bs)
   544    apply simp
   545   apply (case_tac bs)
   546    apply auto
   547   done
   548 
   549 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   550   by (fastsimp simp add: map_le_def dom_def)
   551 
   552 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   553   by (simp add: map_le_def)
   554 
   555 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   556   by (auto simp add: map_le_def dom_def)
   557 
   558 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   559   unfolding map_le_def
   560   apply (rule ext)
   561   apply (case_tac "x \<in> dom f", simp)
   562   apply (case_tac "x \<in> dom g", simp, fastsimp)
   563   done
   564 
   565 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   566   by (fastsimp simp add: map_le_def)
   567 
   568 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   569   by (fastsimp simp add: map_add_def map_le_def expand_fun_eq split: option.splits)
   570 
   571 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   572   by (fastsimp simp add: map_le_def map_add_def dom_def)
   573 
   574 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   575   by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   576 
   577 end