src/Pure/Isar/attrib.ML
author wenzelm
Mon Nov 14 19:27:42 2011 +0100 (2011-11-14)
changeset 45491 3c9aff74fb58
parent 45390 e29521ef9059
child 45493 12453fd8dcff
permissions -rw-r--r--
eliminated dead code;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Symbolic representation of attributes -- with name and syntax.
     5 *)
     6 
     7 signature ATTRIB =
     8 sig
     9   type src = Args.src
    10   type binding = binding * src list
    11   val empty_binding: binding
    12   val print_attributes: theory -> unit
    13   val intern: theory -> xstring -> string
    14   val intern_src: theory -> src -> src
    15   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    16   val defined: theory -> string -> bool
    17   val attribute: theory -> src -> attribute
    18   val attribute_i: theory -> src -> attribute
    19   val map_specs: ('a list -> 'att list) ->
    20     (('c * 'a list) * 'b) list -> (('c * 'att list) * 'b) list
    21   val map_facts: ('a list -> 'att list) ->
    22     (('c * 'a list) * ('d * 'a list) list) list ->
    23     (('c * 'att list) * ('d * 'att list) list) list
    24   val map_facts_refs: ('a list -> 'att list) -> ('b -> 'fact) ->
    25     (('c * 'a list) * ('b * 'a list) list) list ->
    26     (('c * 'att list) * ('fact * 'att list) list) list
    27   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    28   val setup: Binding.binding -> attribute context_parser -> string -> theory -> theory
    29   val attribute_setup: bstring * Position.T -> Symbol_Pos.text * Position.T -> string ->
    30     theory -> theory
    31   val add_del: attribute -> attribute -> attribute context_parser
    32   val thm_sel: Facts.interval list parser
    33   val thm: thm context_parser
    34   val thms: thm list context_parser
    35   val multi_thm: thm list context_parser
    36   val print_configs: Proof.context -> unit
    37   val internal: (morphism -> attribute) -> src
    38   val config_bool: Binding.binding ->
    39     (Context.generic -> bool) -> bool Config.T * (theory -> theory)
    40   val config_int: Binding.binding ->
    41     (Context.generic -> int) -> int Config.T * (theory -> theory)
    42   val config_real: Binding.binding ->
    43     (Context.generic -> real) -> real Config.T * (theory -> theory)
    44   val config_string: Binding.binding ->
    45     (Context.generic -> string) -> string Config.T * (theory -> theory)
    46   val setup_config_bool: Binding.binding -> (Context.generic -> bool) -> bool Config.T
    47   val setup_config_int: Binding.binding -> (Context.generic -> int) -> int Config.T
    48   val setup_config_string: Binding.binding -> (Context.generic -> string) -> string Config.T
    49   val setup_config_real: Binding.binding -> (Context.generic -> real) -> real Config.T
    50 end;
    51 
    52 structure Attrib: ATTRIB =
    53 struct
    54 
    55 (* source and bindings *)
    56 
    57 type src = Args.src;
    58 
    59 type binding = binding * src list;
    60 val empty_binding: binding = (Binding.empty, []);
    61 
    62 
    63 
    64 (** named attributes **)
    65 
    66 (* theory data *)
    67 
    68 structure Attributes = Theory_Data
    69 (
    70   type T = ((src -> attribute) * string) Name_Space.table;
    71   val empty : T = Name_Space.empty_table "attribute";
    72   val extend = I;
    73   fun merge data : T = Name_Space.merge_tables data;
    74 );
    75 
    76 fun print_attributes thy =
    77   let
    78     val ctxt = Proof_Context.init_global thy;
    79     val attribs = Attributes.get thy;
    80     fun prt_attr (name, (_, "")) = Pretty.str name
    81       | prt_attr (name, (_, comment)) =
    82           Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    83   in
    84     [Pretty.big_list "attributes:" (map prt_attr (Name_Space.extern_table ctxt attribs))]
    85     |> Pretty.chunks |> Pretty.writeln
    86   end;
    87 
    88 fun add_attribute name att comment thy = thy
    89   |> Attributes.map
    90     (Name_Space.define (Proof_Context.init_global thy) true (Sign.naming_of thy)
    91       (name, (att, comment)) #> snd);
    92 
    93 
    94 (* name space *)
    95 
    96 val intern = Name_Space.intern o #1 o Attributes.get;
    97 val intern_src = Args.map_name o intern;
    98 
    99 fun extern ctxt = Name_Space.extern ctxt (#1 (Attributes.get (Proof_Context.theory_of ctxt)));
   100 
   101 
   102 (* pretty printing *)
   103 
   104 fun pretty_attribs _ [] = []
   105   | pretty_attribs ctxt srcs =
   106       [Pretty.enum "," "[" "]" (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs)];
   107 
   108 
   109 (* get attributes *)
   110 
   111 val defined = Symtab.defined o #2 o Attributes.get;
   112 
   113 fun attribute_i thy =
   114   let
   115     val (space, tab) = Attributes.get thy;
   116     fun attr src =
   117       let val ((name, _), pos) = Args.dest_src src in
   118         (case Symtab.lookup tab name of
   119           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   120         | SOME (att, _) => (Position.report pos (Name_Space.markup space name); att src))
   121       end;
   122   in attr end;
   123 
   124 fun attribute thy = attribute_i thy o intern_src thy;
   125 
   126 
   127 (* attributed declarations *)
   128 
   129 fun map_specs f = map (apfst (apsnd f));
   130 
   131 fun map_facts f = map (apfst (apsnd f) o apsnd (map (apsnd f)));
   132 fun map_facts_refs f g = map_facts f #> map (apsnd (map (apfst g)));
   133 
   134 
   135 (* fact expressions *)
   136 
   137 fun eval_thms ctxt srcs = ctxt
   138   |> Proof_Context.note_thmss ""
   139     (map_facts_refs (map (attribute (Proof_Context.theory_of ctxt))) (Proof_Context.get_fact ctxt)
   140       [((Binding.empty, []), srcs)])
   141   |> fst |> maps snd;
   142 
   143 
   144 (* attribute setup *)
   145 
   146 fun syntax scan = Args.syntax "attribute" scan;
   147 
   148 fun setup name scan =
   149   add_attribute name
   150     (fn src => fn (ctxt, th) => let val (a, ctxt') = syntax scan src ctxt in a (ctxt', th) end);
   151 
   152 fun attribute_setup name (txt, pos) cmt =
   153   Context.theory_map (ML_Context.expression pos
   154     "val (name, scan, comment): binding * attribute context_parser * string"
   155     "Context.map_theory (Attrib.setup name scan comment)"
   156     (ML_Lex.read Position.none ("(" ^ ML_Syntax.make_binding name ^ ", ") @
   157       ML_Lex.read pos txt @
   158       ML_Lex.read Position.none (", " ^ ML_Syntax.print_string cmt ^ ")")));
   159 
   160 
   161 (* add/del syntax *)
   162 
   163 fun add_del add del = Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add);
   164 
   165 
   166 
   167 (** parsing attributed theorems **)
   168 
   169 val thm_sel = Parse.$$$ "(" |-- Parse.list1
   170  (Parse.nat --| Parse.minus -- Parse.nat >> Facts.FromTo ||
   171   Parse.nat --| Parse.minus >> Facts.From ||
   172   Parse.nat >> Facts.Single) --| Parse.$$$ ")";
   173 
   174 local
   175 
   176 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   177 
   178 fun gen_thm pick = Scan.depend (fn context =>
   179   let
   180     val thy = Context.theory_of context;
   181     val get = Context.cases (Global_Theory.get_fact context) Proof_Context.get_fact context;
   182     val get_fact = get o Facts.Fact;
   183     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   184   in
   185     Parse.$$$ "[" |-- Args.attribs (intern thy) --| Parse.$$$ "]" >> (fn srcs =>
   186       let
   187         val atts = map (attribute_i thy) srcs;
   188         val (context', th') =
   189           Library.apply (map Thm.apply_attribute atts) (context, Drule.dummy_thm);
   190       in (context', pick "" [th']) end)
   191     ||
   192     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   193       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   194      Scan.ahead (Parse.position fact_name) :|-- (fn (name, pos) =>
   195       Args.named_fact (get_named pos) -- Scan.option thm_sel
   196         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   197     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   198       let
   199         val ths = Facts.select thmref fact;
   200         val atts = map (attribute_i thy) srcs;
   201         val (context', ths') =
   202           Library.foldl_map (Library.apply (map Thm.apply_attribute atts)) (context, ths);
   203       in (context', pick name ths') end)
   204   end);
   205 
   206 in
   207 
   208 val thm = gen_thm Facts.the_single;
   209 val multi_thm = gen_thm (K I);
   210 val thms = Scan.repeat multi_thm >> flat;
   211 
   212 end;
   213 
   214 
   215 
   216 (** basic attributes **)
   217 
   218 (* internal *)
   219 
   220 fun internal att = Args.src (("Pure.attribute", [Token.mk_attribute att]), Position.none);
   221 
   222 
   223 (* rule composition *)
   224 
   225 val COMP_att =
   226   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   227     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B)));
   228 
   229 val THEN_att =
   230   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   231     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B)));
   232 
   233 val OF_att =
   234   thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A));
   235 
   236 
   237 (* rename_abs *)
   238 
   239 val rename_abs =
   240   Scan.repeat (Args.maybe Args.name)
   241   >> (fn args => Thm.rule_attribute (K (Drule.rename_bvars' args)));
   242 
   243 
   244 (* unfold / fold definitions *)
   245 
   246 fun unfolded_syntax rule =
   247   thms >> (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths));
   248 
   249 val unfolded = unfolded_syntax Local_Defs.unfold;
   250 val folded = unfolded_syntax Local_Defs.fold;
   251 
   252 
   253 (* rule format *)
   254 
   255 val rule_format = Args.mode "no_asm"
   256   >> (fn true => Object_Logic.rule_format_no_asm | false => Object_Logic.rule_format);
   257 
   258 val elim_format = Thm.rule_attribute (K Tactic.make_elim);
   259 
   260 
   261 (* case names *)
   262 
   263 val case_names =
   264   Scan.repeat1 (Args.name --
   265     Scan.optional (Parse.$$$ "[" |-- Scan.repeat1 (Args.maybe Args.name) --| Parse.$$$ "]") []) >>
   266   (fn cs =>
   267     Rule_Cases.cases_hyp_names (map fst cs)
   268       (map (map (the_default Rule_Cases.case_hypsN) o snd) cs));
   269 
   270 
   271 (* misc rules *)
   272 
   273 val no_vars = Thm.rule_attribute (fn context => fn th =>
   274   let
   275     val ctxt = Variable.set_body false (Context.proof_of context);
   276     val ((_, [th']), _) = Variable.import true [th] ctxt;
   277   in th' end);
   278 
   279 val eta_long =
   280   Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion));
   281 
   282 val rotated = Scan.optional Parse.int 1 >> (fn n => Thm.rule_attribute (K (rotate_prems n)));
   283 
   284 
   285 (* theory setup *)
   286 
   287 val _ = Context.>> (Context.map_theory
   288  (setup (Binding.name "attribute") (Scan.lift Args.internal_attribute >> Morphism.form)
   289     "internal attribute" #>
   290   setup (Binding.name "tagged") (Scan.lift (Args.name -- Args.name) >> Thm.tag) "tagged theorem" #>
   291   setup (Binding.name "untagged") (Scan.lift Args.name >> Thm.untag) "untagged theorem" #>
   292   setup (Binding.name "kind") (Scan.lift Args.name >> Thm.kind) "theorem kind" #>
   293   setup (Binding.name "COMP") COMP_att "direct composition with rules (no lifting)" #>
   294   setup (Binding.name "THEN") THEN_att "resolution with rule" #>
   295   setup (Binding.name "OF") OF_att "rule applied to facts" #>
   296   setup (Binding.name "rename_abs") (Scan.lift rename_abs)
   297     "rename bound variables in abstractions" #>
   298   setup (Binding.name "unfolded") unfolded "unfolded definitions" #>
   299   setup (Binding.name "folded") folded "folded definitions" #>
   300   setup (Binding.name "consumes") (Scan.lift (Scan.optional Parse.nat 1) >> Rule_Cases.consumes)
   301     "number of consumed facts" #>
   302   setup (Binding.name "constraints") (Scan.lift Parse.nat >> Rule_Cases.constraints)
   303     "number of equality constraints" #>
   304   setup (Binding.name "case_names") (Scan.lift case_names) "named rule cases" #>
   305   setup (Binding.name "case_conclusion")
   306     (Scan.lift (Args.name -- Scan.repeat Args.name) >> Rule_Cases.case_conclusion)
   307     "named conclusion of rule cases" #>
   308   setup (Binding.name "params")
   309     (Scan.lift (Parse.and_list1 (Scan.repeat Args.name)) >> Rule_Cases.params)
   310     "named rule parameters" #>
   311   setup (Binding.name "standard") (Scan.succeed (Thm.rule_attribute (K Drule.export_without_context)))
   312     "result put into standard form (legacy)" #>
   313   setup (Binding.name "rule_format") rule_format "result put into canonical rule format" #>
   314   setup (Binding.name "elim_format") (Scan.succeed elim_format)
   315     "destruct rule turned into elimination rule format" #>
   316   setup (Binding.name "no_vars") (Scan.succeed no_vars) "frozen schematic vars" #>
   317   setup (Binding.name "eta_long") (Scan.succeed eta_long)
   318     "put theorem into eta long beta normal form" #>
   319   setup (Binding.name "atomize") (Scan.succeed Object_Logic.declare_atomize)
   320     "declaration of atomize rule" #>
   321   setup (Binding.name "rulify") (Scan.succeed Object_Logic.declare_rulify)
   322     "declaration of rulify rule" #>
   323   setup (Binding.name "rotated") (Scan.lift rotated) "rotated theorem premises" #>
   324   setup (Binding.name "defn") (add_del Local_Defs.defn_add Local_Defs.defn_del)
   325     "declaration of definitional transformations" #>
   326   setup (Binding.name "abs_def") (Scan.succeed (Thm.rule_attribute (K Drule.abs_def)))
   327     "abstract over free variables of a definition"));
   328 
   329 
   330 
   331 (** configuration options **)
   332 
   333 (* naming *)
   334 
   335 structure Configs = Theory_Data
   336 (
   337   type T = Config.raw Symtab.table;
   338   val empty = Symtab.empty;
   339   val extend = I;
   340   fun merge data = Symtab.merge (K true) data;
   341 );
   342 
   343 fun print_configs ctxt =
   344   let
   345     val thy = Proof_Context.theory_of ctxt;
   346     fun prt (name, config) =
   347       let val value = Config.get ctxt config in
   348         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   349           Pretty.str (Config.print_value value)]
   350       end;
   351     val configs = Name_Space.extern_table ctxt (#1 (Attributes.get thy), Configs.get thy);
   352   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   353 
   354 
   355 (* concrete syntax *)
   356 
   357 local
   358 
   359 val equals = Parse.$$$ "=";
   360 
   361 fun scan_value (Config.Bool _) =
   362       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   363       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   364       Scan.succeed (Config.Bool true)
   365   | scan_value (Config.Int _) = equals |-- Parse.int >> Config.Int
   366   | scan_value (Config.Real _) = equals |-- Parse.real >> Config.Real
   367   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   368 
   369 fun scan_config thy config =
   370   let val config_type = Config.get_global thy config
   371   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   372 
   373 fun register binding config thy =
   374   let val name = Sign.full_name thy binding in
   375     thy
   376     |> setup binding (Scan.lift (scan_config thy config) >> Morphism.form) "configuration option"
   377     |> Configs.map (Symtab.update (name, config))
   378   end;
   379 
   380 fun declare make coerce binding default =
   381   let
   382     val name = Binding.name_of binding;
   383     val config_value = Config.declare_generic {global = false} name (make o default);
   384     val config = coerce config_value;
   385   in (config, register binding config_value) end;
   386 
   387 in
   388 
   389 val config_bool = declare Config.Bool Config.bool;
   390 val config_int = declare Config.Int Config.int;
   391 val config_real = declare Config.Real Config.real;
   392 val config_string = declare Config.String Config.string;
   393 
   394 fun register_config config = register (Binding.name (Config.name_of config)) config;
   395 
   396 end;
   397 
   398 
   399 (* implicit setup *)
   400 
   401 local
   402 
   403 fun setup_config declare_config binding default =
   404   let
   405     val (config, setup) = declare_config binding default;
   406     val _ = Context.>> (Context.map_theory setup);
   407   in config end;
   408 
   409 in
   410 
   411 val setup_config_bool = setup_config config_bool;
   412 val setup_config_int = setup_config config_int;
   413 val setup_config_string = setup_config config_string;
   414 val setup_config_real = setup_config config_real;
   415 
   416 end;
   417 
   418 
   419 (* theory setup *)
   420 
   421 val _ = Context.>> (Context.map_theory
   422  (register_config Ast.trace_raw #>
   423   register_config Ast.stats_raw #>
   424   register_config Syntax.positions_raw #>
   425   register_config Printer.show_brackets_raw #>
   426   register_config Printer.show_sorts_raw #>
   427   register_config Printer.show_types_raw #>
   428   register_config Printer.show_structs_raw #>
   429   register_config Printer.show_question_marks_raw #>
   430   register_config Syntax.ambiguity_level_raw #>
   431   register_config Syntax.ambiguity_warnings_raw #>
   432   register_config Syntax_Trans.eta_contract_raw #>
   433   register_config Name_Space.names_long_raw #>
   434   register_config Name_Space.names_short_raw #>
   435   register_config Name_Space.names_unique_raw #>
   436   register_config ML_Context.trace_raw #>
   437   register_config Proof_Context.show_abbrevs_raw #>
   438   register_config Goal_Display.goals_limit_raw #>
   439   register_config Goal_Display.show_main_goal_raw #>
   440   register_config Goal_Display.show_consts_raw #>
   441   register_config Display.show_hyps_raw #>
   442   register_config Display.show_tags_raw #>
   443   register_config Unify.trace_bound_raw #>
   444   register_config Unify.search_bound_raw #>
   445   register_config Unify.trace_simp_raw #>
   446   register_config Unify.trace_types_raw #>
   447   register_config Raw_Simplifier.simp_depth_limit_raw #>
   448   register_config Raw_Simplifier.simp_trace_depth_limit_raw #>
   449   register_config Raw_Simplifier.simp_debug_raw #>
   450   register_config Raw_Simplifier.simp_trace_raw));
   451 
   452 end;