src/HOL/Transcendental.thy
author huffman
Fri Aug 19 07:45:22 2011 -0700 (2011-08-19)
changeset 44305 3bdc02eb1637
parent 44289 d81d09cdab9c
child 44307 6a383003d0a9
permissions -rw-r--r--
remove some redundant simp rules
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4 *)
     5 
     6 header{*Power Series, Transcendental Functions etc.*}
     7 
     8 theory Transcendental
     9 imports Fact Series Deriv NthRoot
    10 begin
    11 
    12 subsection {* Properties of Power Series *}
    13 
    14 lemma lemma_realpow_diff:
    15   fixes y :: "'a::monoid_mult"
    16   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    17 proof -
    18   assume "p \<le> n"
    19   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    20   thus ?thesis by (simp add: power_commutes)
    21 qed
    22 
    23 lemma lemma_realpow_diff_sumr:
    24   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    25      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =
    26       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    27 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    28          del: setsum_op_ivl_Suc)
    29 
    30 lemma lemma_realpow_diff_sumr2:
    31   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    32      "x ^ (Suc n) - y ^ (Suc n) =
    33       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    34 apply (induct n, simp)
    35 apply (simp del: setsum_op_ivl_Suc)
    36 apply (subst setsum_op_ivl_Suc)
    37 apply (subst lemma_realpow_diff_sumr)
    38 apply (simp add: right_distrib del: setsum_op_ivl_Suc)
    39 apply (subst mult_left_commute [of "x - y"])
    40 apply (erule subst)
    41 apply (simp add: algebra_simps)
    42 done
    43 
    44 lemma lemma_realpow_rev_sumr:
    45      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =
    46       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    47 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    48 apply (rule inj_onI, simp)
    49 apply auto
    50 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    51 done
    52 
    53 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    54 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    55 
    56 lemma powser_insidea:
    57   fixes x z :: "'a::{real_normed_field,banach}"
    58   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    59   assumes 2: "norm z < norm x"
    60   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    61 proof -
    62   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    63   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    64     by (rule summable_LIMSEQ_zero)
    65   hence "convergent (\<lambda>n. f n * x ^ n)"
    66     by (rule convergentI)
    67   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    68     by (simp add: Cauchy_convergent_iff)
    69   hence "Bseq (\<lambda>n. f n * x ^ n)"
    70     by (rule Cauchy_Bseq)
    71   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    72     by (simp add: Bseq_def, safe)
    73   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    74                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    75   proof (intro exI allI impI)
    76     fix n::nat assume "0 \<le> n"
    77     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    78           norm (f n * x ^ n) * norm (z ^ n)"
    79       by (simp add: norm_mult abs_mult)
    80     also have "\<dots> \<le> K * norm (z ^ n)"
    81       by (simp only: mult_right_mono 4 norm_ge_zero)
    82     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    83       by (simp add: x_neq_0)
    84     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    85       by (simp only: mult_assoc)
    86     finally show "norm (norm (f n * z ^ n)) \<le>
    87                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    88       by (simp add: mult_le_cancel_right x_neq_0)
    89   qed
    90   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    91   proof -
    92     from 2 have "norm (norm (z * inverse x)) < 1"
    93       using x_neq_0
    94       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    95     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    96       by (rule summable_geometric)
    97     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
    98       by (rule summable_mult)
    99     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   100       using x_neq_0
   101       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   102                     power_inverse norm_power mult_assoc)
   103   qed
   104   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   105     by (rule summable_comparison_test)
   106 qed
   107 
   108 lemma powser_inside:
   109   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   110      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]
   111       ==> summable (%n. f(n) * (z ^ n))"
   112 by (rule powser_insidea [THEN summable_norm_cancel])
   113 
   114 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   115   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) =
   116    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   117 proof (induct n)
   118   case (Suc n)
   119   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) =
   120         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   121     using Suc.hyps unfolding One_nat_def by auto
   122   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   123   finally show ?case .
   124 qed auto
   125 
   126 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   127   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   128   unfolding sums_def
   129 proof (rule LIMSEQ_I)
   130   fix r :: real assume "0 < r"
   131   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   132   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   133 
   134   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   135   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   136     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }"
   137       using sum_split_even_odd by auto
   138     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   139     moreover
   140     have "?SUM (2 * (m div 2)) = ?SUM m"
   141     proof (cases "even m")
   142       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   143     next
   144       case False hence "even (Suc m)" by auto
   145       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   146       have eq: "Suc (2 * (m div 2)) = m" by auto
   147       hence "even (2 * (m div 2))" using `odd m` by auto
   148       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   149       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   150       finally show ?thesis by auto
   151     qed
   152     ultimately have "(norm (?SUM m - x) < r)" by auto
   153   }
   154   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   155 qed
   156 
   157 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   158   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   159 proof -
   160   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   161   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   162       by (cases B) auto } note if_sum = this
   163   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   164   {
   165     have "?s 0 = 0" by auto
   166     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   167     have if_eq: "\<And>B T E. (if \<not> B then T else E) = (if B then E else T)" by auto
   168 
   169     have "?s sums y" using sums_if'[OF `f sums y`] .
   170     from this[unfolded sums_def, THEN LIMSEQ_Suc]
   171     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   172       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   173                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   174                 even_Suc Suc_m1 if_eq .
   175   } from sums_add[OF g_sums this]
   176   show ?thesis unfolding if_sum .
   177 qed
   178 
   179 subsection {* Alternating series test / Leibniz formula *}
   180 
   181 lemma sums_alternating_upper_lower:
   182   fixes a :: "nat \<Rightarrow> real"
   183   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   184   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and>
   185              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   186   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   187 proof -
   188   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   189 
   190   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   191   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   192   moreover
   193   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   194   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   195     unfolding One_nat_def by auto qed
   196   moreover
   197   have "\<forall> n. ?f n \<le> ?g n"
   198   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   199     unfolding One_nat_def by auto qed
   200   moreover
   201   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   202   proof (rule LIMSEQ_I)
   203     fix r :: real assume "0 < r"
   204     with `a ----> 0`[THEN LIMSEQ_D]
   205     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   206     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   207     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   208   qed
   209   ultimately
   210   show ?thesis by (rule lemma_nest_unique)
   211 qed
   212 
   213 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   214   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   215   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   216   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   217   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   218   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   219   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221 proof -
   222   let "?S n" = "(-1)^n * a n"
   223   let "?P n" = "\<Sum>i=0..<n. ?S i"
   224   let "?f n" = "?P (2 * n)"
   225   let "?g n" = "?P (2 * n + 1)"
   226   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   227     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   228 
   229   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   230   have "?Sa ----> l"
   231   proof (rule LIMSEQ_I)
   232     fix r :: real assume "0 < r"
   233 
   234     with `?f ----> l`[THEN LIMSEQ_D]
   235     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   236 
   237     from `0 < r` `?g ----> l`[THEN LIMSEQ_D]
   238     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   239 
   240     { fix n :: nat
   241       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   242       have "norm (?Sa n - l) < r"
   243       proof (cases "even n")
   244         case True from even_nat_div_two_times_two[OF this]
   245         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   246         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   247         from f[OF this]
   248         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   249       next
   250         case False hence "even (n - 1)" by simp
   251         from even_nat_div_two_times_two[OF this]
   252         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   253         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   254 
   255         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   256         from g[OF this]
   257         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   258       qed
   259     }
   260     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   261   qed
   262   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   263   thus "summable ?S" using summable_def by auto
   264 
   265   have "l = suminf ?S" using sums_unique[OF sums_l] .
   266 
   267   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   268   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   269   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   270   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   271 qed
   272 
   273 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   274   assumes a_zero: "a ----> 0" and "monoseq a"
   275   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   276   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   277   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   278   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   279   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   280 proof -
   281   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   282   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   283     case True
   284     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   285     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   286     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   287     from leibniz[OF mono]
   288     show ?thesis using `0 \<le> a 0` by auto
   289   next
   290     let ?a = "\<lambda> n. - a n"
   291     case False
   292     with monoseq_le[OF `monoseq a` `a ----> 0`]
   293     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   294     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   295     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   296     note monotone = this
   297     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF LIMSEQ_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   298     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   299     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   300     from this[THEN sums_minus]
   301     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   302     hence ?summable unfolding summable_def by auto
   303     moreover
   304     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   305 
   306     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   307     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   308 
   309     have ?pos using `0 \<le> ?a 0` by auto
   310     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   311     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN LIMSEQ_minus_cancel] by auto
   312     ultimately show ?thesis by auto
   313   qed
   314   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   315        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   316   show ?summable and ?pos and ?neg and ?f and ?g .
   317 qed
   318 
   319 subsection {* Term-by-Term Differentiability of Power Series *}
   320 
   321 definition
   322   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   323   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   324 
   325 text{*Lemma about distributing negation over it*}
   326 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   327 by (simp add: diffs_def)
   328 
   329 lemma sums_Suc_imp:
   330   assumes f: "f 0 = 0"
   331   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   332 unfolding sums_def
   333 apply (rule LIMSEQ_imp_Suc)
   334 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   335 apply (simp only: setsum_shift_bounds_Suc_ivl)
   336 done
   337 
   338 lemma diffs_equiv:
   339   fixes x :: "'a::{real_normed_vector, ring_1}"
   340   shows "summable (%n. (diffs c)(n) * (x ^ n)) ==>
   341       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums
   342          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   343 unfolding diffs_def
   344 apply (drule summable_sums)
   345 apply (rule sums_Suc_imp, simp_all)
   346 done
   347 
   348 lemma lemma_termdiff1:
   349   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   350   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =
   351    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   352 by(auto simp add: algebra_simps power_add [symmetric])
   353 
   354 lemma sumr_diff_mult_const2:
   355   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   356 by (simp add: setsum_subtractf)
   357 
   358 lemma lemma_termdiff2:
   359   fixes h :: "'a :: {field}"
   360   assumes h: "h \<noteq> 0" shows
   361   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   362    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   363         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   364 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   365 apply (simp add: right_diff_distrib diff_divide_distrib h)
   366 apply (simp add: mult_assoc [symmetric])
   367 apply (cases "n", simp)
   368 apply (simp add: lemma_realpow_diff_sumr2 h
   369                  right_diff_distrib [symmetric] mult_assoc
   370             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   371 apply (subst lemma_realpow_rev_sumr)
   372 apply (subst sumr_diff_mult_const2)
   373 apply simp
   374 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   375 apply (rule setsum_cong [OF refl])
   376 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   377 apply (clarify)
   378 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   379             del: setsum_op_ivl_Suc power_Suc)
   380 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   381 apply (simp add: mult_ac)
   382 done
   383 
   384 lemma real_setsum_nat_ivl_bounded2:
   385   fixes K :: "'a::linordered_semidom"
   386   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   387   assumes K: "0 \<le> K"
   388   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   389 apply (rule order_trans [OF setsum_mono])
   390 apply (rule f, simp)
   391 apply (simp add: mult_right_mono K)
   392 done
   393 
   394 lemma lemma_termdiff3:
   395   fixes h z :: "'a::{real_normed_field}"
   396   assumes 1: "h \<noteq> 0"
   397   assumes 2: "norm z \<le> K"
   398   assumes 3: "norm (z + h) \<le> K"
   399   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   400           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   401 proof -
   402   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   403         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   404           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   405     apply (subst lemma_termdiff2 [OF 1])
   406     apply (subst norm_mult)
   407     apply (rule mult_commute)
   408     done
   409   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   410   proof (rule mult_right_mono [OF _ norm_ge_zero])
   411     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   412     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   413       apply (erule subst)
   414       apply (simp only: norm_mult norm_power power_add)
   415       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   416       done
   417     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   418               (z + h) ^ q * z ^ (n - 2 - q))
   419           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   420       apply (intro
   421          order_trans [OF norm_setsum]
   422          real_setsum_nat_ivl_bounded2
   423          mult_nonneg_nonneg
   424          zero_le_imp_of_nat
   425          zero_le_power K)
   426       apply (rule le_Kn, simp)
   427       done
   428   qed
   429   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   430     by (simp only: mult_assoc)
   431   finally show ?thesis .
   432 qed
   433 
   434 lemma lemma_termdiff4:
   435   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   436               'b::real_normed_vector"
   437   assumes k: "0 < (k::real)"
   438   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   439   shows "f -- 0 --> 0"
   440 unfolding LIM_eq diff_0_right
   441 proof (safe)
   442   let ?h = "of_real (k / 2)::'a"
   443   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   444   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   445   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   446   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   447 
   448   fix r::real assume r: "0 < r"
   449   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   450   proof (cases)
   451     assume "K = 0"
   452     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   453       by simp
   454     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   455   next
   456     assume K_neq_zero: "K \<noteq> 0"
   457     with zero_le_K have K: "0 < K" by simp
   458     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   459     proof (rule exI, safe)
   460       from k r K show "0 < min k (r * inverse K / 2)"
   461         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   462     next
   463       fix x::'a
   464       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   465       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   466         by simp_all
   467       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   468       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   469         by (rule mult_strict_left_mono)
   470       also have "\<dots> = r / 2"
   471         using K_neq_zero by simp
   472       also have "r / 2 < r"
   473         using r by simp
   474       finally show "norm (f x) < r" .
   475     qed
   476   qed
   477 qed
   478 
   479 lemma lemma_termdiff5:
   480   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   481               nat \<Rightarrow> 'b::banach"
   482   assumes k: "0 < (k::real)"
   483   assumes f: "summable f"
   484   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   485   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   486 proof (rule lemma_termdiff4 [OF k])
   487   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   488   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   489     by (simp add: le)
   490   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   491     by simp
   492   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   493     by (rule summable_mult2)
   494   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   495     by (rule summable_comparison_test)
   496   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   497     by (rule summable_norm)
   498   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   499     by (rule summable_le)
   500   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   501     by (rule suminf_mult2 [symmetric])
   502   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   503 qed
   504 
   505 
   506 text{* FIXME: Long proofs*}
   507 
   508 lemma termdiffs_aux:
   509   fixes x :: "'a::{real_normed_field,banach}"
   510   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   511   assumes 2: "norm x < norm K"
   512   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   513              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   514 proof -
   515   from dense [OF 2]
   516   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   517   from norm_ge_zero r1 have r: "0 < r"
   518     by (rule order_le_less_trans)
   519   hence r_neq_0: "r \<noteq> 0" by simp
   520   show ?thesis
   521   proof (rule lemma_termdiff5)
   522     show "0 < r - norm x" using r1 by simp
   523   next
   524     from r r2 have "norm (of_real r::'a) < norm K"
   525       by simp
   526     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   527       by (rule powser_insidea)
   528     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   529       using r
   530       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   531     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   532       by (rule diffs_equiv [THEN sums_summable])
   533     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   534       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   535       apply (rule ext)
   536       apply (simp add: diffs_def)
   537       apply (case_tac n, simp_all add: r_neq_0)
   538       done
   539     finally have "summable
   540       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   541       by (rule diffs_equiv [THEN sums_summable])
   542     also have
   543       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   544            r ^ (n - Suc 0)) =
   545        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   546       apply (rule ext)
   547       apply (case_tac "n", simp)
   548       apply (case_tac "nat", simp)
   549       apply (simp add: r_neq_0)
   550       done
   551     finally show
   552       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   553   next
   554     fix h::'a and n::nat
   555     assume h: "h \<noteq> 0"
   556     assume "norm h < r - norm x"
   557     hence "norm x + norm h < r" by simp
   558     with norm_triangle_ineq have xh: "norm (x + h) < r"
   559       by (rule order_le_less_trans)
   560     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   561           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   562       apply (simp only: norm_mult mult_assoc)
   563       apply (rule mult_left_mono [OF _ norm_ge_zero])
   564       apply (simp (no_asm) add: mult_assoc [symmetric])
   565       apply (rule lemma_termdiff3)
   566       apply (rule h)
   567       apply (rule r1 [THEN order_less_imp_le])
   568       apply (rule xh [THEN order_less_imp_le])
   569       done
   570   qed
   571 qed
   572 
   573 lemma termdiffs:
   574   fixes K x :: "'a::{real_normed_field,banach}"
   575   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   576   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   577   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   578   assumes 4: "norm x < norm K"
   579   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   580 unfolding deriv_def
   581 proof (rule LIM_zero_cancel)
   582   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   583             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   584   proof (rule LIM_equal2)
   585     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   586   next
   587     fix h :: 'a
   588     assume "h \<noteq> 0"
   589     assume "norm (h - 0) < norm K - norm x"
   590     hence "norm x + norm h < norm K" by simp
   591     hence 5: "norm (x + h) < norm K"
   592       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   593     have A: "summable (\<lambda>n. c n * x ^ n)"
   594       by (rule powser_inside [OF 1 4])
   595     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   596       by (rule powser_inside [OF 1 5])
   597     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   598       by (rule powser_inside [OF 2 4])
   599     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   600              - (\<Sum>n. diffs c n * x ^ n) =
   601           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   602       apply (subst sums_unique [OF diffs_equiv [OF C]])
   603       apply (subst suminf_diff [OF B A])
   604       apply (subst suminf_divide [symmetric])
   605       apply (rule summable_diff [OF B A])
   606       apply (subst suminf_diff)
   607       apply (rule summable_divide)
   608       apply (rule summable_diff [OF B A])
   609       apply (rule sums_summable [OF diffs_equiv [OF C]])
   610       apply (rule arg_cong [where f="suminf"], rule ext)
   611       apply (simp add: algebra_simps)
   612       done
   613   next
   614     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   615                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   616         by (rule termdiffs_aux [OF 3 4])
   617   qed
   618 qed
   619 
   620 
   621 subsection {* Derivability of power series *}
   622 
   623 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   624   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   625   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   626   and "summable (f' x0)"
   627   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   628   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   629   unfolding deriv_def
   630 proof (rule LIM_I)
   631   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   632 
   633   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3"
   634     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   635 
   636   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3"
   637     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   638 
   639   let ?N = "Suc (max N_L N_f')"
   640   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   641     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   642 
   643   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   644 
   645   let ?r = "r / (3 * real ?N)"
   646   have "0 < 3 * real ?N" by auto
   647   from divide_pos_pos[OF `0 < r` this]
   648   have "0 < ?r" .
   649 
   650   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   651   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   652 
   653   have "0 < S'" unfolding S'_def
   654   proof (rule iffD2[OF Min_gr_iff])
   655     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   656     proof (rule ballI)
   657       fix x assume "x \<in> ?s ` {0..<?N}"
   658       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   659       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def]
   660       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   661       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   662       thus "0 < x" unfolding `x = ?s n` .
   663     qed
   664   qed auto
   665 
   666   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   667   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   668     by auto
   669 
   670   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   671     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   672 
   673     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   674     note div_smbl = summable_divide[OF diff_smbl]
   675     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   676     note ign = summable_ignore_initial_segment[where k="?N"]
   677     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   678     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   679     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   680 
   681     { fix n
   682       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>"
   683         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   684       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   685     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   686     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   687     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   688     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   689 
   690     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   691     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   692     proof (rule setsum_strict_mono)
   693       fix n assume "n \<in> { 0 ..< ?N}"
   694       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   695       also have "S \<le> S'" using `S \<le> S'` .
   696       also have "S' \<le> ?s n" unfolding S'_def
   697       proof (rule Min_le_iff[THEN iffD2])
   698         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   699         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   700       qed auto
   701       finally have "\<bar> x \<bar> < ?s n" .
   702 
   703       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   704       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   705       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   706       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   707     qed auto
   708     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   709     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   710     also have "\<dots> = r/3" by auto
   711     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   712 
   713     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   714     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> =
   715                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   716     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   717     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   718     also have "\<dots> < r /3 + r/3 + r/3"
   719       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3`
   720       by (rule add_strict_mono [OF add_less_le_mono])
   721     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   722       by auto
   723   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow>
   724       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   725     unfolding real_norm_def diff_0_right by blast
   726 qed
   727 
   728 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   729   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   730   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   731   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   732   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   733 proof -
   734   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   735     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   736     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   737     proof (rule DERIV_series')
   738       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   739       proof -
   740         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   741         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   742         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   743         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   744       qed
   745       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   746         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   747         proof -
   748           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>"
   749             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   750           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)"
   751           proof (rule mult_left_mono)
   752             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   753             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   754             proof (rule setsum_mono)
   755               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   756               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   757                 hence "\<bar>x\<bar> \<le> R'"  by auto
   758                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   759               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   760               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   761               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   762             qed
   763             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   764             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   765             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   766           qed
   767           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult mult_assoc[symmetric] by algebra
   768           finally show ?thesis .
   769         qed }
   770       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   771           by (auto intro!: DERIV_intros simp del: power_Suc) }
   772       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   773         have "summable (\<lambda> n. f n * x^n)"
   774         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   775           fix n
   776           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   777           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   778             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   779         qed
   780         from this[THEN summable_mult2[where c=x], unfolded mult_assoc, unfolded mult_commute]
   781         show "summable (?f x)" by auto }
   782       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   783       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   784     qed
   785   } note for_subinterval = this
   786   let ?R = "(R + \<bar>x0\<bar>) / 2"
   787   have "\<bar>x0\<bar> < ?R" using assms by auto
   788   hence "- ?R < x0"
   789   proof (cases "x0 < 0")
   790     case True
   791     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   792     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   793   next
   794     case False
   795     have "- ?R < 0" using assms by auto
   796     also have "\<dots> \<le> x0" using False by auto
   797     finally show ?thesis .
   798   qed
   799   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   800   from for_subinterval[OF this]
   801   show ?thesis .
   802 qed
   803 
   804 subsection {* Exponential Function *}
   805 
   806 definition
   807   exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   808   "exp x = (\<Sum>n. x ^ n /\<^sub>R real (fact n))"
   809 
   810 lemma summable_exp_generic:
   811   fixes x :: "'a::{real_normed_algebra_1,banach}"
   812   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   813   shows "summable S"
   814 proof -
   815   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   816     unfolding S_def by (simp del: mult_Suc)
   817   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   818     using dense [OF zero_less_one] by fast
   819   obtain N :: nat where N: "norm x < real N * r"
   820     using reals_Archimedean3 [OF r0] by fast
   821   from r1 show ?thesis
   822   proof (rule ratio_test [rule_format])
   823     fix n :: nat
   824     assume n: "N \<le> n"
   825     have "norm x \<le> real N * r"
   826       using N by (rule order_less_imp_le)
   827     also have "real N * r \<le> real (Suc n) * r"
   828       using r0 n by (simp add: mult_right_mono)
   829     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   830       using norm_ge_zero by (rule mult_right_mono)
   831     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   832       by (rule order_trans [OF norm_mult_ineq])
   833     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   834       by (simp add: pos_divide_le_eq mult_ac)
   835     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   836       by (simp add: S_Suc inverse_eq_divide)
   837   qed
   838 qed
   839 
   840 lemma summable_norm_exp:
   841   fixes x :: "'a::{real_normed_algebra_1,banach}"
   842   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   843 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   844   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   845     by (rule summable_exp_generic)
   846 next
   847   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   848     by (simp add: norm_power_ineq)
   849 qed
   850 
   851 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   852 by (insert summable_exp_generic [where x=x], simp)
   853 
   854 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   855 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   856 
   857 
   858 lemma exp_fdiffs:
   859       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   860 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   861          del: mult_Suc of_nat_Suc)
   862 
   863 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   864 by (simp add: diffs_def)
   865 
   866 lemma lemma_exp_ext: "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   867 by (auto simp add: exp_def)
   868 
   869 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   870 apply (simp add: exp_def)
   871 apply (subst lemma_exp_ext)
   872 apply (subgoal_tac "DERIV (\<lambda>u. \<Sum>n. of_real (inverse (real (fact n))) * u ^ n) x :> (\<Sum>n. diffs (\<lambda>n. of_real (inverse (real (fact n)))) n * x ^ n)")
   873 apply (rule_tac [2] K = "of_real (1 + norm x)" in termdiffs)
   874 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   875 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   876 apply (simp del: of_real_add)
   877 done
   878 
   879 lemma isCont_exp [simp]: "isCont exp x"
   880 by (rule DERIV_exp [THEN DERIV_isCont])
   881 
   882 
   883 subsubsection {* Properties of the Exponential Function *}
   884 
   885 lemma powser_zero:
   886   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   887   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   888 proof -
   889   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   890     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   891   thus ?thesis unfolding One_nat_def by simp
   892 qed
   893 
   894 lemma exp_zero [simp]: "exp 0 = 1"
   895 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   896 
   897 lemma setsum_cl_ivl_Suc2:
   898   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   899 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   900          del: setsum_cl_ivl_Suc)
   901 
   902 lemma exp_series_add:
   903   fixes x y :: "'a::{real_field}"
   904   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   905   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   906 proof (induct n)
   907   case 0
   908   show ?case
   909     unfolding S_def by simp
   910 next
   911   case (Suc n)
   912   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   913     unfolding S_def by (simp del: mult_Suc)
   914   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   915     by simp
   916 
   917   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   918     by (simp only: times_S)
   919   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   920     by (simp only: Suc)
   921   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   922                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   923     by (rule left_distrib)
   924   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   925                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   926     by (simp only: setsum_right_distrib mult_ac)
   927   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   928                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   929     by (simp add: times_S Suc_diff_le)
   930   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   931              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   932     by (subst setsum_cl_ivl_Suc2, simp)
   933   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   934              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   935     by (subst setsum_cl_ivl_Suc, simp)
   936   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   937              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   938              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   939     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   940               real_of_nat_add [symmetric], simp)
   941   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   942     by (simp only: scaleR_right.setsum)
   943   finally show
   944     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   945     by (simp del: setsum_cl_ivl_Suc)
   946 qed
   947 
   948 lemma exp_add: "exp (x + y) = exp x * exp y"
   949 unfolding exp_def
   950 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   951 
   952 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   953 by (rule exp_add [symmetric])
   954 
   955 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   956 unfolding exp_def
   957 apply (subst suminf_of_real)
   958 apply (rule summable_exp_generic)
   959 apply (simp add: scaleR_conv_of_real)
   960 done
   961 
   962 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   963 proof
   964   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   965   also assume "exp x = 0"
   966   finally show "False" by simp
   967 qed
   968 
   969 lemma exp_minus: "exp (- x) = inverse (exp x)"
   970 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   971 
   972 lemma exp_diff: "exp (x - y) = exp x / exp y"
   973   unfolding diff_minus divide_inverse
   974   by (simp add: exp_add exp_minus)
   975 
   976 
   977 subsubsection {* Properties of the Exponential Function on Reals *}
   978 
   979 text {* Comparisons of @{term "exp x"} with zero. *}
   980 
   981 text{*Proof: because every exponential can be seen as a square.*}
   982 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   983 proof -
   984   have "0 \<le> exp (x/2) * exp (x/2)" by simp
   985   thus ?thesis by (simp add: exp_add [symmetric])
   986 qed
   987 
   988 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
   989 by (simp add: order_less_le)
   990 
   991 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
   992 by (simp add: not_less)
   993 
   994 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
   995 by (simp add: not_le)
   996 
   997 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
   998 by simp
   999 
  1000 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1001 apply (induct "n")
  1002 apply (auto simp add: real_of_nat_Suc right_distrib exp_add mult_commute)
  1003 done
  1004 
  1005 text {* Strict monotonicity of exponential. *}
  1006 
  1007 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1008 apply (drule order_le_imp_less_or_eq, auto)
  1009 apply (simp add: exp_def)
  1010 apply (rule order_trans)
  1011 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1012 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1013 done
  1014 
  1015 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1016 proof -
  1017   assume x: "0 < x"
  1018   hence "1 < 1 + x" by simp
  1019   also from x have "1 + x \<le> exp x"
  1020     by (simp add: exp_ge_add_one_self_aux)
  1021   finally show ?thesis .
  1022 qed
  1023 
  1024 lemma exp_less_mono:
  1025   fixes x y :: real
  1026   assumes "x < y" shows "exp x < exp y"
  1027 proof -
  1028   from `x < y` have "0 < y - x" by simp
  1029   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1030   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1031   thus "exp x < exp y" by simp
  1032 qed
  1033 
  1034 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1035 apply (simp add: linorder_not_le [symmetric])
  1036 apply (auto simp add: order_le_less exp_less_mono)
  1037 done
  1038 
  1039 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1040 by (auto intro: exp_less_mono exp_less_cancel)
  1041 
  1042 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1043 by (auto simp add: linorder_not_less [symmetric])
  1044 
  1045 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1046 by (simp add: order_eq_iff)
  1047 
  1048 text {* Comparisons of @{term "exp x"} with one. *}
  1049 
  1050 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1051   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1052 
  1053 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1054   using exp_less_cancel_iff [where x=x and y=0] by simp
  1055 
  1056 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1057   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1058 
  1059 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1060   using exp_le_cancel_iff [where x=x and y=0] by simp
  1061 
  1062 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1063   using exp_inj_iff [where x=x and y=0] by simp
  1064 
  1065 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1066 apply (rule IVT)
  1067 apply (auto intro: isCont_exp simp add: le_diff_eq)
  1068 apply (subgoal_tac "1 + (y - 1) \<le> exp (y - 1)")
  1069 apply simp
  1070 apply (rule exp_ge_add_one_self_aux, simp)
  1071 done
  1072 
  1073 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1074 apply (rule_tac x = 1 and y = y in linorder_cases)
  1075 apply (drule order_less_imp_le [THEN lemma_exp_total])
  1076 apply (rule_tac [2] x = 0 in exI)
  1077 apply (frule_tac [3] one_less_inverse)
  1078 apply (drule_tac [4] order_less_imp_le [THEN lemma_exp_total], auto)
  1079 apply (rule_tac x = "-x" in exI)
  1080 apply (simp add: exp_minus)
  1081 done
  1082 
  1083 
  1084 subsection {* Natural Logarithm *}
  1085 
  1086 definition
  1087   ln :: "real => real" where
  1088   "ln x = (THE u. exp u = x)"
  1089 
  1090 lemma ln_exp [simp]: "ln (exp x) = x"
  1091 by (simp add: ln_def)
  1092 
  1093 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1094 by (auto dest: exp_total)
  1095 
  1096 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1097 apply (rule iffI)
  1098 apply (erule subst, rule exp_gt_zero)
  1099 apply (erule exp_ln)
  1100 done
  1101 
  1102 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1103 by (erule subst, rule ln_exp)
  1104 
  1105 lemma ln_one [simp]: "ln 1 = 0"
  1106 by (rule ln_unique, simp)
  1107 
  1108 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1109 by (rule ln_unique, simp add: exp_add)
  1110 
  1111 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1112 by (rule ln_unique, simp add: exp_minus)
  1113 
  1114 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1115 by (rule ln_unique, simp add: exp_diff)
  1116 
  1117 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1118 by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1119 
  1120 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1121 by (subst exp_less_cancel_iff [symmetric], simp)
  1122 
  1123 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1124 by (simp add: linorder_not_less [symmetric])
  1125 
  1126 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1127 by (simp add: order_eq_iff)
  1128 
  1129 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1130 apply (rule exp_le_cancel_iff [THEN iffD1])
  1131 apply (simp add: exp_ge_add_one_self_aux)
  1132 done
  1133 
  1134 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1135 by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1136 
  1137 lemma ln_ge_zero [simp]:
  1138   assumes x: "1 \<le> x" shows "0 \<le> ln x"
  1139 proof -
  1140   have "0 < x" using x by arith
  1141   hence "exp 0 \<le> exp (ln x)"
  1142     by (simp add: x)
  1143   thus ?thesis by (simp only: exp_le_cancel_iff)
  1144 qed
  1145 
  1146 lemma ln_ge_zero_imp_ge_one:
  1147   assumes ln: "0 \<le> ln x"
  1148       and x:  "0 < x"
  1149   shows "1 \<le> x"
  1150 proof -
  1151   from ln have "ln 1 \<le> ln x" by simp
  1152   thus ?thesis by (simp add: x del: ln_one)
  1153 qed
  1154 
  1155 lemma ln_ge_zero_iff [simp]: "0 < x ==> (0 \<le> ln x) = (1 \<le> x)"
  1156 by (blast intro: ln_ge_zero ln_ge_zero_imp_ge_one)
  1157 
  1158 lemma ln_less_zero_iff [simp]: "0 < x ==> (ln x < 0) = (x < 1)"
  1159 by (insert ln_ge_zero_iff [of x], arith)
  1160 
  1161 lemma ln_gt_zero:
  1162   assumes x: "1 < x" shows "0 < ln x"
  1163 proof -
  1164   have "0 < x" using x by arith
  1165   hence "exp 0 < exp (ln x)" by (simp add: x)
  1166   thus ?thesis  by (simp only: exp_less_cancel_iff)
  1167 qed
  1168 
  1169 lemma ln_gt_zero_imp_gt_one:
  1170   assumes ln: "0 < ln x"
  1171       and x:  "0 < x"
  1172   shows "1 < x"
  1173 proof -
  1174   from ln have "ln 1 < ln x" by simp
  1175   thus ?thesis by (simp add: x del: ln_one)
  1176 qed
  1177 
  1178 lemma ln_gt_zero_iff [simp]: "0 < x ==> (0 < ln x) = (1 < x)"
  1179 by (blast intro: ln_gt_zero ln_gt_zero_imp_gt_one)
  1180 
  1181 lemma ln_eq_zero_iff [simp]: "0 < x ==> (ln x = 0) = (x = 1)"
  1182 by (insert ln_less_zero_iff [of x] ln_gt_zero_iff [of x], arith)
  1183 
  1184 lemma ln_less_zero: "[| 0 < x; x < 1 |] ==> ln x < 0"
  1185 by simp
  1186 
  1187 lemma exp_ln_eq: "exp u = x ==> ln x = u"
  1188 by auto
  1189 
  1190 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1191 apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1192 apply (rule isCont_inverse_function [where f=exp], simp_all)
  1193 done
  1194 
  1195 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1196 apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1197 apply (erule lemma_DERIV_subst [OF DERIV_exp exp_ln])
  1198 apply (simp_all add: abs_if isCont_ln)
  1199 done
  1200 
  1201 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1202   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1203 
  1204 lemma ln_series: assumes "0 < x" and "x < 2"
  1205   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1206 proof -
  1207   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1208 
  1209   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1210   proof (rule DERIV_isconst3[where x=x])
  1211     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1212     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1213     have "1 / x = 1 / (1 - (1 - x))" by auto
  1214     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1215     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1216     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding divide_inverse by auto
  1217     moreover
  1218     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1219     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1220     proof (rule DERIV_power_series')
  1221       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1222       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1223         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1224           unfolding One_nat_def
  1225           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1226       }
  1227     qed
  1228     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1229     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1230     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1231       by (rule DERIV_diff)
  1232     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1233   qed (auto simp add: assms)
  1234   thus ?thesis by auto
  1235 qed
  1236 
  1237 subsection {* Sine and Cosine *}
  1238 
  1239 definition
  1240   sin_coeff :: "nat \<Rightarrow> real" where
  1241   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1242 
  1243 definition
  1244   cos_coeff :: "nat \<Rightarrow> real" where
  1245   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1246 
  1247 definition
  1248   sin :: "real => real" where
  1249   "sin x = (\<Sum>n. sin_coeff n * x ^ n)"
  1250 
  1251 definition
  1252   cos :: "real => real" where
  1253   "cos x = (\<Sum>n. cos_coeff n * x ^ n)"
  1254 
  1255 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1256 unfolding sin_coeff_def
  1257 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1258 apply (rule_tac [2] summable_exp)
  1259 apply (rule_tac x = 0 in exI)
  1260 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1261 done
  1262 
  1263 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1264 unfolding cos_coeff_def
  1265 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1266 apply (rule_tac [2] summable_exp)
  1267 apply (rule_tac x = 0 in exI)
  1268 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1269 done
  1270 
  1271 lemma lemma_STAR_sin:
  1272      "(if even n then 0
  1273        else -1 ^ ((n - Suc 0) div 2)/(real (fact n))) * 0 ^ n = 0"
  1274 by (induct "n", auto)
  1275 
  1276 lemma lemma_STAR_cos:
  1277      "0 < n -->
  1278       -1 ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1279 by (induct "n", auto)
  1280 
  1281 lemma lemma_STAR_cos1:
  1282      "0 < n -->
  1283       (-1) ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1284 by (induct "n", auto)
  1285 
  1286 lemma lemma_STAR_cos2:
  1287   "(\<Sum>n=1..<n. if even n then -1 ^ (n div 2)/(real (fact n)) *  0 ^ n
  1288                          else 0) = 0"
  1289 apply (induct "n")
  1290 apply (case_tac [2] "n", auto)
  1291 done
  1292 
  1293 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1294 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1295 
  1296 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1297 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1298 
  1299 lemma sin_fdiffs: "diffs sin_coeff = cos_coeff"
  1300 unfolding sin_coeff_def cos_coeff_def
  1301 by (auto intro!: ext
  1302          simp add: diffs_def divide_inverse real_of_nat_def of_nat_mult
  1303          simp del: mult_Suc of_nat_Suc)
  1304 
  1305 lemma sin_fdiffs2: "diffs sin_coeff n = cos_coeff n"
  1306 by (simp only: sin_fdiffs)
  1307 
  1308 lemma cos_fdiffs: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1309 unfolding sin_coeff_def cos_coeff_def
  1310 by (auto intro!: ext
  1311          simp add: diffs_def divide_inverse odd_Suc_mult_two_ex real_of_nat_def of_nat_mult
  1312          simp del: mult_Suc of_nat_Suc)
  1313 
  1314 lemma cos_fdiffs2: "diffs cos_coeff n = - sin_coeff n"
  1315 by (simp only: cos_fdiffs)
  1316 
  1317 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1318 
  1319 lemma lemma_sin_minus: "- sin x = (\<Sum>n. - (sin_coeff n * x ^ n))"
  1320 by (auto intro!: sums_unique sums_minus sin_converges)
  1321 
  1322 lemma lemma_sin_ext: "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1323   by (auto simp add: sin_def)
  1324 
  1325 lemma lemma_cos_ext: "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1326   by (auto simp add: cos_def)
  1327 
  1328 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1329 apply (simp add: cos_def)
  1330 apply (subst lemma_sin_ext)
  1331 apply (auto simp add: sin_fdiffs2 [symmetric])
  1332 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1333 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs)
  1334 done
  1335 
  1336 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1337 apply (subst lemma_cos_ext)
  1338 apply (auto simp add: lemma_sin_minus cos_fdiffs2 [symmetric] minus_mult_left)
  1339 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1340 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs diffs_minus)
  1341 done
  1342 
  1343 lemma isCont_sin [simp]: "isCont sin x"
  1344 by (rule DERIV_sin [THEN DERIV_isCont])
  1345 
  1346 lemma isCont_cos [simp]: "isCont cos x"
  1347 by (rule DERIV_cos [THEN DERIV_isCont])
  1348 
  1349 
  1350 declare
  1351   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1352   DERIV_ln_divide[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1353   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1354   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1355 
  1356 subsection {* Properties of Sine and Cosine *}
  1357 
  1358 lemma sin_zero [simp]: "sin 0 = 0"
  1359 unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1360 
  1361 lemma cos_zero [simp]: "cos 0 = 1"
  1362 unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1363 
  1364 lemma DERIV_sin_sin_mult [simp]:
  1365      "DERIV (%x. sin(x)*sin(x)) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1366 by (rule DERIV_mult, auto)
  1367 
  1368 lemma DERIV_sin_sin_mult2 [simp]:
  1369      "DERIV (%x. sin(x)*sin(x)) x :> 2 * cos(x) * sin(x)"
  1370 apply (cut_tac x = x in DERIV_sin_sin_mult)
  1371 apply (auto simp add: mult_assoc)
  1372 done
  1373 
  1374 lemma DERIV_sin_realpow2 [simp]:
  1375      "DERIV (%x. (sin x)\<twosuperior>) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1376 by (auto simp add: numeral_2_eq_2 mult_assoc [symmetric])
  1377 
  1378 lemma DERIV_sin_realpow2a [simp]:
  1379      "DERIV (%x. (sin x)\<twosuperior>) x :> 2 * cos(x) * sin(x)"
  1380 by (auto simp add: numeral_2_eq_2)
  1381 
  1382 lemma DERIV_cos_cos_mult [simp]:
  1383      "DERIV (%x. cos(x)*cos(x)) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1384 by (rule DERIV_mult, auto)
  1385 
  1386 lemma DERIV_cos_cos_mult2 [simp]:
  1387      "DERIV (%x. cos(x)*cos(x)) x :> -2 * cos(x) * sin(x)"
  1388 apply (cut_tac x = x in DERIV_cos_cos_mult)
  1389 apply (auto simp add: mult_ac)
  1390 done
  1391 
  1392 lemma DERIV_cos_realpow2 [simp]:
  1393      "DERIV (%x. (cos x)\<twosuperior>) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1394 by (auto simp add: numeral_2_eq_2 mult_assoc [symmetric])
  1395 
  1396 lemma DERIV_cos_realpow2a [simp]:
  1397      "DERIV (%x. (cos x)\<twosuperior>) x :> -2 * cos(x) * sin(x)"
  1398 by (auto simp add: numeral_2_eq_2)
  1399 
  1400 lemma lemma_DERIV_subst: "[| DERIV f x :> D; D = E |] ==> DERIV f x :> E"
  1401 by auto
  1402 
  1403 lemma DERIV_cos_realpow2b: "DERIV (%x. (cos x)\<twosuperior>) x :> -(2 * cos(x) * sin(x))"
  1404   by (auto intro!: DERIV_intros)
  1405 
  1406 (* most useful *)
  1407 lemma DERIV_cos_cos_mult3 [simp]:
  1408      "DERIV (%x. cos(x)*cos(x)) x :> -(2 * cos(x) * sin(x))"
  1409   by (auto intro!: DERIV_intros)
  1410 
  1411 lemma DERIV_sin_circle_all:
  1412      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :>
  1413              (2*cos(x)*sin(x) - 2*cos(x)*sin(x))"
  1414   by (auto intro!: DERIV_intros)
  1415 
  1416 lemma DERIV_sin_circle_all_zero [simp]:
  1417      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1418 by (cut_tac DERIV_sin_circle_all, auto)
  1419 
  1420 lemma sin_cos_squared_add [simp]: "((sin x)\<twosuperior>) + ((cos x)\<twosuperior>) = 1"
  1421 apply (cut_tac x = x and y = 0 in DERIV_sin_circle_all_zero [THEN DERIV_isconst_all])
  1422 apply (auto simp add: numeral_2_eq_2)
  1423 done
  1424 
  1425 lemma sin_cos_squared_add2 [simp]: "((cos x)\<twosuperior>) + ((sin x)\<twosuperior>) = 1"
  1426 apply (subst add_commute)
  1427 apply (rule sin_cos_squared_add)
  1428 done
  1429 
  1430 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1431 apply (cut_tac x = x in sin_cos_squared_add2)
  1432 apply (simp add: power2_eq_square)
  1433 done
  1434 
  1435 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1436 apply (rule_tac a1 = "(cos x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1437 apply simp
  1438 done
  1439 
  1440 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1441 apply (rule_tac a1 = "(sin x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1442 apply simp
  1443 done
  1444 
  1445 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1446 by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1447 
  1448 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1449 apply (insert abs_sin_le_one [of x])
  1450 apply (simp add: abs_le_iff del: abs_sin_le_one)
  1451 done
  1452 
  1453 lemma sin_le_one [simp]: "sin x \<le> 1"
  1454 apply (insert abs_sin_le_one [of x])
  1455 apply (simp add: abs_le_iff del: abs_sin_le_one)
  1456 done
  1457 
  1458 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1459 by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1460 
  1461 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1462 apply (insert abs_cos_le_one [of x])
  1463 apply (simp add: abs_le_iff del: abs_cos_le_one)
  1464 done
  1465 
  1466 lemma cos_le_one [simp]: "cos x \<le> 1"
  1467 apply (insert abs_cos_le_one [of x])
  1468 apply (simp add: abs_le_iff del: abs_cos_le_one)
  1469 done
  1470 
  1471 lemma DERIV_fun_pow: "DERIV g x :> m ==>
  1472       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1473 unfolding One_nat_def
  1474 apply (rule lemma_DERIV_subst)
  1475 apply (rule_tac f = "(%x. x ^ n)" in DERIV_chain2)
  1476 apply (rule DERIV_pow, auto)
  1477 done
  1478 
  1479 lemma DERIV_fun_exp:
  1480      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1481 apply (rule lemma_DERIV_subst)
  1482 apply (rule_tac f = exp in DERIV_chain2)
  1483 apply (rule DERIV_exp, auto)
  1484 done
  1485 
  1486 lemma DERIV_fun_sin:
  1487      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1488 apply (rule lemma_DERIV_subst)
  1489 apply (rule_tac f = sin in DERIV_chain2)
  1490 apply (rule DERIV_sin, auto)
  1491 done
  1492 
  1493 lemma DERIV_fun_cos:
  1494      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1495 apply (rule lemma_DERIV_subst)
  1496 apply (rule_tac f = cos in DERIV_chain2)
  1497 apply (rule DERIV_cos, auto)
  1498 done
  1499 
  1500 (* lemma *)
  1501 lemma lemma_DERIV_sin_cos_add:
  1502      "\<forall>x.
  1503          DERIV (%x. (sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +
  1504                (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2) x :> 0"
  1505   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1506 
  1507 lemma sin_cos_add [simp]:
  1508      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +
  1509       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1510 apply (cut_tac y = 0 and x = x and y7 = y
  1511        in lemma_DERIV_sin_cos_add [THEN DERIV_isconst_all])
  1512 apply (auto simp add: numeral_2_eq_2)
  1513 done
  1514 
  1515 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1516 apply (cut_tac x = x and y = y in sin_cos_add)
  1517 apply (simp del: sin_cos_add)
  1518 done
  1519 
  1520 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1521 apply (cut_tac x = x and y = y in sin_cos_add)
  1522 apply (simp del: sin_cos_add)
  1523 done
  1524 
  1525 lemma lemma_DERIV_sin_cos_minus:
  1526     "\<forall>x. DERIV (%x. (sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2) x :> 0"
  1527   by (auto intro!: DERIV_intros simp add: algebra_simps)
  1528 
  1529 
  1530 lemma sin_cos_minus:
  1531     "(sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2 = 0"
  1532 apply (cut_tac y = 0 and x = x
  1533        in lemma_DERIV_sin_cos_minus [THEN DERIV_isconst_all])
  1534 apply simp
  1535 done
  1536 
  1537 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1538   using sin_cos_minus [where x=x] by simp
  1539 
  1540 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1541   using sin_cos_minus [where x=x] by simp
  1542 
  1543 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1544 by (simp add: diff_minus sin_add)
  1545 
  1546 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1547 by (simp add: sin_diff mult_commute)
  1548 
  1549 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1550 by (simp add: diff_minus cos_add)
  1551 
  1552 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1553 by (simp add: cos_diff mult_commute)
  1554 
  1555 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1556   using sin_add [where x=x and y=x] by simp
  1557 
  1558 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1559   using cos_add [where x=x and y=x]
  1560   by (simp add: power2_eq_square)
  1561 
  1562 
  1563 subsection {* The Constant Pi *}
  1564 
  1565 definition
  1566   pi :: "real" where
  1567   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1568 
  1569 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"};
  1570    hence define pi.*}
  1571 
  1572 lemma sin_paired:
  1573      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1))
  1574       sums  sin x"
  1575 proof -
  1576   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1577     unfolding sin_def
  1578     by (rule sin_converges [THEN sums_summable, THEN sums_group], simp)
  1579   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1580 qed
  1581 
  1582 text {* FIXME: This is a long, ugly proof! *}
  1583 lemma sin_gt_zero: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1584 apply (subgoal_tac
  1585        "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2.
  1586               -1 ^ k / real (fact (2 * k + 1)) * x ^ (2 * k + 1))
  1587      sums (\<Sum>n. -1 ^ n / real (fact (2 * n + 1)) * x ^ (2 * n + 1))")
  1588  prefer 2
  1589  apply (rule sin_paired [THEN sums_summable, THEN sums_group], simp)
  1590 apply (rotate_tac 2)
  1591 apply (drule sin_paired [THEN sums_unique, THEN ssubst])
  1592 unfolding One_nat_def
  1593 apply (auto simp del: fact_Suc)
  1594 apply (frule sums_unique)
  1595 apply (auto simp del: fact_Suc)
  1596 apply (rule_tac n1 = 0 in series_pos_less [THEN [2] order_le_less_trans])
  1597 apply (auto simp del: fact_Suc)
  1598 apply (erule sums_summable)
  1599 apply (case_tac "m=0")
  1600 apply (simp (no_asm_simp))
  1601 apply (subgoal_tac "6 * (x * (x * x) / real (Suc (Suc (Suc (Suc (Suc (Suc 0))))))) < 6 * x")
  1602 apply (simp only: mult_less_cancel_left, simp)
  1603 apply (simp (no_asm_simp) add: numeral_2_eq_2 [symmetric] mult_assoc [symmetric])
  1604 apply (subgoal_tac "x*x < 2*3", simp)
  1605 apply (rule mult_strict_mono)
  1606 apply (auto simp add: real_0_less_add_iff real_of_nat_Suc simp del: fact_Suc)
  1607 apply (subst fact_Suc)
  1608 apply (subst fact_Suc)
  1609 apply (subst fact_Suc)
  1610 apply (subst fact_Suc)
  1611 apply (subst real_of_nat_mult)
  1612 apply (subst real_of_nat_mult)
  1613 apply (subst real_of_nat_mult)
  1614 apply (subst real_of_nat_mult)
  1615 apply (simp (no_asm) add: divide_inverse del: fact_Suc)
  1616 apply (auto simp add: mult_assoc [symmetric] simp del: fact_Suc)
  1617 apply (rule_tac c="real (Suc (Suc (4*m)))" in mult_less_imp_less_right)
  1618 apply (auto simp add: mult_assoc simp del: fact_Suc)
  1619 apply (rule_tac c="real (Suc (Suc (Suc (4*m))))" in mult_less_imp_less_right)
  1620 apply (auto simp add: mult_assoc mult_less_cancel_left simp del: fact_Suc)
  1621 apply (subgoal_tac "x * (x * x ^ (4*m)) = (x ^ (4*m)) * (x * x)")
  1622 apply (erule ssubst)+
  1623 apply (auto simp del: fact_Suc)
  1624 apply (subgoal_tac "0 < x ^ (4 * m) ")
  1625  prefer 2 apply (simp only: zero_less_power)
  1626 apply (simp (no_asm_simp) add: mult_less_cancel_left)
  1627 apply (rule mult_strict_mono)
  1628 apply (simp_all (no_asm_simp))
  1629 done
  1630 
  1631 lemma sin_gt_zero1: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1632 by (auto intro: sin_gt_zero)
  1633 
  1634 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1635 apply (cut_tac x = x in sin_gt_zero1)
  1636 apply (auto simp add: cos_squared_eq cos_double)
  1637 done
  1638 
  1639 lemma cos_paired:
  1640      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1641 proof -
  1642   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1643     unfolding cos_def
  1644     by (rule cos_converges [THEN sums_summable, THEN sums_group], simp)
  1645   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1646 qed
  1647 
  1648 lemma fact_lemma: "real (n::nat) * 4 = real (4 * n)"
  1649 by simp
  1650 
  1651 lemma real_mult_inverse_cancel:
  1652      "[|(0::real) < x; 0 < x1; x1 * y < x * u |]
  1653       ==> inverse x * y < inverse x1 * u"
  1654 apply (rule_tac c=x in mult_less_imp_less_left)
  1655 apply (auto simp add: mult_assoc [symmetric])
  1656 apply (simp (no_asm) add: mult_ac)
  1657 apply (rule_tac c=x1 in mult_less_imp_less_right)
  1658 apply (auto simp add: mult_ac)
  1659 done
  1660 
  1661 lemma real_mult_inverse_cancel2:
  1662      "[|(0::real) < x;0 < x1; x1 * y < x * u |] ==> y * inverse x < u * inverse x1"
  1663 apply (auto dest: real_mult_inverse_cancel simp add: mult_ac)
  1664 done
  1665 
  1666 lemma realpow_num_eq_if:
  1667   fixes m :: "'a::power"
  1668   shows "m ^ n = (if n=0 then 1 else m * m ^ (n - 1))"
  1669 by (cases n, auto)
  1670 
  1671 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1672 apply (cut_tac x = 2 in cos_paired)
  1673 apply (drule sums_minus)
  1674 apply (rule neg_less_iff_less [THEN iffD1])
  1675 apply (frule sums_unique, auto)
  1676 apply (rule_tac y =
  1677  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1678        in order_less_trans)
  1679 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1680 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1681 apply (rule sumr_pos_lt_pair)
  1682 apply (erule sums_summable, safe)
  1683 unfolding One_nat_def
  1684 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric]
  1685             del: fact_Suc)
  1686 apply (rule real_mult_inverse_cancel2)
  1687 apply (simp del: fact_Suc)
  1688 apply (simp del: fact_Suc)
  1689 apply (simp (no_asm) add: mult_assoc [symmetric] del: fact_Suc)
  1690 apply (subst fact_lemma)
  1691 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1692 apply (simp only: real_of_nat_mult)
  1693 apply (rule mult_strict_mono, force)
  1694   apply (rule_tac [3] real_of_nat_ge_zero)
  1695  prefer 2 apply force
  1696 apply (rule real_of_nat_less_iff [THEN iffD2])
  1697 apply (rule fact_less_mono_nat, auto)
  1698 done
  1699 
  1700 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1701 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1702 
  1703 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1704 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0")
  1705 apply (rule_tac [2] IVT2)
  1706 apply (auto intro: DERIV_isCont DERIV_cos)
  1707 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1708 apply (rule ccontr)
  1709 apply (subgoal_tac " (\<forall>x. cos differentiable x) & (\<forall>x. isCont cos x) ")
  1710 apply (auto intro: DERIV_cos DERIV_isCont simp add: differentiable_def)
  1711 apply (drule_tac f = cos in Rolle)
  1712 apply (drule_tac [5] f = cos in Rolle)
  1713 apply (auto dest!: DERIV_cos [THEN DERIV_unique] simp add: differentiable_def)
  1714 apply (metis order_less_le_trans less_le sin_gt_zero)
  1715 apply (metis order_less_le_trans less_le sin_gt_zero)
  1716 done
  1717 
  1718 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1719 by (simp add: pi_def)
  1720 
  1721 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1722 by (simp add: pi_half cos_is_zero [THEN theI'])
  1723 
  1724 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1725 apply (rule order_le_neq_trans)
  1726 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1727 apply (rule notI, drule arg_cong [where f=cos], simp)
  1728 done
  1729 
  1730 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1731 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1732 
  1733 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1734 apply (rule order_le_neq_trans)
  1735 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1736 apply (rule notI, drule arg_cong [where f=cos], simp)
  1737 done
  1738 
  1739 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1740 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1741 
  1742 lemma pi_gt_zero [simp]: "0 < pi"
  1743 by (insert pi_half_gt_zero, simp)
  1744 
  1745 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1746 by (rule pi_gt_zero [THEN order_less_imp_le])
  1747 
  1748 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1749 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1750 
  1751 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1752 by (simp add: linorder_not_less)
  1753 
  1754 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1755 by simp
  1756 
  1757 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1758 proof -
  1759   have "- (2 * pi) < 0" and "0 < pi" by auto
  1760   from order_less_trans[OF this] show ?thesis .
  1761 qed
  1762 
  1763 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1764 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1765 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1766 apply (simp add: power2_eq_1_iff)
  1767 done
  1768 
  1769 lemma cos_pi [simp]: "cos pi = -1"
  1770 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1771 
  1772 lemma sin_pi [simp]: "sin pi = 0"
  1773 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1774 
  1775 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1776 by (simp add: diff_minus cos_add)
  1777 declare sin_cos_eq [symmetric, simp]
  1778 
  1779 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1780 by (simp add: cos_add)
  1781 declare minus_sin_cos_eq [symmetric, simp]
  1782 
  1783 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1784 by (simp add: diff_minus sin_add)
  1785 declare cos_sin_eq [symmetric, simp]
  1786 
  1787 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1788 by (simp add: sin_add)
  1789 
  1790 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1791 by (simp add: sin_add)
  1792 
  1793 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1794 by (simp add: cos_add)
  1795 
  1796 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1797 by (simp add: sin_add cos_double)
  1798 
  1799 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1800 by (simp add: cos_add cos_double)
  1801 
  1802 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1803 apply (induct "n")
  1804 apply (auto simp add: real_of_nat_Suc left_distrib)
  1805 done
  1806 
  1807 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1808 proof -
  1809   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1810   also have "... = -1 ^ n" by (rule cos_npi)
  1811   finally show ?thesis .
  1812 qed
  1813 
  1814 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1815 apply (induct "n")
  1816 apply (auto simp add: real_of_nat_Suc left_distrib)
  1817 done
  1818 
  1819 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1820 by (simp add: mult_commute [of pi])
  1821 
  1822 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1823 by (simp add: cos_double)
  1824 
  1825 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1826 by simp
  1827 
  1828 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1829 apply (rule sin_gt_zero, assumption)
  1830 apply (rule order_less_trans, assumption)
  1831 apply (rule pi_half_less_two)
  1832 done
  1833 
  1834 lemma sin_less_zero:
  1835   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1836 proof -
  1837   have "0 < sin (- x)" using assms by (simp only: sin_gt_zero2)
  1838   thus ?thesis by simp
  1839 qed
  1840 
  1841 lemma pi_less_4: "pi < 4"
  1842 by (cut_tac pi_half_less_two, auto)
  1843 
  1844 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1845 apply (cut_tac pi_less_4)
  1846 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1847 apply (cut_tac cos_is_zero, safe)
  1848 apply (rename_tac y z)
  1849 apply (drule_tac x = y in spec)
  1850 apply (drule_tac x = "pi/2" in spec, simp)
  1851 done
  1852 
  1853 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1854 apply (rule_tac x = x and y = 0 in linorder_cases)
  1855 apply (rule cos_minus [THEN subst])
  1856 apply (rule cos_gt_zero)
  1857 apply (auto intro: cos_gt_zero)
  1858 done
  1859 
  1860 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1861 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1862 apply (subgoal_tac "x = pi/2", auto)
  1863 done
  1864 
  1865 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1866 apply (subst sin_cos_eq)
  1867 apply (rotate_tac 1)
  1868 apply (drule real_sum_of_halves [THEN ssubst])
  1869 apply (auto intro!: cos_gt_zero_pi simp del: sin_cos_eq [symmetric])
  1870 done
  1871 
  1872 
  1873 lemma pi_ge_two: "2 \<le> pi"
  1874 proof (rule ccontr)
  1875   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1876   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1877   proof (cases "2 < 2 * pi")
  1878     case True with dense[OF `pi < 2`] show ?thesis by auto
  1879   next
  1880     case False have "pi < 2 * pi" by auto
  1881     from dense[OF this] and False show ?thesis by auto
  1882   qed
  1883   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1884   hence "0 < sin y" using sin_gt_zero by auto
  1885   moreover
  1886   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1887   ultimately show False by auto
  1888 qed
  1889 
  1890 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1891 by (auto simp add: order_le_less sin_gt_zero_pi)
  1892 
  1893 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1894 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y")
  1895 apply (rule_tac [2] IVT2)
  1896 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos)
  1897 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1898 apply (rule ccontr, auto)
  1899 apply (drule_tac f = cos in Rolle)
  1900 apply (drule_tac [5] f = cos in Rolle)
  1901 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos
  1902             dest!: DERIV_cos [THEN DERIV_unique]
  1903             simp add: differentiable_def)
  1904 apply (auto dest: sin_gt_zero_pi [OF order_le_less_trans order_less_le_trans])
  1905 done
  1906 
  1907 lemma sin_total:
  1908      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1909 apply (rule ccontr)
  1910 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1911 apply (erule contrapos_np)
  1912 apply (simp del: minus_sin_cos_eq [symmetric])
  1913 apply (cut_tac y="-y" in cos_total, simp) apply simp
  1914 apply (erule ex1E)
  1915 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1916 apply (simp (no_asm) add: add_assoc)
  1917 apply (rotate_tac 3)
  1918 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all)
  1919 done
  1920 
  1921 lemma reals_Archimedean4:
  1922      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1923 apply (auto dest!: reals_Archimedean3)
  1924 apply (drule_tac x = x in spec, clarify)
  1925 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1926  prefer 2 apply (erule LeastI)
  1927 apply (case_tac "LEAST m::nat. x < real m * y", simp)
  1928 apply (subgoal_tac "~ x < real nat * y")
  1929  prefer 2 apply (rule not_less_Least, simp, force)
  1930 done
  1931 
  1932 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic
  1933    now causes some unwanted re-arrangements of literals!   *)
  1934 lemma cos_zero_lemma:
  1935      "[| 0 \<le> x; cos x = 0 |] ==>
  1936       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1937 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1938 apply (subgoal_tac "0 \<le> x - real n * pi &
  1939                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1940 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1941  prefer 2 apply (simp add: cos_diff)
  1942 apply (simp add: cos_diff)
  1943 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1944 apply (rule_tac [2] cos_total, safe)
  1945 apply (drule_tac x = "x - real n * pi" in spec)
  1946 apply (drule_tac x = "pi/2" in spec)
  1947 apply (simp add: cos_diff)
  1948 apply (rule_tac x = "Suc (2 * n)" in exI)
  1949 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1950 done
  1951 
  1952 lemma sin_zero_lemma:
  1953      "[| 0 \<le> x; sin x = 0 |] ==>
  1954       \<exists>n::nat. even n & x = real n * (pi/2)"
  1955 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1956  apply (clarify, rule_tac x = "n - 1" in exI)
  1957  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1958 apply (rule cos_zero_lemma)
  1959 apply (simp_all add: add_increasing)
  1960 done
  1961 
  1962 
  1963 lemma cos_zero_iff:
  1964      "(cos x = 0) =
  1965       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |
  1966        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1967 apply (rule iffI)
  1968 apply (cut_tac linorder_linear [of 0 x], safe)
  1969 apply (drule cos_zero_lemma, assumption+)
  1970 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp)
  1971 apply (force simp add: minus_equation_iff [of x])
  1972 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1973 apply (auto simp add: cos_add)
  1974 done
  1975 
  1976 (* ditto: but to a lesser extent *)
  1977 lemma sin_zero_iff:
  1978      "(sin x = 0) =
  1979       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |
  1980        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1981 apply (rule iffI)
  1982 apply (cut_tac linorder_linear [of 0 x], safe)
  1983 apply (drule sin_zero_lemma, assumption+)
  1984 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1985 apply (force simp add: minus_equation_iff [of x])
  1986 apply (auto simp add: even_mult_two_ex)
  1987 done
  1988 
  1989 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1990   shows "cos x < cos y"
  1991 proof -
  1992   have "- (x - y) < 0" using assms by auto
  1993 
  1994   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  1995   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  1996   hence "0 < z" and "z < pi" using assms by auto
  1997   hence "0 < sin z" using sin_gt_zero_pi by auto
  1998   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  1999   thus ?thesis by auto
  2000 qed
  2001 
  2002 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  2003 proof (cases "y < x")
  2004   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  2005 next
  2006   case False hence "y = x" using `y \<le> x` by auto
  2007   thus ?thesis by auto
  2008 qed
  2009 
  2010 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  2011   shows "cos y < cos x"
  2012 proof -
  2013   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  2014   from cos_monotone_0_pi[OF this]
  2015   show ?thesis unfolding cos_minus .
  2016 qed
  2017 
  2018 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  2019 proof (cases "y < x")
  2020   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2021 next
  2022   case False hence "y = x" using `y \<le> x` by auto
  2023   thus ?thesis by auto
  2024 qed
  2025 
  2026 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2027 proof -
  2028   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  2029     using pi_ge_two and assms by auto
  2030   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2031 qed
  2032 
  2033 subsection {* Tangent *}
  2034 
  2035 definition
  2036   tan :: "real => real" where
  2037   "tan x = (sin x)/(cos x)"
  2038 
  2039 lemma tan_zero [simp]: "tan 0 = 0"
  2040 by (simp add: tan_def)
  2041 
  2042 lemma tan_pi [simp]: "tan pi = 0"
  2043 by (simp add: tan_def)
  2044 
  2045 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2046 by (simp add: tan_def)
  2047 
  2048 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2049 by (simp add: tan_def minus_mult_left)
  2050 
  2051 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2052 by (simp add: tan_def)
  2053 
  2054 lemma lemma_tan_add1:
  2055       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]
  2056         ==> 1 - tan(x)*tan(y) = cos (x + y)/(cos x * cos y)"
  2057 apply (simp add: tan_def divide_inverse)
  2058 apply (auto simp del: inverse_mult_distrib
  2059             simp add: inverse_mult_distrib [symmetric] mult_ac)
  2060 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2061 apply (auto simp del: inverse_mult_distrib
  2062             simp add: mult_assoc left_diff_distrib cos_add)
  2063 done
  2064 
  2065 lemma add_tan_eq:
  2066       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]
  2067        ==> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2068 apply (simp add: tan_def)
  2069 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2070 apply (auto simp add: mult_assoc left_distrib)
  2071 apply (simp add: sin_add)
  2072 done
  2073 
  2074 lemma tan_add:
  2075      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]
  2076       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2077 apply (simp (no_asm_simp) add: add_tan_eq lemma_tan_add1)
  2078 apply (simp add: tan_def)
  2079 done
  2080 
  2081 lemma tan_double:
  2082      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]
  2083       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2084 apply (insert tan_add [of x x])
  2085 apply (simp add: mult_2 [symmetric])
  2086 apply (auto simp add: numeral_2_eq_2)
  2087 done
  2088 
  2089 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2090 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi)
  2091 
  2092 lemma tan_less_zero:
  2093   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2094 proof -
  2095   have "0 < tan (- x)" using assms by (simp only: tan_gt_zero)
  2096   thus ?thesis by simp
  2097 qed
  2098 
  2099 lemma tan_half: fixes x :: real assumes "- (pi / 2) < x" and "x < pi / 2"
  2100   shows "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2101 proof -
  2102   from cos_gt_zero_pi[OF `- (pi / 2) < x` `x < pi / 2`]
  2103   have "cos x \<noteq> 0" by auto
  2104 
  2105   have minus_cos_2x: "\<And>X. X - cos (2*x) = X - (cos x) ^ 2 + (sin x) ^ 2" unfolding cos_double by algebra
  2106 
  2107   have "tan x = (tan x + tan x) / 2" by auto
  2108   also have "\<dots> = sin (x + x) / (cos x * cos x) / 2" unfolding add_tan_eq[OF `cos x \<noteq> 0` `cos x \<noteq> 0`] ..
  2109   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + (cos x) ^ 2 + cos (2*x) - cos (2*x))" unfolding divide_divide_eq_left numeral_2_eq_2 by auto
  2110   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + cos (2*x) + (sin x)^2)" unfolding minus_cos_2x by auto
  2111   also have "\<dots> = sin (2 * x) / (cos (2*x) + 1)" by auto
  2112   finally show ?thesis .
  2113 qed
  2114 
  2115 lemma lemma_DERIV_tan:
  2116      "cos x \<noteq> 0 ==> DERIV (%x. sin(x)/cos(x)) x :> inverse((cos x)\<twosuperior>)"
  2117   by (auto intro!: DERIV_intros simp add: field_simps numeral_2_eq_2)
  2118 
  2119 lemma DERIV_tan [simp]: "cos x \<noteq> 0 ==> DERIV tan x :> inverse((cos x)\<twosuperior>)"
  2120 by (auto dest: lemma_DERIV_tan simp add: tan_def [symmetric])
  2121 
  2122 lemma isCont_tan [simp]: "cos x \<noteq> 0 ==> isCont tan x"
  2123 by (rule DERIV_tan [THEN DERIV_isCont])
  2124 
  2125 lemma LIM_cos_div_sin [simp]: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2126 apply (subgoal_tac "(\<lambda>x. cos x * inverse (sin x)) -- pi * inverse 2 --> 0*1")
  2127 apply (simp add: divide_inverse [symmetric])
  2128 apply (rule LIM_mult)
  2129 apply (rule_tac [2] inverse_1 [THEN subst])
  2130 apply (rule_tac [2] LIM_inverse)
  2131 apply (simp_all add: divide_inverse [symmetric])
  2132 apply (simp_all only: isCont_def [symmetric] cos_pi_half [symmetric] sin_pi_half [symmetric])
  2133 apply (blast intro!: DERIV_isCont DERIV_sin DERIV_cos)+
  2134 done
  2135 
  2136 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2137 apply (cut_tac LIM_cos_div_sin)
  2138 apply (simp only: LIM_eq)
  2139 apply (drule_tac x = "inverse y" in spec, safe, force)
  2140 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2141 apply (rule_tac x = "(pi/2) - e" in exI)
  2142 apply (simp (no_asm_simp))
  2143 apply (drule_tac x = "(pi/2) - e" in spec)
  2144 apply (auto simp add: tan_def)
  2145 apply (rule inverse_less_iff_less [THEN iffD1])
  2146 apply (auto simp add: divide_inverse)
  2147 apply (rule mult_pos_pos)
  2148 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2149 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute)
  2150 done
  2151 
  2152 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2153 apply (frule order_le_imp_less_or_eq, safe)
  2154  prefer 2 apply force
  2155 apply (drule lemma_tan_total, safe)
  2156 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2157 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2158 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2159 apply (auto dest: cos_gt_zero)
  2160 done
  2161 
  2162 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2163 apply (cut_tac linorder_linear [of 0 y], safe)
  2164 apply (drule tan_total_pos)
  2165 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2166 apply (rule_tac [3] x = "-x" in exI)
  2167 apply (auto intro!: exI)
  2168 done
  2169 
  2170 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2171 apply (cut_tac y = y in lemma_tan_total1, auto)
  2172 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2173 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2174 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2175 apply (rule_tac [4] Rolle)
  2176 apply (rule_tac [2] Rolle)
  2177 apply (auto intro!: DERIV_tan DERIV_isCont exI
  2178             simp add: differentiable_def)
  2179 txt{*Now, simulate TRYALL*}
  2180 apply (rule_tac [!] DERIV_tan asm_rl)
  2181 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2182             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym])
  2183 done
  2184 
  2185 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2186   shows "tan y < tan x"
  2187 proof -
  2188   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2189   proof (rule allI, rule impI)
  2190     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2191     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  2192     from cos_gt_zero_pi[OF this]
  2193     have "cos x' \<noteq> 0" by auto
  2194     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2195   qed
  2196   from MVT2[OF `y < x` this]
  2197   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2198   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  2199   hence "0 < cos z" using cos_gt_zero_pi by auto
  2200   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2201   have "0 < x - y" using `y < x` by auto
  2202   from mult_pos_pos [OF this inv_pos]
  2203   have "0 < tan x - tan y" unfolding tan_diff by auto
  2204   thus ?thesis by auto
  2205 qed
  2206 
  2207 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2208   shows "(y < x) = (tan y < tan x)"
  2209 proof
  2210   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2211 next
  2212   assume "tan y < tan x"
  2213   show "y < x"
  2214   proof (rule ccontr)
  2215     assume "\<not> y < x" hence "x \<le> y" by auto
  2216     hence "tan x \<le> tan y"
  2217     proof (cases "x = y")
  2218       case True thus ?thesis by auto
  2219     next
  2220       case False hence "x < y" using `x \<le> y` by auto
  2221       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2222     qed
  2223     thus False using `tan y < tan x` by auto
  2224   qed
  2225 qed
  2226 
  2227 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2228 
  2229 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x"
  2230   by (simp add: tan_def)
  2231 
  2232 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x"
  2233 proof (induct n arbitrary: x)
  2234   case (Suc n)
  2235   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one left_distrib by auto
  2236   show ?case unfolding split_pi_off using Suc by auto
  2237 qed auto
  2238 
  2239 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2240 proof (cases "0 \<le> i")
  2241   case True hence i_nat: "real i = real (nat i)" by auto
  2242   show ?thesis unfolding i_nat by auto
  2243 next
  2244   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2245   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2246   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2247   finally show ?thesis by auto
  2248 qed
  2249 
  2250 lemma tan_periodic_n[simp]: "tan (x + number_of n * pi) = tan x"
  2251   using tan_periodic_int[of _ "number_of n" ] unfolding real_number_of .
  2252 
  2253 subsection {* Inverse Trigonometric Functions *}
  2254 
  2255 definition
  2256   arcsin :: "real => real" where
  2257   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2258 
  2259 definition
  2260   arccos :: "real => real" where
  2261   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2262 
  2263 definition
  2264   arctan :: "real => real" where
  2265   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2266 
  2267 lemma arcsin:
  2268      "[| -1 \<le> y; y \<le> 1 |]
  2269       ==> -(pi/2) \<le> arcsin y &
  2270            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2271 unfolding arcsin_def by (rule theI' [OF sin_total])
  2272 
  2273 lemma arcsin_pi:
  2274      "[| -1 \<le> y; y \<le> 1 |]
  2275       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2276 apply (drule (1) arcsin)
  2277 apply (force intro: order_trans)
  2278 done
  2279 
  2280 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2281 by (blast dest: arcsin)
  2282 
  2283 lemma arcsin_bounded:
  2284      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2285 by (blast dest: arcsin)
  2286 
  2287 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2288 by (blast dest: arcsin)
  2289 
  2290 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2291 by (blast dest: arcsin)
  2292 
  2293 lemma arcsin_lt_bounded:
  2294      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2295 apply (frule order_less_imp_le)
  2296 apply (frule_tac y = y in order_less_imp_le)
  2297 apply (frule arcsin_bounded)
  2298 apply (safe, simp)
  2299 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2300 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2301 apply (drule_tac [!] f = sin in arg_cong, auto)
  2302 done
  2303 
  2304 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2305 apply (unfold arcsin_def)
  2306 apply (rule the1_equality)
  2307 apply (rule sin_total, auto)
  2308 done
  2309 
  2310 lemma arccos:
  2311      "[| -1 \<le> y; y \<le> 1 |]
  2312       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2313 unfolding arccos_def by (rule theI' [OF cos_total])
  2314 
  2315 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2316 by (blast dest: arccos)
  2317 
  2318 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2319 by (blast dest: arccos)
  2320 
  2321 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2322 by (blast dest: arccos)
  2323 
  2324 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2325 by (blast dest: arccos)
  2326 
  2327 lemma arccos_lt_bounded:
  2328      "[| -1 < y; y < 1 |]
  2329       ==> 0 < arccos y & arccos y < pi"
  2330 apply (frule order_less_imp_le)
  2331 apply (frule_tac y = y in order_less_imp_le)
  2332 apply (frule arccos_bounded, auto)
  2333 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2334 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2335 apply (drule_tac [!] f = cos in arg_cong, auto)
  2336 done
  2337 
  2338 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2339 apply (simp add: arccos_def)
  2340 apply (auto intro!: the1_equality cos_total)
  2341 done
  2342 
  2343 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2344 apply (simp add: arccos_def)
  2345 apply (auto intro!: the1_equality cos_total)
  2346 done
  2347 
  2348 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2349 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2350 apply (rule power2_eq_imp_eq)
  2351 apply (simp add: cos_squared_eq)
  2352 apply (rule cos_ge_zero)
  2353 apply (erule (1) arcsin_lbound)
  2354 apply (erule (1) arcsin_ubound)
  2355 apply simp
  2356 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2357 apply (rule power_mono, simp, simp)
  2358 done
  2359 
  2360 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2361 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2362 apply (rule power2_eq_imp_eq)
  2363 apply (simp add: sin_squared_eq)
  2364 apply (rule sin_ge_zero)
  2365 apply (erule (1) arccos_lbound)
  2366 apply (erule (1) arccos_ubound)
  2367 apply simp
  2368 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2369 apply (rule power_mono, simp, simp)
  2370 done
  2371 
  2372 lemma arctan [simp]:
  2373      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2374 unfolding arctan_def by (rule theI' [OF tan_total])
  2375 
  2376 lemma tan_arctan: "tan(arctan y) = y"
  2377 by auto
  2378 
  2379 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2380 by (auto simp only: arctan)
  2381 
  2382 lemma arctan_lbound: "- (pi/2) < arctan y"
  2383 by auto
  2384 
  2385 lemma arctan_ubound: "arctan y < pi/2"
  2386 by (auto simp only: arctan)
  2387 
  2388 lemma arctan_tan:
  2389       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2390 apply (unfold arctan_def)
  2391 apply (rule the1_equality)
  2392 apply (rule tan_total, auto)
  2393 done
  2394 
  2395 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2396 by (insert arctan_tan [of 0], simp)
  2397 
  2398 lemma cos_arctan_not_zero [simp]: "cos(arctan x) \<noteq> 0"
  2399 apply (auto simp add: cos_zero_iff)
  2400 apply (case_tac "n")
  2401 apply (case_tac [3] "n")
  2402 apply (cut_tac [2] y = x in arctan_ubound)
  2403 apply (cut_tac [4] y = x in arctan_lbound)
  2404 apply (auto simp add: real_of_nat_Suc left_distrib mult_less_0_iff)
  2405 done
  2406 
  2407 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2408 apply (rule power_inverse [THEN subst])
  2409 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2410 apply (auto dest: field_power_not_zero
  2411         simp add: power_mult_distrib left_distrib power_divide tan_def
  2412                   mult_assoc power_inverse [symmetric])
  2413 done
  2414 
  2415 lemma isCont_inverse_function2:
  2416   fixes f g :: "real \<Rightarrow> real" shows
  2417   "\<lbrakk>a < x; x < b;
  2418     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2419     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2420    \<Longrightarrow> isCont g (f x)"
  2421 apply (rule isCont_inverse_function
  2422        [where f=f and d="min (x - a) (b - x)"])
  2423 apply (simp_all add: abs_le_iff)
  2424 done
  2425 
  2426 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2427 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2428 apply (rule isCont_inverse_function2 [where f=sin])
  2429 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2430 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2431 apply (fast intro: arcsin_sin, simp)
  2432 done
  2433 
  2434 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2435 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2436 apply (rule isCont_inverse_function2 [where f=cos])
  2437 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2438 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2439 apply (fast intro: arccos_cos, simp)
  2440 done
  2441 
  2442 lemma isCont_arctan: "isCont arctan x"
  2443 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2444 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2445 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2446 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2447 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  2448 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans less_le)
  2449 done
  2450 
  2451 lemma DERIV_arcsin:
  2452   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2453 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2454 apply (rule lemma_DERIV_subst [OF DERIV_sin])
  2455 apply (simp add: cos_arcsin)
  2456 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2457 apply (rule power_strict_mono, simp, simp, simp)
  2458 apply assumption
  2459 apply assumption
  2460 apply simp
  2461 apply (erule (1) isCont_arcsin)
  2462 done
  2463 
  2464 lemma DERIV_arccos:
  2465   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2466 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2467 apply (rule lemma_DERIV_subst [OF DERIV_cos])
  2468 apply (simp add: sin_arccos)
  2469 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2470 apply (rule power_strict_mono, simp, simp, simp)
  2471 apply assumption
  2472 apply assumption
  2473 apply simp
  2474 apply (erule (1) isCont_arccos)
  2475 done
  2476 
  2477 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2478 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2479 apply (rule lemma_DERIV_subst [OF DERIV_tan])
  2480 apply (rule cos_arctan_not_zero)
  2481 apply (simp add: power_inverse tan_sec [symmetric])
  2482 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2483 apply (simp add: add_pos_nonneg)
  2484 apply (simp, simp, simp, rule isCont_arctan)
  2485 done
  2486 
  2487 declare
  2488   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2489   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2490   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2491 
  2492 subsection {* More Theorems about Sin and Cos *}
  2493 
  2494 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2495 proof -
  2496   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2497   have nonneg: "0 \<le> ?c"
  2498     by (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2499   have "0 = cos (pi / 4 + pi / 4)"
  2500     by simp
  2501   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2502     by (simp only: cos_add power2_eq_square)
  2503   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2504     by (simp add: sin_squared_eq)
  2505   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2506     by (simp add: power_divide)
  2507   thus ?thesis
  2508     using nonneg by (rule power2_eq_imp_eq) simp
  2509 qed
  2510 
  2511 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2512 proof -
  2513   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2514   have pos_c: "0 < ?c"
  2515     by (rule cos_gt_zero, simp, simp)
  2516   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2517     by simp
  2518   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2519     by (simp only: cos_add sin_add)
  2520   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2521     by (simp add: algebra_simps power2_eq_square)
  2522   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2523     using pos_c by (simp add: sin_squared_eq power_divide)
  2524   thus ?thesis
  2525     using pos_c [THEN order_less_imp_le]
  2526     by (rule power2_eq_imp_eq) simp
  2527 qed
  2528 
  2529 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2530 proof -
  2531   have "sin (pi / 4) = cos (pi / 2 - pi / 4)" by (rule sin_cos_eq)
  2532   also have "pi / 2 - pi / 4 = pi / 4" by simp
  2533   also have "cos (pi / 4) = sqrt 2 / 2" by (rule cos_45)
  2534   finally show ?thesis .
  2535 qed
  2536 
  2537 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2538 proof -
  2539   have "sin (pi / 3) = cos (pi / 2 - pi / 3)" by (rule sin_cos_eq)
  2540   also have "pi / 2 - pi / 3 = pi / 6" by simp
  2541   also have "cos (pi / 6) = sqrt 3 / 2" by (rule cos_30)
  2542   finally show ?thesis .
  2543 qed
  2544 
  2545 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2546 apply (rule power2_eq_imp_eq)
  2547 apply (simp add: cos_squared_eq sin_60 power_divide)
  2548 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2549 done
  2550 
  2551 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2552 proof -
  2553   have "sin (pi / 6) = cos (pi / 2 - pi / 6)" by (rule sin_cos_eq)
  2554   also have "pi / 2 - pi / 6 = pi / 3" by simp
  2555   also have "cos (pi / 3) = 1 / 2" by (rule cos_60)
  2556   finally show ?thesis .
  2557 qed
  2558 
  2559 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2560 unfolding tan_def by (simp add: sin_30 cos_30)
  2561 
  2562 lemma tan_45: "tan (pi / 4) = 1"
  2563 unfolding tan_def by (simp add: sin_45 cos_45)
  2564 
  2565 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2566 unfolding tan_def by (simp add: sin_60 cos_60)
  2567 
  2568 lemma DERIV_sin_add [simp]: "DERIV (%x. sin (x + k)) xa :> cos (xa + k)"
  2569   by (auto intro!: DERIV_intros)
  2570 
  2571 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2572 proof -
  2573   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2574     by (auto simp add: algebra_simps sin_add)
  2575   thus ?thesis
  2576     by (simp add: real_of_nat_Suc left_distrib add_divide_distrib
  2577                   mult_commute [of pi])
  2578 qed
  2579 
  2580 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2581 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2582 
  2583 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2584 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2585 apply (subst cos_add, simp)
  2586 done
  2587 
  2588 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2589 by (auto simp add: mult_assoc)
  2590 
  2591 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2592 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2593 apply (subst sin_add, simp)
  2594 done
  2595 
  2596 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2597 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib add_divide_distrib, auto)
  2598 
  2599 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2600   by (auto intro!: DERIV_intros)
  2601 
  2602 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2603 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2604 
  2605 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2606 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2607 
  2608 subsection {* Machins formula *}
  2609 
  2610 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2611   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2612 proof -
  2613   obtain z where "- (pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  2614   have "tan (pi / 4) = 1" and "tan (- (pi / 4)) = - 1" using tan_45 tan_minus by auto
  2615   have "z \<noteq> pi / 4"
  2616   proof (rule ccontr)
  2617     assume "\<not> (z \<noteq> pi / 4)" hence "z = pi / 4" by auto
  2618     have "tan z = 1" unfolding `z = pi / 4` `tan (pi / 4) = 1` ..
  2619     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2620   qed
  2621   have "z \<noteq> - (pi / 4)"
  2622   proof (rule ccontr)
  2623     assume "\<not> (z \<noteq> - (pi / 4))" hence "z = - (pi / 4)" by auto
  2624     have "tan z = - 1" unfolding `z = - (pi / 4)` `tan (- (pi / 4)) = - 1` ..
  2625     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2626   qed
  2627 
  2628   have "z < pi / 4"
  2629   proof (rule ccontr)
  2630     assume "\<not> (z < pi / 4)" hence "pi / 4 < z" using `z \<noteq> pi / 4` by auto
  2631     have "- (pi / 2) < pi / 4" using m2pi_less_pi by auto
  2632     from tan_monotone[OF this `pi / 4 < z` `z < pi / 2`]
  2633     have "1 < x" unfolding `tan z = x` `tan (pi / 4) = 1` .
  2634     thus False using `\<bar>x\<bar> < 1` by auto
  2635   qed
  2636   moreover
  2637   have "-(pi / 4) < z"
  2638   proof (rule ccontr)
  2639     assume "\<not> (-(pi / 4) < z)" hence "z < - (pi / 4)" using `z \<noteq> - (pi / 4)` by auto
  2640     have "-(pi / 4) < pi / 2" using m2pi_less_pi by auto
  2641     from tan_monotone[OF `-(pi / 2) < z` `z < -(pi / 4)` this]
  2642     have "x < - 1" unfolding `tan z = x` `tan (-(pi / 4)) = - 1` .
  2643     thus False using `\<bar>x\<bar> < 1` by auto
  2644   qed
  2645   ultimately show ?thesis using `tan z = x` by auto
  2646 qed
  2647 
  2648 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2649   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2650 proof -
  2651   obtain y' where "-(pi/4) < y'" and "y' < pi/4" and "tan y' = y" using tan_total_pi4[OF `\<bar>y\<bar> < 1`] by blast
  2652 
  2653   have "pi / 4 < pi / 2" by auto
  2654 
  2655   have "\<exists> x'. -(pi/4) \<le> x' \<and> x' \<le> pi/4 \<and> tan x' = x"
  2656   proof (cases "\<bar>x\<bar> < 1")
  2657     case True from tan_total_pi4[OF this] obtain x' where "-(pi/4) < x'" and "x' < pi/4" and "tan x' = x" by blast
  2658     hence "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by auto
  2659     thus ?thesis by auto
  2660   next
  2661     case False
  2662     show ?thesis
  2663     proof (cases "x = 1")
  2664       case True hence "tan (pi/4) = x" using tan_45 by auto
  2665       moreover
  2666       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2667       hence "-(pi/4) \<le> pi/4" and "pi/4 \<le> pi/4" by auto
  2668       ultimately show ?thesis by blast
  2669     next
  2670       case False hence "x = -1" using `\<not> \<bar>x\<bar> < 1` and `\<bar>x\<bar> \<le> 1` by auto
  2671       hence "tan (-(pi/4)) = x" using tan_45 tan_minus by auto
  2672       moreover
  2673       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2674       hence "-(pi/4) \<le> pi/4" and "-(pi/4) \<le> -(pi/4)" by auto
  2675       ultimately show ?thesis by blast
  2676     qed
  2677   qed
  2678   then obtain x' where "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by blast
  2679   hence "-(pi/2) < x'" and "x' < pi/2" using order_le_less_trans[OF `x' \<le> pi/4` `pi / 4 < pi / 2`] by auto
  2680 
  2681   have "cos x' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/2) < x'` and `x' < pi/2` by auto
  2682   moreover have "cos y' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/4) < y'` and `y' < pi/4` by auto
  2683   ultimately have "cos x' * cos y' \<noteq> 0" by auto
  2684 
  2685   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> (A / C) / (B / C) = A / B" by auto
  2686   have divide_mult_commute: "\<And> A B C D :: real. A * B / (C * D) = (A / C) * (B / D)" by auto
  2687 
  2688   have "tan (x' + y') = sin (x' + y') / (cos x' * cos y' - sin x' * sin y')" unfolding tan_def cos_add ..
  2689   also have "\<dots> = (tan x' + tan y') / ((cos x' * cos y' - sin x' * sin y') / (cos x' * cos y'))" unfolding add_tan_eq[OF `cos x' \<noteq> 0` `cos y' \<noteq> 0`] divide_nonzero_divide[OF `cos x' * cos y' \<noteq> 0`] ..
  2690   also have "\<dots> = (tan x' + tan y') / (1 - tan x' * tan y')" unfolding tan_def diff_divide_distrib divide_self[OF `cos x' * cos y' \<noteq> 0`] unfolding divide_mult_commute ..
  2691   finally have tan_eq: "tan (x' + y') = (x + y) / (1 - x * y)" unfolding `tan y' = y` `tan x' = x` .
  2692 
  2693   have "arctan (tan (x' + y')) = x' + y'" using `-(pi/4) < y'` `-(pi/4) \<le> x'` `y' < pi/4` and `x' \<le> pi/4` by (auto intro!: arctan_tan)
  2694   moreover have "arctan (tan (x')) = x'" using `-(pi/2) < x'` and `x' < pi/2` by (auto intro!: arctan_tan)
  2695   moreover have "arctan (tan (y')) = y'" using `-(pi/4) < y'` and `y' < pi/4` by (auto intro!: arctan_tan)
  2696   ultimately have "arctan x + arctan y = arctan (tan (x' + y'))" unfolding `tan y' = y` [symmetric] `tan x' = x`[symmetric] by auto
  2697   thus "arctan x + arctan y = arctan ((x + y) / (1 - x * y))" unfolding tan_eq .
  2698 qed
  2699 
  2700 lemma arctan1_eq_pi4: "arctan 1 = pi / 4" unfolding tan_45[symmetric] by (rule arctan_tan, auto simp add: m2pi_less_pi)
  2701 
  2702 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2703 proof -
  2704   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2705   from arctan_add[OF less_imp_le[OF this] this]
  2706   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2707   moreover
  2708   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2709   from arctan_add[OF less_imp_le[OF this] this]
  2710   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2711   moreover
  2712   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2713   from arctan_add[OF this]
  2714   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2715   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2716   thus ?thesis unfolding arctan1_eq_pi4 by algebra
  2717 qed
  2718 subsection {* Introducing the arcus tangens power series *}
  2719 
  2720 lemma monoseq_arctan_series: fixes x :: real
  2721   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2722 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2723 next
  2724   case False
  2725   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2726   show "monoseq ?a"
  2727   proof -
  2728     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2729       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2730       proof (rule mult_mono)
  2731         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2732         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2733         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2734         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2735       qed
  2736     } note mono = this
  2737 
  2738     show ?thesis
  2739     proof (cases "0 \<le> x")
  2740       case True from mono[OF this `x \<le> 1`, THEN allI]
  2741       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2742     next
  2743       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2744       from mono[OF this]
  2745       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2746       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2747     qed
  2748   qed
  2749 qed
  2750 
  2751 lemma zeroseq_arctan_series: fixes x :: real
  2752   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2753 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: LIMSEQ_const)
  2754 next
  2755   case False
  2756   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2757   show "?a ----> 0"
  2758   proof (cases "\<bar>x\<bar> < 1")
  2759     case True hence "norm x < 1" by auto
  2760     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2761     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2762       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2763     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2764   next
  2765     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2766     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2767     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] LIMSEQ_const[of x]]
  2768     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2769   qed
  2770 qed
  2771 
  2772 lemma summable_arctan_series: fixes x :: real and n :: nat
  2773   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2774   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2775 
  2776 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2777 proof -
  2778   from mult_left_mono[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2779   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2780   thus ?thesis using zero_le_power2 by auto
  2781 qed
  2782 
  2783 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2784   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2785 proof -
  2786   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2787 
  2788   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2789   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2790 
  2791   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2792     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2793       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2794     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2795   } note summable_Integral = this
  2796 
  2797   { fix f :: "nat \<Rightarrow> real"
  2798     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2799     proof
  2800       fix x :: real assume "f sums x"
  2801       from sums_if[OF sums_zero this]
  2802       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2803     next
  2804       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2805       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2806       show "f sums x" unfolding sums_def by auto
  2807     qed
  2808     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2809   } note sums_even = this
  2810 
  2811   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2812     by auto
  2813 
  2814   { fix x :: real
  2815     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n =
  2816       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2817       using n_even by auto
  2818     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto
  2819     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2820       by auto
  2821   } note arctan_eq = this
  2822 
  2823   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2824   proof (rule DERIV_power_series')
  2825     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2826     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2827       hence "\<bar>x'\<bar> < 1" by auto
  2828 
  2829       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2830       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2831         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2832     }
  2833   qed auto
  2834   thus ?thesis unfolding Int_eq arctan_eq .
  2835 qed
  2836 
  2837 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2838   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2839 proof -
  2840   let "?c' x n" = "(-1)^n * x^(n*2)"
  2841 
  2842   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2843     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2844     from DERIV_arctan_series[OF this]
  2845     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2846   } note DERIV_arctan_suminf = this
  2847 
  2848   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2849   note arctan_series_borders = this
  2850 
  2851   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2852   proof -
  2853     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2854     hence "0 < r" and "-r < x" and "x < r" by auto
  2855 
  2856     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2857     proof -
  2858       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2859       hence "\<bar>x\<bar> < r" by auto
  2860       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2861       proof (rule DERIV_isconst2[of "a" "b"])
  2862         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2863         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2864         proof (rule allI, rule impI)
  2865           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2866           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2867           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2868           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2869           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2870           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2871           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2872             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2873           from DERIV_add_minus[OF this DERIV_arctan]
  2874           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2875         qed
  2876         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2877         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2878         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2879       qed
  2880     qed
  2881 
  2882     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2883       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2884 
  2885     have "suminf (?c x) - arctan x = 0"
  2886     proof (cases "x = 0")
  2887       case True thus ?thesis using suminf_arctan_zero by auto
  2888     next
  2889       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2890       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2891         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  2892           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2893       moreover
  2894       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2895         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  2896           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2897       ultimately
  2898       show ?thesis using suminf_arctan_zero by auto
  2899     qed
  2900     thus ?thesis by auto
  2901   qed } note when_less_one = this
  2902 
  2903   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2904   proof (cases "\<bar>x\<bar> < 1")
  2905     case True thus ?thesis by (rule when_less_one)
  2906   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2907     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2908     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2909     { fix n :: nat
  2910       have "0 < (1 :: real)" by auto
  2911       moreover
  2912       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2913         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2914         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2915         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2916         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2917         have "?diff x n \<le> ?a x n"
  2918         proof (cases "even n")
  2919           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2920           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2921           from bounds[of m, unfolded this atLeastAtMost_iff]
  2922           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2923           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2924           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2925           finally show ?thesis .
  2926         next
  2927           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2928           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2929           hence m_plus: "2 * (m + 1) = n + 1" by auto
  2930           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2931           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2932           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2933           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2934           finally show ?thesis .
  2935         qed
  2936         hence "0 \<le> ?a x n - ?diff x n" by auto
  2937       }
  2938       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2939       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2940         unfolding diff_minus divide_inverse
  2941         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2942       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2943       hence "?diff 1 n \<le> ?a 1 n" by auto
  2944     }
  2945     have "?a 1 ----> 0"
  2946       unfolding LIMSEQ_rabs_zero power_one divide_inverse One_nat_def
  2947       by (auto intro!: LIMSEQ_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2948     have "?diff 1 ----> 0"
  2949     proof (rule LIMSEQ_I)
  2950       fix r :: real assume "0 < r"
  2951       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2952       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2953         have "norm (?diff 1 n - 0) < r" by auto }
  2954       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2955     qed
  2956     from this[unfolded LIMSEQ_rabs_zero diff_minus add_commute[of "arctan 1"], THEN LIMSEQ_add_const, of "- arctan 1", THEN LIMSEQ_minus]
  2957     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2958     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2959 
  2960     show ?thesis
  2961     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2962       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2963 
  2964       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2965       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2966 
  2967       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2968 
  2969       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2970       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2971       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2972       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2973       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2974       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2975       finally show ?thesis using `x = -1` by auto
  2976     qed
  2977   qed
  2978 qed
  2979 
  2980 lemma arctan_half: fixes x :: real
  2981   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  2982 proof -
  2983   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  2984   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  2985 
  2986   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  2987 
  2988   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  2989   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  2990 
  2991   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  2992   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  2993   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  2994   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  2995 
  2996   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  2997   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  2998   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  2999   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  3000   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  3001 
  3002   have "arctan x = y" using arctan_tan low high y_eq by auto
  3003   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  3004   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half[OF low2 high2] by auto
  3005   finally show ?thesis unfolding eq `tan y = x` .
  3006 qed
  3007 
  3008 lemma arctan_monotone: assumes "x < y"
  3009   shows "arctan x < arctan y"
  3010 proof -
  3011   obtain z where "-(pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  3012   obtain w where "-(pi / 2) < w" and "w < pi / 2" and "tan w = y" using tan_total by blast
  3013   have "z < w" unfolding tan_monotone'[OF `-(pi / 2) < z` `z < pi / 2` `-(pi / 2) < w` `w < pi / 2`] `tan z = x` `tan w = y` using `x < y` .
  3014   thus ?thesis
  3015     unfolding `tan z = x`[symmetric] arctan_tan[OF `-(pi / 2) < z` `z < pi / 2`]
  3016     unfolding `tan w = y`[symmetric] arctan_tan[OF `-(pi / 2) < w` `w < pi / 2`] .
  3017 qed
  3018 
  3019 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  3020 proof (cases "x = y")
  3021   case False hence "x < y" using `x \<le> y` by auto from arctan_monotone[OF this] show ?thesis by auto
  3022 qed auto
  3023 
  3024 lemma arctan_minus: "arctan (- x) = - arctan x"
  3025 proof -
  3026   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3027   thus ?thesis unfolding `tan y = x`[symmetric] tan_minus[symmetric] using arctan_tan[of y] arctan_tan[of "-y"] by auto
  3028 qed
  3029 
  3030 lemma arctan_inverse: assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  3031 proof -
  3032   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3033   hence "y = arctan x" unfolding `tan y = x`[symmetric] using arctan_tan by auto
  3034 
  3035   { fix y x :: real assume "0 < y" and "y < pi /2" and "y = arctan x" and "tan y = x" hence "- (pi / 2) < y" by auto
  3036     have "tan y > 0" using tan_monotone'[OF _ _ `- (pi / 2) < y` `y < pi / 2`, of 0] tan_zero `0 < y` by auto
  3037     hence "x > 0" using `tan y = x` by auto
  3038 
  3039     have "- (pi / 2) < pi / 2 - y" using `y > 0` `y < pi / 2` by auto
  3040     moreover have "pi / 2 - y < pi / 2" using `y > 0` `y < pi / 2` by auto
  3041     ultimately have "arctan (1 / x) = pi / 2 - y" unfolding `tan y = x`[symmetric] tan_inverse using arctan_tan by auto
  3042     hence "arctan (1 / x) = sgn x * pi / 2 - arctan x" unfolding `y = arctan x` real_sgn_pos[OF `x > 0`] by auto
  3043   } note pos_y = this
  3044 
  3045   show ?thesis
  3046   proof (cases "y > 0")
  3047     case True from pos_y[OF this `y < pi / 2` `y = arctan x` `tan y = x`] show ?thesis .
  3048   next
  3049     case False hence "y \<le> 0" by auto
  3050     moreover have "y \<noteq> 0"
  3051     proof (rule ccontr)
  3052       assume "\<not> y \<noteq> 0" hence "y = 0" by auto
  3053       have "x = 0" unfolding `tan y = x`[symmetric] `y = 0` tan_zero ..
  3054       thus False using `x \<noteq> 0` by auto
  3055     qed
  3056     ultimately have "y < 0" by auto
  3057     hence "0 < - y" and "-y < pi / 2" using `- (pi / 2) < y` by auto
  3058     moreover have "-y = arctan (-x)" unfolding arctan_minus `y = arctan x` ..
  3059     moreover have "tan (-y) = -x" unfolding tan_minus `tan y = x` ..
  3060     ultimately have "arctan (1 / -x) = sgn (-x) * pi / 2 - arctan (-x)" using pos_y by blast
  3061     hence "arctan (- (1 / x)) = - (sgn x * pi / 2 - arctan x)" unfolding arctan_minus[of x] divide_minus_right sgn_minus by auto
  3062     thus ?thesis unfolding arctan_minus neg_equal_iff_equal .
  3063   qed
  3064 qed
  3065 
  3066 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  3067 proof -
  3068   have "pi / 4 = arctan 1" using arctan1_eq_pi4 by auto
  3069   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  3070   finally show ?thesis by auto
  3071 qed
  3072 
  3073 subsection {* Existence of Polar Coordinates *}
  3074 
  3075 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  3076 apply (rule power2_le_imp_le [OF _ zero_le_one])
  3077 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  3078 done
  3079 
  3080 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  3081 by (simp add: abs_le_iff)
  3082 
  3083 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  3084 by (simp add: sin_arccos abs_le_iff)
  3085 
  3086 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  3087 
  3088 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  3089 
  3090 lemma polar_ex1:
  3091      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3092 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  3093 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  3094 apply (simp add: cos_arccos_lemma1)
  3095 apply (simp add: sin_arccos_lemma1)
  3096 apply (simp add: power_divide)
  3097 apply (simp add: real_sqrt_mult [symmetric])
  3098 apply (simp add: right_diff_distrib)
  3099 done
  3100 
  3101 lemma polar_ex2:
  3102      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3103 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  3104 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  3105 done
  3106 
  3107 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  3108 apply (rule_tac x=0 and y=y in linorder_cases)
  3109 apply (erule polar_ex1)
  3110 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  3111 apply (erule polar_ex2)
  3112 done
  3113 
  3114 end