src/HOL/Lattices.thy
author haftmann
Fri Nov 30 20:13:03 2007 +0100 (2007-11-30)
changeset 25510 38c15efe603b
parent 25482 4ed49eccb1eb
child 26014 00c2c3525bef
permissions -rw-r--r--
adjustions to due to instance target
     1 (*  Title:      HOL/Lattices.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* Abstract lattices *}
     7 
     8 theory Lattices
     9 imports Orderings
    10 begin
    11 
    12 subsection{* Lattices *}
    13 
    14 notation
    15   less_eq  (infix "\<sqsubseteq>" 50) and
    16   less  (infix "\<sqsubset>" 50)
    17 
    18 class lower_semilattice = order +
    19   fixes inf :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<sqinter>" 70)
    20   assumes inf_le1 [simp]: "x \<sqinter> y \<sqsubseteq> x"
    21   and inf_le2 [simp]: "x \<sqinter> y \<sqsubseteq> y"
    22   and inf_greatest: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> y \<sqinter> z"
    23 
    24 class upper_semilattice = order +
    25   fixes sup :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<squnion>" 65)
    26   assumes sup_ge1 [simp]: "x \<sqsubseteq> x \<squnion> y"
    27   and sup_ge2 [simp]: "y \<sqsubseteq> x \<squnion> y"
    28   and sup_least: "y \<sqsubseteq> x \<Longrightarrow> z \<sqsubseteq> x \<Longrightarrow> y \<squnion> z \<sqsubseteq> x"
    29 
    30 class lattice = lower_semilattice + upper_semilattice
    31 
    32 
    33 subsubsection{* Intro and elim rules*}
    34 
    35 context lower_semilattice
    36 begin
    37 
    38 lemma le_infI1[intro]:
    39   assumes "a \<sqsubseteq> x"
    40   shows "a \<sqinter> b \<sqsubseteq> x"
    41 proof (rule order_trans)
    42   from assms show "a \<sqsubseteq> x" .
    43   show "a \<sqinter> b \<sqsubseteq> a" by simp 
    44 qed
    45 lemmas (in -) [rule del] = le_infI1
    46 
    47 lemma le_infI2[intro]:
    48   assumes "b \<sqsubseteq> x"
    49   shows "a \<sqinter> b \<sqsubseteq> x"
    50 proof (rule order_trans)
    51   from assms show "b \<sqsubseteq> x" .
    52   show "a \<sqinter> b \<sqsubseteq> b" by simp
    53 qed
    54 lemmas (in -) [rule del] = le_infI2
    55 
    56 lemma le_infI[intro!]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<sqinter> b"
    57 by(blast intro: inf_greatest)
    58 lemmas (in -) [rule del] = le_infI
    59 
    60 lemma le_infE [elim!]: "x \<sqsubseteq> a \<sqinter> b \<Longrightarrow> (x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> P) \<Longrightarrow> P"
    61   by (blast intro: order_trans)
    62 lemmas (in -) [rule del] = le_infE
    63 
    64 lemma le_inf_iff [simp]:
    65   "x \<sqsubseteq> y \<sqinter> z = (x \<sqsubseteq> y \<and> x \<sqsubseteq> z)"
    66 by blast
    67 
    68 lemma le_iff_inf: "(x \<sqsubseteq> y) = (x \<sqinter> y = x)"
    69   by (blast intro: antisym dest: eq_iff [THEN iffD1])
    70 
    71 lemma mono_inf:
    72   fixes f :: "'a \<Rightarrow> 'b\<Colon>lower_semilattice"
    73   shows "mono f \<Longrightarrow> f (A \<sqinter> B) \<le> f A \<sqinter> f B"
    74   by (auto simp add: mono_def intro: Lattices.inf_greatest)
    75 
    76 end
    77 
    78 context upper_semilattice
    79 begin
    80 
    81 lemma le_supI1[intro]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    82   by (rule order_trans) auto
    83 lemmas (in -) [rule del] = le_supI1
    84 
    85 lemma le_supI2[intro]: "x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    86   by (rule order_trans) auto 
    87 lemmas (in -) [rule del] = le_supI2
    88 
    89 lemma le_supI[intro!]: "a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> a \<squnion> b \<sqsubseteq> x"
    90 by(blast intro: sup_least)
    91 lemmas (in -) [rule del] = le_supI
    92 
    93 lemma le_supE[elim!]: "a \<squnion> b \<sqsubseteq> x \<Longrightarrow> (a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> P) \<Longrightarrow> P"
    94   by (blast intro: order_trans)
    95 lemmas (in -) [rule del] = le_supE
    96 
    97 lemma ge_sup_conv[simp]:
    98   "x \<squnion> y \<sqsubseteq> z = (x \<sqsubseteq> z \<and> y \<sqsubseteq> z)"
    99 by blast
   100 
   101 lemma le_iff_sup: "(x \<sqsubseteq> y) = (x \<squnion> y = y)"
   102   by (blast intro: antisym dest: eq_iff [THEN iffD1])
   103 
   104 lemma mono_sup:
   105   fixes f :: "'a \<Rightarrow> 'b\<Colon>upper_semilattice"
   106   shows "mono f \<Longrightarrow> f A \<squnion> f B \<le> f (A \<squnion> B)"
   107   by (auto simp add: mono_def intro: Lattices.sup_least)
   108 
   109 end
   110 
   111 
   112 subsubsection{* Equational laws *}
   113 
   114 context lower_semilattice
   115 begin
   116 
   117 lemma inf_commute: "(x \<sqinter> y) = (y \<sqinter> x)"
   118   by (blast intro: antisym)
   119 
   120 lemma inf_assoc: "(x \<sqinter> y) \<sqinter> z = x \<sqinter> (y \<sqinter> z)"
   121   by (blast intro: antisym)
   122 
   123 lemma inf_idem[simp]: "x \<sqinter> x = x"
   124   by (blast intro: antisym)
   125 
   126 lemma inf_left_idem[simp]: "x \<sqinter> (x \<sqinter> y) = x \<sqinter> y"
   127   by (blast intro: antisym)
   128 
   129 lemma inf_absorb1: "x \<sqsubseteq> y \<Longrightarrow> x \<sqinter> y = x"
   130   by (blast intro: antisym)
   131 
   132 lemma inf_absorb2: "y \<sqsubseteq> x \<Longrightarrow> x \<sqinter> y = y"
   133   by (blast intro: antisym)
   134 
   135 lemma inf_left_commute: "x \<sqinter> (y \<sqinter> z) = y \<sqinter> (x \<sqinter> z)"
   136   by (blast intro: antisym)
   137 
   138 lemmas inf_ACI = inf_commute inf_assoc inf_left_commute inf_left_idem
   139 
   140 end
   141 
   142 
   143 context upper_semilattice
   144 begin
   145 
   146 lemma sup_commute: "(x \<squnion> y) = (y \<squnion> x)"
   147   by (blast intro: antisym)
   148 
   149 lemma sup_assoc: "(x \<squnion> y) \<squnion> z = x \<squnion> (y \<squnion> z)"
   150   by (blast intro: antisym)
   151 
   152 lemma sup_idem[simp]: "x \<squnion> x = x"
   153   by (blast intro: antisym)
   154 
   155 lemma sup_left_idem[simp]: "x \<squnion> (x \<squnion> y) = x \<squnion> y"
   156   by (blast intro: antisym)
   157 
   158 lemma sup_absorb1: "y \<sqsubseteq> x \<Longrightarrow> x \<squnion> y = x"
   159   by (blast intro: antisym)
   160 
   161 lemma sup_absorb2: "x \<sqsubseteq> y \<Longrightarrow> x \<squnion> y = y"
   162   by (blast intro: antisym)
   163 
   164 lemma sup_left_commute: "x \<squnion> (y \<squnion> z) = y \<squnion> (x \<squnion> z)"
   165   by (blast intro: antisym)
   166 
   167 lemmas sup_ACI = sup_commute sup_assoc sup_left_commute sup_left_idem
   168 
   169 end
   170 
   171 context lattice
   172 begin
   173 
   174 lemma inf_sup_absorb: "x \<sqinter> (x \<squnion> y) = x"
   175   by (blast intro: antisym inf_le1 inf_greatest sup_ge1)
   176 
   177 lemma sup_inf_absorb: "x \<squnion> (x \<sqinter> y) = x"
   178   by (blast intro: antisym sup_ge1 sup_least inf_le1)
   179 
   180 lemmas ACI = inf_ACI sup_ACI
   181 
   182 lemmas inf_sup_ord = inf_le1 inf_le2 sup_ge1 sup_ge2
   183 
   184 text{* Towards distributivity *}
   185 
   186 lemma distrib_sup_le: "x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   187   by blast
   188 
   189 lemma distrib_inf_le: "(x \<sqinter> y) \<squnion> (x \<sqinter> z) \<sqsubseteq> x \<sqinter> (y \<squnion> z)"
   190   by blast
   191 
   192 
   193 text{* If you have one of them, you have them all. *}
   194 
   195 lemma distrib_imp1:
   196 assumes D: "!!x y z. x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   197 shows "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   198 proof-
   199   have "x \<squnion> (y \<sqinter> z) = (x \<squnion> (x \<sqinter> z)) \<squnion> (y \<sqinter> z)" by(simp add:sup_inf_absorb)
   200   also have "\<dots> = x \<squnion> (z \<sqinter> (x \<squnion> y))" by(simp add:D inf_commute sup_assoc)
   201   also have "\<dots> = ((x \<squnion> y) \<sqinter> x) \<squnion> ((x \<squnion> y) \<sqinter> z)"
   202     by(simp add:inf_sup_absorb inf_commute)
   203   also have "\<dots> = (x \<squnion> y) \<sqinter> (x \<squnion> z)" by(simp add:D)
   204   finally show ?thesis .
   205 qed
   206 
   207 lemma distrib_imp2:
   208 assumes D: "!!x y z. x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   209 shows "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   210 proof-
   211   have "x \<sqinter> (y \<squnion> z) = (x \<sqinter> (x \<squnion> z)) \<sqinter> (y \<squnion> z)" by(simp add:inf_sup_absorb)
   212   also have "\<dots> = x \<sqinter> (z \<squnion> (x \<sqinter> y))" by(simp add:D sup_commute inf_assoc)
   213   also have "\<dots> = ((x \<sqinter> y) \<squnion> x) \<sqinter> ((x \<sqinter> y) \<squnion> z)"
   214     by(simp add:sup_inf_absorb sup_commute)
   215   also have "\<dots> = (x \<sqinter> y) \<squnion> (x \<sqinter> z)" by(simp add:D)
   216   finally show ?thesis .
   217 qed
   218 
   219 (* seems unused *)
   220 lemma modular_le: "x \<sqsubseteq> z \<Longrightarrow> x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> z"
   221 by blast
   222 
   223 end
   224 
   225 
   226 subsection {* Distributive lattices *}
   227 
   228 class distrib_lattice = lattice +
   229   assumes sup_inf_distrib1: "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   230 
   231 context distrib_lattice
   232 begin
   233 
   234 lemma sup_inf_distrib2:
   235  "(y \<sqinter> z) \<squnion> x = (y \<squnion> x) \<sqinter> (z \<squnion> x)"
   236 by(simp add:ACI sup_inf_distrib1)
   237 
   238 lemma inf_sup_distrib1:
   239  "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   240 by(rule distrib_imp2[OF sup_inf_distrib1])
   241 
   242 lemma inf_sup_distrib2:
   243  "(y \<squnion> z) \<sqinter> x = (y \<sqinter> x) \<squnion> (z \<sqinter> x)"
   244 by(simp add:ACI inf_sup_distrib1)
   245 
   246 lemmas distrib =
   247   sup_inf_distrib1 sup_inf_distrib2 inf_sup_distrib1 inf_sup_distrib2
   248 
   249 end
   250 
   251 
   252 subsection {* Uniqueness of inf and sup *}
   253 
   254 lemma (in lower_semilattice) inf_unique:
   255   fixes f (infixl "\<triangle>" 70)
   256   assumes le1: "\<And>x y. x \<triangle> y \<le> x" and le2: "\<And>x y. x \<triangle> y \<le> y"
   257   and greatest: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z"
   258   shows "x \<sqinter> y = x \<triangle> y"
   259 proof (rule antisym)
   260   show "x \<triangle> y \<le> x \<sqinter> y" by (rule le_infI) (rule le1, rule le2)
   261 next
   262   have leI: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z" by (blast intro: greatest)
   263   show "x \<sqinter> y \<le> x \<triangle> y" by (rule leI) simp_all
   264 qed
   265 
   266 lemma (in upper_semilattice) sup_unique:
   267   fixes f (infixl "\<nabla>" 70)
   268   assumes ge1 [simp]: "\<And>x y. x \<le> x \<nabla> y" and ge2: "\<And>x y. y \<le> x \<nabla> y"
   269   and least: "\<And>x y z. y \<le> x \<Longrightarrow> z \<le> x \<Longrightarrow> y \<nabla> z \<le> x"
   270   shows "x \<squnion> y = x \<nabla> y"
   271 proof (rule antisym)
   272   show "x \<squnion> y \<le> x \<nabla> y" by (rule le_supI) (rule ge1, rule ge2)
   273 next
   274   have leI: "\<And>x y z. x \<le> z \<Longrightarrow> y \<le> z \<Longrightarrow> x \<nabla> y \<le> z" by (blast intro: least)
   275   show "x \<nabla> y \<le> x \<squnion> y" by (rule leI) simp_all
   276 qed
   277   
   278 
   279 subsection {* @{const min}/@{const max} on linear orders as
   280   special case of @{const inf}/@{const sup} *}
   281 
   282 lemma (in linorder) distrib_lattice_min_max:
   283   "distrib_lattice (op \<le>) (op <) min max"
   284 proof unfold_locales
   285   have aux: "\<And>x y \<Colon> 'a. x < y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   286     by (auto simp add: less_le antisym)
   287   fix x y z
   288   show "max x (min y z) = min (max x y) (max x z)"
   289   unfolding min_def max_def
   290   by auto
   291 qed (auto simp add: min_def max_def not_le less_imp_le)
   292 
   293 interpretation min_max:
   294   distrib_lattice ["op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool" "op <" min max]
   295   by (rule distrib_lattice_min_max)
   296 
   297 lemma inf_min: "inf = (min \<Colon> 'a\<Colon>{lower_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   298   by (rule ext)+ (auto intro: antisym)
   299 
   300 lemma sup_max: "sup = (max \<Colon> 'a\<Colon>{upper_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   301   by (rule ext)+ (auto intro: antisym)
   302 
   303 lemmas le_maxI1 = min_max.sup_ge1
   304 lemmas le_maxI2 = min_max.sup_ge2
   305  
   306 lemmas max_ac = min_max.sup_assoc min_max.sup_commute
   307   mk_left_commute [of max, OF min_max.sup_assoc min_max.sup_commute]
   308 
   309 lemmas min_ac = min_max.inf_assoc min_max.inf_commute
   310   mk_left_commute [of min, OF min_max.inf_assoc min_max.inf_commute]
   311 
   312 text {*
   313   Now we have inherited antisymmetry as an intro-rule on all
   314   linear orders. This is a problem because it applies to bool, which is
   315   undesirable.
   316 *}
   317 
   318 lemmas [rule del] = min_max.le_infI min_max.le_supI
   319   min_max.le_supE min_max.le_infE min_max.le_supI1 min_max.le_supI2
   320   min_max.le_infI1 min_max.le_infI2
   321 
   322 
   323 subsection {* Complete lattices *}
   324 
   325 class complete_lattice = lattice +
   326   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
   327     and Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
   328   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
   329      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
   330   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
   331      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
   332 begin
   333 
   334 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<le> a}"
   335   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   336 
   337 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<le> b}"
   338   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   339 
   340 lemma Inf_Univ: "\<Sqinter>UNIV = \<Squnion>{}"
   341   unfolding Sup_Inf by auto
   342 
   343 lemma Sup_Univ: "\<Squnion>UNIV = \<Sqinter>{}"
   344   unfolding Inf_Sup by auto
   345 
   346 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   347   apply (rule antisym)
   348   apply (rule le_infI)
   349   apply (rule Inf_lower)
   350   apply simp
   351   apply (rule Inf_greatest)
   352   apply (rule Inf_lower)
   353   apply simp
   354   apply (rule Inf_greatest)
   355   apply (erule insertE)
   356   apply (rule le_infI1)
   357   apply simp
   358   apply (rule le_infI2)
   359   apply (erule Inf_lower)
   360   done
   361 
   362 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   363   apply (rule antisym)
   364   apply (rule Sup_least)
   365   apply (erule insertE)
   366   apply (rule le_supI1)
   367   apply simp
   368   apply (rule le_supI2)
   369   apply (erule Sup_upper)
   370   apply (rule le_supI)
   371   apply (rule Sup_upper)
   372   apply simp
   373   apply (rule Sup_least)
   374   apply (rule Sup_upper)
   375   apply simp
   376   done
   377 
   378 lemma Inf_singleton [simp]:
   379   "\<Sqinter>{a} = a"
   380   by (auto intro: antisym Inf_lower Inf_greatest)
   381 
   382 lemma Sup_singleton [simp]:
   383   "\<Squnion>{a} = a"
   384   by (auto intro: antisym Sup_upper Sup_least)
   385 
   386 lemma Inf_insert_simp:
   387   "\<Sqinter>insert a A = (if A = {} then a else a \<sqinter> \<Sqinter>A)"
   388   by (cases "A = {}") (simp_all, simp add: Inf_insert)
   389 
   390 lemma Sup_insert_simp:
   391   "\<Squnion>insert a A = (if A = {} then a else a \<squnion> \<Squnion>A)"
   392   by (cases "A = {}") (simp_all, simp add: Sup_insert)
   393 
   394 lemma Inf_binary:
   395   "\<Sqinter>{a, b} = a \<sqinter> b"
   396   by (simp add: Inf_insert_simp)
   397 
   398 lemma Sup_binary:
   399   "\<Squnion>{a, b} = a \<squnion> b"
   400   by (simp add: Sup_insert_simp)
   401 
   402 definition
   403   top :: 'a where
   404   "top = \<Sqinter>{}"
   405 
   406 definition
   407   bot :: 'a where
   408   "bot = \<Squnion>{}"
   409 
   410 lemma top_greatest [simp]: "x \<le> top"
   411   by (unfold top_def, rule Inf_greatest, simp)
   412 
   413 lemma bot_least [simp]: "bot \<le> x"
   414   by (unfold bot_def, rule Sup_least, simp)
   415 
   416 definition
   417   SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a"
   418 where
   419   "SUPR A f == \<Squnion> (f ` A)"
   420 
   421 definition
   422   INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a"
   423 where
   424   "INFI A f == \<Sqinter> (f ` A)"
   425 
   426 end
   427 
   428 syntax
   429   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
   430   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 10] 10)
   431   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
   432   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 10] 10)
   433 
   434 translations
   435   "SUP x y. B"   == "SUP x. SUP y. B"
   436   "SUP x. B"     == "CONST SUPR UNIV (%x. B)"
   437   "SUP x. B"     == "SUP x:UNIV. B"
   438   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   439   "INF x y. B"   == "INF x. INF y. B"
   440   "INF x. B"     == "CONST INFI UNIV (%x. B)"
   441   "INF x. B"     == "INF x:UNIV. B"
   442   "INF x:A. B"   == "CONST INFI A (%x. B)"
   443 
   444 (* To avoid eta-contraction of body: *)
   445 print_translation {*
   446 let
   447   fun btr' syn (A :: Abs abs :: ts) =
   448     let val (x,t) = atomic_abs_tr' abs
   449     in list_comb (Syntax.const syn $ x $ A $ t, ts) end
   450   val const_syntax_name = Sign.const_syntax_name @{theory} o fst o dest_Const
   451 in
   452 [(const_syntax_name @{term SUPR}, btr' "_SUP"),(const_syntax_name @{term "INFI"}, btr' "_INF")]
   453 end
   454 *}
   455 
   456 context complete_lattice
   457 begin
   458 
   459 lemma le_SUPI: "i : A \<Longrightarrow> M i \<le> (SUP i:A. M i)"
   460   by (auto simp add: SUPR_def intro: Sup_upper)
   461 
   462 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<le> u) \<Longrightarrow> (SUP i:A. M i) \<le> u"
   463   by (auto simp add: SUPR_def intro: Sup_least)
   464 
   465 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<le> M i"
   466   by (auto simp add: INFI_def intro: Inf_lower)
   467 
   468 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<le> M i) \<Longrightarrow> u \<le> (INF i:A. M i)"
   469   by (auto simp add: INFI_def intro: Inf_greatest)
   470 
   471 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
   472   by (auto intro: antisym SUP_leI le_SUPI)
   473 
   474 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
   475   by (auto intro: antisym INF_leI le_INFI)
   476 
   477 end
   478 
   479 
   480 subsection {* Bool as lattice *}
   481 
   482 instantiation bool :: distrib_lattice
   483 begin
   484 
   485 definition
   486   inf_bool_eq: "P \<sqinter> Q \<longleftrightarrow> P \<and> Q"
   487 
   488 definition
   489   sup_bool_eq: "P \<squnion> Q \<longleftrightarrow> P \<or> Q"
   490 
   491 instance
   492   by intro_classes (auto simp add: inf_bool_eq sup_bool_eq le_bool_def)
   493 
   494 end
   495 
   496 instantiation bool :: complete_lattice
   497 begin
   498 
   499 definition
   500   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   501 
   502 definition
   503   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   504 
   505 instance
   506   by intro_classes (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   507 
   508 end
   509 
   510 lemma Inf_empty_bool [simp]:
   511   "\<Sqinter>{}"
   512   unfolding Inf_bool_def by auto
   513 
   514 lemma not_Sup_empty_bool [simp]:
   515   "\<not> Sup {}"
   516   unfolding Sup_bool_def by auto
   517 
   518 lemma top_bool_eq: "top = True"
   519   by (iprover intro!: order_antisym le_boolI top_greatest)
   520 
   521 lemma bot_bool_eq: "bot = False"
   522   by (iprover intro!: order_antisym le_boolI bot_least)
   523 
   524 
   525 subsection {* Set as lattice *}
   526 
   527 instantiation set :: (type) distrib_lattice
   528 begin
   529 
   530 definition
   531   inf_set_eq [code func del]: "A \<sqinter> B = A \<inter> B"
   532 
   533 definition
   534   sup_set_eq [code func del]: "A \<squnion> B = A \<union> B"
   535 
   536 instance
   537   by intro_classes (auto simp add: inf_set_eq sup_set_eq)
   538 
   539 end
   540 
   541 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
   542   apply (fold inf_set_eq sup_set_eq)
   543   apply (erule mono_inf)
   544   done
   545 
   546 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
   547   apply (fold inf_set_eq sup_set_eq)
   548   apply (erule mono_sup)
   549   done
   550 
   551 instantiation set :: (type) complete_lattice
   552 begin
   553 
   554 definition
   555   Inf_set_def [code func del]: "\<Sqinter>S \<equiv> \<Inter>S"
   556 
   557 definition
   558   Sup_set_def [code func del]: "\<Squnion>S \<equiv> \<Union>S"
   559 
   560 instance
   561   by intro_classes (auto simp add: Inf_set_def Sup_set_def)
   562 
   563 end
   564 
   565 lemma top_set_eq: "top = UNIV"
   566   by (iprover intro!: subset_antisym subset_UNIV top_greatest)
   567 
   568 lemma bot_set_eq: "bot = {}"
   569   by (iprover intro!: subset_antisym empty_subsetI bot_least)
   570 
   571 
   572 subsection {* Fun as lattice *}
   573 
   574 instantiation "fun" :: (type, lattice) lattice
   575 begin
   576 
   577 definition
   578   inf_fun_eq [code func del]: "f \<sqinter> g = (\<lambda>x. f x \<sqinter> g x)"
   579 
   580 definition
   581   sup_fun_eq [code func del]: "f \<squnion> g = (\<lambda>x. f x \<squnion> g x)"
   582 
   583 instance
   584 apply intro_classes
   585 unfolding inf_fun_eq sup_fun_eq
   586 apply (auto intro: le_funI)
   587 apply (rule le_funI)
   588 apply (auto dest: le_funD)
   589 apply (rule le_funI)
   590 apply (auto dest: le_funD)
   591 done
   592 
   593 end
   594 
   595 instance "fun" :: (type, distrib_lattice) distrib_lattice
   596   by default (auto simp add: inf_fun_eq sup_fun_eq sup_inf_distrib1)
   597 
   598 instantiation "fun" :: (type, complete_lattice) complete_lattice
   599 begin
   600 
   601 definition
   602   Inf_fun_def [code func del]: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   603 
   604 definition
   605   Sup_fun_def [code func del]: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   606 
   607 instance
   608   by intro_classes
   609     (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
   610       intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   611 
   612 end
   613 
   614 lemma Inf_empty_fun:
   615   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
   616   by rule (auto simp add: Inf_fun_def)
   617 
   618 lemma Sup_empty_fun:
   619   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
   620   by rule (auto simp add: Sup_fun_def)
   621 
   622 lemma top_fun_eq: "top = (\<lambda>x. top)"
   623   by (iprover intro!: order_antisym le_funI top_greatest)
   624 
   625 lemma bot_fun_eq: "bot = (\<lambda>x. bot)"
   626   by (iprover intro!: order_antisym le_funI bot_least)
   627 
   628 
   629 text {* redundant bindings *}
   630 
   631 lemmas inf_aci = inf_ACI
   632 lemmas sup_aci = sup_ACI
   633 
   634 no_notation
   635   less_eq  (infix "\<sqsubseteq>" 50) and
   636   less (infix "\<sqsubset>" 50) and
   637   inf  (infixl "\<sqinter>" 70) and
   638   sup  (infixl "\<squnion>" 65) and
   639   Inf  ("\<Sqinter>_" [900] 900) and
   640   Sup  ("\<Squnion>_" [900] 900)
   641 
   642 end