src/HOL/Limits.thy
 author huffman Mon May 10 21:33:48 2010 -0700 (2010-05-10) changeset 36822 38a480e0346f parent 36662 621122eeb138 child 37767 a2b7a20d6ea3 permissions -rw-r--r--
minimize imports
1 (*  Title       : Limits.thy
2     Author      : Brian Huffman
3 *)
5 header {* Filters and Limits *}
7 theory Limits
8 imports RealVector
9 begin
11 subsection {* Nets *}
13 text {*
14   A net is now defined simply as a filter on a set.
15   The definition also allows non-proper filters.
16 *}
18 locale is_filter =
19   fixes net :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
20   assumes True: "net (\<lambda>x. True)"
21   assumes conj: "net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x) \<Longrightarrow> net (\<lambda>x. P x \<and> Q x)"
22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x)"
24 typedef (open) 'a net =
25   "{net :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter net}"
26 proof
27   show "(\<lambda>x. True) \<in> ?net" by (auto intro: is_filter.intro)
28 qed
30 lemma is_filter_Rep_net: "is_filter (Rep_net net)"
31 using Rep_net [of net] by simp
33 lemma Abs_net_inverse':
34   assumes "is_filter net" shows "Rep_net (Abs_net net) = net"
35 using assms by (simp add: Abs_net_inverse)
38 subsection {* Eventually *}
40 definition
41   eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a net \<Rightarrow> bool" where
42   [code del]: "eventually P net \<longleftrightarrow> Rep_net net P"
44 lemma eventually_Abs_net:
45   assumes "is_filter net" shows "eventually P (Abs_net net) = net P"
46 unfolding eventually_def using assms by (simp add: Abs_net_inverse)
48 lemma expand_net_eq:
49   shows "net = net' \<longleftrightarrow> (\<forall>P. eventually P net = eventually P net')"
50 unfolding Rep_net_inject [symmetric] expand_fun_eq eventually_def ..
52 lemma eventually_True [simp]: "eventually (\<lambda>x. True) net"
53 unfolding eventually_def
54 by (rule is_filter.True [OF is_filter_Rep_net])
56 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P net"
57 proof -
58   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
59   thus "eventually P net" by simp
60 qed
62 lemma eventually_mono:
63   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P net \<Longrightarrow> eventually Q net"
64 unfolding eventually_def
65 by (rule is_filter.mono [OF is_filter_Rep_net])
67 lemma eventually_conj:
68   assumes P: "eventually (\<lambda>x. P x) net"
69   assumes Q: "eventually (\<lambda>x. Q x) net"
70   shows "eventually (\<lambda>x. P x \<and> Q x) net"
71 using assms unfolding eventually_def
72 by (rule is_filter.conj [OF is_filter_Rep_net])
74 lemma eventually_mp:
75   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
76   assumes "eventually (\<lambda>x. P x) net"
77   shows "eventually (\<lambda>x. Q x) net"
78 proof (rule eventually_mono)
79   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
80   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) net"
81     using assms by (rule eventually_conj)
82 qed
84 lemma eventually_rev_mp:
85   assumes "eventually (\<lambda>x. P x) net"
86   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
87   shows "eventually (\<lambda>x. Q x) net"
88 using assms(2) assms(1) by (rule eventually_mp)
90 lemma eventually_conj_iff:
91   "eventually (\<lambda>x. P x \<and> Q x) net \<longleftrightarrow> eventually P net \<and> eventually Q net"
92 by (auto intro: eventually_conj elim: eventually_rev_mp)
94 lemma eventually_elim1:
95   assumes "eventually (\<lambda>i. P i) net"
96   assumes "\<And>i. P i \<Longrightarrow> Q i"
97   shows "eventually (\<lambda>i. Q i) net"
98 using assms by (auto elim!: eventually_rev_mp)
100 lemma eventually_elim2:
101   assumes "eventually (\<lambda>i. P i) net"
102   assumes "eventually (\<lambda>i. Q i) net"
103   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
104   shows "eventually (\<lambda>i. R i) net"
105 using assms by (auto elim!: eventually_rev_mp)
108 subsection {* Finer-than relation *}
110 text {* @{term "net \<le> net'"} means that @{term net} is finer than
111 @{term net'}. *}
113 instantiation net :: (type) complete_lattice
114 begin
116 definition
117   le_net_def [code del]:
118     "net \<le> net' \<longleftrightarrow> (\<forall>P. eventually P net' \<longrightarrow> eventually P net)"
120 definition
121   less_net_def [code del]:
122     "(net :: 'a net) < net' \<longleftrightarrow> net \<le> net' \<and> \<not> net' \<le> net"
124 definition
125   top_net_def [code del]:
126     "top = Abs_net (\<lambda>P. \<forall>x. P x)"
128 definition
129   bot_net_def [code del]:
130     "bot = Abs_net (\<lambda>P. True)"
132 definition
133   sup_net_def [code del]:
134     "sup net net' = Abs_net (\<lambda>P. eventually P net \<and> eventually P net')"
136 definition
137   inf_net_def [code del]:
138     "inf a b = Abs_net
139       (\<lambda>P. \<exists>Q R. eventually Q a \<and> eventually R b \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
141 definition
142   Sup_net_def [code del]:
143     "Sup A = Abs_net (\<lambda>P. \<forall>net\<in>A. eventually P net)"
145 definition
146   Inf_net_def [code del]:
147     "Inf A = Sup {x::'a net. \<forall>y\<in>A. x \<le> y}"
149 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
150 unfolding top_net_def
151 by (rule eventually_Abs_net, rule is_filter.intro, auto)
153 lemma eventually_bot [simp]: "eventually P bot"
154 unfolding bot_net_def
155 by (subst eventually_Abs_net, rule is_filter.intro, auto)
157 lemma eventually_sup:
158   "eventually P (sup net net') \<longleftrightarrow> eventually P net \<and> eventually P net'"
159 unfolding sup_net_def
160 by (rule eventually_Abs_net, rule is_filter.intro)
161    (auto elim!: eventually_rev_mp)
163 lemma eventually_inf:
164   "eventually P (inf a b) \<longleftrightarrow>
165    (\<exists>Q R. eventually Q a \<and> eventually R b \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
166 unfolding inf_net_def
167 apply (rule eventually_Abs_net, rule is_filter.intro)
168 apply (fast intro: eventually_True)
169 apply clarify
170 apply (intro exI conjI)
171 apply (erule (1) eventually_conj)
172 apply (erule (1) eventually_conj)
173 apply simp
174 apply auto
175 done
177 lemma eventually_Sup:
178   "eventually P (Sup A) \<longleftrightarrow> (\<forall>net\<in>A. eventually P net)"
179 unfolding Sup_net_def
180 apply (rule eventually_Abs_net, rule is_filter.intro)
181 apply (auto intro: eventually_conj elim!: eventually_rev_mp)
182 done
184 instance proof
185   fix x y :: "'a net" show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
186     by (rule less_net_def)
187 next
188   fix x :: "'a net" show "x \<le> x"
189     unfolding le_net_def by simp
190 next
191   fix x y z :: "'a net" assume "x \<le> y" and "y \<le> z" thus "x \<le> z"
192     unfolding le_net_def by simp
193 next
194   fix x y :: "'a net" assume "x \<le> y" and "y \<le> x" thus "x = y"
195     unfolding le_net_def expand_net_eq by fast
196 next
197   fix x :: "'a net" show "x \<le> top"
198     unfolding le_net_def eventually_top by (simp add: always_eventually)
199 next
200   fix x :: "'a net" show "bot \<le> x"
201     unfolding le_net_def by simp
202 next
203   fix x y :: "'a net" show "x \<le> sup x y" and "y \<le> sup x y"
204     unfolding le_net_def eventually_sup by simp_all
205 next
206   fix x y z :: "'a net" assume "x \<le> z" and "y \<le> z" thus "sup x y \<le> z"
207     unfolding le_net_def eventually_sup by simp
208 next
209   fix x y :: "'a net" show "inf x y \<le> x" and "inf x y \<le> y"
210     unfolding le_net_def eventually_inf by (auto intro: eventually_True)
211 next
212   fix x y z :: "'a net" assume "x \<le> y" and "x \<le> z" thus "x \<le> inf y z"
213     unfolding le_net_def eventually_inf
214     by (auto elim!: eventually_mono intro: eventually_conj)
215 next
216   fix x :: "'a net" and A assume "x \<in> A" thus "x \<le> Sup A"
217     unfolding le_net_def eventually_Sup by simp
218 next
219   fix A and y :: "'a net" assume "\<And>x. x \<in> A \<Longrightarrow> x \<le> y" thus "Sup A \<le> y"
220     unfolding le_net_def eventually_Sup by simp
221 next
222   fix z :: "'a net" and A assume "z \<in> A" thus "Inf A \<le> z"
223     unfolding le_net_def Inf_net_def eventually_Sup Ball_def by simp
224 next
225   fix A and x :: "'a net" assume "\<And>y. y \<in> A \<Longrightarrow> x \<le> y" thus "x \<le> Inf A"
226     unfolding le_net_def Inf_net_def eventually_Sup Ball_def by simp
227 qed
229 end
231 lemma net_leD:
232   "net \<le> net' \<Longrightarrow> eventually P net' \<Longrightarrow> eventually P net"
233 unfolding le_net_def by simp
235 lemma net_leI:
236   "(\<And>P. eventually P net' \<Longrightarrow> eventually P net) \<Longrightarrow> net \<le> net'"
237 unfolding le_net_def by simp
239 lemma eventually_False:
240   "eventually (\<lambda>x. False) net \<longleftrightarrow> net = bot"
241 unfolding expand_net_eq by (auto elim: eventually_rev_mp)
244 subsection {* Map function for nets *}
246 definition
247   netmap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a net \<Rightarrow> 'b net"
248 where [code del]:
249   "netmap f net = Abs_net (\<lambda>P. eventually (\<lambda>x. P (f x)) net)"
251 lemma eventually_netmap:
252   "eventually P (netmap f net) = eventually (\<lambda>x. P (f x)) net"
253 unfolding netmap_def
254 apply (rule eventually_Abs_net)
255 apply (rule is_filter.intro)
256 apply (auto elim!: eventually_rev_mp)
257 done
259 lemma netmap_ident: "netmap (\<lambda>x. x) net = net"
260 by (simp add: expand_net_eq eventually_netmap)
262 lemma netmap_netmap: "netmap f (netmap g net) = netmap (\<lambda>x. f (g x)) net"
263 by (simp add: expand_net_eq eventually_netmap)
265 lemma netmap_mono: "net \<le> net' \<Longrightarrow> netmap f net \<le> netmap f net'"
266 unfolding le_net_def eventually_netmap by simp
268 lemma netmap_bot [simp]: "netmap f bot = bot"
269 by (simp add: expand_net_eq eventually_netmap)
272 subsection {* Sequentially *}
274 definition
275   sequentially :: "nat net"
276 where [code del]:
277   "sequentially = Abs_net (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
279 lemma eventually_sequentially:
280   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
281 unfolding sequentially_def
282 proof (rule eventually_Abs_net, rule is_filter.intro)
283   fix P Q :: "nat \<Rightarrow> bool"
284   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
285   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
286   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
287   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
288 qed auto
290 lemma sequentially_bot [simp]: "sequentially \<noteq> bot"
291 unfolding expand_net_eq eventually_sequentially by auto
293 lemma eventually_False_sequentially [simp]:
294   "\<not> eventually (\<lambda>n. False) sequentially"
295 by (simp add: eventually_False)
297 lemma le_sequentially:
298   "net \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) net)"
299 unfolding le_net_def eventually_sequentially
300 by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
303 subsection {* Standard Nets *}
305 definition
306   within :: "'a net \<Rightarrow> 'a set \<Rightarrow> 'a net" (infixr "within" 70)
307 where [code del]:
308   "net within S = Abs_net (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net)"
310 definition
311   nhds :: "'a::topological_space \<Rightarrow> 'a net"
312 where [code del]:
313   "nhds a = Abs_net (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
315 definition
316   at :: "'a::topological_space \<Rightarrow> 'a net"
317 where [code del]:
318   "at a = nhds a within - {a}"
320 lemma eventually_within:
321   "eventually P (net within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net"
322 unfolding within_def
323 by (rule eventually_Abs_net, rule is_filter.intro)
324    (auto elim!: eventually_rev_mp)
326 lemma within_UNIV: "net within UNIV = net"
327   unfolding expand_net_eq eventually_within by simp
329 lemma eventually_nhds:
330   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
331 unfolding nhds_def
332 proof (rule eventually_Abs_net, rule is_filter.intro)
333   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
334   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
335 next
336   fix P Q
337   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
338      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
339   then obtain S T where
340     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
341     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
342   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
343     by (simp add: open_Int)
344   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
345 qed auto
347 lemma eventually_nhds_metric:
348   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
349 unfolding eventually_nhds open_dist
350 apply safe
351 apply fast
352 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
353 apply clarsimp
354 apply (rule_tac x="d - dist x a" in exI, clarsimp)
355 apply (simp only: less_diff_eq)
356 apply (erule le_less_trans [OF dist_triangle])
357 done
359 lemma eventually_at_topological:
360   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
361 unfolding at_def eventually_within eventually_nhds by simp
363 lemma eventually_at:
364   fixes a :: "'a::metric_space"
365   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
366 unfolding at_def eventually_within eventually_nhds_metric by auto
369 subsection {* Boundedness *}
371 definition
372   Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
373   [code del]: "Bfun f net = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) net)"
375 lemma BfunI:
376   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) net" shows "Bfun f net"
377 unfolding Bfun_def
378 proof (intro exI conjI allI)
379   show "0 < max K 1" by simp
380 next
381   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) net"
382     using K by (rule eventually_elim1, simp)
383 qed
385 lemma BfunE:
386   assumes "Bfun f net"
387   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) net"
388 using assms unfolding Bfun_def by fast
391 subsection {* Convergence to Zero *}
393 definition
394   Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
395   [code del]: "Zfun f net = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) net)"
397 lemma ZfunI:
398   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net) \<Longrightarrow> Zfun f net"
399 unfolding Zfun_def by simp
401 lemma ZfunD:
402   "\<lbrakk>Zfun f net; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net"
403 unfolding Zfun_def by simp
405 lemma Zfun_ssubst:
406   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> Zfun g net \<Longrightarrow> Zfun f net"
407 unfolding Zfun_def by (auto elim!: eventually_rev_mp)
409 lemma Zfun_zero: "Zfun (\<lambda>x. 0) net"
410 unfolding Zfun_def by simp
412 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) net = Zfun (\<lambda>x. f x) net"
413 unfolding Zfun_def by simp
415 lemma Zfun_imp_Zfun:
416   assumes f: "Zfun f net"
417   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) net"
418   shows "Zfun (\<lambda>x. g x) net"
419 proof (cases)
420   assume K: "0 < K"
421   show ?thesis
422   proof (rule ZfunI)
423     fix r::real assume "0 < r"
424     hence "0 < r / K"
425       using K by (rule divide_pos_pos)
426     then have "eventually (\<lambda>x. norm (f x) < r / K) net"
427       using ZfunD [OF f] by fast
428     with g show "eventually (\<lambda>x. norm (g x) < r) net"
429     proof (rule eventually_elim2)
430       fix x
431       assume *: "norm (g x) \<le> norm (f x) * K"
432       assume "norm (f x) < r / K"
433       hence "norm (f x) * K < r"
434         by (simp add: pos_less_divide_eq K)
435       thus "norm (g x) < r"
436         by (simp add: order_le_less_trans [OF *])
437     qed
438   qed
439 next
440   assume "\<not> 0 < K"
441   hence K: "K \<le> 0" by (simp only: not_less)
442   show ?thesis
443   proof (rule ZfunI)
444     fix r :: real
445     assume "0 < r"
446     from g show "eventually (\<lambda>x. norm (g x) < r) net"
447     proof (rule eventually_elim1)
448       fix x
449       assume "norm (g x) \<le> norm (f x) * K"
450       also have "\<dots> \<le> norm (f x) * 0"
451         using K norm_ge_zero by (rule mult_left_mono)
452       finally show "norm (g x) < r"
453         using `0 < r` by simp
454     qed
455   qed
456 qed
458 lemma Zfun_le: "\<lbrakk>Zfun g net; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f net"
459 by (erule_tac K="1" in Zfun_imp_Zfun, simp)
462   assumes f: "Zfun f net" and g: "Zfun g net"
463   shows "Zfun (\<lambda>x. f x + g x) net"
464 proof (rule ZfunI)
465   fix r::real assume "0 < r"
466   hence r: "0 < r / 2" by simp
467   have "eventually (\<lambda>x. norm (f x) < r/2) net"
468     using f r by (rule ZfunD)
469   moreover
470   have "eventually (\<lambda>x. norm (g x) < r/2) net"
471     using g r by (rule ZfunD)
472   ultimately
473   show "eventually (\<lambda>x. norm (f x + g x) < r) net"
474   proof (rule eventually_elim2)
475     fix x
476     assume *: "norm (f x) < r/2" "norm (g x) < r/2"
477     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
478       by (rule norm_triangle_ineq)
479     also have "\<dots> < r/2 + r/2"
480       using * by (rule add_strict_mono)
481     finally show "norm (f x + g x) < r"
482       by simp
483   qed
484 qed
486 lemma Zfun_minus: "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. - f x) net"
487 unfolding Zfun_def by simp
489 lemma Zfun_diff: "\<lbrakk>Zfun f net; Zfun g net\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) net"
490 by (simp only: diff_minus Zfun_add Zfun_minus)
492 lemma (in bounded_linear) Zfun:
493   assumes g: "Zfun g net"
494   shows "Zfun (\<lambda>x. f (g x)) net"
495 proof -
496   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
497     using bounded by fast
498   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) net"
499     by simp
500   with g show ?thesis
501     by (rule Zfun_imp_Zfun)
502 qed
504 lemma (in bounded_bilinear) Zfun:
505   assumes f: "Zfun f net"
506   assumes g: "Zfun g net"
507   shows "Zfun (\<lambda>x. f x ** g x) net"
508 proof (rule ZfunI)
509   fix r::real assume r: "0 < r"
510   obtain K where K: "0 < K"
511     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
512     using pos_bounded by fast
513   from K have K': "0 < inverse K"
514     by (rule positive_imp_inverse_positive)
515   have "eventually (\<lambda>x. norm (f x) < r) net"
516     using f r by (rule ZfunD)
517   moreover
518   have "eventually (\<lambda>x. norm (g x) < inverse K) net"
519     using g K' by (rule ZfunD)
520   ultimately
521   show "eventually (\<lambda>x. norm (f x ** g x) < r) net"
522   proof (rule eventually_elim2)
523     fix x
524     assume *: "norm (f x) < r" "norm (g x) < inverse K"
525     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
526       by (rule norm_le)
527     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
528       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero * K)
529     also from K have "r * inverse K * K = r"
530       by simp
531     finally show "norm (f x ** g x) < r" .
532   qed
533 qed
535 lemma (in bounded_bilinear) Zfun_left:
536   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. f x ** a) net"
537 by (rule bounded_linear_left [THEN bounded_linear.Zfun])
539 lemma (in bounded_bilinear) Zfun_right:
540   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. a ** f x) net"
541 by (rule bounded_linear_right [THEN bounded_linear.Zfun])
543 lemmas Zfun_mult = mult.Zfun
544 lemmas Zfun_mult_right = mult.Zfun_right
545 lemmas Zfun_mult_left = mult.Zfun_left
548 subsection {* Limits *}
550 definition
551   tendsto :: "('a \<Rightarrow> 'b::topological_space) \<Rightarrow> 'b \<Rightarrow> 'a net \<Rightarrow> bool"
552     (infixr "--->" 55)
553 where [code del]:
554   "(f ---> l) net \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
556 ML {*
557 structure Tendsto_Intros = Named_Thms
558 (
559   val name = "tendsto_intros"
560   val description = "introduction rules for tendsto"
561 )
562 *}
564 setup Tendsto_Intros.setup
566 lemma tendsto_mono: "net \<le> net' \<Longrightarrow> (f ---> l) net' \<Longrightarrow> (f ---> l) net"
567 unfolding tendsto_def le_net_def by fast
569 lemma topological_tendstoI:
570   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net)
571     \<Longrightarrow> (f ---> l) net"
572   unfolding tendsto_def by auto
574 lemma topological_tendstoD:
575   "(f ---> l) net \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net"
576   unfolding tendsto_def by auto
578 lemma tendstoI:
579   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
580   shows "(f ---> l) net"
581 apply (rule topological_tendstoI)
582 apply (simp add: open_dist)
583 apply (drule (1) bspec, clarify)
584 apply (drule assms)
585 apply (erule eventually_elim1, simp)
586 done
588 lemma tendstoD:
589   "(f ---> l) net \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
590 apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
591 apply (clarsimp simp add: open_dist)
592 apply (rule_tac x="e - dist x l" in exI, clarsimp)
593 apply (simp only: less_diff_eq)
594 apply (erule le_less_trans [OF dist_triangle])
595 apply simp
596 apply simp
597 done
599 lemma tendsto_iff:
600   "(f ---> l) net \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
601 using tendstoI tendstoD by fast
603 lemma tendsto_Zfun_iff: "(f ---> a) net = Zfun (\<lambda>x. f x - a) net"
604 by (simp only: tendsto_iff Zfun_def dist_norm)
606 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
607 unfolding tendsto_def eventually_at_topological by auto
609 lemma tendsto_ident_at_within [tendsto_intros]:
610   "((\<lambda>x. x) ---> a) (at a within S)"
611 unfolding tendsto_def eventually_within eventually_at_topological by auto
613 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) net"
614 by (simp add: tendsto_def)
616 lemma tendsto_const_iff:
617   fixes k l :: "'a::metric_space"
618   assumes "net \<noteq> bot" shows "((\<lambda>n. k) ---> l) net \<longleftrightarrow> k = l"
619 apply (safe intro!: tendsto_const)
620 apply (rule ccontr)
621 apply (drule_tac e="dist k l" in tendstoD)
622 apply (simp add: zero_less_dist_iff)
623 apply (simp add: eventually_False assms)
624 done
626 lemma tendsto_dist [tendsto_intros]:
627   assumes f: "(f ---> l) net" and g: "(g ---> m) net"
628   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) net"
629 proof (rule tendstoI)
630   fix e :: real assume "0 < e"
631   hence e2: "0 < e/2" by simp
632   from tendstoD [OF f e2] tendstoD [OF g e2]
633   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) net"
634   proof (rule eventually_elim2)
635     fix x assume "dist (f x) l < e/2" "dist (g x) m < e/2"
636     then show "dist (dist (f x) (g x)) (dist l m) < e"
637       unfolding dist_real_def
638       using dist_triangle2 [of "f x" "g x" "l"]
639       using dist_triangle2 [of "g x" "l" "m"]
640       using dist_triangle3 [of "l" "m" "f x"]
641       using dist_triangle [of "f x" "m" "g x"]
642       by arith
643   qed
644 qed
646 lemma norm_conv_dist: "norm x = dist x 0"
647 unfolding dist_norm by simp
649 lemma tendsto_norm [tendsto_intros]:
650   "(f ---> a) net \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) net"
651 unfolding norm_conv_dist by (intro tendsto_intros)
653 lemma tendsto_norm_zero:
654   "(f ---> 0) net \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) net"
655 by (drule tendsto_norm, simp)
657 lemma tendsto_norm_zero_cancel:
658   "((\<lambda>x. norm (f x)) ---> 0) net \<Longrightarrow> (f ---> 0) net"
659 unfolding tendsto_iff dist_norm by simp
661 lemma tendsto_norm_zero_iff:
662   "((\<lambda>x. norm (f x)) ---> 0) net \<longleftrightarrow> (f ---> 0) net"
663 unfolding tendsto_iff dist_norm by simp
666   fixes a b c d :: "'a::ab_group_add"
667   shows "(a + c) - (b + d) = (a - b) + (c - d)"
668 by simp
670 lemma minus_diff_minus:
671   fixes a b :: "'a::ab_group_add"
672   shows "(- a) - (- b) = - (a - b)"
673 by simp
675 lemma tendsto_add [tendsto_intros]:
676   fixes a b :: "'a::real_normed_vector"
677   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) net"
680 lemma tendsto_minus [tendsto_intros]:
681   fixes a :: "'a::real_normed_vector"
682   shows "(f ---> a) net \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) net"
683 by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
685 lemma tendsto_minus_cancel:
686   fixes a :: "'a::real_normed_vector"
687   shows "((\<lambda>x. - f x) ---> - a) net \<Longrightarrow> (f ---> a) net"
688 by (drule tendsto_minus, simp)
690 lemma tendsto_diff [tendsto_intros]:
691   fixes a b :: "'a::real_normed_vector"
692   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) net"
693 by (simp add: diff_minus tendsto_add tendsto_minus)
695 lemma tendsto_setsum [tendsto_intros]:
696   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
697   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) net"
698   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) net"
699 proof (cases "finite S")
700   assume "finite S" thus ?thesis using assms
701   proof (induct set: finite)
702     case empty show ?case
703       by (simp add: tendsto_const)
704   next
705     case (insert i F) thus ?case
707   qed
708 next
709   assume "\<not> finite S" thus ?thesis
710     by (simp add: tendsto_const)
711 qed
713 lemma (in bounded_linear) tendsto [tendsto_intros]:
714   "(g ---> a) net \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) net"
715 by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
717 lemma (in bounded_bilinear) tendsto [tendsto_intros]:
718   "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) net"
719 by (simp only: tendsto_Zfun_iff prod_diff_prod
720                Zfun_add Zfun Zfun_left Zfun_right)
723 subsection {* Continuity of Inverse *}
725 lemma (in bounded_bilinear) Zfun_prod_Bfun:
726   assumes f: "Zfun f net"
727   assumes g: "Bfun g net"
728   shows "Zfun (\<lambda>x. f x ** g x) net"
729 proof -
730   obtain K where K: "0 \<le> K"
731     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
732     using nonneg_bounded by fast
733   obtain B where B: "0 < B"
734     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) net"
735     using g by (rule BfunE)
736   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) net"
737   using norm_g proof (rule eventually_elim1)
738     fix x
739     assume *: "norm (g x) \<le> B"
740     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
741       by (rule norm_le)
742     also have "\<dots> \<le> norm (f x) * B * K"
743       by (intro mult_mono' order_refl norm_g norm_ge_zero
744                 mult_nonneg_nonneg K *)
745     also have "\<dots> = norm (f x) * (B * K)"
746       by (rule mult_assoc)
747     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
748   qed
749   with f show ?thesis
750     by (rule Zfun_imp_Zfun)
751 qed
753 lemma (in bounded_bilinear) flip:
754   "bounded_bilinear (\<lambda>x y. y ** x)"
755 apply default
756 apply (rule add_right)
757 apply (rule add_left)
758 apply (rule scaleR_right)
759 apply (rule scaleR_left)
760 apply (subst mult_commute)
761 using bounded by fast
763 lemma (in bounded_bilinear) Bfun_prod_Zfun:
764   assumes f: "Bfun f net"
765   assumes g: "Zfun g net"
766   shows "Zfun (\<lambda>x. f x ** g x) net"
767 using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
769 lemma inverse_diff_inverse:
770   "\<lbrakk>(a::'a::division_ring) \<noteq> 0; b \<noteq> 0\<rbrakk>
771    \<Longrightarrow> inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
772 by (simp add: algebra_simps)
774 lemma Bfun_inverse_lemma:
775   fixes x :: "'a::real_normed_div_algebra"
776   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
777 apply (subst nonzero_norm_inverse, clarsimp)
778 apply (erule (1) le_imp_inverse_le)
779 done
781 lemma Bfun_inverse:
782   fixes a :: "'a::real_normed_div_algebra"
783   assumes f: "(f ---> a) net"
784   assumes a: "a \<noteq> 0"
785   shows "Bfun (\<lambda>x. inverse (f x)) net"
786 proof -
787   from a have "0 < norm a" by simp
788   hence "\<exists>r>0. r < norm a" by (rule dense)
789   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
790   have "eventually (\<lambda>x. dist (f x) a < r) net"
791     using tendstoD [OF f r1] by fast
792   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) net"
793   proof (rule eventually_elim1)
794     fix x
795     assume "dist (f x) a < r"
796     hence 1: "norm (f x - a) < r"
797       by (simp add: dist_norm)
798     hence 2: "f x \<noteq> 0" using r2 by auto
799     hence "norm (inverse (f x)) = inverse (norm (f x))"
800       by (rule nonzero_norm_inverse)
801     also have "\<dots> \<le> inverse (norm a - r)"
802     proof (rule le_imp_inverse_le)
803       show "0 < norm a - r" using r2 by simp
804     next
805       have "norm a - norm (f x) \<le> norm (a - f x)"
806         by (rule norm_triangle_ineq2)
807       also have "\<dots> = norm (f x - a)"
808         by (rule norm_minus_commute)
809       also have "\<dots> < r" using 1 .
810       finally show "norm a - r \<le> norm (f x)" by simp
811     qed
812     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
813   qed
814   thus ?thesis by (rule BfunI)
815 qed
817 lemma tendsto_inverse_lemma:
818   fixes a :: "'a::real_normed_div_algebra"
819   shows "\<lbrakk>(f ---> a) net; a \<noteq> 0; eventually (\<lambda>x. f x \<noteq> 0) net\<rbrakk>
820          \<Longrightarrow> ((\<lambda>x. inverse (f x)) ---> inverse a) net"
821 apply (subst tendsto_Zfun_iff)
822 apply (rule Zfun_ssubst)
823 apply (erule eventually_elim1)
824 apply (erule (1) inverse_diff_inverse)
825 apply (rule Zfun_minus)
826 apply (rule Zfun_mult_left)
827 apply (rule mult.Bfun_prod_Zfun)
828 apply (erule (1) Bfun_inverse)
829 apply (simp add: tendsto_Zfun_iff)
830 done
832 lemma tendsto_inverse [tendsto_intros]:
833   fixes a :: "'a::real_normed_div_algebra"
834   assumes f: "(f ---> a) net"
835   assumes a: "a \<noteq> 0"
836   shows "((\<lambda>x. inverse (f x)) ---> inverse a) net"
837 proof -
838   from a have "0 < norm a" by simp
839   with f have "eventually (\<lambda>x. dist (f x) a < norm a) net"
840     by (rule tendstoD)
841   then have "eventually (\<lambda>x. f x \<noteq> 0) net"
842     unfolding dist_norm by (auto elim!: eventually_elim1)
843   with f a show ?thesis
844     by (rule tendsto_inverse_lemma)
845 qed
847 lemma tendsto_divide [tendsto_intros]:
848   fixes a b :: "'a::real_normed_field"
849   shows "\<lbrakk>(f ---> a) net; (g ---> b) net; b \<noteq> 0\<rbrakk>
850     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) net"
851 by (simp add: mult.tendsto tendsto_inverse divide_inverse)
853 end