src/HOL/HOL.thy
author wenzelm
Fri Oct 28 23:41:16 2011 +0200 (2011-10-28)
changeset 45294 3c5d3d286055
parent 45231 d85a2fdc586c
child 45607 16b4f5774621
permissions -rw-r--r--
tuned Named_Thms: proper binding;
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 uses
    10   ("Tools/hologic.ML")
    11   "~~/src/Tools/IsaPlanner/zipper.ML"
    12   "~~/src/Tools/IsaPlanner/isand.ML"
    13   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    14   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    15   "~~/src/Tools/intuitionistic.ML"
    16   "~~/src/Tools/project_rule.ML"
    17   "~~/src/Tools/cong_tac.ML"
    18   "~~/src/Provers/hypsubst.ML"
    19   "~~/src/Provers/splitter.ML"
    20   "~~/src/Provers/classical.ML"
    21   "~~/src/Provers/blast.ML"
    22   "~~/src/Provers/clasimp.ML"
    23   "~~/src/Tools/coherent.ML"
    24   "~~/src/Tools/eqsubst.ML"
    25   "~~/src/Provers/quantifier1.ML"
    26   ("Tools/simpdata.ML")
    27   "~~/src/Tools/atomize_elim.ML"
    28   "~~/src/Tools/induct.ML"
    29   ("~~/src/Tools/induction.ML")
    30   ("~~/src/Tools/induct_tacs.ML")
    31   ("Tools/cnf_funcs.ML")
    32   "~~/src/Tools/subtyping.ML"
    33   "~~/src/Tools/case_product.ML"
    34 begin
    35 
    36 setup {* Intuitionistic.method_setup @{binding iprover} *}
    37 setup Subtyping.setup
    38 setup Case_Product.setup
    39 
    40 
    41 subsection {* Primitive logic *}
    42 
    43 subsubsection {* Core syntax *}
    44 
    45 classes type
    46 default_sort type
    47 setup {* Object_Logic.add_base_sort @{sort type} *}
    48 
    49 arities
    50   "fun" :: (type, type) type
    51   itself :: (type) type
    52 
    53 typedecl bool
    54 
    55 judgment
    56   Trueprop      :: "bool => prop"                   ("(_)" 5)
    57 
    58 consts
    59   True          :: bool
    60   False         :: bool
    61   Not           :: "bool => bool"                   ("~ _" [40] 40)
    62 
    63   conj          :: "[bool, bool] => bool"           (infixr "&" 35)
    64   disj          :: "[bool, bool] => bool"           (infixr "|" 30)
    65   implies       :: "[bool, bool] => bool"           (infixr "-->" 25)
    66 
    67   eq            :: "['a, 'a] => bool"               (infixl "=" 50)
    68 
    69   The           :: "('a => bool) => 'a"
    70   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    71   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    72   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    73 
    74 
    75 subsubsection {* Additional concrete syntax *}
    76 
    77 notation (output)
    78   eq  (infix "=" 50)
    79 
    80 abbreviation
    81   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    82   "x ~= y == ~ (x = y)"
    83 
    84 notation (output)
    85   not_equal  (infix "~=" 50)
    86 
    87 notation (xsymbols)
    88   Not  ("\<not> _" [40] 40) and
    89   conj  (infixr "\<and>" 35) and
    90   disj  (infixr "\<or>" 30) and
    91   implies  (infixr "\<longrightarrow>" 25) and
    92   not_equal  (infix "\<noteq>" 50)
    93 
    94 notation (HTML output)
    95   Not  ("\<not> _" [40] 40) and
    96   conj  (infixr "\<and>" 35) and
    97   disj  (infixr "\<or>" 30) and
    98   not_equal  (infix "\<noteq>" 50)
    99 
   100 abbreviation (iff)
   101   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   102   "A <-> B == A = B"
   103 
   104 notation (xsymbols)
   105   iff  (infixr "\<longleftrightarrow>" 25)
   106 
   107 nonterminal letbinds and letbind
   108 nonterminal case_pat and case_syn and cases_syn
   109 
   110 syntax
   111   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   112 
   113   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   114   ""            :: "letbind => letbinds"                 ("_")
   115   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   116   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   117 
   118   "_case_syntax"      :: "['a, cases_syn] => 'b"              ("(case _ of/ _)" 10)
   119   "_case1"            :: "[case_pat, 'b] => case_syn"         ("(2_ =>/ _)" 10)
   120   ""                  :: "case_syn => cases_syn"              ("_")
   121   "_case2"            :: "[case_syn, cases_syn] => cases_syn" ("_/ | _")
   122   "_strip_positions"  :: "'a => case_pat"                     ("_")
   123 
   124 syntax (xsymbols)
   125   "_case1" :: "[case_pat, 'b] => case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   126 
   127 translations
   128   "THE x. P"              == "CONST The (%x. P)"
   129 
   130 print_translation {*
   131   [(@{const_syntax The}, fn [Abs abs] =>
   132       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   133       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   134 *}  -- {* To avoid eta-contraction of body *}
   135 
   136 notation (xsymbols)
   137   All  (binder "\<forall>" 10) and
   138   Ex  (binder "\<exists>" 10) and
   139   Ex1  (binder "\<exists>!" 10)
   140 
   141 notation (HTML output)
   142   All  (binder "\<forall>" 10) and
   143   Ex  (binder "\<exists>" 10) and
   144   Ex1  (binder "\<exists>!" 10)
   145 
   146 notation (HOL)
   147   All  (binder "! " 10) and
   148   Ex  (binder "? " 10) and
   149   Ex1  (binder "?! " 10)
   150 
   151 
   152 subsubsection {* Axioms and basic definitions *}
   153 
   154 axioms
   155   refl:           "t = (t::'a)"
   156   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   157   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   158     -- {*Extensionality is built into the meta-logic, and this rule expresses
   159          a related property.  It is an eta-expanded version of the traditional
   160          rule, and similar to the ABS rule of HOL*}
   161 
   162   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   163 
   164   impI:           "(P ==> Q) ==> P-->Q"
   165   mp:             "[| P-->Q;  P |] ==> Q"
   166 
   167 
   168 defs
   169   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   170   All_def:      "All(P)    == (P = (%x. True))"
   171   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   172   False_def:    "False     == (!P. P)"
   173   not_def:      "~ P       == P-->False"
   174   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   175   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   176   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   177 
   178 axioms
   179   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   180   True_or_False:  "(P=True) | (P=False)"
   181 
   182 finalconsts
   183   eq
   184   implies
   185   The
   186 
   187 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10) where
   188   "If P x y \<equiv> (THE z::'a. (P=True --> z=x) & (P=False --> z=y))"
   189 
   190 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b" where
   191   "Let s f \<equiv> f s"
   192 
   193 translations
   194   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   195   "let x = a in e"        == "CONST Let a (%x. e)"
   196 
   197 axiomatization
   198   undefined :: 'a
   199 
   200 class default =
   201   fixes default :: 'a
   202 
   203 
   204 subsection {* Fundamental rules *}
   205 
   206 subsubsection {* Equality *}
   207 
   208 lemma sym: "s = t ==> t = s"
   209   by (erule subst) (rule refl)
   210 
   211 lemma ssubst: "t = s ==> P s ==> P t"
   212   by (drule sym) (erule subst)
   213 
   214 lemma trans: "[| r=s; s=t |] ==> r=t"
   215   by (erule subst)
   216 
   217 lemma trans_sym [Pure.elim?]: "r = s ==> t = s ==> r = t"
   218   by (rule trans [OF _ sym])
   219 
   220 lemma meta_eq_to_obj_eq: 
   221   assumes meq: "A == B"
   222   shows "A = B"
   223   by (unfold meq) (rule refl)
   224 
   225 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   226      (* a = b
   227         |   |
   228         c = d   *)
   229 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   230 apply (rule trans)
   231 apply (rule trans)
   232 apply (rule sym)
   233 apply assumption+
   234 done
   235 
   236 text {* For calculational reasoning: *}
   237 
   238 lemma forw_subst: "a = b ==> P b ==> P a"
   239   by (rule ssubst)
   240 
   241 lemma back_subst: "P a ==> a = b ==> P b"
   242   by (rule subst)
   243 
   244 
   245 subsubsection {* Congruence rules for application *}
   246 
   247 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   248 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   249 apply (erule subst)
   250 apply (rule refl)
   251 done
   252 
   253 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   254 lemma arg_cong: "x=y ==> f(x)=f(y)"
   255 apply (erule subst)
   256 apply (rule refl)
   257 done
   258 
   259 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   260 apply (erule ssubst)+
   261 apply (rule refl)
   262 done
   263 
   264 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   265 apply (erule subst)+
   266 apply (rule refl)
   267 done
   268 
   269 ML {* val cong_tac = Cong_Tac.cong_tac @{thm cong} *}
   270 
   271 
   272 subsubsection {* Equality of booleans -- iff *}
   273 
   274 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   275   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   276 
   277 lemma iffD2: "[| P=Q; Q |] ==> P"
   278   by (erule ssubst)
   279 
   280 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   281   by (erule iffD2)
   282 
   283 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   284   by (drule sym) (rule iffD2)
   285 
   286 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   287   by (drule sym) (rule rev_iffD2)
   288 
   289 lemma iffE:
   290   assumes major: "P=Q"
   291     and minor: "[| P --> Q; Q --> P |] ==> R"
   292   shows R
   293   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   294 
   295 
   296 subsubsection {*True*}
   297 
   298 lemma TrueI: "True"
   299   unfolding True_def by (rule refl)
   300 
   301 lemma eqTrueI: "P ==> P = True"
   302   by (iprover intro: iffI TrueI)
   303 
   304 lemma eqTrueE: "P = True ==> P"
   305   by (erule iffD2) (rule TrueI)
   306 
   307 
   308 subsubsection {*Universal quantifier*}
   309 
   310 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   311   unfolding All_def by (iprover intro: ext eqTrueI assms)
   312 
   313 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   314 apply (unfold All_def)
   315 apply (rule eqTrueE)
   316 apply (erule fun_cong)
   317 done
   318 
   319 lemma allE:
   320   assumes major: "ALL x. P(x)"
   321     and minor: "P(x) ==> R"
   322   shows R
   323   by (iprover intro: minor major [THEN spec])
   324 
   325 lemma all_dupE:
   326   assumes major: "ALL x. P(x)"
   327     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   328   shows R
   329   by (iprover intro: minor major major [THEN spec])
   330 
   331 
   332 subsubsection {* False *}
   333 
   334 text {*
   335   Depends upon @{text spec}; it is impossible to do propositional
   336   logic before quantifiers!
   337 *}
   338 
   339 lemma FalseE: "False ==> P"
   340   apply (unfold False_def)
   341   apply (erule spec)
   342   done
   343 
   344 lemma False_neq_True: "False = True ==> P"
   345   by (erule eqTrueE [THEN FalseE])
   346 
   347 
   348 subsubsection {* Negation *}
   349 
   350 lemma notI:
   351   assumes "P ==> False"
   352   shows "~P"
   353   apply (unfold not_def)
   354   apply (iprover intro: impI assms)
   355   done
   356 
   357 lemma False_not_True: "False ~= True"
   358   apply (rule notI)
   359   apply (erule False_neq_True)
   360   done
   361 
   362 lemma True_not_False: "True ~= False"
   363   apply (rule notI)
   364   apply (drule sym)
   365   apply (erule False_neq_True)
   366   done
   367 
   368 lemma notE: "[| ~P;  P |] ==> R"
   369   apply (unfold not_def)
   370   apply (erule mp [THEN FalseE])
   371   apply assumption
   372   done
   373 
   374 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   375   by (erule notE [THEN notI]) (erule meta_mp)
   376 
   377 
   378 subsubsection {*Implication*}
   379 
   380 lemma impE:
   381   assumes "P-->Q" "P" "Q ==> R"
   382   shows "R"
   383 by (iprover intro: assms mp)
   384 
   385 (* Reduces Q to P-->Q, allowing substitution in P. *)
   386 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   387 by (iprover intro: mp)
   388 
   389 lemma contrapos_nn:
   390   assumes major: "~Q"
   391       and minor: "P==>Q"
   392   shows "~P"
   393 by (iprover intro: notI minor major [THEN notE])
   394 
   395 (*not used at all, but we already have the other 3 combinations *)
   396 lemma contrapos_pn:
   397   assumes major: "Q"
   398       and minor: "P ==> ~Q"
   399   shows "~P"
   400 by (iprover intro: notI minor major notE)
   401 
   402 lemma not_sym: "t ~= s ==> s ~= t"
   403   by (erule contrapos_nn) (erule sym)
   404 
   405 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   406   by (erule subst, erule ssubst, assumption)
   407 
   408 (*still used in HOLCF*)
   409 lemma rev_contrapos:
   410   assumes pq: "P ==> Q"
   411       and nq: "~Q"
   412   shows "~P"
   413 apply (rule nq [THEN contrapos_nn])
   414 apply (erule pq)
   415 done
   416 
   417 subsubsection {*Existential quantifier*}
   418 
   419 lemma exI: "P x ==> EX x::'a. P x"
   420 apply (unfold Ex_def)
   421 apply (iprover intro: allI allE impI mp)
   422 done
   423 
   424 lemma exE:
   425   assumes major: "EX x::'a. P(x)"
   426       and minor: "!!x. P(x) ==> Q"
   427   shows "Q"
   428 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   429 apply (iprover intro: impI [THEN allI] minor)
   430 done
   431 
   432 
   433 subsubsection {*Conjunction*}
   434 
   435 lemma conjI: "[| P; Q |] ==> P&Q"
   436 apply (unfold and_def)
   437 apply (iprover intro: impI [THEN allI] mp)
   438 done
   439 
   440 lemma conjunct1: "[| P & Q |] ==> P"
   441 apply (unfold and_def)
   442 apply (iprover intro: impI dest: spec mp)
   443 done
   444 
   445 lemma conjunct2: "[| P & Q |] ==> Q"
   446 apply (unfold and_def)
   447 apply (iprover intro: impI dest: spec mp)
   448 done
   449 
   450 lemma conjE:
   451   assumes major: "P&Q"
   452       and minor: "[| P; Q |] ==> R"
   453   shows "R"
   454 apply (rule minor)
   455 apply (rule major [THEN conjunct1])
   456 apply (rule major [THEN conjunct2])
   457 done
   458 
   459 lemma context_conjI:
   460   assumes "P" "P ==> Q" shows "P & Q"
   461 by (iprover intro: conjI assms)
   462 
   463 
   464 subsubsection {*Disjunction*}
   465 
   466 lemma disjI1: "P ==> P|Q"
   467 apply (unfold or_def)
   468 apply (iprover intro: allI impI mp)
   469 done
   470 
   471 lemma disjI2: "Q ==> P|Q"
   472 apply (unfold or_def)
   473 apply (iprover intro: allI impI mp)
   474 done
   475 
   476 lemma disjE:
   477   assumes major: "P|Q"
   478       and minorP: "P ==> R"
   479       and minorQ: "Q ==> R"
   480   shows "R"
   481 by (iprover intro: minorP minorQ impI
   482                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   483 
   484 
   485 subsubsection {*Classical logic*}
   486 
   487 lemma classical:
   488   assumes prem: "~P ==> P"
   489   shows "P"
   490 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   491 apply assumption
   492 apply (rule notI [THEN prem, THEN eqTrueI])
   493 apply (erule subst)
   494 apply assumption
   495 done
   496 
   497 lemmas ccontr = FalseE [THEN classical, standard]
   498 
   499 (*notE with premises exchanged; it discharges ~R so that it can be used to
   500   make elimination rules*)
   501 lemma rev_notE:
   502   assumes premp: "P"
   503       and premnot: "~R ==> ~P"
   504   shows "R"
   505 apply (rule ccontr)
   506 apply (erule notE [OF premnot premp])
   507 done
   508 
   509 (*Double negation law*)
   510 lemma notnotD: "~~P ==> P"
   511 apply (rule classical)
   512 apply (erule notE)
   513 apply assumption
   514 done
   515 
   516 lemma contrapos_pp:
   517   assumes p1: "Q"
   518       and p2: "~P ==> ~Q"
   519   shows "P"
   520 by (iprover intro: classical p1 p2 notE)
   521 
   522 
   523 subsubsection {*Unique existence*}
   524 
   525 lemma ex1I:
   526   assumes "P a" "!!x. P(x) ==> x=a"
   527   shows "EX! x. P(x)"
   528 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   529 
   530 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   531 lemma ex_ex1I:
   532   assumes ex_prem: "EX x. P(x)"
   533       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   534   shows "EX! x. P(x)"
   535 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   536 
   537 lemma ex1E:
   538   assumes major: "EX! x. P(x)"
   539       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   540   shows "R"
   541 apply (rule major [unfolded Ex1_def, THEN exE])
   542 apply (erule conjE)
   543 apply (iprover intro: minor)
   544 done
   545 
   546 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   547 apply (erule ex1E)
   548 apply (rule exI)
   549 apply assumption
   550 done
   551 
   552 
   553 subsubsection {*THE: definite description operator*}
   554 
   555 lemma the_equality:
   556   assumes prema: "P a"
   557       and premx: "!!x. P x ==> x=a"
   558   shows "(THE x. P x) = a"
   559 apply (rule trans [OF _ the_eq_trivial])
   560 apply (rule_tac f = "The" in arg_cong)
   561 apply (rule ext)
   562 apply (rule iffI)
   563  apply (erule premx)
   564 apply (erule ssubst, rule prema)
   565 done
   566 
   567 lemma theI:
   568   assumes "P a" and "!!x. P x ==> x=a"
   569   shows "P (THE x. P x)"
   570 by (iprover intro: assms the_equality [THEN ssubst])
   571 
   572 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   573 apply (erule ex1E)
   574 apply (erule theI)
   575 apply (erule allE)
   576 apply (erule mp)
   577 apply assumption
   578 done
   579 
   580 (*Easier to apply than theI: only one occurrence of P*)
   581 lemma theI2:
   582   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   583   shows "Q (THE x. P x)"
   584 by (iprover intro: assms theI)
   585 
   586 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   587 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   588            elim:allE impE)
   589 
   590 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   591 apply (rule the_equality)
   592 apply  assumption
   593 apply (erule ex1E)
   594 apply (erule all_dupE)
   595 apply (drule mp)
   596 apply  assumption
   597 apply (erule ssubst)
   598 apply (erule allE)
   599 apply (erule mp)
   600 apply assumption
   601 done
   602 
   603 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   604 apply (rule the_equality)
   605 apply (rule refl)
   606 apply (erule sym)
   607 done
   608 
   609 
   610 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   611 
   612 lemma disjCI:
   613   assumes "~Q ==> P" shows "P|Q"
   614 apply (rule classical)
   615 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   616 done
   617 
   618 lemma excluded_middle: "~P | P"
   619 by (iprover intro: disjCI)
   620 
   621 text {*
   622   case distinction as a natural deduction rule.
   623   Note that @{term "~P"} is the second case, not the first
   624 *}
   625 lemma case_split [case_names True False]:
   626   assumes prem1: "P ==> Q"
   627       and prem2: "~P ==> Q"
   628   shows "Q"
   629 apply (rule excluded_middle [THEN disjE])
   630 apply (erule prem2)
   631 apply (erule prem1)
   632 done
   633 
   634 (*Classical implies (-->) elimination. *)
   635 lemma impCE:
   636   assumes major: "P-->Q"
   637       and minor: "~P ==> R" "Q ==> R"
   638   shows "R"
   639 apply (rule excluded_middle [of P, THEN disjE])
   640 apply (iprover intro: minor major [THEN mp])+
   641 done
   642 
   643 (*This version of --> elimination works on Q before P.  It works best for
   644   those cases in which P holds "almost everywhere".  Can't install as
   645   default: would break old proofs.*)
   646 lemma impCE':
   647   assumes major: "P-->Q"
   648       and minor: "Q ==> R" "~P ==> R"
   649   shows "R"
   650 apply (rule excluded_middle [of P, THEN disjE])
   651 apply (iprover intro: minor major [THEN mp])+
   652 done
   653 
   654 (*Classical <-> elimination. *)
   655 lemma iffCE:
   656   assumes major: "P=Q"
   657       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   658   shows "R"
   659 apply (rule major [THEN iffE])
   660 apply (iprover intro: minor elim: impCE notE)
   661 done
   662 
   663 lemma exCI:
   664   assumes "ALL x. ~P(x) ==> P(a)"
   665   shows "EX x. P(x)"
   666 apply (rule ccontr)
   667 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   668 done
   669 
   670 
   671 subsubsection {* Intuitionistic Reasoning *}
   672 
   673 lemma impE':
   674   assumes 1: "P --> Q"
   675     and 2: "Q ==> R"
   676     and 3: "P --> Q ==> P"
   677   shows R
   678 proof -
   679   from 3 and 1 have P .
   680   with 1 have Q by (rule impE)
   681   with 2 show R .
   682 qed
   683 
   684 lemma allE':
   685   assumes 1: "ALL x. P x"
   686     and 2: "P x ==> ALL x. P x ==> Q"
   687   shows Q
   688 proof -
   689   from 1 have "P x" by (rule spec)
   690   from this and 1 show Q by (rule 2)
   691 qed
   692 
   693 lemma notE':
   694   assumes 1: "~ P"
   695     and 2: "~ P ==> P"
   696   shows R
   697 proof -
   698   from 2 and 1 have P .
   699   with 1 show R by (rule notE)
   700 qed
   701 
   702 lemma TrueE: "True ==> P ==> P" .
   703 lemma notFalseE: "~ False ==> P ==> P" .
   704 
   705 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   706   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   707   and [Pure.elim 2] = allE notE' impE'
   708   and [Pure.intro] = exI disjI2 disjI1
   709 
   710 lemmas [trans] = trans
   711   and [sym] = sym not_sym
   712   and [Pure.elim?] = iffD1 iffD2 impE
   713 
   714 use "Tools/hologic.ML"
   715 
   716 
   717 subsubsection {* Atomizing meta-level connectives *}
   718 
   719 axiomatization where
   720   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   721 
   722 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   723 proof
   724   assume "!!x. P x"
   725   then show "ALL x. P x" ..
   726 next
   727   assume "ALL x. P x"
   728   then show "!!x. P x" by (rule allE)
   729 qed
   730 
   731 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   732 proof
   733   assume r: "A ==> B"
   734   show "A --> B" by (rule impI) (rule r)
   735 next
   736   assume "A --> B" and A
   737   then show B by (rule mp)
   738 qed
   739 
   740 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   741 proof
   742   assume r: "A ==> False"
   743   show "~A" by (rule notI) (rule r)
   744 next
   745   assume "~A" and A
   746   then show False by (rule notE)
   747 qed
   748 
   749 lemma atomize_eq [atomize, code]: "(x == y) == Trueprop (x = y)"
   750 proof
   751   assume "x == y"
   752   show "x = y" by (unfold `x == y`) (rule refl)
   753 next
   754   assume "x = y"
   755   then show "x == y" by (rule eq_reflection)
   756 qed
   757 
   758 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   759 proof
   760   assume conj: "A &&& B"
   761   show "A & B"
   762   proof (rule conjI)
   763     from conj show A by (rule conjunctionD1)
   764     from conj show B by (rule conjunctionD2)
   765   qed
   766 next
   767   assume conj: "A & B"
   768   show "A &&& B"
   769   proof -
   770     from conj show A ..
   771     from conj show B ..
   772   qed
   773 qed
   774 
   775 lemmas [symmetric, rulify] = atomize_all atomize_imp
   776   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   777 
   778 
   779 subsubsection {* Atomizing elimination rules *}
   780 
   781 setup AtomizeElim.setup
   782 
   783 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   784   by rule iprover+
   785 
   786 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   787   by rule iprover+
   788 
   789 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   790   by rule iprover+
   791 
   792 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   793 
   794 
   795 subsection {* Package setup *}
   796 
   797 subsubsection {* Sledgehammer setup *}
   798 
   799 text {*
   800 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   801 that are prolific (match too many equality or membership literals) and relate to
   802 seldom-used facts. Some duplicate other rules.
   803 *}
   804 
   805 ML {*
   806 structure No_ATPs = Named_Thms
   807 (
   808   val name = @{binding no_atp}
   809   val description = "theorems that should be filtered out by Sledgehammer"
   810 )
   811 *}
   812 
   813 setup {* No_ATPs.setup *}
   814 
   815 
   816 subsubsection {* Classical Reasoner setup *}
   817 
   818 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   819   by (rule classical) iprover
   820 
   821 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   822   by (rule classical) iprover
   823 
   824 lemma thin_refl:
   825   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   826 
   827 ML {*
   828 structure Hypsubst = Hypsubst
   829 (
   830   val dest_eq = HOLogic.dest_eq
   831   val dest_Trueprop = HOLogic.dest_Trueprop
   832   val dest_imp = HOLogic.dest_imp
   833   val eq_reflection = @{thm eq_reflection}
   834   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   835   val imp_intr = @{thm impI}
   836   val rev_mp = @{thm rev_mp}
   837   val subst = @{thm subst}
   838   val sym = @{thm sym}
   839   val thin_refl = @{thm thin_refl};
   840 );
   841 open Hypsubst;
   842 
   843 structure Classical = Classical
   844 (
   845   val imp_elim = @{thm imp_elim}
   846   val not_elim = @{thm notE}
   847   val swap = @{thm swap}
   848   val classical = @{thm classical}
   849   val sizef = Drule.size_of_thm
   850   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   851 );
   852 
   853 structure Basic_Classical: BASIC_CLASSICAL = Classical; 
   854 open Basic_Classical;
   855 *}
   856 
   857 setup {*
   858   ML_Antiquote.value @{binding claset}
   859     (Scan.succeed "Classical.claset_of (ML_Context.the_local_context ())")
   860 *}
   861 
   862 setup Classical.setup
   863 
   864 setup {*
   865 let
   866   fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   867     | non_bool_eq _ = false;
   868   val hyp_subst_tac' =
   869     SUBGOAL (fn (goal, i) =>
   870       if Term.exists_Const non_bool_eq goal
   871       then Hypsubst.hyp_subst_tac i
   872       else no_tac);
   873 in
   874   Hypsubst.hypsubst_setup
   875   (*prevent substitution on bool*)
   876   #> Context_Rules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   877 end
   878 *}
   879 
   880 declare iffI [intro!]
   881   and notI [intro!]
   882   and impI [intro!]
   883   and disjCI [intro!]
   884   and conjI [intro!]
   885   and TrueI [intro!]
   886   and refl [intro!]
   887 
   888 declare iffCE [elim!]
   889   and FalseE [elim!]
   890   and impCE [elim!]
   891   and disjE [elim!]
   892   and conjE [elim!]
   893 
   894 declare ex_ex1I [intro!]
   895   and allI [intro!]
   896   and the_equality [intro]
   897   and exI [intro]
   898 
   899 declare exE [elim!]
   900   allE [elim]
   901 
   902 ML {* val HOL_cs = @{claset} *}
   903 
   904 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   905   apply (erule swap)
   906   apply (erule (1) meta_mp)
   907   done
   908 
   909 declare ex_ex1I [rule del, intro! 2]
   910   and ex1I [intro]
   911 
   912 declare ext [intro]
   913 
   914 lemmas [intro?] = ext
   915   and [elim?] = ex1_implies_ex
   916 
   917 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   918 lemma alt_ex1E [elim!]:
   919   assumes major: "\<exists>!x. P x"
   920       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   921   shows R
   922 apply (rule ex1E [OF major])
   923 apply (rule prem)
   924 apply (tactic {* ares_tac @{thms allI} 1 *})+
   925 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   926 apply iprover
   927 done
   928 
   929 ML {*
   930   structure Blast = Blast
   931   (
   932     structure Classical = Classical
   933     val Trueprop_const = dest_Const @{const Trueprop}
   934     val equality_name = @{const_name HOL.eq}
   935     val not_name = @{const_name Not}
   936     val notE = @{thm notE}
   937     val ccontr = @{thm ccontr}
   938     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   939   );
   940   val blast_tac = Blast.blast_tac;
   941 *}
   942 
   943 setup Blast.setup
   944 
   945 
   946 subsubsection {* Simplifier *}
   947 
   948 lemma eta_contract_eq: "(%s. f s) = f" ..
   949 
   950 lemma simp_thms:
   951   shows not_not: "(~ ~ P) = P"
   952   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   953   and
   954     "(P ~= Q) = (P = (~Q))"
   955     "(P | ~P) = True"    "(~P | P) = True"
   956     "(x = x) = True"
   957   and not_True_eq_False [code]: "(\<not> True) = False"
   958   and not_False_eq_True [code]: "(\<not> False) = True"
   959   and
   960     "(~P) ~= P"  "P ~= (~P)"
   961     "(True=P) = P"
   962   and eq_True: "(P = True) = P"
   963   and "(False=P) = (~P)"
   964   and eq_False: "(P = False) = (\<not> P)"
   965   and
   966     "(True --> P) = P"  "(False --> P) = True"
   967     "(P --> True) = True"  "(P --> P) = True"
   968     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   969     "(P & True) = P"  "(True & P) = P"
   970     "(P & False) = False"  "(False & P) = False"
   971     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   972     "(P & ~P) = False"    "(~P & P) = False"
   973     "(P | True) = True"  "(True | P) = True"
   974     "(P | False) = P"  "(False | P) = P"
   975     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   976     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   977   and
   978     "!!P. (EX x. x=t & P(x)) = P(t)"
   979     "!!P. (EX x. t=x & P(x)) = P(t)"
   980     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   981     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   982   by (blast, blast, blast, blast, blast, iprover+)
   983 
   984 lemma disj_absorb: "(A | A) = A"
   985   by blast
   986 
   987 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   988   by blast
   989 
   990 lemma conj_absorb: "(A & A) = A"
   991   by blast
   992 
   993 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   994   by blast
   995 
   996 lemma eq_ac:
   997   shows eq_commute: "(a=b) = (b=a)"
   998     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   999     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1000 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1001 
  1002 lemma conj_comms:
  1003   shows conj_commute: "(P&Q) = (Q&P)"
  1004     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1005 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1006 
  1007 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1008 
  1009 lemma disj_comms:
  1010   shows disj_commute: "(P|Q) = (Q|P)"
  1011     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1012 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1013 
  1014 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1015 
  1016 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1017 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1018 
  1019 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1020 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1021 
  1022 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1023 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1024 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1025 
  1026 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1027 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1028 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1029 
  1030 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1031 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1032 
  1033 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1034   by iprover
  1035 
  1036 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1037 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1038 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1039 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1040 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1041 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1042   by blast
  1043 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1044 
  1045 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1046 
  1047 
  1048 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1049   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1050   -- {* cases boil down to the same thing. *}
  1051   by blast
  1052 
  1053 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1054 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1055 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1056 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1057 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1058 
  1059 declare All_def [no_atp]
  1060 
  1061 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1062 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1063 
  1064 text {*
  1065   \medskip The @{text "&"} congruence rule: not included by default!
  1066   May slow rewrite proofs down by as much as 50\% *}
  1067 
  1068 lemma conj_cong:
  1069     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1070   by iprover
  1071 
  1072 lemma rev_conj_cong:
  1073     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1074   by iprover
  1075 
  1076 text {* The @{text "|"} congruence rule: not included by default! *}
  1077 
  1078 lemma disj_cong:
  1079     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1080   by blast
  1081 
  1082 
  1083 text {* \medskip if-then-else rules *}
  1084 
  1085 lemma if_True [code]: "(if True then x else y) = x"
  1086   by (unfold If_def) blast
  1087 
  1088 lemma if_False [code]: "(if False then x else y) = y"
  1089   by (unfold If_def) blast
  1090 
  1091 lemma if_P: "P ==> (if P then x else y) = x"
  1092   by (unfold If_def) blast
  1093 
  1094 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1095   by (unfold If_def) blast
  1096 
  1097 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1098   apply (rule case_split [of Q])
  1099    apply (simplesubst if_P)
  1100     prefer 3 apply (simplesubst if_not_P, blast+)
  1101   done
  1102 
  1103 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1104 by (simplesubst split_if, blast)
  1105 
  1106 lemmas if_splits [no_atp] = split_if split_if_asm
  1107 
  1108 lemma if_cancel: "(if c then x else x) = x"
  1109 by (simplesubst split_if, blast)
  1110 
  1111 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1112 by (simplesubst split_if, blast)
  1113 
  1114 lemma if_bool_eq_conj:
  1115 "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1116   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1117   by (rule split_if)
  1118 
  1119 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1120   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1121   apply (simplesubst split_if, blast)
  1122   done
  1123 
  1124 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1125 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1126 
  1127 text {* \medskip let rules for simproc *}
  1128 
  1129 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1130   by (unfold Let_def)
  1131 
  1132 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1133   by (unfold Let_def)
  1134 
  1135 text {*
  1136   The following copy of the implication operator is useful for
  1137   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1138   its premise.
  1139 *}
  1140 
  1141 definition simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1) where
  1142   "simp_implies \<equiv> op ==>"
  1143 
  1144 lemma simp_impliesI:
  1145   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1146   shows "PROP P =simp=> PROP Q"
  1147   apply (unfold simp_implies_def)
  1148   apply (rule PQ)
  1149   apply assumption
  1150   done
  1151 
  1152 lemma simp_impliesE:
  1153   assumes PQ: "PROP P =simp=> PROP Q"
  1154   and P: "PROP P"
  1155   and QR: "PROP Q \<Longrightarrow> PROP R"
  1156   shows "PROP R"
  1157   apply (rule QR)
  1158   apply (rule PQ [unfolded simp_implies_def])
  1159   apply (rule P)
  1160   done
  1161 
  1162 lemma simp_implies_cong:
  1163   assumes PP' :"PROP P == PROP P'"
  1164   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1165   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1166 proof (unfold simp_implies_def, rule equal_intr_rule)
  1167   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1168   and P': "PROP P'"
  1169   from PP' [symmetric] and P' have "PROP P"
  1170     by (rule equal_elim_rule1)
  1171   then have "PROP Q" by (rule PQ)
  1172   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1173 next
  1174   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1175   and P: "PROP P"
  1176   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1177   then have "PROP Q'" by (rule P'Q')
  1178   with P'QQ' [OF P', symmetric] show "PROP Q"
  1179     by (rule equal_elim_rule1)
  1180 qed
  1181 
  1182 lemma uncurry:
  1183   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1184   shows "P \<and> Q \<longrightarrow> R"
  1185   using assms by blast
  1186 
  1187 lemma iff_allI:
  1188   assumes "\<And>x. P x = Q x"
  1189   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1190   using assms by blast
  1191 
  1192 lemma iff_exI:
  1193   assumes "\<And>x. P x = Q x"
  1194   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1195   using assms by blast
  1196 
  1197 lemma all_comm:
  1198   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1199   by blast
  1200 
  1201 lemma ex_comm:
  1202   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1203   by blast
  1204 
  1205 use "Tools/simpdata.ML"
  1206 ML {* open Simpdata *}
  1207 
  1208 setup {* Simplifier.map_simpset_global (K HOL_basic_ss) *}
  1209 
  1210 simproc_setup defined_Ex ("EX x. P x") = {* fn _ => Quantifier1.rearrange_ex *}
  1211 simproc_setup defined_All ("ALL x. P x") = {* fn _ => Quantifier1.rearrange_all *}
  1212 
  1213 setup {*
  1214   Simplifier.method_setup Splitter.split_modifiers
  1215   #> Splitter.setup
  1216   #> clasimp_setup
  1217   #> EqSubst.setup
  1218 *}
  1219 
  1220 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1221 
  1222 simproc_setup neq ("x = y") = {* fn _ =>
  1223 let
  1224   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1225   fun is_neq eq lhs rhs thm =
  1226     (case Thm.prop_of thm of
  1227       _ $ (Not $ (eq' $ l' $ r')) =>
  1228         Not = HOLogic.Not andalso eq' = eq andalso
  1229         r' aconv lhs andalso l' aconv rhs
  1230     | _ => false);
  1231   fun proc ss ct =
  1232     (case Thm.term_of ct of
  1233       eq $ lhs $ rhs =>
  1234         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1235           SOME thm => SOME (thm RS neq_to_EQ_False)
  1236         | NONE => NONE)
  1237      | _ => NONE);
  1238 in proc end;
  1239 *}
  1240 
  1241 simproc_setup let_simp ("Let x f") = {*
  1242 let
  1243   val (f_Let_unfold, x_Let_unfold) =
  1244     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1245     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1246   val (f_Let_folded, x_Let_folded) =
  1247     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1248     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1249   val g_Let_folded =
  1250     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1251     in cterm_of @{theory} g end;
  1252   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1253     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1254     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1255     | count_loose _ _ = 0;
  1256   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1257    case t
  1258     of Abs (_, _, t') => count_loose t' 0 <= 1
  1259      | _ => true;
  1260 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1261   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1262   else let (*Norbert Schirmer's case*)
  1263     val ctxt = Simplifier.the_context ss;
  1264     val thy = Proof_Context.theory_of ctxt;
  1265     val t = Thm.term_of ct;
  1266     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1267   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1268     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1269       if is_Free x orelse is_Bound x orelse is_Const x
  1270       then SOME @{thm Let_def}
  1271       else
  1272         let
  1273           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1274           val cx = cterm_of thy x;
  1275           val {T = xT, ...} = rep_cterm cx;
  1276           val cf = cterm_of thy f;
  1277           val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1278           val (_ $ _ $ g) = prop_of fx_g;
  1279           val g' = abstract_over (x,g);
  1280         in (if (g aconv g')
  1281              then
  1282                 let
  1283                   val rl =
  1284                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1285                 in SOME (rl OF [fx_g]) end
  1286              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1287              else let
  1288                    val abs_g'= Abs (n,xT,g');
  1289                    val g'x = abs_g'$x;
  1290                    val g_g'x = Thm.symmetric (Thm.beta_conversion false (cterm_of thy g'x));
  1291                    val rl = cterm_instantiate
  1292                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1293                               (g_Let_folded, cterm_of thy abs_g')]
  1294                              @{thm Let_folded};
  1295                  in SOME (rl OF [Thm.transitive fx_g g_g'x])
  1296                  end)
  1297         end
  1298     | _ => NONE)
  1299   end
  1300 end *}
  1301 
  1302 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1303 proof
  1304   assume "True \<Longrightarrow> PROP P"
  1305   from this [OF TrueI] show "PROP P" .
  1306 next
  1307   assume "PROP P"
  1308   then show "PROP P" .
  1309 qed
  1310 
  1311 lemma ex_simps:
  1312   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1313   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1314   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1315   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1316   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1317   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1318   -- {* Miniscoping: pushing in existential quantifiers. *}
  1319   by (iprover | blast)+
  1320 
  1321 lemma all_simps:
  1322   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1323   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1324   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1325   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1326   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1327   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1328   -- {* Miniscoping: pushing in universal quantifiers. *}
  1329   by (iprover | blast)+
  1330 
  1331 lemmas [simp] =
  1332   triv_forall_equality (*prunes params*)
  1333   True_implies_equals  (*prune asms `True'*)
  1334   if_True
  1335   if_False
  1336   if_cancel
  1337   if_eq_cancel
  1338   imp_disjL
  1339   (*In general it seems wrong to add distributive laws by default: they
  1340     might cause exponential blow-up.  But imp_disjL has been in for a while
  1341     and cannot be removed without affecting existing proofs.  Moreover,
  1342     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1343     grounds that it allows simplification of R in the two cases.*)
  1344   conj_assoc
  1345   disj_assoc
  1346   de_Morgan_conj
  1347   de_Morgan_disj
  1348   imp_disj1
  1349   imp_disj2
  1350   not_imp
  1351   disj_not1
  1352   not_all
  1353   not_ex
  1354   cases_simp
  1355   the_eq_trivial
  1356   the_sym_eq_trivial
  1357   ex_simps
  1358   all_simps
  1359   simp_thms
  1360 
  1361 lemmas [cong] = imp_cong simp_implies_cong
  1362 lemmas [split] = split_if
  1363 
  1364 ML {* val HOL_ss = @{simpset} *}
  1365 
  1366 text {* Simplifies x assuming c and y assuming ~c *}
  1367 lemma if_cong:
  1368   assumes "b = c"
  1369       and "c \<Longrightarrow> x = u"
  1370       and "\<not> c \<Longrightarrow> y = v"
  1371   shows "(if b then x else y) = (if c then u else v)"
  1372   using assms by simp
  1373 
  1374 text {* Prevents simplification of x and y:
  1375   faster and allows the execution of functional programs. *}
  1376 lemma if_weak_cong [cong]:
  1377   assumes "b = c"
  1378   shows "(if b then x else y) = (if c then x else y)"
  1379   using assms by (rule arg_cong)
  1380 
  1381 text {* Prevents simplification of t: much faster *}
  1382 lemma let_weak_cong:
  1383   assumes "a = b"
  1384   shows "(let x = a in t x) = (let x = b in t x)"
  1385   using assms by (rule arg_cong)
  1386 
  1387 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1388 lemma eq_cong2:
  1389   assumes "u = u'"
  1390   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1391   using assms by simp
  1392 
  1393 lemma if_distrib:
  1394   "f (if c then x else y) = (if c then f x else f y)"
  1395   by simp
  1396 
  1397 text{*As a simplification rule, it replaces all function equalities by
  1398   first-order equalities.*}
  1399 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1400   by auto
  1401 
  1402 
  1403 subsubsection {* Generic cases and induction *}
  1404 
  1405 text {* Rule projections: *}
  1406 
  1407 ML {*
  1408 structure Project_Rule = Project_Rule
  1409 (
  1410   val conjunct1 = @{thm conjunct1}
  1411   val conjunct2 = @{thm conjunct2}
  1412   val mp = @{thm mp}
  1413 )
  1414 *}
  1415 
  1416 definition induct_forall where
  1417   "induct_forall P == \<forall>x. P x"
  1418 
  1419 definition induct_implies where
  1420   "induct_implies A B == A \<longrightarrow> B"
  1421 
  1422 definition induct_equal where
  1423   "induct_equal x y == x = y"
  1424 
  1425 definition induct_conj where
  1426   "induct_conj A B == A \<and> B"
  1427 
  1428 definition induct_true where
  1429   "induct_true == True"
  1430 
  1431 definition induct_false where
  1432   "induct_false == False"
  1433 
  1434 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1435   by (unfold atomize_all induct_forall_def)
  1436 
  1437 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1438   by (unfold atomize_imp induct_implies_def)
  1439 
  1440 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1441   by (unfold atomize_eq induct_equal_def)
  1442 
  1443 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1444   by (unfold atomize_conj induct_conj_def)
  1445 
  1446 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1447 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1448 lemmas induct_rulify' [symmetric, standard] = induct_atomize'
  1449 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1450 lemmas induct_rulify_fallback =
  1451   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1452   induct_true_def induct_false_def
  1453 
  1454 
  1455 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1456     induct_conj (induct_forall A) (induct_forall B)"
  1457   by (unfold induct_forall_def induct_conj_def) iprover
  1458 
  1459 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1460     induct_conj (induct_implies C A) (induct_implies C B)"
  1461   by (unfold induct_implies_def induct_conj_def) iprover
  1462 
  1463 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1464 proof
  1465   assume r: "induct_conj A B ==> PROP C" and A B
  1466   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1467 next
  1468   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1469   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1470 qed
  1471 
  1472 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1473 
  1474 lemma induct_trueI: "induct_true"
  1475   by (simp add: induct_true_def)
  1476 
  1477 text {* Method setup. *}
  1478 
  1479 ML {*
  1480 structure Induct = Induct
  1481 (
  1482   val cases_default = @{thm case_split}
  1483   val atomize = @{thms induct_atomize}
  1484   val rulify = @{thms induct_rulify'}
  1485   val rulify_fallback = @{thms induct_rulify_fallback}
  1486   val equal_def = @{thm induct_equal_def}
  1487   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1488     | dest_def _ = NONE
  1489   val trivial_tac = match_tac @{thms induct_trueI}
  1490 )
  1491 *}
  1492 
  1493 use "~~/src/Tools/induction.ML"
  1494 
  1495 setup {*
  1496   Induct.setup #> Induction.setup #>
  1497   Context.theory_map (Induct.map_simpset (fn ss => ss
  1498     setmksimps (fn ss => Simpdata.mksimps Simpdata.mksimps_pairs ss #>
  1499       map (Simplifier.rewrite_rule (map Thm.symmetric
  1500         @{thms induct_rulify_fallback})))
  1501     addsimprocs
  1502       [Simplifier.simproc_global @{theory} "swap_induct_false"
  1503          ["induct_false ==> PROP P ==> PROP Q"]
  1504          (fn _ => fn _ =>
  1505             (fn _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1506                   if P <> Q then SOME Drule.swap_prems_eq else NONE
  1507               | _ => NONE)),
  1508        Simplifier.simproc_global @{theory} "induct_equal_conj_curry"
  1509          ["induct_conj P Q ==> PROP R"]
  1510          (fn _ => fn _ =>
  1511             (fn _ $ (_ $ P) $ _ =>
  1512                 let
  1513                   fun is_conj (@{const induct_conj} $ P $ Q) =
  1514                         is_conj P andalso is_conj Q
  1515                     | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1516                     | is_conj @{const induct_true} = true
  1517                     | is_conj @{const induct_false} = true
  1518                     | is_conj _ = false
  1519                 in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1520               | _ => NONE))]))
  1521 *}
  1522 
  1523 text {* Pre-simplification of induction and cases rules *}
  1524 
  1525 lemma [induct_simp]: "(!!x. induct_equal x t ==> PROP P x) == PROP P t"
  1526   unfolding induct_equal_def
  1527 proof
  1528   assume R: "!!x. x = t ==> PROP P x"
  1529   show "PROP P t" by (rule R [OF refl])
  1530 next
  1531   fix x assume "PROP P t" "x = t"
  1532   then show "PROP P x" by simp
  1533 qed
  1534 
  1535 lemma [induct_simp]: "(!!x. induct_equal t x ==> PROP P x) == PROP P t"
  1536   unfolding induct_equal_def
  1537 proof
  1538   assume R: "!!x. t = x ==> PROP P x"
  1539   show "PROP P t" by (rule R [OF refl])
  1540 next
  1541   fix x assume "PROP P t" "t = x"
  1542   then show "PROP P x" by simp
  1543 qed
  1544 
  1545 lemma [induct_simp]: "(induct_false ==> P) == Trueprop induct_true"
  1546   unfolding induct_false_def induct_true_def
  1547   by (iprover intro: equal_intr_rule)
  1548 
  1549 lemma [induct_simp]: "(induct_true ==> PROP P) == PROP P"
  1550   unfolding induct_true_def
  1551 proof
  1552   assume R: "True \<Longrightarrow> PROP P"
  1553   from TrueI show "PROP P" by (rule R)
  1554 next
  1555   assume "PROP P"
  1556   then show "PROP P" .
  1557 qed
  1558 
  1559 lemma [induct_simp]: "(PROP P ==> induct_true) == Trueprop induct_true"
  1560   unfolding induct_true_def
  1561   by (iprover intro: equal_intr_rule)
  1562 
  1563 lemma [induct_simp]: "(!!x. induct_true) == Trueprop induct_true"
  1564   unfolding induct_true_def
  1565   by (iprover intro: equal_intr_rule)
  1566 
  1567 lemma [induct_simp]: "induct_implies induct_true P == P"
  1568   by (simp add: induct_implies_def induct_true_def)
  1569 
  1570 lemma [induct_simp]: "(x = x) = True" 
  1571   by (rule simp_thms)
  1572 
  1573 hide_const induct_forall induct_implies induct_equal induct_conj induct_true induct_false
  1574 
  1575 use "~~/src/Tools/induct_tacs.ML"
  1576 setup Induct_Tacs.setup
  1577 
  1578 
  1579 subsubsection {* Coherent logic *}
  1580 
  1581 ML {*
  1582 structure Coherent = Coherent
  1583 (
  1584   val atomize_elimL = @{thm atomize_elimL}
  1585   val atomize_exL = @{thm atomize_exL}
  1586   val atomize_conjL = @{thm atomize_conjL}
  1587   val atomize_disjL = @{thm atomize_disjL}
  1588   val operator_names =
  1589     [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}]
  1590 );
  1591 *}
  1592 
  1593 setup Coherent.setup
  1594 
  1595 
  1596 subsubsection {* Reorienting equalities *}
  1597 
  1598 ML {*
  1599 signature REORIENT_PROC =
  1600 sig
  1601   val add : (term -> bool) -> theory -> theory
  1602   val proc : morphism -> simpset -> cterm -> thm option
  1603 end;
  1604 
  1605 structure Reorient_Proc : REORIENT_PROC =
  1606 struct
  1607   structure Data = Theory_Data
  1608   (
  1609     type T = ((term -> bool) * stamp) list;
  1610     val empty = [];
  1611     val extend = I;
  1612     fun merge data : T = Library.merge (eq_snd op =) data;
  1613   );
  1614   fun add m = Data.map (cons (m, stamp ()));
  1615   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1616 
  1617   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1618   fun proc phi ss ct =
  1619     let
  1620       val ctxt = Simplifier.the_context ss;
  1621       val thy = Proof_Context.theory_of ctxt;
  1622     in
  1623       case Thm.term_of ct of
  1624         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1625       | _ => NONE
  1626     end;
  1627 end;
  1628 *}
  1629 
  1630 
  1631 subsection {* Other simple lemmas and lemma duplicates *}
  1632 
  1633 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1634   by blast+
  1635 
  1636 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1637   apply (rule iffI)
  1638   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1639   apply (fast dest!: theI')
  1640   apply (fast intro: the1_equality [symmetric])
  1641   apply (erule ex1E)
  1642   apply (rule allI)
  1643   apply (rule ex1I)
  1644   apply (erule spec)
  1645   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1646   apply (erule impE)
  1647   apply (rule allI)
  1648   apply (case_tac "xa = x")
  1649   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1650   done
  1651 
  1652 lemmas eq_sym_conv = eq_commute
  1653 
  1654 lemma nnf_simps:
  1655   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1656   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1657   "(\<not> \<not>(P)) = P"
  1658 by blast+
  1659 
  1660 subsection {* Basic ML bindings *}
  1661 
  1662 ML {*
  1663 val FalseE = @{thm FalseE}
  1664 val Let_def = @{thm Let_def}
  1665 val TrueI = @{thm TrueI}
  1666 val allE = @{thm allE}
  1667 val allI = @{thm allI}
  1668 val all_dupE = @{thm all_dupE}
  1669 val arg_cong = @{thm arg_cong}
  1670 val box_equals = @{thm box_equals}
  1671 val ccontr = @{thm ccontr}
  1672 val classical = @{thm classical}
  1673 val conjE = @{thm conjE}
  1674 val conjI = @{thm conjI}
  1675 val conjunct1 = @{thm conjunct1}
  1676 val conjunct2 = @{thm conjunct2}
  1677 val disjCI = @{thm disjCI}
  1678 val disjE = @{thm disjE}
  1679 val disjI1 = @{thm disjI1}
  1680 val disjI2 = @{thm disjI2}
  1681 val eq_reflection = @{thm eq_reflection}
  1682 val ex1E = @{thm ex1E}
  1683 val ex1I = @{thm ex1I}
  1684 val ex1_implies_ex = @{thm ex1_implies_ex}
  1685 val exE = @{thm exE}
  1686 val exI = @{thm exI}
  1687 val excluded_middle = @{thm excluded_middle}
  1688 val ext = @{thm ext}
  1689 val fun_cong = @{thm fun_cong}
  1690 val iffD1 = @{thm iffD1}
  1691 val iffD2 = @{thm iffD2}
  1692 val iffI = @{thm iffI}
  1693 val impE = @{thm impE}
  1694 val impI = @{thm impI}
  1695 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1696 val mp = @{thm mp}
  1697 val notE = @{thm notE}
  1698 val notI = @{thm notI}
  1699 val not_all = @{thm not_all}
  1700 val not_ex = @{thm not_ex}
  1701 val not_iff = @{thm not_iff}
  1702 val not_not = @{thm not_not}
  1703 val not_sym = @{thm not_sym}
  1704 val refl = @{thm refl}
  1705 val rev_mp = @{thm rev_mp}
  1706 val spec = @{thm spec}
  1707 val ssubst = @{thm ssubst}
  1708 val subst = @{thm subst}
  1709 val sym = @{thm sym}
  1710 val trans = @{thm trans}
  1711 *}
  1712 
  1713 use "Tools/cnf_funcs.ML"
  1714 
  1715 subsection {* Code generator setup *}
  1716 
  1717 subsubsection {* Generic code generator preprocessor setup *}
  1718 
  1719 setup {*
  1720   Code_Preproc.map_pre (K HOL_basic_ss)
  1721   #> Code_Preproc.map_post (K HOL_basic_ss)
  1722   #> Code_Simp.map_ss (K HOL_basic_ss)
  1723 *}
  1724 
  1725 subsubsection {* Equality *}
  1726 
  1727 class equal =
  1728   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1729   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1730 begin
  1731 
  1732 lemma equal: "equal = (op =)"
  1733   by (rule ext equal_eq)+
  1734 
  1735 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1736   unfolding equal by rule+
  1737 
  1738 lemma eq_equal: "(op =) \<equiv> equal"
  1739   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1740 
  1741 end
  1742 
  1743 declare eq_equal [symmetric, code_post]
  1744 declare eq_equal [code]
  1745 
  1746 setup {*
  1747   Code_Preproc.map_pre (fn simpset =>
  1748     simpset addsimprocs [Simplifier.simproc_global_i @{theory} "equal" [@{term HOL.eq}]
  1749       (fn thy => fn _ =>
  1750         fn Const (_, Type ("fun", [Type _, _])) => SOME @{thm eq_equal} | _ => NONE)])
  1751 *}
  1752 
  1753 
  1754 subsubsection {* Generic code generator foundation *}
  1755 
  1756 text {* Datatype @{typ bool} *}
  1757 
  1758 code_datatype True False
  1759 
  1760 lemma [code]:
  1761   shows "False \<and> P \<longleftrightarrow> False"
  1762     and "True \<and> P \<longleftrightarrow> P"
  1763     and "P \<and> False \<longleftrightarrow> False"
  1764     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1765 
  1766 lemma [code]:
  1767   shows "False \<or> P \<longleftrightarrow> P"
  1768     and "True \<or> P \<longleftrightarrow> True"
  1769     and "P \<or> False \<longleftrightarrow> P"
  1770     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1771 
  1772 lemma [code]:
  1773   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1774     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1775     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1776     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1777 
  1778 text {* More about @{typ prop} *}
  1779 
  1780 lemma [code nbe]:
  1781   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q" 
  1782     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1783     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1784 
  1785 lemma Trueprop_code [code]:
  1786   "Trueprop True \<equiv> Code_Generator.holds"
  1787   by (auto intro!: equal_intr_rule holds)
  1788 
  1789 declare Trueprop_code [symmetric, code_post]
  1790 
  1791 text {* Equality *}
  1792 
  1793 declare simp_thms(6) [code nbe]
  1794 
  1795 instantiation itself :: (type) equal
  1796 begin
  1797 
  1798 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1799   "equal_itself x y \<longleftrightarrow> x = y"
  1800 
  1801 instance proof
  1802 qed (fact equal_itself_def)
  1803 
  1804 end
  1805 
  1806 lemma equal_itself_code [code]:
  1807   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1808   by (simp add: equal)
  1809 
  1810 setup {*
  1811   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"})
  1812 *}
  1813 
  1814 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1815 proof
  1816   assume "PROP ?ofclass"
  1817   show "PROP ?equal"
  1818     by (tactic {* ALLGOALS (rtac (Thm.unconstrainT @{thm eq_equal})) *})
  1819       (fact `PROP ?ofclass`)
  1820 next
  1821   assume "PROP ?equal"
  1822   show "PROP ?ofclass" proof
  1823   qed (simp add: `PROP ?equal`)
  1824 qed
  1825   
  1826 setup {*
  1827   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>equal \<Rightarrow> 'a \<Rightarrow> bool"})
  1828 *}
  1829 
  1830 setup {*
  1831   Nbe.add_const_alias @{thm equal_alias_cert}
  1832 *}
  1833 
  1834 text {* Cases *}
  1835 
  1836 lemma Let_case_cert:
  1837   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1838   shows "CASE x \<equiv> f x"
  1839   using assms by simp_all
  1840 
  1841 setup {*
  1842   Code.add_case @{thm Let_case_cert}
  1843   #> Code.add_undefined @{const_name undefined}
  1844 *}
  1845 
  1846 code_abort undefined
  1847 
  1848 
  1849 subsubsection {* Generic code generator target languages *}
  1850 
  1851 text {* type @{typ bool} *}
  1852 
  1853 code_type bool
  1854   (SML "bool")
  1855   (OCaml "bool")
  1856   (Haskell "Bool")
  1857   (Scala "Boolean")
  1858 
  1859 code_const True and False and Not and HOL.conj and HOL.disj and HOL.implies and If 
  1860   (SML "true" and "false" and "not"
  1861     and infixl 1 "andalso" and infixl 0 "orelse"
  1862     and "!(if (_)/ then (_)/ else true)"
  1863     and "!(if (_)/ then (_)/ else (_))")
  1864   (OCaml "true" and "false" and "not"
  1865     and infixl 3 "&&" and infixl 2 "||"
  1866     and "!(if (_)/ then (_)/ else true)"
  1867     and "!(if (_)/ then (_)/ else (_))")
  1868   (Haskell "True" and "False" and "not"
  1869     and infixr 3 "&&" and infixr 2 "||"
  1870     and "!(if (_)/ then (_)/ else True)"
  1871     and "!(if (_)/ then (_)/ else (_))")
  1872   (Scala "true" and "false" and "'! _"
  1873     and infixl 3 "&&" and infixl 1 "||"
  1874     and "!(if ((_))/ (_)/ else true)"
  1875     and "!(if ((_))/ (_)/ else (_))")
  1876 
  1877 code_reserved SML
  1878   bool true false not
  1879 
  1880 code_reserved OCaml
  1881   bool not
  1882 
  1883 code_reserved Scala
  1884   Boolean
  1885 
  1886 code_modulename SML Pure HOL
  1887 code_modulename OCaml Pure HOL
  1888 code_modulename Haskell Pure HOL
  1889 
  1890 text {* using built-in Haskell equality *}
  1891 
  1892 code_class equal
  1893   (Haskell "Eq")
  1894 
  1895 code_const "HOL.equal"
  1896   (Haskell infix 4 "==")
  1897 
  1898 code_const HOL.eq
  1899   (Haskell infix 4 "==")
  1900 
  1901 text {* undefined *}
  1902 
  1903 code_const undefined
  1904   (SML "!(raise/ Fail/ \"undefined\")")
  1905   (OCaml "failwith/ \"undefined\"")
  1906   (Haskell "error/ \"undefined\"")
  1907   (Scala "!error(\"undefined\")")
  1908 
  1909 subsubsection {* Evaluation and normalization by evaluation *}
  1910 
  1911 ML {*
  1912 fun gen_eval_method conv ctxt = SIMPLE_METHOD'
  1913   (CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 (conv ctxt))) ctxt)
  1914     THEN' rtac TrueI)
  1915 *}
  1916 
  1917 method_setup eval = {*
  1918   Scan.succeed (gen_eval_method (Code_Runtime.dynamic_holds_conv o Proof_Context.theory_of))
  1919 *} "solve goal by evaluation"
  1920 
  1921 method_setup normalization = {*
  1922   Scan.succeed (fn ctxt => SIMPLE_METHOD'
  1923     (CHANGED_PROP o (CONVERSION (Nbe.dynamic_conv (Proof_Context.theory_of ctxt))
  1924       THEN' (fn k => TRY (rtac TrueI k)))))
  1925 *} "solve goal by normalization"
  1926 
  1927 
  1928 subsection {* Counterexample Search Units *}
  1929 
  1930 subsubsection {* Quickcheck *}
  1931 
  1932 quickcheck_params [size = 5, iterations = 50]
  1933 
  1934 
  1935 subsubsection {* Nitpick setup *}
  1936 
  1937 ML {*
  1938 structure Nitpick_Unfolds = Named_Thms
  1939 (
  1940   val name = @{binding nitpick_unfold}
  1941   val description = "alternative definitions of constants as needed by Nitpick"
  1942 )
  1943 structure Nitpick_Simps = Named_Thms
  1944 (
  1945   val name = @{binding nitpick_simp}
  1946   val description = "equational specification of constants as needed by Nitpick"
  1947 )
  1948 structure Nitpick_Psimps = Named_Thms
  1949 (
  1950   val name = @{binding nitpick_psimp}
  1951   val description = "partial equational specification of constants as needed by Nitpick"
  1952 )
  1953 structure Nitpick_Choice_Specs = Named_Thms
  1954 (
  1955   val name = @{binding nitpick_choice_spec}
  1956   val description = "choice specification of constants as needed by Nitpick"
  1957 )
  1958 *}
  1959 
  1960 setup {*
  1961   Nitpick_Unfolds.setup
  1962   #> Nitpick_Simps.setup
  1963   #> Nitpick_Psimps.setup
  1964   #> Nitpick_Choice_Specs.setup
  1965 *}
  1966 
  1967 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  1968         if_bool_eq_disj [no_atp]
  1969 
  1970 
  1971 subsection {* Preprocessing for the predicate compiler *}
  1972 
  1973 ML {*
  1974 structure Predicate_Compile_Alternative_Defs = Named_Thms
  1975 (
  1976   val name = @{binding code_pred_def}
  1977   val description = "alternative definitions of constants for the Predicate Compiler"
  1978 )
  1979 structure Predicate_Compile_Inline_Defs = Named_Thms
  1980 (
  1981   val name = @{binding code_pred_inline}
  1982   val description = "inlining definitions for the Predicate Compiler"
  1983 )
  1984 structure Predicate_Compile_Simps = Named_Thms
  1985 (
  1986   val name = @{binding code_pred_simp}
  1987   val description = "simplification rules for the optimisations in the Predicate Compiler"
  1988 )
  1989 *}
  1990 
  1991 setup {*
  1992   Predicate_Compile_Alternative_Defs.setup
  1993   #> Predicate_Compile_Inline_Defs.setup
  1994   #> Predicate_Compile_Simps.setup
  1995 *}
  1996 
  1997 
  1998 subsection {* Legacy tactics and ML bindings *}
  1999 
  2000 ML {*
  2001 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  2002 
  2003 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  2004 local
  2005   fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  2006     | wrong_prem (Bound _) = true
  2007     | wrong_prem _ = false;
  2008   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2009 in
  2010   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2011   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2012 end;
  2013 
  2014 val all_conj_distrib = @{thm all_conj_distrib};
  2015 val all_simps = @{thms all_simps};
  2016 val atomize_not = @{thm atomize_not};
  2017 val case_split = @{thm case_split};
  2018 val cases_simp = @{thm cases_simp};
  2019 val choice_eq = @{thm choice_eq};
  2020 val cong = @{thm cong};
  2021 val conj_comms = @{thms conj_comms};
  2022 val conj_cong = @{thm conj_cong};
  2023 val de_Morgan_conj = @{thm de_Morgan_conj};
  2024 val de_Morgan_disj = @{thm de_Morgan_disj};
  2025 val disj_assoc = @{thm disj_assoc};
  2026 val disj_comms = @{thms disj_comms};
  2027 val disj_cong = @{thm disj_cong};
  2028 val eq_ac = @{thms eq_ac};
  2029 val eq_cong2 = @{thm eq_cong2}
  2030 val Eq_FalseI = @{thm Eq_FalseI};
  2031 val Eq_TrueI = @{thm Eq_TrueI};
  2032 val Ex1_def = @{thm Ex1_def};
  2033 val ex_disj_distrib = @{thm ex_disj_distrib};
  2034 val ex_simps = @{thms ex_simps};
  2035 val if_cancel = @{thm if_cancel};
  2036 val if_eq_cancel = @{thm if_eq_cancel};
  2037 val if_False = @{thm if_False};
  2038 val iff_conv_conj_imp = @{thm iff_conv_conj_imp};
  2039 val iff = @{thm iff};
  2040 val if_splits = @{thms if_splits};
  2041 val if_True = @{thm if_True};
  2042 val if_weak_cong = @{thm if_weak_cong};
  2043 val imp_all = @{thm imp_all};
  2044 val imp_cong = @{thm imp_cong};
  2045 val imp_conjL = @{thm imp_conjL};
  2046 val imp_conjR = @{thm imp_conjR};
  2047 val imp_conv_disj = @{thm imp_conv_disj};
  2048 val simp_implies_def = @{thm simp_implies_def};
  2049 val simp_thms = @{thms simp_thms};
  2050 val split_if = @{thm split_if};
  2051 val the1_equality = @{thm the1_equality};
  2052 val theI = @{thm theI};
  2053 val theI' = @{thm theI'};
  2054 val True_implies_equals = @{thm True_implies_equals};
  2055 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  2056 
  2057 *}
  2058 
  2059 hide_const (open) eq equal
  2060 
  2061 end