src/HOL/Limits.thy
author wenzelm
Wed Dec 30 14:05:51 2015 +0100 (2015-12-30)
changeset 61976 3a27957ac658
parent 61973 0c7e865fa7cb
child 62087 44841d07ef1d
permissions -rw-r--r--
more symbols;
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11 imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter" where
    17   "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 lemma at_infinity_eq_at_top_bot:
    25   "(at_infinity :: real filter) = sup at_top at_bot"
    26   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    27                    eventually_at_top_linorder eventually_at_bot_linorder)
    28   apply safe
    29   apply (rule_tac x="b" in exI, simp)
    30   apply (rule_tac x="- b" in exI, simp)
    31   apply (rule_tac x="max (- Na) N" in exI, auto simp: abs_real_def)
    32   done
    33 
    34 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    35   unfolding at_infinity_eq_at_top_bot by simp
    36 
    37 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    38   unfolding at_infinity_eq_at_top_bot by simp
    39 
    40 lemma filterlim_at_top_imp_at_infinity:
    41   fixes f :: "_ \<Rightarrow> real"
    42   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    43   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    44 
    45 lemma lim_infinity_imp_sequentially:
    46   "(f \<longlongrightarrow> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) \<longlongrightarrow> l) sequentially"
    47 by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    48 
    49 
    50 subsubsection \<open>Boundedness\<close>
    51 
    52 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    53   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    54 
    55 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    56   "Bseq X \<equiv> Bfun X sequentially"
    57 
    58 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    59 
    60 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    61   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    62 
    63 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    64   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    65 
    66 lemma Bfun_def:
    67   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    68   unfolding Bfun_metric_def norm_conv_dist
    69 proof safe
    70   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    71   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    72     by (intro always_eventually) (metis dist_commute dist_triangle)
    73   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    74     by eventually_elim auto
    75   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    76     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    77 qed auto
    78 
    79 lemma BfunI:
    80   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    81 unfolding Bfun_def
    82 proof (intro exI conjI allI)
    83   show "0 < max K 1" by simp
    84 next
    85   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    86     using K by (rule eventually_mono, simp)
    87 qed
    88 
    89 lemma BfunE:
    90   assumes "Bfun f F"
    91   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    92 using assms unfolding Bfun_def by blast
    93 
    94 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
    95   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
    96   apply (erule_tac x=1 in allE)
    97   apply simp
    98   apply safe
    99   apply (rule_tac x="X M" in exI)
   100   apply (rule_tac x=1 in exI)
   101   apply (erule_tac x=M in allE)
   102   apply simp
   103   apply (rule_tac x=M in exI)
   104   apply (auto simp: dist_commute)
   105   done
   106 
   107 
   108 subsubsection \<open>Bounded Sequences\<close>
   109 
   110 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   111   by (intro BfunI) (auto simp: eventually_sequentially)
   112 
   113 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   114   by (intro BfunI) (auto simp: eventually_sequentially)
   115 
   116 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   117   unfolding Bfun_def eventually_sequentially
   118 proof safe
   119   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   120   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   121     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   122        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   123 qed auto
   124 
   125 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   126 unfolding Bseq_def by auto
   127 
   128 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   129 by (simp add: Bseq_def)
   130 
   131 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   132 by (auto simp add: Bseq_def)
   133 
   134 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   135 proof (elim BseqE, intro bdd_aboveI2)
   136   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   137     by (auto elim!: allE[of _ n])
   138 qed
   139 
   140 lemma Bseq_bdd_above': 
   141   "Bseq (X::nat \<Rightarrow> 'a :: real_normed_vector) \<Longrightarrow> bdd_above (range (\<lambda>n. norm (X n)))"
   142 proof (elim BseqE, intro bdd_aboveI2)
   143   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "norm (X n) \<le> K"
   144     by (auto elim!: allE[of _ n])
   145 qed
   146 
   147 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   148 proof (elim BseqE, intro bdd_belowI2)
   149   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   150     by (auto elim!: allE[of _ n])
   151 qed
   152 
   153 lemma Bseq_eventually_mono:
   154   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) sequentially" "Bseq g"
   155   shows   "Bseq f" 
   156 proof -
   157   from assms(1) obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> norm (f n) \<le> norm (g n)"
   158     by (auto simp: eventually_at_top_linorder)
   159   moreover from assms(2) obtain K where K: "\<And>n. norm (g n) \<le> K" by (blast elim!: BseqE)
   160   ultimately have "norm (f n) \<le> max K (Max {norm (f n) |n. n < N})" for n
   161     apply (cases "n < N")
   162     apply (rule max.coboundedI2, rule Max.coboundedI, auto) []
   163     apply (rule max.coboundedI1, force intro: order.trans[OF N K])
   164     done
   165   thus ?thesis by (blast intro: BseqI') 
   166 qed
   167 
   168 lemma lemma_NBseq_def:
   169   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   170 proof safe
   171   fix K :: real
   172   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   173   then have "K \<le> real (Suc n)" by auto
   174   moreover assume "\<forall>m. norm (X m) \<le> K"
   175   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   176     by (blast intro: order_trans)
   177   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   178 next
   179   show "\<And>N. \<forall>n. norm (X n) \<le> real (Suc N) \<Longrightarrow> \<exists>K>0. \<forall>n. norm (X n) \<le> K"
   180     using of_nat_0_less_iff by blast
   181 qed
   182 
   183 text\<open>alternative definition for Bseq\<close>
   184 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   185 apply (simp add: Bseq_def)
   186 apply (simp (no_asm) add: lemma_NBseq_def)
   187 done
   188 
   189 lemma lemma_NBseq_def2:
   190      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   191 apply (subst lemma_NBseq_def, auto)
   192 apply (rule_tac x = "Suc N" in exI)
   193 apply (rule_tac [2] x = N in exI)
   194 apply (auto simp add: of_nat_Suc)
   195  prefer 2 apply (blast intro: order_less_imp_le)
   196 apply (drule_tac x = n in spec, simp)
   197 done
   198 
   199 (* yet another definition for Bseq *)
   200 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   201 by (simp add: Bseq_def lemma_NBseq_def2)
   202 
   203 subsubsection\<open>A Few More Equivalence Theorems for Boundedness\<close>
   204 
   205 text\<open>alternative formulation for boundedness\<close>
   206 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   207 apply (unfold Bseq_def, safe)
   208 apply (rule_tac [2] x = "k + norm x" in exI)
   209 apply (rule_tac x = K in exI, simp)
   210 apply (rule exI [where x = 0], auto)
   211 apply (erule order_less_le_trans, simp)
   212 apply (drule_tac x=n in spec)
   213 apply (drule order_trans [OF norm_triangle_ineq2])
   214 apply simp
   215 done
   216 
   217 text\<open>alternative formulation for boundedness\<close>
   218 lemma Bseq_iff3:
   219   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   220 proof
   221   assume ?P
   222   then obtain K
   223     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   224   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   225   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   226     by (auto intro: order_trans norm_triangle_ineq4)
   227   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   228     by simp
   229   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   230 next
   231   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   232 qed
   233 
   234 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   235 apply (simp add: Bseq_def)
   236 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   237 apply (drule_tac x = n in spec, arith)
   238 done
   239 
   240 
   241 subsubsection\<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   242 
   243 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   244   by (simp add: Bseq_def)
   245 
   246 lemma Bseq_add: 
   247   assumes "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   248   shows   "Bseq (\<lambda>x. f x + c)"
   249 proof -
   250   from assms obtain K where K: "\<And>x. norm (f x) \<le> K" unfolding Bseq_def by blast
   251   {
   252     fix x :: nat
   253     have "norm (f x + c) \<le> norm (f x) + norm c" by (rule norm_triangle_ineq)
   254     also have "norm (f x) \<le> K" by (rule K)
   255     finally have "norm (f x + c) \<le> K + norm c" by simp
   256   }
   257   thus ?thesis by (rule BseqI')
   258 qed
   259 
   260 lemma Bseq_add_iff: "Bseq (\<lambda>x. f x + c) \<longleftrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   261   using Bseq_add[of f c] Bseq_add[of "\<lambda>x. f x + c" "-c"] by auto
   262 
   263 lemma Bseq_mult: 
   264   assumes "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_field)"
   265   assumes "Bseq (g :: nat \<Rightarrow> 'a :: real_normed_field)"
   266   shows   "Bseq (\<lambda>x. f x * g x)"
   267 proof -
   268   from assms obtain K1 K2 where K: "\<And>x. norm (f x) \<le> K1" "K1 > 0" "\<And>x. norm (g x) \<le> K2" "K2 > 0" 
   269     unfolding Bseq_def by blast
   270   hence "\<And>x. norm (f x * g x) \<le> K1 * K2" by (auto simp: norm_mult intro!: mult_mono)
   271   thus ?thesis by (rule BseqI')
   272 qed
   273 
   274 lemma Bfun_const [simp]: "Bfun (\<lambda>_. c) F"
   275   unfolding Bfun_metric_def by (auto intro!: exI[of _ c] exI[of _ "1::real"])
   276 
   277 lemma Bseq_cmult_iff: "(c :: 'a :: real_normed_field) \<noteq> 0 \<Longrightarrow> Bseq (\<lambda>x. c * f x) \<longleftrightarrow> Bseq f"
   278 proof
   279   assume "c \<noteq> 0" "Bseq (\<lambda>x. c * f x)"
   280   find_theorems "Bfun (\<lambda>_. ?c) _"
   281   from Bfun_const this(2) have "Bseq (\<lambda>x. inverse c * (c * f x))" by (rule Bseq_mult)
   282   with \<open>c \<noteq> 0\<close> show "Bseq f" by (simp add: divide_simps)
   283 qed (intro Bseq_mult Bfun_const)
   284 
   285 lemma Bseq_subseq: "Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector) \<Longrightarrow> Bseq (\<lambda>x. f (g x))"
   286   unfolding Bseq_def by auto
   287 
   288 lemma Bseq_Suc_iff: "Bseq (\<lambda>n. f (Suc n)) \<longleftrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   289   using Bseq_offset[of f 1] by (auto intro: Bseq_subseq)
   290 
   291 lemma increasing_Bseq_subseq_iff:
   292   assumes "\<And>x y. x \<le> y \<Longrightarrow> norm (f x :: 'a :: real_normed_vector) \<le> norm (f y)" "subseq g"
   293   shows   "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   294 proof
   295   assume "Bseq (\<lambda>x. f (g x))"
   296   then obtain K where K: "\<And>x. norm (f (g x)) \<le> K" unfolding Bseq_def by auto
   297   {
   298     fix x :: nat
   299     from filterlim_subseq[OF assms(2)] obtain y where "g y \<ge> x"
   300       by (auto simp: filterlim_at_top eventually_at_top_linorder)
   301     hence "norm (f x) \<le> norm (f (g y))" using assms(1) by blast
   302     also have "norm (f (g y)) \<le> K" by (rule K)
   303     finally have "norm (f x) \<le> K" .
   304   }
   305   thus "Bseq f" by (rule BseqI')
   306 qed (insert Bseq_subseq[of f g], simp_all)
   307 
   308 lemma nonneg_incseq_Bseq_subseq_iff:
   309   assumes "\<And>x. f x \<ge> 0" "incseq (f :: nat \<Rightarrow> real)" "subseq g"
   310   shows   "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   311   using assms by (intro increasing_Bseq_subseq_iff) (auto simp: incseq_def)
   312 
   313 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   314   apply (simp add: subset_eq)
   315   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   316   apply (erule_tac x=n in allE)
   317   apply auto
   318   done
   319 
   320 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   321   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   322 
   323 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   324   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   325 
   326 subsection \<open>Bounded Monotonic Sequences\<close>
   327 
   328 subsubsection\<open>A Bounded and Monotonic Sequence Converges\<close>
   329 
   330 (* TODO: delete *)
   331 (* FIXME: one use in NSA/HSEQ.thy *)
   332 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X \<longlonglongrightarrow> L)"
   333   apply (rule_tac x="X m" in exI)
   334   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   335   unfolding eventually_sequentially
   336   apply blast
   337   done
   338 
   339 subsection \<open>Convergence to Zero\<close>
   340 
   341 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   342   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   343 
   344 lemma ZfunI:
   345   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   346   unfolding Zfun_def by simp
   347 
   348 lemma ZfunD:
   349   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   350   unfolding Zfun_def by simp
   351 
   352 lemma Zfun_ssubst:
   353   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   354   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   355 
   356 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   357   unfolding Zfun_def by simp
   358 
   359 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   360   unfolding Zfun_def by simp
   361 
   362 lemma Zfun_imp_Zfun:
   363   assumes f: "Zfun f F"
   364   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   365   shows "Zfun (\<lambda>x. g x) F"
   366 proof (cases)
   367   assume K: "0 < K"
   368   show ?thesis
   369   proof (rule ZfunI)
   370     fix r::real assume "0 < r"
   371     hence "0 < r / K" using K by simp
   372     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   373       using ZfunD [OF f] by blast
   374     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   375     proof eventually_elim
   376       case (elim x)
   377       hence "norm (f x) * K < r"
   378         by (simp add: pos_less_divide_eq K)
   379       thus ?case
   380         by (simp add: order_le_less_trans [OF elim(1)])
   381     qed
   382   qed
   383 next
   384   assume "\<not> 0 < K"
   385   hence K: "K \<le> 0" by (simp only: not_less)
   386   show ?thesis
   387   proof (rule ZfunI)
   388     fix r :: real
   389     assume "0 < r"
   390     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   391     proof eventually_elim
   392       case (elim x)
   393       also have "norm (f x) * K \<le> norm (f x) * 0"
   394         using K norm_ge_zero by (rule mult_left_mono)
   395       finally show ?case
   396         using \<open>0 < r\<close> by simp
   397     qed
   398   qed
   399 qed
   400 
   401 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   402   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   403 
   404 lemma Zfun_add:
   405   assumes f: "Zfun f F" and g: "Zfun g F"
   406   shows "Zfun (\<lambda>x. f x + g x) F"
   407 proof (rule ZfunI)
   408   fix r::real assume "0 < r"
   409   hence r: "0 < r / 2" by simp
   410   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   411     using f r by (rule ZfunD)
   412   moreover
   413   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   414     using g r by (rule ZfunD)
   415   ultimately
   416   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   417   proof eventually_elim
   418     case (elim x)
   419     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   420       by (rule norm_triangle_ineq)
   421     also have "\<dots> < r/2 + r/2"
   422       using elim by (rule add_strict_mono)
   423     finally show ?case
   424       by simp
   425   qed
   426 qed
   427 
   428 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   429   unfolding Zfun_def by simp
   430 
   431 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   432   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   433 
   434 lemma (in bounded_linear) Zfun:
   435   assumes g: "Zfun g F"
   436   shows "Zfun (\<lambda>x. f (g x)) F"
   437 proof -
   438   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   439     using bounded by blast
   440   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   441     by simp
   442   with g show ?thesis
   443     by (rule Zfun_imp_Zfun)
   444 qed
   445 
   446 lemma (in bounded_bilinear) Zfun:
   447   assumes f: "Zfun f F"
   448   assumes g: "Zfun g F"
   449   shows "Zfun (\<lambda>x. f x ** g x) F"
   450 proof (rule ZfunI)
   451   fix r::real assume r: "0 < r"
   452   obtain K where K: "0 < K"
   453     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   454     using pos_bounded by blast
   455   from K have K': "0 < inverse K"
   456     by (rule positive_imp_inverse_positive)
   457   have "eventually (\<lambda>x. norm (f x) < r) F"
   458     using f r by (rule ZfunD)
   459   moreover
   460   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   461     using g K' by (rule ZfunD)
   462   ultimately
   463   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   464   proof eventually_elim
   465     case (elim x)
   466     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   467       by (rule norm_le)
   468     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   469       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   470     also from K have "r * inverse K * K = r"
   471       by simp
   472     finally show ?case .
   473   qed
   474 qed
   475 
   476 lemma (in bounded_bilinear) Zfun_left:
   477   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   478   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   479 
   480 lemma (in bounded_bilinear) Zfun_right:
   481   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   482   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   483 
   484 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   485 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   486 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   487 
   488 lemma tendsto_Zfun_iff: "(f \<longlongrightarrow> a) F = Zfun (\<lambda>x. f x - a) F"
   489   by (simp only: tendsto_iff Zfun_def dist_norm)
   490 
   491 lemma tendsto_0_le: "\<lbrakk>(f \<longlongrightarrow> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk>
   492                      \<Longrightarrow> (g \<longlongrightarrow> 0) F"
   493   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   494 
   495 subsubsection \<open>Distance and norms\<close>
   496 
   497 lemma tendsto_dist [tendsto_intros]:
   498   fixes l m :: "'a :: metric_space"
   499   assumes f: "(f \<longlongrightarrow> l) F" and g: "(g \<longlongrightarrow> m) F"
   500   shows "((\<lambda>x. dist (f x) (g x)) \<longlongrightarrow> dist l m) F"
   501 proof (rule tendstoI)
   502   fix e :: real assume "0 < e"
   503   hence e2: "0 < e/2" by simp
   504   from tendstoD [OF f e2] tendstoD [OF g e2]
   505   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   506   proof (eventually_elim)
   507     case (elim x)
   508     then show "dist (dist (f x) (g x)) (dist l m) < e"
   509       unfolding dist_real_def
   510       using dist_triangle2 [of "f x" "g x" "l"]
   511       using dist_triangle2 [of "g x" "l" "m"]
   512       using dist_triangle3 [of "l" "m" "f x"]
   513       using dist_triangle [of "f x" "m" "g x"]
   514       by arith
   515   qed
   516 qed
   517 
   518 lemma continuous_dist[continuous_intros]:
   519   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   520   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   521   unfolding continuous_def by (rule tendsto_dist)
   522 
   523 lemma continuous_on_dist[continuous_intros]:
   524   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   525   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   526   unfolding continuous_on_def by (auto intro: tendsto_dist)
   527 
   528 lemma tendsto_norm [tendsto_intros]:
   529   "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> norm a) F"
   530   unfolding norm_conv_dist by (intro tendsto_intros)
   531 
   532 lemma continuous_norm [continuous_intros]:
   533   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   534   unfolding continuous_def by (rule tendsto_norm)
   535 
   536 lemma continuous_on_norm [continuous_intros]:
   537   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   538   unfolding continuous_on_def by (auto intro: tendsto_norm)
   539 
   540 lemma tendsto_norm_zero:
   541   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F"
   542   by (drule tendsto_norm, simp)
   543 
   544 lemma tendsto_norm_zero_cancel:
   545   "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   546   unfolding tendsto_iff dist_norm by simp
   547 
   548 lemma tendsto_norm_zero_iff:
   549   "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   550   unfolding tendsto_iff dist_norm by simp
   551 
   552 lemma tendsto_rabs [tendsto_intros]:
   553   "(f \<longlongrightarrow> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> \<bar>l\<bar>) F"
   554   by (fold real_norm_def, rule tendsto_norm)
   555 
   556 lemma continuous_rabs [continuous_intros]:
   557   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   558   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   559 
   560 lemma continuous_on_rabs [continuous_intros]:
   561   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   562   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   563 
   564 lemma tendsto_rabs_zero:
   565   "(f \<longlongrightarrow> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> 0) F"
   566   by (fold real_norm_def, rule tendsto_norm_zero)
   567 
   568 lemma tendsto_rabs_zero_cancel:
   569   "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   570   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   571 
   572 lemma tendsto_rabs_zero_iff:
   573   "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   574   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   575 
   576 subsubsection \<open>Addition and subtraction\<close>
   577 
   578 lemma tendsto_add [tendsto_intros]:
   579   fixes a b :: "'a::real_normed_vector"
   580   shows "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> a + b) F"
   581   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   582 
   583 lemma continuous_add [continuous_intros]:
   584   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   585   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   586   unfolding continuous_def by (rule tendsto_add)
   587 
   588 lemma continuous_on_add [continuous_intros]:
   589   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   590   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   591   unfolding continuous_on_def by (auto intro: tendsto_add)
   592 
   593 lemma tendsto_add_zero:
   594   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   595   shows "\<lbrakk>(f \<longlongrightarrow> 0) F; (g \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> 0) F"
   596   by (drule (1) tendsto_add, simp)
   597 
   598 lemma tendsto_minus [tendsto_intros]:
   599   fixes a :: "'a::real_normed_vector"
   600   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> - a) F"
   601   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   602 
   603 lemma continuous_minus [continuous_intros]:
   604   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   605   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   606   unfolding continuous_def by (rule tendsto_minus)
   607 
   608 lemma continuous_on_minus [continuous_intros]:
   609   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   610   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   611   unfolding continuous_on_def by (auto intro: tendsto_minus)
   612 
   613 lemma tendsto_minus_cancel:
   614   fixes a :: "'a::real_normed_vector"
   615   shows "((\<lambda>x. - f x) \<longlongrightarrow> - a) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
   616   by (drule tendsto_minus, simp)
   617 
   618 lemma tendsto_minus_cancel_left:
   619     "(f \<longlongrightarrow> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> y) F"
   620   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   621   by auto
   622 
   623 lemma tendsto_diff [tendsto_intros]:
   624   fixes a b :: "'a::real_normed_vector"
   625   shows "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> a - b) F"
   626   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   627 
   628 lemma continuous_diff [continuous_intros]:
   629   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   630   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   631   unfolding continuous_def by (rule tendsto_diff)
   632 
   633 lemma continuous_on_diff [continuous_intros]:
   634   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   635   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   636   unfolding continuous_on_def by (auto intro: tendsto_diff)
   637 
   638 lemma continuous_on_op_minus: "continuous_on (s::'a::real_normed_vector set) (op - x)"
   639   by (rule continuous_intros | simp)+
   640 
   641 lemma tendsto_setsum [tendsto_intros]:
   642   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   643   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> a i) F"
   644   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) \<longlongrightarrow> (\<Sum>i\<in>S. a i)) F"
   645 proof (cases "finite S")
   646   assume "finite S" thus ?thesis using assms
   647     by (induct, simp, simp add: tendsto_add)
   648 qed simp
   649 
   650 lemma continuous_setsum [continuous_intros]:
   651   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   652   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   653   unfolding continuous_def by (rule tendsto_setsum)
   654 
   655 lemma continuous_on_setsum [continuous_intros]:
   656   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   657   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   658   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   659 
   660 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   661 
   662 subsubsection \<open>Linear operators and multiplication\<close>
   663 
   664 lemma linear_times:
   665   fixes c::"'a::real_algebra" shows "linear (\<lambda>x. c * x)"
   666   by (auto simp: linearI distrib_left)
   667 
   668 lemma (in bounded_linear) tendsto:
   669   "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> f a) F"
   670   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   671 
   672 lemma (in bounded_linear) continuous:
   673   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   674   using tendsto[of g _ F] by (auto simp: continuous_def)
   675 
   676 lemma (in bounded_linear) continuous_on:
   677   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   678   using tendsto[of g] by (auto simp: continuous_on_def)
   679 
   680 lemma (in bounded_linear) tendsto_zero:
   681   "(g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> 0) F"
   682   by (drule tendsto, simp only: zero)
   683 
   684 lemma (in bounded_bilinear) tendsto:
   685   "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) \<longlongrightarrow> a ** b) F"
   686   by (simp only: tendsto_Zfun_iff prod_diff_prod
   687                  Zfun_add Zfun Zfun_left Zfun_right)
   688 
   689 lemma (in bounded_bilinear) continuous:
   690   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   691   using tendsto[of f _ F g] by (auto simp: continuous_def)
   692 
   693 lemma (in bounded_bilinear) continuous_on:
   694   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   695   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   696 
   697 lemma (in bounded_bilinear) tendsto_zero:
   698   assumes f: "(f \<longlongrightarrow> 0) F"
   699   assumes g: "(g \<longlongrightarrow> 0) F"
   700   shows "((\<lambda>x. f x ** g x) \<longlongrightarrow> 0) F"
   701   using tendsto [OF f g] by (simp add: zero_left)
   702 
   703 lemma (in bounded_bilinear) tendsto_left_zero:
   704   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) \<longlongrightarrow> 0) F"
   705   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   706 
   707 lemma (in bounded_bilinear) tendsto_right_zero:
   708   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) \<longlongrightarrow> 0) F"
   709   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   710 
   711 lemmas tendsto_of_real [tendsto_intros] =
   712   bounded_linear.tendsto [OF bounded_linear_of_real]
   713 
   714 lemmas tendsto_scaleR [tendsto_intros] =
   715   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   716 
   717 lemmas tendsto_mult [tendsto_intros] =
   718   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   719 
   720 lemma tendsto_mult_left:
   721   fixes c::"'a::real_normed_algebra"
   722   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. c * (f x)) \<longlongrightarrow> c * l) F"
   723 by (rule tendsto_mult [OF tendsto_const])
   724 
   725 lemma tendsto_mult_right:
   726   fixes c::"'a::real_normed_algebra"
   727   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. (f x) * c) \<longlongrightarrow> l * c) F"
   728 by (rule tendsto_mult [OF _ tendsto_const])
   729 
   730 lemmas continuous_of_real [continuous_intros] =
   731   bounded_linear.continuous [OF bounded_linear_of_real]
   732 
   733 lemmas continuous_scaleR [continuous_intros] =
   734   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   735 
   736 lemmas continuous_mult [continuous_intros] =
   737   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   738 
   739 lemmas continuous_on_of_real [continuous_intros] =
   740   bounded_linear.continuous_on [OF bounded_linear_of_real]
   741 
   742 lemmas continuous_on_scaleR [continuous_intros] =
   743   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   744 
   745 lemmas continuous_on_mult [continuous_intros] =
   746   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   747 
   748 lemmas tendsto_mult_zero =
   749   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   750 
   751 lemmas tendsto_mult_left_zero =
   752   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   753 
   754 lemmas tendsto_mult_right_zero =
   755   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   756 
   757 lemma tendsto_power [tendsto_intros]:
   758   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   759   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> a ^ n) F"
   760   by (induct n) (simp_all add: tendsto_mult)
   761 
   762 lemma continuous_power [continuous_intros]:
   763   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   764   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   765   unfolding continuous_def by (rule tendsto_power)
   766 
   767 lemma continuous_on_power [continuous_intros]:
   768   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   769   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   770   unfolding continuous_on_def by (auto intro: tendsto_power)
   771 
   772 lemma tendsto_setprod [tendsto_intros]:
   773   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   774   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> L i) F"
   775   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) \<longlongrightarrow> (\<Prod>i\<in>S. L i)) F"
   776 proof (cases "finite S")
   777   assume "finite S" thus ?thesis using assms
   778     by (induct, simp, simp add: tendsto_mult)
   779 qed simp
   780 
   781 lemma continuous_setprod [continuous_intros]:
   782   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   783   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   784   unfolding continuous_def by (rule tendsto_setprod)
   785 
   786 lemma continuous_on_setprod [continuous_intros]:
   787   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   788   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   789   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   790 
   791 lemma tendsto_of_real_iff:
   792   "((\<lambda>x. of_real (f x) :: 'a :: real_normed_div_algebra) \<longlongrightarrow> of_real c) F \<longleftrightarrow> (f \<longlongrightarrow> c) F"
   793   unfolding tendsto_iff by simp
   794 
   795 lemma tendsto_add_const_iff:
   796   "((\<lambda>x. c + f x :: 'a :: real_normed_vector) \<longlongrightarrow> c + d) F \<longleftrightarrow> (f \<longlongrightarrow> d) F"
   797   using tendsto_add[OF tendsto_const[of c], of f d] 
   798         tendsto_add[OF tendsto_const[of "-c"], of "\<lambda>x. c + f x" "c + d"] by auto
   799 
   800 
   801 subsubsection \<open>Inverse and division\<close>
   802 
   803 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   804   assumes f: "Zfun f F"
   805   assumes g: "Bfun g F"
   806   shows "Zfun (\<lambda>x. f x ** g x) F"
   807 proof -
   808   obtain K where K: "0 \<le> K"
   809     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   810     using nonneg_bounded by blast
   811   obtain B where B: "0 < B"
   812     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   813     using g by (rule BfunE)
   814   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   815   using norm_g proof eventually_elim
   816     case (elim x)
   817     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   818       by (rule norm_le)
   819     also have "\<dots> \<le> norm (f x) * B * K"
   820       by (intro mult_mono' order_refl norm_g norm_ge_zero
   821                 mult_nonneg_nonneg K elim)
   822     also have "\<dots> = norm (f x) * (B * K)"
   823       by (rule mult.assoc)
   824     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   825   qed
   826   with f show ?thesis
   827     by (rule Zfun_imp_Zfun)
   828 qed
   829 
   830 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   831   assumes f: "Bfun f F"
   832   assumes g: "Zfun g F"
   833   shows "Zfun (\<lambda>x. f x ** g x) F"
   834   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   835 
   836 lemma Bfun_inverse_lemma:
   837   fixes x :: "'a::real_normed_div_algebra"
   838   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   839   apply (subst nonzero_norm_inverse, clarsimp)
   840   apply (erule (1) le_imp_inverse_le)
   841   done
   842 
   843 lemma Bfun_inverse:
   844   fixes a :: "'a::real_normed_div_algebra"
   845   assumes f: "(f \<longlongrightarrow> a) F"
   846   assumes a: "a \<noteq> 0"
   847   shows "Bfun (\<lambda>x. inverse (f x)) F"
   848 proof -
   849   from a have "0 < norm a" by simp
   850   hence "\<exists>r>0. r < norm a" by (rule dense)
   851   then obtain r where r1: "0 < r" and r2: "r < norm a" by blast
   852   have "eventually (\<lambda>x. dist (f x) a < r) F"
   853     using tendstoD [OF f r1] by blast
   854   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   855   proof eventually_elim
   856     case (elim x)
   857     hence 1: "norm (f x - a) < r"
   858       by (simp add: dist_norm)
   859     hence 2: "f x \<noteq> 0" using r2 by auto
   860     hence "norm (inverse (f x)) = inverse (norm (f x))"
   861       by (rule nonzero_norm_inverse)
   862     also have "\<dots> \<le> inverse (norm a - r)"
   863     proof (rule le_imp_inverse_le)
   864       show "0 < norm a - r" using r2 by simp
   865     next
   866       have "norm a - norm (f x) \<le> norm (a - f x)"
   867         by (rule norm_triangle_ineq2)
   868       also have "\<dots> = norm (f x - a)"
   869         by (rule norm_minus_commute)
   870       also have "\<dots> < r" using 1 .
   871       finally show "norm a - r \<le> norm (f x)" by simp
   872     qed
   873     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   874   qed
   875   thus ?thesis by (rule BfunI)
   876 qed
   877 
   878 lemma tendsto_inverse [tendsto_intros]:
   879   fixes a :: "'a::real_normed_div_algebra"
   880   assumes f: "(f \<longlongrightarrow> a) F"
   881   assumes a: "a \<noteq> 0"
   882   shows "((\<lambda>x. inverse (f x)) \<longlongrightarrow> inverse a) F"
   883 proof -
   884   from a have "0 < norm a" by simp
   885   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   886     by (rule tendstoD)
   887   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   888     unfolding dist_norm by (auto elim!: eventually_mono)
   889   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   890     - (inverse (f x) * (f x - a) * inverse a)) F"
   891     by (auto elim!: eventually_mono simp: inverse_diff_inverse)
   892   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   893     by (intro Zfun_minus Zfun_mult_left
   894       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   895       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   896   ultimately show ?thesis
   897     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   898 qed
   899 
   900 lemma continuous_inverse:
   901   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   902   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   903   shows "continuous F (\<lambda>x. inverse (f x))"
   904   using assms unfolding continuous_def by (rule tendsto_inverse)
   905 
   906 lemma continuous_at_within_inverse[continuous_intros]:
   907   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   908   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   909   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   910   using assms unfolding continuous_within by (rule tendsto_inverse)
   911 
   912 lemma isCont_inverse[continuous_intros, simp]:
   913   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   914   assumes "isCont f a" and "f a \<noteq> 0"
   915   shows "isCont (\<lambda>x. inverse (f x)) a"
   916   using assms unfolding continuous_at by (rule tendsto_inverse)
   917 
   918 lemma continuous_on_inverse[continuous_intros]:
   919   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   920   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   921   shows "continuous_on s (\<lambda>x. inverse (f x))"
   922   using assms unfolding continuous_on_def by (blast intro: tendsto_inverse)
   923 
   924 lemma tendsto_divide [tendsto_intros]:
   925   fixes a b :: "'a::real_normed_field"
   926   shows "\<lbrakk>(f \<longlongrightarrow> a) F; (g \<longlongrightarrow> b) F; b \<noteq> 0\<rbrakk>
   927     \<Longrightarrow> ((\<lambda>x. f x / g x) \<longlongrightarrow> a / b) F"
   928   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   929 
   930 lemma continuous_divide:
   931   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   932   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   933   shows "continuous F (\<lambda>x. (f x) / (g x))"
   934   using assms unfolding continuous_def by (rule tendsto_divide)
   935 
   936 lemma continuous_at_within_divide[continuous_intros]:
   937   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   938   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   939   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   940   using assms unfolding continuous_within by (rule tendsto_divide)
   941 
   942 lemma isCont_divide[continuous_intros, simp]:
   943   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   944   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   945   shows "isCont (\<lambda>x. (f x) / g x) a"
   946   using assms unfolding continuous_at by (rule tendsto_divide)
   947 
   948 lemma continuous_on_divide[continuous_intros]:
   949   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   950   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   951   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   952   using assms unfolding continuous_on_def by (blast intro: tendsto_divide)
   953 
   954 lemma tendsto_sgn [tendsto_intros]:
   955   fixes l :: "'a::real_normed_vector"
   956   shows "\<lbrakk>(f \<longlongrightarrow> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) \<longlongrightarrow> sgn l) F"
   957   unfolding sgn_div_norm by (simp add: tendsto_intros)
   958 
   959 lemma continuous_sgn:
   960   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   961   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   962   shows "continuous F (\<lambda>x. sgn (f x))"
   963   using assms unfolding continuous_def by (rule tendsto_sgn)
   964 
   965 lemma continuous_at_within_sgn[continuous_intros]:
   966   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   967   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   968   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   969   using assms unfolding continuous_within by (rule tendsto_sgn)
   970 
   971 lemma isCont_sgn[continuous_intros]:
   972   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   973   assumes "isCont f a" and "f a \<noteq> 0"
   974   shows "isCont (\<lambda>x. sgn (f x)) a"
   975   using assms unfolding continuous_at by (rule tendsto_sgn)
   976 
   977 lemma continuous_on_sgn[continuous_intros]:
   978   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   979   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   980   shows "continuous_on s (\<lambda>x. sgn (f x))"
   981   using assms unfolding continuous_on_def by (blast intro: tendsto_sgn)
   982 
   983 lemma filterlim_at_infinity:
   984   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
   985   assumes "0 \<le> c"
   986   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   987   unfolding filterlim_iff eventually_at_infinity
   988 proof safe
   989   fix P :: "'a \<Rightarrow> bool" and b
   990   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   991     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   992   have "max b (c + 1) > c" by auto
   993   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   994     by auto
   995   then show "eventually (\<lambda>x. P (f x)) F"
   996   proof eventually_elim
   997     fix x assume "max b (c + 1) \<le> norm (f x)"
   998     with P show "P (f x)" by auto
   999   qed
  1000 qed force
  1001 
  1002 lemma not_tendsto_and_filterlim_at_infinity:
  1003   assumes "F \<noteq> bot"
  1004   assumes "(f \<longlongrightarrow> (c :: 'a :: real_normed_vector)) F" 
  1005   assumes "filterlim f at_infinity F"
  1006   shows   False
  1007 proof -
  1008   from tendstoD[OF assms(2), of "1/2"] 
  1009     have "eventually (\<lambda>x. dist (f x) c < 1/2) F" by simp
  1010   moreover from filterlim_at_infinity[of "norm c" f F] assms(3)
  1011     have "eventually (\<lambda>x. norm (f x) \<ge> norm c + 1) F" by simp
  1012   ultimately have "eventually (\<lambda>x. False) F"
  1013   proof eventually_elim
  1014     fix x assume A: "dist (f x) c < 1/2" and B: "norm (f x) \<ge> norm c + 1"
  1015     note B
  1016     also have "norm (f x) = dist (f x) 0" by (simp add: norm_conv_dist)
  1017     also have "... \<le> dist (f x) c + dist c 0" by (rule dist_triangle)
  1018     also note A
  1019     finally show False by (simp add: norm_conv_dist)
  1020   qed
  1021   with assms show False by simp
  1022 qed
  1023 
  1024 lemma filterlim_at_infinity_imp_not_convergent:
  1025   assumes "filterlim f at_infinity sequentially"
  1026   shows   "\<not>convergent f"
  1027   by (rule notI, rule not_tendsto_and_filterlim_at_infinity[OF _ _ assms])
  1028      (simp_all add: convergent_LIMSEQ_iff)
  1029 
  1030 lemma filterlim_at_infinity_imp_eventually_ne:
  1031   assumes "filterlim f at_infinity F"
  1032   shows   "eventually (\<lambda>z. f z \<noteq> c) F"
  1033 proof -
  1034   have "norm c + 1 > 0" by (intro add_nonneg_pos) simp_all
  1035   with filterlim_at_infinity[OF order.refl, of f F] assms
  1036     have "eventually (\<lambda>z. norm (f z) \<ge> norm c + 1) F" by blast
  1037   thus ?thesis by eventually_elim auto
  1038 qed
  1039 
  1040 lemma tendsto_of_nat [tendsto_intros]: 
  1041   "filterlim (of_nat :: nat \<Rightarrow> 'a :: real_normed_algebra_1) at_infinity sequentially"
  1042 proof (subst filterlim_at_infinity[OF order.refl], intro allI impI)
  1043   fix r :: real assume r: "r > 0"
  1044   def n \<equiv> "nat \<lceil>r\<rceil>"
  1045   from r have n: "\<forall>m\<ge>n. of_nat m \<ge> r" unfolding n_def by linarith
  1046   from eventually_ge_at_top[of n] show "eventually (\<lambda>m. norm (of_nat m :: 'a) \<ge> r) sequentially"
  1047     by eventually_elim (insert n, simp_all)
  1048 qed
  1049 
  1050 
  1051 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
  1052 
  1053 text \<open>
  1054 
  1055 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
  1056 @{term "at_right x"} and also @{term "at_right 0"}.
  1057 
  1058 \<close>
  1059 
  1060 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
  1061 
  1062 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
  1063   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
  1064      (auto intro!: tendsto_eq_intros filterlim_ident)
  1065 
  1066 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
  1067   by (rule filtermap_fun_inverse[where g=uminus])
  1068      (auto intro!: tendsto_eq_intros filterlim_ident)
  1069 
  1070 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
  1071   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1072 
  1073 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
  1074   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1075 
  1076 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
  1077   using filtermap_at_right_shift[of "-a" 0] by simp
  1078 
  1079 lemma filterlim_at_right_to_0:
  1080   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
  1081   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
  1082 
  1083 lemma eventually_at_right_to_0:
  1084   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
  1085   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
  1086 
  1087 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
  1088   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1089 
  1090 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
  1091   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1092 
  1093 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
  1094   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1095 
  1096 lemma filterlim_at_left_to_right:
  1097   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
  1098   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
  1099 
  1100 lemma eventually_at_left_to_right:
  1101   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
  1102   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
  1103 
  1104 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1105   unfolding filterlim_at_top eventually_at_bot_dense
  1106   by (metis leI minus_less_iff order_less_asym)
  1107 
  1108 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1109   unfolding filterlim_at_bot eventually_at_top_dense
  1110   by (metis leI less_minus_iff order_less_asym)
  1111 
  1112 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
  1113   by (rule filtermap_fun_inverse[symmetric, of uminus])
  1114      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
  1115 
  1116 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
  1117   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
  1118 
  1119 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
  1120   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
  1121 
  1122 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
  1123   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
  1124 
  1125 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1126   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1127   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1128   by auto
  1129 
  1130 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1131   unfolding filterlim_uminus_at_top by simp
  1132 
  1133 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1134   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1135 proof safe
  1136   fix Z :: real assume [arith]: "0 < Z"
  1137   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1138     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1139   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1140     by (auto elim!: eventually_mono simp: inverse_eq_divide field_simps)
  1141 qed
  1142 
  1143 lemma tendsto_inverse_0:
  1144   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
  1145   shows "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1146   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1147 proof safe
  1148   fix r :: real assume "0 < r"
  1149   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1150   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1151     fix x :: 'a
  1152     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
  1153     also assume *: "inverse (r / 2) \<le> norm x"
  1154     finally show "norm (inverse x) < r"
  1155       using * \<open>0 < r\<close> by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1156   qed
  1157 qed
  1158 
  1159 lemma tendsto_add_filterlim_at_infinity:
  1160   assumes "(f \<longlongrightarrow> (c :: 'b :: real_normed_vector)) (F :: 'a filter)"
  1161   assumes "filterlim g at_infinity F"
  1162   shows   "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1163 proof (subst filterlim_at_infinity[OF order_refl], safe)
  1164   fix r :: real assume r: "r > 0"
  1165   from assms(1) have "((\<lambda>x. norm (f x)) \<longlongrightarrow> norm c) F" by (rule tendsto_norm)
  1166   hence "eventually (\<lambda>x. norm (f x) < norm c + 1) F" by (rule order_tendstoD) simp_all
  1167   moreover from r have "r + norm c + 1 > 0" by (intro add_pos_nonneg) simp_all 
  1168   with assms(2) have "eventually (\<lambda>x. norm (g x) \<ge> r + norm c + 1) F"
  1169     unfolding filterlim_at_infinity[OF order_refl] by (elim allE[of _ "r + norm c + 1"]) simp_all
  1170   ultimately show "eventually (\<lambda>x. norm (f x + g x) \<ge> r) F"
  1171   proof eventually_elim
  1172     fix x :: 'a assume A: "norm (f x) < norm c + 1" and B: "r + norm c + 1 \<le> norm (g x)"
  1173     from A B have "r \<le> norm (g x) - norm (f x)" by simp
  1174     also have "norm (g x) - norm (f x) \<le> norm (g x + f x)" by (rule norm_diff_ineq)
  1175     finally show "r \<le> norm (f x + g x)" by (simp add: add_ac)
  1176   qed
  1177 qed
  1178 
  1179 lemma tendsto_add_filterlim_at_infinity':
  1180   assumes "filterlim f at_infinity F"
  1181   assumes "(g \<longlongrightarrow> (c :: 'b :: real_normed_vector)) (F :: 'a filter)"
  1182   shows   "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1183   by (subst add.commute) (rule tendsto_add_filterlim_at_infinity assms)+
  1184 
  1185 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1186   unfolding filterlim_at
  1187   by (auto simp: eventually_at_top_dense)
  1188      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1189 
  1190 lemma filterlim_inverse_at_top:
  1191   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1192   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1193      (simp add: filterlim_def eventually_filtermap eventually_mono at_within_def le_principal)
  1194 
  1195 lemma filterlim_inverse_at_bot_neg:
  1196   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1197   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1198 
  1199 lemma filterlim_inverse_at_bot:
  1200   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1201   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1202   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1203 
  1204 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1205   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1206      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1207 
  1208 lemma eventually_at_right_to_top:
  1209   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1210   unfolding at_right_to_top eventually_filtermap ..
  1211 
  1212 lemma filterlim_at_right_to_top:
  1213   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1214   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1215 
  1216 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1217   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1218 
  1219 lemma eventually_at_top_to_right:
  1220   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1221   unfolding at_top_to_right eventually_filtermap ..
  1222 
  1223 lemma filterlim_at_top_to_right:
  1224   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1225   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1226 
  1227 lemma filterlim_inverse_at_infinity:
  1228   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1229   shows "filterlim inverse at_infinity (at (0::'a))"
  1230   unfolding filterlim_at_infinity[OF order_refl]
  1231 proof safe
  1232   fix r :: real assume "0 < r"
  1233   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1234     unfolding eventually_at norm_inverse
  1235     by (intro exI[of _ "inverse r"])
  1236        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1237 qed
  1238 
  1239 lemma filterlim_inverse_at_iff:
  1240   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
  1241   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1242   unfolding filterlim_def filtermap_filtermap[symmetric]
  1243 proof
  1244   assume "filtermap g F \<le> at_infinity"
  1245   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1246     by (rule filtermap_mono)
  1247   also have "\<dots> \<le> at 0"
  1248     using tendsto_inverse_0[where 'a='b]
  1249     by (auto intro!: exI[of _ 1]
  1250              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1251   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1252 next
  1253   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1254   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1255     by (rule filtermap_mono)
  1256   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1257     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1258 qed
  1259 
  1260 lemma tendsto_mult_filterlim_at_infinity:
  1261   assumes "F \<noteq> bot" "(f \<longlongrightarrow> (c :: 'a :: real_normed_field)) F" "c \<noteq> 0"
  1262   assumes "filterlim g at_infinity F"
  1263   shows   "filterlim (\<lambda>x. f x * g x) at_infinity F"
  1264 proof -
  1265   have "((\<lambda>x. inverse (f x) * inverse (g x)) \<longlongrightarrow> inverse c * 0) F"
  1266     by (intro tendsto_mult tendsto_inverse assms filterlim_compose[OF tendsto_inverse_0])
  1267   hence "filterlim (\<lambda>x. inverse (f x) * inverse (g x)) (at (inverse c * 0)) F"
  1268     unfolding filterlim_at using assms
  1269     by (auto intro: filterlim_at_infinity_imp_eventually_ne tendsto_imp_eventually_ne eventually_conj)
  1270   thus ?thesis by (subst filterlim_inverse_at_iff[symmetric]) simp_all
  1271 qed
  1272 
  1273 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) \<longlongrightarrow> 0) F"
  1274  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1275 
  1276 lemma mult_nat_left_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. c * x :: nat) at_top sequentially"
  1277   by (rule filterlim_subseq) (auto simp: subseq_def)
  1278 
  1279 lemma mult_nat_right_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. x * c :: nat) at_top sequentially"
  1280   by (rule filterlim_subseq) (auto simp: subseq_def)
  1281 
  1282 lemma at_to_infinity:
  1283   fixes x :: "'a :: {real_normed_field,field}"
  1284   shows "(at (0::'a)) = filtermap inverse at_infinity"
  1285 proof (rule antisym)
  1286   have "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1287     by (fact tendsto_inverse_0)
  1288   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1289     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1290     apply (rule_tac x="1" in exI, auto)
  1291     done
  1292 next
  1293   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1294     using filterlim_inverse_at_infinity unfolding filterlim_def
  1295     by (rule filtermap_mono)
  1296   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1297     by (simp add: filtermap_ident filtermap_filtermap)
  1298 qed
  1299 
  1300 lemma lim_at_infinity_0:
  1301   fixes l :: "'a :: {real_normed_field,field}"
  1302   shows "(f \<longlongrightarrow> l) at_infinity \<longleftrightarrow> ((f o inverse) \<longlongrightarrow> l) (at (0::'a))"
  1303 by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1304 
  1305 lemma lim_zero_infinity:
  1306   fixes l :: "'a :: {real_normed_field,field}"
  1307   shows "((\<lambda>x. f(1 / x)) \<longlongrightarrow> l) (at (0::'a)) \<Longrightarrow> (f \<longlongrightarrow> l) at_infinity"
  1308 by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1309 
  1310 
  1311 text \<open>
  1312 
  1313 We only show rules for multiplication and addition when the functions are either against a real
  1314 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1315 
  1316 \<close>
  1317 
  1318 lemma filterlim_tendsto_pos_mult_at_top:
  1319   assumes f: "(f \<longlongrightarrow> c) F" and c: "0 < c"
  1320   assumes g: "LIM x F. g x :> at_top"
  1321   shows "LIM x F. (f x * g x :: real) :> at_top"
  1322   unfolding filterlim_at_top_gt[where c=0]
  1323 proof safe
  1324   fix Z :: real assume "0 < Z"
  1325   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1326     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_mono
  1327              simp: dist_real_def abs_real_def split: split_if_asm)
  1328   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1329     unfolding filterlim_at_top by auto
  1330   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1331   proof eventually_elim
  1332     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1333     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1334       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1335     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1336        by simp
  1337   qed
  1338 qed
  1339 
  1340 lemma filterlim_at_top_mult_at_top:
  1341   assumes f: "LIM x F. f x :> at_top"
  1342   assumes g: "LIM x F. g x :> at_top"
  1343   shows "LIM x F. (f x * g x :: real) :> at_top"
  1344   unfolding filterlim_at_top_gt[where c=0]
  1345 proof safe
  1346   fix Z :: real assume "0 < Z"
  1347   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1348     unfolding filterlim_at_top by auto
  1349   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1350     unfolding filterlim_at_top by auto
  1351   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1352   proof eventually_elim
  1353     fix x assume "1 \<le> f x" "Z \<le> g x"
  1354     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1355       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1356     then show "Z \<le> f x * g x"
  1357        by simp
  1358   qed
  1359 qed
  1360 
  1361 lemma filterlim_tendsto_pos_mult_at_bot:
  1362   assumes "(f \<longlongrightarrow> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1363   shows "LIM x F. f x * g x :> at_bot"
  1364   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1365   unfolding filterlim_uminus_at_bot by simp
  1366 
  1367 lemma filterlim_tendsto_neg_mult_at_bot:
  1368   assumes c: "(f \<longlongrightarrow> c) F" "(c::real) < 0" and g: "filterlim g at_top F"
  1369   shows "LIM x F. f x * g x :> at_bot"
  1370   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1371   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1372 
  1373 lemma filterlim_pow_at_top:
  1374   fixes f :: "real \<Rightarrow> real"
  1375   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1376   shows "LIM x F. (f x)^n :: real :> at_top"
  1377 using \<open>0 < n\<close> proof (induct n)
  1378   case (Suc n) with f show ?case
  1379     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1380 qed simp
  1381 
  1382 lemma filterlim_pow_at_bot_even:
  1383   fixes f :: "real \<Rightarrow> real"
  1384   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1385   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1386 
  1387 lemma filterlim_pow_at_bot_odd:
  1388   fixes f :: "real \<Rightarrow> real"
  1389   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1390   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1391 
  1392 lemma filterlim_tendsto_add_at_top:
  1393   assumes f: "(f \<longlongrightarrow> c) F"
  1394   assumes g: "LIM x F. g x :> at_top"
  1395   shows "LIM x F. (f x + g x :: real) :> at_top"
  1396   unfolding filterlim_at_top_gt[where c=0]
  1397 proof safe
  1398   fix Z :: real assume "0 < Z"
  1399   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1400     by (auto dest!: tendstoD[where e=1] elim!: eventually_mono simp: dist_real_def)
  1401   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1402     unfolding filterlim_at_top by auto
  1403   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1404     by eventually_elim simp
  1405 qed
  1406 
  1407 lemma LIM_at_top_divide:
  1408   fixes f g :: "'a \<Rightarrow> real"
  1409   assumes f: "(f \<longlongrightarrow> a) F" "0 < a"
  1410   assumes g: "(g \<longlongrightarrow> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1411   shows "LIM x F. f x / g x :> at_top"
  1412   unfolding divide_inverse
  1413   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1414 
  1415 lemma filterlim_at_top_add_at_top:
  1416   assumes f: "LIM x F. f x :> at_top"
  1417   assumes g: "LIM x F. g x :> at_top"
  1418   shows "LIM x F. (f x + g x :: real) :> at_top"
  1419   unfolding filterlim_at_top_gt[where c=0]
  1420 proof safe
  1421   fix Z :: real assume "0 < Z"
  1422   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1423     unfolding filterlim_at_top by auto
  1424   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1425     unfolding filterlim_at_top by auto
  1426   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1427     by eventually_elim simp
  1428 qed
  1429 
  1430 lemma tendsto_divide_0:
  1431   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1432   assumes f: "(f \<longlongrightarrow> c) F"
  1433   assumes g: "LIM x F. g x :> at_infinity"
  1434   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1435   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1436 
  1437 lemma linear_plus_1_le_power:
  1438   fixes x :: real
  1439   assumes x: "0 \<le> x"
  1440   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1441 proof (induct n)
  1442   case (Suc n)
  1443   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1444     by (simp add: field_simps of_nat_Suc x)
  1445   also have "\<dots> \<le> (x + 1)^Suc n"
  1446     using Suc x by (simp add: mult_left_mono)
  1447   finally show ?case .
  1448 qed simp
  1449 
  1450 lemma filterlim_realpow_sequentially_gt1:
  1451   fixes x :: "'a :: real_normed_div_algebra"
  1452   assumes x[arith]: "1 < norm x"
  1453   shows "LIM n sequentially. x ^ n :> at_infinity"
  1454 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1455   fix y :: real assume "0 < y"
  1456   have "0 < norm x - 1" by simp
  1457   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1458   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1459   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1460   also have "\<dots> = norm x ^ N" by simp
  1461   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1462     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1463   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1464     unfolding eventually_sequentially
  1465     by (auto simp: norm_power)
  1466 qed simp
  1467 
  1468 
  1469 subsection \<open>Limits of Sequences\<close>
  1470 
  1471 lemma [trans]: "X=Y ==> Y \<longlonglongrightarrow> z ==> X \<longlonglongrightarrow> z"
  1472   by simp
  1473 
  1474 lemma LIMSEQ_iff:
  1475   fixes L :: "'a::real_normed_vector"
  1476   shows "(X \<longlonglongrightarrow> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1477 unfolding lim_sequentially dist_norm ..
  1478 
  1479 lemma LIMSEQ_I:
  1480   fixes L :: "'a::real_normed_vector"
  1481   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1482 by (simp add: LIMSEQ_iff)
  1483 
  1484 lemma LIMSEQ_D:
  1485   fixes L :: "'a::real_normed_vector"
  1486   shows "\<lbrakk>X \<longlonglongrightarrow> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1487 by (simp add: LIMSEQ_iff)
  1488 
  1489 lemma LIMSEQ_linear: "\<lbrakk> X \<longlonglongrightarrow> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) \<longlonglongrightarrow> x"
  1490   unfolding tendsto_def eventually_sequentially
  1491   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1492 
  1493 lemma Bseq_inverse_lemma:
  1494   fixes x :: "'a::real_normed_div_algebra"
  1495   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1496 apply (subst nonzero_norm_inverse, clarsimp)
  1497 apply (erule (1) le_imp_inverse_le)
  1498 done
  1499 
  1500 lemma Bseq_inverse:
  1501   fixes a :: "'a::real_normed_div_algebra"
  1502   shows "\<lbrakk>X \<longlonglongrightarrow> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1503   by (rule Bfun_inverse)
  1504 
  1505 text\<open>Transformation of limit.\<close>
  1506 
  1507 lemma eventually_at2:
  1508   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
  1509   unfolding eventually_at dist_nz by auto
  1510 
  1511 lemma Lim_transform:
  1512   fixes a b :: "'a::real_normed_vector"
  1513   shows "\<lbrakk>(g \<longlongrightarrow> a) F; ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> (f \<longlongrightarrow> a) F"
  1514   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1515 
  1516 lemma Lim_transform2:
  1517   fixes a b :: "'a::real_normed_vector"
  1518   shows "\<lbrakk>(f \<longlongrightarrow> a) F; ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F\<rbrakk> \<Longrightarrow> (g \<longlongrightarrow> a) F"
  1519   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1520 
  1521 lemma Lim_transform_eventually:
  1522   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> (g \<longlongrightarrow> l) net"
  1523   apply (rule topological_tendstoI)
  1524   apply (drule (2) topological_tendstoD)
  1525   apply (erule (1) eventually_elim2, simp)
  1526   done
  1527 
  1528 lemma Lim_transform_within:
  1529   assumes "0 < d"
  1530     and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1531     and "(f \<longlongrightarrow> l) (at x within S)"
  1532   shows "(g \<longlongrightarrow> l) (at x within S)"
  1533 proof (rule Lim_transform_eventually)
  1534   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1535     using assms(1,2) by (auto simp: dist_nz eventually_at)
  1536   show "(f \<longlongrightarrow> l) (at x within S)" by fact
  1537 qed
  1538 
  1539 lemma Lim_transform_at:
  1540   assumes "0 < d"
  1541     and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1542     and "(f \<longlongrightarrow> l) (at x)"
  1543   shows "(g \<longlongrightarrow> l) (at x)"
  1544   using _ assms(3)
  1545 proof (rule Lim_transform_eventually)
  1546   show "eventually (\<lambda>x. f x = g x) (at x)"
  1547     unfolding eventually_at2
  1548     using assms(1,2) by auto
  1549 qed
  1550 
  1551 text\<open>Common case assuming being away from some crucial point like 0.\<close>
  1552 
  1553 lemma Lim_transform_away_within:
  1554   fixes a b :: "'a::t1_space"
  1555   assumes "a \<noteq> b"
  1556     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1557     and "(f \<longlongrightarrow> l) (at a within S)"
  1558   shows "(g \<longlongrightarrow> l) (at a within S)"
  1559 proof (rule Lim_transform_eventually)
  1560   show "(f \<longlongrightarrow> l) (at a within S)" by fact
  1561   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1562     unfolding eventually_at_topological
  1563     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1564 qed
  1565 
  1566 lemma Lim_transform_away_at:
  1567   fixes a b :: "'a::t1_space"
  1568   assumes ab: "a\<noteq>b"
  1569     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1570     and fl: "(f \<longlongrightarrow> l) (at a)"
  1571   shows "(g \<longlongrightarrow> l) (at a)"
  1572   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1573 
  1574 text\<open>Alternatively, within an open set.\<close>
  1575 
  1576 lemma Lim_transform_within_open:
  1577   assumes "open S" and "a \<in> S"
  1578     and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1579     and "(f \<longlongrightarrow> l) (at a)"
  1580   shows "(g \<longlongrightarrow> l) (at a)"
  1581 proof (rule Lim_transform_eventually)
  1582   show "eventually (\<lambda>x. f x = g x) (at a)"
  1583     unfolding eventually_at_topological
  1584     using assms(1,2,3) by auto
  1585   show "(f \<longlongrightarrow> l) (at a)" by fact
  1586 qed
  1587 
  1588 text\<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1589 
  1590 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1591 
  1592 lemma Lim_cong_within(*[cong add]*):
  1593   assumes "a = b"
  1594     and "x = y"
  1595     and "S = T"
  1596     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1597   shows "(f \<longlongrightarrow> x) (at a within S) \<longleftrightarrow> (g \<longlongrightarrow> y) (at b within T)"
  1598   unfolding tendsto_def eventually_at_topological
  1599   using assms by simp
  1600 
  1601 lemma Lim_cong_at(*[cong add]*):
  1602   assumes "a = b" "x = y"
  1603     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1604   shows "((\<lambda>x. f x) \<longlongrightarrow> x) (at a) \<longleftrightarrow> ((g \<longlongrightarrow> y) (at a))"
  1605   unfolding tendsto_def eventually_at_topological
  1606   using assms by simp
  1607 text\<open>An unbounded sequence's inverse tends to 0\<close>
  1608 
  1609 lemma LIMSEQ_inverse_zero:
  1610   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) \<longlonglongrightarrow> 0"
  1611   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1612   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1613   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1614   done
  1615 
  1616 text\<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity\<close>
  1617 
  1618 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) \<longlonglongrightarrow> 0"
  1619   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1620             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1621 
  1622 text\<open>The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1623 infinity is now easily proved\<close>
  1624 
  1625 lemma LIMSEQ_inverse_real_of_nat_add:
  1626      "(%n. r + inverse(real(Suc n))) \<longlonglongrightarrow> r"
  1627   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1628 
  1629 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1630      "(%n. r + -inverse(real(Suc n))) \<longlonglongrightarrow> r"
  1631   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1632   by auto
  1633 
  1634 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1635      "(%n. r*( 1 + -inverse(real(Suc n)))) \<longlonglongrightarrow> r"
  1636   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1637   by auto
  1638 
  1639 lemma lim_1_over_n: "((\<lambda>n. 1 / of_nat n) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1640 proof (subst lim_sequentially, intro allI impI exI)
  1641   fix e :: real assume e: "e > 0"
  1642   fix n :: nat assume n: "n \<ge> nat \<lceil>inverse e + 1\<rceil>"
  1643   have "inverse e < of_nat (nat \<lceil>inverse e + 1\<rceil>)" by linarith
  1644   also note n
  1645   finally show "dist (1 / of_nat n :: 'a) 0 < e" using e 
  1646     by (simp add: divide_simps mult.commute norm_conv_dist[symmetric] norm_divide)
  1647 qed
  1648 
  1649 lemma lim_inverse_n: "((\<lambda>n. inverse(of_nat n)) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1650   using lim_1_over_n by (simp add: inverse_eq_divide)
  1651 
  1652 lemma LIMSEQ_Suc_n_over_n: "(\<lambda>n. of_nat (Suc n) / of_nat n :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1653 proof (rule Lim_transform_eventually)
  1654   show "eventually (\<lambda>n. 1 + inverse (of_nat n :: 'a) = of_nat (Suc n) / of_nat n) sequentially"
  1655     using eventually_gt_at_top[of "0::nat"] by eventually_elim (simp add: field_simps)
  1656   have "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1 + 0"
  1657     by (intro tendsto_add tendsto_const lim_inverse_n)
  1658   thus "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1" by simp
  1659 qed
  1660 
  1661 lemma LIMSEQ_n_over_Suc_n: "(\<lambda>n. of_nat n / of_nat (Suc n) :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1662 proof (rule Lim_transform_eventually)
  1663   show "eventually (\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a) = 
  1664                         of_nat n / of_nat (Suc n)) sequentially"
  1665     using eventually_gt_at_top[of "0::nat"] 
  1666     by eventually_elim (simp add: field_simps del: of_nat_Suc)
  1667   have "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> inverse 1"
  1668     by (intro tendsto_inverse LIMSEQ_Suc_n_over_n) simp_all
  1669   thus "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> 1" by simp
  1670 qed
  1671 
  1672 subsection \<open>Convergence on sequences\<close>
  1673 
  1674 lemma convergent_cong:
  1675   assumes "eventually (\<lambda>x. f x = g x) sequentially"
  1676   shows   "convergent f \<longleftrightarrow> convergent g"
  1677   unfolding convergent_def by (subst filterlim_cong[OF refl refl assms]) (rule refl)
  1678 
  1679 lemma convergent_Suc_iff: "convergent (\<lambda>n. f (Suc n)) \<longleftrightarrow> convergent f"
  1680   by (auto simp: convergent_def LIMSEQ_Suc_iff)
  1681 
  1682 lemma convergent_ignore_initial_segment: "convergent (\<lambda>n. f (n + m)) = convergent f"
  1683 proof (induction m arbitrary: f)
  1684   case (Suc m)
  1685   have "convergent (\<lambda>n. f (n + Suc m)) \<longleftrightarrow> convergent (\<lambda>n. f (Suc n + m))" by simp
  1686   also have "\<dots> \<longleftrightarrow> convergent (\<lambda>n. f (n + m))" by (rule convergent_Suc_iff)
  1687   also have "\<dots> \<longleftrightarrow> convergent f" by (rule Suc)
  1688   finally show ?case .
  1689 qed simp_all
  1690 
  1691 lemma convergent_add:
  1692   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1693   assumes "convergent (\<lambda>n. X n)"
  1694   assumes "convergent (\<lambda>n. Y n)"
  1695   shows "convergent (\<lambda>n. X n + Y n)"
  1696   using assms unfolding convergent_def by (blast intro: tendsto_add)
  1697 
  1698 lemma convergent_setsum:
  1699   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1700   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1701   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1702 proof (cases "finite A")
  1703   case True from this and assms show ?thesis
  1704     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1705 qed (simp add: convergent_const)
  1706 
  1707 lemma (in bounded_linear) convergent:
  1708   assumes "convergent (\<lambda>n. X n)"
  1709   shows "convergent (\<lambda>n. f (X n))"
  1710   using assms unfolding convergent_def by (blast intro: tendsto)
  1711 
  1712 lemma (in bounded_bilinear) convergent:
  1713   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1714   shows "convergent (\<lambda>n. X n ** Y n)"
  1715   using assms unfolding convergent_def by (blast intro: tendsto)
  1716 
  1717 lemma convergent_minus_iff:
  1718   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1719   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1720 apply (simp add: convergent_def)
  1721 apply (auto dest: tendsto_minus)
  1722 apply (drule tendsto_minus, auto)
  1723 done
  1724 
  1725 lemma convergent_diff:
  1726   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1727   assumes "convergent (\<lambda>n. X n)"
  1728   assumes "convergent (\<lambda>n. Y n)"
  1729   shows "convergent (\<lambda>n. X n - Y n)"
  1730   using assms unfolding convergent_def by (blast intro: tendsto_diff)
  1731 
  1732 lemma convergent_norm:
  1733   assumes "convergent f"
  1734   shows   "convergent (\<lambda>n. norm (f n))"
  1735 proof -
  1736   from assms have "f \<longlonglongrightarrow> lim f" by (simp add: convergent_LIMSEQ_iff)
  1737   hence "(\<lambda>n. norm (f n)) \<longlonglongrightarrow> norm (lim f)" by (rule tendsto_norm)
  1738   thus ?thesis by (auto simp: convergent_def)
  1739 qed
  1740 
  1741 lemma convergent_of_real: 
  1742   "convergent f \<Longrightarrow> convergent (\<lambda>n. of_real (f n) :: 'a :: real_normed_algebra_1)"
  1743   unfolding convergent_def by (blast intro!: tendsto_of_real)
  1744 
  1745 lemma convergent_add_const_iff: 
  1746   "convergent (\<lambda>n. c + f n :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1747 proof
  1748   assume "convergent (\<lambda>n. c + f n)"
  1749   from convergent_diff[OF this convergent_const[of c]] show "convergent f" by simp
  1750 next
  1751   assume "convergent f"
  1752   from convergent_add[OF convergent_const[of c] this] show "convergent (\<lambda>n. c + f n)" by simp
  1753 qed
  1754 
  1755 lemma convergent_add_const_right_iff: 
  1756   "convergent (\<lambda>n. f n + c :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1757   using convergent_add_const_iff[of c f] by (simp add: add_ac)
  1758 
  1759 lemma convergent_diff_const_right_iff: 
  1760   "convergent (\<lambda>n. f n - c :: 'a :: real_normed_vector) \<longleftrightarrow> convergent f"
  1761   using convergent_add_const_right_iff[of f "-c"] by (simp add: add_ac)
  1762 
  1763 lemma convergent_mult:
  1764   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
  1765   assumes "convergent (\<lambda>n. X n)"
  1766   assumes "convergent (\<lambda>n. Y n)"
  1767   shows "convergent (\<lambda>n. X n * Y n)"
  1768   using assms unfolding convergent_def by (blast intro: tendsto_mult)
  1769 
  1770 lemma convergent_mult_const_iff:
  1771   assumes "c \<noteq> 0"
  1772   shows   "convergent (\<lambda>n. c * f n :: 'a :: real_normed_field) \<longleftrightarrow> convergent f"
  1773 proof
  1774   assume "convergent (\<lambda>n. c * f n)"
  1775   from assms convergent_mult[OF this convergent_const[of "inverse c"]] 
  1776     show "convergent f" by (simp add: field_simps)
  1777 next
  1778   assume "convergent f"
  1779   from convergent_mult[OF convergent_const[of c] this] show "convergent (\<lambda>n. c * f n)" by simp
  1780 qed
  1781 
  1782 lemma convergent_mult_const_right_iff:
  1783   assumes "c \<noteq> 0"
  1784   shows   "convergent (\<lambda>n. (f n :: 'a :: real_normed_field) * c) \<longleftrightarrow> convergent f"
  1785   using convergent_mult_const_iff[OF assms, of f] by (simp add: mult_ac)
  1786 
  1787 lemma convergent_imp_Bseq: "convergent f \<Longrightarrow> Bseq f"
  1788   by (simp add: Cauchy_Bseq convergent_Cauchy)
  1789 
  1790 
  1791 text \<open>A monotone sequence converges to its least upper bound.\<close>
  1792 
  1793 lemma LIMSEQ_incseq_SUP:
  1794   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1795   assumes u: "bdd_above (range X)"
  1796   assumes X: "incseq X"
  1797   shows "X \<longlonglongrightarrow> (SUP i. X i)"
  1798   by (rule order_tendstoI)
  1799      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1800 
  1801 lemma LIMSEQ_decseq_INF:
  1802   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1803   assumes u: "bdd_below (range X)"
  1804   assumes X: "decseq X"
  1805   shows "X \<longlonglongrightarrow> (INF i. X i)"
  1806   by (rule order_tendstoI)
  1807      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1808 
  1809 text\<open>Main monotonicity theorem\<close>
  1810 
  1811 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1812   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1813 
  1814 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1815   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1816 
  1817 lemma monoseq_imp_convergent_iff_Bseq: "monoseq (f :: nat \<Rightarrow> real) \<Longrightarrow> convergent f \<longleftrightarrow> Bseq f"
  1818   using Bseq_monoseq_convergent[of f] convergent_imp_Bseq[of f] by blast
  1819 
  1820 lemma Bseq_monoseq_convergent'_inc:
  1821   "Bseq (\<lambda>n. f (n + M) :: real) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<le> f n) \<Longrightarrow> convergent f"
  1822   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  1823      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  1824 
  1825 lemma Bseq_monoseq_convergent'_dec:
  1826   "Bseq (\<lambda>n. f (n + M) :: real) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<ge> f n) \<Longrightarrow> convergent f"
  1827   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  1828      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  1829 
  1830 lemma Cauchy_iff:
  1831   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1832   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1833   unfolding Cauchy_def dist_norm ..
  1834 
  1835 lemma CauchyI:
  1836   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1837   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1838 by (simp add: Cauchy_iff)
  1839 
  1840 lemma CauchyD:
  1841   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1842   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1843 by (simp add: Cauchy_iff)
  1844 
  1845 lemma incseq_convergent:
  1846   fixes X :: "nat \<Rightarrow> real"
  1847   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1848   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. X i \<le> L"
  1849 proof atomize_elim
  1850   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  1851   obtain L where "X \<longlonglongrightarrow> L"
  1852     by (auto simp: convergent_def monoseq_def incseq_def)
  1853   with \<open>incseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. X i \<le> L)"
  1854     by (auto intro!: exI[of _ L] incseq_le)
  1855 qed
  1856 
  1857 lemma decseq_convergent:
  1858   fixes X :: "nat \<Rightarrow> real"
  1859   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1860   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. L \<le> X i"
  1861 proof atomize_elim
  1862   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  1863   obtain L where "X \<longlonglongrightarrow> L"
  1864     by (auto simp: convergent_def monoseq_def decseq_def)
  1865   with \<open>decseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. L \<le> X i)"
  1866     by (auto intro!: exI[of _ L] decseq_le)
  1867 qed
  1868 
  1869 subsubsection \<open>Cauchy Sequences are Bounded\<close>
  1870 
  1871 text\<open>A Cauchy sequence is bounded -- this is the standard
  1872   proof mechanization rather than the nonstandard proof\<close>
  1873 
  1874 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1875           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1876 apply (clarify, drule spec, drule (1) mp)
  1877 apply (simp only: norm_minus_commute)
  1878 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1879 apply simp
  1880 done
  1881 
  1882 subsection \<open>Power Sequences\<close>
  1883 
  1884 text\<open>The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1885 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1886   also fact that bounded and monotonic sequence converges.\<close>
  1887 
  1888 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1889 apply (simp add: Bseq_def)
  1890 apply (rule_tac x = 1 in exI)
  1891 apply (simp add: power_abs)
  1892 apply (auto dest: power_mono)
  1893 done
  1894 
  1895 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1896 apply (clarify intro!: mono_SucI2)
  1897 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1898 done
  1899 
  1900 lemma convergent_realpow:
  1901   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1902 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1903 
  1904 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) \<longlonglongrightarrow> 0"
  1905   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1906 
  1907 lemma LIMSEQ_realpow_zero:
  1908   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  1909 proof cases
  1910   assume "0 \<le> x" and "x \<noteq> 0"
  1911   hence x0: "0 < x" by simp
  1912   assume x1: "x < 1"
  1913   from x0 x1 have "1 < inverse x"
  1914     by (rule one_less_inverse)
  1915   hence "(\<lambda>n. inverse (inverse x ^ n)) \<longlonglongrightarrow> 0"
  1916     by (rule LIMSEQ_inverse_realpow_zero)
  1917   thus ?thesis by (simp add: power_inverse)
  1918 qed (rule LIMSEQ_imp_Suc, simp)
  1919 
  1920 lemma LIMSEQ_power_zero:
  1921   fixes x :: "'a::{real_normed_algebra_1}"
  1922   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  1923 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1924 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1925 apply (simp add: power_abs norm_power_ineq)
  1926 done
  1927 
  1928 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) \<longlonglongrightarrow> 0"
  1929   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1930 
  1931 text\<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}\<close>
  1932 
  1933 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) \<longlonglongrightarrow> 0"
  1934   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1935 
  1936 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) \<longlonglongrightarrow> 0"
  1937   by (rule LIMSEQ_power_zero) simp
  1938 
  1939 
  1940 subsection \<open>Limits of Functions\<close>
  1941 
  1942 lemma LIM_eq:
  1943   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1944   shows "f \<midarrow>a\<rightarrow> L =
  1945      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1946 by (simp add: LIM_def dist_norm)
  1947 
  1948 lemma LIM_I:
  1949   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1950   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1951       ==> f \<midarrow>a\<rightarrow> L"
  1952 by (simp add: LIM_eq)
  1953 
  1954 lemma LIM_D:
  1955   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1956   shows "[| f \<midarrow>a\<rightarrow> L; 0<r |]
  1957       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1958 by (simp add: LIM_eq)
  1959 
  1960 lemma LIM_offset:
  1961   fixes a :: "'a::real_normed_vector"
  1962   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>x. f (x + k)) \<midarrow>(a - k)\<rightarrow> L"
  1963   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1964 
  1965 lemma LIM_offset_zero:
  1966   fixes a :: "'a::real_normed_vector"
  1967   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  1968 by (drule_tac k="a" in LIM_offset, simp add: add.commute)
  1969 
  1970 lemma LIM_offset_zero_cancel:
  1971   fixes a :: "'a::real_normed_vector"
  1972   shows "(\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  1973 by (drule_tac k="- a" in LIM_offset, simp)
  1974 
  1975 lemma LIM_offset_zero_iff:
  1976   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1977   shows  "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  1978   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1979 
  1980 lemma LIM_zero:
  1981   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1982   shows "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. f x - l) \<longlongrightarrow> 0) F"
  1983 unfolding tendsto_iff dist_norm by simp
  1984 
  1985 lemma LIM_zero_cancel:
  1986   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1987   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> l) F"
  1988 unfolding tendsto_iff dist_norm by simp
  1989 
  1990 lemma LIM_zero_iff:
  1991   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1992   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F = (f \<longlongrightarrow> l) F"
  1993 unfolding tendsto_iff dist_norm by simp
  1994 
  1995 lemma LIM_imp_LIM:
  1996   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1997   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1998   assumes f: "f \<midarrow>a\<rightarrow> l"
  1999   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  2000   shows "g \<midarrow>a\<rightarrow> m"
  2001   by (rule metric_LIM_imp_LIM [OF f],
  2002     simp add: dist_norm le)
  2003 
  2004 lemma LIM_equal2:
  2005   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2006   assumes 1: "0 < R"
  2007   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  2008   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  2009 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  2010 
  2011 lemma LIM_compose2:
  2012   fixes a :: "'a::real_normed_vector"
  2013   assumes f: "f \<midarrow>a\<rightarrow> b"
  2014   assumes g: "g \<midarrow>b\<rightarrow> c"
  2015   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  2016   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  2017 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  2018 
  2019 lemma real_LIM_sandwich_zero:
  2020   fixes f g :: "'a::topological_space \<Rightarrow> real"
  2021   assumes f: "f \<midarrow>a\<rightarrow> 0"
  2022   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  2023   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  2024   shows "g \<midarrow>a\<rightarrow> 0"
  2025 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  2026   fix x assume x: "x \<noteq> a"
  2027   have "norm (g x - 0) = g x" by (simp add: 1 x)
  2028   also have "g x \<le> f x" by (rule 2 [OF x])
  2029   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  2030   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  2031   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  2032 qed
  2033 
  2034 
  2035 subsection \<open>Continuity\<close>
  2036 
  2037 lemma LIM_isCont_iff:
  2038   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2039   shows "(f \<midarrow>a\<rightarrow> f a) = ((\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> f a)"
  2040 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  2041 
  2042 lemma isCont_iff:
  2043   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2044   shows "isCont f x = (\<lambda>h. f (x + h)) \<midarrow>0\<rightarrow> f x"
  2045 by (simp add: isCont_def LIM_isCont_iff)
  2046 
  2047 lemma isCont_LIM_compose2:
  2048   fixes a :: "'a::real_normed_vector"
  2049   assumes f [unfolded isCont_def]: "isCont f a"
  2050   assumes g: "g \<midarrow>f a\<rightarrow> l"
  2051   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  2052   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  2053 by (rule LIM_compose2 [OF f g inj])
  2054 
  2055 
  2056 lemma isCont_norm [simp]:
  2057   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2058   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  2059   by (fact continuous_norm)
  2060 
  2061 lemma isCont_rabs [simp]:
  2062   fixes f :: "'a::t2_space \<Rightarrow> real"
  2063   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  2064   by (fact continuous_rabs)
  2065 
  2066 lemma isCont_add [simp]:
  2067   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2068   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  2069   by (fact continuous_add)
  2070 
  2071 lemma isCont_minus [simp]:
  2072   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2073   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  2074   by (fact continuous_minus)
  2075 
  2076 lemma isCont_diff [simp]:
  2077   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2078   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  2079   by (fact continuous_diff)
  2080 
  2081 lemma isCont_mult [simp]:
  2082   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  2083   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  2084   by (fact continuous_mult)
  2085 
  2086 lemma (in bounded_linear) isCont:
  2087   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  2088   by (fact continuous)
  2089 
  2090 lemma (in bounded_bilinear) isCont:
  2091   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  2092   by (fact continuous)
  2093 
  2094 lemmas isCont_scaleR [simp] =
  2095   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  2096 
  2097 lemmas isCont_of_real [simp] =
  2098   bounded_linear.isCont [OF bounded_linear_of_real]
  2099 
  2100 lemma isCont_power [simp]:
  2101   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  2102   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  2103   by (fact continuous_power)
  2104 
  2105 lemma isCont_setsum [simp]:
  2106   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  2107   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  2108   by (auto intro: continuous_setsum)
  2109 
  2110 subsection \<open>Uniform Continuity\<close>
  2111 
  2112 definition
  2113   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  2114   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  2115 
  2116 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  2117 by (simp add: isUCont_def isCont_def LIM_def, force)
  2118 
  2119 lemma isUCont_Cauchy:
  2120   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2121 unfolding isUCont_def
  2122 apply (rule metric_CauchyI)
  2123 apply (drule_tac x=e in spec, safe)
  2124 apply (drule_tac e=s in metric_CauchyD, safe)
  2125 apply (rule_tac x=M in exI, simp)
  2126 done
  2127 
  2128 lemma (in bounded_linear) isUCont: "isUCont f"
  2129 unfolding isUCont_def dist_norm
  2130 proof (intro allI impI)
  2131   fix r::real assume r: "0 < r"
  2132   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  2133     using pos_bounded by blast
  2134   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  2135   proof (rule exI, safe)
  2136     from r K show "0 < r / K" by simp
  2137   next
  2138     fix x y :: 'a
  2139     assume xy: "norm (x - y) < r / K"
  2140     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  2141     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  2142     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  2143     finally show "norm (f x - f y) < r" .
  2144   qed
  2145 qed
  2146 
  2147 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2148 by (rule isUCont [THEN isUCont_Cauchy])
  2149 
  2150 lemma LIM_less_bound:
  2151   fixes f :: "real \<Rightarrow> real"
  2152   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  2153   shows "0 \<le> f x"
  2154 proof (rule tendsto_le_const)
  2155   show "(f \<longlongrightarrow> f x) (at_left x)"
  2156     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  2157   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  2158     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  2159 qed simp
  2160 
  2161 
  2162 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  2163 
  2164 lemma nested_sequence_unique:
  2165   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) \<longlonglongrightarrow> 0"
  2166   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f \<longlonglongrightarrow> l) \<and> ((\<forall>n. l \<le> g n) \<and> g \<longlonglongrightarrow> l)"
  2167 proof -
  2168   have "incseq f" unfolding incseq_Suc_iff by fact
  2169   have "decseq g" unfolding decseq_Suc_iff by fact
  2170 
  2171   { fix n
  2172     from \<open>decseq g\<close> have "g n \<le> g 0" by (rule decseqD) simp
  2173     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f n \<le> g 0" by auto }
  2174   then obtain u where "f \<longlonglongrightarrow> u" "\<forall>i. f i \<le> u"
  2175     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  2176   moreover
  2177   { fix n
  2178     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  2179     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f 0 \<le> g n" by simp }
  2180   then obtain l where "g \<longlonglongrightarrow> l" "\<forall>i. l \<le> g i"
  2181     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  2182   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f \<longlonglongrightarrow> u\<close> \<open>g \<longlonglongrightarrow> l\<close>]]
  2183   ultimately show ?thesis by auto
  2184 qed
  2185 
  2186 lemma Bolzano[consumes 1, case_names trans local]:
  2187   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  2188   assumes [arith]: "a \<le> b"
  2189   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  2190   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  2191   shows "P a b"
  2192 proof -
  2193   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  2194   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  2195   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  2196     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  2197     by (simp_all add: l_def u_def bisect_def split: prod.split)
  2198 
  2199   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  2200 
  2201   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l \<longlonglongrightarrow> x) \<and> ((\<forall>n. x \<le> u n) \<and> u \<longlonglongrightarrow> x)"
  2202   proof (safe intro!: nested_sequence_unique)
  2203     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  2204   next
  2205     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  2206     then show "(\<lambda>n. l n - u n) \<longlonglongrightarrow> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  2207   qed fact
  2208   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l \<longlonglongrightarrow> x" "u \<longlonglongrightarrow> x" by auto
  2209   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  2210     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  2211 
  2212   show "P a b"
  2213   proof (rule ccontr)
  2214     assume "\<not> P a b"
  2215     { fix n have "\<not> P (l n) (u n)"
  2216       proof (induct n)
  2217         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  2218       qed (simp add: \<open>\<not> P a b\<close>) }
  2219     moreover
  2220     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  2221         using \<open>0 < d\<close> \<open>l \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2222       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  2223         using \<open>0 < d\<close> \<open>u \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2224       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  2225       proof eventually_elim
  2226         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  2227         from add_strict_mono[OF this] have "u n - l n < d" by simp
  2228         with x show "P (l n) (u n)" by (rule d)
  2229       qed }
  2230     ultimately show False by simp
  2231   qed
  2232 qed
  2233 
  2234 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  2235 proof (cases "a \<le> b", rule compactI)
  2236   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  2237   def T == "{a .. b}"
  2238   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  2239   proof (induct rule: Bolzano)
  2240     case (trans a b c)
  2241     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  2242     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  2243       by (auto simp: *)
  2244     with trans show ?case
  2245       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  2246   next
  2247     case (local x)
  2248     then have "x \<in> \<Union>C" using C by auto
  2249     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  2250     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  2251       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  2252     with \<open>c \<in> C\<close> show ?case
  2253       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  2254   qed
  2255 qed simp
  2256 
  2257 
  2258 lemma continuous_image_closed_interval:
  2259   fixes a b and f :: "real \<Rightarrow> real"
  2260   defines "S \<equiv> {a..b}"
  2261   assumes "a \<le> b" and f: "continuous_on S f"
  2262   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  2263 proof -
  2264   have S: "compact S" "S \<noteq> {}"
  2265     using \<open>a \<le> b\<close> by (auto simp: S_def)
  2266   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  2267     using continuous_attains_sup[OF S f] by auto
  2268   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  2269     using continuous_attains_inf[OF S f] by auto
  2270   moreover have "connected (f`S)"
  2271     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  2272   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  2273     by (auto simp: connected_iff_interval)
  2274   then show ?thesis
  2275     by auto
  2276 qed
  2277 
  2278 lemma open_Collect_positive:
  2279  fixes f :: "'a::t2_space \<Rightarrow> real"
  2280  assumes f: "continuous_on s f"
  2281  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  2282  using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  2283  by (auto simp: Int_def field_simps)
  2284 
  2285 lemma open_Collect_less_Int:
  2286  fixes f g :: "'a::t2_space \<Rightarrow> real"
  2287  assumes f: "continuous_on s f" and g: "continuous_on s g"
  2288  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  2289  using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  2290 
  2291 
  2292 subsection \<open>Boundedness of continuous functions\<close>
  2293 
  2294 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  2295 
  2296 lemma isCont_eq_Ub:
  2297   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2298   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2299     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2300   using continuous_attains_sup[of "{a .. b}" f]
  2301   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2302 
  2303 lemma isCont_eq_Lb:
  2304   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2305   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2306     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2307   using continuous_attains_inf[of "{a .. b}" f]
  2308   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2309 
  2310 lemma isCont_bounded:
  2311   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2312   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  2313   using isCont_eq_Ub[of a b f] by auto
  2314 
  2315 lemma isCont_has_Ub:
  2316   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2317   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2318     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  2319   using isCont_eq_Ub[of a b f] by auto
  2320 
  2321 (*HOL style here: object-level formulations*)
  2322 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  2323       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2324       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2325   by (blast intro: IVT)
  2326 
  2327 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  2328       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  2329       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2330   by (blast intro: IVT2)
  2331 
  2332 lemma isCont_Lb_Ub:
  2333   fixes f :: "real \<Rightarrow> real"
  2334   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2335   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2336                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2337 proof -
  2338   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2339     using isCont_eq_Ub[OF assms] by auto
  2340   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2341     using isCont_eq_Lb[OF assms] by auto
  2342   show ?thesis
  2343     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2344     apply (rule_tac x="f L" in exI)
  2345     apply (rule_tac x="f M" in exI)
  2346     apply (cases "L \<le> M")
  2347     apply (simp, metis order_trans)
  2348     apply (simp, metis order_trans)
  2349     done
  2350 qed
  2351 
  2352 
  2353 text\<open>Continuity of inverse function\<close>
  2354 
  2355 lemma isCont_inverse_function:
  2356   fixes f g :: "real \<Rightarrow> real"
  2357   assumes d: "0 < d"
  2358       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2359       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2360   shows "isCont g (f x)"
  2361 proof -
  2362   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  2363 
  2364   have f: "continuous_on ?D f"
  2365     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2366   then have g: "continuous_on (f`?D) g"
  2367     using inj by (intro continuous_on_inv) auto
  2368 
  2369   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2370     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2371   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2372     by (rule continuous_on_subset)
  2373   moreover
  2374   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2375     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2376   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2377     by auto
  2378   ultimately
  2379   show ?thesis
  2380     by (simp add: continuous_on_eq_continuous_at)
  2381 qed
  2382 
  2383 lemma isCont_inverse_function2:
  2384   fixes f g :: "real \<Rightarrow> real" shows
  2385   "\<lbrakk>a < x; x < b;
  2386     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2387     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2388    \<Longrightarrow> isCont g (f x)"
  2389 apply (rule isCont_inverse_function
  2390        [where f=f and d="min (x - a) (b - x)"])
  2391 apply (simp_all add: abs_le_iff)
  2392 done
  2393 
  2394 (* need to rename second isCont_inverse *)
  2395 
  2396 lemma isCont_inv_fun:
  2397   fixes f g :: "real \<Rightarrow> real"
  2398   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;
  2399          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]
  2400       ==> isCont g (f x)"
  2401 by (rule isCont_inverse_function)
  2402 
  2403 text\<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110\<close>
  2404 lemma LIM_fun_gt_zero:
  2405   fixes f :: "real \<Rightarrow> real"
  2406   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2407 apply (drule (1) LIM_D, clarify)
  2408 apply (rule_tac x = s in exI)
  2409 apply (simp add: abs_less_iff)
  2410 done
  2411 
  2412 lemma LIM_fun_less_zero:
  2413   fixes f :: "real \<Rightarrow> real"
  2414   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2415 apply (drule LIM_D [where r="-l"], simp, clarify)
  2416 apply (rule_tac x = s in exI)
  2417 apply (simp add: abs_less_iff)
  2418 done
  2419 
  2420 lemma LIM_fun_not_zero:
  2421   fixes f :: "real \<Rightarrow> real"
  2422   shows "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2423   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2424 
  2425 end
  2426