src/HOL/BNF/Tools/bnf_comp.ML
author traytel
Thu Oct 04 17:16:55 2012 +0200 (2012-10-04)
changeset 49713 3d07ddf70f8b
parent 49669 620fa6272c48
child 49714 2c7c32f34220
permissions -rw-r--r--
do not expose details of internal data structures for composition of BNFs
     1 (*  Title:      HOL/BNF/Tools/bnf_comp.ML
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Author:     Jasmin Blanchette, TU Muenchen
     4     Copyright   2012
     5 
     6 Composition of bounded natural functors.
     7 *)
     8 
     9 signature BNF_COMP =
    10 sig
    11   val ID_bnf: BNF_Def.BNF
    12   val DEADID_bnf: BNF_Def.BNF
    13 
    14   type unfold_set
    15   val empty_unfolds: unfold_set
    16 
    17   val bnf_of_typ: BNF_Def.const_policy -> (binding -> binding) ->
    18     ((string * sort) list list -> (string * sort) list) -> typ -> unfold_set * Proof.context ->
    19     (BNF_Def.BNF * (typ list * typ list)) * (unfold_set * Proof.context)
    20   val default_comp_sort: (string * sort) list list -> (string * sort) list
    21   val normalize_bnfs: (int -> binding -> binding) -> ''a list list -> ''a list ->
    22     (''a list list -> ''a list) -> BNF_Def.BNF list -> unfold_set -> Proof.context ->
    23     (int list list * ''a list) * (BNF_Def.BNF list * (unfold_set * Proof.context))
    24   val seal_bnf: unfold_set -> binding -> typ list -> BNF_Def.BNF -> Proof.context ->
    25     (BNF_Def.BNF * typ list) * local_theory
    26 end;
    27 
    28 structure BNF_Comp : BNF_COMP =
    29 struct
    30 
    31 open BNF_Def
    32 open BNF_Util
    33 open BNF_Tactics
    34 open BNF_Comp_Tactics
    35 
    36 val ID_bnf = the (bnf_of @{context} "Basic_BNFs.ID");
    37 val DEADID_bnf = the (bnf_of @{context} "Basic_BNFs.DEADID");
    38 
    39 (* TODO: Replace by "BNF_Defs.defs list" *)
    40 type unfold_set = {
    41   map_unfolds: thm list,
    42   set_unfoldss: thm list list,
    43   rel_unfolds: thm list,
    44   srel_unfolds: thm list
    45 };
    46 
    47 val empty_unfolds = {map_unfolds = [], set_unfoldss = [], rel_unfolds = [], srel_unfolds = []};
    48 
    49 fun add_to_thms thms new = thms |> not (Thm.is_reflexive new) ? insert Thm.eq_thm new;
    50 fun adds_to_thms thms news = insert (eq_set Thm.eq_thm) (no_reflexive news) thms;
    51 
    52 fun add_to_unfolds map sets rel srel
    53   {map_unfolds, set_unfoldss, rel_unfolds, srel_unfolds} =
    54   {map_unfolds = add_to_thms map_unfolds map,
    55     set_unfoldss = adds_to_thms set_unfoldss sets,
    56     rel_unfolds = add_to_thms rel_unfolds rel,
    57     srel_unfolds = add_to_thms srel_unfolds srel};
    58 
    59 fun add_bnf_to_unfolds bnf =
    60   add_to_unfolds (map_def_of_bnf bnf) (set_defs_of_bnf bnf) (rel_def_of_bnf bnf)
    61     (srel_def_of_bnf bnf);
    62 
    63 val bdTN = "bdT";
    64 
    65 fun mk_killN n = "_kill" ^ string_of_int n;
    66 fun mk_liftN n = "_lift" ^ string_of_int n;
    67 fun mk_permuteN src dest =
    68   "_permute_" ^ implode (map string_of_int src) ^ "_" ^ implode (map string_of_int dest);
    69 
    70 (*copied from Envir.expand_term_free*)
    71 fun expand_term_const defs =
    72   let
    73     val eqs = map ((fn ((x, U), u) => (x, (U, u))) o apfst dest_Const) defs;
    74     val get = fn Const (x, _) => AList.lookup (op =) eqs x | _ => NONE;
    75   in Envir.expand_term get end;
    76 
    77 fun clean_compose_bnf const_policy qualify b outer inners (unfold_set, lthy) =
    78   let
    79     val olive = live_of_bnf outer;
    80     val onwits = nwits_of_bnf outer;
    81     val odead = dead_of_bnf outer;
    82     val inner = hd inners;
    83     val ilive = live_of_bnf inner;
    84     val ideads = map dead_of_bnf inners;
    85     val inwitss = map nwits_of_bnf inners;
    86 
    87     (* TODO: check olive = length inners > 0,
    88                    forall inner from inners. ilive = live,
    89                    forall inner from inners. idead = dead  *)
    90 
    91     val (oDs, lthy1) = apfst (map TFree)
    92       (Variable.invent_types (replicate odead HOLogic.typeS) lthy);
    93     val (Dss, lthy2) = apfst (map (map TFree))
    94         (fold_map Variable.invent_types (map (fn n => replicate n HOLogic.typeS) ideads) lthy1);
    95     val (Ass, lthy3) = apfst (replicate ilive o map TFree)
    96       (Variable.invent_types (replicate ilive HOLogic.typeS) lthy2);
    97     val As = if ilive > 0 then hd Ass else [];
    98     val Ass_repl = replicate olive As;
    99     val (Bs, _(*lthy4*)) = apfst (map TFree)
   100       (Variable.invent_types (replicate ilive HOLogic.typeS) lthy3);
   101     val Bss_repl = replicate olive Bs;
   102 
   103     val ((((fs', Qs'), Asets), xs), _(*names_lthy*)) = lthy
   104       |> apfst snd o mk_Frees' "f" (map2 (curry (op -->)) As Bs)
   105       ||>> apfst snd o mk_Frees' "Q" (map2 mk_pred2T As Bs)
   106       ||>> mk_Frees "A" (map HOLogic.mk_setT As)
   107       ||>> mk_Frees "x" As;
   108 
   109     val CAs = map3 mk_T_of_bnf Dss Ass_repl inners;
   110     val CCA = mk_T_of_bnf oDs CAs outer;
   111     val CBs = map3 mk_T_of_bnf Dss Bss_repl inners;
   112     val outer_sets = mk_sets_of_bnf (replicate olive oDs) (replicate olive CAs) outer;
   113     val inner_setss = map3 mk_sets_of_bnf (map (replicate ilive) Dss) (replicate olive Ass) inners;
   114     val inner_bds = map3 mk_bd_of_bnf Dss Ass_repl inners;
   115     val outer_bd = mk_bd_of_bnf oDs CAs outer;
   116 
   117     (*%f1 ... fn. outer.map (inner_1.map f1 ... fn) ... (inner_m.map f1 ... fn)*)
   118     val mapx = fold_rev Term.abs fs'
   119       (Term.list_comb (mk_map_of_bnf oDs CAs CBs outer,
   120         map2 (fn Ds => (fn f => Term.list_comb (f, map Bound (ilive - 1 downto 0))) o
   121           mk_map_of_bnf Ds As Bs) Dss inners));
   122     (*%Q1 ... Qn. outer.rel (inner_1.rel Q1 ... Qn) ... (inner_m.rel Q1 ... Qn)*)
   123     val rel = fold_rev Term.abs Qs'
   124       (Term.list_comb (mk_rel_of_bnf oDs CAs CBs outer,
   125         map2 (fn Ds => (fn f => Term.list_comb (f, map Bound (ilive - 1 downto 0))) o
   126           mk_rel_of_bnf Ds As Bs) Dss inners));
   127 
   128     (*Union o collect {outer.set_1 ... outer.set_m} o outer.map inner_1.set_i ... inner_m.set_i*)
   129     (*Union o collect {image inner_1.set_i o outer.set_1 ... image inner_m.set_i o outer.set_m}*)
   130     fun mk_set i =
   131       let
   132         val (setTs, T) = `(replicate olive o HOLogic.mk_setT) (nth As i);
   133         val outer_set = mk_collect
   134           (mk_sets_of_bnf (replicate olive oDs) (replicate olive setTs) outer)
   135           (mk_T_of_bnf oDs setTs outer --> HOLogic.mk_setT T);
   136         val inner_sets = map (fn sets => nth sets i) inner_setss;
   137         val outer_map = mk_map_of_bnf oDs CAs setTs outer;
   138         val map_inner_sets = Term.list_comb (outer_map, inner_sets);
   139         val collect_image = mk_collect
   140           (map2 (fn f => fn set => HOLogic.mk_comp (mk_image f, set)) inner_sets outer_sets)
   141           (CCA --> HOLogic.mk_setT T);
   142       in
   143         (Library.foldl1 HOLogic.mk_comp [mk_Union T, outer_set, map_inner_sets],
   144         HOLogic.mk_comp (mk_Union T, collect_image))
   145       end;
   146 
   147     val (sets, sets_alt) = map_split mk_set (0 upto ilive - 1);
   148 
   149     (*(inner_1.bd +c ... +c inner_m.bd) *c outer.bd*)
   150     val bd = Term.absdummy CCA (mk_cprod (Library.foldr1 (uncurry mk_csum) inner_bds) outer_bd);
   151 
   152     fun map_id_tac _ =
   153       mk_comp_map_id_tac (map_id_of_bnf outer) (map_cong_of_bnf outer)
   154         (map map_id_of_bnf inners);
   155 
   156     fun map_comp_tac _ =
   157       mk_comp_map_comp_tac (map_comp_of_bnf outer) (map_cong_of_bnf outer)
   158         (map map_comp_of_bnf inners);
   159 
   160     fun mk_single_set_natural_tac i _ =
   161       mk_comp_set_natural_tac (map_comp_of_bnf outer) (map_cong_of_bnf outer)
   162         (collect_set_natural_of_bnf outer)
   163         (map ((fn thms => nth thms i) o set_natural_of_bnf) inners);
   164 
   165     val set_natural_tacs = map mk_single_set_natural_tac (0 upto ilive - 1);
   166 
   167     fun bd_card_order_tac _ =
   168       mk_comp_bd_card_order_tac (map bd_card_order_of_bnf inners) (bd_card_order_of_bnf outer);
   169 
   170     fun bd_cinfinite_tac _ =
   171       mk_comp_bd_cinfinite_tac (bd_cinfinite_of_bnf inner) (bd_cinfinite_of_bnf outer);
   172 
   173     val set_alt_thms =
   174       if ! quick_and_dirty then
   175         []
   176       else
   177         map (fn goal =>
   178           Skip_Proof.prove lthy [] [] goal
   179             (fn {context, ...} => (mk_comp_set_alt_tac context (collect_set_natural_of_bnf outer)))
   180           |> Thm.close_derivation)
   181         (map2 (curry (HOLogic.mk_Trueprop o HOLogic.mk_eq)) sets sets_alt);
   182 
   183     fun map_cong_tac _ =
   184       mk_comp_map_cong_tac set_alt_thms (map_cong_of_bnf outer) (map map_cong_of_bnf inners);
   185 
   186     val set_bd_tacs =
   187       if ! quick_and_dirty then
   188         replicate ilive (K all_tac)
   189       else
   190         let
   191           val outer_set_bds = set_bd_of_bnf outer;
   192           val inner_set_bdss = map set_bd_of_bnf inners;
   193           val inner_bd_Card_orders = map bd_Card_order_of_bnf inners;
   194           fun single_set_bd_thm i j =
   195             @{thm comp_single_set_bd} OF [nth inner_bd_Card_orders j, nth (nth inner_set_bdss j) i,
   196               nth outer_set_bds j]
   197           val single_set_bd_thmss =
   198             map ((fn f => map f (0 upto olive - 1)) o single_set_bd_thm) (0 upto ilive - 1);
   199         in
   200           map2 (fn set_alt => fn single_set_bds => fn {context, ...} =>
   201             mk_comp_set_bd_tac context set_alt single_set_bds)
   202           set_alt_thms single_set_bd_thmss
   203         end;
   204 
   205     val in_alt_thm =
   206       let
   207         val inx = mk_in Asets sets CCA;
   208         val in_alt = mk_in (map2 (mk_in Asets) inner_setss CAs) outer_sets CCA;
   209         val goal = fold_rev Logic.all Asets (mk_Trueprop_eq (inx, in_alt));
   210       in
   211         Skip_Proof.prove lthy [] [] goal
   212           (fn {context, ...} => mk_comp_in_alt_tac context set_alt_thms)
   213         |> Thm.close_derivation
   214       end;
   215 
   216     fun in_bd_tac _ =
   217       mk_comp_in_bd_tac in_alt_thm (map in_bd_of_bnf inners) (in_bd_of_bnf outer)
   218         (map bd_Cinfinite_of_bnf inners) (bd_Card_order_of_bnf outer);
   219 
   220     fun map_wpull_tac _ =
   221       mk_map_wpull_tac in_alt_thm (map map_wpull_of_bnf inners) (map_wpull_of_bnf outer);
   222 
   223     fun srel_O_Gr_tac _ =
   224       let
   225         val basic_thms = @{thms mem_Collect_eq fst_conv snd_conv}; (*TODO: tune*)
   226         val outer_srel_Gr = srel_Gr_of_bnf outer RS sym;
   227         val outer_srel_cong = srel_cong_of_bnf outer;
   228         val thm =
   229           (trans OF [in_alt_thm RS @{thm O_Gr_cong},
   230              trans OF [@{thm arg_cong2[of _ _ _ _ relcomp]} OF
   231                [trans OF [outer_srel_Gr RS @{thm arg_cong[of _ _ converse]},
   232                  srel_converse_of_bnf outer RS sym], outer_srel_Gr],
   233                trans OF [srel_O_of_bnf outer RS sym, outer_srel_cong OF
   234                  (map (fn bnf => srel_O_Gr_of_bnf bnf RS sym) inners)]]] RS sym)
   235           |> unfold_thms lthy (basic_thms @ srel_def_of_bnf outer :: map srel_def_of_bnf inners);
   236       in
   237         unfold_thms_tac lthy basic_thms THEN rtac thm 1
   238       end;
   239 
   240     val tacs = zip_axioms map_id_tac map_comp_tac map_cong_tac set_natural_tacs bd_card_order_tac
   241       bd_cinfinite_tac set_bd_tacs in_bd_tac map_wpull_tac srel_O_Gr_tac;
   242 
   243     val outer_wits = mk_wits_of_bnf (replicate onwits oDs) (replicate onwits CAs) outer;
   244 
   245     val inner_witss = map (map (fn (I, wit) => Term.list_comb (wit, map (nth xs) I)))
   246       (map3 (fn Ds => fn n => mk_wits_of_bnf (replicate n Ds) (replicate n As))
   247         Dss inwitss inners);
   248 
   249     val inner_witsss = map (map (nth inner_witss) o fst) outer_wits;
   250 
   251     val wits = (inner_witsss, (map (single o snd) outer_wits))
   252       |-> map2 (fold (map_product (fn iwit => fn owit => owit $ iwit)))
   253       |> flat
   254       |> map (`(fn t => Term.add_frees t []))
   255       |> minimize_wits
   256       |> map (fn (frees, t) => fold absfree frees t);
   257 
   258     fun wit_tac {context = ctxt, ...} =
   259       mk_comp_wit_tac ctxt (wit_thms_of_bnf outer) (collect_set_natural_of_bnf outer)
   260         (maps wit_thms_of_bnf inners);
   261 
   262     val (bnf', lthy') =
   263       bnf_def const_policy (K Dont_Note) qualify tacs wit_tac (SOME (oDs @ flat Dss))
   264         (((((b, mapx), sets), bd), wits), SOME rel) lthy;
   265   in
   266     (bnf', (add_bnf_to_unfolds bnf' unfold_set, lthy'))
   267   end;
   268 
   269 (* Killing live variables *)
   270 
   271 fun kill_bnf qualify n bnf (unfold_set, lthy) = if n = 0 then (bnf, (unfold_set, lthy)) else
   272   let
   273     val b = Binding.suffix_name (mk_killN n) (name_of_bnf bnf);
   274     val live = live_of_bnf bnf;
   275     val dead = dead_of_bnf bnf;
   276     val nwits = nwits_of_bnf bnf;
   277 
   278     (* TODO: check 0 < n <= live *)
   279 
   280     val (Ds, lthy1) = apfst (map TFree)
   281       (Variable.invent_types (replicate dead HOLogic.typeS) lthy);
   282     val ((killedAs, As), lthy2) = apfst (`(take n) o map TFree)
   283       (Variable.invent_types (replicate live HOLogic.typeS) lthy1);
   284     val (Bs, _(*lthy3*)) = apfst (append killedAs o map TFree)
   285       (Variable.invent_types (replicate (live - n) HOLogic.typeS) lthy2);
   286 
   287     val ((Asets, lives), _(*names_lthy*)) = lthy
   288       |> mk_Frees "A" (map HOLogic.mk_setT (drop n As))
   289       ||>> mk_Frees "x" (drop n As);
   290     val xs = map (fn T => HOLogic.choice_const T $ absdummy T @{term True}) killedAs @ lives;
   291 
   292     val T = mk_T_of_bnf Ds As bnf;
   293 
   294     (*bnf.map id ... id*)
   295     val mapx = Term.list_comb (mk_map_of_bnf Ds As Bs bnf, map HOLogic.id_const killedAs);
   296     (*bnf.rel (op =) ... (op =)*)
   297     val rel = Term.list_comb (mk_rel_of_bnf Ds As Bs bnf, map HOLogic.eq_const killedAs);
   298 
   299     val bnf_sets = mk_sets_of_bnf (replicate live Ds) (replicate live As) bnf;
   300     val sets = drop n bnf_sets;
   301 
   302     (*(|UNIV :: A1 set| +c ... +c |UNIV :: An set|) *c bnf.bd*)
   303     val bnf_bd = mk_bd_of_bnf Ds As bnf;
   304     val bd = mk_cprod
   305       (Library.foldr1 (uncurry mk_csum) (map (mk_card_of o HOLogic.mk_UNIV) killedAs)) bnf_bd;
   306 
   307     fun map_id_tac _ = rtac (map_id_of_bnf bnf) 1;
   308     fun map_comp_tac {context, ...} =
   309       unfold_thms_tac context ((map_comp_of_bnf bnf RS sym) :: @{thms o_assoc id_o o_id}) THEN
   310       rtac refl 1;
   311     fun map_cong_tac {context, ...} =
   312       mk_kill_map_cong_tac context n (live - n) (map_cong_of_bnf bnf);
   313     val set_natural_tacs = map (fn thm => fn _ => rtac thm 1) (drop n (set_natural_of_bnf bnf));
   314     fun bd_card_order_tac _ = mk_kill_bd_card_order_tac n (bd_card_order_of_bnf bnf);
   315     fun bd_cinfinite_tac _ = mk_kill_bd_cinfinite_tac (bd_Cinfinite_of_bnf bnf);
   316     val set_bd_tacs =
   317       map (fn thm => fn _ => mk_kill_set_bd_tac (bd_Card_order_of_bnf bnf) thm)
   318         (drop n (set_bd_of_bnf bnf));
   319 
   320     val in_alt_thm =
   321       let
   322         val inx = mk_in Asets sets T;
   323         val in_alt = mk_in (map HOLogic.mk_UNIV killedAs @ Asets) bnf_sets T;
   324         val goal = fold_rev Logic.all Asets (mk_Trueprop_eq (inx, in_alt));
   325       in
   326         Skip_Proof.prove lthy [] [] goal (K kill_in_alt_tac) |> Thm.close_derivation
   327       end;
   328 
   329     fun in_bd_tac _ =
   330       mk_kill_in_bd_tac n (live > n) in_alt_thm (in_bd_of_bnf bnf) (bd_Card_order_of_bnf bnf)
   331         (bd_Cinfinite_of_bnf bnf) (bd_Cnotzero_of_bnf bnf);
   332     fun map_wpull_tac _ = mk_map_wpull_tac in_alt_thm [] (map_wpull_of_bnf bnf);
   333 
   334     fun srel_O_Gr_tac _ =
   335       let
   336         val srel_Gr = srel_Gr_of_bnf bnf RS sym
   337         val thm =
   338           (trans OF [in_alt_thm RS @{thm O_Gr_cong},
   339             trans OF [@{thm arg_cong2[of _ _ _ _ relcomp]} OF
   340               [trans OF [srel_Gr RS @{thm arg_cong[of _ _ converse]},
   341                 srel_converse_of_bnf bnf RS sym], srel_Gr],
   342               trans OF [srel_O_of_bnf bnf RS sym, srel_cong_of_bnf bnf OF
   343                 (replicate n @{thm trans[OF Gr_UNIV_id[OF refl] Id_alt[symmetric]]} @
   344                  replicate (live - n) @{thm Gr_fst_snd})]]] RS sym)
   345           |> unfold_thms lthy (srel_def_of_bnf bnf :: @{thms Id_def' mem_Collect_eq split_conv});
   346       in
   347         rtac thm 1
   348       end;
   349 
   350     val tacs = zip_axioms map_id_tac map_comp_tac map_cong_tac set_natural_tacs bd_card_order_tac
   351       bd_cinfinite_tac set_bd_tacs in_bd_tac map_wpull_tac srel_O_Gr_tac;
   352 
   353     val bnf_wits = mk_wits_of_bnf (replicate nwits Ds) (replicate nwits As) bnf;
   354 
   355     val wits = map (fn t => fold absfree (Term.add_frees t []) t)
   356       (map (fn (I, wit) => Term.list_comb (wit, map (nth xs) I)) bnf_wits);
   357 
   358     fun wit_tac _ = mk_simple_wit_tac (wit_thms_of_bnf bnf);
   359 
   360     val (bnf', lthy') =
   361       bnf_def Smart_Inline (K Dont_Note) qualify tacs wit_tac (SOME (killedAs @ Ds))
   362         (((((b, mapx), sets), Term.absdummy T bd), wits), SOME rel) lthy;
   363   in
   364     (bnf', (add_bnf_to_unfolds bnf' unfold_set, lthy'))
   365   end;
   366 
   367 (* Adding dummy live variables *)
   368 
   369 fun lift_bnf qualify n bnf (unfold_set, lthy) = if n = 0 then (bnf, (unfold_set, lthy)) else
   370   let
   371     val b = Binding.suffix_name (mk_liftN n) (name_of_bnf bnf);
   372     val live = live_of_bnf bnf;
   373     val dead = dead_of_bnf bnf;
   374     val nwits = nwits_of_bnf bnf;
   375 
   376     (* TODO: check 0 < n *)
   377 
   378     val (Ds, lthy1) = apfst (map TFree)
   379       (Variable.invent_types (replicate dead HOLogic.typeS) lthy);
   380     val ((newAs, As), lthy2) = apfst (chop n o map TFree)
   381       (Variable.invent_types (replicate (n + live) HOLogic.typeS) lthy1);
   382     val ((newBs, Bs), _(*lthy3*)) = apfst (chop n o map TFree)
   383       (Variable.invent_types (replicate (n + live) HOLogic.typeS) lthy2);
   384 
   385     val (Asets, _(*names_lthy*)) = lthy
   386       |> mk_Frees "A" (map HOLogic.mk_setT (newAs @ As));
   387 
   388     val T = mk_T_of_bnf Ds As bnf;
   389 
   390     (*%f1 ... fn. bnf.map*)
   391     val mapx =
   392       fold_rev Term.absdummy (map2 (curry (op -->)) newAs newBs) (mk_map_of_bnf Ds As Bs bnf);
   393     (*%Q1 ... Qn. bnf.rel*)
   394     val rel = fold_rev Term.absdummy (map2 mk_pred2T newAs newBs) (mk_rel_of_bnf Ds As Bs bnf);
   395 
   396     val bnf_sets = mk_sets_of_bnf (replicate live Ds) (replicate live As) bnf;
   397     val sets = map (fn A => absdummy T (HOLogic.mk_set A [])) newAs @ bnf_sets;
   398 
   399     val bd = mk_bd_of_bnf Ds As bnf;
   400 
   401     fun map_id_tac _ = rtac (map_id_of_bnf bnf) 1;
   402     fun map_comp_tac {context, ...} =
   403       unfold_thms_tac context ((map_comp_of_bnf bnf RS sym) :: @{thms o_assoc id_o o_id}) THEN
   404       rtac refl 1;
   405     fun map_cong_tac {context, ...} =
   406       rtac (map_cong_of_bnf bnf) 1 THEN REPEAT_DETERM_N live (Goal.assume_rule_tac context 1);
   407     val set_natural_tacs =
   408       if ! quick_and_dirty then
   409         replicate (n + live) (K all_tac)
   410       else
   411         replicate n (K empty_natural_tac) @
   412         map (fn thm => fn _ => rtac thm 1) (set_natural_of_bnf bnf);
   413     fun bd_card_order_tac _ = rtac (bd_card_order_of_bnf bnf) 1;
   414     fun bd_cinfinite_tac _ = rtac (bd_cinfinite_of_bnf bnf) 1;
   415     val set_bd_tacs =
   416       if ! quick_and_dirty then
   417         replicate (n + live) (K all_tac)
   418       else
   419         replicate n (K (mk_lift_set_bd_tac (bd_Card_order_of_bnf bnf))) @
   420         (map (fn thm => fn _ => rtac thm 1) (set_bd_of_bnf bnf));
   421 
   422     val in_alt_thm =
   423       let
   424         val inx = mk_in Asets sets T;
   425         val in_alt = mk_in (drop n Asets) bnf_sets T;
   426         val goal = fold_rev Logic.all Asets (mk_Trueprop_eq (inx, in_alt));
   427       in
   428         Skip_Proof.prove lthy [] [] goal (K lift_in_alt_tac) |> Thm.close_derivation
   429       end;
   430 
   431     fun in_bd_tac _ = mk_lift_in_bd_tac n in_alt_thm (in_bd_of_bnf bnf) (bd_Card_order_of_bnf bnf);
   432     fun map_wpull_tac _ = mk_map_wpull_tac in_alt_thm [] (map_wpull_of_bnf bnf);
   433 
   434     fun srel_O_Gr_tac _ =
   435       mk_simple_srel_O_Gr_tac lthy (srel_def_of_bnf bnf) (srel_O_Gr_of_bnf bnf) in_alt_thm;
   436 
   437     val tacs = zip_axioms map_id_tac map_comp_tac map_cong_tac set_natural_tacs bd_card_order_tac
   438       bd_cinfinite_tac set_bd_tacs in_bd_tac map_wpull_tac srel_O_Gr_tac;
   439 
   440     val wits = map snd (mk_wits_of_bnf (replicate nwits Ds) (replicate nwits As) bnf);
   441 
   442     fun wit_tac _ = mk_simple_wit_tac (wit_thms_of_bnf bnf);
   443 
   444     val (bnf', lthy') =
   445       bnf_def Smart_Inline (K Dont_Note) qualify tacs wit_tac (SOME Ds)
   446         (((((b, mapx), sets), Term.absdummy T bd), wits), SOME rel) lthy;
   447 
   448   in
   449     (bnf', (add_bnf_to_unfolds bnf' unfold_set, lthy'))
   450   end;
   451 
   452 (* Changing the order of live variables *)
   453 
   454 fun permute_bnf qualify src dest bnf (unfold_set, lthy) =
   455   if src = dest then (bnf, (unfold_set, lthy)) else
   456   let
   457     val b = Binding.suffix_name (mk_permuteN src dest) (name_of_bnf bnf);
   458     val live = live_of_bnf bnf;
   459     val dead = dead_of_bnf bnf;
   460     val nwits = nwits_of_bnf bnf;
   461     fun permute xs = mk_permute src dest xs;
   462     fun permute_rev xs = mk_permute dest src xs;
   463 
   464     val (Ds, lthy1) = apfst (map TFree)
   465       (Variable.invent_types (replicate dead HOLogic.typeS) lthy);
   466     val (As, lthy2) = apfst (map TFree)
   467       (Variable.invent_types (replicate live HOLogic.typeS) lthy1);
   468     val (Bs, _(*lthy3*)) = apfst (map TFree)
   469       (Variable.invent_types (replicate live HOLogic.typeS) lthy2);
   470 
   471     val (Asets, _(*names_lthy*)) = lthy
   472       |> mk_Frees "A" (map HOLogic.mk_setT (permute As));
   473 
   474     val T = mk_T_of_bnf Ds As bnf;
   475 
   476     (*%f(1) ... f(n). bnf.map f\<sigma>(1) ... f\<sigma>(n)*)
   477     val mapx = fold_rev Term.absdummy (permute (map2 (curry op -->) As Bs))
   478       (Term.list_comb (mk_map_of_bnf Ds As Bs bnf, permute_rev (map Bound (live - 1 downto 0))));
   479     (*%Q(1) ... Q(n). bnf.rel Q\<sigma>(1) ... Q\<sigma>(n)*)
   480     val rel = fold_rev Term.absdummy (permute (map2 mk_pred2T As Bs))
   481       (Term.list_comb (mk_rel_of_bnf Ds As Bs bnf, permute_rev (map Bound (live - 1 downto 0))));
   482 
   483     val bnf_sets = mk_sets_of_bnf (replicate live Ds) (replicate live As) bnf;
   484     val sets = permute bnf_sets;
   485 
   486     val bd = mk_bd_of_bnf Ds As bnf;
   487 
   488     fun map_id_tac _ = rtac (map_id_of_bnf bnf) 1;
   489     fun map_comp_tac _ = rtac (map_comp_of_bnf bnf) 1;
   490     fun map_cong_tac {context, ...} =
   491       rtac (map_cong_of_bnf bnf) 1 THEN REPEAT_DETERM_N live (Goal.assume_rule_tac context 1);
   492     val set_natural_tacs = permute (map (fn thm => fn _ => rtac thm 1) (set_natural_of_bnf bnf));
   493     fun bd_card_order_tac _ = rtac (bd_card_order_of_bnf bnf) 1;
   494     fun bd_cinfinite_tac _ = rtac (bd_cinfinite_of_bnf bnf) 1;
   495     val set_bd_tacs = permute (map (fn thm => fn _ => rtac thm 1) (set_bd_of_bnf bnf));
   496 
   497     val in_alt_thm =
   498       let
   499         val inx = mk_in Asets sets T;
   500         val in_alt = mk_in (permute_rev Asets) bnf_sets T;
   501         val goal = fold_rev Logic.all Asets (mk_Trueprop_eq (inx, in_alt));
   502       in
   503         Skip_Proof.prove lthy [] [] goal (K (mk_permute_in_alt_tac src dest))
   504         |> Thm.close_derivation
   505       end;
   506 
   507     fun in_bd_tac _ =
   508       mk_permute_in_bd_tac src dest in_alt_thm (in_bd_of_bnf bnf) (bd_Card_order_of_bnf bnf);
   509     fun map_wpull_tac _ = mk_map_wpull_tac in_alt_thm [] (map_wpull_of_bnf bnf);
   510 
   511     fun srel_O_Gr_tac _ =
   512       mk_simple_srel_O_Gr_tac lthy (srel_def_of_bnf bnf) (srel_O_Gr_of_bnf bnf) in_alt_thm;
   513 
   514     val tacs = zip_axioms map_id_tac map_comp_tac map_cong_tac set_natural_tacs bd_card_order_tac
   515       bd_cinfinite_tac set_bd_tacs in_bd_tac map_wpull_tac srel_O_Gr_tac;
   516 
   517     val wits = map snd (mk_wits_of_bnf (replicate nwits Ds) (replicate nwits As) bnf);
   518 
   519     fun wit_tac _ = mk_simple_wit_tac (wit_thms_of_bnf bnf);
   520 
   521     val (bnf', lthy') =
   522       bnf_def Smart_Inline (K Dont_Note) qualify tacs wit_tac (SOME Ds)
   523         (((((b, mapx), sets), Term.absdummy T bd), wits), SOME rel) lthy;
   524   in
   525     (bnf', (add_bnf_to_unfolds bnf' unfold_set, lthy'))
   526   end;
   527 
   528 (* Composition pipeline *)
   529 
   530 fun permute_and_kill qualify n src dest bnf =
   531   bnf
   532   |> permute_bnf qualify src dest
   533   #> uncurry (kill_bnf qualify n);
   534 
   535 fun lift_and_permute qualify n src dest bnf =
   536   bnf
   537   |> lift_bnf qualify n
   538   #> uncurry (permute_bnf qualify src dest);
   539 
   540 fun normalize_bnfs qualify Ass Ds sort bnfs unfold_set lthy =
   541   let
   542     val before_kill_src = map (fn As => 0 upto (length As - 1)) Ass;
   543     val kill_poss = map (find_indices Ds) Ass;
   544     val live_poss = map2 (subtract (op =)) kill_poss before_kill_src;
   545     val before_kill_dest = map2 append kill_poss live_poss;
   546     val kill_ns = map length kill_poss;
   547     val (inners', (unfold_set', lthy')) =
   548       fold_map5 (fn i => permute_and_kill (qualify i))
   549         (if length bnfs = 1 then [0] else (1 upto length bnfs))
   550         kill_ns before_kill_src before_kill_dest bnfs (unfold_set, lthy);
   551 
   552     val Ass' = map2 (map o nth) Ass live_poss;
   553     val As = sort Ass';
   554     val after_lift_dest = replicate (length Ass') (0 upto (length As - 1));
   555     val old_poss = map (map (fn x => find_index (fn y => x = y) As)) Ass';
   556     val new_poss = map2 (subtract (op =)) old_poss after_lift_dest;
   557     val after_lift_src = map2 append new_poss old_poss;
   558     val lift_ns = map (fn xs => length As - length xs) Ass';
   559   in
   560     ((kill_poss, As), fold_map5 (fn i => lift_and_permute (qualify i))
   561       (if length bnfs = 1 then [0] else (1 upto length bnfs))
   562       lift_ns after_lift_src after_lift_dest inners' (unfold_set', lthy'))
   563   end;
   564 
   565 fun default_comp_sort Ass =
   566   Library.sort (Term_Ord.typ_ord o pairself TFree) (fold (fold (insert (op =))) Ass []);
   567 
   568 fun compose_bnf const_policy qualify sort outer inners oDs Dss tfreess (unfold_set, lthy) =
   569   let
   570     val b = name_of_bnf outer;
   571 
   572     val Ass = map (map Term.dest_TFree) tfreess;
   573     val Ds = fold (fold Term.add_tfreesT) (oDs :: Dss) [];
   574 
   575     val ((kill_poss, As), (inners', (unfold_set', lthy'))) =
   576       normalize_bnfs qualify Ass Ds sort inners unfold_set lthy;
   577 
   578     val Ds = oDs @ flat (map3 (append oo map o nth) tfreess kill_poss Dss);
   579     val As = map TFree As;
   580   in
   581     apfst (rpair (Ds, As))
   582       (clean_compose_bnf const_policy (qualify 0) b outer inners' (unfold_set', lthy'))
   583   end;
   584 
   585 (* Hide the type of the bound (optimization) and unfold the definitions (nicer to the user) *)
   586 
   587 fun seal_bnf unfold_set b Ds bnf lthy =
   588   let
   589     val live = live_of_bnf bnf;
   590     val nwits = nwits_of_bnf bnf;
   591 
   592     val (As, lthy1) = apfst (map TFree)
   593       (Variable.invent_types (replicate live HOLogic.typeS) (fold Variable.declare_typ Ds lthy));
   594     val (Bs, _) = apfst (map TFree)
   595       (Variable.invent_types (replicate live HOLogic.typeS) lthy1);
   596 
   597     val map_unfolds = #map_unfolds unfold_set;
   598     val set_unfoldss = #set_unfoldss unfold_set;
   599     val rel_unfolds = #rel_unfolds unfold_set;
   600     val srel_unfolds = #srel_unfolds unfold_set;
   601 
   602     val expand_maps =
   603       fold expand_term_const (map (single o Logic.dest_equals o Thm.prop_of) map_unfolds);
   604     val expand_sets =
   605       fold expand_term_const (map (map (Logic.dest_equals o Thm.prop_of)) set_unfoldss);
   606     val expand_rels =
   607       fold expand_term_const (map (single o Logic.dest_equals o Thm.prop_of) rel_unfolds);
   608     val unfold_maps = fold (unfold_thms lthy o single) map_unfolds;
   609     val unfold_sets = fold (unfold_thms lthy) set_unfoldss;
   610     val unfold_rels = unfold_thms lthy rel_unfolds;
   611     val unfold_srels = unfold_thms lthy srel_unfolds;
   612     val unfold_all = unfold_sets o unfold_maps o unfold_rels o unfold_srels;
   613     val bnf_map = expand_maps (mk_map_of_bnf Ds As Bs bnf);
   614     val bnf_sets = map (expand_maps o expand_sets)
   615       (mk_sets_of_bnf (replicate live Ds) (replicate live As) bnf);
   616     val bnf_bd = mk_bd_of_bnf Ds As bnf;
   617     val bnf_rel = expand_rels (mk_rel_of_bnf Ds As Bs bnf);
   618     val T = mk_T_of_bnf Ds As bnf;
   619 
   620     (*bd should only depend on dead type variables!*)
   621     val bd_repT = fst (dest_relT (fastype_of bnf_bd));
   622     val bdT_bind = Binding.suffix_name ("_" ^ bdTN) b;
   623     val params = fold Term.add_tfreesT Ds [];
   624     val deads = map TFree params;
   625 
   626     val ((bdT_name, (bdT_glob_info, bdT_loc_info)), lthy) =
   627       typedef false NONE (bdT_bind, params, NoSyn)
   628         (HOLogic.mk_UNIV bd_repT) NONE (EVERY' [rtac exI, rtac UNIV_I] 1) lthy;
   629 
   630     val bnf_bd' = mk_dir_image bnf_bd
   631       (Const (#Abs_name bdT_glob_info, bd_repT --> Type (bdT_name, deads)))
   632 
   633     val Abs_bdT_inj = mk_Abs_inj_thm (#Abs_inject bdT_loc_info);
   634     val Abs_bdT_bij = mk_Abs_bij_thm lthy Abs_bdT_inj (#Abs_cases bdT_loc_info);
   635 
   636     val bd_ordIso = @{thm dir_image} OF [Abs_bdT_inj, bd_Card_order_of_bnf bnf];
   637     val bd_card_order =
   638       @{thm card_order_dir_image} OF [Abs_bdT_bij, bd_card_order_of_bnf bnf];
   639     val bd_cinfinite =
   640       (@{thm Cinfinite_cong} OF [bd_ordIso, bd_Cinfinite_of_bnf bnf]) RS conjunct1;
   641 
   642     val set_bds =
   643       map (fn thm => @{thm ordLeq_ordIso_trans} OF [thm, bd_ordIso]) (set_bd_of_bnf bnf);
   644     val in_bd =
   645       @{thm ordLeq_ordIso_trans} OF [in_bd_of_bnf bnf,
   646         @{thm cexp_cong2_Cnotzero} OF [bd_ordIso, if live = 0 then
   647           @{thm ctwo_Cnotzero} else @{thm ctwo_Cnotzero} RS @{thm csum_Cnotzero2},
   648             bd_Card_order_of_bnf bnf]];
   649 
   650     fun mk_tac thm {context = ctxt, prems = _} =
   651       (rtac (unfold_all thm) THEN'
   652       SOLVE o REPEAT_DETERM o (atac ORELSE' Goal.assume_rule_tac ctxt)) 1;
   653 
   654     val tacs = zip_axioms (mk_tac (map_id_of_bnf bnf)) (mk_tac (map_comp_of_bnf bnf))
   655       (mk_tac (map_cong_of_bnf bnf)) (map mk_tac (set_natural_of_bnf bnf))
   656       (K (rtac bd_card_order 1)) (K (rtac bd_cinfinite 1)) (map mk_tac set_bds) (mk_tac in_bd)
   657       (mk_tac (map_wpull_of_bnf bnf))
   658       (mk_tac (unfold_thms lthy [srel_def_of_bnf bnf] (srel_O_Gr_of_bnf bnf)));
   659 
   660     val bnf_wits = map snd (mk_wits_of_bnf (replicate nwits Ds) (replicate nwits As) bnf);
   661 
   662     fun wit_tac _ = mk_simple_wit_tac (map unfold_all (wit_thms_of_bnf bnf));
   663 
   664     val (bnf', lthy') = bnf_def Hardly_Inline (user_policy Dont_Note) I tacs wit_tac (SOME deads)
   665       (((((b, bnf_map), bnf_sets), Term.absdummy T bnf_bd'), bnf_wits), SOME bnf_rel) lthy;
   666   in
   667     ((bnf', deads), lthy')
   668   end;
   669 
   670 fun bnf_of_typ _ _ _ (T as TFree _) accum = ((ID_bnf, ([], [T])), accum)
   671   | bnf_of_typ _ _ _ (TVar _) _ = error "Unexpected schematic variable"
   672   | bnf_of_typ const_policy qualify' sort (T as Type (C, Ts)) (unfold_set, lthy) =
   673     let
   674       val tfrees = Term.add_tfreesT T [];
   675       val bnf_opt = if null tfrees then NONE else bnf_of lthy C;
   676     in
   677       (case bnf_opt of
   678         NONE => ((DEADID_bnf, ([T], [])), (unfold_set, lthy))
   679       | SOME bnf =>
   680         if forall (can Term.dest_TFree) Ts andalso length Ts = length tfrees then
   681           let
   682             val T' = T_of_bnf bnf;
   683             val deads = deads_of_bnf bnf;
   684             val lives = lives_of_bnf bnf;
   685             val tvars' = Term.add_tvarsT T' [];
   686             val deads_lives =
   687               pairself (map (Term.typ_subst_TVars (map fst tvars' ~~ map TFree tfrees)))
   688                 (deads, lives);
   689           in ((bnf, deads_lives), (unfold_set, lthy)) end
   690         else
   691           let
   692             val name = Long_Name.base_name C;
   693             fun qualify i =
   694               let val namei = name ^ nonzero_string_of_int i;
   695               in qualify' o Binding.qualify true namei end;
   696             val odead = dead_of_bnf bnf;
   697             val olive = live_of_bnf bnf;
   698             val oDs_pos = find_indices [TFree ("dead", [])] (snd (Term.dest_Type
   699               (mk_T_of_bnf (replicate odead (TFree ("dead", []))) (replicate olive dummyT) bnf)));
   700             val oDs = map (nth Ts) oDs_pos;
   701             val Ts' = map (nth Ts) (subtract (op =) oDs_pos (0 upto length Ts - 1));
   702             val ((inners, (Dss, Ass)), (unfold_set', lthy')) =
   703               apfst (apsnd split_list o split_list)
   704                 (fold_map2 (fn i => bnf_of_typ Smart_Inline (qualify i) sort)
   705                 (if length Ts' = 1 then [0] else (1 upto length Ts')) Ts' (unfold_set, lthy));
   706           in
   707             compose_bnf const_policy qualify sort bnf inners oDs Dss Ass (unfold_set', lthy')
   708           end)
   709     end;
   710 
   711 end;