src/HOL/Library/Permutation.thy
author hoelzl
Thu Sep 02 14:34:08 2010 +0200 (2010-09-02)
changeset 39078 39f8f6d1eb74
parent 39075 a18e5946d63c
child 39916 8c83139a1433
permissions -rw-r--r--
Fixes lemma names
     1 (*  Title:      HOL/Library/Permutation.thy
     2     Author:     Lawrence C Paulson and Thomas M Rasmussen and Norbert Voelker
     3 *)
     4 
     5 header {* Permutations *}
     6 
     7 theory Permutation
     8 imports Main Multiset
     9 begin
    10 
    11 inductive
    12   perm :: "'a list => 'a list => bool"  ("_ <~~> _"  [50, 50] 50)
    13   where
    14     Nil  [intro!]: "[] <~~> []"
    15   | swap [intro!]: "y # x # l <~~> x # y # l"
    16   | Cons [intro!]: "xs <~~> ys ==> z # xs <~~> z # ys"
    17   | trans [intro]: "xs <~~> ys ==> ys <~~> zs ==> xs <~~> zs"
    18 
    19 lemma perm_refl [iff]: "l <~~> l"
    20   by (induct l) auto
    21 
    22 
    23 subsection {* Some examples of rule induction on permutations *}
    24 
    25 lemma xperm_empty_imp: "[] <~~> ys ==> ys = []"
    26   by (induct xs == "[]::'a list" ys pred: perm) simp_all
    27 
    28 
    29 text {*
    30   \medskip This more general theorem is easier to understand!
    31   *}
    32 
    33 lemma perm_length: "xs <~~> ys ==> length xs = length ys"
    34   by (induct pred: perm) simp_all
    35 
    36 lemma perm_empty_imp: "[] <~~> xs ==> xs = []"
    37   by (drule perm_length) auto
    38 
    39 lemma perm_sym: "xs <~~> ys ==> ys <~~> xs"
    40   by (induct pred: perm) auto
    41 
    42 
    43 subsection {* Ways of making new permutations *}
    44 
    45 text {*
    46   We can insert the head anywhere in the list.
    47 *}
    48 
    49 lemma perm_append_Cons: "a # xs @ ys <~~> xs @ a # ys"
    50   by (induct xs) auto
    51 
    52 lemma perm_append_swap: "xs @ ys <~~> ys @ xs"
    53   apply (induct xs)
    54     apply simp_all
    55   apply (blast intro: perm_append_Cons)
    56   done
    57 
    58 lemma perm_append_single: "a # xs <~~> xs @ [a]"
    59   by (rule perm.trans [OF _ perm_append_swap]) simp
    60 
    61 lemma perm_rev: "rev xs <~~> xs"
    62   apply (induct xs)
    63    apply simp_all
    64   apply (blast intro!: perm_append_single intro: perm_sym)
    65   done
    66 
    67 lemma perm_append1: "xs <~~> ys ==> l @ xs <~~> l @ ys"
    68   by (induct l) auto
    69 
    70 lemma perm_append2: "xs <~~> ys ==> xs @ l <~~> ys @ l"
    71   by (blast intro!: perm_append_swap perm_append1)
    72 
    73 
    74 subsection {* Further results *}
    75 
    76 lemma perm_empty [iff]: "([] <~~> xs) = (xs = [])"
    77   by (blast intro: perm_empty_imp)
    78 
    79 lemma perm_empty2 [iff]: "(xs <~~> []) = (xs = [])"
    80   apply auto
    81   apply (erule perm_sym [THEN perm_empty_imp])
    82   done
    83 
    84 lemma perm_sing_imp: "ys <~~> xs ==> xs = [y] ==> ys = [y]"
    85   by (induct pred: perm) auto
    86 
    87 lemma perm_sing_eq [iff]: "(ys <~~> [y]) = (ys = [y])"
    88   by (blast intro: perm_sing_imp)
    89 
    90 lemma perm_sing_eq2 [iff]: "([y] <~~> ys) = (ys = [y])"
    91   by (blast dest: perm_sym)
    92 
    93 
    94 subsection {* Removing elements *}
    95 
    96 lemma perm_remove: "x \<in> set ys ==> ys <~~> x # remove1 x ys"
    97   by (induct ys) auto
    98 
    99 
   100 text {* \medskip Congruence rule *}
   101 
   102 lemma perm_remove_perm: "xs <~~> ys ==> remove1 z xs <~~> remove1 z ys"
   103   by (induct pred: perm) auto
   104 
   105 lemma remove_hd [simp]: "remove1 z (z # xs) = xs"
   106   by auto
   107 
   108 lemma cons_perm_imp_perm: "z # xs <~~> z # ys ==> xs <~~> ys"
   109   by (drule_tac z = z in perm_remove_perm) auto
   110 
   111 lemma cons_perm_eq [iff]: "(z#xs <~~> z#ys) = (xs <~~> ys)"
   112   by (blast intro: cons_perm_imp_perm)
   113 
   114 lemma append_perm_imp_perm: "zs @ xs <~~> zs @ ys ==> xs <~~> ys"
   115   apply (induct zs arbitrary: xs ys rule: rev_induct)
   116    apply (simp_all (no_asm_use))
   117   apply blast
   118   done
   119 
   120 lemma perm_append1_eq [iff]: "(zs @ xs <~~> zs @ ys) = (xs <~~> ys)"
   121   by (blast intro: append_perm_imp_perm perm_append1)
   122 
   123 lemma perm_append2_eq [iff]: "(xs @ zs <~~> ys @ zs) = (xs <~~> ys)"
   124   apply (safe intro!: perm_append2)
   125   apply (rule append_perm_imp_perm)
   126   apply (rule perm_append_swap [THEN perm.trans])
   127     -- {* the previous step helps this @{text blast} call succeed quickly *}
   128   apply (blast intro: perm_append_swap)
   129   done
   130 
   131 lemma multiset_of_eq_perm: "(multiset_of xs = multiset_of ys) = (xs <~~> ys) "
   132   apply (rule iffI)
   133   apply (erule_tac [2] perm.induct, simp_all add: union_ac)
   134   apply (erule rev_mp, rule_tac x=ys in spec)
   135   apply (induct_tac xs, auto)
   136   apply (erule_tac x = "remove1 a x" in allE, drule sym, simp)
   137   apply (subgoal_tac "a \<in> set x")
   138   apply (drule_tac z=a in perm.Cons)
   139   apply (erule perm.trans, rule perm_sym, erule perm_remove)
   140   apply (drule_tac f=set_of in arg_cong, simp)
   141   done
   142 
   143 lemma multiset_of_le_perm_append:
   144     "multiset_of xs \<le> multiset_of ys \<longleftrightarrow> (\<exists>zs. xs @ zs <~~> ys)"
   145   apply (auto simp: multiset_of_eq_perm[THEN sym] mset_le_exists_conv)
   146   apply (insert surj_multiset_of, drule surjD)
   147   apply (blast intro: sym)+
   148   done
   149 
   150 lemma perm_set_eq: "xs <~~> ys ==> set xs = set ys"
   151   by (metis multiset_of_eq_perm multiset_of_eq_setD)
   152 
   153 lemma perm_distinct_iff: "xs <~~> ys ==> distinct xs = distinct ys"
   154   apply (induct pred: perm)
   155      apply simp_all
   156    apply fastsimp
   157   apply (metis perm_set_eq)
   158   done
   159 
   160 lemma eq_set_perm_remdups: "set xs = set ys ==> remdups xs <~~> remdups ys"
   161   apply (induct xs arbitrary: ys rule: length_induct)
   162   apply (case_tac "remdups xs", simp, simp)
   163   apply (subgoal_tac "a : set (remdups ys)")
   164    prefer 2 apply (metis set.simps(2) insert_iff set_remdups)
   165   apply (drule split_list) apply(elim exE conjE)
   166   apply (drule_tac x=list in spec) apply(erule impE) prefer 2
   167    apply (drule_tac x="ysa@zs" in spec) apply(erule impE) prefer 2
   168     apply simp
   169     apply (subgoal_tac "a#list <~~> a#ysa@zs")
   170      apply (metis Cons_eq_appendI perm_append_Cons trans)
   171     apply (metis Cons Cons_eq_appendI distinct.simps(2)
   172       distinct_remdups distinct_remdups_id perm_append_swap perm_distinct_iff)
   173    apply (subgoal_tac "set (a#list) = set (ysa@a#zs) & distinct (a#list) & distinct (ysa@a#zs)")
   174     apply (fastsimp simp add: insert_ident)
   175    apply (metis distinct_remdups set_remdups)
   176    apply (subgoal_tac "length (remdups xs) < Suc (length xs)")
   177    apply simp
   178    apply (subgoal_tac "length (remdups xs) \<le> length xs")
   179    apply simp
   180    apply (rule length_remdups_leq)
   181   done
   182 
   183 lemma perm_remdups_iff_eq_set: "remdups x <~~> remdups y = (set x = set y)"
   184   by (metis List.set_remdups perm_set_eq eq_set_perm_remdups)
   185 
   186 lemma permutation_Ex_bij:
   187   assumes "xs <~~> ys"
   188   shows "\<exists>f. bij_betw f {..<length xs} {..<length ys} \<and> (\<forall>i<length xs. xs ! i = ys ! (f i))"
   189 using assms proof induct
   190   case Nil then show ?case unfolding bij_betw_def by simp
   191 next
   192   case (swap y x l)
   193   show ?case
   194   proof (intro exI[of _ "Fun.swap 0 1 id"] conjI allI impI)
   195     show "bij_betw (Fun.swap 0 1 id) {..<length (y # x # l)} {..<length (x # y # l)}"
   196       by (auto simp: bij_betw_def bij_betw_swap_iff)
   197     fix i assume "i < length(y#x#l)"
   198     show "(y # x # l) ! i = (x # y # l) ! (Fun.swap 0 1 id) i"
   199       by (cases i) (auto simp: Fun.swap_def gr0_conv_Suc)
   200   qed
   201 next
   202   case (Cons xs ys z)
   203   then obtain f where bij: "bij_betw f {..<length xs} {..<length ys}" and
   204     perm: "\<forall>i<length xs. xs ! i = ys ! (f i)" by blast
   205   let "?f i" = "case i of Suc n \<Rightarrow> Suc (f n) | 0 \<Rightarrow> 0"
   206   show ?case
   207   proof (intro exI[of _ ?f] allI conjI impI)
   208     have *: "{..<length (z#xs)} = {0} \<union> Suc ` {..<length xs}"
   209             "{..<length (z#ys)} = {0} \<union> Suc ` {..<length ys}"
   210       by (simp_all add: lessThan_Suc_eq_insert_0)
   211     show "bij_betw ?f {..<length (z#xs)} {..<length (z#ys)}" unfolding *
   212     proof (rule bij_betw_combine)
   213       show "bij_betw ?f (Suc ` {..<length xs}) (Suc ` {..<length ys})"
   214         using bij unfolding bij_betw_def
   215         by (auto intro!: inj_onI imageI dest: inj_onD simp: image_compose[symmetric] comp_def)
   216     qed (auto simp: bij_betw_def)
   217     fix i assume "i < length (z#xs)"
   218     then show "(z # xs) ! i = (z # ys) ! (?f i)"
   219       using perm by (cases i) auto
   220   qed
   221 next
   222   case (trans xs ys zs)
   223   then obtain f g where
   224     bij: "bij_betw f {..<length xs} {..<length ys}" "bij_betw g {..<length ys} {..<length zs}" and
   225     perm: "\<forall>i<length xs. xs ! i = ys ! (f i)" "\<forall>i<length ys. ys ! i = zs ! (g i)" by blast
   226   show ?case
   227   proof (intro exI[of _ "g\<circ>f"] conjI allI impI)
   228     show "bij_betw (g \<circ> f) {..<length xs} {..<length zs}"
   229       using bij by (rule bij_betw_trans)
   230     fix i assume "i < length xs"
   231     with bij have "f i < length ys" unfolding bij_betw_def by force
   232     with `i < length xs` show "xs ! i = zs ! (g \<circ> f) i"
   233       using trans(1,3)[THEN perm_length] perm by force
   234   qed
   235 qed
   236 
   237 end