src/Pure/PIDE/document.ML
author wenzelm
Fri Jun 01 10:56:01 2018 +0200 (15 months ago)
changeset 68344 3bb44c25ce8b
parent 68336 09ac56914b29
child 68354 93d3c967802e
permissions -rw-r--r--
clarified priority;
     1 (*  Title:      Pure/PIDE/document.ML
     2     Author:     Makarius
     3 
     4 Document as collection of named nodes, each consisting of an editable
     5 list of commands, associated with asynchronous execution process.
     6 *)
     7 
     8 signature DOCUMENT =
     9 sig
    10   val timing: bool Unsynchronized.ref
    11   type node_header = {master: string, header: Thy_Header.header, errors: string list}
    12   type overlay = Document_ID.command * (string * string list)
    13   datatype node_edit =
    14     Edits of (Document_ID.command option * Document_ID.command option) list |
    15     Deps of node_header |
    16     Perspective of bool * Document_ID.command list * overlay list
    17   type edit = string * node_edit
    18   type state
    19   val init_state: state
    20   val define_blob: string -> string -> state -> state
    21   type blob_digest = (string * string option) Exn.result
    22   val define_command: Document_ID.command -> string -> blob_digest list -> int ->
    23     ((int * int) * string) list -> state -> state
    24   val command_exec: state -> string -> Document_ID.command -> Command.exec option
    25   val remove_versions: Document_ID.version list -> state -> state
    26   val start_execution: state -> state
    27   val update: Document_ID.version -> Document_ID.version -> edit list -> bool -> state ->
    28     Document_ID.exec list * (Document_ID.command * Document_ID.exec list) list * state
    29   val state: unit -> state
    30   val change_state: (state -> state) -> unit
    31 end;
    32 
    33 structure Document: DOCUMENT =
    34 struct
    35 
    36 val timing = Unsynchronized.ref false;
    37 fun timeit msg e = cond_timeit (! timing) msg e;
    38 
    39 
    40 
    41 (** document structure **)
    42 
    43 fun err_dup kind id = error ("Duplicate " ^ kind ^ ": " ^ Document_ID.print id);
    44 fun err_undef kind id = error ("Undefined " ^ kind ^ ": " ^ Document_ID.print id);
    45 
    46 type node_header =
    47   {master: string, header: Thy_Header.header, errors: string list};
    48 
    49 type perspective =
    50  {required: bool,  (*required node*)
    51   visible: Inttab.set,  (*visible commands*)
    52   visible_last: Document_ID.command option,  (*last visible command*)
    53   overlays: (string * string list) list Inttab.table};  (*command id -> print functions with args*)
    54 
    55 structure Entries = Linear_Set(type key = Document_ID.command val ord = int_ord);
    56 
    57 abstype node = Node of
    58  {header: node_header,  (*master directory, theory header, errors*)
    59   keywords: Keyword.keywords option,  (*outer syntax keywords*)
    60   perspective: perspective,  (*command perspective*)
    61   entries: Command.exec option Entries.T,  (*command entries with executions*)
    62   result: (Document_ID.command * Command.eval) option,  (*result of last execution*)
    63   consolidated: unit lazy}  (*consolidated status of eval forks*)
    64 and version = Version of node String_Graph.T  (*development graph wrt. static imports*)
    65 with
    66 
    67 fun make_node (header, keywords, perspective, entries, result, consolidated) =
    68   Node {header = header, keywords = keywords, perspective = perspective,
    69     entries = entries, result = result, consolidated = consolidated};
    70 
    71 fun map_node f (Node {header, keywords, perspective, entries, result, consolidated}) =
    72   make_node (f (header, keywords, perspective, entries, result, consolidated));
    73 
    74 fun make_perspective (required, command_ids, overlays) : perspective =
    75  {required = required,
    76   visible = Inttab.make_set command_ids,
    77   visible_last = try List.last command_ids,
    78   overlays = Inttab.make_list overlays};
    79 
    80 val no_header: node_header =
    81   {master = "", header = Thy_Header.make ("", Position.none) [] [], errors = []};
    82 val no_perspective = make_perspective (false, [], []);
    83 
    84 val empty_node =
    85   make_node (no_header, NONE, no_perspective, Entries.empty, NONE, Lazy.value ());
    86 
    87 fun is_no_perspective ({required, visible, visible_last, overlays}: perspective) =
    88   not required andalso
    89   Inttab.is_empty visible andalso
    90   is_none visible_last andalso
    91   Inttab.is_empty overlays;
    92 
    93 fun is_empty_node (Node {header, keywords, perspective, entries, result, consolidated}) =
    94   header = no_header andalso
    95   is_none keywords andalso
    96   is_no_perspective perspective andalso
    97   Entries.is_empty entries andalso
    98   is_none result andalso
    99   Lazy.is_finished consolidated;
   100 
   101 
   102 (* basic components *)
   103 
   104 fun master_directory (Node {header = {master, ...}, ...}) =
   105   (case try Url.explode master of
   106     SOME (Url.File path) => path
   107   | _ => Path.current);
   108 
   109 fun set_header master header errors =
   110   map_node (fn (_, keywords, perspective, entries, result, consolidated) =>
   111     ({master = master, header = header, errors = errors},
   112       keywords, perspective, entries, result, consolidated));
   113 
   114 fun get_header (Node {header, ...}) = header;
   115 
   116 fun set_keywords keywords =
   117   map_node (fn (header, _, perspective, entries, result, consolidated) =>
   118     (header, keywords, perspective, entries, result, consolidated));
   119 
   120 fun get_keywords (Node {keywords, ...}) = keywords;
   121 
   122 fun read_header node span =
   123   let
   124     val {header, errors, ...} = get_header node;
   125     val _ =
   126       if null errors then ()
   127       else
   128         cat_lines errors |>
   129         (case Position.get_id (Position.thread_data ()) of
   130           NONE => I
   131         | SOME id => Protocol_Message.command_positions_yxml id)
   132         |> error;
   133     val {name = (name, _), imports, ...} = header;
   134     val {name = (_, pos), imports = imports', keywords} =
   135       Thy_Header.read_tokens Position.none span;
   136     val imports'' = (map #1 imports ~~ map #2 imports') handle ListPair.UnequalLengths => imports;
   137   in Thy_Header.make (name, pos) imports'' keywords end;
   138 
   139 fun get_perspective (Node {perspective, ...}) = perspective;
   140 
   141 fun set_perspective args =
   142   map_node (fn (header, keywords, _, entries, result, consolidated) =>
   143     (header, keywords, make_perspective args, entries, result, consolidated));
   144 
   145 val required_node = #required o get_perspective;
   146 val visible_command = Inttab.defined o #visible o get_perspective;
   147 val visible_last = #visible_last o get_perspective;
   148 val visible_node = is_some o visible_last
   149 val overlays = Inttab.lookup_list o #overlays o get_perspective;
   150 
   151 fun map_entries f =
   152   map_node (fn (header, keywords, perspective, entries, result, consolidated) =>
   153     (header, keywords, perspective, f entries, result, consolidated));
   154 
   155 fun get_entries (Node {entries, ...}) = entries;
   156 
   157 fun iterate_entries f = Entries.iterate NONE f o get_entries;
   158 fun iterate_entries_after start f (Node {entries, ...}) =
   159   (case Entries.get_after entries start of
   160     NONE => I
   161   | SOME id => Entries.iterate (SOME id) f entries);
   162 
   163 fun get_result (Node {result, ...}) = result;
   164 
   165 fun set_result result =
   166   map_node (fn (header, keywords, perspective, entries, _, consolidated) =>
   167     (header, keywords, perspective, entries, result, consolidated));
   168 
   169 fun pending_result node =
   170   (case get_result node of
   171     SOME (_, eval) => not (Command.eval_finished eval)
   172   | NONE => false);
   173 
   174 fun finished_result node =
   175   (case get_result node of
   176     SOME (_, eval) => Command.eval_finished eval
   177   | NONE => false);
   178 
   179 fun finished_result_theory node =
   180   if finished_result node then
   181     let
   182       val (result_id, eval) = the (get_result node);
   183       val st = Command.eval_result_state eval;
   184     in SOME (result_id, Toplevel.end_theory Position.none st) handle ERROR _ => NONE end
   185   else NONE;
   186 
   187 val reset_consolidated =
   188   map_node (fn (header, keywords, perspective, entries, result, _) =>
   189     (header, keywords, perspective, entries, result, Lazy.lazy I));
   190 
   191 fun get_consolidated (Node {consolidated, ...}) = consolidated;
   192 
   193 val is_consolidated = Lazy.is_finished o get_consolidated;
   194 
   195 fun commit_consolidated node =
   196   (Lazy.force (get_consolidated node); Output.status (Markup.markup_only Markup.consolidated));
   197 
   198 fun could_consolidate node =
   199   not (is_consolidated node) andalso is_some (finished_result_theory node);
   200 
   201 fun get_node nodes name = String_Graph.get_node nodes name
   202   handle String_Graph.UNDEF _ => empty_node;
   203 fun default_node name = String_Graph.default_node (name, empty_node);
   204 fun update_node name f = default_node name #> String_Graph.map_node name f;
   205 
   206 
   207 (* node edits and associated executions *)
   208 
   209 type overlay = Document_ID.command * (string * string list);
   210 
   211 datatype node_edit =
   212   Edits of (Document_ID.command option * Document_ID.command option) list |
   213   Deps of node_header |
   214   Perspective of bool * Document_ID.command list * overlay list;
   215 
   216 type edit = string * node_edit;
   217 
   218 val after_entry = Entries.get_after o get_entries;
   219 
   220 fun lookup_entry node id =
   221   (case Entries.lookup (get_entries node) id of
   222     NONE => NONE
   223   | SOME (exec, _) => exec);
   224 
   225 fun the_entry node id =
   226   (case Entries.lookup (get_entries node) id of
   227     NONE => err_undef "command entry" id
   228   | SOME (exec, _) => exec);
   229 
   230 fun assign_entry (command_id, exec) node =
   231   if is_none (Entries.lookup (get_entries node) command_id) then node
   232   else map_entries (Entries.update (command_id, exec)) node;
   233 
   234 fun reset_after id entries =
   235   (case Entries.get_after entries id of
   236     NONE => entries
   237   | SOME next => Entries.update (next, NONE) entries);
   238 
   239 val edit_node = map_entries o fold
   240   (fn (id, SOME id2) => Entries.insert_after id (id2, NONE)
   241     | (id, NONE) => Entries.delete_after id #> reset_after id);
   242 
   243 
   244 (* version operations *)
   245 
   246 val empty_version = Version String_Graph.empty;
   247 
   248 fun nodes_of (Version nodes) = nodes;
   249 val node_of = get_node o nodes_of;
   250 
   251 fun cycle_msg names = "Cyclic dependency of " ^ space_implode " via " (map quote names);
   252 
   253 fun edit_nodes (name, node_edit) (Version nodes) =
   254   Version
   255     (case node_edit of
   256       Edits edits => update_node name (edit_node edits) nodes
   257     | Deps {master, header, errors} =>
   258         let
   259           val imports = map fst (#imports header);
   260           val nodes1 = nodes
   261             |> default_node name
   262             |> fold default_node imports;
   263           val nodes2 = nodes1
   264             |> String_Graph.Keys.fold
   265                 (fn dep => String_Graph.del_edge (dep, name)) (String_Graph.imm_preds nodes1 name);
   266           val (nodes3, errors1) =
   267             (String_Graph.add_deps_acyclic (name, imports) nodes2, errors)
   268               handle String_Graph.CYCLES cs => (nodes2, errors @ map cycle_msg cs);
   269         in String_Graph.map_node name (set_header master header errors1) nodes3 end
   270     | Perspective perspective => update_node name (set_perspective perspective) nodes);
   271 
   272 fun update_keywords name nodes =
   273   nodes |> String_Graph.map_node name (fn node =>
   274     if is_empty_node node then node
   275     else
   276       let
   277         val {master, header, errors} = get_header node;
   278         val imports_keywords = map_filter (get_keywords o get_node nodes o #1) (#imports header);
   279         val keywords =
   280           Library.foldl Keyword.merge_keywords (Session.get_keywords (), imports_keywords);
   281         val (keywords', errors') =
   282           (Keyword.add_keywords (#keywords header) keywords, errors)
   283             handle ERROR msg =>
   284               (keywords, if member (op =) errors msg then errors else errors @ [msg]);
   285       in
   286         node
   287         |> set_header master header errors'
   288         |> set_keywords (SOME keywords')
   289       end);
   290 
   291 fun edit_keywords edits (Version nodes) =
   292   Version
   293     (fold update_keywords
   294       (String_Graph.all_succs nodes (map_filter (fn (a, Deps _) => SOME a | _ => NONE) edits))
   295       nodes);
   296 
   297 fun put_node (name, node) (Version nodes) =
   298   let
   299     val nodes1 = update_node name (K node) nodes;
   300     val nodes2 =
   301       if String_Graph.is_maximal nodes1 name andalso is_empty_node node
   302       then String_Graph.del_node name nodes1
   303       else nodes1;
   304   in Version nodes2 end;
   305 
   306 end;
   307 
   308 
   309 
   310 (** main state -- document structure and execution process **)
   311 
   312 type blob_digest = (string * string option) Exn.result;  (*file node name, raw digest*)
   313 
   314 type execution =
   315  {version_id: Document_ID.version,  (*static version id*)
   316   execution_id: Document_ID.execution,  (*dynamic execution id*)
   317   delay_request: unit future};  (*pending event timer request*)
   318 
   319 val no_execution: execution =
   320   {version_id = Document_ID.none,
   321    execution_id = Document_ID.none,
   322    delay_request = Future.value ()};
   323 
   324 fun new_execution version_id delay_request : execution =
   325   {version_id = version_id,
   326    execution_id = Execution.start (),
   327    delay_request = delay_request};
   328 
   329 abstype state = State of
   330  {versions: version Inttab.table,  (*version id -> document content*)
   331   blobs: (SHA1.digest * string list) Symtab.table,  (*raw digest -> digest, lines*)
   332   commands: (string * blob_digest list * int * Token.T list lazy) Inttab.table,
   333     (*command id -> name, inlined files, token index of files, command span*)
   334   execution: execution}  (*current execution process*)
   335 with
   336 
   337 fun make_state (versions, blobs, commands, execution) =
   338   State {versions = versions, blobs = blobs, commands = commands, execution = execution};
   339 
   340 fun map_state f (State {versions, blobs, commands, execution}) =
   341   make_state (f (versions, blobs, commands, execution));
   342 
   343 val init_state =
   344   make_state (Inttab.make [(Document_ID.none, empty_version)],
   345     Symtab.empty, Inttab.empty, no_execution);
   346 
   347 
   348 (* document versions *)
   349 
   350 fun define_version version_id version =
   351   map_state (fn (versions, blobs, commands, {delay_request, ...}) =>
   352     let
   353       val versions' = Inttab.update_new (version_id, version) versions
   354         handle Inttab.DUP dup => err_dup "document version" dup;
   355       val execution' = new_execution version_id delay_request;
   356     in (versions', blobs, commands, execution') end);
   357 
   358 fun the_version (State {versions, ...}) version_id =
   359   (case Inttab.lookup versions version_id of
   360     NONE => err_undef "document version" version_id
   361   | SOME version => version);
   362 
   363 fun delete_version version_id versions =
   364   Inttab.delete version_id versions
   365     handle Inttab.UNDEF _ => err_undef "document version" version_id;
   366 
   367 
   368 (* inlined files *)
   369 
   370 fun define_blob digest text =
   371   map_state (fn (versions, blobs, commands, execution) =>
   372     let val blobs' = Symtab.update (digest, (SHA1.fake digest, split_lines text)) blobs
   373     in (versions, blobs', commands, execution) end);
   374 
   375 fun the_blob (State {blobs, ...}) digest =
   376   (case Symtab.lookup blobs digest of
   377     NONE => error ("Undefined blob: " ^ digest)
   378   | SOME content => content);
   379 
   380 fun resolve_blob state (blob_digest: blob_digest) =
   381   blob_digest |> Exn.map_res (fn (file_node, raw_digest) =>
   382     (file_node, Option.map (the_blob state) raw_digest));
   383 
   384 fun blob_reports pos (blob_digest: blob_digest) =
   385   (case blob_digest of Exn.Res (file_node, _) => [(pos, Markup.path file_node)] | _ => []);
   386 
   387 
   388 (* commands *)
   389 
   390 fun define_command command_id name blobs_digests blobs_index toks =
   391   map_state (fn (versions, blobs, commands, execution) =>
   392     let
   393       val id = Document_ID.print command_id;
   394       val span =
   395         Lazy.lazy_name "Document.define_command" (fn () =>
   396           Position.setmp_thread_data (Position.id_only id)
   397             (fn () =>
   398               let
   399                 val (tokens, _) = fold_map Token.make toks (Position.id id);
   400                 val _ =
   401                   if blobs_index < 0
   402                   then (*inlined errors*)
   403                     map_filter Exn.get_exn blobs_digests
   404                     |> List.app (Output.error_message o Runtime.exn_message)
   405                   else (*auxiliary files*)
   406                     let val pos = Token.pos_of (nth tokens blobs_index)
   407                     in Position.reports (maps (blob_reports pos) blobs_digests) end;
   408               in tokens end) ());
   409       val commands' =
   410         Inttab.update_new (command_id, (name, blobs_digests, blobs_index, span)) commands
   411           handle Inttab.DUP dup => err_dup "command" dup;
   412       val _ =
   413         Position.setmp_thread_data (Position.id_only id)
   414           (fn () => Output.status (Markup.markup_only Markup.accepted)) ();
   415     in (versions, blobs, commands', execution) end);
   416 
   417 fun the_command (State {commands, ...}) command_id =
   418   (case Inttab.lookup commands command_id of
   419     NONE => err_undef "command" command_id
   420   | SOME command => command);
   421 
   422 val the_command_name = #1 oo the_command;
   423 
   424 
   425 (* execution *)
   426 
   427 fun get_execution (State {execution, ...}) = execution;
   428 fun get_execution_version state = the_version state (#version_id (get_execution state));
   429 
   430 fun command_exec state node_name command_id =
   431   let
   432     val version = get_execution_version state;
   433     val node = get_node (nodes_of version) node_name;
   434   in the_entry node command_id end;
   435 
   436 end;
   437 
   438 
   439 (* remove_versions *)
   440 
   441 fun remove_versions version_ids state = state |> map_state (fn (versions, _, _, execution) =>
   442   let
   443     val _ =
   444       member (op =) version_ids (#version_id execution) andalso
   445         error ("Attempt to remove execution version " ^ Document_ID.print (#version_id execution));
   446 
   447     val versions' = fold delete_version version_ids versions;
   448     val commands' =
   449       (versions', Inttab.empty) |->
   450         Inttab.fold (fn (_, version) => nodes_of version |>
   451           String_Graph.fold (fn (_, (node, _)) => node |>
   452             iterate_entries (fn ((_, command_id), _) =>
   453               SOME o Inttab.insert (K true) (command_id, the_command state command_id))));
   454     val blobs' =
   455       (commands', Symtab.empty) |->
   456         Inttab.fold (fn (_, (_, blobs, _, _)) => blobs |>
   457           fold (fn Exn.Res (_, SOME b) => Symtab.update (b, the_blob state b) | _ => I));
   458 
   459   in (versions', blobs', commands', execution) end);
   460 
   461 
   462 (* document execution *)
   463 
   464 fun make_required nodes =
   465   let
   466     fun all_preds P =
   467       String_Graph.fold (fn (a, (node, _)) => P node ? cons a) nodes []
   468       |> String_Graph.all_preds nodes
   469       |> Symtab.make_set;
   470 
   471     val all_visible = all_preds visible_node;
   472     val all_required = all_preds required_node;
   473   in
   474     Symtab.fold (fn (a, ()) =>
   475       exists (Symtab.defined all_visible) (String_Graph.immediate_succs nodes a) ?
   476         Symtab.update (a, ())) all_visible all_required
   477   end;
   478 
   479 fun start_execution state = state |> map_state (fn (versions, blobs, commands, execution) =>
   480   timeit "Document.start_execution" (fn () =>
   481     let
   482       val {version_id, execution_id, delay_request} = execution;
   483 
   484       val delay = seconds (Options.default_real "editor_execution_delay");
   485 
   486       val _ = Future.cancel delay_request;
   487       val delay_request' = Event_Timer.future (Time.now () + delay);
   488 
   489       fun finished_import (name, (node, _)) =
   490         finished_result node orelse is_some (Thy_Info.lookup_theory name);
   491 
   492       val nodes = nodes_of (the_version state version_id);
   493       val required = make_required nodes;
   494       val _ =
   495         nodes |> String_Graph.schedule
   496           (fn deps => fn (name, node) =>
   497             if Symtab.defined required name orelse visible_node node orelse pending_result node then
   498               let
   499                 fun body () =
   500                   (if forall finished_import deps then
   501                     iterate_entries (fn (_, opt_exec) => fn () =>
   502                       (case opt_exec of
   503                         SOME exec =>
   504                           if Execution.is_running execution_id
   505                           then SOME (Command.exec execution_id exec)
   506                           else NONE
   507                       | NONE => NONE)) node ()
   508                    else ())
   509                    handle exn => (Output.system_message (Runtime.exn_message exn); Exn.reraise exn);
   510                 val future =
   511                   (singleton o Future.forks)
   512                    {name = "theory:" ^ name,
   513                     group = SOME (Future.new_group NONE),
   514                     deps = Future.task_of delay_request' :: maps (the_list o #2 o #2) deps,
   515                     pri = 0, interrupts = false} body;
   516               in (node, SOME (Future.task_of future)) end
   517             else (node, NONE));
   518       val execution' =
   519         {version_id = version_id, execution_id = execution_id, delay_request = delay_request'};
   520     in (versions, blobs, commands, execution') end));
   521 
   522 
   523 
   524 (** document update **)
   525 
   526 (* exec state assignment *)
   527 
   528 type assign_update = Command.exec option Inttab.table;  (*command id -> exec*)
   529 
   530 val assign_update_empty: assign_update = Inttab.empty;
   531 fun assign_update_defined (tab: assign_update) command_id = Inttab.defined tab command_id;
   532 fun assign_update_change entry (tab: assign_update) = Inttab.update entry tab;
   533 fun assign_update_apply (tab: assign_update) node = Inttab.fold assign_entry tab node;
   534 
   535 fun assign_update_new upd (tab: assign_update) =
   536   Inttab.update_new upd tab
   537     handle Inttab.DUP dup => err_dup "exec state assignment" dup;
   538 
   539 fun assign_update_result (tab: assign_update) =
   540   Inttab.fold (fn (command_id, exec) => cons (command_id, Command.exec_ids exec)) tab [];
   541 
   542 
   543 (* update *)
   544 
   545 local
   546 
   547 fun init_theory deps node span =
   548   let
   549     val master_dir = master_directory node;
   550     val header = read_header node span;
   551     val imports = #imports header;
   552 
   553     fun maybe_end_theory pos st =
   554       SOME (Toplevel.end_theory pos st)
   555         handle ERROR msg => (Output.error_message msg; NONE);
   556     val parents_reports =
   557       imports |> map_filter (fn (import, pos) =>
   558         (case Thy_Info.lookup_theory import of
   559           NONE =>
   560             maybe_end_theory pos
   561               (case get_result (snd (the (AList.lookup (op =) deps import))) of
   562                 NONE => Toplevel.toplevel
   563               | SOME (_, eval) => Command.eval_result_state eval)
   564         | some => some)
   565         |> Option.map (fn thy => (thy, (pos, Theory.get_markup thy))));
   566 
   567     val parents =
   568       if null parents_reports then [Theory.get_pure ()] else map #1 parents_reports;
   569     val _ = Position.reports (map #2 parents_reports);
   570     val thy = Resources.begin_theory master_dir header parents;
   571     val _ = Output.status (Markup.markup_only Markup.initialized);
   572   in thy end;
   573 
   574 fun check_root_theory node =
   575   let
   576     val master_dir = master_directory node;
   577     val header = #header (get_header node);
   578     val header_name = #1 (#name header);
   579     val parent =
   580       if header_name = Sessions.root_name then
   581         SOME (Thy_Info.get_theory Sessions.theory_name)
   582       else if member (op =) Thy_Header.ml_roots header_name then
   583         SOME (Thy_Info.get_theory Thy_Header.ml_bootstrapN)
   584       else NONE;
   585   in parent |> Option.map (fn thy => Resources.begin_theory master_dir header [thy]) end;
   586 
   587 fun check_theory full name node =
   588   is_some (Thy_Info.lookup_theory name) orelse
   589   null (#errors (get_header node)) andalso (not full orelse is_some (get_result node));
   590 
   591 fun last_common keywords state node_required node0 node =
   592   let
   593     fun update_flags prev (visible, initial) =
   594       let
   595         val visible' = visible andalso prev <> visible_last node;
   596         val initial' = initial andalso
   597           (case prev of
   598             NONE => true
   599           | SOME command_id => the_command_name state command_id <> Thy_Header.theoryN);
   600       in (visible', initial') end;
   601 
   602     fun get_common ((prev, command_id), opt_exec) (_, ok, flags, assign_update) =
   603       if ok then
   604         let
   605           val flags' as (visible', _) = update_flags prev flags;
   606           val ok' =
   607             (case (lookup_entry node0 command_id, opt_exec) of
   608               (SOME (eval0, _), SOME (eval, _)) =>
   609                 Command.eval_eq (eval0, eval) andalso
   610                   (visible' orelse node_required orelse Command.eval_running eval)
   611             | _ => false);
   612           val assign_update' = assign_update |> ok' ?
   613             (case opt_exec of
   614               SOME (eval, prints) =>
   615                 let
   616                   val command_visible = visible_command node command_id;
   617                   val command_overlays = overlays node command_id;
   618                   val command_name = the_command_name state command_id;
   619                 in
   620                   (case
   621                     Command.print command_visible command_overlays keywords command_name eval prints
   622                    of
   623                     SOME prints' => assign_update_new (command_id, SOME (eval, prints'))
   624                   | NONE => I)
   625                 end
   626             | NONE => I);
   627         in SOME (prev, ok', flags', assign_update') end
   628       else NONE;
   629     val (common, ok, flags, assign_update') =
   630       iterate_entries get_common node (NONE, true, (true, true), assign_update_empty);
   631     val (common', flags') =
   632       if ok then
   633         let val last = Entries.get_after (get_entries node) common
   634         in (last, update_flags last flags) end
   635       else (common, flags);
   636   in (assign_update', common', flags') end;
   637 
   638 fun illegal_init _ = error "Illegal theory header";
   639 
   640 fun new_exec keywords state node proper_init command_id' (assign_update, command_exec, init) =
   641   if not proper_init andalso is_none init then NONE
   642   else
   643     let
   644       val command_visible = visible_command node command_id';
   645       val command_overlays = overlays node command_id';
   646       val (command_name, blob_digests, blobs_index, span0) = the_command state command_id';
   647       val blobs = map (resolve_blob state) blob_digests;
   648       val span = Lazy.force span0;
   649 
   650       val eval' =
   651         Command.eval keywords (master_directory node) (fn () => the_default illegal_init init span)
   652           (blobs, blobs_index) command_id' span (#1 (#2 command_exec));
   653       val prints' =
   654         perhaps (Command.print command_visible command_overlays keywords command_name eval') [];
   655       val exec' = (eval', prints');
   656 
   657       val assign_update' = assign_update_new (command_id', SOME exec') assign_update;
   658       val init' = if command_name = Thy_Header.theoryN then NONE else init;
   659     in SOME (assign_update', (command_id', exec'), init') end;
   660 
   661 fun removed_execs node0 (command_id, exec_ids) =
   662   subtract (op =) exec_ids (Command.exec_ids (lookup_entry node0 command_id));
   663 
   664 fun print_consolidation options the_command_span node_name (assign_update, node) =
   665   (case finished_result_theory node of
   666     SOME (result_id, thy) =>
   667       let
   668         val eval_ids =
   669           iterate_entries (fn (_, opt_exec) => fn eval_ids =>
   670             (case opt_exec of
   671               SOME (eval, _) => SOME (cons (Command.eval_exec_id eval) eval_ids)
   672             | NONE => NONE)) node [];
   673       in
   674         if null (Execution.snapshot eval_ids) then
   675           let
   676             val consolidation =
   677               if Options.bool options "editor_presentation" then
   678                 let
   679                   val (_, offsets, rev_segments) =
   680                     iterate_entries (fn (_, opt_exec) => fn (offset, offsets, segments) =>
   681                       (case opt_exec of
   682                         SOME (eval, _) =>
   683                           let
   684                             val command_id = Command.eval_command_id eval;
   685                             val span = the_command_span command_id;
   686 
   687                             val exec_id = Command.eval_exec_id eval;
   688                             val tr = Command.eval_result_command eval;
   689                             val st' = Command.eval_result_state eval;
   690 
   691                             val offset' = offset + the_default 0 (Command_Span.symbol_length span);
   692                             val offsets' = offsets
   693                               |> Inttab.update (command_id, offset)
   694                               |> Inttab.update (exec_id, offset);
   695                             val segments' = (span, tr, st') :: segments;
   696                           in SOME (offset', offsets', segments') end
   697                       | NONE => NONE)) node (0, Inttab.empty, []);
   698 
   699                   val adjust = Inttab.lookup offsets;
   700                   val segments =
   701                     rev rev_segments |> map (fn (span, tr, st') =>
   702                       {span = Command_Span.adjust_offsets adjust span, command = tr, state = st'});
   703 
   704                   val presentation_context: Thy_Info.presentation_context =
   705                    {options = options,
   706                     file_pos = Position.file node_name,
   707                     adjust_pos = Position.adjust_offsets adjust,
   708                     segments = segments};
   709                 in
   710                   fn _ =>
   711                     (Thy_Info.apply_presentation presentation_context thy;
   712                      commit_consolidated node)
   713                 end
   714               else fn _ => commit_consolidated node;
   715 
   716             val result_entry =
   717               (case lookup_entry node result_id of
   718                 NONE => err_undef "result command entry" result_id
   719               | SOME (eval, prints) =>
   720                   let
   721                     val print = eval |> Command.print0
   722                       {pri = Task_Queue.urgent_pri + 1, print_fn = K consolidation};
   723                   in (result_id, SOME (eval, print :: prints)) end);
   724 
   725             val assign_update' = assign_update |> assign_update_change result_entry;
   726             val node' = node |> assign_entry result_entry;
   727           in (assign_update', node') end
   728         else (assign_update, node)
   729       end
   730   | NONE => (assign_update, node));
   731 in
   732 
   733 fun update old_version_id new_version_id edits consolidate state =
   734   Runtime.exn_trace_system (fn () =>
   735   let
   736     val options = Options.default ();
   737     val the_command_span = Outer_Syntax.make_span o Lazy.force o #4 o the_command state;
   738 
   739     val old_version = the_version state old_version_id;
   740     val new_version =
   741       timeit "Document.edit_nodes"
   742         (fn () => old_version |> fold edit_nodes edits |> edit_keywords edits);
   743 
   744     val nodes = nodes_of new_version;
   745     val required = make_required nodes;
   746     val required0 = make_required (nodes_of old_version);
   747     val edited = fold (fn (name, _) => Symtab.update (name, ())) edits Symtab.empty;
   748 
   749     val updated = timeit "Document.update" (fn () =>
   750       nodes |> String_Graph.schedule
   751         (fn deps => fn (name, node) =>
   752           (singleton o Future.forks)
   753             {name = "Document.update", group = NONE,
   754               deps = map (Future.task_of o #2) deps, pri = 1, interrupts = false}
   755             (fn () =>
   756               timeit ("Document.update " ^ name) (fn () =>
   757                 Runtime.exn_trace_system (fn () =>
   758                   let
   759                     val root_theory = check_root_theory node;
   760                     val keywords = the_default (Session.get_keywords ()) (get_keywords node);
   761 
   762                     val maybe_consolidate = consolidate andalso could_consolidate node;
   763                     val imports = map (apsnd Future.join) deps;
   764                     val imports_result_changed = exists (#4 o #1 o #2) imports;
   765                     val node_required = Symtab.defined required name;
   766                   in
   767                     if Symtab.defined edited name orelse maybe_consolidate orelse
   768                       visible_node node orelse imports_result_changed orelse
   769                       Symtab.defined required0 name <> node_required
   770                     then
   771                       let
   772                         val node0 = node_of old_version name;
   773                         val init = init_theory imports node;
   774                         val proper_init =
   775                           is_some root_theory orelse
   776                             check_theory false name node andalso
   777                             forall (fn (name, (_, node)) => check_theory true name node) imports;
   778 
   779                         val (print_execs, common, (still_visible, initial)) =
   780                           if imports_result_changed then (assign_update_empty, NONE, (true, true))
   781                           else last_common keywords state node_required node0 node;
   782 
   783                         val common_command_exec =
   784                           (case common of
   785                             SOME id => (id, the_default Command.no_exec (the_entry node id))
   786                           | NONE => (Document_ID.none, Command.init_exec root_theory));
   787 
   788                         val (updated_execs, (command_id', exec'), _) =
   789                           (print_execs, common_command_exec, if initial then SOME init else NONE)
   790                           |> (still_visible orelse node_required) ?
   791                             iterate_entries_after common
   792                               (fn ((prev, id), _) => fn res =>
   793                                 if not node_required andalso prev = visible_last node then NONE
   794                                 else new_exec keywords state node proper_init id res) node;
   795 
   796                         val assign_update =
   797                           (node0, updated_execs) |-> iterate_entries_after common
   798                             (fn ((_, command_id0), exec0) => fn res =>
   799                               if is_none exec0 then NONE
   800                               else if assign_update_defined updated_execs command_id0 then SOME res
   801                               else SOME (assign_update_new (command_id0, NONE) res));
   802 
   803                         val last_exec =
   804                           if command_id' = Document_ID.none then NONE else SOME command_id';
   805                         val result =
   806                           if is_none last_exec orelse is_some (after_entry node last_exec) then NONE
   807                           else SOME (command_id', #1 exec');
   808 
   809                         val result_changed =
   810                           not (eq_option (Command.eval_eq o apply2 #2) (get_result node0, result));
   811                         val (assign_update', node') = node
   812                           |> assign_update_apply assign_update
   813                           |> set_result result
   814                           |> result_changed ? reset_consolidated
   815                           |> pair assign_update
   816                           |> (not result_changed andalso maybe_consolidate) ?
   817                               print_consolidation options the_command_span name;
   818 
   819                         val assign_result = assign_update_result assign_update';
   820                         val removed = maps (removed_execs node0) assign_result;
   821                         val _ = List.app Execution.cancel removed;
   822 
   823                         val assigned_node = SOME (name, node');
   824                       in ((removed, assign_result, assigned_node, result_changed), node') end
   825                     else (([], [], NONE, false), node)
   826                   end))))
   827       |> Future.joins |> map #1);
   828 
   829     val removed = maps #1 updated;
   830     val assign_result = maps #2 updated;
   831     val assigned_nodes = map_filter #3 updated;
   832 
   833     val state' = state
   834       |> define_version new_version_id (fold put_node assigned_nodes new_version);
   835 
   836   in (removed, assign_result, state') end);
   837 
   838 end;
   839 
   840 
   841 
   842 (** global state **)
   843 
   844 val global_state = Synchronized.var "Document.global_state" init_state;
   845 
   846 fun state () = Synchronized.value global_state;
   847 val change_state = Synchronized.change global_state;
   848 
   849 end;