src/HOL/Nitpick.thy
author blanchet
Tue Nov 17 23:47:57 2009 +0100 (2009-11-17)
changeset 33747 3aa6b9911252
parent 33608 5c0024338cef
child 34124 c4628a1dcf75
permissions -rw-r--r--
bump up Nitpick's axiom/definition unfolding limits, because some real-world problems (e.g. from Boogie) ran into the previous limits;
the limits are there to prevent infinite recursion; they can be set arbitrarily high without much harm
     1 (*  Title:      HOL/Nitpick.thy
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2008, 2009
     4 
     5 Nitpick: Yet another counterexample generator for Isabelle/HOL.
     6 *)
     7 
     8 header {* Nitpick: Yet Another Counterexample Generator for Isabelle/HOL *}
     9 
    10 theory Nitpick
    11 imports Map SAT
    12 uses ("Tools/Nitpick/kodkod.ML")
    13      ("Tools/Nitpick/kodkod_sat.ML")
    14      ("Tools/Nitpick/nitpick_util.ML")
    15      ("Tools/Nitpick/nitpick_hol.ML")
    16      ("Tools/Nitpick/nitpick_mono.ML")
    17      ("Tools/Nitpick/nitpick_scope.ML")
    18      ("Tools/Nitpick/nitpick_peephole.ML")
    19      ("Tools/Nitpick/nitpick_rep.ML")
    20      ("Tools/Nitpick/nitpick_nut.ML")
    21      ("Tools/Nitpick/nitpick_kodkod.ML")
    22      ("Tools/Nitpick/nitpick_model.ML")
    23      ("Tools/Nitpick/nitpick.ML")
    24      ("Tools/Nitpick/nitpick_isar.ML")
    25      ("Tools/Nitpick/nitpick_tests.ML")
    26      ("Tools/Nitpick/minipick.ML")
    27 begin
    28 
    29 typedecl bisim_iterator
    30 
    31 axiomatization unknown :: 'a
    32            and undefined_fast_The :: 'a
    33            and undefined_fast_Eps :: 'a
    34            and bisim :: "bisim_iterator \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
    35            and bisim_iterator_max :: bisim_iterator
    36            and Tha :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    37 
    38 datatype ('a, 'b) pair_box = PairBox 'a 'b
    39 datatype ('a, 'b) fun_box = FunBox "'a \<Rightarrow> 'b"
    40 
    41 text {*
    42 Alternative definitions.
    43 *}
    44 
    45 lemma If_def [nitpick_def]:
    46 "(if P then Q else R) \<equiv> (P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R)"
    47 by (rule eq_reflection) (rule if_bool_eq_conj)
    48 
    49 lemma Ex1_def [nitpick_def]:
    50 "Ex1 P \<equiv> \<exists>x. P = {x}"
    51 apply (rule eq_reflection)
    52 apply (simp add: Ex1_def expand_set_eq)
    53 apply (rule iffI)
    54  apply (erule exE)
    55  apply (erule conjE)
    56  apply (rule_tac x = x in exI)
    57  apply (rule allI)
    58  apply (rename_tac y)
    59  apply (erule_tac x = y in allE)
    60 by (auto simp: mem_def)
    61 
    62 lemma rtrancl_def [nitpick_def]: "r\<^sup>* \<equiv> (r\<^sup>+)\<^sup>="
    63 by simp
    64 
    65 lemma rtranclp_def [nitpick_def]:
    66 "rtranclp r a b \<equiv> (a = b \<or> tranclp r a b)"
    67 by (rule eq_reflection) (auto dest: rtranclpD)
    68 
    69 lemma tranclp_def [nitpick_def]:
    70 "tranclp r a b \<equiv> trancl (split r) (a, b)"
    71 by (simp add: trancl_def Collect_def mem_def)
    72 
    73 definition refl' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    74 "refl' r \<equiv> \<forall>x. (x, x) \<in> r"
    75 
    76 definition wf' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> bool" where
    77 "wf' r \<equiv> acyclic r \<and> (finite r \<or> unknown)"
    78 
    79 axiomatization wf_wfrec :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b"
    80 
    81 definition wf_wfrec' :: "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    82 [nitpick_simp]: "wf_wfrec' R F x = F (Recdef.cut (wf_wfrec R F) R x) x"
    83 
    84 definition wfrec' ::  "('a \<times> 'a \<Rightarrow> bool) \<Rightarrow> (('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b" where
    85 "wfrec' R F x \<equiv> if wf R then wf_wfrec' R F x
    86                 else THE y. wfrec_rel R (%f x. F (Recdef.cut f R x) x) x y"
    87 
    88 definition card' :: "('a \<Rightarrow> bool) \<Rightarrow> nat" where
    89 "card' X \<equiv> length (SOME xs. set xs = X \<and> distinct xs)"
    90 
    91 definition setsum' :: "('a \<Rightarrow> 'b\<Colon>comm_monoid_add) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b" where
    92 "setsum' f A \<equiv> if finite A then listsum (map f (SOME xs. set xs = A \<and> distinct xs)) else 0"
    93 
    94 inductive fold_graph' :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'b \<Rightarrow> bool" where
    95 "fold_graph' f z {} z" |
    96 "\<lbrakk>x \<in> A; fold_graph' f z (A - {x}) y\<rbrakk> \<Longrightarrow> fold_graph' f z A (f x y)"
    97 
    98 text {*
    99 The following lemmas are not strictly necessary but they help the
   100 \textit{special\_level} optimization.
   101 *}
   102 
   103 lemma The_psimp [nitpick_psimp]:
   104 "P = {x} \<Longrightarrow> The P = x"
   105 by (subgoal_tac "{x} = (\<lambda>y. y = x)") (auto simp: mem_def)
   106 
   107 lemma Eps_psimp [nitpick_psimp]:
   108 "\<lbrakk>P x; \<not> P y; Eps P = y\<rbrakk> \<Longrightarrow> Eps P = x"
   109 apply (case_tac "P (Eps P)")
   110  apply auto
   111 apply (erule contrapos_np)
   112 by (rule someI)
   113 
   114 lemma unit_case_def [nitpick_def]:
   115 "unit_case x u \<equiv> x"
   116 apply (subgoal_tac "u = ()")
   117  apply (simp only: unit.cases)
   118 by simp
   119 
   120 declare unit.cases [nitpick_simp del]
   121 
   122 lemma nat_case_def [nitpick_def]:
   123 "nat_case x f n \<equiv> if n = 0 then x else f (n - 1)"
   124 apply (rule eq_reflection)
   125 by (case_tac n) auto
   126 
   127 declare nat.cases [nitpick_simp del]
   128 
   129 lemmas [nitpick_def] = dvd_eq_mod_eq_0 [THEN eq_reflection]
   130 
   131 lemma list_size_simp [nitpick_simp]:
   132 "list_size f xs = (if xs = [] then 0
   133                    else Suc (f (hd xs) + list_size f (tl xs)))"
   134 "size xs = (if xs = [] then 0 else Suc (size (tl xs)))"
   135 by (case_tac xs) auto
   136 
   137 text {*
   138 Auxiliary definitions used to provide an alternative representation for
   139 @{text rat} and @{text real}.
   140 *}
   141 
   142 function nat_gcd :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   143 [simp del]: "nat_gcd x y = (if y = 0 then x else nat_gcd y (x mod y))"
   144 by auto
   145 termination
   146 apply (relation "measure (\<lambda>(x, y). x + y + (if y > x then 1 else 0))")
   147  apply auto
   148  apply (metis mod_less_divisor xt1(9))
   149 by (metis mod_mod_trivial mod_self nat_neq_iff xt1(10))
   150 
   151 definition nat_lcm :: "nat \<Rightarrow> nat \<Rightarrow> nat" where
   152 "nat_lcm x y = x * y div (nat_gcd x y)"
   153 
   154 definition int_gcd :: "int \<Rightarrow> int \<Rightarrow> int" where
   155 "int_gcd x y = int (nat_gcd (nat (abs x)) (nat (abs y)))"
   156 
   157 definition int_lcm :: "int \<Rightarrow> int \<Rightarrow> int" where
   158 "int_lcm x y = int (nat_lcm (nat (abs x)) (nat (abs y)))"
   159 
   160 definition Frac :: "int \<times> int \<Rightarrow> bool" where
   161 "Frac \<equiv> \<lambda>(a, b). b > 0 \<and> int_gcd a b = 1"
   162 
   163 axiomatization Abs_Frac :: "int \<times> int \<Rightarrow> 'a"
   164            and Rep_Frac :: "'a \<Rightarrow> int \<times> int"
   165 
   166 definition zero_frac :: 'a where
   167 "zero_frac \<equiv> Abs_Frac (0, 1)"
   168 
   169 definition one_frac :: 'a where
   170 "one_frac \<equiv> Abs_Frac (1, 1)"
   171 
   172 definition num :: "'a \<Rightarrow> int" where
   173 "num \<equiv> fst o Rep_Frac"
   174 
   175 definition denom :: "'a \<Rightarrow> int" where
   176 "denom \<equiv> snd o Rep_Frac"
   177 
   178 function norm_frac :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
   179 [simp del]: "norm_frac a b = (if b < 0 then norm_frac (- a) (- b)
   180                               else if a = 0 \<or> b = 0 then (0, 1)
   181                               else let c = int_gcd a b in (a div c, b div c))"
   182 by pat_completeness auto
   183 termination by (relation "measure (\<lambda>(_, b). if b < 0 then 1 else 0)") auto
   184 
   185 definition frac :: "int \<Rightarrow> int \<Rightarrow> 'a" where
   186 "frac a b \<equiv> Abs_Frac (norm_frac a b)"
   187 
   188 definition plus_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   189 [nitpick_simp]:
   190 "plus_frac q r = (let d = int_lcm (denom q) (denom r) in
   191                     frac (num q * (d div denom q) + num r * (d div denom r)) d)"
   192 
   193 definition times_frac :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   194 [nitpick_simp]:
   195 "times_frac q r = frac (num q * num r) (denom q * denom r)"
   196 
   197 definition uminus_frac :: "'a \<Rightarrow> 'a" where
   198 "uminus_frac q \<equiv> Abs_Frac (- num q, denom q)"
   199 
   200 definition number_of_frac :: "int \<Rightarrow> 'a" where
   201 "number_of_frac n \<equiv> Abs_Frac (n, 1)"
   202 
   203 definition inverse_frac :: "'a \<Rightarrow> 'a" where
   204 "inverse_frac q \<equiv> frac (denom q) (num q)"
   205 
   206 definition less_eq_frac :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where
   207 [nitpick_simp]:
   208 "less_eq_frac q r \<longleftrightarrow> num (plus_frac q (uminus_frac r)) \<le> 0"
   209 
   210 definition of_frac :: "'a \<Rightarrow> 'b\<Colon>{inverse,ring_1}" where
   211 "of_frac q \<equiv> of_int (num q) / of_int (denom q)"
   212 
   213 (* While Nitpick normally avoids to unfold definitions for locales, it
   214    unfortunately needs to unfold them when dealing with the following built-in
   215    constants. A cleaner approach would be to change "Nitpick_HOL" and
   216    "Nitpick_Nut" so that they handle the unexpanded overloaded constants
   217    directly, but this is slightly more tricky to implement. *)
   218 lemmas [nitpick_def] = div_int_inst.div_int div_int_inst.mod_int
   219     div_nat_inst.div_nat div_nat_inst.mod_nat lower_semilattice_fun_inst.inf_fun
   220     minus_fun_inst.minus_fun minus_int_inst.minus_int minus_nat_inst.minus_nat
   221     one_int_inst.one_int one_nat_inst.one_nat ord_fun_inst.less_eq_fun
   222     ord_int_inst.less_eq_int ord_int_inst.less_int ord_nat_inst.less_eq_nat
   223     ord_nat_inst.less_nat plus_int_inst.plus_int plus_nat_inst.plus_nat
   224     times_int_inst.times_int times_nat_inst.times_nat uminus_int_inst.uminus_int
   225     upper_semilattice_fun_inst.sup_fun zero_int_inst.zero_int
   226     zero_nat_inst.zero_nat
   227 
   228 use "Tools/Nitpick/kodkod.ML"
   229 use "Tools/Nitpick/kodkod_sat.ML"
   230 use "Tools/Nitpick/nitpick_util.ML"
   231 use "Tools/Nitpick/nitpick_hol.ML"
   232 use "Tools/Nitpick/nitpick_mono.ML"
   233 use "Tools/Nitpick/nitpick_scope.ML"
   234 use "Tools/Nitpick/nitpick_peephole.ML"
   235 use "Tools/Nitpick/nitpick_rep.ML"
   236 use "Tools/Nitpick/nitpick_nut.ML"
   237 use "Tools/Nitpick/nitpick_kodkod.ML"
   238 use "Tools/Nitpick/nitpick_model.ML"
   239 use "Tools/Nitpick/nitpick.ML"
   240 use "Tools/Nitpick/nitpick_isar.ML"
   241 use "Tools/Nitpick/nitpick_tests.ML"
   242 use "Tools/Nitpick/minipick.ML"
   243 
   244 setup {* Nitpick_Isar.setup *}
   245 
   246 hide (open) const unknown undefined_fast_The undefined_fast_Eps bisim 
   247     bisim_iterator_max Tha refl' wf' wf_wfrec wf_wfrec' wfrec' card' setsum'
   248     fold_graph' nat_gcd nat_lcm int_gcd int_lcm Frac Abs_Frac Rep_Frac zero_frac
   249     one_frac num denom norm_frac frac plus_frac times_frac uminus_frac
   250     number_of_frac inverse_frac less_eq_frac of_frac
   251 hide (open) type bisim_iterator pair_box fun_box
   252 hide (open) fact If_def Ex1_def rtrancl_def rtranclp_def tranclp_def refl'_def
   253     wf'_def wf_wfrec'_def wfrec'_def card'_def setsum'_def fold_graph'_def
   254     The_psimp Eps_psimp unit_case_def nat_case_def list_size_simp nat_gcd_def
   255     nat_lcm_def int_gcd_def int_lcm_def Frac_def zero_frac_def one_frac_def
   256     num_def denom_def norm_frac_def frac_def plus_frac_def times_frac_def
   257     uminus_frac_def number_of_frac_def inverse_frac_def less_eq_frac_def
   258     of_frac_def
   259 
   260 end