src/ZF/Constructible/Datatype_absolute.thy
author paulson
Fri Jul 12 11:24:40 2002 +0200 (2002-07-12)
changeset 13352 3cd767f8d78b
parent 13350 626b79677dfa
child 13353 1800e7134d2e
permissions -rw-r--r--
new definitions of fun_apply and M_is_recfun
     1 header {*Absoluteness Properties for Recursive Datatypes*}
     2 
     3 theory Datatype_absolute = Formula + WF_absolute:
     4 
     5 
     6 subsection{*The lfp of a continuous function can be expressed as a union*}
     7 
     8 constdefs
     9   contin :: "[i=>i]=>o"
    10    "contin(h) == (\<forall>A. A\<noteq>0 --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    11 
    12 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    13 apply (induct_tac n) 
    14  apply (simp_all add: bnd_mono_def, blast) 
    15 done
    16 
    17 
    18 lemma contin_iterates_eq: 
    19     "contin(h) \<Longrightarrow> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    20 apply (simp add: contin_def) 
    21 apply (rule trans) 
    22 apply (rule equalityI) 
    23  apply (simp_all add: UN_subset_iff) 
    24  apply safe
    25  apply (erule_tac [2] natE) 
    26   apply (rule_tac a="succ(x)" in UN_I) 
    27    apply simp_all 
    28 apply blast 
    29 done
    30 
    31 lemma lfp_subset_Union:
    32      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    33 apply (rule lfp_lowerbound) 
    34  apply (simp add: contin_iterates_eq) 
    35 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    36 done
    37 
    38 lemma Union_subset_lfp:
    39      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    40 apply (simp add: UN_subset_iff)
    41 apply (rule ballI)  
    42 apply (induct_tac n, simp_all) 
    43 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    44  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset] )  
    45 apply (erule lfp_lemma2) 
    46 done
    47 
    48 lemma lfp_eq_Union:
    49      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    50 by (blast del: subsetI 
    51           intro: lfp_subset_Union Union_subset_lfp)
    52 
    53 
    54 subsection {*lists without univ*}
    55 
    56 lemmas datatype_univs = A_into_univ Inl_in_univ Inr_in_univ 
    57                         Pair_in_univ zero_in_univ
    58 
    59 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
    60 apply (rule bnd_monoI)
    61  apply (intro subset_refl zero_subset_univ A_subset_univ 
    62 	      sum_subset_univ Sigma_subset_univ) 
    63  apply (blast intro!: subset_refl sum_mono Sigma_mono del: subsetI)
    64 done
    65 
    66 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
    67 by (simp add: contin_def, blast)
    68 
    69 text{*Re-expresses lists using sum and product*}
    70 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
    71 apply (simp add: list_def) 
    72 apply (rule equalityI) 
    73  apply (rule lfp_lowerbound) 
    74   prefer 2 apply (rule lfp_subset)
    75  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
    76  apply (simp add: Nil_def Cons_def)
    77  apply blast 
    78 txt{*Opposite inclusion*}
    79 apply (rule lfp_lowerbound) 
    80  prefer 2 apply (rule lfp_subset) 
    81 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
    82 apply (simp add: Nil_def Cons_def)
    83 apply (blast intro: datatype_univs
    84              dest: lfp_subset [THEN subsetD])
    85 done
    86 
    87 text{*Re-expresses lists using "iterates", no univ.*}
    88 lemma list_eq_Union:
    89      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
    90 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
    91 
    92 
    93 subsection {*Absoluteness for "Iterates"*}
    94 
    95 lemma (in M_trancl) iterates_relativize:
    96   "[|n \<in> nat; M(v); \<forall>x[M]. M(F(x));
    97      strong_replacement(M, 
    98        \<lambda>x z. \<exists>y[M]. \<exists>g[M]. pair(M,x,y,z) &
    99               M_is_recfun(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   100                           Memrel(succ(n)), x, g) &
   101               y = nat_case(v, \<lambda>m. F(g`m), x))|] 
   102    ==> iterates(F,n,v) = z <-> 
   103        (\<exists>g[M]. is_recfun(Memrel(succ(n)), n, 
   104                              \<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n), g) &
   105             z = nat_case(v, \<lambda>m. F(g`m), n))"
   106 by (simp add: iterates_nat_def recursor_def transrec_def 
   107               eclose_sing_Ord_eq trans_wfrec_relativize nat_into_M
   108               wf_Memrel trans_Memrel relation_Memrel
   109               is_recfun_abs [of "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   110 
   111 lemma (in M_wfrank) iterates_closed [intro,simp]:
   112   "[|n \<in> nat; M(v); \<forall>x[M]. M(F(x));
   113      strong_replacement(M, 
   114        \<lambda>x z. \<exists>y[M]. \<exists>g[M]. pair(M, x, y, z) &
   115               is_recfun (Memrel(succ(n)), x,
   116                          \<lambda>n f. nat_case(v, \<lambda>m. F(f`m), n), g) &
   117               y = nat_case(v, \<lambda>m. F(g`m), x))|] 
   118    ==> M(iterates(F,n,v))"
   119 by (simp add: iterates_nat_def recursor_def transrec_def 
   120               eclose_sing_Ord_eq trans_wfrec_closed nat_into_M
   121               wf_Memrel trans_Memrel relation_Memrel nat_case_closed)
   122 
   123 
   124 constdefs
   125   is_list_functor :: "[i=>o,i,i,i] => o"
   126     "is_list_functor(M,A,X,Z) == 
   127         \<exists>n1[M]. \<exists>AX[M]. 
   128          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   129 
   130   list_functor_case :: "[i=>o,i,i,i,i] => o"
   131     --{*Abbreviation for the definition of lists below*}
   132     "list_functor_case(M,A,g,x,y) == 
   133         is_nat_case(M, 0, 
   134              \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & is_list_functor(M,A,gm,u),
   135              x, y)"
   136 
   137 lemma (in M_axioms) list_functor_abs [simp]: 
   138      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   139 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   140 
   141 lemma (in M_axioms) list_functor_case_abs: 
   142      "[| M(A); M(n); M(y); M(g) |] 
   143       ==> list_functor_case(M,A,g,n,y) <-> 
   144           y = nat_case(0, \<lambda>m. {0} + A * g`m, n)"
   145 by (simp add: list_functor_case_def nat_into_M)
   146 
   147 
   148 locale M_datatypes = M_wfrank +
   149   assumes list_replacement1: 
   150        "[|M(A); n \<in> nat|] ==> 
   151 	strong_replacement(M, 
   152 	  \<lambda>x z. \<exists>y[M]. \<exists>g[M]. \<exists>sucn[M]. \<exists>memr[M]. 
   153 		 pair(M,x,y,z) & successor(M,n,sucn) & 
   154 		 membership(M,sucn,memr) &
   155 		 M_is_recfun(M, \<lambda>n f z. list_functor_case(M,A,f,n,z), 
   156                              memr, x, g) &
   157                  list_functor_case(M,A,g,x,y))"
   158 (*THEY NEED RELATIVIZATION*)
   159       and list_replacement2: 
   160            "M(A) ==> strong_replacement(M, \<lambda>x y. y = (\<lambda>X. {0} + A * X)^x (0))"
   161 
   162 
   163 
   164 lemma (in M_datatypes) list_replacement1':
   165   "[|M(A); n \<in> nat|]
   166    ==> strong_replacement
   167 	  (M, \<lambda>x z. \<exists>y[M]. z = \<langle>x,y\<rangle> &
   168                (\<exists>g[M]. is_recfun (Memrel(succ(n)), x,
   169 		          \<lambda>n f. nat_case(0, \<lambda>m. {0} + A * f`m, n), g) &
   170  	       y = nat_case(0, \<lambda>m. {0} + A * g ` m, x)))"
   171 apply (insert list_replacement1 [of A n], simp add: nat_into_M)
   172 apply (simp add: nat_into_M list_functor_case_abs
   173                  is_recfun_abs [of "\<lambda>n f. nat_case(0, \<lambda>m. {0} + A * f`m, n)"])
   174 done
   175 
   176 lemma (in M_datatypes) list_replacement2': 
   177   "M(A) ==> strong_replacement(M, \<lambda>x y. y = (\<lambda>X. {0} + A * X)^x (0))"
   178 by (insert list_replacement2, simp add: nat_into_M) 
   179 
   180 
   181 lemma (in M_datatypes) list_closed [intro,simp]:
   182      "M(A) ==> M(list(A))"
   183 by (simp add: list_eq_Union list_replacement1' list_replacement2')
   184 
   185 
   186 end