src/HOL/Divides.thy
author haftmann
Sun Feb 17 21:29:30 2013 +0100 (2013-02-17)
changeset 51173 3cbb4e95a565
parent 50422 ee729dbd1b7f
child 51299 30b014246e21
permissions -rw-r--r--
Sieve of Eratosthenes
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Transfer
    10 begin
    11 
    12 subsection {* Syntactic division operations *}
    13 
    14 class div = dvd +
    15   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    16     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    17 
    18 
    19 subsection {* Abstract division in commutative semirings. *}
    20 
    21 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    22   assumes mod_div_equality: "a div b * b + a mod b = a"
    23     and div_by_0 [simp]: "a div 0 = 0"
    24     and div_0 [simp]: "0 div a = 0"
    25     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    26     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    27 begin
    28 
    29 text {* @{const div} and @{const mod} *}
    30 
    31 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    32   unfolding mult_commute [of b]
    33   by (rule mod_div_equality)
    34 
    35 lemma mod_div_equality': "a mod b + a div b * b = a"
    36   using mod_div_equality [of a b]
    37   by (simp only: add_ac)
    38 
    39 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    40   by (simp add: mod_div_equality)
    41 
    42 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    43   by (simp add: mod_div_equality2)
    44 
    45 lemma mod_by_0 [simp]: "a mod 0 = a"
    46   using mod_div_equality [of a zero] by simp
    47 
    48 lemma mod_0 [simp]: "0 mod a = 0"
    49   using mod_div_equality [of zero a] div_0 by simp
    50 
    51 lemma div_mult_self2 [simp]:
    52   assumes "b \<noteq> 0"
    53   shows "(a + b * c) div b = c + a div b"
    54   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    55 
    56 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    57 proof (cases "b = 0")
    58   case True then show ?thesis by simp
    59 next
    60   case False
    61   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    62     by (simp add: mod_div_equality)
    63   also from False div_mult_self1 [of b a c] have
    64     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    65       by (simp add: algebra_simps)
    66   finally have "a = a div b * b + (a + c * b) mod b"
    67     by (simp add: add_commute [of a] add_assoc distrib_right)
    68   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    69     by (simp add: mod_div_equality)
    70   then show ?thesis by simp
    71 qed
    72 
    73 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    74   by (simp add: mult_commute [of b])
    75 
    76 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    77   using div_mult_self2 [of b 0 a] by simp
    78 
    79 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    80   using div_mult_self1 [of b 0 a] by simp
    81 
    82 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    83   using mod_mult_self2 [of 0 b a] by simp
    84 
    85 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    86   using mod_mult_self1 [of 0 a b] by simp
    87 
    88 lemma div_by_1 [simp]: "a div 1 = a"
    89   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    90 
    91 lemma mod_by_1 [simp]: "a mod 1 = 0"
    92 proof -
    93   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    94   then have "a + a mod 1 = a + 0" by simp
    95   then show ?thesis by (rule add_left_imp_eq)
    96 qed
    97 
    98 lemma mod_self [simp]: "a mod a = 0"
    99   using mod_mult_self2_is_0 [of 1] by simp
   100 
   101 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   102   using div_mult_self2_is_id [of _ 1] by simp
   103 
   104 lemma div_add_self1 [simp]:
   105   assumes "b \<noteq> 0"
   106   shows "(b + a) div b = a div b + 1"
   107   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   108 
   109 lemma div_add_self2 [simp]:
   110   assumes "b \<noteq> 0"
   111   shows "(a + b) div b = a div b + 1"
   112   using assms div_add_self1 [of b a] by (simp add: add_commute)
   113 
   114 lemma mod_add_self1 [simp]:
   115   "(b + a) mod b = a mod b"
   116   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   117 
   118 lemma mod_add_self2 [simp]:
   119   "(a + b) mod b = a mod b"
   120   using mod_mult_self1 [of a 1 b] by simp
   121 
   122 lemma mod_div_decomp:
   123   fixes a b
   124   obtains q r where "q = a div b" and "r = a mod b"
   125     and "a = q * b + r"
   126 proof -
   127   from mod_div_equality have "a = a div b * b + a mod b" by simp
   128   moreover have "a div b = a div b" ..
   129   moreover have "a mod b = a mod b" ..
   130   note that ultimately show thesis by blast
   131 qed
   132 
   133 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   134 proof
   135   assume "b mod a = 0"
   136   with mod_div_equality [of b a] have "b div a * a = b" by simp
   137   then have "b = a * (b div a)" unfolding mult_commute ..
   138   then have "\<exists>c. b = a * c" ..
   139   then show "a dvd b" unfolding dvd_def .
   140 next
   141   assume "a dvd b"
   142   then have "\<exists>c. b = a * c" unfolding dvd_def .
   143   then obtain c where "b = a * c" ..
   144   then have "b mod a = a * c mod a" by simp
   145   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   146   then show "b mod a = 0" by simp
   147 qed
   148 
   149 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   150 proof (cases "b = 0")
   151   assume "b = 0"
   152   thus ?thesis by simp
   153 next
   154   assume "b \<noteq> 0"
   155   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   156     by (rule div_mult_self1 [symmetric])
   157   also have "\<dots> = a div b"
   158     by (simp only: mod_div_equality')
   159   also have "\<dots> = a div b + 0"
   160     by simp
   161   finally show ?thesis
   162     by (rule add_left_imp_eq)
   163 qed
   164 
   165 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   166 proof -
   167   have "a mod b mod b = (a mod b + a div b * b) mod b"
   168     by (simp only: mod_mult_self1)
   169   also have "\<dots> = a mod b"
   170     by (simp only: mod_div_equality')
   171   finally show ?thesis .
   172 qed
   173 
   174 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   175 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   176 
   177 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   178 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   179 
   180 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   181 by (drule dvd_div_mult_self) (simp add: mult_commute)
   182 
   183 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   184 apply (cases "a = 0")
   185  apply simp
   186 apply (auto simp: dvd_def mult_assoc)
   187 done
   188 
   189 lemma div_dvd_div[simp]:
   190   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   191 apply (cases "a = 0")
   192  apply simp
   193 apply (unfold dvd_def)
   194 apply auto
   195  apply(blast intro:mult_assoc[symmetric])
   196 apply(fastforce simp add: mult_assoc)
   197 done
   198 
   199 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   200   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   201    apply (simp add: mod_div_equality)
   202   apply (simp only: dvd_add dvd_mult)
   203   done
   204 
   205 text {* Addition respects modular equivalence. *}
   206 
   207 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   208 proof -
   209   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   210     by (simp only: mod_div_equality)
   211   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   212     by (simp only: add_ac)
   213   also have "\<dots> = (a mod c + b) mod c"
   214     by (rule mod_mult_self1)
   215   finally show ?thesis .
   216 qed
   217 
   218 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   219 proof -
   220   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   221     by (simp only: mod_div_equality)
   222   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   223     by (simp only: add_ac)
   224   also have "\<dots> = (a + b mod c) mod c"
   225     by (rule mod_mult_self1)
   226   finally show ?thesis .
   227 qed
   228 
   229 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   230 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   231 
   232 lemma mod_add_cong:
   233   assumes "a mod c = a' mod c"
   234   assumes "b mod c = b' mod c"
   235   shows "(a + b) mod c = (a' + b') mod c"
   236 proof -
   237   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   238     unfolding assms ..
   239   thus ?thesis
   240     by (simp only: mod_add_eq [symmetric])
   241 qed
   242 
   243 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   244   \<Longrightarrow> (x + y) div z = x div z + y div z"
   245 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   246 
   247 text {* Multiplication respects modular equivalence. *}
   248 
   249 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   250 proof -
   251   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   252     by (simp only: mod_div_equality)
   253   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   254     by (simp only: algebra_simps)
   255   also have "\<dots> = (a mod c * b) mod c"
   256     by (rule mod_mult_self1)
   257   finally show ?thesis .
   258 qed
   259 
   260 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   261 proof -
   262   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   263     by (simp only: mod_div_equality)
   264   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   265     by (simp only: algebra_simps)
   266   also have "\<dots> = (a * (b mod c)) mod c"
   267     by (rule mod_mult_self1)
   268   finally show ?thesis .
   269 qed
   270 
   271 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   272 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   273 
   274 lemma mod_mult_cong:
   275   assumes "a mod c = a' mod c"
   276   assumes "b mod c = b' mod c"
   277   shows "(a * b) mod c = (a' * b') mod c"
   278 proof -
   279   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   280     unfolding assms ..
   281   thus ?thesis
   282     by (simp only: mod_mult_eq [symmetric])
   283 qed
   284 
   285 text {* Exponentiation respects modular equivalence. *}
   286 
   287 lemma power_mod: "(a mod b)^n mod b = a^n mod b"
   288 apply (induct n, simp_all)
   289 apply (rule mod_mult_right_eq [THEN trans])
   290 apply (simp (no_asm_simp))
   291 apply (rule mod_mult_eq [symmetric])
   292 done
   293 
   294 lemma mod_mod_cancel:
   295   assumes "c dvd b"
   296   shows "a mod b mod c = a mod c"
   297 proof -
   298   from `c dvd b` obtain k where "b = c * k"
   299     by (rule dvdE)
   300   have "a mod b mod c = a mod (c * k) mod c"
   301     by (simp only: `b = c * k`)
   302   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   303     by (simp only: mod_mult_self1)
   304   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   305     by (simp only: add_ac mult_ac)
   306   also have "\<dots> = a mod c"
   307     by (simp only: mod_div_equality)
   308   finally show ?thesis .
   309 qed
   310 
   311 lemma div_mult_div_if_dvd:
   312   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   313   apply (cases "y = 0", simp)
   314   apply (cases "z = 0", simp)
   315   apply (auto elim!: dvdE simp add: algebra_simps)
   316   apply (subst mult_assoc [symmetric])
   317   apply (simp add: no_zero_divisors)
   318   done
   319 
   320 lemma div_mult_swap:
   321   assumes "c dvd b"
   322   shows "a * (b div c) = (a * b) div c"
   323 proof -
   324   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   325     by (simp only: div_mult_div_if_dvd one_dvd)
   326   then show ?thesis by (simp add: mult_commute)
   327 qed
   328    
   329 lemma div_mult_mult2 [simp]:
   330   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   331   by (drule div_mult_mult1) (simp add: mult_commute)
   332 
   333 lemma div_mult_mult1_if [simp]:
   334   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   335   by simp_all
   336 
   337 lemma mod_mult_mult1:
   338   "(c * a) mod (c * b) = c * (a mod b)"
   339 proof (cases "c = 0")
   340   case True then show ?thesis by simp
   341 next
   342   case False
   343   from mod_div_equality
   344   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   345   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   346     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   347   with mod_div_equality show ?thesis by simp 
   348 qed
   349   
   350 lemma mod_mult_mult2:
   351   "(a * c) mod (b * c) = (a mod b) * c"
   352   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   353 
   354 lemma mult_mod_left: "(a mod b) * c = (a * c) mod (b * c)"
   355   by (fact mod_mult_mult2 [symmetric])
   356 
   357 lemma mult_mod_right: "c * (a mod b) = (c * a) mod (c * b)"
   358   by (fact mod_mult_mult1 [symmetric])
   359 
   360 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   361   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   362 
   363 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   364 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   365 
   366 lemma div_power:
   367   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   368 apply (induct n)
   369  apply simp
   370 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   371 done
   372 
   373 lemma dvd_div_eq_mult:
   374   assumes "a \<noteq> 0" and "a dvd b"  
   375   shows "b div a = c \<longleftrightarrow> b = c * a"
   376 proof
   377   assume "b = c * a"
   378   then show "b div a = c" by (simp add: assms)
   379 next
   380   assume "b div a = c"
   381   then have "b div a * a = c * a" by simp
   382   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   383   ultimately show "b = c * a" by simp
   384 qed
   385    
   386 lemma dvd_div_div_eq_mult:
   387   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   388   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   389   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   390 
   391 end
   392 
   393 class ring_div = semiring_div + comm_ring_1
   394 begin
   395 
   396 subclass ring_1_no_zero_divisors ..
   397 
   398 text {* Negation respects modular equivalence. *}
   399 
   400 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   401 proof -
   402   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   403     by (simp only: mod_div_equality)
   404   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   405     by (simp only: minus_add_distrib minus_mult_left add_ac)
   406   also have "\<dots> = (- (a mod b)) mod b"
   407     by (rule mod_mult_self1)
   408   finally show ?thesis .
   409 qed
   410 
   411 lemma mod_minus_cong:
   412   assumes "a mod b = a' mod b"
   413   shows "(- a) mod b = (- a') mod b"
   414 proof -
   415   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   416     unfolding assms ..
   417   thus ?thesis
   418     by (simp only: mod_minus_eq [symmetric])
   419 qed
   420 
   421 text {* Subtraction respects modular equivalence. *}
   422 
   423 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   424   unfolding diff_minus
   425   by (intro mod_add_cong mod_minus_cong) simp_all
   426 
   427 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   428   unfolding diff_minus
   429   by (intro mod_add_cong mod_minus_cong) simp_all
   430 
   431 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   432   unfolding diff_minus
   433   by (intro mod_add_cong mod_minus_cong) simp_all
   434 
   435 lemma mod_diff_cong:
   436   assumes "a mod c = a' mod c"
   437   assumes "b mod c = b' mod c"
   438   shows "(a - b) mod c = (a' - b') mod c"
   439   unfolding diff_minus using assms
   440   by (intro mod_add_cong mod_minus_cong)
   441 
   442 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   443 apply (case_tac "y = 0") apply simp
   444 apply (auto simp add: dvd_def)
   445 apply (subgoal_tac "-(y * k) = y * - k")
   446  apply (erule ssubst)
   447  apply (erule div_mult_self1_is_id)
   448 apply simp
   449 done
   450 
   451 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   452 apply (case_tac "y = 0") apply simp
   453 apply (auto simp add: dvd_def)
   454 apply (subgoal_tac "y * k = -y * -k")
   455  apply (erule ssubst)
   456  apply (rule div_mult_self1_is_id)
   457  apply simp
   458 apply simp
   459 done
   460 
   461 lemma div_minus_minus [simp]: "(-a) div (-b) = a div b"
   462   using div_mult_mult1 [of "- 1" a b]
   463   unfolding neg_equal_0_iff_equal by simp
   464 
   465 lemma mod_minus_minus [simp]: "(-a) mod (-b) = - (a mod b)"
   466   using mod_mult_mult1 [of "- 1" a b] by simp
   467 
   468 lemma div_minus_right: "a div (-b) = (-a) div b"
   469   using div_minus_minus [of "-a" b] by simp
   470 
   471 lemma mod_minus_right: "a mod (-b) = - ((-a) mod b)"
   472   using mod_minus_minus [of "-a" b] by simp
   473 
   474 lemma div_minus1_right [simp]: "a div (-1) = -a"
   475   using div_minus_right [of a 1] by simp
   476 
   477 lemma mod_minus1_right [simp]: "a mod (-1) = 0"
   478   using mod_minus_right [of a 1] by simp
   479 
   480 end
   481 
   482 
   483 subsection {* Division on @{typ nat} *}
   484 
   485 text {*
   486   We define @{const div} and @{const mod} on @{typ nat} by means
   487   of a characteristic relation with two input arguments
   488   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   489   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   490 *}
   491 
   492 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   493   "divmod_nat_rel m n qr \<longleftrightarrow>
   494     m = fst qr * n + snd qr \<and>
   495       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   496 
   497 text {* @{const divmod_nat_rel} is total: *}
   498 
   499 lemma divmod_nat_rel_ex:
   500   obtains q r where "divmod_nat_rel m n (q, r)"
   501 proof (cases "n = 0")
   502   case True  with that show thesis
   503     by (auto simp add: divmod_nat_rel_def)
   504 next
   505   case False
   506   have "\<exists>q r. m = q * n + r \<and> r < n"
   507   proof (induct m)
   508     case 0 with `n \<noteq> 0`
   509     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   510     then show ?case by blast
   511   next
   512     case (Suc m) then obtain q' r'
   513       where m: "m = q' * n + r'" and n: "r' < n" by auto
   514     then show ?case proof (cases "Suc r' < n")
   515       case True
   516       from m n have "Suc m = q' * n + Suc r'" by simp
   517       with True show ?thesis by blast
   518     next
   519       case False then have "n \<le> Suc r'" by auto
   520       moreover from n have "Suc r' \<le> n" by auto
   521       ultimately have "n = Suc r'" by auto
   522       with m have "Suc m = Suc q' * n + 0" by simp
   523       with `n \<noteq> 0` show ?thesis by blast
   524     qed
   525   qed
   526   with that show thesis
   527     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   528 qed
   529 
   530 text {* @{const divmod_nat_rel} is injective: *}
   531 
   532 lemma divmod_nat_rel_unique:
   533   assumes "divmod_nat_rel m n qr"
   534     and "divmod_nat_rel m n qr'"
   535   shows "qr = qr'"
   536 proof (cases "n = 0")
   537   case True with assms show ?thesis
   538     by (cases qr, cases qr')
   539       (simp add: divmod_nat_rel_def)
   540 next
   541   case False
   542   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   543   apply (rule leI)
   544   apply (subst less_iff_Suc_add)
   545   apply (auto simp add: add_mult_distrib)
   546   done
   547   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   548     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   549   moreover from this assms have "snd qr = snd qr'"
   550     by (simp add: divmod_nat_rel_def)
   551   ultimately show ?thesis by (cases qr, cases qr') simp
   552 qed
   553 
   554 text {*
   555   We instantiate divisibility on the natural numbers by
   556   means of @{const divmod_nat_rel}:
   557 *}
   558 
   559 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   560   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   561 
   562 lemma divmod_nat_rel_divmod_nat:
   563   "divmod_nat_rel m n (divmod_nat m n)"
   564 proof -
   565   from divmod_nat_rel_ex
   566     obtain qr where rel: "divmod_nat_rel m n qr" .
   567   then show ?thesis
   568   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   569 qed
   570 
   571 lemma divmod_nat_unique:
   572   assumes "divmod_nat_rel m n qr" 
   573   shows "divmod_nat m n = qr"
   574   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   575 
   576 instantiation nat :: semiring_div
   577 begin
   578 
   579 definition div_nat where
   580   "m div n = fst (divmod_nat m n)"
   581 
   582 lemma fst_divmod_nat [simp]:
   583   "fst (divmod_nat m n) = m div n"
   584   by (simp add: div_nat_def)
   585 
   586 definition mod_nat where
   587   "m mod n = snd (divmod_nat m n)"
   588 
   589 lemma snd_divmod_nat [simp]:
   590   "snd (divmod_nat m n) = m mod n"
   591   by (simp add: mod_nat_def)
   592 
   593 lemma divmod_nat_div_mod:
   594   "divmod_nat m n = (m div n, m mod n)"
   595   by (simp add: prod_eq_iff)
   596 
   597 lemma div_nat_unique:
   598   assumes "divmod_nat_rel m n (q, r)" 
   599   shows "m div n = q"
   600   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   601 
   602 lemma mod_nat_unique:
   603   assumes "divmod_nat_rel m n (q, r)" 
   604   shows "m mod n = r"
   605   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   606 
   607 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   608   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   609 
   610 lemma divmod_nat_zero: "divmod_nat m 0 = (0, m)"
   611   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   612 
   613 lemma divmod_nat_zero_left: "divmod_nat 0 n = (0, 0)"
   614   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   615 
   616 lemma divmod_nat_base: "m < n \<Longrightarrow> divmod_nat m n = (0, m)"
   617   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   618 
   619 lemma divmod_nat_step:
   620   assumes "0 < n" and "n \<le> m"
   621   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   622 proof (rule divmod_nat_unique)
   623   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   624     by (rule divmod_nat_rel)
   625   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   626     unfolding divmod_nat_rel_def using assms by auto
   627 qed
   628 
   629 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   630 
   631 lemma div_less [simp]:
   632   fixes m n :: nat
   633   assumes "m < n"
   634   shows "m div n = 0"
   635   using assms divmod_nat_base by (simp add: prod_eq_iff)
   636 
   637 lemma le_div_geq:
   638   fixes m n :: nat
   639   assumes "0 < n" and "n \<le> m"
   640   shows "m div n = Suc ((m - n) div n)"
   641   using assms divmod_nat_step by (simp add: prod_eq_iff)
   642 
   643 lemma mod_less [simp]:
   644   fixes m n :: nat
   645   assumes "m < n"
   646   shows "m mod n = m"
   647   using assms divmod_nat_base by (simp add: prod_eq_iff)
   648 
   649 lemma le_mod_geq:
   650   fixes m n :: nat
   651   assumes "n \<le> m"
   652   shows "m mod n = (m - n) mod n"
   653   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   654 
   655 instance proof
   656   fix m n :: nat
   657   show "m div n * n + m mod n = m"
   658     using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   659 next
   660   fix m n q :: nat
   661   assume "n \<noteq> 0"
   662   then show "(q + m * n) div n = m + q div n"
   663     by (induct m) (simp_all add: le_div_geq)
   664 next
   665   fix m n q :: nat
   666   assume "m \<noteq> 0"
   667   hence "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   668     unfolding divmod_nat_rel_def
   669     by (auto split: split_if_asm, simp_all add: algebra_simps)
   670   moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   671   ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   672   thus "(m * n) div (m * q) = n div q" by (rule div_nat_unique)
   673 next
   674   fix n :: nat show "n div 0 = 0"
   675     by (simp add: div_nat_def divmod_nat_zero)
   676 next
   677   fix n :: nat show "0 div n = 0"
   678     by (simp add: div_nat_def divmod_nat_zero_left)
   679 qed
   680 
   681 end
   682 
   683 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   684   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   685   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   686 
   687 text {* Simproc for cancelling @{const div} and @{const mod} *}
   688 
   689 ML {*
   690 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   691 (
   692   val div_name = @{const_name div};
   693   val mod_name = @{const_name mod};
   694   val mk_binop = HOLogic.mk_binop;
   695   val mk_plus = HOLogic.mk_binop @{const_name Groups.plus};
   696   val dest_plus = HOLogic.dest_bin @{const_name Groups.plus} HOLogic.natT;
   697   fun mk_sum [] = HOLogic.zero
   698     | mk_sum [t] = t
   699     | mk_sum (t :: ts) = mk_plus (t, mk_sum ts);
   700   fun dest_sum tm =
   701     if HOLogic.is_zero tm then []
   702     else
   703       (case try HOLogic.dest_Suc tm of
   704         SOME t => HOLogic.Suc_zero :: dest_sum t
   705       | NONE =>
   706           (case try dest_plus tm of
   707             SOME (t, u) => dest_sum t @ dest_sum u
   708           | NONE => [tm]));
   709 
   710   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   711 
   712   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   713     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   714 )
   715 *}
   716 
   717 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   718 
   719 
   720 subsubsection {* Quotient *}
   721 
   722 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   723 by (simp add: le_div_geq linorder_not_less)
   724 
   725 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   726 by (simp add: div_geq)
   727 
   728 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   729 by simp
   730 
   731 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   732 by simp
   733 
   734 
   735 subsubsection {* Remainder *}
   736 
   737 lemma mod_less_divisor [simp]:
   738   fixes m n :: nat
   739   assumes "n > 0"
   740   shows "m mod n < (n::nat)"
   741   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   742 
   743 lemma mod_Suc_le_divisor [simp]:
   744   "m mod Suc n \<le> n"
   745   using mod_less_divisor [of "Suc n" m] by arith
   746 
   747 lemma mod_less_eq_dividend [simp]:
   748   fixes m n :: nat
   749   shows "m mod n \<le> m"
   750 proof (rule add_leD2)
   751   from mod_div_equality have "m div n * n + m mod n = m" .
   752   then show "m div n * n + m mod n \<le> m" by auto
   753 qed
   754 
   755 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   756 by (simp add: le_mod_geq linorder_not_less)
   757 
   758 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   759 by (simp add: le_mod_geq)
   760 
   761 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   762 by (induct m) (simp_all add: mod_geq)
   763 
   764 (* a simple rearrangement of mod_div_equality: *)
   765 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   766   using mod_div_equality2 [of n m] by arith
   767 
   768 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   769   apply (drule mod_less_divisor [where m = m])
   770   apply simp
   771   done
   772 
   773 subsubsection {* Quotient and Remainder *}
   774 
   775 lemma divmod_nat_rel_mult1_eq:
   776   "divmod_nat_rel b c (q, r)
   777    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   778 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   779 
   780 lemma div_mult1_eq:
   781   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   782 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   783 
   784 lemma divmod_nat_rel_add1_eq:
   785   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   786    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   787 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   788 
   789 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   790 lemma div_add1_eq:
   791   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   792 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   793 
   794 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   795   apply (cut_tac m = q and n = c in mod_less_divisor)
   796   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   797   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   798   apply (simp add: add_mult_distrib2)
   799   done
   800 
   801 lemma divmod_nat_rel_mult2_eq:
   802   "divmod_nat_rel a b (q, r)
   803    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   804 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   805 
   806 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   807 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   808 
   809 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   810 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   811 
   812 
   813 subsubsection {* Further Facts about Quotient and Remainder *}
   814 
   815 lemma div_1 [simp]: "m div Suc 0 = m"
   816 by (induct m) (simp_all add: div_geq)
   817 
   818 (* Monotonicity of div in first argument *)
   819 lemma div_le_mono [rule_format (no_asm)]:
   820     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   821 apply (case_tac "k=0", simp)
   822 apply (induct "n" rule: nat_less_induct, clarify)
   823 apply (case_tac "n<k")
   824 (* 1  case n<k *)
   825 apply simp
   826 (* 2  case n >= k *)
   827 apply (case_tac "m<k")
   828 (* 2.1  case m<k *)
   829 apply simp
   830 (* 2.2  case m>=k *)
   831 apply (simp add: div_geq diff_le_mono)
   832 done
   833 
   834 (* Antimonotonicity of div in second argument *)
   835 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   836 apply (subgoal_tac "0<n")
   837  prefer 2 apply simp
   838 apply (induct_tac k rule: nat_less_induct)
   839 apply (rename_tac "k")
   840 apply (case_tac "k<n", simp)
   841 apply (subgoal_tac "~ (k<m) ")
   842  prefer 2 apply simp
   843 apply (simp add: div_geq)
   844 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   845  prefer 2
   846  apply (blast intro: div_le_mono diff_le_mono2)
   847 apply (rule le_trans, simp)
   848 apply (simp)
   849 done
   850 
   851 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   852 apply (case_tac "n=0", simp)
   853 apply (subgoal_tac "m div n \<le> m div 1", simp)
   854 apply (rule div_le_mono2)
   855 apply (simp_all (no_asm_simp))
   856 done
   857 
   858 (* Similar for "less than" *)
   859 lemma div_less_dividend [simp]:
   860   "\<lbrakk>(1::nat) < n; 0 < m\<rbrakk> \<Longrightarrow> m div n < m"
   861 apply (induct m rule: nat_less_induct)
   862 apply (rename_tac "m")
   863 apply (case_tac "m<n", simp)
   864 apply (subgoal_tac "0<n")
   865  prefer 2 apply simp
   866 apply (simp add: div_geq)
   867 apply (case_tac "n<m")
   868  apply (subgoal_tac "(m-n) div n < (m-n) ")
   869   apply (rule impI less_trans_Suc)+
   870 apply assumption
   871   apply (simp_all)
   872 done
   873 
   874 text{*A fact for the mutilated chess board*}
   875 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   876 apply (case_tac "n=0", simp)
   877 apply (induct "m" rule: nat_less_induct)
   878 apply (case_tac "Suc (na) <n")
   879 (* case Suc(na) < n *)
   880 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   881 (* case n \<le> Suc(na) *)
   882 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   883 apply (auto simp add: Suc_diff_le le_mod_geq)
   884 done
   885 
   886 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   887 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   888 
   889 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   890 
   891 (*Loses information, namely we also have r<d provided d is nonzero*)
   892 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   893   apply (cut_tac a = m in mod_div_equality)
   894   apply (simp only: add_ac)
   895   apply (blast intro: sym)
   896   done
   897 
   898 lemma split_div:
   899  "P(n div k :: nat) =
   900  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   901  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   902 proof
   903   assume P: ?P
   904   show ?Q
   905   proof (cases)
   906     assume "k = 0"
   907     with P show ?Q by simp
   908   next
   909     assume not0: "k \<noteq> 0"
   910     thus ?Q
   911     proof (simp, intro allI impI)
   912       fix i j
   913       assume n: "n = k*i + j" and j: "j < k"
   914       show "P i"
   915       proof (cases)
   916         assume "i = 0"
   917         with n j P show "P i" by simp
   918       next
   919         assume "i \<noteq> 0"
   920         with not0 n j P show "P i" by(simp add:add_ac)
   921       qed
   922     qed
   923   qed
   924 next
   925   assume Q: ?Q
   926   show ?P
   927   proof (cases)
   928     assume "k = 0"
   929     with Q show ?P by simp
   930   next
   931     assume not0: "k \<noteq> 0"
   932     with Q have R: ?R by simp
   933     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   934     show ?P by simp
   935   qed
   936 qed
   937 
   938 lemma split_div_lemma:
   939   assumes "0 < n"
   940   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   941 proof
   942   assume ?rhs
   943   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   944   then have A: "n * q \<le> m" by simp
   945   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   946   then have "m < m + (n - (m mod n))" by simp
   947   then have "m < n + (m - (m mod n))" by simp
   948   with nq have "m < n + n * q" by simp
   949   then have B: "m < n * Suc q" by simp
   950   from A B show ?lhs ..
   951 next
   952   assume P: ?lhs
   953   then have "divmod_nat_rel m n (q, m - n * q)"
   954     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   955   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   956   have "(q, m - n * q) = (m div n, m mod n)" by auto
   957   then show ?rhs by simp
   958 qed
   959 
   960 theorem split_div':
   961   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   962    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   963   apply (case_tac "0 < n")
   964   apply (simp only: add: split_div_lemma)
   965   apply simp_all
   966   done
   967 
   968 lemma split_mod:
   969  "P(n mod k :: nat) =
   970  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   971  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   972 proof
   973   assume P: ?P
   974   show ?Q
   975   proof (cases)
   976     assume "k = 0"
   977     with P show ?Q by simp
   978   next
   979     assume not0: "k \<noteq> 0"
   980     thus ?Q
   981     proof (simp, intro allI impI)
   982       fix i j
   983       assume "n = k*i + j" "j < k"
   984       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   985     qed
   986   qed
   987 next
   988   assume Q: ?Q
   989   show ?P
   990   proof (cases)
   991     assume "k = 0"
   992     with Q show ?P by simp
   993   next
   994     assume not0: "k \<noteq> 0"
   995     with Q have R: ?R by simp
   996     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   997     show ?P by simp
   998   qed
   999 qed
  1000 
  1001 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
  1002   using mod_div_equality [of m n] by arith
  1003 
  1004 lemma div_mod_equality': "(m::nat) div n * n = m - m mod n"
  1005   using mod_div_equality [of m n] by arith
  1006 (* FIXME: very similar to mult_div_cancel *)
  1007 
  1008 
  1009 subsubsection {* An ``induction'' law for modulus arithmetic. *}
  1010 
  1011 lemma mod_induct_0:
  1012   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1013   and base: "P i" and i: "i<p"
  1014   shows "P 0"
  1015 proof (rule ccontr)
  1016   assume contra: "\<not>(P 0)"
  1017   from i have p: "0<p" by simp
  1018   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1019   proof
  1020     fix k
  1021     show "?A k"
  1022     proof (induct k)
  1023       show "?A 0" by simp  -- "by contradiction"
  1024     next
  1025       fix n
  1026       assume ih: "?A n"
  1027       show "?A (Suc n)"
  1028       proof (clarsimp)
  1029         assume y: "P (p - Suc n)"
  1030         have n: "Suc n < p"
  1031         proof (rule ccontr)
  1032           assume "\<not>(Suc n < p)"
  1033           hence "p - Suc n = 0"
  1034             by simp
  1035           with y contra show "False"
  1036             by simp
  1037         qed
  1038         hence n2: "Suc (p - Suc n) = p-n" by arith
  1039         from p have "p - Suc n < p" by arith
  1040         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1041           by blast
  1042         show "False"
  1043         proof (cases "n=0")
  1044           case True
  1045           with z n2 contra show ?thesis by simp
  1046         next
  1047           case False
  1048           with p have "p-n < p" by arith
  1049           with z n2 False ih show ?thesis by simp
  1050         qed
  1051       qed
  1052     qed
  1053   qed
  1054   moreover
  1055   from i obtain k where "0<k \<and> i+k=p"
  1056     by (blast dest: less_imp_add_positive)
  1057   hence "0<k \<and> i=p-k" by auto
  1058   moreover
  1059   note base
  1060   ultimately
  1061   show "False" by blast
  1062 qed
  1063 
  1064 lemma mod_induct:
  1065   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1066   and base: "P i" and i: "i<p" and j: "j<p"
  1067   shows "P j"
  1068 proof -
  1069   have "\<forall>j<p. P j"
  1070   proof
  1071     fix j
  1072     show "j<p \<longrightarrow> P j" (is "?A j")
  1073     proof (induct j)
  1074       from step base i show "?A 0"
  1075         by (auto elim: mod_induct_0)
  1076     next
  1077       fix k
  1078       assume ih: "?A k"
  1079       show "?A (Suc k)"
  1080       proof
  1081         assume suc: "Suc k < p"
  1082         hence k: "k<p" by simp
  1083         with ih have "P k" ..
  1084         with step k have "P (Suc k mod p)"
  1085           by blast
  1086         moreover
  1087         from suc have "Suc k mod p = Suc k"
  1088           by simp
  1089         ultimately
  1090         show "P (Suc k)" by simp
  1091       qed
  1092     qed
  1093   qed
  1094   with j show ?thesis by blast
  1095 qed
  1096 
  1097 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1098   by (simp add: numeral_2_eq_2 le_div_geq)
  1099 
  1100 lemma mod2_Suc_Suc [simp]: "Suc (Suc m) mod 2 = m mod 2"
  1101   by (simp add: numeral_2_eq_2 le_mod_geq)
  1102 
  1103 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1104 by (simp add: mult_2 [symmetric])
  1105 
  1106 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1107 proof -
  1108   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1109   moreover have "m mod 2 < 2" by simp
  1110   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1111   then show ?thesis by auto
  1112 qed
  1113 
  1114 text{*These lemmas collapse some needless occurrences of Suc:
  1115     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1116     We already have some rules to simplify operands smaller than 3.*}
  1117 
  1118 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1119 by (simp add: Suc3_eq_add_3)
  1120 
  1121 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1122 by (simp add: Suc3_eq_add_3)
  1123 
  1124 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1125 by (simp add: Suc3_eq_add_3)
  1126 
  1127 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1128 by (simp add: Suc3_eq_add_3)
  1129 
  1130 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1131 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1132 
  1133 
  1134 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1135 apply (induct "m")
  1136 apply (simp_all add: mod_Suc)
  1137 done
  1138 
  1139 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1140 
  1141 lemma Suc_div_le_mono [simp]: "n div k \<le> (Suc n) div k"
  1142 by (simp add: div_le_mono)
  1143 
  1144 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1145 by (cases n) simp_all
  1146 
  1147 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1148 proof -
  1149   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1150   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1151 qed
  1152 
  1153   (* Potential use of algebra : Equality modulo n*)
  1154 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1155 by (simp add: mult_ac add_ac)
  1156 
  1157 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1158 proof -
  1159   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1160   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1161   finally show ?thesis .
  1162 qed
  1163 
  1164 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1165 apply (subst mod_Suc [of m]) 
  1166 apply (subst mod_Suc [of "m mod n"], simp) 
  1167 done
  1168 
  1169 lemma mod_2_not_eq_zero_eq_one_nat:
  1170   fixes n :: nat
  1171   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1172   by simp
  1173 
  1174 
  1175 subsection {* Division on @{typ int} *}
  1176 
  1177 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1178     --{*definition of quotient and remainder*}
  1179   "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1180     (if 0 < b then 0 \<le> r \<and> r < b else if b < 0 then b < r \<and> r \<le> 0 else q = 0))"
  1181 
  1182 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1183     --{*for the division algorithm*}
  1184     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1185                          else (2 * q, r))"
  1186 
  1187 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1188 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1189   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1190      else adjust b (posDivAlg a (2 * b)))"
  1191 by auto
  1192 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1193   (auto simp add: mult_2)
  1194 
  1195 text{*algorithm for the case @{text "a<0, b>0"}*}
  1196 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1197   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1198      else adjust b (negDivAlg a (2 * b)))"
  1199 by auto
  1200 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1201   (auto simp add: mult_2)
  1202 
  1203 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1204 
  1205 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1206     --{*The full division algorithm considers all possible signs for a, b
  1207        including the special case @{text "a=0, b<0"} because 
  1208        @{term negDivAlg} requires @{term "a<0"}.*}
  1209   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1210                   else if a = 0 then (0, 0)
  1211                        else apsnd uminus (negDivAlg (-a) (-b))
  1212                else 
  1213                   if 0 < b then negDivAlg a b
  1214                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1215 
  1216 instantiation int :: Divides.div
  1217 begin
  1218 
  1219 definition div_int where
  1220   "a div b = fst (divmod_int a b)"
  1221 
  1222 lemma fst_divmod_int [simp]:
  1223   "fst (divmod_int a b) = a div b"
  1224   by (simp add: div_int_def)
  1225 
  1226 definition mod_int where
  1227   "a mod b = snd (divmod_int a b)"
  1228 
  1229 lemma snd_divmod_int [simp]:
  1230   "snd (divmod_int a b) = a mod b"
  1231   by (simp add: mod_int_def)
  1232 
  1233 instance ..
  1234 
  1235 end
  1236 
  1237 lemma divmod_int_mod_div:
  1238   "divmod_int p q = (p div q, p mod q)"
  1239   by (simp add: prod_eq_iff)
  1240 
  1241 text{*
  1242 Here is the division algorithm in ML:
  1243 
  1244 \begin{verbatim}
  1245     fun posDivAlg (a,b) =
  1246       if a<b then (0,a)
  1247       else let val (q,r) = posDivAlg(a, 2*b)
  1248                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1249            end
  1250 
  1251     fun negDivAlg (a,b) =
  1252       if 0\<le>a+b then (~1,a+b)
  1253       else let val (q,r) = negDivAlg(a, 2*b)
  1254                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1255            end;
  1256 
  1257     fun negateSnd (q,r:int) = (q,~r);
  1258 
  1259     fun divmod (a,b) = if 0\<le>a then 
  1260                           if b>0 then posDivAlg (a,b) 
  1261                            else if a=0 then (0,0)
  1262                                 else negateSnd (negDivAlg (~a,~b))
  1263                        else 
  1264                           if 0<b then negDivAlg (a,b)
  1265                           else        negateSnd (posDivAlg (~a,~b));
  1266 \end{verbatim}
  1267 *}
  1268 
  1269 
  1270 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1271 
  1272 lemma unique_quotient_lemma:
  1273      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1274       ==> q' \<le> (q::int)"
  1275 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1276  prefer 2 apply (simp add: right_diff_distrib)
  1277 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1278 apply (erule_tac [2] order_le_less_trans)
  1279  prefer 2 apply (simp add: right_diff_distrib distrib_left)
  1280 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1281  prefer 2 apply (simp add: right_diff_distrib distrib_left)
  1282 apply (simp add: mult_less_cancel_left)
  1283 done
  1284 
  1285 lemma unique_quotient_lemma_neg:
  1286      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1287       ==> q \<le> (q'::int)"
  1288 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1289     auto)
  1290 
  1291 lemma unique_quotient:
  1292      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1293       ==> q = q'"
  1294 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1295 apply (blast intro: order_antisym
  1296              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1297              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1298 done
  1299 
  1300 
  1301 lemma unique_remainder:
  1302      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1303       ==> r = r'"
  1304 apply (subgoal_tac "q = q'")
  1305  apply (simp add: divmod_int_rel_def)
  1306 apply (blast intro: unique_quotient)
  1307 done
  1308 
  1309 
  1310 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1311 
  1312 text{*And positive divisors*}
  1313 
  1314 lemma adjust_eq [simp]:
  1315      "adjust b (q, r) = 
  1316       (let diff = r - b in  
  1317         if 0 \<le> diff then (2 * q + 1, diff)   
  1318                      else (2*q, r))"
  1319   by (simp add: Let_def adjust_def)
  1320 
  1321 declare posDivAlg.simps [simp del]
  1322 
  1323 text{*use with a simproc to avoid repeatedly proving the premise*}
  1324 lemma posDivAlg_eqn:
  1325      "0 < b ==>  
  1326       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1327 by (rule posDivAlg.simps [THEN trans], simp)
  1328 
  1329 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1330 theorem posDivAlg_correct:
  1331   assumes "0 \<le> a" and "0 < b"
  1332   shows "divmod_int_rel a b (posDivAlg a b)"
  1333   using assms
  1334   apply (induct a b rule: posDivAlg.induct)
  1335   apply auto
  1336   apply (simp add: divmod_int_rel_def)
  1337   apply (subst posDivAlg_eqn, simp add: distrib_left)
  1338   apply (case_tac "a < b")
  1339   apply simp_all
  1340   apply (erule splitE)
  1341   apply (auto simp add: distrib_left Let_def mult_ac mult_2_right)
  1342   done
  1343 
  1344 
  1345 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1346 
  1347 text{*And positive divisors*}
  1348 
  1349 declare negDivAlg.simps [simp del]
  1350 
  1351 text{*use with a simproc to avoid repeatedly proving the premise*}
  1352 lemma negDivAlg_eqn:
  1353      "0 < b ==>  
  1354       negDivAlg a b =       
  1355        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1356 by (rule negDivAlg.simps [THEN trans], simp)
  1357 
  1358 (*Correctness of negDivAlg: it computes quotients correctly
  1359   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1360 lemma negDivAlg_correct:
  1361   assumes "a < 0" and "b > 0"
  1362   shows "divmod_int_rel a b (negDivAlg a b)"
  1363   using assms
  1364   apply (induct a b rule: negDivAlg.induct)
  1365   apply (auto simp add: linorder_not_le)
  1366   apply (simp add: divmod_int_rel_def)
  1367   apply (subst negDivAlg_eqn, assumption)
  1368   apply (case_tac "a + b < (0\<Colon>int)")
  1369   apply simp_all
  1370   apply (erule splitE)
  1371   apply (auto simp add: distrib_left Let_def mult_ac mult_2_right)
  1372   done
  1373 
  1374 
  1375 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1376 
  1377 (*the case a=0*)
  1378 lemma divmod_int_rel_0: "divmod_int_rel 0 b (0, 0)"
  1379 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1380 
  1381 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1382 by (subst posDivAlg.simps, auto)
  1383 
  1384 lemma posDivAlg_0_right [simp]: "posDivAlg a 0 = (0, a)"
  1385 by (subst posDivAlg.simps, auto)
  1386 
  1387 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1388 by (subst negDivAlg.simps, auto)
  1389 
  1390 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1391 by (auto simp add: divmod_int_rel_def)
  1392 
  1393 lemma divmod_int_correct: "divmod_int_rel a b (divmod_int a b)"
  1394 apply (cases "b = 0", simp add: divmod_int_def divmod_int_rel_def)
  1395 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1396                     posDivAlg_correct negDivAlg_correct)
  1397 
  1398 lemma divmod_int_unique:
  1399   assumes "divmod_int_rel a b qr" 
  1400   shows "divmod_int a b = qr"
  1401   using assms divmod_int_correct [of a b]
  1402   using unique_quotient [of a b] unique_remainder [of a b]
  1403   by (metis pair_collapse)
  1404 
  1405 lemma divmod_int_rel_div_mod: "divmod_int_rel a b (a div b, a mod b)"
  1406   using divmod_int_correct by (simp add: divmod_int_mod_div)
  1407 
  1408 lemma div_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a div b = q"
  1409   by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1410 
  1411 lemma mod_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a mod b = r"
  1412   by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1413 
  1414 instance int :: ring_div
  1415 proof
  1416   fix a b :: int
  1417   show "a div b * b + a mod b = a"
  1418     using divmod_int_rel_div_mod [of a b]
  1419     unfolding divmod_int_rel_def by (simp add: mult_commute)
  1420 next
  1421   fix a b c :: int
  1422   assume "b \<noteq> 0"
  1423   hence "divmod_int_rel (a + c * b) b (c + a div b, a mod b)"
  1424     using divmod_int_rel_div_mod [of a b]
  1425     unfolding divmod_int_rel_def by (auto simp: algebra_simps)
  1426   thus "(a + c * b) div b = c + a div b"
  1427     by (rule div_int_unique)
  1428 next
  1429   fix a b c :: int
  1430   assume "c \<noteq> 0"
  1431   hence "\<And>q r. divmod_int_rel a b (q, r)
  1432     \<Longrightarrow> divmod_int_rel (c * a) (c * b) (q, c * r)"
  1433     unfolding divmod_int_rel_def
  1434     by - (rule linorder_cases [of 0 b], auto simp: algebra_simps
  1435       mult_less_0_iff zero_less_mult_iff mult_strict_right_mono
  1436       mult_strict_right_mono_neg zero_le_mult_iff mult_le_0_iff)
  1437   hence "divmod_int_rel (c * a) (c * b) (a div b, c * (a mod b))"
  1438     using divmod_int_rel_div_mod [of a b] .
  1439   thus "(c * a) div (c * b) = a div b"
  1440     by (rule div_int_unique)
  1441 next
  1442   fix a :: int show "a div 0 = 0"
  1443     by (rule div_int_unique, simp add: divmod_int_rel_def)
  1444 next
  1445   fix a :: int show "0 div a = 0"
  1446     by (rule div_int_unique, auto simp add: divmod_int_rel_def)
  1447 qed
  1448 
  1449 text{*Basic laws about division and remainder*}
  1450 
  1451 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1452   by (fact mod_div_equality2 [symmetric])
  1453 
  1454 text {* Tool setup *}
  1455 
  1456 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1457 lemmas add_0s = add_0_left add_0_right
  1458 
  1459 ML {*
  1460 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1461 (
  1462   val div_name = @{const_name div};
  1463   val mod_name = @{const_name mod};
  1464   val mk_binop = HOLogic.mk_binop;
  1465   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1466   val dest_sum = Arith_Data.dest_sum;
  1467 
  1468   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
  1469 
  1470   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1471     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1472 )
  1473 *}
  1474 
  1475 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1476 
  1477 lemma pos_mod_conj: "(0::int) < b \<Longrightarrow> 0 \<le> a mod b \<and> a mod b < b"
  1478   using divmod_int_correct [of a b]
  1479   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1480 
  1481 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1482    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1483 
  1484 lemma neg_mod_conj: "b < (0::int) \<Longrightarrow> a mod b \<le> 0 \<and> b < a mod b"
  1485   using divmod_int_correct [of a b]
  1486   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1487 
  1488 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1489    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1490 
  1491 
  1492 subsubsection {* General Properties of div and mod *}
  1493 
  1494 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1495 apply (rule div_int_unique)
  1496 apply (auto simp add: divmod_int_rel_def)
  1497 done
  1498 
  1499 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1500 apply (rule div_int_unique)
  1501 apply (auto simp add: divmod_int_rel_def)
  1502 done
  1503 
  1504 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1505 apply (rule div_int_unique)
  1506 apply (auto simp add: divmod_int_rel_def)
  1507 done
  1508 
  1509 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1510 
  1511 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1512 apply (rule_tac q = 0 in mod_int_unique)
  1513 apply (auto simp add: divmod_int_rel_def)
  1514 done
  1515 
  1516 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1517 apply (rule_tac q = 0 in mod_int_unique)
  1518 apply (auto simp add: divmod_int_rel_def)
  1519 done
  1520 
  1521 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1522 apply (rule_tac q = "-1" in mod_int_unique)
  1523 apply (auto simp add: divmod_int_rel_def)
  1524 done
  1525 
  1526 text{*There is no @{text mod_neg_pos_trivial}.*}
  1527 
  1528 
  1529 subsubsection {* Laws for div and mod with Unary Minus *}
  1530 
  1531 lemma zminus1_lemma:
  1532      "divmod_int_rel a b (q, r) ==> b \<noteq> 0
  1533       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1534                           if r=0 then 0 else b-r)"
  1535 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1536 
  1537 
  1538 lemma zdiv_zminus1_eq_if:
  1539      "b \<noteq> (0::int)  
  1540       ==> (-a) div b =  
  1541           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1542 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN div_int_unique])
  1543 
  1544 lemma zmod_zminus1_eq_if:
  1545      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1546 apply (case_tac "b = 0", simp)
  1547 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN mod_int_unique])
  1548 done
  1549 
  1550 lemma zmod_zminus1_not_zero:
  1551   fixes k l :: int
  1552   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1553   unfolding zmod_zminus1_eq_if by auto
  1554 
  1555 lemma zdiv_zminus2_eq_if:
  1556      "b \<noteq> (0::int)  
  1557       ==> a div (-b) =  
  1558           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1559 by (simp add: zdiv_zminus1_eq_if div_minus_right)
  1560 
  1561 lemma zmod_zminus2_eq_if:
  1562      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1563 by (simp add: zmod_zminus1_eq_if mod_minus_right)
  1564 
  1565 lemma zmod_zminus2_not_zero:
  1566   fixes k l :: int
  1567   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1568   unfolding zmod_zminus2_eq_if by auto 
  1569 
  1570 
  1571 subsubsection {* Computation of Division and Remainder *}
  1572 
  1573 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1574 by (simp add: div_int_def divmod_int_def)
  1575 
  1576 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1577 by (simp add: mod_int_def divmod_int_def)
  1578 
  1579 text{*a positive, b positive *}
  1580 
  1581 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1582 by (simp add: div_int_def divmod_int_def)
  1583 
  1584 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1585 by (simp add: mod_int_def divmod_int_def)
  1586 
  1587 text{*a negative, b positive *}
  1588 
  1589 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1590 by (simp add: div_int_def divmod_int_def)
  1591 
  1592 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1593 by (simp add: mod_int_def divmod_int_def)
  1594 
  1595 text{*a positive, b negative *}
  1596 
  1597 lemma div_pos_neg:
  1598      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1599 by (simp add: div_int_def divmod_int_def)
  1600 
  1601 lemma mod_pos_neg:
  1602      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1603 by (simp add: mod_int_def divmod_int_def)
  1604 
  1605 text{*a negative, b negative *}
  1606 
  1607 lemma div_neg_neg:
  1608      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1609 by (simp add: div_int_def divmod_int_def)
  1610 
  1611 lemma mod_neg_neg:
  1612      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1613 by (simp add: mod_int_def divmod_int_def)
  1614 
  1615 text {*Simplify expresions in which div and mod combine numerical constants*}
  1616 
  1617 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1618   by (rule div_int_unique [of a b q r]) (simp add: divmod_int_rel_def)
  1619 
  1620 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1621   by (rule div_int_unique [of a b q r],
  1622     simp add: divmod_int_rel_def)
  1623 
  1624 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1625   by (rule mod_int_unique [of a b q r],
  1626     simp add: divmod_int_rel_def)
  1627 
  1628 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1629   by (rule mod_int_unique [of a b q r],
  1630     simp add: divmod_int_rel_def)
  1631 
  1632 (* simprocs adapted from HOL/ex/Binary.thy *)
  1633 ML {*
  1634 local
  1635   val mk_number = HOLogic.mk_number HOLogic.intT
  1636   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1637   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1638   val zero = @{term "0 :: int"}
  1639   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1640   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1641   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1642     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1643   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1644     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1645   fun binary_proc proc ss ct =
  1646     (case Thm.term_of ct of
  1647       _ $ t $ u =>
  1648       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1649         SOME args => proc (Simplifier.the_context ss) args
  1650       | NONE => NONE)
  1651     | _ => NONE);
  1652 in
  1653   fun divmod_proc posrule negrule =
  1654     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1655       if b = 0 then NONE else let
  1656         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1657         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1658         val (goal2, goal3, rule) = if b > 0
  1659           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1660           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1661       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1662 end
  1663 *}
  1664 
  1665 simproc_setup binary_int_div
  1666   ("numeral m div numeral n :: int" |
  1667    "numeral m div neg_numeral n :: int" |
  1668    "neg_numeral m div numeral n :: int" |
  1669    "neg_numeral m div neg_numeral n :: int") =
  1670   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1671 
  1672 simproc_setup binary_int_mod
  1673   ("numeral m mod numeral n :: int" |
  1674    "numeral m mod neg_numeral n :: int" |
  1675    "neg_numeral m mod numeral n :: int" |
  1676    "neg_numeral m mod neg_numeral n :: int") =
  1677   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1678 
  1679 lemmas posDivAlg_eqn_numeral [simp] =
  1680     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1681 
  1682 lemmas negDivAlg_eqn_numeral [simp] =
  1683     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1684 
  1685 
  1686 text{*Special-case simplification *}
  1687 
  1688 (** The last remaining special cases for constant arithmetic:
  1689     1 div z and 1 mod z **)
  1690 
  1691 lemmas div_pos_pos_1_numeral [simp] =
  1692   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1693 
  1694 lemmas div_pos_neg_1_numeral [simp] =
  1695   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1696   OF neg_numeral_less_zero] for w
  1697 
  1698 lemmas mod_pos_pos_1_numeral [simp] =
  1699   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1700 
  1701 lemmas mod_pos_neg_1_numeral [simp] =
  1702   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1703   OF neg_numeral_less_zero] for w
  1704 
  1705 lemmas posDivAlg_eqn_1_numeral [simp] =
  1706     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1707 
  1708 lemmas negDivAlg_eqn_1_numeral [simp] =
  1709     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1710 
  1711 
  1712 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1713 
  1714 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1715 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1716 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1717 apply (rule unique_quotient_lemma)
  1718 apply (erule subst)
  1719 apply (erule subst, simp_all)
  1720 done
  1721 
  1722 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1723 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1724 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1725 apply (rule unique_quotient_lemma_neg)
  1726 apply (erule subst)
  1727 apply (erule subst, simp_all)
  1728 done
  1729 
  1730 
  1731 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1732 
  1733 lemma q_pos_lemma:
  1734      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1735 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1736  apply (simp add: zero_less_mult_iff)
  1737 apply (simp add: distrib_left)
  1738 done
  1739 
  1740 lemma zdiv_mono2_lemma:
  1741      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1742          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1743       ==> q \<le> (q'::int)"
  1744 apply (frule q_pos_lemma, assumption+) 
  1745 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1746  apply (simp add: mult_less_cancel_left)
  1747 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1748  prefer 2 apply simp
  1749 apply (simp (no_asm_simp) add: distrib_left)
  1750 apply (subst add_commute, rule add_less_le_mono, arith)
  1751 apply (rule mult_right_mono, auto)
  1752 done
  1753 
  1754 lemma zdiv_mono2:
  1755      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1756 apply (subgoal_tac "b \<noteq> 0")
  1757  prefer 2 apply arith
  1758 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1759 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1760 apply (rule zdiv_mono2_lemma)
  1761 apply (erule subst)
  1762 apply (erule subst, simp_all)
  1763 done
  1764 
  1765 lemma q_neg_lemma:
  1766      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1767 apply (subgoal_tac "b'*q' < 0")
  1768  apply (simp add: mult_less_0_iff, arith)
  1769 done
  1770 
  1771 lemma zdiv_mono2_neg_lemma:
  1772      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1773          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1774       ==> q' \<le> (q::int)"
  1775 apply (frule q_neg_lemma, assumption+) 
  1776 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1777  apply (simp add: mult_less_cancel_left)
  1778 apply (simp add: distrib_left)
  1779 apply (subgoal_tac "b*q' \<le> b'*q'")
  1780  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1781 done
  1782 
  1783 lemma zdiv_mono2_neg:
  1784      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1785 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1786 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1787 apply (rule zdiv_mono2_neg_lemma)
  1788 apply (erule subst)
  1789 apply (erule subst, simp_all)
  1790 done
  1791 
  1792 
  1793 subsubsection {* More Algebraic Laws for div and mod *}
  1794 
  1795 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1796 
  1797 lemma zmult1_lemma:
  1798      "[| divmod_int_rel b c (q, r) |]  
  1799       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1800 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff distrib_left mult_ac)
  1801 
  1802 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1803 apply (case_tac "c = 0", simp)
  1804 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN div_int_unique])
  1805 done
  1806 
  1807 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1808 
  1809 lemma zadd1_lemma:
  1810      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1811       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1812 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff distrib_left)
  1813 
  1814 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1815 lemma zdiv_zadd1_eq:
  1816      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1817 apply (case_tac "c = 0", simp)
  1818 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] div_int_unique)
  1819 done
  1820 
  1821 lemma posDivAlg_div_mod:
  1822   assumes "k \<ge> 0"
  1823   and "l \<ge> 0"
  1824   shows "posDivAlg k l = (k div l, k mod l)"
  1825 proof (cases "l = 0")
  1826   case True then show ?thesis by (simp add: posDivAlg.simps)
  1827 next
  1828   case False with assms posDivAlg_correct
  1829     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1830     by simp
  1831   from div_int_unique [OF this] mod_int_unique [OF this]
  1832   show ?thesis by simp
  1833 qed
  1834 
  1835 lemma negDivAlg_div_mod:
  1836   assumes "k < 0"
  1837   and "l > 0"
  1838   shows "negDivAlg k l = (k div l, k mod l)"
  1839 proof -
  1840   from assms have "l \<noteq> 0" by simp
  1841   from assms negDivAlg_correct
  1842     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1843     by simp
  1844   from div_int_unique [OF this] mod_int_unique [OF this]
  1845   show ?thesis by simp
  1846 qed
  1847 
  1848 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1849 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1850 
  1851 (* REVISIT: should this be generalized to all semiring_div types? *)
  1852 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1853 
  1854 lemma zmod_zdiv_equality':
  1855   "(m\<Colon>int) mod n = m - (m div n) * n"
  1856   using mod_div_equality [of m n] by arith
  1857 
  1858 
  1859 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1860 
  1861 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1862   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1863   to cause particular problems.*)
  1864 
  1865 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1866 
  1867 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1868 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1869  apply (simp add: algebra_simps)
  1870 apply (rule order_le_less_trans)
  1871  apply (erule_tac [2] mult_strict_right_mono)
  1872  apply (rule mult_left_mono_neg)
  1873   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1874  apply (simp)
  1875 apply (simp)
  1876 done
  1877 
  1878 lemma zmult2_lemma_aux2:
  1879      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1880 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1881  apply arith
  1882 apply (simp add: mult_le_0_iff)
  1883 done
  1884 
  1885 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1886 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1887 apply arith
  1888 apply (simp add: zero_le_mult_iff)
  1889 done
  1890 
  1891 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1892 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1893  apply (simp add: right_diff_distrib)
  1894 apply (rule order_less_le_trans)
  1895  apply (erule mult_strict_right_mono)
  1896  apply (rule_tac [2] mult_left_mono)
  1897   apply simp
  1898  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1899 apply simp
  1900 done
  1901 
  1902 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1903       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1904 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1905                    zero_less_mult_iff distrib_left [symmetric] 
  1906                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4 mult_less_0_iff split: split_if_asm)
  1907 
  1908 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1909 apply (case_tac "b = 0", simp)
  1910 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN div_int_unique])
  1911 done
  1912 
  1913 lemma zmod_zmult2_eq:
  1914      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1915 apply (case_tac "b = 0", simp)
  1916 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN mod_int_unique])
  1917 done
  1918 
  1919 lemma div_pos_geq:
  1920   fixes k l :: int
  1921   assumes "0 < l" and "l \<le> k"
  1922   shows "k div l = (k - l) div l + 1"
  1923 proof -
  1924   have "k = (k - l) + l" by simp
  1925   then obtain j where k: "k = j + l" ..
  1926   with assms show ?thesis by simp
  1927 qed
  1928 
  1929 lemma mod_pos_geq:
  1930   fixes k l :: int
  1931   assumes "0 < l" and "l \<le> k"
  1932   shows "k mod l = (k - l) mod l"
  1933 proof -
  1934   have "k = (k - l) + l" by simp
  1935   then obtain j where k: "k = j + l" ..
  1936   with assms show ?thesis by simp
  1937 qed
  1938 
  1939 
  1940 subsubsection {* Splitting Rules for div and mod *}
  1941 
  1942 text{*The proofs of the two lemmas below are essentially identical*}
  1943 
  1944 lemma split_pos_lemma:
  1945  "0<k ==> 
  1946     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  1947 apply (rule iffI, clarify)
  1948  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1949  apply (subst mod_add_eq) 
  1950  apply (subst zdiv_zadd1_eq) 
  1951  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  1952 txt{*converse direction*}
  1953 apply (drule_tac x = "n div k" in spec) 
  1954 apply (drule_tac x = "n mod k" in spec, simp)
  1955 done
  1956 
  1957 lemma split_neg_lemma:
  1958  "k<0 ==>
  1959     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  1960 apply (rule iffI, clarify)
  1961  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1962  apply (subst mod_add_eq) 
  1963  apply (subst zdiv_zadd1_eq) 
  1964  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  1965 txt{*converse direction*}
  1966 apply (drule_tac x = "n div k" in spec) 
  1967 apply (drule_tac x = "n mod k" in spec, simp)
  1968 done
  1969 
  1970 lemma split_zdiv:
  1971  "P(n div k :: int) =
  1972   ((k = 0 --> P 0) & 
  1973    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  1974    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  1975 apply (case_tac "k=0", simp)
  1976 apply (simp only: linorder_neq_iff)
  1977 apply (erule disjE) 
  1978  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  1979                       split_neg_lemma [of concl: "%x y. P x"])
  1980 done
  1981 
  1982 lemma split_zmod:
  1983  "P(n mod k :: int) =
  1984   ((k = 0 --> P n) & 
  1985    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  1986    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  1987 apply (case_tac "k=0", simp)
  1988 apply (simp only: linorder_neq_iff)
  1989 apply (erule disjE) 
  1990  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  1991                       split_neg_lemma [of concl: "%x y. P y"])
  1992 done
  1993 
  1994 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  1995   when these are applied to some constant that is of the form
  1996   @{term "numeral k"}: *}
  1997 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  1998 declare split_zmod [of _ _ "numeral k", arith_split] for k
  1999 
  2000 
  2001 subsubsection {* Computing @{text "div"} and @{text "mod"} with shifting *}
  2002 
  2003 lemma pos_divmod_int_rel_mult_2:
  2004   assumes "0 \<le> b"
  2005   assumes "divmod_int_rel a b (q, r)"
  2006   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 1 + 2*r)"
  2007   using assms unfolding divmod_int_rel_def by auto
  2008 
  2009 lemma neg_divmod_int_rel_mult_2:
  2010   assumes "b \<le> 0"
  2011   assumes "divmod_int_rel (a + 1) b (q, r)"
  2012   shows "divmod_int_rel (1 + 2*a) (2*b) (q, 2*r - 1)"
  2013   using assms unfolding divmod_int_rel_def by auto
  2014 
  2015 text{*computing div by shifting *}
  2016 
  2017 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2018   using pos_divmod_int_rel_mult_2 [OF _ divmod_int_rel_div_mod]
  2019   by (rule div_int_unique)
  2020 
  2021 lemma neg_zdiv_mult_2: 
  2022   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2023   using neg_divmod_int_rel_mult_2 [OF A divmod_int_rel_div_mod]
  2024   by (rule div_int_unique)
  2025 
  2026 (* FIXME: add rules for negative numerals *)
  2027 lemma zdiv_numeral_Bit0 [simp]:
  2028   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2029     numeral v div (numeral w :: int)"
  2030   unfolding numeral.simps unfolding mult_2 [symmetric]
  2031   by (rule div_mult_mult1, simp)
  2032 
  2033 lemma zdiv_numeral_Bit1 [simp]:
  2034   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2035     (numeral v div (numeral w :: int))"
  2036   unfolding numeral.simps
  2037   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2038   by (rule pos_zdiv_mult_2, simp)
  2039 
  2040 lemma pos_zmod_mult_2:
  2041   fixes a b :: int
  2042   assumes "0 \<le> a"
  2043   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2044   using pos_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2045   by (rule mod_int_unique)
  2046 
  2047 lemma neg_zmod_mult_2:
  2048   fixes a b :: int
  2049   assumes "a \<le> 0"
  2050   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2051   using neg_divmod_int_rel_mult_2 [OF assms divmod_int_rel_div_mod]
  2052   by (rule mod_int_unique)
  2053 
  2054 (* FIXME: add rules for negative numerals *)
  2055 lemma zmod_numeral_Bit0 [simp]:
  2056   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2057     (2::int) * (numeral v mod numeral w)"
  2058   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2059   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2060 
  2061 lemma zmod_numeral_Bit1 [simp]:
  2062   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2063     2 * (numeral v mod numeral w) + (1::int)"
  2064   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2065   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2066   by (rule pos_zmod_mult_2, simp)
  2067 
  2068 lemma zdiv_eq_0_iff:
  2069  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2070 proof
  2071   assume ?L
  2072   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2073   with `?L` show ?R by blast
  2074 next
  2075   assume ?R thus ?L
  2076     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2077 qed
  2078 
  2079 
  2080 subsubsection {* Quotients of Signs *}
  2081 
  2082 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2083 apply (subgoal_tac "a div b \<le> -1", force)
  2084 apply (rule order_trans)
  2085 apply (rule_tac a' = "-1" in zdiv_mono1)
  2086 apply (auto simp add: div_eq_minus1)
  2087 done
  2088 
  2089 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2090 by (drule zdiv_mono1_neg, auto)
  2091 
  2092 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2093 by (drule zdiv_mono1, auto)
  2094 
  2095 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2096 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2097 They should all be simp rules unless that causes too much search. *}
  2098 
  2099 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2100 apply auto
  2101 apply (drule_tac [2] zdiv_mono1)
  2102 apply (auto simp add: linorder_neq_iff)
  2103 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2104 apply (blast intro: div_neg_pos_less0)
  2105 done
  2106 
  2107 lemma neg_imp_zdiv_nonneg_iff:
  2108   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2109 apply (subst div_minus_minus [symmetric])
  2110 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2111 done
  2112 
  2113 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2114 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2115 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2116 
  2117 lemma pos_imp_zdiv_pos_iff:
  2118   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2119 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2120 by arith
  2121 
  2122 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2123 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2124 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2125 
  2126 lemma nonneg1_imp_zdiv_pos_iff:
  2127   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2128 apply rule
  2129  apply rule
  2130   using div_pos_pos_trivial[of a b]apply arith
  2131  apply(cases "b=0")apply simp
  2132  using div_nonneg_neg_le0[of a b]apply arith
  2133 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2134 done
  2135 
  2136 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2137 apply (rule split_zmod[THEN iffD2])
  2138 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2139 done
  2140 
  2141 
  2142 subsubsection {* The Divides Relation *}
  2143 
  2144 lemma dvd_neg_numeral_left [simp]:
  2145   fixes y :: "'a::comm_ring_1"
  2146   shows "(neg_numeral k) dvd y \<longleftrightarrow> (numeral k) dvd y"
  2147   unfolding neg_numeral_def minus_dvd_iff ..
  2148 
  2149 lemma dvd_neg_numeral_right [simp]:
  2150   fixes x :: "'a::comm_ring_1"
  2151   shows "x dvd (neg_numeral k) \<longleftrightarrow> x dvd (numeral k)"
  2152   unfolding neg_numeral_def dvd_minus_iff ..
  2153 
  2154 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2155   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2156 
  2157 
  2158 subsubsection {* Further properties *}
  2159 
  2160 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2161   using zmod_zdiv_equality[where a="m" and b="n"]
  2162   by (simp add: algebra_simps) (* FIXME: generalize *)
  2163 
  2164 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2165 apply (subst split_div, auto)
  2166 apply (subst split_zdiv, auto)
  2167 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2168 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2169 done
  2170 
  2171 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2172 apply (subst split_mod, auto)
  2173 apply (subst split_zmod, auto)
  2174 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2175        in unique_remainder)
  2176 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2177 done
  2178 
  2179 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2180 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2181 
  2182 text{*Suggested by Matthias Daum*}
  2183 lemma int_power_div_base:
  2184      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2185 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2186  apply (erule ssubst)
  2187  apply (simp only: power_add)
  2188  apply simp_all
  2189 done
  2190 
  2191 text {* by Brian Huffman *}
  2192 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2193 by (rule mod_minus_eq [symmetric])
  2194 
  2195 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2196 by (rule mod_diff_left_eq [symmetric])
  2197 
  2198 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2199 by (rule mod_diff_right_eq [symmetric])
  2200 
  2201 lemmas zmod_simps =
  2202   mod_add_left_eq  [symmetric]
  2203   mod_add_right_eq [symmetric]
  2204   mod_mult_right_eq[symmetric]
  2205   mod_mult_left_eq [symmetric]
  2206   power_mod
  2207   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2208 
  2209 text {* Distributive laws for function @{text nat}. *}
  2210 
  2211 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2212 apply (rule linorder_cases [of y 0])
  2213 apply (simp add: div_nonneg_neg_le0)
  2214 apply simp
  2215 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2216 done
  2217 
  2218 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2219 lemma nat_mod_distrib:
  2220   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2221 apply (case_tac "y = 0", simp)
  2222 apply (simp add: nat_eq_iff zmod_int)
  2223 done
  2224 
  2225 text  {* transfer setup *}
  2226 
  2227 lemma transfer_nat_int_functions:
  2228     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2229     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2230   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2231 
  2232 lemma transfer_nat_int_function_closures:
  2233     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2234     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2235   apply (cases "y = 0")
  2236   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2237   apply (cases "y = 0")
  2238   apply auto
  2239 done
  2240 
  2241 declare transfer_morphism_nat_int [transfer add return:
  2242   transfer_nat_int_functions
  2243   transfer_nat_int_function_closures
  2244 ]
  2245 
  2246 lemma transfer_int_nat_functions:
  2247     "(int x) div (int y) = int (x div y)"
  2248     "(int x) mod (int y) = int (x mod y)"
  2249   by (auto simp add: zdiv_int zmod_int)
  2250 
  2251 lemma transfer_int_nat_function_closures:
  2252     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2253     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2254   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2255 
  2256 declare transfer_morphism_int_nat [transfer add return:
  2257   transfer_int_nat_functions
  2258   transfer_int_nat_function_closures
  2259 ]
  2260 
  2261 text{*Suggested by Matthias Daum*}
  2262 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2263 apply (subgoal_tac "nat x div nat k < nat x")
  2264  apply (simp add: nat_div_distrib [symmetric])
  2265 apply (rule Divides.div_less_dividend, simp_all)
  2266 done
  2267 
  2268 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2269 proof
  2270   assume H: "x mod n = y mod n"
  2271   hence "x mod n - y mod n = 0" by simp
  2272   hence "(x mod n - y mod n) mod n = 0" by simp 
  2273   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2274   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2275 next
  2276   assume H: "n dvd x - y"
  2277   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2278   hence "x = n*k + y" by simp
  2279   hence "x mod n = (n*k + y) mod n" by simp
  2280   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2281 qed
  2282 
  2283 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2284   shows "\<exists>q. x = y + n * q"
  2285 proof-
  2286   from xy have th: "int x - int y = int (x - y)" by simp 
  2287   from xyn have "int x mod int n = int y mod int n" 
  2288     by (simp add: zmod_int [symmetric])
  2289   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2290   hence "n dvd x - y" by (simp add: th zdvd_int)
  2291   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2292 qed
  2293 
  2294 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2295   (is "?lhs = ?rhs")
  2296 proof
  2297   assume H: "x mod n = y mod n"
  2298   {assume xy: "x \<le> y"
  2299     from H have th: "y mod n = x mod n" by simp
  2300     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2301       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2302   moreover
  2303   {assume xy: "y \<le> x"
  2304     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2305       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2306   ultimately  show ?rhs using linear[of x y] by blast  
  2307 next
  2308   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2309   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2310   thus  ?lhs by simp
  2311 qed
  2312 
  2313 lemma div_nat_numeral [simp]:
  2314   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2315   by (simp add: nat_div_distrib)
  2316 
  2317 lemma one_div_nat_numeral [simp]:
  2318   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2319   by (subst nat_div_distrib, simp_all)
  2320 
  2321 lemma mod_nat_numeral [simp]:
  2322   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2323   by (simp add: nat_mod_distrib)
  2324 
  2325 lemma one_mod_nat_numeral [simp]:
  2326   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2327   by (subst nat_mod_distrib) simp_all
  2328 
  2329 lemma mod_2_not_eq_zero_eq_one_int:
  2330   fixes k :: int
  2331   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2332   by auto
  2333 
  2334 
  2335 subsubsection {* Tools setup *}
  2336 
  2337 text {* Nitpick *}
  2338 
  2339 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2340 
  2341 
  2342 subsubsection {* Code generation *}
  2343 
  2344 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2345   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2346 
  2347 lemma pdivmod_posDivAlg [code]:
  2348   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2349 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2350 
  2351 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2352   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2353     then pdivmod k l
  2354     else (let (r, s) = pdivmod k l in
  2355        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2356 proof -
  2357   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2358   show ?thesis
  2359     by (simp add: divmod_int_mod_div pdivmod_def)
  2360       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2361       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2362 qed
  2363 
  2364 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2365   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2366     then pdivmod k l
  2367     else (let (r, s) = pdivmod k l in
  2368       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2369 proof -
  2370   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2371     by (auto simp add: not_less sgn_if)
  2372   then show ?thesis by (simp add: divmod_int_pdivmod)
  2373 qed
  2374 
  2375 code_modulename SML
  2376   Divides Arith
  2377 
  2378 code_modulename OCaml
  2379   Divides Arith
  2380 
  2381 code_modulename Haskell
  2382   Divides Arith
  2383 
  2384 end