src/HOL/Relation.thy
author krauss
Fri Nov 24 13:44:51 2006 +0100 (2006-11-24)
changeset 21512 3786eb1b69d6
parent 21404 eb85850d3eb7
child 22172 e7d6cb237b5e
permissions -rw-r--r--
Lemma "fundef_default_value" uses predicate instead of set.
     1 (*  Title:      HOL/Relation.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 *)
     6 
     7 header {* Relations *}
     8 
     9 theory Relation
    10 imports Product_Type
    11 begin
    12 
    13 subsection {* Definitions *}
    14 
    15 definition
    16   converse :: "('a * 'b) set => ('b * 'a) set"
    17     ("(_^-1)" [1000] 999) where
    18   "r^-1 == {(y, x). (x, y) : r}"
    19 
    20 notation (xsymbols)
    21   converse  ("(_\<inverse>)" [1000] 999)
    22 
    23 definition
    24   rel_comp  :: "[('b * 'c) set, ('a * 'b) set] => ('a * 'c) set"
    25     (infixr "O" 75) where
    26   "r O s == {(x,z). EX y. (x, y) : s & (y, z) : r}"
    27 
    28 definition
    29   Image :: "[('a * 'b) set, 'a set] => 'b set"
    30     (infixl "``" 90) where
    31   "r `` s == {y. EX x:s. (x,y):r}"
    32 
    33 definition
    34   Id :: "('a * 'a) set" where -- {* the identity relation *}
    35   "Id == {p. EX x. p = (x,x)}"
    36 
    37 definition
    38   diag  :: "'a set => ('a * 'a) set" where -- {* diagonal: identity over a set *}
    39   "diag A == \<Union>x\<in>A. {(x,x)}"
    40 
    41 definition
    42   Domain :: "('a * 'b) set => 'a set" where
    43   "Domain r == {x. EX y. (x,y):r}"
    44 
    45 definition
    46   Range  :: "('a * 'b) set => 'b set" where
    47   "Range r == Domain(r^-1)"
    48 
    49 definition
    50   Field :: "('a * 'a) set => 'a set" where
    51   "Field r == Domain r \<union> Range r"
    52 
    53 definition
    54   refl :: "['a set, ('a * 'a) set] => bool" where -- {* reflexivity over a set *}
    55   "refl A r == r \<subseteq> A \<times> A & (ALL x: A. (x,x) : r)"
    56 
    57 definition
    58   sym :: "('a * 'a) set => bool" where -- {* symmetry predicate *}
    59   "sym r == ALL x y. (x,y): r --> (y,x): r"
    60 
    61 definition
    62   antisym :: "('a * 'a) set => bool" where -- {* antisymmetry predicate *}
    63   "antisym r == ALL x y. (x,y):r --> (y,x):r --> x=y"
    64 
    65 definition
    66   trans :: "('a * 'a) set => bool" where -- {* transitivity predicate *}
    67   "trans r == (ALL x y z. (x,y):r --> (y,z):r --> (x,z):r)"
    68 
    69 definition
    70   single_valued :: "('a * 'b) set => bool" where
    71   "single_valued r == ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z)"
    72 
    73 definition
    74   inv_image :: "('b * 'b) set => ('a => 'b) => ('a * 'a) set" where
    75   "inv_image r f == {(x, y). (f x, f y) : r}"
    76 
    77 abbreviation
    78   reflexive :: "('a * 'a) set => bool" where -- {* reflexivity over a type *}
    79   "reflexive == refl UNIV"
    80 
    81 
    82 subsection {* The identity relation *}
    83 
    84 lemma IdI [intro]: "(a, a) : Id"
    85   by (simp add: Id_def)
    86 
    87 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
    88   by (unfold Id_def) (iprover elim: CollectE)
    89 
    90 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
    91   by (unfold Id_def) blast
    92 
    93 lemma reflexive_Id: "reflexive Id"
    94   by (simp add: refl_def)
    95 
    96 lemma antisym_Id: "antisym Id"
    97   -- {* A strange result, since @{text Id} is also symmetric. *}
    98   by (simp add: antisym_def)
    99 
   100 lemma sym_Id: "sym Id"
   101   by (simp add: sym_def)
   102 
   103 lemma trans_Id: "trans Id"
   104   by (simp add: trans_def)
   105 
   106 
   107 subsection {* Diagonal: identity over a set *}
   108 
   109 lemma diag_empty [simp]: "diag {} = {}"
   110   by (simp add: diag_def) 
   111 
   112 lemma diag_eqI: "a = b ==> a : A ==> (a, b) : diag A"
   113   by (simp add: diag_def)
   114 
   115 lemma diagI [intro!]: "a : A ==> (a, a) : diag A"
   116   by (rule diag_eqI) (rule refl)
   117 
   118 lemma diagE [elim!]:
   119   "c : diag A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   120   -- {* The general elimination rule. *}
   121   by (unfold diag_def) (iprover elim!: UN_E singletonE)
   122 
   123 lemma diag_iff: "((x, y) : diag A) = (x = y & x : A)"
   124   by blast
   125 
   126 lemma diag_subset_Times: "diag A \<subseteq> A \<times> A"
   127   by blast
   128 
   129 
   130 subsection {* Composition of two relations *}
   131 
   132 lemma rel_compI [intro]:
   133   "(a, b) : s ==> (b, c) : r ==> (a, c) : r O s"
   134   by (unfold rel_comp_def) blast
   135 
   136 lemma rel_compE [elim!]: "xz : r O s ==>
   137   (!!x y z. xz = (x, z) ==> (x, y) : s ==> (y, z) : r  ==> P) ==> P"
   138   by (unfold rel_comp_def) (iprover elim!: CollectE splitE exE conjE)
   139 
   140 lemma rel_compEpair:
   141   "(a, c) : r O s ==> (!!y. (a, y) : s ==> (y, c) : r ==> P) ==> P"
   142   by (iprover elim: rel_compE Pair_inject ssubst)
   143 
   144 lemma R_O_Id [simp]: "R O Id = R"
   145   by fast
   146 
   147 lemma Id_O_R [simp]: "Id O R = R"
   148   by fast
   149 
   150 lemma O_assoc: "(R O S) O T = R O (S O T)"
   151   by blast
   152 
   153 lemma trans_O_subset: "trans r ==> r O r \<subseteq> r"
   154   by (unfold trans_def) blast
   155 
   156 lemma rel_comp_mono: "r' \<subseteq> r ==> s' \<subseteq> s ==> (r' O s') \<subseteq> (r O s)"
   157   by blast
   158 
   159 lemma rel_comp_subset_Sigma:
   160     "s \<subseteq> A \<times> B ==> r \<subseteq> B \<times> C ==> (r O s) \<subseteq> A \<times> C"
   161   by blast
   162 
   163 
   164 subsection {* Reflexivity *}
   165 
   166 lemma reflI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl A r"
   167   by (unfold refl_def) (iprover intro!: ballI)
   168 
   169 lemma reflD: "refl A r ==> a : A ==> (a, a) : r"
   170   by (unfold refl_def) blast
   171 
   172 lemma reflD1: "refl A r ==> (x, y) : r ==> x : A"
   173   by (unfold refl_def) blast
   174 
   175 lemma reflD2: "refl A r ==> (x, y) : r ==> y : A"
   176   by (unfold refl_def) blast
   177 
   178 lemma refl_Int: "refl A r ==> refl B s ==> refl (A \<inter> B) (r \<inter> s)"
   179   by (unfold refl_def) blast
   180 
   181 lemma refl_Un: "refl A r ==> refl B s ==> refl (A \<union> B) (r \<union> s)"
   182   by (unfold refl_def) blast
   183 
   184 lemma refl_INTER:
   185   "ALL x:S. refl (A x) (r x) ==> refl (INTER S A) (INTER S r)"
   186   by (unfold refl_def) fast
   187 
   188 lemma refl_UNION:
   189   "ALL x:S. refl (A x) (r x) \<Longrightarrow> refl (UNION S A) (UNION S r)"
   190   by (unfold refl_def) blast
   191 
   192 lemma refl_diag: "refl A (diag A)"
   193   by (rule reflI [OF diag_subset_Times diagI])
   194 
   195 
   196 subsection {* Antisymmetry *}
   197 
   198 lemma antisymI:
   199   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   200   by (unfold antisym_def) iprover
   201 
   202 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   203   by (unfold antisym_def) iprover
   204 
   205 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   206   by (unfold antisym_def) blast
   207 
   208 lemma antisym_empty [simp]: "antisym {}"
   209   by (unfold antisym_def) blast
   210 
   211 lemma antisym_diag [simp]: "antisym (diag A)"
   212   by (unfold antisym_def) blast
   213 
   214 
   215 subsection {* Symmetry *}
   216 
   217 lemma symI: "(!!a b. (a, b) : r ==> (b, a) : r) ==> sym r"
   218   by (unfold sym_def) iprover
   219 
   220 lemma symD: "sym r ==> (a, b) : r ==> (b, a) : r"
   221   by (unfold sym_def, blast)
   222 
   223 lemma sym_Int: "sym r ==> sym s ==> sym (r \<inter> s)"
   224   by (fast intro: symI dest: symD)
   225 
   226 lemma sym_Un: "sym r ==> sym s ==> sym (r \<union> s)"
   227   by (fast intro: symI dest: symD)
   228 
   229 lemma sym_INTER: "ALL x:S. sym (r x) ==> sym (INTER S r)"
   230   by (fast intro: symI dest: symD)
   231 
   232 lemma sym_UNION: "ALL x:S. sym (r x) ==> sym (UNION S r)"
   233   by (fast intro: symI dest: symD)
   234 
   235 lemma sym_diag [simp]: "sym (diag A)"
   236   by (rule symI) clarify
   237 
   238 
   239 subsection {* Transitivity *}
   240 
   241 lemma transI:
   242   "(!!x y z. (x, y) : r ==> (y, z) : r ==> (x, z) : r) ==> trans r"
   243   by (unfold trans_def) iprover
   244 
   245 lemma transD: "trans r ==> (a, b) : r ==> (b, c) : r ==> (a, c) : r"
   246   by (unfold trans_def) iprover
   247 
   248 lemma trans_Int: "trans r ==> trans s ==> trans (r \<inter> s)"
   249   by (fast intro: transI elim: transD)
   250 
   251 lemma trans_INTER: "ALL x:S. trans (r x) ==> trans (INTER S r)"
   252   by (fast intro: transI elim: transD)
   253 
   254 lemma trans_diag [simp]: "trans (diag A)"
   255   by (fast intro: transI elim: transD)
   256 
   257 
   258 subsection {* Converse *}
   259 
   260 lemma converse_iff [iff]: "((a,b): r^-1) = ((b,a) : r)"
   261   by (simp add: converse_def)
   262 
   263 lemma converseI[sym]: "(a, b) : r ==> (b, a) : r^-1"
   264   by (simp add: converse_def)
   265 
   266 lemma converseD[sym]: "(a,b) : r^-1 ==> (b, a) : r"
   267   by (simp add: converse_def)
   268 
   269 lemma converseE [elim!]:
   270   "yx : r^-1 ==> (!!x y. yx = (y, x) ==> (x, y) : r ==> P) ==> P"
   271     -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   272   by (unfold converse_def) (iprover elim!: CollectE splitE bexE)
   273 
   274 lemma converse_converse [simp]: "(r^-1)^-1 = r"
   275   by (unfold converse_def) blast
   276 
   277 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   278   by blast
   279 
   280 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   281   by blast
   282 
   283 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   284   by blast
   285 
   286 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   287   by fast
   288 
   289 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   290   by blast
   291 
   292 lemma converse_Id [simp]: "Id^-1 = Id"
   293   by blast
   294 
   295 lemma converse_diag [simp]: "(diag A)^-1 = diag A"
   296   by blast
   297 
   298 lemma refl_converse [simp]: "refl A (converse r) = refl A r"
   299   by (unfold refl_def) auto
   300 
   301 lemma sym_converse [simp]: "sym (converse r) = sym r"
   302   by (unfold sym_def) blast
   303 
   304 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   305   by (unfold antisym_def) blast
   306 
   307 lemma trans_converse [simp]: "trans (converse r) = trans r"
   308   by (unfold trans_def) blast
   309 
   310 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   311   by (unfold sym_def) fast
   312 
   313 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   314   by (unfold sym_def) blast
   315 
   316 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   317   by (unfold sym_def) blast
   318 
   319 
   320 subsection {* Domain *}
   321 
   322 lemma Domain_iff: "(a : Domain r) = (EX y. (a, y) : r)"
   323   by (unfold Domain_def) blast
   324 
   325 lemma DomainI [intro]: "(a, b) : r ==> a : Domain r"
   326   by (iprover intro!: iffD2 [OF Domain_iff])
   327 
   328 lemma DomainE [elim!]:
   329   "a : Domain r ==> (!!y. (a, y) : r ==> P) ==> P"
   330   by (iprover dest!: iffD1 [OF Domain_iff])
   331 
   332 lemma Domain_empty [simp]: "Domain {} = {}"
   333   by blast
   334 
   335 lemma Domain_insert: "Domain (insert (a, b) r) = insert a (Domain r)"
   336   by blast
   337 
   338 lemma Domain_Id [simp]: "Domain Id = UNIV"
   339   by blast
   340 
   341 lemma Domain_diag [simp]: "Domain (diag A) = A"
   342   by blast
   343 
   344 lemma Domain_Un_eq: "Domain(A \<union> B) = Domain(A) \<union> Domain(B)"
   345   by blast
   346 
   347 lemma Domain_Int_subset: "Domain(A \<inter> B) \<subseteq> Domain(A) \<inter> Domain(B)"
   348   by blast
   349 
   350 lemma Domain_Diff_subset: "Domain(A) - Domain(B) \<subseteq> Domain(A - B)"
   351   by blast
   352 
   353 lemma Domain_Union: "Domain (Union S) = (\<Union>A\<in>S. Domain A)"
   354   by blast
   355 
   356 lemma Domain_mono: "r \<subseteq> s ==> Domain r \<subseteq> Domain s"
   357   by blast
   358 
   359 
   360 subsection {* Range *}
   361 
   362 lemma Range_iff: "(a : Range r) = (EX y. (y, a) : r)"
   363   by (simp add: Domain_def Range_def)
   364 
   365 lemma RangeI [intro]: "(a, b) : r ==> b : Range r"
   366   by (unfold Range_def) (iprover intro!: converseI DomainI)
   367 
   368 lemma RangeE [elim!]: "b : Range r ==> (!!x. (x, b) : r ==> P) ==> P"
   369   by (unfold Range_def) (iprover elim!: DomainE dest!: converseD)
   370 
   371 lemma Range_empty [simp]: "Range {} = {}"
   372   by blast
   373 
   374 lemma Range_insert: "Range (insert (a, b) r) = insert b (Range r)"
   375   by blast
   376 
   377 lemma Range_Id [simp]: "Range Id = UNIV"
   378   by blast
   379 
   380 lemma Range_diag [simp]: "Range (diag A) = A"
   381   by auto
   382 
   383 lemma Range_Un_eq: "Range(A \<union> B) = Range(A) \<union> Range(B)"
   384   by blast
   385 
   386 lemma Range_Int_subset: "Range(A \<inter> B) \<subseteq> Range(A) \<inter> Range(B)"
   387   by blast
   388 
   389 lemma Range_Diff_subset: "Range(A) - Range(B) \<subseteq> Range(A - B)"
   390   by blast
   391 
   392 lemma Range_Union: "Range (Union S) = (\<Union>A\<in>S. Range A)"
   393   by blast
   394 
   395 
   396 subsection {* Image of a set under a relation *}
   397 
   398 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   399   by (simp add: Image_def)
   400 
   401 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   402   by (simp add: Image_def)
   403 
   404 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   405   by (rule Image_iff [THEN trans]) simp
   406 
   407 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
   408   by (unfold Image_def) blast
   409 
   410 lemma ImageE [elim!]:
   411     "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   412   by (unfold Image_def) (iprover elim!: CollectE bexE)
   413 
   414 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   415   -- {* This version's more effective when we already have the required @{text a} *}
   416   by blast
   417 
   418 lemma Image_empty [simp]: "R``{} = {}"
   419   by blast
   420 
   421 lemma Image_Id [simp]: "Id `` A = A"
   422   by blast
   423 
   424 lemma Image_diag [simp]: "diag A `` B = A \<inter> B"
   425   by blast
   426 
   427 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   428   by blast
   429 
   430 lemma Image_Int_eq:
   431      "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   432   by (simp add: single_valued_def, blast) 
   433 
   434 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   435   by blast
   436 
   437 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   438   by blast
   439 
   440 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   441   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   442 
   443 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   444   -- {* NOT suitable for rewriting *}
   445   by blast
   446 
   447 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   448   by blast
   449 
   450 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   451   by blast
   452 
   453 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   454   by blast
   455 
   456 text{*Converse inclusion requires some assumptions*}
   457 lemma Image_INT_eq:
   458      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   459 apply (rule equalityI)
   460  apply (rule Image_INT_subset) 
   461 apply  (simp add: single_valued_def, blast)
   462 done
   463 
   464 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   465   by blast
   466 
   467 
   468 subsection {* Single valued relations *}
   469 
   470 lemma single_valuedI:
   471   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   472   by (unfold single_valued_def)
   473 
   474 lemma single_valuedD:
   475   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   476   by (simp add: single_valued_def)
   477 
   478 lemma single_valued_rel_comp:
   479   "single_valued r ==> single_valued s ==> single_valued (r O s)"
   480   by (unfold single_valued_def) blast
   481 
   482 lemma single_valued_subset:
   483   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   484   by (unfold single_valued_def) blast
   485 
   486 lemma single_valued_Id [simp]: "single_valued Id"
   487   by (unfold single_valued_def) blast
   488 
   489 lemma single_valued_diag [simp]: "single_valued (diag A)"
   490   by (unfold single_valued_def) blast
   491 
   492 
   493 subsection {* Graphs given by @{text Collect} *}
   494 
   495 lemma Domain_Collect_split [simp]: "Domain{(x,y). P x y} = {x. EX y. P x y}"
   496   by auto
   497 
   498 lemma Range_Collect_split [simp]: "Range{(x,y). P x y} = {y. EX x. P x y}"
   499   by auto
   500 
   501 lemma Image_Collect_split [simp]: "{(x,y). P x y} `` A = {y. EX x:A. P x y}"
   502   by auto
   503 
   504 
   505 subsection {* Inverse image *}
   506 
   507 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
   508   by (unfold sym_def inv_image_def) blast
   509 
   510 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
   511   apply (unfold trans_def inv_image_def)
   512   apply (simp (no_asm))
   513   apply blast
   514   done
   515 
   516 end