src/Pure/pattern.ML
author wenzelm
Mon Jun 12 21:19:03 2006 +0200 (2006-06-12)
changeset 19863 3a4ca87efdc5
parent 19776 a8c02d8b8b40
child 19880 1b0d48257caf
permissions -rw-r--r--
removed matches_seq -- didn't quite work;
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4 
     5 Unification of Higher-Order Patterns.
     6 
     7 See also:
     8 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
     9 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    10 
    11 TODO: optimize red by special-casing it
    12 *)
    13 
    14 infix aeconv;
    15 
    16 signature PATTERN =
    17 sig
    18   val trace_unify_fail: bool ref
    19   val aeconv: term * term -> bool
    20   val eta_long: typ list -> term -> term
    21   val eta_contract_atom: term -> term
    22   val match: theory -> term * term -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    23   val first_order_match: theory -> term * term
    24     -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    25   val matches: theory -> term * term -> bool
    26   val matches_subterm: theory -> term * term -> bool
    27   val unify: theory -> term * term -> Envir.env -> Envir.env
    28   val first_order: term -> bool
    29   val pattern: term -> bool
    30   val rewrite_term: theory -> (term * term) list -> (term -> term option) list -> term -> term
    31   exception Unif
    32   exception MATCH
    33   exception Pattern
    34 end;
    35 
    36 structure Pattern: PATTERN =
    37 struct
    38 
    39 exception Unif;
    40 exception Pattern;
    41 
    42 val trace_unify_fail = ref false;
    43 
    44 fun string_of_term thy env binders t = Sign.string_of_term thy
    45   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    46 
    47 fun bname binders i = fst (nth binders i);
    48 fun bnames binders is = space_implode " " (map (bname binders) is);
    49 
    50 fun typ_clash thy (tye,T,U) =
    51   if !trace_unify_fail
    52   then let val t = Sign.string_of_typ thy (Envir.norm_type tye T)
    53            and u = Sign.string_of_typ thy (Envir.norm_type tye U)
    54        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    55   else ()
    56 
    57 fun clash a b =
    58   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    59 
    60 fun boundVar binders i =
    61   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    62 
    63 fun clashBB binders i j =
    64   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    65   else ()
    66 
    67 fun clashB binders i s =
    68   if !trace_unify_fail then clash (boundVar binders i) s
    69   else ()
    70 
    71 fun proj_fail thy (env,binders,F,_,is,t) =
    72   if !trace_unify_fail
    73   then let val f = Syntax.string_of_vname F
    74            val xs = bnames binders is
    75            val u = string_of_term thy env binders t
    76            val ys = bnames binders (subtract (op =) is (loose_bnos t))
    77        in tracing("Cannot unify variable " ^ f ^
    78                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    79                "\nTerm contains additional bound variable(s) " ^ ys)
    80        end
    81   else ()
    82 
    83 fun ocheck_fail thy (F,t,binders,env) =
    84   if !trace_unify_fail
    85   then let val f = Syntax.string_of_vname F
    86            val u = string_of_term thy env binders t
    87        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    88                   "\nCannot unify!\n")
    89        end
    90   else ()
    91 
    92 fun occurs(F,t,env) =
    93     let fun occ(Var (G, T))   = (case Envir.lookup (env, (G, T)) of
    94                                  SOME(t) => occ t
    95                                | NONE    => F=G)
    96           | occ(t1$t2)      = occ t1 orelse occ t2
    97           | occ(Abs(_,_,t)) = occ t
    98           | occ _           = false
    99     in occ t end;
   100 
   101 
   102 fun mapbnd f =
   103     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   104           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   105           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   106           | mpb _ atom           = atom
   107     in mpb 0 end;
   108 
   109 fun idx [] j     = raise Unif
   110   | idx(i::is) j = if (i:int) =j then length is else idx is j;
   111 
   112 fun mkabs (binders,is,t)  =
   113     let fun mk(i::is) = let val (x,T) = nth binders i
   114                         in Abs(x,T,mk is) end
   115           | mk []     = t
   116     in mk is end;
   117 
   118 val incr = mapbnd (fn i => i+1);
   119 
   120 fun ints_of []             = []
   121   | ints_of (Bound i ::bs) =
   122       let val is = ints_of bs
   123       in if i mem_int is then raise Pattern else i::is end
   124   | ints_of _              = raise Pattern;
   125 
   126 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   127 
   128 
   129 fun app (s,(i::is)) = app (s$Bound(i),is)
   130   | app (s,[])      = s;
   131 
   132 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   133   | red t            []      [] = t
   134   | red t            is      jn = app (mapbnd (nth jn) t,is);
   135 
   136 
   137 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   138 fun split_type (T,0,Ts)                    = (Ts,T)
   139   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   140   | split_type _                           = error("split_type");
   141 
   142 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   143   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   144   in map (nth Ts) is ---> U end;
   145 
   146 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   147 
   148 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   149   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   150   in Envir.update (((F, T), mkhnf (binders, is, G, js)), env') end;
   151 
   152 
   153 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   154 fun mk_proj_list is =
   155     let fun mk(i::is,j) = if is_some i then j :: mk(is,j-1) else mk(is,j-1)
   156           | mk([],_)    = []
   157     in mk(is,length is - 1) end;
   158 
   159 fun proj(s,env,binders,is) =
   160     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   161         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   162               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   163                             in (Abs(a,T,t'),env') end
   164             | t => (case strip_comb t of
   165                 (c as Const _,ts) =>
   166                          let val (ts',env') = prs(ts,env,d,binders)
   167                          in (list_comb(c,ts'),env') end
   168                  | (f as Free _,ts) =>
   169                          let val (ts',env') = prs(ts,env,d,binders)
   170                          in (list_comb(f,ts'),env') end
   171                  | (Bound(i),ts) =>
   172                          let val j = trans d i
   173                              val (ts',env') = prs(ts,env,d,binders)
   174                          in (list_comb(Bound j,ts'),env') end
   175                  | (Var(F as (a,_),Fty),ts) =>
   176                       let val js = ints_of' env ts;
   177                           val js' = map (try (trans d)) js;
   178                           val ks = mk_proj_list js';
   179                           val ls = map_filter I js'
   180                           val Hty = type_of_G env (Fty,length js,ks)
   181                           val (env',H) = Envir.genvar a (env,Hty)
   182                           val env'' =
   183                             Envir.update (((F, Fty), mkhnf (binders, js, H, ks)), env')
   184                       in (app(H,ls),env'') end
   185                  | _  => raise Pattern))
   186         and prs(s::ss,env,d,binders) =
   187               let val (s',env1) = pr(s,env,d,binders)
   188                   val (ss',env2) = prs(ss,env1,d,binders)
   189               in (s'::ss',env2) end
   190           | prs([],env,_,_) = ([],env)
   191    in if downto0(is,length binders - 1) then (s,env)
   192       else pr(s,env,0,binders)
   193    end;
   194 
   195 
   196 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   197 fun mk_ff_list(is,js) =
   198     let fun mk([],[],_)        = []
   199           | mk(i::is,j::js, k) = if (i:int) = j then k :: mk(is,js,k-1)
   200                                         else mk(is,js,k-1)
   201           | mk _               = error"mk_ff_list"
   202     in mk(is,js,length is-1) end;
   203 
   204 fun flexflex1(env,binders,F,Fty,is,js) =
   205   if is=js then env
   206   else let val ks = mk_ff_list(is,js)
   207        in mknewhnf(env,binders,is,F,Fty,ks) end;
   208 
   209 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   210   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   211             if js subset_int is
   212             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   213                  in Envir.update (((F, Fty), t), env) end
   214             else let val ks = is inter_int js
   215                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   216                      val (env',H) = Envir.genvar a (env,Hty)
   217                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   218                  in Envir.update (((G, Gty), lam js), Envir.update (((F, Fty), lam is), env'))
   219                  end;
   220   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   221 
   222 fun unify_types thy (T,U) (env as Envir.Envir{asol,iTs,maxidx}) =
   223   if T=U then env
   224   else let val (iTs',maxidx') = Sign.typ_unify thy (U, T) (iTs, maxidx)
   225        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   226        handle Type.TUNIFY => (typ_clash thy (iTs,T,U); raise Unif);
   227 
   228 fun unif thy binders (s,t) env = case (Envir.head_norm env s, Envir.head_norm env t) of
   229       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   230          let val name = if ns = "" then nt else ns
   231          in unif thy ((name,Ts)::binders) (ts,tt) env end
   232     | (Abs(ns,Ts,ts),t) => unif thy ((ns,Ts)::binders) (ts,(incr t)$Bound(0)) env
   233     | (t,Abs(nt,Tt,tt)) => unif thy ((nt,Tt)::binders) ((incr t)$Bound(0),tt) env
   234     | p => cases thy (binders,env,p)
   235 
   236 and cases thy (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   237        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   238          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   239                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   240       | ((Var(F,Fty),ss),_)           => flexrigid thy (env,binders,F,Fty,ints_of' env ss,t)
   241       | (_,(Var(F,Fty),ts))           => flexrigid thy (env,binders,F,Fty,ints_of' env ts,s)
   242       | ((Const c,ss),(Const d,ts))   => rigidrigid thy (env,binders,c,d,ss,ts)
   243       | ((Free(f),ss),(Free(g),ts))   => rigidrigid thy (env,binders,f,g,ss,ts)
   244       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB thy (env,binders,i,j,ss,ts)
   245       | ((Abs(_),_),_)                => raise Pattern
   246       | (_,(Abs(_),_))                => raise Pattern
   247       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   248       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   249       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   250       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   251       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   252       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   253 
   254 
   255 and rigidrigid thy (env,binders,(a,Ta),(b,Tb),ss,ts) =
   256       if a<>b then (clash a b; raise Unif)
   257       else env |> unify_types thy (Ta,Tb) |> fold (unif thy binders) (ss~~ts)
   258 
   259 and rigidrigidB thy (env,binders,i,j,ss,ts) =
   260      if i <> j then (clashBB binders i j; raise Unif)
   261      else fold (unif thy binders) (ss~~ts) env
   262 
   263 and flexrigid thy (params as (env,binders,F,Fty,is,t)) =
   264       if occurs(F,t,env) then (ocheck_fail thy (F,t,binders,env); raise Unif)
   265       else (let val (u,env') = proj(t,env,binders,is)
   266             in Envir.update (((F, Fty), mkabs (binders, is, u)), env') end
   267             handle Unif => (proj_fail thy params; raise Unif));
   268 
   269 fun unify thy = unif thy [];
   270 
   271 
   272 (*Eta-contract a term from outside: just enough to reduce it to an atom
   273 DOESN'T QUITE WORK!
   274 *)
   275 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   276       (case  eta_contract2 body  of
   277         body' as (f $ Bound 0) =>
   278             if loose_bvar1(f,0) then Abs(a,T,body')
   279             else eta_contract_atom (incr_boundvars ~1 f)
   280       | _ => t0)
   281   | eta_contract_atom t = t
   282 and eta_contract2 (f$t) = f $ eta_contract_atom t
   283   | eta_contract2 t     = eta_contract_atom t;
   284 
   285 (* put a term into eta long beta normal form *)
   286 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   287   | eta_long Ts t = (case strip_comb t of
   288       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   289     | (u, ts) =>
   290       let
   291         val Us = binder_types (fastype_of1 (Ts, t));
   292         val i = length Us
   293       in list_abs (map (pair "x") Us,
   294         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   295           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   296       end);
   297 
   298 
   299 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   300   Note that Consts and Vars may have more than one type.*)
   301 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   302 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   303   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   304   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   305   | aconv_aux (Bound i,    Bound j)    = i=j
   306   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   307   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   308   | aconv_aux _ =  false;
   309 
   310 
   311 (*** Matching ***)
   312 
   313 exception MATCH;
   314 
   315 fun typ_match thy TU tyenv = Sign.typ_match thy TU tyenv
   316   handle Type.TYPE_MATCH => raise MATCH;
   317 
   318 (*First-order matching;
   319   The pattern and object may have variables in common.
   320   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   321   Object is eta-contracted on the fly (by eta-expanding the pattern).
   322   Precondition: the pattern is already eta-contracted!
   323   Types are matched on the fly*)
   324 fun first_order_match thy =
   325   let
   326     fun mtch (instsp as (tyinsts,insts)) = fn
   327         (Var(ixn,T), t)  =>
   328           if loose_bvar(t,0) then raise MATCH
   329           else (case Envir.lookup' (insts, (ixn, T)) of
   330                   NONE => (typ_match thy (T, fastype_of t) tyinsts,
   331                            Vartab.update_new (ixn, (T, t)) insts)
   332                 | SOME u => if t aeconv u then instsp else raise MATCH)
   333       | (Free (a,T), Free (b,U)) =>
   334           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   335       | (Const (a,T), Const (b,U))  =>
   336           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   337       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   338       | (Abs(_,T,t), Abs(_,U,u))  =>
   339           mtch (typ_match thy (T,U) tyinsts, insts) (t,u)
   340       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   341       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   342       | _ => raise MATCH
   343   in fn tu => fn env => mtch env tu end;
   344 
   345 
   346 (* Matching of higher-order patterns *)
   347 
   348 fun match_bind(itms,binders,ixn,T,is,t) =
   349   let val js = loose_bnos t
   350   in if null is
   351      then if null js then Vartab.update_new (ixn, (T, t)) itms else raise MATCH
   352      else if js subset_int is
   353           then let val t' = if downto0(is,length binders - 1) then t
   354                             else mapbnd (idx is) t
   355                in Vartab.update_new (ixn, (T, mkabs (binders, is, t'))) itms end
   356           else raise MATCH
   357   end;
   358 
   359 fun match thy (po as (pat,obj)) envir =
   360 let
   361   (* Pre: pat and obj have same type *)
   362   fun mtch binders (pat,obj) (env as (iTs,itms)) =
   363     case pat of
   364       Abs(ns,Ts,ts) =>
   365         (case obj of
   366            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (ts,tt) env
   367          | _ => let val Tt = Envir.typ_subst_TVars iTs Ts
   368                 in mtch((ns,Tt)::binders) (ts,(incr obj)$Bound(0)) env end)
   369     | _ => (case obj of
   370               Abs(nt,Tt,tt) =>
   371                 mtch((nt,Tt)::binders) ((incr pat)$Bound(0),tt) env
   372             | _ => cases(binders,env,pat,obj))
   373 
   374   and cases(binders,env as (iTs,itms),pat,obj) =
   375     let val (ph,pargs) = strip_comb pat
   376         fun rigrig1(iTs,oargs) = fold (mtch binders) (pargs~~oargs) (iTs,itms)
   377         fun rigrig2((a:string,Ta),(b,Tb),oargs) =
   378               if a <> b then raise MATCH
   379               else rigrig1(typ_match thy (Ta,Tb) iTs, oargs)
   380     in case ph of
   381          Var(ixn,T) =>
   382            let val is = ints_of pargs
   383            in case Envir.lookup' (itms, (ixn, T)) of
   384                 NONE => (iTs,match_bind(itms,binders,ixn,T,is,obj))
   385               | SOME u => if obj aeconv (red u is []) then env
   386                           else raise MATCH
   387            end
   388        | _ =>
   389            let val (oh,oargs) = strip_comb obj
   390            in case (ph,oh) of
   391                 (Const c,Const d) => rigrig2(c,d,oargs)
   392               | (Free f,Free g)   => rigrig2(f,g,oargs)
   393               | (Bound i,Bound j) => if i<>j then raise MATCH
   394                                      else rigrig1(iTs,oargs)
   395               | (Abs _, _)        => raise Pattern
   396               | (_, Abs _)        => raise Pattern
   397               | _                 => raise MATCH
   398            end
   399     end;
   400 
   401   val pT = fastype_of pat
   402   and oT = fastype_of obj
   403   val envir' = apfst (typ_match thy (pT, oT)) envir;
   404 in mtch [] po envir' handle Pattern => first_order_match thy po envir' end;
   405 
   406 fun matches thy po = (match thy po (Vartab.empty, Vartab.empty); true) handle MATCH => false;
   407 
   408 
   409 (* Does pat match a subterm of obj? *)
   410 fun matches_subterm thy (pat,obj) =
   411   let fun msub(bounds,obj) = matches thy (pat,obj) orelse
   412             (case obj of
   413               Abs(x,T,t) => let val y = variant bounds x
   414                                 val f = Free(":" ^ y,T)
   415                             in msub(x::bounds,subst_bound(f,t)) end
   416             | s$t => msub(bounds,s) orelse msub(bounds,t)
   417             | _ => false)
   418   in msub([],obj) end;
   419 
   420 fun first_order(Abs(_,_,t)) = first_order t
   421   | first_order(t $ u) = first_order t andalso first_order u andalso
   422                          not(is_Var t)
   423   | first_order _ = true;
   424 
   425 fun pattern(Abs(_,_,t)) = pattern t
   426   | pattern(t) = let val (head,args) = strip_comb t
   427                  in if is_Var head
   428                     then let val _ = ints_of args in true end
   429                          handle Pattern => false
   430                     else forall pattern args
   431                  end;
   432 
   433 
   434 (* rewriting -- simple but fast *)
   435 
   436 fun rewrite_term thy rules procs tm =
   437   let
   438     val skel0 = Bound 0;
   439 
   440     fun variant_absfree bounds (x, T, t) =
   441       let
   442         val (x', t') = Term.dest_abs (Term.bound bounds, T, t);
   443         fun abs u = Abs (x, T, abstract_over (Free (x', T), u));
   444       in (abs, t') end;
   445 
   446     fun match_rew tm (tm1, tm2) =
   447       let val rtm = the_default tm2 (Term.rename_abs tm1 tm tm2) in
   448         SOME (Envir.subst_vars (match thy (tm1, tm) (Vartab.empty, Vartab.empty)) rtm, rtm)
   449           handle MATCH => NONE
   450       end;
   451 
   452     fun rew (Abs (_, _, body) $ t) = SOME (subst_bound (t, body), skel0)
   453       | rew tm = (case get_first (match_rew tm) rules of
   454           NONE => Option.map (rpair skel0) (get_first (fn p => p tm) procs)
   455         | x => x);
   456 
   457     fun rew1 bounds (Var _) _ = NONE
   458       | rew1 bounds skel tm = (case rew2 bounds skel tm of
   459           SOME tm1 => (case rew tm1 of
   460               SOME (tm2, skel') => SOME (the_default tm2 (rew1 bounds skel' tm2))
   461             | NONE => SOME tm1)
   462         | NONE => (case rew tm of
   463               SOME (tm1, skel') => SOME (the_default tm1 (rew1 bounds skel' tm1))
   464             | NONE => NONE))
   465 
   466     and rew2 bounds skel (tm1 $ tm2) = (case tm1 of
   467             Abs (_, _, body) =>
   468               let val tm' = subst_bound (tm2, body)
   469               in SOME (the_default tm' (rew2 bounds skel0 tm')) end
   470           | _ =>
   471             let val (skel1, skel2) = (case skel of
   472                 skel1 $ skel2 => (skel1, skel2)
   473               | _ => (skel0, skel0))
   474             in case rew1 bounds skel1 tm1 of
   475                 SOME tm1' => (case rew1 bounds skel2 tm2 of
   476                     SOME tm2' => SOME (tm1' $ tm2')
   477                   | NONE => SOME (tm1' $ tm2))
   478               | NONE => (case rew1 bounds skel2 tm2 of
   479                     SOME tm2' => SOME (tm1 $ tm2')
   480                   | NONE => NONE)
   481             end)
   482       | rew2 bounds skel (Abs body) =
   483           let
   484             val (abs, tm') = variant_absfree bounds body;
   485             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   486           in case rew1 (bounds + 1) skel' tm' of
   487               SOME tm'' => SOME (abs tm'')
   488             | NONE => NONE
   489           end
   490       | rew2 _ _ _ = NONE;
   491 
   492   in the_default tm (rew1 0 skel0 tm) end;
   493 
   494 end;
   495 
   496 val trace_unify_fail = Pattern.trace_unify_fail;