src/Pure/goal.ML
author wenzelm
Tue Sep 23 23:07:48 2008 +0200 (2008-09-23)
changeset 28341 383f512314b9
parent 28340 e8597242f649
child 28355 b9d9360e2440
permissions -rw-r--r--
prove_multi: immediate;
     1 (*  Title:      Pure/goal.ML
     2     ID:         $Id$
     3     Author:     Makarius and Lawrence C Paulson
     4 
     5 Goals in tactical theorem proving.
     6 *)
     7 
     8 signature BASIC_GOAL =
     9 sig
    10   val SELECT_GOAL: tactic -> int -> tactic
    11   val CONJUNCTS: tactic -> int -> tactic
    12   val PRECISE_CONJUNCTS: int -> tactic -> int -> tactic
    13 end;
    14 
    15 signature GOAL =
    16 sig
    17   include BASIC_GOAL
    18   val init: cterm -> thm
    19   val protect: thm -> thm
    20   val conclude: thm -> thm
    21   val finish: thm -> thm
    22   val norm_result: thm -> thm
    23   val promise_result: Proof.context -> (unit -> thm) -> term -> thm
    24   val prove_internal: cterm list -> cterm -> (thm list -> tactic) -> thm
    25   val prove_multi: Proof.context -> string list -> term list -> term list ->
    26     ({prems: thm list, context: Proof.context} -> tactic) -> thm list
    27   val prove_promise: Proof.context -> string list -> term list -> term ->
    28     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    29   val prove: Proof.context -> string list -> term list -> term ->
    30     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    31   val prove_global: theory -> string list -> term list -> term ->
    32     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    33   val extract: int -> int -> thm -> thm Seq.seq
    34   val retrofit: int -> int -> thm -> thm -> thm Seq.seq
    35   val conjunction_tac: int -> tactic
    36   val precise_conjunction_tac: int -> int -> tactic
    37   val recover_conjunction_tac: tactic
    38   val norm_hhf_tac: int -> tactic
    39   val compose_hhf_tac: thm -> int -> tactic
    40   val assume_rule_tac: Proof.context -> int -> tactic
    41 end;
    42 
    43 structure Goal: GOAL =
    44 struct
    45 
    46 (** goals **)
    47 
    48 (*
    49   -------- (init)
    50   C ==> #C
    51 *)
    52 val init =
    53   let val A = #1 (Thm.dest_implies (Thm.cprop_of Drule.protectI))
    54   in fn C => Thm.instantiate ([], [(A, C)]) Drule.protectI end;
    55 
    56 (*
    57    C
    58   --- (protect)
    59   #C
    60 *)
    61 fun protect th = th COMP_INCR Drule.protectI;
    62 
    63 (*
    64   A ==> ... ==> #C
    65   ---------------- (conclude)
    66   A ==> ... ==> C
    67 *)
    68 fun conclude th =
    69   (case SINGLE (Thm.compose_no_flatten false (th, Thm.nprems_of th) 1)
    70       (Drule.incr_indexes th Drule.protectD) of
    71     SOME th' => th'
    72   | NONE => raise THM ("Failed to conclude goal", 0, [th]));
    73 
    74 (*
    75   #C
    76   --- (finish)
    77    C
    78 *)
    79 fun finish th =
    80   (case Thm.nprems_of th of
    81     0 => conclude th
    82   | n => raise THM ("Proof failed.\n" ^
    83       Pretty.string_of (Pretty.chunks (Display.pretty_goals n th)) ^
    84       ("\n" ^ string_of_int n ^ " unsolved goal(s)!"), 0, [th]));
    85 
    86 
    87 
    88 (** results **)
    89 
    90 (* normal form *)
    91 
    92 val norm_result =
    93   Drule.flexflex_unique
    94   #> MetaSimplifier.norm_hhf_protect
    95   #> Thm.strip_shyps
    96   #> Drule.zero_var_indexes;
    97 
    98 
    99 (* promise *)
   100 
   101 fun promise_result ctxt result prop =
   102   let
   103     val thy = ProofContext.theory_of ctxt;
   104     val _ = Context.reject_draft thy;
   105     val cert = Thm.cterm_of thy;
   106     val certT = Thm.ctyp_of thy;
   107 
   108     val assms = Assumption.assms_of ctxt;
   109     val As = map Thm.term_of assms;
   110 
   111     val xs = map Free (fold Term.add_frees (prop :: As) []);
   112     val fixes = map cert xs;
   113 
   114     val tfrees = fold Term.add_tfrees (prop :: As) [];
   115     val instT = map (fn (a, S) => (certT (TVar ((a, 0), S)), certT (TFree (a, S)))) tfrees;
   116 
   117     val global_prop =
   118       Term.map_types Logic.varifyT (fold_rev Logic.all xs (Logic.list_implies (As, prop)));
   119     val global_result =
   120       Thm.generalize (map #1 tfrees, []) 0 o
   121       Drule.forall_intr_list fixes o
   122       Drule.implies_intr_list assms o
   123       Thm.adjust_maxidx_thm ~1 o result;
   124     val local_result =
   125       Thm.promise (Future.fork_irrelevant global_result) (cert global_prop)
   126       |> Thm.instantiate (instT, [])
   127       |> Drule.forall_elim_list fixes
   128       |> fold (Thm.elim_implies o Thm.assume) assms;
   129   in local_result end;
   130 
   131 
   132 
   133 (** tactical theorem proving **)
   134 
   135 (* prove_internal -- minimal checks, no normalization of result! *)
   136 
   137 fun prove_internal casms cprop tac =
   138   (case SINGLE (tac (map Assumption.assume casms)) (init cprop) of
   139     SOME th => Drule.implies_intr_list casms (finish th)
   140   | NONE => error "Tactic failed.");
   141 
   142 
   143 (* prove_common etc. *)
   144 
   145 fun prove_common immediate ctxt xs asms props tac =
   146   let
   147     val thy = ProofContext.theory_of ctxt;
   148     val string_of_term = Syntax.string_of_term ctxt;
   149 
   150     fun err msg = cat_error msg
   151       ("The error(s) above occurred for the goal statement:\n" ^
   152         string_of_term (Logic.list_implies (asms, Logic.mk_conjunction_list props)));
   153 
   154     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm (Term.no_dummy_patterns t))
   155       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   156     val casms = map cert_safe asms;
   157     val cprops = map cert_safe props;
   158 
   159     val (prems, ctxt') = ctxt
   160       |> Variable.add_fixes_direct xs
   161       |> fold Variable.declare_term (asms @ props)
   162       |> Assumption.add_assumes casms
   163       ||> Variable.set_body true;
   164 
   165     val stmt = Conjunction.mk_conjunction_balanced cprops;
   166 
   167     fun result () =
   168       (case SINGLE (tac {prems = prems, context = ctxt'}) (init stmt) of
   169         NONE => err "Tactic failed."
   170       | SOME st =>
   171           let val res = finish st handle THM (msg, _, _) => err msg in
   172             if Unify.matches_list thy [Thm.term_of stmt] [Thm.prop_of res] then res
   173             else err ("Proved a different theorem: " ^ string_of_term (Thm.prop_of res))
   174           end);
   175     val res =
   176       if immediate orelse #maxidx (Thm.rep_cterm stmt) >= 0 then result ()
   177       else promise_result ctxt result (Thm.term_of stmt);
   178   in
   179     Conjunction.elim_balanced (length props) res
   180     |> map (Assumption.export false ctxt' ctxt)
   181     |> Variable.export ctxt' ctxt
   182     |> map Drule.zero_var_indexes
   183   end;
   184 
   185 val prove_multi = prove_common true;
   186 
   187 fun prove_promise ctxt xs asms prop tac = hd (prove_common false ctxt xs asms [prop] tac);
   188 fun prove ctxt xs asms prop tac = hd (prove_common true ctxt xs asms [prop] tac);
   189 
   190 fun prove_global thy xs asms prop tac =
   191   Drule.standard (prove (ProofContext.init thy) xs asms prop tac);
   192 
   193 
   194 
   195 (** goal structure **)
   196 
   197 (* nested goals *)
   198 
   199 fun extract i n st =
   200   (if i < 1 orelse n < 1 orelse i + n - 1 > Thm.nprems_of st then Seq.empty
   201    else if n = 1 then Seq.single (Thm.cprem_of st i)
   202    else
   203      Seq.single (Conjunction.mk_conjunction_balanced (map (Thm.cprem_of st) (i upto i + n - 1))))
   204   |> Seq.map (Thm.adjust_maxidx_cterm ~1 #> init);
   205 
   206 fun retrofit i n st' st =
   207   (if n = 1 then st
   208    else st |> Drule.with_subgoal i (Conjunction.uncurry_balanced n))
   209   |> Thm.compose_no_flatten false (conclude st', Thm.nprems_of st') i;
   210 
   211 fun SELECT_GOAL tac i st =
   212   if Thm.nprems_of st = 1 andalso i = 1 then tac st
   213   else Seq.lifts (retrofit i 1) (Seq.maps tac (extract i 1 st)) st;
   214 
   215 
   216 (* multiple goals *)
   217 
   218 fun precise_conjunction_tac 0 i = eq_assume_tac i
   219   | precise_conjunction_tac 1 i = SUBGOAL (K all_tac) i
   220   | precise_conjunction_tac n i = PRIMITIVE (Drule.with_subgoal i (Conjunction.curry_balanced n));
   221 
   222 val adhoc_conjunction_tac = REPEAT_ALL_NEW
   223   (SUBGOAL (fn (goal, i) =>
   224     if can Logic.dest_conjunction goal then rtac Conjunction.conjunctionI i
   225     else no_tac));
   226 
   227 val conjunction_tac = SUBGOAL (fn (goal, i) =>
   228   precise_conjunction_tac (length (Logic.dest_conjunctions goal)) i ORELSE
   229   TRY (adhoc_conjunction_tac i));
   230 
   231 val recover_conjunction_tac = PRIMITIVE (fn th =>
   232   Conjunction.uncurry_balanced (Thm.nprems_of th) th);
   233 
   234 fun PRECISE_CONJUNCTS n tac =
   235   SELECT_GOAL (precise_conjunction_tac n 1
   236     THEN tac
   237     THEN recover_conjunction_tac);
   238 
   239 fun CONJUNCTS tac =
   240   SELECT_GOAL (conjunction_tac 1
   241     THEN tac
   242     THEN recover_conjunction_tac);
   243 
   244 
   245 (* hhf normal form *)
   246 
   247 val norm_hhf_tac =
   248   rtac Drule.asm_rl  (*cheap approximation -- thanks to builtin Logic.flatten_params*)
   249   THEN' SUBGOAL (fn (t, i) =>
   250     if Drule.is_norm_hhf t then all_tac
   251     else MetaSimplifier.rewrite_goal_tac [Drule.norm_hhf_eq] i);
   252 
   253 fun compose_hhf_tac th i st =
   254   PRIMSEQ (Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of st i) th, 0) i) st;
   255 
   256 
   257 (* non-atomic goal assumptions *)
   258 
   259 fun non_atomic (Const ("==>", _) $ _ $ _) = true
   260   | non_atomic (Const ("all", _) $ _) = true
   261   | non_atomic _ = false;
   262 
   263 fun assume_rule_tac ctxt = norm_hhf_tac THEN' CSUBGOAL (fn (goal, i) =>
   264   let
   265     val ((_, goal'), ctxt') = Variable.focus goal ctxt;
   266     val goal'' = Drule.cterm_rule (singleton (Variable.export ctxt' ctxt)) goal';
   267     val Rs = filter (non_atomic o Thm.term_of) (Drule.strip_imp_prems goal'');
   268     val tacs = Rs |> map (fn R =>
   269       Tactic.etac (MetaSimplifier.norm_hhf (Thm.trivial R)) THEN_ALL_NEW assume_tac);
   270   in fold_rev (curry op APPEND') tacs (K no_tac) i end);
   271 
   272 end;
   273 
   274 structure BasicGoal: BASIC_GOAL = Goal;
   275 open BasicGoal;