src/HOL/Probability/Independent_Family.thy
author hoelzl
Wed Oct 10 12:12:30 2012 +0200 (2012-10-10)
changeset 49794 3c7b5988e094
parent 49784 5e5b2da42a69
child 49795 9f2fb9b25a77
permissions -rw-r--r--
indep_vars does not need sigma-sets
     1 (*  Title:      HOL/Probability/Independent_Family.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {* Independent families of events, event sets, and random variables *}
     6 
     7 theory Independent_Family
     8   imports Probability_Measure Infinite_Product_Measure
     9 begin
    10 
    11 lemma INT_decseq_offset:
    12   assumes "decseq F"
    13   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
    14 proof safe
    15   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
    16   show "x \<in> F i"
    17   proof cases
    18     from x have "x \<in> F n" by auto
    19     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
    20       unfolding decseq_def by simp
    21     finally show ?thesis .
    22   qed (insert x, simp)
    23 qed auto
    24 
    25 definition (in prob_space)
    26   "indep_sets F I \<longleftrightarrow> (\<forall>i\<in>I. F i \<subseteq> events) \<and>
    27     (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> (\<forall>A\<in>Pi J F. prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))))"
    28 
    29 definition (in prob_space)
    30   "indep_set A B \<longleftrightarrow> indep_sets (bool_case A B) UNIV"
    31 
    32 definition (in prob_space)
    33   indep_events_def_alt: "indep_events A I \<longleftrightarrow> indep_sets (\<lambda>i. {A i}) I"
    34 
    35 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    36   by auto
    37 
    38 lemma (in prob_space) indep_events_def:
    39   "indep_events A I \<longleftrightarrow> (A`I \<subseteq> events) \<and>
    40     (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j)))"
    41   unfolding indep_events_def_alt indep_sets_def
    42   apply (simp add: Ball_def Pi_iff image_subset_iff_funcset)
    43   apply (intro conj_cong refl arg_cong[where f=All] ext imp_cong)
    44   apply auto
    45   done
    46 
    47 definition (in prob_space)
    48   "indep_event A B \<longleftrightarrow> indep_events (bool_case A B) UNIV"
    49 
    50 lemma (in prob_space) indep_sets_cong:
    51   "I = J \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> F i = G i) \<Longrightarrow> indep_sets F I \<longleftrightarrow> indep_sets G J"
    52   by (simp add: indep_sets_def, intro conj_cong all_cong imp_cong ball_cong) blast+
    53 
    54 lemma (in prob_space) indep_events_finite_index_events:
    55   "indep_events F I \<longleftrightarrow> (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_events F J)"
    56   by (auto simp: indep_events_def)
    57 
    58 lemma (in prob_space) indep_sets_finite_index_sets:
    59   "indep_sets F I \<longleftrightarrow> (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_sets F J)"
    60 proof (intro iffI allI impI)
    61   assume *: "\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_sets F J"
    62   show "indep_sets F I" unfolding indep_sets_def
    63   proof (intro conjI ballI allI impI)
    64     fix i assume "i \<in> I"
    65     with *[THEN spec, of "{i}"] show "F i \<subseteq> events"
    66       by (auto simp: indep_sets_def)
    67   qed (insert *, auto simp: indep_sets_def)
    68 qed (auto simp: indep_sets_def)
    69 
    70 lemma (in prob_space) indep_sets_mono_index:
    71   "J \<subseteq> I \<Longrightarrow> indep_sets F I \<Longrightarrow> indep_sets F J"
    72   unfolding indep_sets_def by auto
    73 
    74 lemma (in prob_space) indep_sets_mono_sets:
    75   assumes indep: "indep_sets F I"
    76   assumes mono: "\<And>i. i\<in>I \<Longrightarrow> G i \<subseteq> F i"
    77   shows "indep_sets G I"
    78 proof -
    79   have "(\<forall>i\<in>I. F i \<subseteq> events) \<Longrightarrow> (\<forall>i\<in>I. G i \<subseteq> events)"
    80     using mono by auto
    81   moreover have "\<And>A J. J \<subseteq> I \<Longrightarrow> A \<in> (\<Pi> j\<in>J. G j) \<Longrightarrow> A \<in> (\<Pi> j\<in>J. F j)"
    82     using mono by (auto simp: Pi_iff)
    83   ultimately show ?thesis
    84     using indep by (auto simp: indep_sets_def)
    85 qed
    86 
    87 lemma (in prob_space) indep_sets_mono:
    88   assumes indep: "indep_sets F I"
    89   assumes mono: "J \<subseteq> I" "\<And>i. i\<in>J \<Longrightarrow> G i \<subseteq> F i"
    90   shows "indep_sets G J"
    91   apply (rule indep_sets_mono_sets)
    92   apply (rule indep_sets_mono_index)
    93   apply (fact +)
    94   done
    95 
    96 lemma (in prob_space) indep_setsI:
    97   assumes "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> events"
    98     and "\<And>A J. J \<noteq> {} \<Longrightarrow> J \<subseteq> I \<Longrightarrow> finite J \<Longrightarrow> (\<forall>j\<in>J. A j \<in> F j) \<Longrightarrow> prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
    99   shows "indep_sets F I"
   100   using assms unfolding indep_sets_def by (auto simp: Pi_iff)
   101 
   102 lemma (in prob_space) indep_setsD:
   103   assumes "indep_sets F I" and "J \<subseteq> I" "J \<noteq> {}" "finite J" "\<forall>j\<in>J. A j \<in> F j"
   104   shows "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   105   using assms unfolding indep_sets_def by auto
   106 
   107 lemma (in prob_space) indep_setI:
   108   assumes ev: "A \<subseteq> events" "B \<subseteq> events"
   109     and indep: "\<And>a b. a \<in> A \<Longrightarrow> b \<in> B \<Longrightarrow> prob (a \<inter> b) = prob a * prob b"
   110   shows "indep_set A B"
   111   unfolding indep_set_def
   112 proof (rule indep_setsI)
   113   fix F J assume "J \<noteq> {}" "J \<subseteq> UNIV"
   114     and F: "\<forall>j\<in>J. F j \<in> (case j of True \<Rightarrow> A | False \<Rightarrow> B)"
   115   have "J \<in> Pow UNIV" by auto
   116   with F `J \<noteq> {}` indep[of "F True" "F False"]
   117   show "prob (\<Inter>j\<in>J. F j) = (\<Prod>j\<in>J. prob (F j))"
   118     unfolding UNIV_bool Pow_insert by (auto simp: ac_simps)
   119 qed (auto split: bool.split simp: ev)
   120 
   121 lemma (in prob_space) indep_setD:
   122   assumes indep: "indep_set A B" and ev: "a \<in> A" "b \<in> B"
   123   shows "prob (a \<inter> b) = prob a * prob b"
   124   using indep[unfolded indep_set_def, THEN indep_setsD, of UNIV "bool_case a b"] ev
   125   by (simp add: ac_simps UNIV_bool)
   126 
   127 lemma (in prob_space)
   128   assumes indep: "indep_set A B"
   129   shows indep_setD_ev1: "A \<subseteq> events"
   130     and indep_setD_ev2: "B \<subseteq> events"
   131   using indep unfolding indep_set_def indep_sets_def UNIV_bool by auto
   132 
   133 lemma (in prob_space) indep_sets_dynkin:
   134   assumes indep: "indep_sets F I"
   135   shows "indep_sets (\<lambda>i. dynkin (space M) (F i)) I"
   136     (is "indep_sets ?F I")
   137 proof (subst indep_sets_finite_index_sets, intro allI impI ballI)
   138   fix J assume "finite J" "J \<subseteq> I" "J \<noteq> {}"
   139   with indep have "indep_sets F J"
   140     by (subst (asm) indep_sets_finite_index_sets) auto
   141   { fix J K assume "indep_sets F K"
   142     let ?G = "\<lambda>S i. if i \<in> S then ?F i else F i"
   143     assume "finite J" "J \<subseteq> K"
   144     then have "indep_sets (?G J) K"
   145     proof induct
   146       case (insert j J)
   147       moreover def G \<equiv> "?G J"
   148       ultimately have G: "indep_sets G K" "\<And>i. i \<in> K \<Longrightarrow> G i \<subseteq> events" and "j \<in> K"
   149         by (auto simp: indep_sets_def)
   150       let ?D = "{E\<in>events. indep_sets (G(j := {E})) K }"
   151       { fix X assume X: "X \<in> events"
   152         assume indep: "\<And>J A. J \<noteq> {} \<Longrightarrow> J \<subseteq> K \<Longrightarrow> finite J \<Longrightarrow> j \<notin> J \<Longrightarrow> (\<forall>i\<in>J. A i \<in> G i)
   153           \<Longrightarrow> prob ((\<Inter>i\<in>J. A i) \<inter> X) = prob X * (\<Prod>i\<in>J. prob (A i))"
   154         have "indep_sets (G(j := {X})) K"
   155         proof (rule indep_setsI)
   156           fix i assume "i \<in> K" then show "(G(j:={X})) i \<subseteq> events"
   157             using G X by auto
   158         next
   159           fix A J assume J: "J \<noteq> {}" "J \<subseteq> K" "finite J" "\<forall>i\<in>J. A i \<in> (G(j := {X})) i"
   160           show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   161           proof cases
   162             assume "j \<in> J"
   163             with J have "A j = X" by auto
   164             show ?thesis
   165             proof cases
   166               assume "J = {j}" then show ?thesis by simp
   167             next
   168               assume "J \<noteq> {j}"
   169               have "prob (\<Inter>i\<in>J. A i) = prob ((\<Inter>i\<in>J-{j}. A i) \<inter> X)"
   170                 using `j \<in> J` `A j = X` by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   171               also have "\<dots> = prob X * (\<Prod>i\<in>J-{j}. prob (A i))"
   172               proof (rule indep)
   173                 show "J - {j} \<noteq> {}" "J - {j} \<subseteq> K" "finite (J - {j})" "j \<notin> J - {j}"
   174                   using J `J \<noteq> {j}` `j \<in> J` by auto
   175                 show "\<forall>i\<in>J - {j}. A i \<in> G i"
   176                   using J by auto
   177               qed
   178               also have "\<dots> = prob (A j) * (\<Prod>i\<in>J-{j}. prob (A i))"
   179                 using `A j = X` by simp
   180               also have "\<dots> = (\<Prod>i\<in>J. prob (A i))"
   181                 unfolding setprod.insert_remove[OF `finite J`, symmetric, of "\<lambda>i. prob  (A i)"]
   182                 using `j \<in> J` by (simp add: insert_absorb)
   183               finally show ?thesis .
   184             qed
   185           next
   186             assume "j \<notin> J"
   187             with J have "\<forall>i\<in>J. A i \<in> G i" by (auto split: split_if_asm)
   188             with J show ?thesis
   189               by (intro indep_setsD[OF G(1)]) auto
   190           qed
   191         qed }
   192       note indep_sets_insert = this
   193       have "dynkin_system (space M) ?D"
   194       proof (rule dynkin_systemI', simp_all cong del: indep_sets_cong, safe)
   195         show "indep_sets (G(j := {{}})) K"
   196           by (rule indep_sets_insert) auto
   197       next
   198         fix X assume X: "X \<in> events" and G': "indep_sets (G(j := {X})) K"
   199         show "indep_sets (G(j := {space M - X})) K"
   200         proof (rule indep_sets_insert)
   201           fix J A assume J: "J \<noteq> {}" "J \<subseteq> K" "finite J" "j \<notin> J" and A: "\<forall>i\<in>J. A i \<in> G i"
   202           then have A_sets: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> events"
   203             using G by auto
   204           have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) =
   205               prob ((\<Inter>j\<in>J. A j) - (\<Inter>i\<in>insert j J. (A(j := X)) i))"
   206             using A_sets sets_into_space[of _ M] X `J \<noteq> {}`
   207             by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   208           also have "\<dots> = prob (\<Inter>j\<in>J. A j) - prob (\<Inter>i\<in>insert j J. (A(j := X)) i)"
   209             using J `J \<noteq> {}` `j \<notin> J` A_sets X sets_into_space
   210             by (auto intro!: finite_measure_Diff finite_INT split: split_if_asm)
   211           finally have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) =
   212               prob (\<Inter>j\<in>J. A j) - prob (\<Inter>i\<in>insert j J. (A(j := X)) i)" .
   213           moreover {
   214             have "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   215               using J A `finite J` by (intro indep_setsD[OF G(1)]) auto
   216             then have "prob (\<Inter>j\<in>J. A j) = prob (space M) * (\<Prod>i\<in>J. prob (A i))"
   217               using prob_space by simp }
   218           moreover {
   219             have "prob (\<Inter>i\<in>insert j J. (A(j := X)) i) = (\<Prod>i\<in>insert j J. prob ((A(j := X)) i))"
   220               using J A `j \<in> K` by (intro indep_setsD[OF G']) auto
   221             then have "prob (\<Inter>i\<in>insert j J. (A(j := X)) i) = prob X * (\<Prod>i\<in>J. prob (A i))"
   222               using `finite J` `j \<notin> J` by (auto intro!: setprod_cong) }
   223           ultimately have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) = (prob (space M) - prob X) * (\<Prod>i\<in>J. prob (A i))"
   224             by (simp add: field_simps)
   225           also have "\<dots> = prob (space M - X) * (\<Prod>i\<in>J. prob (A i))"
   226             using X A by (simp add: finite_measure_compl)
   227           finally show "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) = prob (space M - X) * (\<Prod>i\<in>J. prob (A i))" .
   228         qed (insert X, auto)
   229       next
   230         fix F :: "nat \<Rightarrow> 'a set" assume disj: "disjoint_family F" and "range F \<subseteq> ?D"
   231         then have F: "\<And>i. F i \<in> events" "\<And>i. indep_sets (G(j:={F i})) K" by auto
   232         show "indep_sets (G(j := {\<Union>k. F k})) K"
   233         proof (rule indep_sets_insert)
   234           fix J A assume J: "j \<notin> J" "J \<noteq> {}" "J \<subseteq> K" "finite J" and A: "\<forall>i\<in>J. A i \<in> G i"
   235           then have A_sets: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> events"
   236             using G by auto
   237           have "prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)) = prob (\<Union>k. (\<Inter>i\<in>insert j J. (A(j := F k)) i))"
   238             using `J \<noteq> {}` `j \<notin> J` `j \<in> K` by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   239           moreover have "(\<lambda>k. prob (\<Inter>i\<in>insert j J. (A(j := F k)) i)) sums prob (\<Union>k. (\<Inter>i\<in>insert j J. (A(j := F k)) i))"
   240           proof (rule finite_measure_UNION)
   241             show "disjoint_family (\<lambda>k. \<Inter>i\<in>insert j J. (A(j := F k)) i)"
   242               using disj by (rule disjoint_family_on_bisimulation) auto
   243             show "range (\<lambda>k. \<Inter>i\<in>insert j J. (A(j := F k)) i) \<subseteq> events"
   244               using A_sets F `finite J` `J \<noteq> {}` `j \<notin> J` by (auto intro!: Int)
   245           qed
   246           moreover { fix k
   247             from J A `j \<in> K` have "prob (\<Inter>i\<in>insert j J. (A(j := F k)) i) = prob (F k) * (\<Prod>i\<in>J. prob (A i))"
   248               by (subst indep_setsD[OF F(2)]) (auto intro!: setprod_cong split: split_if_asm)
   249             also have "\<dots> = prob (F k) * prob (\<Inter>i\<in>J. A i)"
   250               using J A `j \<in> K` by (subst indep_setsD[OF G(1)]) auto
   251             finally have "prob (\<Inter>i\<in>insert j J. (A(j := F k)) i) = prob (F k) * prob (\<Inter>i\<in>J. A i)" . }
   252           ultimately have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)))"
   253             by simp
   254           moreover
   255           have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob (\<Union>k. F k) * prob (\<Inter>i\<in>J. A i))"
   256             using disj F(1) by (intro finite_measure_UNION sums_mult2) auto
   257           then have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob (\<Union>k. F k) * (\<Prod>i\<in>J. prob (A i)))"
   258             using J A `j \<in> K` by (subst indep_setsD[OF G(1), symmetric]) auto
   259           ultimately
   260           show "prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)) = prob (\<Union>k. F k) * (\<Prod>j\<in>J. prob (A j))"
   261             by (auto dest!: sums_unique)
   262         qed (insert F, auto)
   263       qed (insert sets_into_space, auto)
   264       then have mono: "dynkin (space M) (G j) \<subseteq> {E \<in> events. indep_sets (G(j := {E})) K}"
   265       proof (rule dynkin_system.dynkin_subset, safe)
   266         fix X assume "X \<in> G j"
   267         then show "X \<in> events" using G `j \<in> K` by auto
   268         from `indep_sets G K`
   269         show "indep_sets (G(j := {X})) K"
   270           by (rule indep_sets_mono_sets) (insert `X \<in> G j`, auto)
   271       qed
   272       have "indep_sets (G(j:=?D)) K"
   273       proof (rule indep_setsI)
   274         fix i assume "i \<in> K" then show "(G(j := ?D)) i \<subseteq> events"
   275           using G(2) by auto
   276       next
   277         fix A J assume J: "J\<noteq>{}" "J \<subseteq> K" "finite J" and A: "\<forall>i\<in>J. A i \<in> (G(j := ?D)) i"
   278         show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   279         proof cases
   280           assume "j \<in> J"
   281           with A have indep: "indep_sets (G(j := {A j})) K" by auto
   282           from J A show ?thesis
   283             by (intro indep_setsD[OF indep]) auto
   284         next
   285           assume "j \<notin> J"
   286           with J A have "\<forall>i\<in>J. A i \<in> G i" by (auto split: split_if_asm)
   287           with J show ?thesis
   288             by (intro indep_setsD[OF G(1)]) auto
   289         qed
   290       qed
   291       then have "indep_sets (G(j := dynkin (space M) (G j))) K"
   292         by (rule indep_sets_mono_sets) (insert mono, auto)
   293       then show ?case
   294         by (rule indep_sets_mono_sets) (insert `j \<in> K` `j \<notin> J`, auto simp: G_def)
   295     qed (insert `indep_sets F K`, simp) }
   296   from this[OF `indep_sets F J` `finite J` subset_refl]
   297   show "indep_sets ?F J"
   298     by (rule indep_sets_mono_sets) auto
   299 qed
   300 
   301 lemma (in prob_space) indep_sets_sigma:
   302   assumes indep: "indep_sets F I"
   303   assumes stable: "\<And>i. i \<in> I \<Longrightarrow> Int_stable (F i)"
   304   shows "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I"
   305 proof -
   306   from indep_sets_dynkin[OF indep]
   307   show ?thesis
   308   proof (rule indep_sets_mono_sets, subst sigma_eq_dynkin, simp_all add: stable)
   309     fix i assume "i \<in> I"
   310     with indep have "F i \<subseteq> events" by (auto simp: indep_sets_def)
   311     with sets_into_space show "F i \<subseteq> Pow (space M)" by auto
   312   qed
   313 qed
   314 
   315 lemma (in prob_space) indep_sets_sigma_sets_iff:
   316   assumes "\<And>i. i \<in> I \<Longrightarrow> Int_stable (F i)"
   317   shows "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I \<longleftrightarrow> indep_sets F I"
   318 proof
   319   assume "indep_sets F I" then show "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I"
   320     by (rule indep_sets_sigma) fact
   321 next
   322   assume "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I" then show "indep_sets F I"
   323     by (rule indep_sets_mono_sets) (intro subsetI sigma_sets.Basic)
   324 qed
   325 
   326 definition (in prob_space)
   327   indep_vars_def2: "indep_vars M' X I \<longleftrightarrow>
   328     (\<forall>i\<in>I. random_variable (M' i) (X i)) \<and>
   329     indep_sets (\<lambda>i. { X i -` A \<inter> space M | A. A \<in> sets (M' i)}) I"
   330 
   331 definition (in prob_space)
   332   "indep_var Ma A Mb B \<longleftrightarrow> indep_vars (bool_case Ma Mb) (bool_case A B) UNIV"
   333 
   334 lemma (in prob_space) indep_vars_def:
   335   "indep_vars M' X I \<longleftrightarrow>
   336     (\<forall>i\<in>I. random_variable (M' i) (X i)) \<and>
   337     indep_sets (\<lambda>i. sigma_sets (space M) { X i -` A \<inter> space M | A. A \<in> sets (M' i)}) I"
   338   unfolding indep_vars_def2
   339   apply (rule conj_cong[OF refl])
   340   apply (rule indep_sets_sigma_sets_iff[symmetric])
   341   apply (auto simp: Int_stable_def)
   342   apply (rule_tac x="A \<inter> Aa" in exI)
   343   apply auto
   344   done
   345 
   346 lemma (in prob_space) indep_var_eq:
   347   "indep_var S X T Y \<longleftrightarrow>
   348     (random_variable S X \<and> random_variable T Y) \<and>
   349     indep_set
   350       (sigma_sets (space M) { X -` A \<inter> space M | A. A \<in> sets S})
   351       (sigma_sets (space M) { Y -` A \<inter> space M | A. A \<in> sets T})"
   352   unfolding indep_var_def indep_vars_def indep_set_def UNIV_bool
   353   by (intro arg_cong2[where f="op \<and>"] arg_cong2[where f=indep_sets] ext)
   354      (auto split: bool.split)
   355 
   356 lemma (in prob_space) indep_sets2_eq:
   357   "indep_set A B \<longleftrightarrow> A \<subseteq> events \<and> B \<subseteq> events \<and> (\<forall>a\<in>A. \<forall>b\<in>B. prob (a \<inter> b) = prob a * prob b)"
   358   unfolding indep_set_def
   359 proof (intro iffI ballI conjI)
   360   assume indep: "indep_sets (bool_case A B) UNIV"
   361   { fix a b assume "a \<in> A" "b \<in> B"
   362     with indep_setsD[OF indep, of UNIV "bool_case a b"]
   363     show "prob (a \<inter> b) = prob a * prob b"
   364       unfolding UNIV_bool by (simp add: ac_simps) }
   365   from indep show "A \<subseteq> events" "B \<subseteq> events"
   366     unfolding indep_sets_def UNIV_bool by auto
   367 next
   368   assume *: "A \<subseteq> events \<and> B \<subseteq> events \<and> (\<forall>a\<in>A. \<forall>b\<in>B. prob (a \<inter> b) = prob a * prob b)"
   369   show "indep_sets (bool_case A B) UNIV"
   370   proof (rule indep_setsI)
   371     fix i show "(case i of True \<Rightarrow> A | False \<Rightarrow> B) \<subseteq> events"
   372       using * by (auto split: bool.split)
   373   next
   374     fix J X assume "J \<noteq> {}" "J \<subseteq> UNIV" and X: "\<forall>j\<in>J. X j \<in> (case j of True \<Rightarrow> A | False \<Rightarrow> B)"
   375     then have "J = {True} \<or> J = {False} \<or> J = {True,False}"
   376       by (auto simp: UNIV_bool)
   377     then show "prob (\<Inter>j\<in>J. X j) = (\<Prod>j\<in>J. prob (X j))"
   378       using X * by auto
   379   qed
   380 qed
   381 
   382 lemma (in prob_space) indep_set_sigma_sets:
   383   assumes "indep_set A B"
   384   assumes A: "Int_stable A" and B: "Int_stable B"
   385   shows "indep_set (sigma_sets (space M) A) (sigma_sets (space M) B)"
   386 proof -
   387   have "indep_sets (\<lambda>i. sigma_sets (space M) (case i of True \<Rightarrow> A | False \<Rightarrow> B)) UNIV"
   388   proof (rule indep_sets_sigma)
   389     show "indep_sets (bool_case A B) UNIV"
   390       by (rule `indep_set A B`[unfolded indep_set_def])
   391     fix i show "Int_stable (case i of True \<Rightarrow> A | False \<Rightarrow> B)"
   392       using A B by (cases i) auto
   393   qed
   394   then show ?thesis
   395     unfolding indep_set_def
   396     by (rule indep_sets_mono_sets) (auto split: bool.split)
   397 qed
   398 
   399 lemma (in prob_space) indep_sets_collect_sigma:
   400   fixes I :: "'j \<Rightarrow> 'i set" and J :: "'j set" and E :: "'i \<Rightarrow> 'a set set"
   401   assumes indep: "indep_sets E (\<Union>j\<in>J. I j)"
   402   assumes Int_stable: "\<And>i j. j \<in> J \<Longrightarrow> i \<in> I j \<Longrightarrow> Int_stable (E i)"
   403   assumes disjoint: "disjoint_family_on I J"
   404   shows "indep_sets (\<lambda>j. sigma_sets (space M) (\<Union>i\<in>I j. E i)) J"
   405 proof -
   406   let ?E = "\<lambda>j. {\<Inter>k\<in>K. E' k| E' K. finite K \<and> K \<noteq> {} \<and> K \<subseteq> I j \<and> (\<forall>k\<in>K. E' k \<in> E k) }"
   407 
   408   from indep have E: "\<And>j i. j \<in> J \<Longrightarrow> i \<in> I j \<Longrightarrow> E i \<subseteq> events"
   409     unfolding indep_sets_def by auto
   410   { fix j
   411     let ?S = "sigma_sets (space M) (\<Union>i\<in>I j. E i)"
   412     assume "j \<in> J"
   413     from E[OF this] interpret S: sigma_algebra "space M" ?S
   414       using sets_into_space[of _ M] by (intro sigma_algebra_sigma_sets) auto
   415 
   416     have "sigma_sets (space M) (\<Union>i\<in>I j. E i) = sigma_sets (space M) (?E j)"
   417     proof (rule sigma_sets_eqI)
   418       fix A assume "A \<in> (\<Union>i\<in>I j. E i)"
   419       then guess i ..
   420       then show "A \<in> sigma_sets (space M) (?E j)"
   421         by (auto intro!: sigma_sets.intros(2-) exI[of _ "{i}"] exI[of _ "\<lambda>i. A"])
   422     next
   423       fix A assume "A \<in> ?E j"
   424       then obtain E' K where "finite K" "K \<noteq> {}" "K \<subseteq> I j" "\<And>k. k \<in> K \<Longrightarrow> E' k \<in> E k"
   425         and A: "A = (\<Inter>k\<in>K. E' k)"
   426         by auto
   427       then have "A \<in> ?S" unfolding A
   428         by (safe intro!: S.finite_INT) auto
   429       then show "A \<in> sigma_sets (space M) (\<Union>i\<in>I j. E i)"
   430         by simp
   431     qed }
   432   moreover have "indep_sets (\<lambda>j. sigma_sets (space M) (?E j)) J"
   433   proof (rule indep_sets_sigma)
   434     show "indep_sets ?E J"
   435     proof (intro indep_setsI)
   436       fix j assume "j \<in> J" with E show "?E j \<subseteq> events" by (force  intro!: finite_INT)
   437     next
   438       fix K A assume K: "K \<noteq> {}" "K \<subseteq> J" "finite K"
   439         and "\<forall>j\<in>K. A j \<in> ?E j"
   440       then have "\<forall>j\<in>K. \<exists>E' L. A j = (\<Inter>l\<in>L. E' l) \<and> finite L \<and> L \<noteq> {} \<and> L \<subseteq> I j \<and> (\<forall>l\<in>L. E' l \<in> E l)"
   441         by simp
   442       from bchoice[OF this] guess E' ..
   443       from bchoice[OF this] obtain L
   444         where A: "\<And>j. j\<in>K \<Longrightarrow> A j = (\<Inter>l\<in>L j. E' j l)"
   445         and L: "\<And>j. j\<in>K \<Longrightarrow> finite (L j)" "\<And>j. j\<in>K \<Longrightarrow> L j \<noteq> {}" "\<And>j. j\<in>K \<Longrightarrow> L j \<subseteq> I j"
   446         and E': "\<And>j l. j\<in>K \<Longrightarrow> l \<in> L j \<Longrightarrow> E' j l \<in> E l"
   447         by auto
   448 
   449       { fix k l j assume "k \<in> K" "j \<in> K" "l \<in> L j" "l \<in> L k"
   450         have "k = j"
   451         proof (rule ccontr)
   452           assume "k \<noteq> j"
   453           with disjoint `K \<subseteq> J` `k \<in> K` `j \<in> K` have "I k \<inter> I j = {}"
   454             unfolding disjoint_family_on_def by auto
   455           with L(2,3)[OF `j \<in> K`] L(2,3)[OF `k \<in> K`]
   456           show False using `l \<in> L k` `l \<in> L j` by auto
   457         qed }
   458       note L_inj = this
   459 
   460       def k \<equiv> "\<lambda>l. (SOME k. k \<in> K \<and> l \<in> L k)"
   461       { fix x j l assume *: "j \<in> K" "l \<in> L j"
   462         have "k l = j" unfolding k_def
   463         proof (rule some_equality)
   464           fix k assume "k \<in> K \<and> l \<in> L k"
   465           with * L_inj show "k = j" by auto
   466         qed (insert *, simp) }
   467       note k_simp[simp] = this
   468       let ?E' = "\<lambda>l. E' (k l) l"
   469       have "prob (\<Inter>j\<in>K. A j) = prob (\<Inter>l\<in>(\<Union>k\<in>K. L k). ?E' l)"
   470         by (auto simp: A intro!: arg_cong[where f=prob])
   471       also have "\<dots> = (\<Prod>l\<in>(\<Union>k\<in>K. L k). prob (?E' l))"
   472         using L K E' by (intro indep_setsD[OF indep]) (simp_all add: UN_mono)
   473       also have "\<dots> = (\<Prod>j\<in>K. \<Prod>l\<in>L j. prob (E' j l))"
   474         using K L L_inj by (subst setprod_UN_disjoint) auto
   475       also have "\<dots> = (\<Prod>j\<in>K. prob (A j))"
   476         using K L E' by (auto simp add: A intro!: setprod_cong indep_setsD[OF indep, symmetric]) blast
   477       finally show "prob (\<Inter>j\<in>K. A j) = (\<Prod>j\<in>K. prob (A j))" .
   478     qed
   479   next
   480     fix j assume "j \<in> J"
   481     show "Int_stable (?E j)"
   482     proof (rule Int_stableI)
   483       fix a assume "a \<in> ?E j" then obtain Ka Ea
   484         where a: "a = (\<Inter>k\<in>Ka. Ea k)" "finite Ka" "Ka \<noteq> {}" "Ka \<subseteq> I j" "\<And>k. k\<in>Ka \<Longrightarrow> Ea k \<in> E k" by auto
   485       fix b assume "b \<in> ?E j" then obtain Kb Eb
   486         where b: "b = (\<Inter>k\<in>Kb. Eb k)" "finite Kb" "Kb \<noteq> {}" "Kb \<subseteq> I j" "\<And>k. k\<in>Kb \<Longrightarrow> Eb k \<in> E k" by auto
   487       let ?A = "\<lambda>k. (if k \<in> Ka \<inter> Kb then Ea k \<inter> Eb k else if k \<in> Kb then Eb k else if k \<in> Ka then Ea k else {})"
   488       have "a \<inter> b = INTER (Ka \<union> Kb) ?A"
   489         by (simp add: a b set_eq_iff) auto
   490       with a b `j \<in> J` Int_stableD[OF Int_stable] show "a \<inter> b \<in> ?E j"
   491         by (intro CollectI exI[of _ "Ka \<union> Kb"] exI[of _ ?A]) auto
   492     qed
   493   qed
   494   ultimately show ?thesis
   495     by (simp cong: indep_sets_cong)
   496 qed
   497 
   498 definition (in prob_space) tail_events where
   499   "tail_events A = (\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   500 
   501 lemma (in prob_space) tail_events_sets:
   502   assumes A: "\<And>i::nat. A i \<subseteq> events"
   503   shows "tail_events A \<subseteq> events"
   504 proof
   505   fix X assume X: "X \<in> tail_events A"
   506   let ?A = "(\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   507   from X have "\<And>n::nat. X \<in> sigma_sets (space M) (UNION {n..} A)" by (auto simp: tail_events_def)
   508   from this[of 0] have "X \<in> sigma_sets (space M) (UNION UNIV A)" by simp
   509   then show "X \<in> events"
   510     by induct (insert A, auto)
   511 qed
   512 
   513 lemma (in prob_space) sigma_algebra_tail_events:
   514   assumes "\<And>i::nat. sigma_algebra (space M) (A i)"
   515   shows "sigma_algebra (space M) (tail_events A)"
   516   unfolding tail_events_def
   517 proof (simp add: sigma_algebra_iff2, safe)
   518   let ?A = "(\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   519   interpret A: sigma_algebra "space M" "A i" for i by fact
   520   { fix X x assume "X \<in> ?A" "x \<in> X"
   521     then have "\<And>n. X \<in> sigma_sets (space M) (UNION {n..} A)" by auto
   522     from this[of 0] have "X \<in> sigma_sets (space M) (UNION UNIV A)" by simp
   523     then have "X \<subseteq> space M"
   524       by induct (insert A.sets_into_space, auto)
   525     with `x \<in> X` show "x \<in> space M" by auto }
   526   { fix F :: "nat \<Rightarrow> 'a set" and n assume "range F \<subseteq> ?A"
   527     then show "(UNION UNIV F) \<in> sigma_sets (space M) (UNION {n..} A)"
   528       by (intro sigma_sets.Union) auto }
   529 qed (auto intro!: sigma_sets.Compl sigma_sets.Empty)
   530 
   531 lemma (in prob_space) kolmogorov_0_1_law:
   532   fixes A :: "nat \<Rightarrow> 'a set set"
   533   assumes "\<And>i::nat. sigma_algebra (space M) (A i)"
   534   assumes indep: "indep_sets A UNIV"
   535   and X: "X \<in> tail_events A"
   536   shows "prob X = 0 \<or> prob X = 1"
   537 proof -
   538   have A: "\<And>i. A i \<subseteq> events"
   539     using indep unfolding indep_sets_def by simp
   540 
   541   let ?D = "{D \<in> events. prob (X \<inter> D) = prob X * prob D}"
   542   interpret A: sigma_algebra "space M" "A i" for i by fact
   543   interpret T: sigma_algebra "space M" "tail_events A"
   544     by (rule sigma_algebra_tail_events) fact
   545   have "X \<subseteq> space M" using T.space_closed X by auto
   546 
   547   have X_in: "X \<in> events"
   548     using tail_events_sets A X by auto
   549 
   550   interpret D: dynkin_system "space M" ?D
   551   proof (rule dynkin_systemI)
   552     fix D assume "D \<in> ?D" then show "D \<subseteq> space M"
   553       using sets_into_space by auto
   554   next
   555     show "space M \<in> ?D"
   556       using prob_space `X \<subseteq> space M` by (simp add: Int_absorb2)
   557   next
   558     fix A assume A: "A \<in> ?D"
   559     have "prob (X \<inter> (space M - A)) = prob (X - (X \<inter> A))"
   560       using `X \<subseteq> space M` by (auto intro!: arg_cong[where f=prob])
   561     also have "\<dots> = prob X - prob (X \<inter> A)"
   562       using X_in A by (intro finite_measure_Diff) auto
   563     also have "\<dots> = prob X * prob (space M) - prob X * prob A"
   564       using A prob_space by auto
   565     also have "\<dots> = prob X * prob (space M - A)"
   566       using X_in A sets_into_space
   567       by (subst finite_measure_Diff) (auto simp: field_simps)
   568     finally show "space M - A \<in> ?D"
   569       using A `X \<subseteq> space M` by auto
   570   next
   571     fix F :: "nat \<Rightarrow> 'a set" assume dis: "disjoint_family F" and "range F \<subseteq> ?D"
   572     then have F: "range F \<subseteq> events" "\<And>i. prob (X \<inter> F i) = prob X * prob (F i)"
   573       by auto
   574     have "(\<lambda>i. prob (X \<inter> F i)) sums prob (\<Union>i. X \<inter> F i)"
   575     proof (rule finite_measure_UNION)
   576       show "range (\<lambda>i. X \<inter> F i) \<subseteq> events"
   577         using F X_in by auto
   578       show "disjoint_family (\<lambda>i. X \<inter> F i)"
   579         using dis by (rule disjoint_family_on_bisimulation) auto
   580     qed
   581     with F have "(\<lambda>i. prob X * prob (F i)) sums prob (X \<inter> (\<Union>i. F i))"
   582       by simp
   583     moreover have "(\<lambda>i. prob X * prob (F i)) sums (prob X * prob (\<Union>i. F i))"
   584       by (intro sums_mult finite_measure_UNION F dis)
   585     ultimately have "prob (X \<inter> (\<Union>i. F i)) = prob X * prob (\<Union>i. F i)"
   586       by (auto dest!: sums_unique)
   587     with F show "(\<Union>i. F i) \<in> ?D"
   588       by auto
   589   qed
   590 
   591   { fix n
   592     have "indep_sets (\<lambda>b. sigma_sets (space M) (\<Union>m\<in>bool_case {..n} {Suc n..} b. A m)) UNIV"
   593     proof (rule indep_sets_collect_sigma)
   594       have *: "(\<Union>b. case b of True \<Rightarrow> {..n} | False \<Rightarrow> {Suc n..}) = UNIV" (is "?U = _")
   595         by (simp split: bool.split add: set_eq_iff) (metis not_less_eq_eq)
   596       with indep show "indep_sets A ?U" by simp
   597       show "disjoint_family (bool_case {..n} {Suc n..})"
   598         unfolding disjoint_family_on_def by (auto split: bool.split)
   599       fix m
   600       show "Int_stable (A m)"
   601         unfolding Int_stable_def using A.Int by auto
   602     qed
   603     also have "(\<lambda>b. sigma_sets (space M) (\<Union>m\<in>bool_case {..n} {Suc n..} b. A m)) =
   604       bool_case (sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) (sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m))"
   605       by (auto intro!: ext split: bool.split)
   606     finally have indep: "indep_set (sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) (sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m))"
   607       unfolding indep_set_def by simp
   608 
   609     have "sigma_sets (space M) (\<Union>m\<in>{..n}. A m) \<subseteq> ?D"
   610     proof (simp add: subset_eq, rule)
   611       fix D assume D: "D \<in> sigma_sets (space M) (\<Union>m\<in>{..n}. A m)"
   612       have "X \<in> sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m)"
   613         using X unfolding tail_events_def by simp
   614       from indep_setD[OF indep D this] indep_setD_ev1[OF indep] D
   615       show "D \<in> events \<and> prob (X \<inter> D) = prob X * prob D"
   616         by (auto simp add: ac_simps)
   617     qed }
   618   then have "(\<Union>n. sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) \<subseteq> ?D" (is "?A \<subseteq> _")
   619     by auto
   620 
   621   note `X \<in> tail_events A`
   622   also {
   623     have "\<And>n. sigma_sets (space M) (\<Union>i\<in>{n..}. A i) \<subseteq> sigma_sets (space M) ?A"
   624       by (intro sigma_sets_subseteq UN_mono) auto
   625    then have "tail_events A \<subseteq> sigma_sets (space M) ?A"
   626       unfolding tail_events_def by auto }
   627   also have "sigma_sets (space M) ?A = dynkin (space M) ?A"
   628   proof (rule sigma_eq_dynkin)
   629     { fix B n assume "B \<in> sigma_sets (space M) (\<Union>m\<in>{..n}. A m)"
   630       then have "B \<subseteq> space M"
   631         by induct (insert A sets_into_space[of _ M], auto) }
   632     then show "?A \<subseteq> Pow (space M)" by auto
   633     show "Int_stable ?A"
   634     proof (rule Int_stableI)
   635       fix a assume "a \<in> ?A" then guess n .. note a = this
   636       fix b assume "b \<in> ?A" then guess m .. note b = this
   637       interpret Amn: sigma_algebra "space M" "sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   638         using A sets_into_space[of _ M] by (intro sigma_algebra_sigma_sets) auto
   639       have "sigma_sets (space M) (\<Union>i\<in>{..n}. A i) \<subseteq> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   640         by (intro sigma_sets_subseteq UN_mono) auto
   641       with a have "a \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)" by auto
   642       moreover
   643       have "sigma_sets (space M) (\<Union>i\<in>{..m}. A i) \<subseteq> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   644         by (intro sigma_sets_subseteq UN_mono) auto
   645       with b have "b \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)" by auto
   646       ultimately have "a \<inter> b \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   647         using Amn.Int[of a b] by simp
   648       then show "a \<inter> b \<in> (\<Union>n. sigma_sets (space M) (\<Union>i\<in>{..n}. A i))" by auto
   649     qed
   650   qed
   651   also have "dynkin (space M) ?A \<subseteq> ?D"
   652     using `?A \<subseteq> ?D` by (auto intro!: D.dynkin_subset)
   653   finally show ?thesis by auto
   654 qed
   655 
   656 lemma (in prob_space) borel_0_1_law:
   657   fixes F :: "nat \<Rightarrow> 'a set"
   658   assumes F2: "indep_events F UNIV"
   659   shows "prob (\<Inter>n. \<Union>m\<in>{n..}. F m) = 0 \<or> prob (\<Inter>n. \<Union>m\<in>{n..}. F m) = 1"
   660 proof (rule kolmogorov_0_1_law[of "\<lambda>i. sigma_sets (space M) { F i }"])
   661   have F1: "range F \<subseteq> events"
   662     using F2 by (simp add: indep_events_def subset_eq)
   663   { fix i show "sigma_algebra (space M) (sigma_sets (space M) {F i})"
   664       using sigma_algebra_sigma_sets[of "{F i}" "space M"] F1 sets_into_space
   665       by auto }
   666   show "indep_sets (\<lambda>i. sigma_sets (space M) {F i}) UNIV"
   667   proof (rule indep_sets_sigma)
   668     show "indep_sets (\<lambda>i. {F i}) UNIV"
   669       unfolding indep_events_def_alt[symmetric] by fact
   670     fix i show "Int_stable {F i}"
   671       unfolding Int_stable_def by simp
   672   qed
   673   let ?Q = "\<lambda>n. \<Union>i\<in>{n..}. F i"
   674   show "(\<Inter>n. \<Union>m\<in>{n..}. F m) \<in> tail_events (\<lambda>i. sigma_sets (space M) {F i})"
   675     unfolding tail_events_def
   676   proof
   677     fix j
   678     interpret S: sigma_algebra "space M" "sigma_sets (space M) (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})"
   679       using order_trans[OF F1 space_closed]
   680       by (intro sigma_algebra_sigma_sets) (simp add: sigma_sets_singleton subset_eq)
   681     have "(\<Inter>n. ?Q n) = (\<Inter>n\<in>{j..}. ?Q n)"
   682       by (intro decseq_SucI INT_decseq_offset UN_mono) auto
   683     also have "\<dots> \<in> sigma_sets (space M) (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})"
   684       using order_trans[OF F1 space_closed]
   685       by (safe intro!: S.countable_INT S.countable_UN)
   686          (auto simp: sigma_sets_singleton intro!: sigma_sets.Basic bexI)
   687     finally show "(\<Inter>n. ?Q n) \<in> sigma_sets (space M) (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})"
   688       by simp
   689   qed
   690 qed
   691 
   692 lemma (in prob_space) indep_sets_finite:
   693   assumes I: "I \<noteq> {}" "finite I"
   694     and F: "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> events" "\<And>i. i \<in> I \<Longrightarrow> space M \<in> F i"
   695   shows "indep_sets F I \<longleftrightarrow> (\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j)))"
   696 proof
   697   assume *: "indep_sets F I"
   698   from I show "\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j))"
   699     by (intro indep_setsD[OF *] ballI) auto
   700 next
   701   assume indep: "\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j))"
   702   show "indep_sets F I"
   703   proof (rule indep_setsI[OF F(1)])
   704     fix A J assume J: "J \<noteq> {}" "J \<subseteq> I" "finite J"
   705     assume A: "\<forall>j\<in>J. A j \<in> F j"
   706     let ?A = "\<lambda>j. if j \<in> J then A j else space M"
   707     have "prob (\<Inter>j\<in>I. ?A j) = prob (\<Inter>j\<in>J. A j)"
   708       using subset_trans[OF F(1) space_closed] J A
   709       by (auto intro!: arg_cong[where f=prob] split: split_if_asm) blast
   710     also
   711     from A F have "(\<lambda>j. if j \<in> J then A j else space M) \<in> Pi I F" (is "?A \<in> _")
   712       by (auto split: split_if_asm)
   713     with indep have "prob (\<Inter>j\<in>I. ?A j) = (\<Prod>j\<in>I. prob (?A j))"
   714       by auto
   715     also have "\<dots> = (\<Prod>j\<in>J. prob (A j))"
   716       unfolding if_distrib setprod.If_cases[OF `finite I`]
   717       using prob_space `J \<subseteq> I` by (simp add: Int_absorb1 setprod_1)
   718     finally show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))" ..
   719   qed
   720 qed
   721 
   722 lemma (in prob_space) indep_vars_finite:
   723   fixes I :: "'i set"
   724   assumes I: "I \<noteq> {}" "finite I"
   725     and M': "\<And>i. i \<in> I \<Longrightarrow> sets (M' i) = sigma_sets (space (M' i)) (E i)"
   726     and rv: "\<And>i. i \<in> I \<Longrightarrow> random_variable (M' i) (X i)"
   727     and Int_stable: "\<And>i. i \<in> I \<Longrightarrow> Int_stable (E i)"
   728     and space: "\<And>i. i \<in> I \<Longrightarrow> space (M' i) \<in> E i" and closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M' i))"
   729   shows "indep_vars M' X I \<longleftrightarrow>
   730     (\<forall>A\<in>(\<Pi> i\<in>I. E i). prob (\<Inter>j\<in>I. X j -` A j \<inter> space M) = (\<Prod>j\<in>I. prob (X j -` A j \<inter> space M)))"
   731 proof -
   732   from rv have X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> space M \<rightarrow> space (M' i)"
   733     unfolding measurable_def by simp
   734 
   735   { fix i assume "i\<in>I"
   736     from closed[OF `i \<in> I`]
   737     have "sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}
   738       = sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> E i}"
   739       unfolding sigma_sets_vimage_commute[OF X, OF `i \<in> I`, symmetric] M'[OF `i \<in> I`]
   740       by (subst sigma_sets_sigma_sets_eq) auto }
   741   note sigma_sets_X = this
   742 
   743   { fix i assume "i\<in>I"
   744     have "Int_stable {X i -` A \<inter> space M |A. A \<in> E i}"
   745     proof (rule Int_stableI)
   746       fix a assume "a \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   747       then obtain A where "a = X i -` A \<inter> space M" "A \<in> E i" by auto
   748       moreover
   749       fix b assume "b \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   750       then obtain B where "b = X i -` B \<inter> space M" "B \<in> E i" by auto
   751       moreover
   752       have "(X i -` A \<inter> space M) \<inter> (X i -` B \<inter> space M) = X i -` (A \<inter> B) \<inter> space M" by auto
   753       moreover note Int_stable[OF `i \<in> I`]
   754       ultimately
   755       show "a \<inter> b \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   756         by (auto simp del: vimage_Int intro!: exI[of _ "A \<inter> B"] dest: Int_stableD)
   757     qed }
   758   note indep_sets_X = indep_sets_sigma_sets_iff[OF this]
   759 
   760   { fix i assume "i \<in> I"
   761     { fix A assume "A \<in> E i"
   762       with M'[OF `i \<in> I`] have "A \<in> sets (M' i)" by auto
   763       moreover
   764       from rv[OF `i\<in>I`] have "X i \<in> measurable M (M' i)" by auto
   765       ultimately
   766       have "X i -` A \<inter> space M \<in> sets M" by (auto intro: measurable_sets) }
   767     with X[OF `i\<in>I`] space[OF `i\<in>I`]
   768     have "{X i -` A \<inter> space M |A. A \<in> E i} \<subseteq> events"
   769       "space M \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   770       by (auto intro!: exI[of _ "space (M' i)"]) }
   771   note indep_sets_finite_X = indep_sets_finite[OF I this]
   772 
   773   have "(\<forall>A\<in>\<Pi> i\<in>I. {X i -` A \<inter> space M |A. A \<in> E i}. prob (INTER I A) = (\<Prod>j\<in>I. prob (A j))) =
   774     (\<forall>A\<in>\<Pi> i\<in>I. E i. prob ((\<Inter>j\<in>I. X j -` A j) \<inter> space M) = (\<Prod>x\<in>I. prob (X x -` A x \<inter> space M)))"
   775     (is "?L = ?R")
   776   proof safe
   777     fix A assume ?L and A: "A \<in> (\<Pi> i\<in>I. E i)"
   778     from `?L`[THEN bspec, of "\<lambda>i. X i -` A i \<inter> space M"] A `I \<noteq> {}`
   779     show "prob ((\<Inter>j\<in>I. X j -` A j) \<inter> space M) = (\<Prod>x\<in>I. prob (X x -` A x \<inter> space M))"
   780       by (auto simp add: Pi_iff)
   781   next
   782     fix A assume ?R and A: "A \<in> (\<Pi> i\<in>I. {X i -` A \<inter> space M |A. A \<in> E i})"
   783     from A have "\<forall>i\<in>I. \<exists>B. A i = X i -` B \<inter> space M \<and> B \<in> E i" by auto
   784     from bchoice[OF this] obtain B where B: "\<forall>i\<in>I. A i = X i -` B i \<inter> space M"
   785       "B \<in> (\<Pi> i\<in>I. E i)" by auto
   786     from `?R`[THEN bspec, OF B(2)] B(1) `I \<noteq> {}`
   787     show "prob (INTER I A) = (\<Prod>j\<in>I. prob (A j))"
   788       by simp
   789   qed
   790   then show ?thesis using `I \<noteq> {}`
   791     by (simp add: rv indep_vars_def indep_sets_X sigma_sets_X indep_sets_finite_X cong: indep_sets_cong)
   792 qed
   793 
   794 lemma (in prob_space) indep_vars_compose:
   795   assumes "indep_vars M' X I"
   796   assumes rv: "\<And>i. i \<in> I \<Longrightarrow> Y i \<in> measurable (M' i) (N i)"
   797   shows "indep_vars N (\<lambda>i. Y i \<circ> X i) I"
   798   unfolding indep_vars_def
   799 proof
   800   from rv `indep_vars M' X I`
   801   show "\<forall>i\<in>I. random_variable (N i) (Y i \<circ> X i)"
   802     by (auto simp: indep_vars_def)
   803 
   804   have "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   805     using `indep_vars M' X I` by (simp add: indep_vars_def)
   806   then show "indep_sets (\<lambda>i. sigma_sets (space M) {(Y i \<circ> X i) -` A \<inter> space M |A. A \<in> sets (N i)}) I"
   807   proof (rule indep_sets_mono_sets)
   808     fix i assume "i \<in> I"
   809     with `indep_vars M' X I` have X: "X i \<in> space M \<rightarrow> space (M' i)"
   810       unfolding indep_vars_def measurable_def by auto
   811     { fix A assume "A \<in> sets (N i)"
   812       then have "\<exists>B. (Y i \<circ> X i) -` A \<inter> space M = X i -` B \<inter> space M \<and> B \<in> sets (M' i)"
   813         by (intro exI[of _ "Y i -` A \<inter> space (M' i)"])
   814            (auto simp: vimage_compose intro!: measurable_sets rv `i \<in> I` funcset_mem[OF X]) }
   815     then show "sigma_sets (space M) {(Y i \<circ> X i) -` A \<inter> space M |A. A \<in> sets (N i)} \<subseteq>
   816       sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   817       by (intro sigma_sets_subseteq) (auto simp: vimage_compose)
   818   qed
   819 qed
   820 
   821 lemma (in prob_space) indep_varsD_finite:
   822   assumes X: "indep_vars M' X I"
   823   assumes I: "I \<noteq> {}" "finite I" "\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M' i)"
   824   shows "prob (\<Inter>i\<in>I. X i -` A i \<inter> space M) = (\<Prod>i\<in>I. prob (X i -` A i \<inter> space M))"
   825 proof (rule indep_setsD)
   826   show "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   827     using X by (auto simp: indep_vars_def)
   828   show "I \<subseteq> I" "I \<noteq> {}" "finite I" using I by auto
   829   show "\<forall>i\<in>I. X i -` A i \<inter> space M \<in> sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   830     using I by auto
   831 qed
   832 
   833 lemma (in prob_space) indep_varsD:
   834   assumes X: "indep_vars M' X I"
   835   assumes I: "J \<noteq> {}" "finite J" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> A i \<in> sets (M' i)"
   836   shows "prob (\<Inter>i\<in>J. X i -` A i \<inter> space M) = (\<Prod>i\<in>J. prob (X i -` A i \<inter> space M))"
   837 proof (rule indep_setsD)
   838   show "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   839     using X by (auto simp: indep_vars_def)
   840   show "\<forall>i\<in>J. X i -` A i \<inter> space M \<in> sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   841     using I by auto
   842 qed fact+
   843 
   844 lemma prod_algebra_cong:
   845   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
   846   shows "prod_algebra I M = prod_algebra J N"
   847 proof -
   848   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
   849     using sets_eq_imp_space_eq[OF sets] by auto
   850   with sets show ?thesis unfolding `I = J`
   851     by (intro antisym prod_algebra_mono) auto
   852 qed
   853 
   854 lemma space_in_prod_algebra:
   855   "(\<Pi>\<^isub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
   856 proof cases
   857   assume "I = {}" then show ?thesis
   858     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
   859 next
   860   assume "I \<noteq> {}"
   861   then obtain i where "i \<in> I" by auto
   862   then have "(\<Pi>\<^isub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^isub>E i\<in>{i}. space (M i))"
   863     by (auto simp: prod_emb_def Pi_iff)
   864   also have "\<dots> \<in> prod_algebra I M"
   865     using `i \<in> I` by (intro prod_algebraI) auto
   866   finally show ?thesis .
   867 qed
   868 
   869 lemma (in prob_space) indep_vars_iff_distr_eq_PiM:
   870   fixes I :: "'i set" and X :: "'i \<Rightarrow> 'a \<Rightarrow> 'b"
   871   assumes "I \<noteq> {}"
   872   assumes rv: "\<And>i. random_variable (M' i) (X i)"
   873   shows "indep_vars M' X I \<longleftrightarrow>
   874     distr M (\<Pi>\<^isub>M i\<in>I. M' i) (\<lambda>x. \<lambda>i\<in>I. X i x) = (\<Pi>\<^isub>M i\<in>I. distr M (M' i) (X i))"
   875 proof -
   876   let ?P = "\<Pi>\<^isub>M i\<in>I. M' i"
   877   let ?X = "\<lambda>x. \<lambda>i\<in>I. X i x"
   878   let ?D = "distr M ?P ?X"
   879   have X: "random_variable ?P ?X" by (intro measurable_restrict rv)
   880   interpret D: prob_space ?D by (intro prob_space_distr X)
   881 
   882   let ?D' = "\<lambda>i. distr M (M' i) (X i)"
   883   let ?P' = "\<Pi>\<^isub>M i\<in>I. distr M (M' i) (X i)"
   884   interpret D': prob_space "?D' i" for i by (intro prob_space_distr rv)
   885   interpret P: product_prob_space ?D' I ..
   886     
   887   show ?thesis
   888   proof
   889     assume "indep_vars M' X I"
   890     show "?D = ?P'"
   891     proof (rule measure_eqI_generator_eq)
   892       show "Int_stable (prod_algebra I M')"
   893         by (rule Int_stable_prod_algebra)
   894       show "prod_algebra I M' \<subseteq> Pow (space ?P)"
   895         using prod_algebra_sets_into_space by (simp add: space_PiM)
   896       show "sets ?D = sigma_sets (space ?P) (prod_algebra I M')"
   897         by (simp add: sets_PiM space_PiM)
   898       show "sets ?P' = sigma_sets (space ?P) (prod_algebra I M')"
   899         by (simp add: sets_PiM space_PiM cong: prod_algebra_cong)
   900       let ?A = "\<lambda>i. \<Pi>\<^isub>E i\<in>I. space (M' i)"
   901       show "range ?A \<subseteq> prod_algebra I M'" "(\<Union>i. ?A i) = space (Pi\<^isub>M I M')"
   902         by (auto simp: space_PiM intro!: space_in_prod_algebra cong: prod_algebra_cong)
   903       { fix i show "emeasure ?D (\<Pi>\<^isub>E i\<in>I. space (M' i)) \<noteq> \<infinity>" by auto }
   904     next
   905       fix E assume E: "E \<in> prod_algebra I M'"
   906       from prod_algebraE[OF E] guess J Y . note J = this
   907 
   908       from E have "E \<in> sets ?P" by (auto simp: sets_PiM)
   909       then have "emeasure ?D E = emeasure M (?X -` E \<inter> space M)"
   910         by (simp add: emeasure_distr X)
   911       also have "?X -` E \<inter> space M = (\<Inter>i\<in>J. X i -` Y i \<inter> space M)"
   912         using J `I \<noteq> {}` measurable_space[OF rv] by (auto simp: prod_emb_def Pi_iff split: split_if_asm)
   913       also have "emeasure M (\<Inter>i\<in>J. X i -` Y i \<inter> space M) = (\<Prod> i\<in>J. emeasure M (X i -` Y i \<inter> space M))"
   914         using `indep_vars M' X I` J `I \<noteq> {}` using indep_varsD[of M' X I J]
   915         by (auto simp: emeasure_eq_measure setprod_ereal)
   916       also have "\<dots> = (\<Prod> i\<in>J. emeasure (?D' i) (Y i))"
   917         using rv J by (simp add: emeasure_distr)
   918       also have "\<dots> = emeasure ?P' E"
   919         using P.emeasure_PiM_emb[of J Y] J by (simp add: prod_emb_def)
   920       finally show "emeasure ?D E = emeasure ?P' E" .
   921     qed
   922   next
   923     assume "?D = ?P'"
   924     show "indep_vars M' X I" unfolding indep_vars_def
   925     proof (intro conjI indep_setsI ballI rv)
   926       fix i show "sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)} \<subseteq> events"
   927         by (auto intro!: sigma_sets_subset measurable_sets rv)
   928     next
   929       fix J Y' assume J: "J \<noteq> {}" "J \<subseteq> I" "finite J"
   930       assume Y': "\<forall>j\<in>J. Y' j \<in> sigma_sets (space M) {X j -` A \<inter> space M |A. A \<in> sets (M' j)}"
   931       have "\<forall>j\<in>J. \<exists>Y. Y' j = X j -` Y \<inter> space M \<and> Y \<in> sets (M' j)"
   932       proof
   933         fix j assume "j \<in> J"
   934         from Y'[rule_format, OF this] rv[of j]
   935         show "\<exists>Y. Y' j = X j -` Y \<inter> space M \<and> Y \<in> sets (M' j)"
   936           by (subst (asm) sigma_sets_vimage_commute[symmetric, of _ _ "space (M' j)"])
   937              (auto dest: measurable_space simp: sigma_sets_eq)
   938       qed
   939       from bchoice[OF this] obtain Y where
   940         Y: "\<And>j. j \<in> J \<Longrightarrow> Y' j = X j -` Y j \<inter> space M" "\<And>j. j \<in> J \<Longrightarrow> Y j \<in> sets (M' j)" by auto
   941       let ?E = "prod_emb I M' J (Pi\<^isub>E J Y)"
   942       from Y have "(\<Inter>j\<in>J. Y' j) = ?X -` ?E \<inter> space M"
   943         using J `I \<noteq> {}` measurable_space[OF rv] by (auto simp: prod_emb_def Pi_iff split: split_if_asm)
   944       then have "emeasure M (\<Inter>j\<in>J. Y' j) = emeasure M (?X -` ?E \<inter> space M)"
   945         by simp
   946       also have "\<dots> = emeasure ?D ?E"
   947         using Y  J by (intro emeasure_distr[symmetric] X sets_PiM_I) auto
   948       also have "\<dots> = emeasure ?P' ?E"
   949         using `?D = ?P'` by simp
   950       also have "\<dots> = (\<Prod> i\<in>J. emeasure (?D' i) (Y i))"
   951         using P.emeasure_PiM_emb[of J Y] J Y by (simp add: prod_emb_def)
   952       also have "\<dots> = (\<Prod> i\<in>J. emeasure M (Y' i))"
   953         using rv J Y by (simp add: emeasure_distr)
   954       finally have "emeasure M (\<Inter>j\<in>J. Y' j) = (\<Prod> i\<in>J. emeasure M (Y' i))" .
   955       then show "prob (\<Inter>j\<in>J. Y' j) = (\<Prod> i\<in>J. prob (Y' i))"
   956         by (auto simp: emeasure_eq_measure setprod_ereal)
   957     qed
   958   qed
   959 qed
   960 
   961 lemma (in prob_space) indep_varD:
   962   assumes indep: "indep_var Ma A Mb B"
   963   assumes sets: "Xa \<in> sets Ma" "Xb \<in> sets Mb"
   964   shows "prob ((\<lambda>x. (A x, B x)) -` (Xa \<times> Xb) \<inter> space M) =
   965     prob (A -` Xa \<inter> space M) * prob (B -` Xb \<inter> space M)"
   966 proof -
   967   have "prob ((\<lambda>x. (A x, B x)) -` (Xa \<times> Xb) \<inter> space M) =
   968     prob (\<Inter>i\<in>UNIV. (bool_case A B i -` bool_case Xa Xb i \<inter> space M))"
   969     by (auto intro!: arg_cong[where f=prob] simp: UNIV_bool)
   970   also have "\<dots> = (\<Prod>i\<in>UNIV. prob (bool_case A B i -` bool_case Xa Xb i \<inter> space M))"
   971     using indep unfolding indep_var_def
   972     by (rule indep_varsD) (auto split: bool.split intro: sets)
   973   also have "\<dots> = prob (A -` Xa \<inter> space M) * prob (B -` Xb \<inter> space M)"
   974     unfolding UNIV_bool by simp
   975   finally show ?thesis .
   976 qed
   977 
   978 lemma (in prob_space)
   979   assumes "indep_var S X T Y"
   980   shows indep_var_rv1: "random_variable S X"
   981     and indep_var_rv2: "random_variable T Y"
   982 proof -
   983   have "\<forall>i\<in>UNIV. random_variable (bool_case S T i) (bool_case X Y i)"
   984     using assms unfolding indep_var_def indep_vars_def by auto
   985   then show "random_variable S X" "random_variable T Y"
   986     unfolding UNIV_bool by auto
   987 qed
   988 
   989 lemma measurable_bool_case[simp, intro]:
   990   "(\<lambda>(x, y). bool_case x y) \<in> measurable (M \<Otimes>\<^isub>M N) (Pi\<^isub>M UNIV (bool_case M N))"
   991     (is "?f \<in> measurable ?B ?P")
   992 proof (rule measurable_PiM_single)
   993   show "?f \<in> space ?B \<rightarrow> (\<Pi>\<^isub>E i\<in>UNIV. space (bool_case M N i))"
   994     by (auto simp: space_pair_measure extensional_def split: bool.split)
   995   fix i A assume "A \<in> sets (case i of True \<Rightarrow> M | False \<Rightarrow> N)"
   996   moreover then have "{\<omega> \<in> space (M \<Otimes>\<^isub>M N). prod_case bool_case \<omega> i \<in> A}
   997     = (case i of True \<Rightarrow> A \<times> space N | False \<Rightarrow> space M \<times> A)" 
   998     by (auto simp: space_pair_measure split: bool.split dest!: sets_into_space)
   999   ultimately show "{\<omega> \<in> space (M \<Otimes>\<^isub>M N). prod_case bool_case \<omega> i \<in> A} \<in> sets ?B"
  1000     by (auto split: bool.split)
  1001 qed
  1002 
  1003 lemma borel_measurable_indicator':
  1004   "A \<in> sets N \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> (\<lambda>x. indicator A (f x)) \<in> borel_measurable M"
  1005   using measurable_comp[OF _ borel_measurable_indicator, of f M N A] by (auto simp add: comp_def)
  1006 
  1007 lemma (in product_sigma_finite) distr_component:
  1008   "distr (M i) (Pi\<^isub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^isub>M {i} M" (is "?D = ?P")
  1009 proof (intro measure_eqI[symmetric])
  1010   interpret I: finite_product_sigma_finite M "{i}" by default simp
  1011 
  1012   have eq: "\<And>x. x \<in> extensional {i} \<Longrightarrow> (\<lambda>j\<in>{i}. x i) = x"
  1013     by (auto simp: extensional_def restrict_def)
  1014 
  1015   fix A assume A: "A \<in> sets ?P"
  1016   then have "emeasure ?P A = (\<integral>\<^isup>+x. indicator A x \<partial>?P)" 
  1017     by simp
  1018   also have "\<dots> = (\<integral>\<^isup>+x. indicator ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i)) x \<partial>M i)" 
  1019     apply (subst product_positive_integral_singleton[symmetric])
  1020     apply (force intro!: measurable_restrict measurable_sets A)
  1021     apply (auto intro!: positive_integral_cong simp: space_PiM indicator_def simp: eq)
  1022     done
  1023   also have "\<dots> = emeasure (M i) ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i))"
  1024     by (force intro!: measurable_restrict measurable_sets A positive_integral_indicator)
  1025   also have "\<dots> = emeasure ?D A"
  1026     using A by (auto intro!: emeasure_distr[symmetric] measurable_restrict) 
  1027   finally show "emeasure (Pi\<^isub>M {i} M) A = emeasure ?D A" .
  1028 qed simp
  1029 
  1030 lemma pair_measure_eqI:
  1031   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1032   assumes sets: "sets (M1 \<Otimes>\<^isub>M M2) = sets M"
  1033   assumes emeasure: "\<And>A B. A \<in> sets M1 \<Longrightarrow> B \<in> sets M2 \<Longrightarrow> emeasure M1 A * emeasure M2 B = emeasure M (A \<times> B)"
  1034   shows "M1 \<Otimes>\<^isub>M M2 = M"
  1035 proof -
  1036   interpret M1: sigma_finite_measure M1 by fact
  1037   interpret M2: sigma_finite_measure M2 by fact
  1038   interpret pair_sigma_finite M1 M2 by default
  1039   from sigma_finite_up_in_pair_measure_generator guess F :: "nat \<Rightarrow> ('a \<times> 'b) set" .. note F = this
  1040   let ?E = "{a \<times> b |a b. a \<in> sets M1 \<and> b \<in> sets M2}"
  1041   let ?P = "M1 \<Otimes>\<^isub>M M2"
  1042   show ?thesis
  1043   proof (rule measure_eqI_generator_eq[OF Int_stable_pair_measure_generator[of M1 M2]])
  1044     show "?E \<subseteq> Pow (space ?P)"
  1045       using space_closed[of M1] space_closed[of M2] by (auto simp: space_pair_measure)
  1046     show "sets ?P = sigma_sets (space ?P) ?E"
  1047       by (simp add: sets_pair_measure space_pair_measure)
  1048     then show "sets M = sigma_sets (space ?P) ?E"
  1049       using sets[symmetric] by simp
  1050   next
  1051     show "range F \<subseteq> ?E" "(\<Union>i. F i) = space ?P" "\<And>i. emeasure ?P (F i) \<noteq> \<infinity>"
  1052       using F by (auto simp: space_pair_measure)
  1053   next
  1054     fix X assume "X \<in> ?E"
  1055     then obtain A B where X[simp]: "X = A \<times> B" and A: "A \<in> sets M1" and B: "B \<in> sets M2" by auto
  1056     then have "emeasure ?P X = emeasure M1 A * emeasure M2 B"
  1057        by (simp add: M2.emeasure_pair_measure_Times)
  1058     also have "\<dots> = emeasure M (A \<times> B)"
  1059       using A B emeasure by auto
  1060     finally show "emeasure ?P X = emeasure M X"
  1061       by simp
  1062   qed
  1063 qed
  1064 
  1065 lemma pair_measure_eq_distr_PiM:
  1066   fixes M1 :: "'a measure" and M2 :: "'a measure"
  1067   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1068   shows "(M1 \<Otimes>\<^isub>M M2) = distr (Pi\<^isub>M UNIV (bool_case M1 M2)) (M1 \<Otimes>\<^isub>M M2) (\<lambda>x. (x True, x False))"
  1069     (is "?P = ?D")
  1070 proof (rule pair_measure_eqI[OF assms])
  1071   interpret B: product_sigma_finite "bool_case M1 M2"
  1072     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
  1073   let ?B = "Pi\<^isub>M UNIV (bool_case M1 M2)"
  1074 
  1075   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
  1076     by auto
  1077   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
  1078   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (bool_case M1 M2 i) (bool_case A B i))"
  1079     by (simp add: UNIV_bool ac_simps)
  1080   also have "\<dots> = emeasure ?B (Pi\<^isub>E UNIV (bool_case A B))"
  1081     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
  1082   also have "Pi\<^isub>E UNIV (bool_case A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
  1083     using A[THEN sets_into_space] B[THEN sets_into_space]
  1084     by (auto simp: Pi_iff all_bool_eq space_PiM split: bool.split)
  1085   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
  1086     using A B
  1087       measurable_component_singleton[of True UNIV "bool_case M1 M2"]
  1088       measurable_component_singleton[of False UNIV "bool_case M1 M2"]
  1089     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
  1090 qed simp
  1091 
  1092 lemma measurable_Pair:
  1093   assumes rvs: "X \<in> measurable M S" "Y \<in> measurable M T"
  1094   shows "(\<lambda>x. (X x, Y x)) \<in> measurable M (S \<Otimes>\<^isub>M T)"
  1095 proof -
  1096   have [simp]: "fst \<circ> (\<lambda>x. (X x, Y x)) = (\<lambda>x. X x)" "snd \<circ> (\<lambda>x. (X x, Y x)) = (\<lambda>x. Y x)"
  1097     by auto
  1098   show " (\<lambda>x. (X x, Y x)) \<in> measurable M (S \<Otimes>\<^isub>M T)"
  1099     by (auto simp: measurable_pair_iff rvs)
  1100 qed
  1101 
  1102 lemma (in prob_space) indep_var_distribution_eq:
  1103   "indep_var S X T Y \<longleftrightarrow> random_variable S X \<and> random_variable T Y \<and>
  1104     distr M S X \<Otimes>\<^isub>M distr M T Y = distr M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))" (is "_ \<longleftrightarrow> _ \<and> _ \<and> ?S \<Otimes>\<^isub>M ?T = ?J")
  1105 proof safe
  1106   assume "indep_var S X T Y"
  1107   then show rvs: "random_variable S X" "random_variable T Y"
  1108     by (blast dest: indep_var_rv1 indep_var_rv2)+
  1109   then have XY: "random_variable (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
  1110     by (rule measurable_Pair)
  1111 
  1112   interpret X: prob_space ?S by (rule prob_space_distr) fact
  1113   interpret Y: prob_space ?T by (rule prob_space_distr) fact
  1114   interpret XY: pair_prob_space ?S ?T ..
  1115   show "?S \<Otimes>\<^isub>M ?T = ?J"
  1116   proof (rule pair_measure_eqI)
  1117     show "sigma_finite_measure ?S" ..
  1118     show "sigma_finite_measure ?T" ..
  1119 
  1120     fix A B assume A: "A \<in> sets ?S" and B: "B \<in> sets ?T"
  1121     have "emeasure ?J (A \<times> B) = emeasure M ((\<lambda>x. (X x, Y x)) -` (A \<times> B) \<inter> space M)"
  1122       using A B by (intro emeasure_distr[OF XY]) auto
  1123     also have "\<dots> = emeasure M (X -` A \<inter> space M) * emeasure M (Y -` B \<inter> space M)"
  1124       using indep_varD[OF `indep_var S X T Y`, of A B] A B by (simp add: emeasure_eq_measure)
  1125     also have "\<dots> = emeasure ?S A * emeasure ?T B"
  1126       using rvs A B by (simp add: emeasure_distr)
  1127     finally show "emeasure ?S A * emeasure ?T B = emeasure ?J (A \<times> B)" by simp
  1128   qed simp
  1129 next
  1130   assume rvs: "random_variable S X" "random_variable T Y"
  1131   then have XY: "random_variable (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
  1132     by (rule measurable_Pair)
  1133 
  1134   let ?S = "distr M S X" and ?T = "distr M T Y"
  1135   interpret X: prob_space ?S by (rule prob_space_distr) fact
  1136   interpret Y: prob_space ?T by (rule prob_space_distr) fact
  1137   interpret XY: pair_prob_space ?S ?T ..
  1138 
  1139   assume "?S \<Otimes>\<^isub>M ?T = ?J"
  1140 
  1141   { fix S and X
  1142     have "Int_stable {X -` A \<inter> space M |A. A \<in> sets S}"
  1143     proof (safe intro!: Int_stableI)
  1144       fix A B assume "A \<in> sets S" "B \<in> sets S"
  1145       then show "\<exists>C. (X -` A \<inter> space M) \<inter> (X -` B \<inter> space M) = (X -` C \<inter> space M) \<and> C \<in> sets S"
  1146         by (intro exI[of _ "A \<inter> B"]) auto
  1147     qed }
  1148   note Int_stable = this
  1149 
  1150   show "indep_var S X T Y" unfolding indep_var_eq
  1151   proof (intro conjI indep_set_sigma_sets Int_stable rvs)
  1152     show "indep_set {X -` A \<inter> space M |A. A \<in> sets S} {Y -` A \<inter> space M |A. A \<in> sets T}"
  1153     proof (safe intro!: indep_setI)
  1154       { fix A assume "A \<in> sets S" then show "X -` A \<inter> space M \<in> sets M"
  1155         using `X \<in> measurable M S` by (auto intro: measurable_sets) }
  1156       { fix A assume "A \<in> sets T" then show "Y -` A \<inter> space M \<in> sets M"
  1157         using `Y \<in> measurable M T` by (auto intro: measurable_sets) }
  1158     next
  1159       fix A B assume ab: "A \<in> sets S" "B \<in> sets T"
  1160       then have "ereal (prob ((X -` A \<inter> space M) \<inter> (Y -` B \<inter> space M))) = emeasure ?J (A \<times> B)"
  1161         using XY by (auto simp add: emeasure_distr emeasure_eq_measure intro!: arg_cong[where f="prob"])
  1162       also have "\<dots> = emeasure (?S \<Otimes>\<^isub>M ?T) (A \<times> B)"
  1163         unfolding `?S \<Otimes>\<^isub>M ?T = ?J` ..
  1164       also have "\<dots> = emeasure ?S A * emeasure ?T B"
  1165         using ab by (simp add: Y.emeasure_pair_measure_Times)
  1166       finally show "prob ((X -` A \<inter> space M) \<inter> (Y -` B \<inter> space M)) =
  1167         prob (X -` A \<inter> space M) * prob (Y -` B \<inter> space M)"
  1168         using rvs ab by (simp add: emeasure_eq_measure emeasure_distr)
  1169     qed
  1170   qed
  1171 qed
  1172 
  1173 end